compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 module WorkWrap ( wwTopBinds, mkWrapper ) where
   8
   9 #include "HsVersions.h"
  10
  11 import CoreSyn
  12 import CoreUnfold       ( certainlyWillInline )
  13 import CoreLint         ( showPass, endPass )
  14 import CoreUtils        ( exprType, exprIsHNF, exprArity )
  15 import Id               ( Id, idType, isOneShotLambda,
  16                           setIdNewStrictness, mkWorkerId,
  17                           setIdWorkerInfo, setInlinePragma,
  18                           setIdArity, idInfo )
  19 import MkId             ( lazyIdKey, lazyIdUnfolding )
  20 import Type             ( Type )
  21 import IdInfo           ( WorkerInfo(..), arityInfo,
  22                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  23                         )
  24 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  25                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  26                         )
  27 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  28 import Unique           ( hasKey )
  29 import BasicTypes       ( RecFlag(..), isNonRec )
  30 import VarEnv           ( isEmptyVarEnv )
  31 import Maybes           ( orElse )
  32 import DynFlags
  33 import WwLib
  34 import Util             ( lengthIs, notNull )
  35 import Outputable
  36 \end{code}
  37
  38 We take Core bindings whose binders have:
  39
  40 \begin{enumerate}
  41
  42 \item Strictness attached (by the front-end of the strictness
  43 analyser), and / or
  44
  45 \item Constructed Product Result information attached by the CPR
  46 analysis pass.
  47
  48 \end{enumerate}
  49
  50 and we return some ``plain'' bindings which have been
  51 worker/wrapper-ified, meaning:
  52
  53 \begin{enumerate}
  54
  55 \item Functions have been split into workers and wrappers where
  56 appropriate.  If a function has both strictness and CPR properties
  57 then only one worker/wrapper doing both transformations is produced;
  58
  59 \item Binders' @IdInfos@ have been updated to reflect the existence of
  60 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  61 info for exported values).
  62 \end{enumerate}
  63
  64 \begin{code}
  65
  66 wwTopBinds :: DynFlags
  67            -> UniqSupply
  68            -> [CoreBind]
  69            -> IO [CoreBind]
  70
  71 wwTopBinds dflags us binds
  72   = do {
  73         showPass dflags "Worker Wrapper binds";
  74
  75         -- Create worker/wrappers, and mark binders with their
  76         -- "strictness info" [which encodes their worker/wrapper-ness]
  77         let { binds' = workersAndWrappers us binds };
  78
  79         endPass dflags "Worker Wrapper binds"
  80                 Opt_D_dump_worker_wrapper binds'
  81     }
  82 \end{code}
  83
  84
  85 \begin{code}
  86 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  87
  88 workersAndWrappers us top_binds
  89   = initUs_ us $
  90     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  91     returnUs (concat top_binds')
  92 \end{code}
  93
  94 %************************************************************************
  95 %*                                                                      *
  96 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
  97 %*                                                                      *
  98 %************************************************************************
  99
 100 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 101 turn.  Non-recursive case first, then recursive...
 102
 103 \begin{code}
 104 wwBind  :: CoreBind
 105         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 106                                 -- the caller will convert to Expr/Binding,
 107                                 -- as appropriate.
 108
 109 wwBind (NonRec binder rhs)
 110   = wwExpr rhs                          `thenUs` \ new_rhs ->
 111     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 112     returnUs [NonRec b e | (b,e) <- new_pairs]
 113       -- Generated bindings must be non-recursive
 114       -- because the original binding was.
 115
 116 wwBind (Rec pairs)
 117   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 118     returnUs [Rec (concat new_pairs)]
 119   where
 120     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 121                            tryWW Recursive binder new_rhs
 122 \end{code}
 123
 124 @wwExpr@ basically just walks the tree, looking for appropriate
 125 annotations that can be used. Remember it is @wwBind@ that does the
 126 matching by looking for strict arguments of the correct type.
 127 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 128
 129 \begin{code}
 130 wwExpr :: CoreExpr -> UniqSM CoreExpr
 131
 132 wwExpr e@(Type _)             = returnUs e
 133 wwExpr e@(Lit _)              = returnUs e
 134 wwExpr e@(Note InlineMe expr) = returnUs e
 135         -- Don't w/w inside InlineMe's
 136
 137 wwExpr e@(Var v)
 138   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 139   | otherwise            = returnUs e
 140         -- HACK alert: Inline 'lazy' after strictness analysis
 141         -- (but not inside InlineMe's)
 142
 143 wwExpr (Lam binder expr)
 144   = wwExpr expr                 `thenUs` \ new_expr ->
 145     returnUs (Lam binder new_expr)
 146
 147 wwExpr (App f a)
 148   = wwExpr f                    `thenUs` \ new_f ->
 149     wwExpr a                    `thenUs` \ new_a ->
 150     returnUs (App new_f new_a)
 151
 152 wwExpr (Note note expr)
 153   = wwExpr expr                 `thenUs` \ new_expr ->
 154     returnUs (Note note new_expr)
 155
 156 wwExpr (Cast expr co)
 157   = wwExpr expr                 `thenUs` \ new_expr ->
 158     returnUs (Cast new_expr co)
 159
 160 wwExpr (Let bind expr)
 161   = wwBind bind                 `thenUs` \ intermediate_bind ->
 162     wwExpr expr                 `thenUs` \ new_expr ->
 163     returnUs (mkLets intermediate_bind new_expr)
 164
 165 wwExpr (Case expr binder ty alts)
 166   = wwExpr expr                         `thenUs` \ new_expr ->
 167     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 168     returnUs (Case new_expr binder ty new_alts)
 169   where
 170     ww_alt (con, binders, rhs)
 171       = wwExpr rhs                      `thenUs` \ new_rhs ->
 172         returnUs (con, binders, new_rhs)
 173 \end{code}
 174
 175 %************************************************************************
 176 %*                                                                      *
 177 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 178 %*                                                                      *
 179 %************************************************************************
 180
 181 @tryWW@ just accumulates arguments, converts strictness info from the
 182 front-end into the proper form, then calls @mkWwBodies@ to do
 183 the business.
 184
 185 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 186 already been w-w'd!  (You can end up with several liked-named Ids
 187 bouncing around at the same time---absolute mischief.)  So the
 188 criterion we use is: if an Id already has an unfolding (for whatever
 189 reason), then we don't w-w it.
 190
 191 The only reason this is monadised is for the unique supply.
 192
 193 \begin{code}
 194 tryWW   :: RecFlag
 195         -> Id                           -- The fn binder
 196         -> CoreExpr                     -- The bound rhs; its innards
 197                                         --   are already ww'd
 198         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 199                                         -- if one, then no worker (only
 200                                         -- the orig "wrapper" lives on);
 201                                         -- if two, then a worker and a
 202                                         -- wrapper.
 203 tryWW is_rec fn_id rhs
 204   |  isNonRec is_rec && certainlyWillInline unfolding
 205         -- No point in worker/wrappering a function that is going to be
 206         -- INLINEd wholesale anyway.  If the strictness analyser is run
 207         -- twice, this test also prevents wrappers (which are INLINEd)
 208         -- from being re-done.
 209         --
 210         -- It's very important to refrain from w/w-ing an INLINE function
 211         -- If we do so by mistake we transform
 212         --      f = __inline (\x -> E)
 213         -- into
 214         --      f = __inline (\x -> case x of (a,b) -> fw E)
 215         --      fw = \ab -> (__inline (\x -> E)) (a,b)
 216         -- and the original __inline now vanishes, so E is no longer
 217         -- inside its __inline wrapper.  Death!  Disaster!
 218   = returnUs [ (new_fn_id, rhs) ]
 219
 220   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 221   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 222     splitThunk new_fn_id rhs
 223
 224   | is_fun && worthSplittingFun wrap_dmds res_info
 225   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 226
 227   | otherwise
 228   = returnUs [ (new_fn_id, rhs) ]
 229
 230   where
 231     fn_info      = idInfo fn_id
 232     maybe_fn_dmd = newDemandInfo fn_info
 233     unfolding    = unfoldingInfo fn_info
 234     inline_prag  = inlinePragInfo fn_info
 235
 236         -- In practice it always will have a strictness
 237         -- signature, even if it's a uninformative one
 238     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 239     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 240
 241         -- new_fn_id has the DmdEnv zapped.
 242         --      (a) it is never used again
 243         --      (b) it wastes space
 244         --      (c) it becomes incorrect as things are cloned, because
 245         --          we don't push the substitution into it
 246     new_fn_id | isEmptyVarEnv env = fn_id
 247               | otherwise         = fn_id `setIdNewStrictness`
 248                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 249
 250     is_fun    = notNull wrap_dmds
 251     is_thunk  = not is_fun && not (exprIsHNF rhs)
 252
 253 ---------------------
 254 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 255   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 256         -- The arity should match the signature
 257     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 258     getUniqueUs                                         `thenUs` \ work_uniq ->
 259     let
 260         work_rhs = work_fn rhs
 261         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 262                         `setInlinePragma` inline_prag
 263                                 -- Any inline pragma (which sets when inlining is active)
 264                                 -- on the original function is duplicated on the worker and wrapper
 265                                 -- It *matters* that the pragma stays on the wrapper
 266                                 -- It seems sensible to have it on the worker too, although we
 267                                 -- can't think of a compelling reason. (In ptic, INLINE things are
 268                                 -- not w/wd)
 269                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 270                                 -- Even though we may not be at top level,
 271                                 -- it's ok to give it an empty DmdEnv
 272                         `setIdArity` (exprArity work_rhs)
 273                                 -- Set the arity so that the Core Lint check that the
 274                                 -- arity is consistent with the demand type goes through
 275
 276         wrap_rhs = wrap_fn work_id
 277         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 278
 279     in
 280     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 281         -- Worker first, because wrapper mentions it
 282         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 283   where
 284     fun_ty = idType fn_id
 285
 286     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 287                                 -- So it may be more than the number of top-level-visible lambdas
 288
 289     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 290                   | otherwise         = TopRes
 291
 292     one_shots = get_one_shots rhs
 293
 294 -- If the original function has one-shot arguments, it is important to
 295 -- make the wrapper and worker have corresponding one-shot arguments too.
 296 -- Otherwise we spuriously float stuff out of case-expression join points,
 297 -- which is very annoying.
 298 get_one_shots (Lam b e)
 299   | isId b    = isOneShotLambda b : get_one_shots e
 300   | otherwise = get_one_shots e
 301 get_one_shots (Note _ e) = get_one_shots e
 302 get_one_shots other      = noOneShotInfo
 303 \end{code}
 304
 305 Thunk splitting
 306 ~~~~~~~~~~~~~~~
 307 Suppose x is used strictly (never mind whether it has the CPR
 308 property).
 309
 310       let
 311         x* = x-rhs
 312       in body
 313
 314 splitThunk transforms like this:
 315
 316       let
 317         x* = case x-rhs of { I# a -> I# a }
 318       in body
 319
 320 Now simplifier will transform to
 321
 322       case x-rhs of
 323         I# a -> let x* = I# a
 324                 in body
 325
 326 which is what we want. Now suppose x-rhs is itself a case:
 327
 328         x-rhs = case e of { T -> I# a; F -> I# b }
 329
 330 The join point will abstract over a, rather than over (which is
 331 what would have happened before) which is fine.
 332
 333 Notice that x certainly has the CPR property now!
 334
 335 In fact, splitThunk uses the function argument w/w splitting
 336 function, so that if x's demand is deeper (say U(U(L,L),L))
 337 then the splitting will go deeper too.
 338
 339 \begin{code}
 340 -- splitThunk converts the *non-recursive* binding
 341 --      x = e
 342 -- into
 343 --      x = let x = e
 344 --          in case x of
 345 --               I# y -> let x = I# y in x }
 346 -- See comments above. Is it not beautifully short?
 347
 348 splitThunk fn_id rhs
 349   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 350     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 351 \end{code}
 352
 353
 354 %************************************************************************
 355 %*                                                                      *
 356 \subsection{Functions over Demands}
 357 %*                                                                      *
 358 %************************************************************************
 359
 360 \begin{code}
 361 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 362                 -- True <=> the wrapper would not be an identity function
 363 worthSplittingFun ds res
 364   = any worth_it ds || returnsCPR res
 365         -- worthSplitting returns False for an empty list of demands,
 366         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 367
 368         -- We used not to split if the result is bottom.
 369         -- [Justification:  there's no efficiency to be gained.]
 370         -- But it's sometimes bad not to make a wrapper.  Consider
 371         --      fw = \x# -> let x = I# x# in case e of
 372         --                                      p1 -> error_fn x
 373         --                                      p2 -> error_fn x
 374         --                                      p3 -> the real stuff
 375         -- The re-boxing code won't go away unless error_fn gets a wrapper too.
 376         -- [We don't do reboxing now, but in general it's better to pass
 377         --  an unboxed thing to f, and have it reboxed in the error cases....]
 378   where
 379     worth_it Abs              = True    -- Absent arg
 380     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 381     worth_it other            = False
 382
 383 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 384                     -> DmdResult        -- CPR info for the thunk
 385                     -> Bool
 386 worthSplittingThunk maybe_dmd res
 387   = worth_it maybe_dmd || returnsCPR res
 388   where
 389         -- Split if the thing is unpacked
 390     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 391     worth_it other                   = False
 392 \end{code}
 393
 394
 395
 396 %************************************************************************
 397 %*                                                                      *
 398 \subsection{The worker wrapper core}
 399 %*                                                                      *
 400 %************************************************************************
 401
 402 @mkWrapper@ is called when importing a function.  We have the type of
 403 the function and the name of its worker, and we want to make its body (the wrapper).
 404
 405 \begin{code}
 406 mkWrapper :: Type               -- Wrapper type
 407           -> StrictSig          -- Wrapper strictness info
 408           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 409
 410 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 411   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 412     returnUs wrap_fn
 413
 414 noOneShotInfo = repeat False
 415 \end{code}