compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module WorkWrap ( wwTopBinds, mkWrapper ) where
  15
  16 #include "HsVersions.h"
  17
  18 import CoreSyn
  19 import CoreUnfold       ( certainlyWillInline )
  20 import CoreLint         ( showPass, endPass )
  21 import CoreUtils        ( exprType, exprIsHNF, exprArity )
  22 import Id               ( Id, idType, isOneShotLambda,
  23                           setIdNewStrictness, mkWorkerId,
  24                           setIdWorkerInfo, setInlinePragma,
  25                           setIdArity, idInfo )
  26 import MkId             ( lazyIdKey, lazyIdUnfolding )
  27 import Type             ( Type )
  28 import IdInfo           ( WorkerInfo(..), arityInfo,
  29                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  30                         )
  31 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  32                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  33                         )
  34 import UniqSupply
  35 import Unique           ( hasKey )
  36 import BasicTypes       ( RecFlag(..), isNonRec, isNeverActive )
  37 import VarEnv           ( isEmptyVarEnv )
  38 import Maybes           ( orElse )
  39 import DynFlags
  40 import WwLib
  41 import Util             ( lengthIs, notNull )
  42 import Outputable
  43 import MonadUtils
  44 \end{code}
  45
  46 We take Core bindings whose binders have:
  47
  48 \begin{enumerate}
  49
  50 \item Strictness attached (by the front-end of the strictness
  51 analyser), and / or
  52
  53 \item Constructed Product Result information attached by the CPR
  54 analysis pass.
  55
  56 \end{enumerate}
  57
  58 and we return some ``plain'' bindings which have been
  59 worker/wrapper-ified, meaning:
  60
  61 \begin{enumerate}
  62
  63 \item Functions have been split into workers and wrappers where
  64 appropriate.  If a function has both strictness and CPR properties
  65 then only one worker/wrapper doing both transformations is produced;
  66
  67 \item Binders' @IdInfos@ have been updated to reflect the existence of
  68 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  69 info for exported values).
  70 \end{enumerate}
  71
  72 \begin{code}
  73
  74 wwTopBinds :: DynFlags
  75            -> UniqSupply
  76            -> [CoreBind]
  77            -> IO [CoreBind]
  78
  79 wwTopBinds dflags us binds
  80   = do {
  81         showPass dflags "Worker Wrapper binds";
  82
  83         -- Create worker/wrappers, and mark binders with their
  84         -- "strictness info" [which encodes their worker/wrapper-ness]
  85         let { binds' = workersAndWrappers us binds };
  86
  87         endPass dflags "Worker Wrapper binds"
  88                 Opt_D_dump_worker_wrapper binds'
  89     }
  90 \end{code}
  91
  92
  93 \begin{code}
  94 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  95
  96 workersAndWrappers us top_binds
  97   = initUs_ us $ do
  98     top_binds' <- mapM wwBind top_binds
  99     return (concat top_binds')
 100 \end{code}
 101
 102 %************************************************************************
 103 %*                                                                      *
 104 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
 105 %*                                                                      *
 106 %************************************************************************
 107
 108 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 109 turn.  Non-recursive case first, then recursive...
 110
 111 \begin{code}
 112 wwBind  :: CoreBind
 113         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 114                                 -- the caller will convert to Expr/Binding,
 115                                 -- as appropriate.
 116
 117 wwBind (NonRec binder rhs) = do
 118     new_rhs <- wwExpr rhs
 119     new_pairs <- tryWW NonRecursive binder new_rhs
 120     return [NonRec b e | (b,e) <- new_pairs]
 121       -- Generated bindings must be non-recursive
 122       -- because the original binding was.
 123
 124 wwBind (Rec pairs)
 125   = return . Rec <$> concatMapM do_one pairs
 126   where
 127     do_one (binder, rhs) = do new_rhs <- wwExpr rhs
 128                               tryWW Recursive binder new_rhs
 129 \end{code}
 130
 131 @wwExpr@ basically just walks the tree, looking for appropriate
 132 annotations that can be used. Remember it is @wwBind@ that does the
 133 matching by looking for strict arguments of the correct type.
 134 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 135
 136 \begin{code}
 137 wwExpr :: CoreExpr -> UniqSM CoreExpr
 138
 139 wwExpr e@(Type _)             = return e
 140 wwExpr e@(Lit _)              = return e
 141 wwExpr e@(Note InlineMe expr) = return e
 142         -- Don't w/w inside InlineMe's
 143
 144 wwExpr e@(Var v)
 145   | v `hasKey` lazyIdKey = return lazyIdUnfolding
 146   | otherwise            = return e
 147         -- HACK alert: Inline 'lazy' after strictness analysis
 148         -- (but not inside InlineMe's)
 149
 150 wwExpr (Lam binder expr)
 151   = Lam binder <$> wwExpr expr
 152
 153 wwExpr (App f a)
 154   = App <$> wwExpr f <*> wwExpr a
 155
 156 wwExpr (Note note expr)
 157   = Note note <$> wwExpr expr
 158
 159 wwExpr (Cast expr co) = do
 160     new_expr <- wwExpr expr
 161     return (Cast new_expr co)
 162
 163 wwExpr (Let bind expr)
 164   = mkLets <$> wwBind bind <*> wwExpr expr
 165
 166 wwExpr (Case expr binder ty alts) = do
 167     new_expr <- wwExpr expr
 168     new_alts <- mapM ww_alt alts
 169     return (Case new_expr binder ty new_alts)
 170   where
 171     ww_alt (con, binders, rhs) = do
 172         new_rhs <- wwExpr rhs
 173         return (con, binders, new_rhs)
 174 \end{code}
 175
 176 %************************************************************************
 177 %*                                                                      *
 178 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 179 %*                                                                      *
 180 %************************************************************************
 181
 182 @tryWW@ just accumulates arguments, converts strictness info from the
 183 front-end into the proper form, then calls @mkWwBodies@ to do
 184 the business.
 185
 186 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 187 already been w-w'd!  (You can end up with several liked-named Ids
 188 bouncing around at the same time---absolute mischief.)  So the
 189 criterion we use is: if an Id already has an unfolding (for whatever
 190 reason), then we don't w-w it.
 191
 192 The only reason this is monadised is for the unique supply.
 193
 194 Note [Don't w/w inline things]
 195 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 196 It's very important to refrain from w/w-ing an INLINE function
 197 If we do so by mistake we transform
 198         f = __inline (\x -> E)
 199 into
 200         f = __inline (\x -> case x of (a,b) -> fw E)
 201         fw = \ab -> (__inline (\x -> E)) (a,b)
 202 and the original __inline now vanishes, so E is no longer
 203 inside its __inline wrapper.  Death!  Disaster!
 204
 205 Furthermore, if the programmer has marked something as INLINE,
 206 we may lose by w/w'ing it.
 207
 208 If the strictness analyser is run twice, this test also prevents
 209 wrappers (which are INLINEd) from being re-done.
 210
 211 Notice that we refrain from w/w'ing an INLINE function even if it is
 212 in a recursive group.  It might not be the loop breaker.  (We could
 213 test for loop-breaker-hood, but I'm not sure that ever matters.)
 214
 215 \begin{code}
 216 tryWW   :: RecFlag
 217         -> Id                           -- The fn binder
 218         -> CoreExpr                     -- The bound rhs; its innards
 219                                         --   are already ww'd
 220         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 221                                         -- if one, then no worker (only
 222                                         -- the orig "wrapper" lives on);
 223                                         -- if two, then a worker and a
 224                                         -- wrapper.
 225 tryWW is_rec fn_id rhs
 226   |  -- isNonRec is_rec &&      -- Now omitted: see Note [Don't w/w inline things]
 227      certainlyWillInline unfolding
 228
 229   || isNeverActive inline_prag
 230         -- No point in worker/wrappering if the thing is never inlined!
 231         -- Because the no-inline prag will prevent the wrapper ever
 232         -- being inlined at a call site.
 233   = return [ (new_fn_id, rhs) ]
 234
 235   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 236   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 237     splitThunk new_fn_id rhs
 238
 239   | is_fun && worthSplittingFun wrap_dmds res_info
 240   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 241
 242   | otherwise
 243   = return [ (new_fn_id, rhs) ]
 244
 245   where
 246     fn_info      = idInfo fn_id
 247     maybe_fn_dmd = newDemandInfo fn_info
 248     unfolding    = unfoldingInfo fn_info
 249     inline_prag  = inlinePragInfo fn_info
 250
 251         -- In practice it always will have a strictness
 252         -- signature, even if it's a uninformative one
 253     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 254     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 255
 256         -- new_fn_id has the DmdEnv zapped.
 257         --      (a) it is never used again
 258         --      (b) it wastes space
 259         --      (c) it becomes incorrect as things are cloned, because
 260         --          we don't push the substitution into it
 261     new_fn_id | isEmptyVarEnv env = fn_id
 262               | otherwise         = fn_id `setIdNewStrictness`
 263                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 264
 265     is_fun    = notNull wrap_dmds
 266     is_thunk  = not is_fun && not (exprIsHNF rhs)
 267
 268 ---------------------
 269 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 270   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) ) do
 271         -- The arity should match the signature
 272     (work_demands, wrap_fn, work_fn) <- mkWwBodies fun_ty wrap_dmds res_info one_shots
 273     work_uniq <- getUniqueM
 274     let
 275         work_rhs = work_fn rhs
 276         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 277                         `setInlinePragma` inline_prag
 278                                 -- Any inline pragma (which sets when inlining is active)
 279                                 -- on the original function is duplicated on the worker and wrapper
 280                                 -- It *matters* that the pragma stays on the wrapper
 281                                 -- It seems sensible to have it on the worker too, although we
 282                                 -- can't think of a compelling reason. (In ptic, INLINE things are
 283                                 -- not w/wd)
 284                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 285                                 -- Even though we may not be at top level,
 286                                 -- it's ok to give it an empty DmdEnv
 287                         `setIdArity` (exprArity work_rhs)
 288                                 -- Set the arity so that the Core Lint check that the
 289                                 -- arity is consistent with the demand type goes through
 290
 291         wrap_rhs = wrap_fn work_id
 292         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 293
 294     return ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 295         -- Worker first, because wrapper mentions it
 296         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 297   where
 298     fun_ty = idType fn_id
 299
 300     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 301                                 -- So it may be more than the number of top-level-visible lambdas
 302
 303     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 304                   | otherwise         = TopRes
 305
 306     one_shots = get_one_shots rhs
 307
 308 -- If the original function has one-shot arguments, it is important to
 309 -- make the wrapper and worker have corresponding one-shot arguments too.
 310 -- Otherwise we spuriously float stuff out of case-expression join points,
 311 -- which is very annoying.
 312 get_one_shots (Lam b e)
 313   | isId b    = isOneShotLambda b : get_one_shots e
 314   | otherwise = get_one_shots e
 315 get_one_shots (Note _ e) = get_one_shots e
 316 get_one_shots other      = noOneShotInfo
 317 \end{code}
 318
 319 Thunk splitting
 320 ~~~~~~~~~~~~~~~
 321 Suppose x is used strictly (never mind whether it has the CPR
 322 property).
 323
 324       let
 325         x* = x-rhs
 326       in body
 327
 328 splitThunk transforms like this:
 329
 330       let
 331         x* = case x-rhs of { I# a -> I# a }
 332       in body
 333
 334 Now simplifier will transform to
 335
 336       case x-rhs of
 337         I# a -> let x* = I# a
 338                 in body
 339
 340 which is what we want. Now suppose x-rhs is itself a case:
 341
 342         x-rhs = case e of { T -> I# a; F -> I# b }
 343
 344 The join point will abstract over a, rather than over (which is
 345 what would have happened before) which is fine.
 346
 347 Notice that x certainly has the CPR property now!
 348
 349 In fact, splitThunk uses the function argument w/w splitting
 350 function, so that if x's demand is deeper (say U(U(L,L),L))
 351 then the splitting will go deeper too.
 352
 353 \begin{code}
 354 -- splitThunk converts the *non-recursive* binding
 355 --      x = e
 356 -- into
 357 --      x = let x = e
 358 --          in case x of
 359 --               I# y -> let x = I# y in x }
 360 -- See comments above. Is it not beautifully short?
 361
 362 splitThunk fn_id rhs = do
 363     (_, wrap_fn, work_fn) <- mkWWstr [fn_id]
 364     return [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 365 \end{code}
 366
 367
 368 %************************************************************************
 369 %*                                                                      *
 370 \subsection{Functions over Demands}
 371 %*                                                                      *
 372 %************************************************************************
 373
 374 \begin{code}
 375 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 376                 -- True <=> the wrapper would not be an identity function
 377 worthSplittingFun ds res
 378   = any worth_it ds || returnsCPR res
 379         -- worthSplitting returns False for an empty list of demands,
 380         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 381   -- See Note [Worker-wrapper for bottoming functions]
 382   where
 383     worth_it Abs              = True    -- Absent arg
 384     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 385     worth_it other            = False
 386
 387 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 388                     -> DmdResult        -- CPR info for the thunk
 389                     -> Bool
 390 worthSplittingThunk maybe_dmd res
 391   = worth_it maybe_dmd || returnsCPR res
 392   where
 393         -- Split if the thing is unpacked
 394     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 395     worth_it other                   = False
 396 \end{code}
 397
 398 Note [Worker-wrapper for bottoming functions]
 399 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 400 We used not to split if the result is bottom.
 401 [Justification:  there's no efficiency to be gained.]
 402
 403 But it's sometimes bad not to make a wrapper.  Consider
 404         fw = \x# -> let x = I# x# in case e of
 405                                         p1 -> error_fn x
 406                                         p2 -> error_fn x
 407                                         p3 -> the real stuff
 408 The re-boxing code won't go away unless error_fn gets a wrapper too.
 409 [We don't do reboxing now, but in general it's better to pass an
 410 unboxed thing to f, and have it reboxed in the error cases....]
 411
 412
 413 %************************************************************************
 414 %*                                                                      *
 415 \subsection{The worker wrapper core}
 416 %*                                                                      *
 417 %************************************************************************
 418
 419 @mkWrapper@ is called when importing a function.  We have the type of
 420 the function and the name of its worker, and we want to make its body (the wrapper).
 421
 422 \begin{code}
 423 mkWrapper :: Type               -- Wrapper type
 424           -> StrictSig          -- Wrapper strictness info
 425           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 426
 427 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info)) = do
 428     (_, wrap_fn, _) <- mkWwBodies fun_ty demands res_info noOneShotInfo
 429     return wrap_fn
 430
 431 noOneShotInfo = repeat False
 432 \end{code}