compiler/stgSyn/StgSyn.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section[StgSyn]{Shared term graph (STG) syntax for spineless-tagless code generation}
   5
   6 This data type represents programs just before code generation
   7 (conversion to @AbstractC@): basically, what we have is a stylised
   8 form of @CoreSyntax@, the style being one that happens to be ideally
   9 suited to spineless tagless code generation.
  10
  11 \begin{code}
  12 module StgSyn (
  13         GenStgArg(..),
  14         GenStgLiveVars,
  15
  16         GenStgBinding(..), GenStgExpr(..), GenStgRhs(..),
  17         GenStgAlt, AltType(..),
  18
  19         UpdateFlag(..), isUpdatable,
  20
  21         StgBinderInfo,
  22         noBinderInfo, stgSatOcc, stgUnsatOcc, satCallsOnly,
  23         combineStgBinderInfo,
  24
  25         -- a set of synonyms for the most common (only :-) parameterisation
  26         StgArg, StgLiveVars,
  27         StgBinding, StgExpr, StgRhs, StgAlt,
  28
  29         -- StgOp
  30         StgOp(..),
  31
  32         -- SRTs
  33         SRT(..),
  34
  35         -- utils
  36         stgBindHasCafRefs, stgArgHasCafRefs, stgRhsArity,
  37         isDllConApp, isStgTypeArg,
  38         stgArgType,
  39
  40         pprStgBinding, pprStgBindings, pprStgBindingsWithSRTs
  41
  42 #ifdef DEBUG
  43         , pprStgLVs
  44 #endif
  45     ) where
  46
  47 #include "HsVersions.h"
  48
  49 import CostCentre       ( CostCentreStack, CostCentre )
  50 import VarSet           ( IdSet, isEmptyVarSet )
  51 import Var              ( isId )
  52 import Id               ( Id, idName, idType, idCafInfo )
  53 import IdInfo           ( mayHaveCafRefs )
  54 import Packages         ( isDllName )
  55 import PackageConfig    ( PackageId )
  56 import Literal          ( Literal, literalType )
  57 import ForeignCall      ( ForeignCall )
  58 import DataCon          ( DataCon, dataConName )
  59 import CoreSyn          ( AltCon )
  60 import PprCore          ( {- instances -} )
  61 import PrimOp           ( PrimOp )
  62 import Outputable
  63 import Util             ( count )
  64 import Type             ( Type )
  65 import TyCon            ( TyCon )
  66 import UniqSet          ( isEmptyUniqSet, uniqSetToList, UniqSet )
  67 import Unique           ( Unique )
  68 import Bitmap
  69 import StaticFlags      ( opt_SccProfilingOn )
  70 import Module           ( Module, pprModule )
  71 \end{code}
  72
  73 %************************************************************************
  74 %*                                                                      *
  75 \subsection{@GenStgBinding@}
  76 %*                                                                      *
  77 %************************************************************************
  78
  79 As usual, expressions are interesting; other things are boring.  Here
  80 are the boring things [except note the @GenStgRhs@], parameterised
  81 with respect to binder and occurrence information (just as in
  82 @CoreSyn@):
  83
  84 There is one SRT for each group of bindings.
  85
  86 \begin{code}
  87 data GenStgBinding bndr occ
  88   = StgNonRec   bndr (GenStgRhs bndr occ)
  89   | StgRec      [(bndr, GenStgRhs bndr occ)]
  90 \end{code}
  91
  92 %************************************************************************
  93 %*                                                                      *
  94 \subsection{@GenStgArg@}
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 data GenStgArg occ
 100   = StgVarArg   occ
 101   | StgLitArg   Literal
 102   | StgTypeArg  Type            -- For when we want to preserve all type info
 103 \end{code}
 104
 105 \begin{code}
 106 isStgTypeArg (StgTypeArg _) = True
 107 isStgTypeArg other          = False
 108
 109 isDllArg :: PackageId -> StgArg -> Bool
 110         -- Does this argument refer to something in a different DLL?
 111 isDllArg this_pkg (StgTypeArg v)  = False
 112 isDllArg this_pkg (StgVarArg v)   = isDllName this_pkg (idName v)
 113 isDllArg this_pkg (StgLitArg lit) = False
 114
 115 isDllConApp :: PackageId -> DataCon -> [StgArg] -> Bool
 116         -- Does this constructor application refer to
 117         -- anything in a different DLL?
 118         -- If so, we can't allocate it statically
 119 isDllConApp this_pkg con args
 120    = isDllName this_pkg (dataConName con) || any (isDllArg this_pkg) args
 121
 122 stgArgType :: StgArg -> Type
 123         -- Very half baked becase we have lost the type arguments
 124 stgArgType (StgVarArg v)   = idType v
 125 stgArgType (StgLitArg lit) = literalType lit
 126 stgArgType (StgTypeArg lit) = panic "stgArgType called on stgTypeArg"
 127 \end{code}
 128
 129 %************************************************************************
 130 %*                                                                      *
 131 \subsection{STG expressions}
 132 %*                                                                      *
 133 %************************************************************************
 134
 135 The @GenStgExpr@ data type is parameterised on binder and occurrence
 136 info, as before.
 137
 138 %************************************************************************
 139 %*                                                                      *
 140 \subsubsection{@GenStgExpr@ application}
 141 %*                                                                      *
 142 %************************************************************************
 143
 144 An application is of a function to a list of atoms [not expressions].
 145 Operationally, we want to push the arguments on the stack and call the
 146 function.  (If the arguments were expressions, we would have to build
 147 their closures first.)
 148
 149 There is no constructor for a lone variable; it would appear as
 150 @StgApp var [] _@.
 151 \begin{code}
 152 type GenStgLiveVars occ = UniqSet occ
 153
 154 data GenStgExpr bndr occ
 155   = StgApp
 156         occ             -- function
 157         [GenStgArg occ] -- arguments; may be empty
 158 \end{code}
 159
 160 %************************************************************************
 161 %*                                                                      *
 162 \subsubsection{@StgConApp@ and @StgPrimApp@---saturated applications}
 163 %*                                                                      *
 164 %************************************************************************
 165
 166 There are a specialised forms of application, for
 167 constructors, primitives, and literals.
 168 \begin{code}
 169   | StgLit      Literal
 170
 171         -- StgConApp is vital for returning unboxed tuples
 172         -- which can't be let-bound first
 173   | StgConApp   DataCon
 174                 [GenStgArg occ] -- Saturated
 175
 176   | StgOpApp    StgOp           -- Primitive op or foreign call
 177                 [GenStgArg occ] -- Saturated
 178                 Type            -- Result type
 179                                 -- We need to know this so that we can
 180                                 -- assign result registers
 181 \end{code}
 182
 183 %************************************************************************
 184 %*                                                                      *
 185 \subsubsection{@StgLam@}
 186 %*                                                                      *
 187 %************************************************************************
 188
 189 StgLam is used *only* during CoreToStg's work.  Before CoreToStg has finished
 190 it encodes (\x -> e) as (let f = \x -> e in f)
 191
 192 \begin{code}
 193   | StgLam
 194         Type            -- Type of whole lambda (useful when making a binder for it)
 195         [bndr]
 196         StgExpr         -- Body of lambda
 197 \end{code}
 198
 199
 200 %************************************************************************
 201 %*                                                                      *
 202 \subsubsection{@GenStgExpr@: case-expressions}
 203 %*                                                                      *
 204 %************************************************************************
 205
 206 This has the same boxed/unboxed business as Core case expressions.
 207 \begin{code}
 208   | StgCase
 209         (GenStgExpr bndr occ)
 210                         -- the thing to examine
 211
 212         (GenStgLiveVars occ) -- Live vars of whole case expression,
 213                         -- plus everything that happens after the case
 214                         -- i.e., those which mustn't be overwritten
 215
 216         (GenStgLiveVars occ) -- Live vars of RHSs (plus what happens afterwards)
 217                         -- i.e., those which must be saved before eval.
 218                         --
 219                         -- note that an alt's constructor's
 220                         -- binder-variables are NOT counted in the
 221                         -- free vars for the alt's RHS
 222
 223         bndr            -- binds the result of evaluating the scrutinee
 224
 225         SRT             -- The SRT for the continuation
 226
 227         AltType
 228
 229         [GenStgAlt bndr occ]    -- The DEFAULT case is always *first*
 230                                 -- if it is there at all
 231 \end{code}
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsubsection{@GenStgExpr@:  @let(rec)@-expressions}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 The various forms of let(rec)-expression encode most of the
 240 interesting things we want to do.
 241 \begin{enumerate}
 242 \item
 243 \begin{verbatim}
 244 let-closure x = [free-vars] expr [args]
 245 in e
 246 \end{verbatim}
 247 is equivalent to
 248 \begin{verbatim}
 249 let x = (\free-vars -> \args -> expr) free-vars
 250 \end{verbatim}
 251 \tr{args} may be empty (and is for most closures).  It isn't under
 252 circumstances like this:
 253 \begin{verbatim}
 254 let x = (\y -> y+z)
 255 \end{verbatim}
 256 This gets mangled to
 257 \begin{verbatim}
 258 let-closure x = [z] [y] (y+z)
 259 \end{verbatim}
 260 The idea is that we compile code for @(y+z)@ in an environment in which
 261 @z@ is bound to an offset from \tr{Node}, and @y@ is bound to an
 262 offset from the stack pointer.
 263
 264 (A let-closure is an @StgLet@ with a @StgRhsClosure@ RHS.)
 265
 266 \item
 267 \begin{verbatim}
 268 let-constructor x = Constructor [args]
 269 in e
 270 \end{verbatim}
 271
 272 (A let-constructor is an @StgLet@ with a @StgRhsCon@ RHS.)
 273
 274 \item
 275 Letrec-expressions are essentially the same deal as
 276 let-closure/let-constructor, so we use a common structure and
 277 distinguish between them with an @is_recursive@ boolean flag.
 278
 279 \item
 280 \begin{verbatim}
 281 let-unboxed u = an arbitrary arithmetic expression in unboxed values
 282 in e
 283 \end{verbatim}
 284 All the stuff on the RHS must be fully evaluated.  No function calls either!
 285
 286 (We've backed away from this toward case-expressions with
 287 suitably-magical alts ...)
 288
 289 \item
 290 ~[Advanced stuff here!  Not to start with, but makes pattern matching
 291 generate more efficient code.]
 292
 293 \begin{verbatim}
 294 let-escapes-not fail = expr
 295 in e'
 296 \end{verbatim}
 297 Here the idea is that @e'@ guarantees not to put @fail@ in a data structure,
 298 or pass it to another function.  All @e'@ will ever do is tail-call @fail@.
 299 Rather than build a closure for @fail@, all we need do is to record the stack
 300 level at the moment of the @let-escapes-not@; then entering @fail@ is just
 301 a matter of adjusting the stack pointer back down to that point and entering
 302 the code for it.
 303
 304 Another example:
 305 \begin{verbatim}
 306 f x y = let z = huge-expression in
 307         if y==1 then z else
 308         if y==2 then z else
 309         1
 310 \end{verbatim}
 311
 312 (A let-escapes-not is an @StgLetNoEscape@.)
 313
 314 \item
 315 We may eventually want:
 316 \begin{verbatim}
 317 let-literal x = Literal
 318 in e
 319 \end{verbatim}
 320
 321 (ToDo: is this obsolete?)
 322 \end{enumerate}
 323
 324 And so the code for let(rec)-things:
 325 \begin{code}
 326   | StgLet
 327         (GenStgBinding bndr occ)        -- right hand sides (see below)
 328         (GenStgExpr bndr occ)           -- body
 329
 330   | StgLetNoEscape                      -- remember: ``advanced stuff''
 331         (GenStgLiveVars occ)            -- Live in the whole let-expression
 332                                         -- Mustn't overwrite these stack slots
 333                                         --  *Doesn't* include binders of the let(rec).
 334
 335         (GenStgLiveVars occ)            -- Live in the right hand sides (only)
 336                                         -- These are the ones which must be saved on
 337                                         -- the stack if they aren't there already
 338                                         --  *Does* include binders of the let(rec) if recursive.
 339
 340         (GenStgBinding bndr occ)        -- right hand sides (see below)
 341         (GenStgExpr bndr occ)           -- body
 342 \end{code}
 343
 344 %************************************************************************
 345 %*                                                                      *
 346 \subsubsection{@GenStgExpr@: @scc@ expressions}
 347 %*                                                                      *
 348 %************************************************************************
 349
 350 Finally for @scc@ expressions we introduce a new STG construct.
 351
 352 \begin{code}
 353   | StgSCC
 354         CostCentre              -- label of SCC expression
 355         (GenStgExpr bndr occ)   -- scc expression
 356 \end{code}
 357
 358 %************************************************************************
 359 %*                                                                      *
 360 \subsubsection{@GenStgExpr@: @hpc@ expressions}
 361 %*                                                                      *
 362 %************************************************************************
 363
 364 Finally for @scc@ expressions we introduce a new STG construct.
 365
 366 \begin{code}
 367   | StgTick
 368     Module                      -- the module of the source of this tick
 369     Int                         -- tick number
 370     (GenStgExpr bndr occ)       -- sub expression
 371   -- end of GenStgExpr
 372 \end{code}
 373
 374 %************************************************************************
 375 %*                                                                      *
 376 \subsection{STG right-hand sides}
 377 %*                                                                      *
 378 %************************************************************************
 379
 380 Here's the rest of the interesting stuff for @StgLet@s; the first
 381 flavour is for closures:
 382 \begin{code}
 383 data GenStgRhs bndr occ
 384   = StgRhsClosure
 385         CostCentreStack         -- CCS to be attached (default is CurrentCCS)
 386         StgBinderInfo           -- Info about how this binder is used (see below)
 387         [occ]                   -- non-global free vars; a list, rather than
 388                                 -- a set, because order is important
 389         !UpdateFlag             -- ReEntrant | Updatable | SingleEntry
 390         SRT                     -- The SRT reference
 391         [bndr]                  -- arguments; if empty, then not a function;
 392                                 -- as above, order is important.
 393         (GenStgExpr bndr occ)   -- body
 394 \end{code}
 395 An example may be in order.  Consider:
 396 \begin{verbatim}
 397 let t = \x -> \y -> ... x ... y ... p ... q in e
 398 \end{verbatim}
 399 Pulling out the free vars and stylising somewhat, we get the equivalent:
 400 \begin{verbatim}
 401 let t = (\[p,q] -> \[x,y] -> ... x ... y ... p ...q) p q
 402 \end{verbatim}
 403 Stg-operationally, the @[x,y]@ are on the stack, the @[p,q]@ are
 404 offsets from @Node@ into the closure, and the code ptr for the closure
 405 will be exactly that in parentheses above.
 406
 407 The second flavour of right-hand-side is for constructors (simple but important):
 408 \begin{code}
 409   | StgRhsCon
 410         CostCentreStack         -- CCS to be attached (default is CurrentCCS).
 411                                 -- Top-level (static) ones will end up with
 412                                 -- DontCareCCS, because we don't count static
 413                                 -- data in heap profiles, and we don't set CCCS
 414                                 -- from static closure.
 415         DataCon                 -- constructor
 416         [GenStgArg occ] -- args
 417 \end{code}
 418
 419 \begin{code}
 420 stgRhsArity :: StgRhs -> Int
 421 stgRhsArity (StgRhsClosure _ _ _ _ _ bndrs _) = count isId bndrs
 422   -- The arity never includes type parameters, so
 423   -- when keeping type arguments and binders in the Stg syntax
 424   -- (opt_RuntimeTypes) we have to fliter out the type binders.
 425 stgRhsArity (StgRhsCon _ _ _) = 0
 426 \end{code}
 427
 428 \begin{code}
 429 stgBindHasCafRefs :: GenStgBinding bndr Id -> Bool
 430 stgBindHasCafRefs (StgNonRec _ rhs) = rhsHasCafRefs rhs
 431 stgBindHasCafRefs (StgRec binds)    = any rhsHasCafRefs (map snd binds)
 432
 433 rhsHasCafRefs (StgRhsClosure _ _ _ upd srt _ _)
 434   = isUpdatable upd || nonEmptySRT srt
 435 rhsHasCafRefs (StgRhsCon _ _ args)
 436   = any stgArgHasCafRefs args
 437
 438 stgArgHasCafRefs (StgVarArg id) = mayHaveCafRefs (idCafInfo id)
 439 stgArgHasCafRefs _ = False
 440 \end{code}
 441
 442 Here's the @StgBinderInfo@ type, and its combining op:
 443 \begin{code}
 444 data StgBinderInfo
 445   = NoStgBinderInfo
 446   | SatCallsOnly        -- All occurrences are *saturated* *function* calls
 447                         -- This means we don't need to build an info table and
 448                         -- slow entry code for the thing
 449                         -- Thunks never get this value
 450
 451 noBinderInfo = NoStgBinderInfo
 452 stgUnsatOcc  = NoStgBinderInfo
 453 stgSatOcc    = SatCallsOnly
 454
 455 satCallsOnly :: StgBinderInfo -> Bool
 456 satCallsOnly SatCallsOnly    = True
 457 satCallsOnly NoStgBinderInfo = False
 458
 459 combineStgBinderInfo :: StgBinderInfo -> StgBinderInfo -> StgBinderInfo
 460 combineStgBinderInfo SatCallsOnly SatCallsOnly = SatCallsOnly
 461 combineStgBinderInfo info1 info2               = NoStgBinderInfo
 462
 463 --------------
 464 pp_binder_info NoStgBinderInfo = empty
 465 pp_binder_info SatCallsOnly    = ptext SLIT("sat-only")
 466 \end{code}
 467
 468 %************************************************************************
 469 %*                                                                      *
 470 \subsection[Stg-case-alternatives]{STG case alternatives}
 471 %*                                                                      *
 472 %************************************************************************
 473
 474 Very like in @CoreSyntax@ (except no type-world stuff).
 475
 476 The type constructor is guaranteed not to be abstract; that is, we can
 477 see its representation.  This is important because the code generator
 478 uses it to determine return conventions etc.  But it's not trivial
 479 where there's a moduule loop involved, because some versions of a type
 480 constructor might not have all the constructors visible.  So
 481 mkStgAlgAlts (in CoreToStg) ensures that it gets the TyCon from the
 482 constructors or literals (which are guaranteed to have the Real McCoy)
 483 rather than from the scrutinee type.
 484
 485 \begin{code}
 486 type GenStgAlt bndr occ
 487   = (AltCon,            -- alts: data constructor,
 488      [bndr],            -- constructor's parameters,
 489      [Bool],            -- "use mask", same length as
 490                         -- parameters; a True in a
 491                         -- param's position if it is
 492                         -- used in the ...
 493      GenStgExpr bndr occ)       -- ...right-hand side.
 494
 495 data AltType
 496   = PolyAlt             -- Polymorphic (a type variable)
 497   | UbxTupAlt TyCon     -- Unboxed tuple
 498   | AlgAlt    TyCon     -- Algebraic data type; the AltCons will be DataAlts
 499   | PrimAlt   TyCon     -- Primitive data type; the AltCons will be LitAlts
 500 \end{code}
 501
 502 %************************************************************************
 503 %*                                                                      *
 504 \subsection[Stg]{The Plain STG parameterisation}
 505 %*                                                                      *
 506 %************************************************************************
 507
 508 This happens to be the only one we use at the moment.
 509
 510 \begin{code}
 511 type StgBinding     = GenStgBinding     Id Id
 512 type StgArg         = GenStgArg         Id
 513 type StgLiveVars    = GenStgLiveVars    Id
 514 type StgExpr        = GenStgExpr        Id Id
 515 type StgRhs         = GenStgRhs         Id Id
 516 type StgAlt         = GenStgAlt         Id Id
 517 \end{code}
 518
 519 %************************************************************************
 520 %*                                                                      *
 521 \subsubsection[UpdateFlag-datatype]{@UpdateFlag@}
 522 %*                                                                      *
 523 %************************************************************************
 524
 525 This is also used in @LambdaFormInfo@ in the @ClosureInfo@ module.
 526
 527 A @ReEntrant@ closure may be entered multiple times, but should not be
 528 updated or blackholed.  An @Updatable@ closure should be updated after
 529 evaluation (and may be blackholed during evaluation).  A @SingleEntry@
 530 closure will only be entered once, and so need not be updated but may
 531 safely be blackholed.
 532
 533 \begin{code}
 534 data UpdateFlag = ReEntrant | Updatable | SingleEntry
 535
 536 instance Outputable UpdateFlag where
 537     ppr u
 538       = char (case u of { ReEntrant -> 'r';  Updatable -> 'u';  SingleEntry -> 's' })
 539
 540 isUpdatable ReEntrant   = False
 541 isUpdatable SingleEntry = False
 542 isUpdatable Updatable   = True
 543 \end{code}
 544
 545 %************************************************************************
 546 %*                                                                      *
 547 \subsubsection{StgOp}
 548 %*                                                                      *
 549 %************************************************************************
 550
 551 An StgOp allows us to group together PrimOps and ForeignCalls.
 552 It's quite useful to move these around together, notably
 553 in StgOpApp and COpStmt.
 554
 555 \begin{code}
 556 data StgOp = StgPrimOp  PrimOp
 557
 558            | StgFCallOp ForeignCall Unique
 559                 -- The Unique is occasionally needed by the C pretty-printer
 560                 -- (which lacks a unique supply), notably when generating a
 561                 -- typedef for foreign-export-dynamic
 562 \end{code}
 563
 564
 565 %************************************************************************
 566 %*                                                                      *
 567 \subsubsection[Static Reference Tables]{@SRT@}
 568 %*                                                                      *
 569 %************************************************************************
 570
 571 There is one SRT per top-level function group.  Each local binding and
 572 case expression within this binding group has a subrange of the whole
 573 SRT, expressed as an offset and length.
 574
 575 In CoreToStg we collect the list of CafRefs at each SRT site, which is later
 576 converted into the length and offset form by the SRT pass.
 577
 578 \begin{code}
 579 data SRT = NoSRT
 580          | SRTEntries IdSet
 581                 -- generated by CoreToStg
 582          | SRT !Int{-offset-} !Int{-length-} !Bitmap{-bitmap-}
 583                 -- generated by computeSRTs
 584
 585 noSRT :: SRT
 586 noSRT = NoSRT
 587
 588 nonEmptySRT NoSRT           = False
 589 nonEmptySRT (SRTEntries vs) = not (isEmptyVarSet vs)
 590 nonEmptySRT _               = True
 591
 592 pprSRT (NoSRT) = ptext SLIT("_no_srt_")
 593 pprSRT (SRTEntries ids) = text "SRT:" <> ppr ids
 594 pprSRT (SRT off length bitmap) = parens (ppr off <> comma <> text "*bitmap*")
 595 \end{code}
 596
 597 %************************************************************************
 598 %*                                                                      *
 599 \subsection[Stg-pretty-printing]{Pretty-printing}
 600 %*                                                                      *
 601 %************************************************************************
 602
 603 Robin Popplestone asked for semi-colon separators on STG binds; here's
 604 hoping he likes terminators instead...  Ditto for case alternatives.
 605
 606 \begin{code}
 607 pprGenStgBinding :: (Outputable bndr, Outputable bdee, Ord bdee)
 608                  => GenStgBinding bndr bdee -> SDoc
 609
 610 pprGenStgBinding (StgNonRec bndr rhs)
 611   = hang (hsep [ppr bndr, equals])
 612         4 ((<>) (ppr rhs) semi)
 613
 614 pprGenStgBinding (StgRec pairs)
 615   = vcat ((ifPprDebug (ptext SLIT("{- StgRec (begin) -}"))) :
 616            (map (ppr_bind) pairs) ++ [(ifPprDebug (ptext SLIT("{- StgRec (end) -}")))])
 617   where
 618     ppr_bind (bndr, expr)
 619       = hang (hsep [ppr bndr, equals])
 620              4 ((<>) (ppr expr) semi)
 621
 622 pprStgBinding  :: StgBinding -> SDoc
 623 pprStgBinding  bind  = pprGenStgBinding bind
 624
 625 pprStgBindings :: [StgBinding] -> SDoc
 626 pprStgBindings binds = vcat (map pprGenStgBinding binds)
 627
 628 pprGenStgBindingWithSRT
 629         :: (Outputable bndr, Outputable bdee, Ord bdee)
 630         => (GenStgBinding bndr bdee,[(Id,[Id])]) -> SDoc
 631
 632 pprGenStgBindingWithSRT (bind,srts)
 633   = vcat (pprGenStgBinding bind : map pprSRT srts)
 634   where pprSRT (id,srt) =
 635            ptext SLIT("SRT") <> parens (ppr id) <> ptext SLIT(": ") <> ppr srt
 636
 637 pprStgBindingsWithSRTs :: [(StgBinding,[(Id,[Id])])] -> SDoc
 638 pprStgBindingsWithSRTs binds = vcat (map pprGenStgBindingWithSRT binds)
 639 \end{code}
 640
 641 \begin{code}
 642 instance (Outputable bdee) => Outputable (GenStgArg bdee) where
 643     ppr = pprStgArg
 644
 645 instance (Outputable bndr, Outputable bdee, Ord bdee)
 646                 => Outputable (GenStgBinding bndr bdee) where
 647     ppr = pprGenStgBinding
 648
 649 instance (Outputable bndr, Outputable bdee, Ord bdee)
 650                 => Outputable (GenStgExpr bndr bdee) where
 651     ppr = pprStgExpr
 652
 653 instance (Outputable bndr, Outputable bdee, Ord bdee)
 654                 => Outputable (GenStgRhs bndr bdee) where
 655     ppr rhs = pprStgRhs rhs
 656 \end{code}
 657
 658 \begin{code}
 659 pprStgArg :: (Outputable bdee) => GenStgArg bdee -> SDoc
 660
 661 pprStgArg (StgVarArg var) = ppr var
 662 pprStgArg (StgLitArg con) = ppr con
 663 pprStgArg (StgTypeArg ty) = char '@' <+> ppr ty
 664 \end{code}
 665
 666 \begin{code}
 667 pprStgExpr :: (Outputable bndr, Outputable bdee, Ord bdee)
 668            => GenStgExpr bndr bdee -> SDoc
 669 -- special case
 670 pprStgExpr (StgLit lit)     = ppr lit
 671
 672 -- general case
 673 pprStgExpr (StgApp func args)
 674   = hang (ppr func)
 675          4 (sep (map (ppr) args))
 676 \end{code}
 677
 678 \begin{code}
 679 pprStgExpr (StgConApp con args)
 680   = hsep [ ppr con, brackets (interppSP args)]
 681
 682 pprStgExpr (StgOpApp op args _)
 683   = hsep [ pprStgOp op, brackets (interppSP args)]
 684
 685 pprStgExpr (StgLam _ bndrs body)
 686   =sep [ char '\\' <+> ppr bndrs <+> ptext SLIT("->"),
 687          pprStgExpr body ]
 688 \end{code}
 689
 690 \begin{code}
 691 -- special case: let v = <very specific thing>
 692 --               in
 693 --               let ...
 694 --               in
 695 --               ...
 696 --
 697 -- Very special!  Suspicious! (SLPJ)
 698
 699 {-
 700 pprStgExpr (StgLet srt (StgNonRec bndr (StgRhsClosure cc bi free_vars upd_flag args rhs))
 701                         expr@(StgLet _ _))
 702   = ($$)
 703       (hang (hcat [ptext SLIT("let { "), ppr bndr, ptext SLIT(" = "),
 704                           ppr cc,
 705                           pp_binder_info bi,
 706                           ptext SLIT(" ["), ifPprDebug (interppSP free_vars), ptext SLIT("] \\"),
 707                           ppr upd_flag, ptext SLIT(" ["),
 708                           interppSP args, char ']'])
 709             8 (sep [hsep [ppr rhs, ptext SLIT("} in")]]))
 710       (ppr expr)
 711 -}
 712
 713 -- special case: let ... in let ...
 714
 715 pprStgExpr (StgLet bind expr@(StgLet _ _))
 716   = ($$)
 717       (sep [hang (ptext SLIT("let {"))
 718                 2 (hsep [pprGenStgBinding bind, ptext SLIT("} in")])])
 719       (ppr expr)
 720
 721 -- general case
 722 pprStgExpr (StgLet bind expr)
 723   = sep [hang (ptext SLIT("let {")) 2 (pprGenStgBinding bind),
 724            hang (ptext SLIT("} in ")) 2 (ppr expr)]
 725
 726 pprStgExpr (StgLetNoEscape lvs_whole lvs_rhss bind expr)
 727   = sep [hang (ptext SLIT("let-no-escape {"))
 728                 2 (pprGenStgBinding bind),
 729            hang ((<>) (ptext SLIT("} in "))
 730                    (ifPprDebug (
 731                     nest 4 (
 732                       hcat [ptext  SLIT("-- lvs: ["), interppSP (uniqSetToList lvs_whole),
 733                              ptext SLIT("]; rhs lvs: ["), interppSP (uniqSetToList lvs_rhss),
 734                              char ']']))))
 735                 2 (ppr expr)]
 736
 737 pprStgExpr (StgSCC cc expr)
 738   = sep [ hsep [ptext SLIT("_scc_"), ppr cc],
 739           pprStgExpr expr ]
 740
 741 pprStgExpr (StgTick m n expr)
 742   = sep [ hsep [ptext SLIT("_tick_"),  pprModule m,text (show n)],
 743           pprStgExpr expr ]
 744
 745 pprStgExpr (StgCase expr lvs_whole lvs_rhss bndr srt alt_type alts)
 746   = sep [sep [ptext SLIT("case"),
 747            nest 4 (hsep [pprStgExpr expr,
 748              ifPprDebug (dcolon <+> ppr alt_type)]),
 749            ptext SLIT("of"), ppr bndr, char '{'],
 750            ifPprDebug (
 751            nest 4 (
 752              hcat [ptext  SLIT("-- lvs: ["), interppSP (uniqSetToList lvs_whole),
 753                     ptext SLIT("]; rhs lvs: ["), interppSP (uniqSetToList lvs_rhss),
 754                     ptext SLIT("]; "),
 755                     pprMaybeSRT srt])),
 756            nest 2 (vcat (map pprStgAlt alts)),
 757            char '}']
 758
 759 pprStgAlt (con, params, use_mask, expr)
 760   = hang (hsep [ppr con, interppSP params, ptext SLIT("->")])
 761          4 (ppr expr <> semi)
 762
 763 pprStgOp (StgPrimOp  op)   = ppr op
 764 pprStgOp (StgFCallOp op _) = ppr op
 765
 766 instance Outputable AltType where
 767   ppr PolyAlt        = ptext SLIT("Polymorphic")
 768   ppr (UbxTupAlt tc) = ptext SLIT("UbxTup") <+> ppr tc
 769   ppr (AlgAlt tc)    = ptext SLIT("Alg")    <+> ppr tc
 770   ppr (PrimAlt tc)   = ptext SLIT("Prim")   <+> ppr tc
 771 \end{code}
 772
 773 \begin{code}
 774 pprStgLVs :: Outputable occ => GenStgLiveVars occ -> SDoc
 775 pprStgLVs lvs
 776   = getPprStyle $ \ sty ->
 777     if userStyle sty || isEmptyUniqSet lvs then
 778         empty
 779     else
 780         hcat [text "{-lvs:", interpp'SP (uniqSetToList lvs), text "-}"]
 781 \end{code}
 782
 783 \begin{code}
 784 pprStgRhs :: (Outputable bndr, Outputable bdee, Ord bdee)
 785           => GenStgRhs bndr bdee -> SDoc
 786
 787 -- special case
 788 pprStgRhs (StgRhsClosure cc bi [free_var] upd_flag srt [{-no args-}] (StgApp func []))
 789   = hcat [ ppr cc,
 790            pp_binder_info bi,
 791            brackets (ifPprDebug (ppr free_var)),
 792            ptext SLIT(" \\"), ppr upd_flag, pprMaybeSRT srt, ptext SLIT(" [] "), ppr func ]
 793
 794 -- general case
 795 pprStgRhs (StgRhsClosure cc bi free_vars upd_flag srt args body)
 796   = hang (hsep [if opt_SccProfilingOn then ppr cc else empty,
 797                 pp_binder_info bi,
 798                 ifPprDebug (brackets (interppSP free_vars)),
 799                 char '\\' <> ppr upd_flag, pprMaybeSRT srt, brackets (interppSP args)])
 800          4 (ppr body)
 801
 802 pprStgRhs (StgRhsCon cc con args)
 803   = hcat [ ppr cc,
 804            space, ppr con, ptext SLIT("! "), brackets (interppSP args)]
 805
 806 pprMaybeSRT (NoSRT) = empty
 807 pprMaybeSRT srt     = ptext SLIT("srt:") <> pprSRT srt
 808 \end{code}