compiler/stranal/DmdAnal.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4
   5                         -----------------
   6                         A demand analysis
   7                         -----------------
   8
   9 \begin{code}
  10 {-# OPTIONS -w #-}
  11 -- The above warning supression flag is a temporary kludge.
  12 -- While working on this module you are encouraged to remove it and fix
  13 -- any warnings in the module. See
  14 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  15 -- for details
  16
  17 module DmdAnal ( dmdAnalPgm, dmdAnalTopRhs,
  18                  both {- needed by WwLib -}
  19    ) where
  20
  21 #include "HsVersions.h"
  22
  23 import DynFlags         ( DynFlags, DynFlag(..) )
  24 import StaticFlags      ( opt_MaxWorkerArgs )
  25 import NewDemand        -- All of it
  26 import CoreSyn
  27 import PprCore
  28 import CoreUtils        ( exprIsHNF, exprIsTrivial, exprArity )
  29 import DataCon          ( dataConTyCon )
  30 import TyCon            ( isProductTyCon, isRecursiveTyCon )
  31 import Id               ( Id, idType, idInlinePragma,
  32                           isDataConWorkId, isGlobalId, idArity,
  33 #ifdef OLD_STRICTNESS
  34                           idDemandInfo,  idStrictness, idCprInfo, idName,
  35 #endif
  36                           idNewStrictness, idNewStrictness_maybe,
  37                           setIdNewStrictness, idNewDemandInfo,
  38                           idNewDemandInfo_maybe,
  39                           setIdNewDemandInfo
  40                         )
  41 #ifdef OLD_STRICTNESS
  42 import IdInfo           ( newStrictnessFromOld, newDemand )
  43 #endif
  44 import Var              ( Var )
  45 import VarEnv
  46 import TysWiredIn       ( unboxedPairDataCon )
  47 import TysPrim          ( realWorldStatePrimTy )
  48 import UniqFM           ( plusUFM_C, addToUFM_Directly, lookupUFM_Directly,
  49                           keysUFM, minusUFM, ufmToList, filterUFM )
  50 import Type             ( isUnLiftedType, coreEqType, splitTyConApp_maybe )
  51 import Coercion         ( coercionKind )
  52 import CoreLint         ( showPass, endPass )
  53 import Util             ( mapAndUnzip, lengthIs )
  54 import BasicTypes       ( Arity, TopLevelFlag(..), isTopLevel, isNeverActive,
  55                           RecFlag(..), isRec )
  56 import Maybes           ( orElse, expectJust )
  57 import Outputable
  58
  59 import Data.List
  60 \end{code}
  61
  62 To think about
  63
  64 * set a noinline pragma on bottoming Ids
  65
  66 * Consider f x = x+1 `fatbar` error (show x)
  67   We'd like to unbox x, even if that means reboxing it in the error case.
  68
  69
  70 %************************************************************************
  71 %*                                                                      *
  72 \subsection{Top level stuff}
  73 %*                                                                      *
  74 %************************************************************************
  75
  76 \begin{code}
  77 dmdAnalPgm :: DynFlags -> [CoreBind] -> IO [CoreBind]
  78 dmdAnalPgm dflags binds
  79   = do {
  80         showPass dflags "Demand analysis" ;
  81         let { binds_plus_dmds = do_prog binds } ;
  82
  83         endPass dflags "Demand analysis"
  84                 Opt_D_dump_stranal binds_plus_dmds ;
  85 #ifdef OLD_STRICTNESS
  86         -- Only if OLD_STRICTNESS is on, because only then is the old
  87         -- strictness analyser run
  88         let { dmd_changes = get_changes binds_plus_dmds } ;
  89         printDump (text "Changes in demands" $$ dmd_changes) ;
  90 #endif
  91         return binds_plus_dmds
  92     }
  93   where
  94     do_prog :: [CoreBind] -> [CoreBind]
  95     do_prog binds = snd $ mapAccumL dmdAnalTopBind emptySigEnv binds
  96
  97 dmdAnalTopBind :: SigEnv
  98                -> CoreBind
  99                -> (SigEnv, CoreBind)
 100 dmdAnalTopBind sigs (NonRec id rhs)
 101   = let
 102         (    _, _, (_,   rhs1)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs)
 103         (sigs2, _, (id2, rhs2)) = dmdAnalRhs TopLevel NonRecursive sigs (id, rhs1)
 104                 -- Do two passes to improve CPR information
 105                 -- See comments with ignore_cpr_info in mk_sig_ty
 106                 -- and with extendSigsWithLam
 107     in
 108     (sigs2, NonRec id2 rhs2)
 109
 110 dmdAnalTopBind sigs (Rec pairs)
 111   = let
 112         (sigs', _, pairs')  = dmdFix TopLevel sigs pairs
 113                 -- We get two iterations automatically
 114                 -- c.f. the NonRec case above
 115     in
 116     (sigs', Rec pairs')
 117 \end{code}
 118
 119 \begin{code}
 120 dmdAnalTopRhs :: CoreExpr -> (StrictSig, CoreExpr)
 121 -- Analyse the RHS and return
 122 --      a) appropriate strictness info
 123 --      b) the unfolding (decorated with stricntess info)
 124 dmdAnalTopRhs rhs
 125   = (sig, rhs2)
 126   where
 127     call_dmd       = vanillaCall (exprArity rhs)
 128     (_,      rhs1) = dmdAnal emptySigEnv call_dmd rhs
 129     (rhs_ty, rhs2) = dmdAnal emptySigEnv call_dmd rhs1
 130     sig            = mkTopSigTy rhs rhs_ty
 131         -- Do two passes; see notes with extendSigsWithLam
 132         -- Otherwise we get bogus CPR info for constructors like
 133         --      newtype T a = MkT a
 134         -- The constructor looks like (\x::T a -> x), modulo the coerce
 135         -- extendSigsWithLam will optimistically give x a CPR tag the
 136         -- first time, which is wrong in the end.
 137 \end{code}
 138
 139 %************************************************************************
 140 %*                                                                      *
 141 \subsection{The analyser itself}
 142 %*                                                                      *
 143 %************************************************************************
 144
 145 \begin{code}
 146 dmdAnal :: SigEnv -> Demand -> CoreExpr -> (DmdType, CoreExpr)
 147
 148 dmdAnal sigs Abs  e = (topDmdType, e)
 149
 150 dmdAnal sigs dmd e
 151   | not (isStrictDmd dmd)
 152   = let
 153         (res_ty, e') = dmdAnal sigs evalDmd e
 154     in
 155     (deferType res_ty, e')
 156         -- It's important not to analyse e with a lazy demand because
 157         -- a) When we encounter   case s of (a,b) ->
 158         --      we demand s with U(d1d2)... but if the overall demand is lazy
 159         --      that is wrong, and we'd need to reduce the demand on s,
 160         --      which is inconvenient
 161         -- b) More important, consider
 162         --      f (let x = R in x+x), where f is lazy
 163         --    We still want to mark x as demanded, because it will be when we
 164         --    enter the let.  If we analyse f's arg with a Lazy demand, we'll
 165         --    just mark x as Lazy
 166         -- c) The application rule wouldn't be right either
 167         --    Evaluating (f x) in a L demand does *not* cause
 168         --    evaluation of f in a C(L) demand!
 169
 170
 171 dmdAnal sigs dmd (Lit lit)
 172   = (topDmdType, Lit lit)
 173
 174 dmdAnal sigs dmd (Var var)
 175   = (dmdTransform sigs var dmd, Var var)
 176
 177 dmdAnal sigs dmd (Cast e co)
 178   = (dmd_ty, Cast e' co)
 179   where
 180     (dmd_ty, e') = dmdAnal sigs dmd' e
 181     to_co        = snd (coercionKind co)
 182     dmd'
 183       | Just (tc, args) <- splitTyConApp_maybe to_co
 184       , isRecursiveTyCon tc = evalDmd
 185       | otherwise           = dmd
 186         -- This coerce usually arises from a recursive
 187         -- newtype, and we don't want to look inside them
 188         -- for exactly the same reason that we don't look
 189         -- inside recursive products -- we might not reach
 190         -- a fixpoint.  So revert to a vanilla Eval demand
 191
 192 dmdAnal sigs dmd (Note n e)
 193   = (dmd_ty, Note n e')
 194   where
 195     (dmd_ty, e') = dmdAnal sigs dmd e
 196
 197 dmdAnal sigs dmd (App fun (Type ty))
 198   = (fun_ty, App fun' (Type ty))
 199   where
 200     (fun_ty, fun') = dmdAnal sigs dmd fun
 201
 202 -- Lots of the other code is there to make this
 203 -- beautiful, compositional, application rule :-)
 204 dmdAnal sigs dmd e@(App fun arg)        -- Non-type arguments
 205   = let                         -- [Type arg handled above]
 206         (fun_ty, fun')    = dmdAnal sigs (Call dmd) fun
 207         (arg_ty, arg')    = dmdAnal sigs arg_dmd arg
 208         (arg_dmd, res_ty) = splitDmdTy fun_ty
 209     in
 210     (res_ty `bothType` arg_ty, App fun' arg')
 211
 212 dmdAnal sigs dmd (Lam var body)
 213   | isTyVar var
 214   = let
 215         (body_ty, body') = dmdAnal sigs dmd body
 216     in
 217     (body_ty, Lam var body')
 218
 219   | Call body_dmd <- dmd        -- A call demand: good!
 220   = let
 221         sigs'            = extendSigsWithLam sigs var
 222         (body_ty, body') = dmdAnal sigs' body_dmd body
 223         (lam_ty, var')   = annotateLamIdBndr body_ty var
 224     in
 225     (lam_ty, Lam var' body')
 226
 227   | otherwise   -- Not enough demand on the lambda; but do the body
 228   = let         -- anyway to annotate it and gather free var info
 229         (body_ty, body') = dmdAnal sigs evalDmd body
 230         (lam_ty, var')   = annotateLamIdBndr body_ty var
 231     in
 232     (deferType lam_ty, Lam var' body')
 233
 234 dmdAnal sigs dmd (Case scrut case_bndr ty [alt@(DataAlt dc,bndrs,rhs)])
 235   | let tycon = dataConTyCon dc,
 236     isProductTyCon tycon,
 237     not (isRecursiveTyCon tycon)
 238   = let
 239         sigs_alt              = extendSigEnv NotTopLevel sigs case_bndr case_bndr_sig
 240         (alt_ty, alt')        = dmdAnalAlt sigs_alt dmd alt
 241         (alt_ty1, case_bndr') = annotateBndr alt_ty case_bndr
 242         (_, bndrs', _)        = alt'
 243         case_bndr_sig         = cprSig
 244                 -- Inside the alternative, the case binder has the CPR property.
 245                 -- Meaning that a case on it will successfully cancel.
 246                 -- Example:
 247                 --      f True  x = case x of y { I# x' -> if x' ==# 3 then y else I# 8 }
 248                 --      f False x = I# 3
 249                 --
 250                 -- We want f to have the CPR property:
 251                 --      f b x = case fw b x of { r -> I# r }
 252                 --      fw True  x = case x of y { I# x' -> if x' ==# 3 then x' else 8 }
 253                 --      fw False x = 3
 254
 255         -- Figure out whether the demand on the case binder is used, and use
 256         -- that to set the scrut_dmd.  This is utterly essential.
 257         -- Consider     f x = case x of y { (a,b) -> k y a }
 258         -- If we just take scrut_demand = U(L,A), then we won't pass x to the
 259         -- worker, so the worker will rebuild
 260         --      x = (a, absent-error)
 261         -- and that'll crash.
 262         -- So at one stage I had:
 263         --      dead_case_bndr           = isAbsentDmd (idNewDemandInfo case_bndr')
 264         --      keepity | dead_case_bndr = Drop
 265         --              | otherwise      = Keep
 266         --
 267         -- But then consider
 268         --      case x of y { (a,b) -> h y + a }
 269         -- where h : U(LL) -> T
 270         -- The above code would compute a Keep for x, since y is not Abs, which is silly
 271         -- The insight is, of course, that a demand on y is a demand on the
 272         -- scrutinee, so we need to `both` it with the scrut demand
 273
 274         alt_dmd            = Eval (Prod [idNewDemandInfo b | b <- bndrs', isId b])
 275         scrut_dmd          = alt_dmd `both`
 276                              idNewDemandInfo case_bndr'
 277
 278         (scrut_ty, scrut') = dmdAnal sigs scrut_dmd scrut
 279     in
 280     (alt_ty1 `bothType` scrut_ty, Case scrut' case_bndr' ty [alt'])
 281
 282 dmdAnal sigs dmd (Case scrut case_bndr ty alts)
 283   = let
 284         (alt_tys, alts')        = mapAndUnzip (dmdAnalAlt sigs dmd) alts
 285         (scrut_ty, scrut')      = dmdAnal sigs evalDmd scrut
 286         (alt_ty, case_bndr')    = annotateBndr (foldr1 lubType alt_tys) case_bndr
 287     in
 288 --    pprTrace "dmdAnal:Case" (ppr alts $$ ppr alt_tys)
 289     (alt_ty `bothType` scrut_ty, Case scrut' case_bndr' ty alts')
 290
 291 dmdAnal sigs dmd (Let (NonRec id rhs) body)
 292   = let
 293         (sigs', lazy_fv, (id1, rhs')) = dmdAnalRhs NotTopLevel NonRecursive sigs (id, rhs)
 294         (body_ty, body')              = dmdAnal sigs' dmd body
 295         (body_ty1, id2)               = annotateBndr body_ty id1
 296         body_ty2                      = addLazyFVs body_ty1 lazy_fv
 297     in
 298         -- If the actual demand is better than the vanilla call
 299         -- demand, you might think that we might do better to re-analyse
 300         -- the RHS with the stronger demand.
 301         -- But (a) That seldom happens, because it means that *every* path in
 302         --         the body of the let has to use that stronger demand
 303         -- (b) It often happens temporarily in when fixpointing, because
 304         --     the recursive function at first seems to place a massive demand.
 305         --     But we don't want to go to extra work when the function will
 306         --     probably iterate to something less demanding.
 307         -- In practice, all the times the actual demand on id2 is more than
 308         -- the vanilla call demand seem to be due to (b).  So we don't
 309         -- bother to re-analyse the RHS.
 310     (body_ty2, Let (NonRec id2 rhs') body')
 311
 312 dmdAnal sigs dmd (Let (Rec pairs) body)
 313   = let
 314         bndrs                    = map fst pairs
 315         (sigs', lazy_fv, pairs') = dmdFix NotTopLevel sigs pairs
 316         (body_ty, body')         = dmdAnal sigs' dmd body
 317         body_ty1                 = addLazyFVs body_ty lazy_fv
 318     in
 319     sigs' `seq` body_ty `seq`
 320     let
 321         (body_ty2, _) = annotateBndrs body_ty1 bndrs
 322                 -- Don't bother to add demand info to recursive
 323                 -- binders as annotateBndr does;
 324                 -- being recursive, we can't treat them strictly.
 325                 -- But we do need to remove the binders from the result demand env
 326     in
 327     (body_ty2,  Let (Rec pairs') body')
 328
 329
 330 dmdAnalAlt sigs dmd (con,bndrs,rhs)
 331   = let
 332         (rhs_ty, rhs')   = dmdAnal sigs dmd rhs
 333         (alt_ty, bndrs') = annotateBndrs rhs_ty bndrs
 334         final_alt_ty | io_hack_reqd = alt_ty `lubType` topDmdType
 335                      | otherwise    = alt_ty
 336
 337         -- There's a hack here for I/O operations.  Consider
 338         --      case foo x s of { (# s, r #) -> y }
 339         -- Is this strict in 'y'.  Normally yes, but what if 'foo' is an I/O
 340         -- operation that simply terminates the program (not in an erroneous way)?
 341         -- In that case we should not evaluate y before the call to 'foo'.
 342         -- Hackish solution: spot the IO-like situation and add a virtual branch,
 343         -- as if we had
 344         --      case foo x s of
 345         --         (# s, r #) -> y
 346         --         other      -> return ()
 347         -- So the 'y' isn't necessarily going to be evaluated
 348         --
 349         -- A more complete example where this shows up is:
 350         --      do { let len = <expensive> ;
 351         --         ; when (...) (exitWith ExitSuccess)
 352         --         ; print len }
 353
 354         io_hack_reqd = con == DataAlt unboxedPairDataCon &&
 355                        idType (head bndrs) `coreEqType` realWorldStatePrimTy
 356     in
 357     (final_alt_ty, (con, bndrs', rhs'))
 358 \end{code}
 359
 360 %************************************************************************
 361 %*                                                                      *
 362 \subsection{Bindings}
 363 %*                                                                      *
 364 %************************************************************************
 365
 366 \begin{code}
 367 dmdFix :: TopLevelFlag
 368        -> SigEnv                -- Does not include bindings for this binding
 369        -> [(Id,CoreExpr)]
 370        -> (SigEnv, DmdEnv,
 371            [(Id,CoreExpr)])     -- Binders annotated with stricness info
 372
 373 dmdFix top_lvl sigs orig_pairs
 374   = loop 1 initial_sigs orig_pairs
 375   where
 376     bndrs        = map fst orig_pairs
 377     initial_sigs = extendSigEnvList sigs [(id, (initialSig id, top_lvl)) | id <- bndrs]
 378
 379     loop :: Int
 380          -> SigEnv                      -- Already contains the current sigs
 381          -> [(Id,CoreExpr)]
 382          -> (SigEnv, DmdEnv, [(Id,CoreExpr)])
 383     loop n sigs pairs
 384       | found_fixpoint
 385       = (sigs', lazy_fv, pairs')
 386                 -- Note: use pairs', not pairs.   pairs' is the result of
 387                 -- processing the RHSs with sigs (= sigs'), whereas pairs
 388                 -- is the result of processing the RHSs with the *previous*
 389                 -- iteration of sigs.
 390
 391       | n >= 10  = pprTrace "dmdFix loop" (ppr n <+> (vcat
 392                                 [ text "Sigs:" <+> ppr [(id,lookup sigs id, lookup sigs' id) | (id,_) <- pairs],
 393                                   text "env:" <+> ppr (ufmToList sigs),
 394                                   text "binds:" <+> pprCoreBinding (Rec pairs)]))
 395                               (emptySigEnv, lazy_fv, orig_pairs)        -- Safe output
 396                         -- The lazy_fv part is really important!  orig_pairs has no strictness
 397                         -- info, including nothing about free vars.  But if we have
 398                         --      letrec f = ....y..... in ...f...
 399                         -- where 'y' is free in f, we must record that y is mentioned,
 400                         -- otherwise y will get recorded as absent altogether
 401
 402       | otherwise    = loop (n+1) sigs' pairs'
 403       where
 404         found_fixpoint = all (same_sig sigs sigs') bndrs
 405                 -- Use the new signature to do the next pair
 406                 -- The occurrence analyser has arranged them in a good order
 407                 -- so this can significantly reduce the number of iterations needed
 408         ((sigs',lazy_fv), pairs') = mapAccumL (my_downRhs top_lvl) (sigs, emptyDmdEnv) pairs
 409
 410     my_downRhs top_lvl (sigs,lazy_fv) (id,rhs)
 411         = -- pprTrace "downRhs {" (ppr id <+> (ppr old_sig))
 412           -- (new_sig `seq`
 413           --    pprTrace "downRhsEnd" (ppr id <+> ppr new_sig <+> char '}' )
 414           ((sigs', lazy_fv'), pair')
 415           --     )
 416         where
 417           (sigs', lazy_fv1, pair') = dmdAnalRhs top_lvl Recursive sigs (id,rhs)
 418           lazy_fv'                 = plusUFM_C both lazy_fv lazy_fv1
 419           -- old_sig               = lookup sigs id
 420           -- new_sig               = lookup sigs' id
 421
 422     same_sig sigs sigs' var = lookup sigs var == lookup sigs' var
 423     lookup sigs var = case lookupVarEnv sigs var of
 424                         Just (sig,_) -> sig
 425
 426         -- Get an initial strictness signature from the Id
 427         -- itself.  That way we make use of earlier iterations
 428         -- of the fixpoint algorithm.  (Cunning plan.)
 429         -- Note that the cunning plan extends to the DmdEnv too,
 430         -- since it is part of the strictness signature
 431 initialSig id = idNewStrictness_maybe id `orElse` botSig
 432
 433 dmdAnalRhs :: TopLevelFlag -> RecFlag
 434         -> SigEnv -> (Id, CoreExpr)
 435         -> (SigEnv,  DmdEnv, (Id, CoreExpr))
 436 -- Process the RHS of the binding, add the strictness signature
 437 -- to the Id, and augment the environment with the signature as well.
 438
 439 dmdAnalRhs top_lvl rec_flag sigs (id, rhs)
 440  = (sigs', lazy_fv, (id', rhs'))
 441  where
 442   arity              = idArity id   -- The idArity should be up to date
 443                                     -- The simplifier was run just beforehand
 444   (rhs_dmd_ty, rhs') = dmdAnal sigs (vanillaCall arity) rhs
 445   (lazy_fv, sig_ty)  = WARN( arity /= dmdTypeDepth rhs_dmd_ty && not (exprIsTrivial rhs), ppr id )
 446                                 -- The RHS can be eta-reduced to just a variable,
 447                                 -- in which case we should not complain.
 448                        mkSigTy top_lvl rec_flag id rhs rhs_dmd_ty
 449   id'                = id `setIdNewStrictness` sig_ty
 450   sigs'              = extendSigEnv top_lvl sigs id sig_ty
 451 \end{code}
 452
 453 %************************************************************************
 454 %*                                                                      *
 455 \subsection{Strictness signatures and types}
 456 %*                                                                      *
 457 %************************************************************************
 458
 459 \begin{code}
 460 mkTopSigTy :: CoreExpr -> DmdType -> StrictSig
 461         -- Take a DmdType and turn it into a StrictSig
 462         -- NB: not used for never-inline things; hence False
 463 mkTopSigTy rhs dmd_ty = snd (mk_sig_ty False False rhs dmd_ty)
 464
 465 mkSigTy :: TopLevelFlag -> RecFlag -> Id -> CoreExpr -> DmdType -> (DmdEnv, StrictSig)
 466 mkSigTy top_lvl rec_flag id rhs dmd_ty
 467   = mk_sig_ty never_inline thunk_cpr_ok rhs dmd_ty
 468   where
 469     never_inline = isNeverActive (idInlinePragma id)
 470     maybe_id_dmd = idNewDemandInfo_maybe id
 471         -- Is Nothing the first time round
 472
 473     thunk_cpr_ok
 474         | isTopLevel top_lvl       = False      -- Top level things don't get
 475                                                 -- their demandInfo set at all
 476         | isRec rec_flag           = False      -- Ditto recursive things
 477         | Just dmd <- maybe_id_dmd = isStrictDmd dmd
 478         | otherwise                = True       -- Optimistic, first time round
 479                                                 -- See notes below
 480 \end{code}
 481
 482 The thunk_cpr_ok stuff [CPR-AND-STRICTNESS]
 483 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 484 If the rhs is a thunk, we usually forget the CPR info, because
 485 it is presumably shared (else it would have been inlined, and
 486 so we'd lose sharing if w/w'd it into a function).  E.g.
 487
 488         let r = case expensive of
 489                   (a,b) -> (b,a)
 490         in ...
 491
 492 If we marked r as having the CPR property, then we'd w/w into
 493
 494         let $wr = \() -> case expensive of
 495                             (a,b) -> (# b, a #)
 496             r = case $wr () of
 497                   (# b,a #) -> (b,a)
 498         in ...
 499
 500 But now r is a thunk, which won't be inlined, so we are no further ahead.
 501 But consider
 502
 503         f x = let r = case expensive of (a,b) -> (b,a)
 504               in if foo r then r else (x,x)
 505
 506 Does f have the CPR property?  Well, no.
 507
 508 However, if the strictness analyser has figured out (in a previous
 509 iteration) that it's strict, then we DON'T need to forget the CPR info.
 510 Instead we can retain the CPR info and do the thunk-splitting transform
 511 (see WorkWrap.splitThunk).
 512
 513 This made a big difference to PrelBase.modInt, which had something like
 514         modInt = \ x -> let r = ... -> I# v in
 515                         ...body strict in r...
 516 r's RHS isn't a value yet; but modInt returns r in various branches, so
 517 if r doesn't have the CPR property then neither does modInt
 518 Another case I found in practice (in Complex.magnitude), looks like this:
 519                 let k = if ... then I# a else I# b
 520                 in ... body strict in k ....
 521 (For this example, it doesn't matter whether k is returned as part of
 522 the overall result; but it does matter that k's RHS has the CPR property.)
 523 Left to itself, the simplifier will make a join point thus:
 524                 let $j k = ...body strict in k...
 525                 if ... then $j (I# a) else $j (I# b)
 526 With thunk-splitting, we get instead
 527                 let $j x = let k = I#x in ...body strict in k...
 528                 in if ... then $j a else $j b
 529 This is much better; there's a good chance the I# won't get allocated.
 530
 531 The difficulty with this is that we need the strictness type to
 532 look at the body... but we now need the body to calculate the demand
 533 on the variable, so we can decide whether its strictness type should
 534 have a CPR in it or not.  Simple solution:
 535         a) use strictness info from the previous iteration
 536         b) make sure we do at least 2 iterations, by doing a second
 537            round for top-level non-recs.  Top level recs will get at
 538            least 2 iterations except for totally-bottom functions
 539            which aren't very interesting anyway.
 540
 541 NB: strictly_demanded is never true of a top-level Id, or of a recursive Id.
 542
 543 The Nothing case in thunk_cpr_ok [CPR-AND-STRICTNESS]
 544 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 545 Demand info now has a 'Nothing' state, just like strictness info.
 546 The analysis works from 'dangerous' towards a 'safe' state; so we
 547 start with botSig for 'Nothing' strictness infos, and we start with
 548 "yes, it's demanded" for 'Nothing' in the demand info.  The
 549 fixpoint iteration will sort it all out.
 550
 551 We can't start with 'not-demanded' because then consider
 552         f x = let
 553                   t = ... I# x
 554               in
 555               if ... then t else I# y else f x'
 556
 557 In the first iteration we'd have no demand info for x, so assume
 558 not-demanded; then we'd get TopRes for f's CPR info.  Next iteration
 559 we'd see that t was demanded, and so give it the CPR property, but by
 560 now f has TopRes, so it will stay TopRes.  Instead, with the Nothing
 561 setting the first time round, we say 'yes t is demanded' the first
 562 time.
 563
 564 However, this does mean that for non-recursive bindings we must
 565 iterate twice to be sure of not getting over-optimistic CPR info,
 566 in the case where t turns out to be not-demanded.  This is handled
 567 by dmdAnalTopBind.
 568
 569
 570 \begin{code}
 571 mk_sig_ty never_inline thunk_cpr_ok rhs (DmdType fv dmds res)
 572   = (lazy_fv, mkStrictSig dmd_ty)
 573   where
 574     dmd_ty = DmdType strict_fv final_dmds res'
 575
 576     lazy_fv   = filterUFM (not . isStrictDmd) fv
 577     strict_fv = filterUFM isStrictDmd         fv
 578         -- We put the strict FVs in the DmdType of the Id, so
 579         -- that at its call sites we unleash demands on its strict fvs.
 580         -- An example is 'roll' in imaginary/wheel-sieve2
 581         -- Something like this:
 582         --      roll x = letrec
 583         --                   go y = if ... then roll (x-1) else x+1
 584         --               in
 585         --               go ms
 586         -- We want to see that roll is strict in x, which is because
 587         -- go is called.   So we put the DmdEnv for x in go's DmdType.
 588         --
 589         -- Another example:
 590         --      f :: Int -> Int -> Int
 591         --      f x y = let t = x+1
 592         --          h z = if z==0 then t else
 593         --                if z==1 then x+1 else
 594         --                x + h (z-1)
 595         --      in
 596         --      h y
 597         -- Calling h does indeed evaluate x, but we can only see
 598         -- that if we unleash a demand on x at the call site for t.
 599         --
 600         -- Incidentally, here's a place where lambda-lifting h would
 601         -- lose the cigar --- we couldn't see the joint strictness in t/x
 602         --
 603         --      ON THE OTHER HAND
 604         -- We don't want to put *all* the fv's from the RHS into the
 605         -- DmdType, because that makes fixpointing very slow --- the
 606         -- DmdType gets full of lazy demands that are slow to converge.
 607
 608     final_dmds = setUnpackStrategy dmds
 609         -- Set the unpacking strategy
 610
 611     res' = case res of
 612                 RetCPR | ignore_cpr_info -> TopRes
 613                 other                    -> res
 614     ignore_cpr_info = not (exprIsHNF rhs || thunk_cpr_ok)
 615 \end{code}
 616
 617 The unpack strategy determines whether we'll *really* unpack the argument,
 618 or whether we'll just remember its strictness.  If unpacking would give
 619 rise to a *lot* of worker args, we may decide not to unpack after all.
 620
 621 \begin{code}
 622 setUnpackStrategy :: [Demand] -> [Demand]
 623 setUnpackStrategy ds
 624   = snd (go (opt_MaxWorkerArgs - nonAbsentArgs ds) ds)
 625   where
 626     go :: Int                   -- Max number of args available for sub-components of [Demand]
 627        -> [Demand]
 628        -> (Int, [Demand])       -- Args remaining after subcomponents of [Demand] are unpacked
 629
 630     go n (Eval (Prod cs) : ds)
 631         | n' >= 0   = Eval (Prod cs') `cons` go n'' ds
 632         | otherwise = Box (Eval (Prod cs)) `cons` go n ds
 633         where
 634           (n'',cs') = go n' cs
 635           n' = n + 1 - non_abs_args
 636                 -- Add one to the budget 'cos we drop the top-level arg
 637           non_abs_args = nonAbsentArgs cs
 638                 -- Delete # of non-absent args to which we'll now be committed
 639
 640     go n (d:ds) = d `cons` go n ds
 641     go n []     = (n,[])
 642
 643     cons d (n,ds) = (n, d:ds)
 644
 645 nonAbsentArgs :: [Demand] -> Int
 646 nonAbsentArgs []         = 0
 647 nonAbsentArgs (Abs : ds) = nonAbsentArgs ds
 648 nonAbsentArgs (d   : ds) = 1 + nonAbsentArgs ds
 649 \end{code}
 650
 651
 652 %************************************************************************
 653 %*                                                                      *
 654 \subsection{Strictness signatures and types}
 655 %*                                                                      *
 656 %************************************************************************
 657
 658 \begin{code}
 659 unitVarDmd var dmd = DmdType (unitVarEnv var dmd) [] TopRes
 660
 661 addVarDmd top_lvl dmd_ty@(DmdType fv ds res) var dmd
 662   | isTopLevel top_lvl = dmd_ty         -- Don't record top level things
 663   | otherwise          = DmdType (extendVarEnv fv var dmd) ds res
 664
 665 addLazyFVs (DmdType fv ds res) lazy_fvs
 666   = DmdType both_fv1 ds res
 667   where
 668     both_fv = (plusUFM_C both fv lazy_fvs)
 669     both_fv1 = modifyEnv (isBotRes res) (`both` Bot) lazy_fvs fv both_fv
 670         -- This modifyEnv is vital.  Consider
 671         --      let f = \x -> (x,y)
 672         --      in  error (f 3)
 673         -- Here, y is treated as a lazy-fv of f, but we must `both` that L
 674         -- demand with the bottom coming up from 'error'
 675         --
 676         -- I got a loop in the fixpointer without this, due to an interaction
 677         -- with the lazy_fv filtering in mkSigTy.  Roughly, it was
 678         --      letrec f n x
 679         --          = letrec g y = x `fatbar`
 680         --                         letrec h z = z + ...g...
 681         --                         in h (f (n-1) x)
 682         --      in ...
 683         -- In the initial iteration for f, f=Bot
 684         -- Suppose h is found to be strict in z, but the occurrence of g in its RHS
 685         -- is lazy.  Now consider the fixpoint iteration for g, esp the demands it
 686         -- places on its free variables.  Suppose it places none.  Then the
 687         --      x `fatbar` ...call to h...
 688         -- will give a x->V demand for x.  That turns into a L demand for x,
 689         -- which floats out of the defn for h.  Without the modifyEnv, that
 690         -- L demand doesn't get both'd with the Bot coming up from the inner
 691         -- call to f.  So we just get an L demand for x for g.
 692         --
 693         -- A better way to say this is that the lazy-fv filtering should give the
 694         -- same answer as putting the lazy fv demands in the function's type.
 695
 696 annotateBndr :: DmdType -> Var -> (DmdType, Var)
 697 -- The returned env has the var deleted
 698 -- The returned var is annotated with demand info
 699 -- No effect on the argument demands
 700 annotateBndr dmd_ty@(DmdType fv ds res) var
 701   | isTyVar var = (dmd_ty, var)
 702   | otherwise   = (DmdType fv' ds res, setIdNewDemandInfo var dmd)
 703   where
 704     (fv', dmd) = removeFV fv var res
 705
 706 annotateBndrs = mapAccumR annotateBndr
 707
 708 annotateLamIdBndr dmd_ty@(DmdType fv ds res) id
 709 -- For lambdas we add the demand to the argument demands
 710 -- Only called for Ids
 711   = ASSERT( isId id )
 712     (DmdType fv' (hacked_dmd:ds) res, setIdNewDemandInfo id hacked_dmd)
 713   where
 714     (fv', dmd) = removeFV fv id res
 715     hacked_dmd = argDemand dmd
 716         -- This call to argDemand is vital, because otherwise we label
 717         -- a lambda binder with demand 'B'.  But in terms of calling
 718         -- conventions that's Abs, because we don't pass it.  But
 719         -- when we do a w/w split we get
 720         --      fw x = (\x y:B -> ...) x (error "oops")
 721         -- And then the simplifier things the 'B' is a strict demand
 722         -- and evaluates the (error "oops").  Sigh
 723
 724 removeFV fv id res = (fv', zapUnlifted id dmd)
 725                 where
 726                   fv' = fv `delVarEnv` id
 727                   dmd = lookupVarEnv fv id `orElse` deflt
 728                   deflt | isBotRes res = Bot
 729                         | otherwise    = Abs
 730
 731 -- For unlifted-type variables, we are only
 732 -- interested in Bot/Abs/Box Abs
 733 zapUnlifted is Bot = Bot
 734 zapUnlifted id Abs = Abs
 735 zapUnlifted id dmd | isUnLiftedType (idType id) = lazyDmd
 736                    | otherwise                  = dmd
 737 \end{code}
 738
 739 %************************************************************************
 740 %*                                                                      *
 741 \subsection{Strictness signatures}
 742 %*                                                                      *
 743 %************************************************************************
 744
 745 \begin{code}
 746 type SigEnv  = VarEnv (StrictSig, TopLevelFlag)
 747         -- We use the SigEnv to tell us whether to
 748         -- record info about a variable in the DmdEnv
 749         -- We do so if it's a LocalId, but not top-level
 750         --
 751         -- The DmdEnv gives the demand on the free vars of the function
 752         -- when it is given enough args to satisfy the strictness signature
 753
 754 emptySigEnv  = emptyVarEnv
 755
 756 extendSigEnv :: TopLevelFlag -> SigEnv -> Id -> StrictSig -> SigEnv
 757 extendSigEnv top_lvl env var sig = extendVarEnv env var (sig, top_lvl)
 758
 759 extendSigEnvList = extendVarEnvList
 760
 761 extendSigsWithLam :: SigEnv -> Id -> SigEnv
 762 -- Extend the SigEnv when we meet a lambda binder
 763 -- If the binder is marked demanded with a product demand, then give it a CPR
 764 -- signature, because in the likely event that this is a lambda on a fn defn
 765 -- [we only use this when the lambda is being consumed with a call demand],
 766 -- it'll be w/w'd and so it will be CPR-ish.  E.g.
 767 --      f = \x::(Int,Int).  if ...strict in x... then
 768 --                              x
 769 --                          else
 770 --                              (a,b)
 771 -- We want f to have the CPR property because x does, by the time f has been w/w'd
 772 --
 773 -- Also note that we only want to do this for something that
 774 -- definitely has product type, else we may get over-optimistic
 775 -- CPR results (e.g. from \x -> x!).
 776
 777 extendSigsWithLam sigs id
 778   = case idNewDemandInfo_maybe id of
 779         Nothing               -> extendVarEnv sigs id (cprSig, NotTopLevel)
 780                 -- Optimistic in the Nothing case;
 781                 -- See notes [CPR-AND-STRICTNESS]
 782         Just (Eval (Prod ds)) -> extendVarEnv sigs id (cprSig, NotTopLevel)
 783         other                 -> sigs
 784
 785
 786 dmdTransform :: SigEnv          -- The strictness environment
 787              -> Id              -- The function
 788              -> Demand          -- The demand on the function
 789              -> DmdType         -- The demand type of the function in this context
 790         -- Returned DmdEnv includes the demand on
 791         -- this function plus demand on its free variables
 792
 793 dmdTransform sigs var dmd
 794
 795 ------  DATA CONSTRUCTOR
 796   | isDataConWorkId var         -- Data constructor
 797   = let
 798         StrictSig dmd_ty    = idNewStrictness var       -- It must have a strictness sig
 799         DmdType _ _ con_res = dmd_ty
 800         arity               = idArity var
 801     in
 802     if arity == call_depth then         -- Saturated, so unleash the demand
 803         let
 804                 -- Important!  If we Keep the constructor application, then
 805                 -- we need the demands the constructor places (always lazy)
 806                 -- If not, we don't need to.  For example:
 807                 --      f p@(x,y) = (p,y)       -- S(AL)
 808                 --      g a b     = f (a,b)
 809                 -- It's vital that we don't calculate Absent for a!
 810            dmd_ds = case res_dmd of
 811                         Box (Eval ds) -> mapDmds box ds
 812                         Eval ds       -> ds
 813                         other         -> Poly Top
 814
 815                 -- ds can be empty, when we are just seq'ing the thing
 816                 -- If so we must make up a suitable bunch of demands
 817            arg_ds = case dmd_ds of
 818                       Poly d  -> replicate arity d
 819                       Prod ds -> ASSERT( ds `lengthIs` arity ) ds
 820
 821         in
 822         mkDmdType emptyDmdEnv arg_ds con_res
 823                 -- Must remember whether it's a product, hence con_res, not TopRes
 824     else
 825         topDmdType
 826
 827 ------  IMPORTED FUNCTION
 828   | isGlobalId var,             -- Imported function
 829     let StrictSig dmd_ty = idNewStrictness var
 830   = if dmdTypeDepth dmd_ty <= call_depth then   -- Saturated, so unleash the demand
 831         dmd_ty
 832     else
 833         topDmdType
 834
 835 ------  LOCAL LET/REC BOUND THING
 836   | Just (StrictSig dmd_ty, top_lvl) <- lookupVarEnv sigs var
 837   = let
 838         fn_ty | dmdTypeDepth dmd_ty <= call_depth = dmd_ty
 839               | otherwise                         = deferType dmd_ty
 840         -- NB: it's important to use deferType, and not just return topDmdType
 841         -- Consider     let { f x y = p + x } in f 1
 842         -- The application isn't saturated, but we must nevertheless propagate
 843         --      a lazy demand for p!
 844     in
 845     addVarDmd top_lvl fn_ty var dmd
 846
 847 ------  LOCAL NON-LET/REC BOUND THING
 848   | otherwise                   -- Default case
 849   = unitVarDmd var dmd
 850
 851   where
 852     (call_depth, res_dmd) = splitCallDmd dmd
 853 \end{code}
 854
 855
 856 %************************************************************************
 857 %*                                                                      *
 858 \subsection{Demands}
 859 %*                                                                      *
 860 %************************************************************************
 861
 862 \begin{code}
 863 splitDmdTy :: DmdType -> (Demand, DmdType)
 864 -- Split off one function argument
 865 -- We already have a suitable demand on all
 866 -- free vars, so no need to add more!
 867 splitDmdTy (DmdType fv (dmd:dmds) res_ty) = (dmd, DmdType fv dmds res_ty)
 868 splitDmdTy ty@(DmdType fv [] res_ty)      = (resTypeArgDmd res_ty, ty)
 869
 870 splitCallDmd :: Demand -> (Int, Demand)
 871 splitCallDmd (Call d) = case splitCallDmd d of
 872                           (n, r) -> (n+1, r)
 873 splitCallDmd d        = (0, d)
 874
 875 vanillaCall :: Arity -> Demand
 876 vanillaCall 0 = evalDmd
 877 vanillaCall n = Call (vanillaCall (n-1))
 878
 879 deferType :: DmdType -> DmdType
 880 deferType (DmdType fv _ _) = DmdType (deferEnv fv) [] TopRes
 881         -- Notice that we throw away info about both arguments and results
 882         -- For example,   f = let ... in \x -> x
 883         -- We don't want to get a stricness type V->T for f.
 884
 885 deferEnv :: DmdEnv -> DmdEnv
 886 deferEnv fv = mapVarEnv defer fv
 887
 888
 889 ----------------
 890 argDemand :: Demand -> Demand
 891 -- The 'Defer' demands are just Lazy at function boundaries
 892 -- Ugly!  Ask John how to improve it.
 893 argDemand Top       = lazyDmd
 894 argDemand (Defer d) = lazyDmd
 895 argDemand (Eval ds) = Eval (mapDmds argDemand ds)
 896 argDemand (Box Bot) = evalDmd
 897 argDemand (Box d)   = box (argDemand d)
 898 argDemand Bot       = Abs       -- Don't pass args that are consumed (only) by bottom
 899 argDemand d         = d
 900 \end{code}
 901
 902 \begin{code}
 903 -------------------------
 904 -- Consider (if x then y else []) with demand V
 905 -- Then the first branch gives {y->V} and the second
 906 --  *implicitly* has {y->A}.  So we must put {y->(V `lub` A)}
 907 -- in the result env.
 908 lubType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 909   = DmdType lub_fv2 (lub_ds ds1 ds2) (r1 `lubRes` r2)
 910   where
 911     lub_fv  = plusUFM_C lub fv1 fv2
 912     lub_fv1 = modifyEnv (not (isBotRes r1)) absLub fv2 fv1 lub_fv
 913     lub_fv2 = modifyEnv (not (isBotRes r2)) absLub fv1 fv2 lub_fv1
 914         -- lub is the identity for Bot
 915
 916         -- Extend the shorter argument list to match the longer
 917     lub_ds (d1:ds1) (d2:ds2) = lub d1 d2 : lub_ds ds1 ds2
 918     lub_ds []       []       = []
 919     lub_ds ds1      []       = map (`lub` resTypeArgDmd r2) ds1
 920     lub_ds []       ds2      = map (resTypeArgDmd r1 `lub`) ds2
 921
 922 -----------------------------------
 923 -- (t1 `bothType` t2) takes the argument/result info from t1,
 924 -- using t2 just for its free-var info
 925 -- NB: Don't forget about r2!  It might be BotRes, which is
 926 --     a bottom demand on all the in-scope variables.
 927 -- Peter: can this be done more neatly?
 928 bothType (DmdType fv1 ds1 r1) (DmdType fv2 ds2 r2)
 929   = DmdType both_fv2 ds1 (r1 `bothRes` r2)
 930   where
 931     both_fv  = plusUFM_C both fv1 fv2
 932     both_fv1 = modifyEnv (isBotRes r1) (`both` Bot) fv2 fv1 both_fv
 933     both_fv2 = modifyEnv (isBotRes r2) (`both` Bot) fv1 fv2 both_fv1
 934         -- both is the identity for Abs
 935 \end{code}
 936
 937
 938 \begin{code}
 939 lubRes BotRes r      = r
 940 lubRes r      BotRes = r
 941 lubRes RetCPR RetCPR = RetCPR
 942 lubRes r1     r2     = TopRes
 943
 944 -- If either diverges, the whole thing does
 945 -- Otherwise take CPR info from the first
 946 bothRes r1 BotRes = BotRes
 947 bothRes r1 r2     = r1
 948 \end{code}
 949
 950 \begin{code}
 951 modifyEnv :: Bool                       -- No-op if False
 952           -> (Demand -> Demand)         -- The zapper
 953           -> DmdEnv -> DmdEnv           -- Env1 and Env2
 954           -> DmdEnv -> DmdEnv           -- Transform this env
 955         -- Zap anything in Env1 but not in Env2
 956         -- Assume: dom(env) includes dom(Env1) and dom(Env2)
 957
 958 modifyEnv need_to_modify zapper env1 env2 env
 959   | need_to_modify = foldr zap env (keysUFM (env1 `minusUFM` env2))
 960   | otherwise      = env
 961   where
 962     zap uniq env = addToUFM_Directly env uniq (zapper current_val)
 963                  where
 964                    current_val = expectJust "modifyEnv" (lookupUFM_Directly env uniq)
 965 \end{code}
 966
 967
 968 %************************************************************************
 969 %*                                                                      *
 970 \subsection{LUB and BOTH}
 971 %*                                                                      *
 972 %************************************************************************
 973
 974 \begin{code}
 975 lub :: Demand -> Demand -> Demand
 976
 977 lub Bot         d2 = d2
 978 lub Abs         d2 = absLub d2
 979 lub Top         d2 = Top
 980 lub (Defer ds1) d2 = defer (Eval ds1 `lub` d2)
 981
 982 lub (Call d1)   (Call d2)    = Call (d1 `lub` d2)
 983 lub d1@(Call _) (Box d2)     = d1 `lub` d2      -- Just strip the box
 984 lub d1@(Call _) d2@(Eval _)  = d2               -- Presumably seq or vanilla eval
 985 lub d1@(Call _) d2           = d2 `lub` d1      -- Bot, Abs, Top
 986
 987 -- For the Eval case, we use these approximation rules
 988 -- Box Bot       <= Eval (Box Bot ...)
 989 -- Box Top       <= Defer (Box Bot ...)
 990 -- Box (Eval ds) <= Eval (map Box ds)
 991 lub (Eval ds1)  (Eval ds2)        = Eval (ds1 `lubs` ds2)
 992 lub (Eval ds1)  (Box Bot)         = Eval (mapDmds (`lub` Box Bot) ds1)
 993 lub (Eval ds1)  (Box (Eval ds2)) = Eval (ds1 `lubs` mapDmds box ds2)
 994 lub (Eval ds1)  (Box Abs)        = deferEval (mapDmds (`lub` Box Bot) ds1)
 995 lub d1@(Eval _) d2                = d2 `lub` d1 -- Bot,Abs,Top,Call,Defer
 996
 997 lub (Box d1)   (Box d2) = box (d1 `lub` d2)
 998 lub d1@(Box _)  d2      = d2 `lub` d1
 999
1000 lubs ds1 ds2 = zipWithDmds lub ds1 ds2
1001
1002 ---------------------
1003 -- box is the smart constructor for Box
1004 -- It computes <B,bot> & d
1005 -- INVARIANT: (Box d) => d = Bot, Abs, Eval
1006 -- Seems to be no point in allowing (Box (Call d))
1007 box (Call d)  = Call d  -- The odd man out.  Why?
1008 box (Box d)   = Box d
1009 box (Defer _) = lazyDmd
1010 box Top       = lazyDmd -- Box Abs and Box Top
1011 box Abs       = lazyDmd -- are the same <B,L>
1012 box d         = Box d   -- Bot, Eval
1013
1014 ---------------
1015 defer :: Demand -> Demand
1016
1017 -- defer is the smart constructor for Defer
1018 -- The idea is that (Defer ds) = <U(ds), L>
1019 --
1020 -- It specifies what happens at a lazy function argument
1021 -- or a lambda; the L* operator
1022 -- Set the strictness part to L, but leave
1023 -- the boxity side unaffected
1024 -- It also ensures that Defer (Eval [LLLL]) = L
1025
1026 defer Bot        = Abs
1027 defer Abs        = Abs
1028 defer Top        = Top
1029 defer (Call _)   = lazyDmd      -- Approximation here?
1030 defer (Box _)    = lazyDmd
1031 defer (Defer ds) = Defer ds
1032 defer (Eval ds)  = deferEval ds
1033
1034 -- deferEval ds = defer (Eval ds)
1035 deferEval ds | allTop ds = Top
1036              | otherwise  = Defer ds
1037
1038 ---------------------
1039 absLub :: Demand -> Demand
1040 -- Computes (Abs `lub` d)
1041 -- For the Bot case consider
1042 --      f x y = if ... then x else error x
1043 --   Then for y we get Abs `lub` Bot, and we really
1044 --   want Abs overall
1045 absLub Bot        = Abs
1046 absLub Abs        = Abs
1047 absLub Top        = Top
1048 absLub (Call _)   = Top
1049 absLub (Box _)    = Top
1050 absLub (Eval ds)  = Defer (absLubs ds)  -- Or (Defer ds)?
1051 absLub (Defer ds) = Defer (absLubs ds)  -- Or (Defer ds)?
1052
1053 absLubs = mapDmds absLub
1054
1055 ---------------
1056 both :: Demand -> Demand -> Demand
1057
1058 both Abs d2 = d2
1059
1060 both Bot Bot       = Bot
1061 both Bot Abs       = Bot
1062 both Bot (Eval ds) = Eval (mapDmds (`both` Bot) ds)
1063         -- Consider
1064         --      f x = error x
1065         -- From 'error' itself we get demand Bot on x
1066         -- From the arg demand on x we get
1067         --      x :-> evalDmd = Box (Eval (Poly Abs))
1068         -- So we get  Bot `both` Box (Eval (Poly Abs))
1069         --          = Seq Keep (Poly Bot)
1070         --
1071         -- Consider also
1072         --      f x = if ... then error (fst x) else fst x
1073         -- Then we get (Eval (Box Bot, Bot) `lub` Eval (SA))
1074         --      = Eval (SA)
1075         -- which is what we want.
1076 both Bot d = errDmd
1077
1078 both Top Bot         = errDmd
1079 both Top Abs         = Top
1080 both Top Top         = Top
1081 both Top (Box d)    = Box d
1082 both Top (Call d)   = Call d
1083 both Top (Eval ds)  = Eval (mapDmds (`both` Top) ds)
1084 both Top (Defer ds)     -- = defer (Top `both` Eval ds)
1085                         -- = defer (Eval (mapDmds (`both` Top) ds))
1086                      = deferEval (mapDmds (`both` Top) ds)
1087
1088
1089 both (Box d1)   (Box d2)    = box (d1 `both` d2)
1090 both (Box d1)   d2@(Call _) = box (d1 `both` d2)
1091 both (Box d1)   d2@(Eval _) = box (d1 `both` d2)
1092 both (Box d1)   (Defer d2)  = Box d1
1093 both d1@(Box _) d2          = d2 `both` d1
1094
1095 both (Call d1)   (Call d2)   = Call (d1 `both` d2)
1096 both (Call d1)   (Eval ds2)  = Call d1  -- Could do better for (Poly Bot)?
1097 both (Call d1)   (Defer ds2) = Call d1  -- Ditto
1098 both d1@(Call _) d2          = d1 `both` d1
1099
1100 both (Eval ds1)    (Eval  ds2) = Eval (ds1 `boths` ds2)
1101 both (Eval ds1)    (Defer ds2) = Eval (ds1 `boths` mapDmds defer ds2)
1102 both d1@(Eval ds1) d2          = d2 `both` d1
1103
1104 both (Defer ds1) (Defer ds2) = deferEval (ds1 `boths` ds2)
1105 both d1@(Defer ds1) d2       = d2 `both` d1
1106
1107 boths ds1 ds2 = zipWithDmds both ds1 ds2
1108 \end{code}
1109
1110
1111
1112 %************************************************************************
1113 %*                                                                      *
1114 \subsection{Miscellaneous
1115 %*                                                                      *
1116 %************************************************************************
1117
1118
1119 \begin{code}
1120 #ifdef OLD_STRICTNESS
1121 get_changes binds = vcat (map get_changes_bind binds)
1122
1123 get_changes_bind (Rec pairs) = vcat (map get_changes_pr pairs)
1124 get_changes_bind (NonRec id rhs) = get_changes_pr (id,rhs)
1125
1126 get_changes_pr (id,rhs)
1127   = get_changes_var id $$ get_changes_expr rhs
1128
1129 get_changes_var var
1130   | isId var  = get_changes_str var $$ get_changes_dmd var
1131   | otherwise = empty
1132
1133 get_changes_expr (Type t)     = empty
1134 get_changes_expr (Var v)      = empty
1135 get_changes_expr (Lit l)      = empty
1136 get_changes_expr (Note n e)   = get_changes_expr e
1137 get_changes_expr (App e1 e2)  = get_changes_expr e1 $$ get_changes_expr e2
1138 get_changes_expr (Lam b e)    = {- get_changes_var b $$ -} get_changes_expr e
1139 get_changes_expr (Let b e)    = get_changes_bind b $$ get_changes_expr e
1140 get_changes_expr (Case e b a) = get_changes_expr e $$ {- get_changes_var b $$ -} vcat (map get_changes_alt a)
1141
1142 get_changes_alt (con,bs,rhs) = {- vcat (map get_changes_var bs) $$ -} get_changes_expr rhs
1143
1144 get_changes_str id
1145   | new_better && old_better = empty
1146   | new_better               = message "BETTER"
1147   | old_better               = message "WORSE"
1148   | otherwise                = message "INCOMPARABLE"
1149   where
1150     message word = text word <+> text "strictness for" <+> ppr id <+> info
1151     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1152     new = squashSig (idNewStrictness id)        -- Don't report spurious diffs that the old
1153                                                 -- strictness analyser can't track
1154     old = newStrictnessFromOld (idName id) (idArity id) (idStrictness id) (idCprInfo id)
1155     old_better = old `betterStrictness` new
1156     new_better = new `betterStrictness` old
1157
1158 get_changes_dmd id
1159   | isUnLiftedType (idType id) = empty  -- Not useful
1160   | new_better && old_better = empty
1161   | new_better               = message "BETTER"
1162   | old_better               = message "WORSE"
1163   | otherwise                = message "INCOMPARABLE"
1164   where
1165     message word = text word <+> text "demand for" <+> ppr id <+> info
1166     info = (text "Old" <+> ppr old) $$ (text "New" <+> ppr new)
1167     new = squashDmd (argDemand (idNewDemandInfo id))    -- To avoid spurious improvements
1168                                                         -- A bit of a hack
1169     old = newDemand (idDemandInfo id)
1170     new_better = new `betterDemand` old
1171     old_better = old `betterDemand` new
1172
1173 betterStrictness :: StrictSig -> StrictSig -> Bool
1174 betterStrictness (StrictSig t1) (StrictSig t2) = betterDmdType t1 t2
1175
1176 betterDmdType t1 t2 = (t1 `lubType` t2) == t2
1177
1178 betterDemand :: Demand -> Demand -> Bool
1179 -- If d1 `better` d2, and d2 `better` d2, then d1==d2
1180 betterDemand d1 d2 = (d1 `lub` d2) == d2
1181
1182 squashSig (StrictSig (DmdType fv ds res))
1183   = StrictSig (DmdType emptyDmdEnv (map squashDmd ds) res)
1184   where
1185         -- squash just gets rid of call demands
1186         -- which the old analyser doesn't track
1187 squashDmd (Call d)   = evalDmd
1188 squashDmd (Box d)    = Box (squashDmd d)
1189 squashDmd (Eval ds)  = Eval (mapDmds squashDmd ds)
1190 squashDmd (Defer ds) = Defer (mapDmds squashDmd ds)
1191 squashDmd d          = d
1192 #endif
1193 \end{code}