compiler/stranal/WorkWrap.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1993-1998
   3 %
   4 \section[WorkWrap]{Worker/wrapper-generating back-end of strictness analyser}
   5
   6 \begin{code}
   7 {-# OPTIONS -w #-}
   8 -- The above warning supression flag is a temporary kludge.
   9 -- While working on this module you are encouraged to remove it and fix
  10 -- any warnings in the module. See
  11 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  12 -- for details
  13
  14 module WorkWrap ( wwTopBinds, mkWrapper ) where
  15
  16 #include "HsVersions.h"
  17
  18 import CoreSyn
  19 import CoreUnfold       ( certainlyWillInline )
  20 import CoreLint         ( showPass, endPass )
  21 import CoreUtils        ( exprType, exprIsHNF, exprArity )
  22 import Id               ( Id, idType, isOneShotLambda,
  23                           setIdNewStrictness, mkWorkerId,
  24                           setIdWorkerInfo, setInlinePragma,
  25                           setIdArity, idInfo )
  26 import MkId             ( lazyIdKey, lazyIdUnfolding )
  27 import Type             ( Type )
  28 import IdInfo           ( WorkerInfo(..), arityInfo,
  29                           newDemandInfo, newStrictnessInfo, unfoldingInfo, inlinePragInfo
  30                         )
  31 import NewDemand        ( Demand(..), StrictSig(..), DmdType(..), DmdResult(..),
  32                           Demands(..), mkTopDmdType, isBotRes, returnsCPR, topSig, isAbsent
  33                         )
  34 import UniqSupply       ( UniqSupply, initUs_, returnUs, thenUs, mapUs, getUniqueUs, UniqSM )
  35 import Unique           ( hasKey )
  36 import BasicTypes       ( RecFlag(..), isNonRec, isNeverActive )
  37 import VarEnv           ( isEmptyVarEnv )
  38 import Maybes           ( orElse )
  39 import DynFlags
  40 import WwLib
  41 import Util             ( lengthIs, notNull )
  42 import Outputable
  43 \end{code}
  44
  45 We take Core bindings whose binders have:
  46
  47 \begin{enumerate}
  48
  49 \item Strictness attached (by the front-end of the strictness
  50 analyser), and / or
  51
  52 \item Constructed Product Result information attached by the CPR
  53 analysis pass.
  54
  55 \end{enumerate}
  56
  57 and we return some ``plain'' bindings which have been
  58 worker/wrapper-ified, meaning:
  59
  60 \begin{enumerate}
  61
  62 \item Functions have been split into workers and wrappers where
  63 appropriate.  If a function has both strictness and CPR properties
  64 then only one worker/wrapper doing both transformations is produced;
  65
  66 \item Binders' @IdInfos@ have been updated to reflect the existence of
  67 these workers/wrappers (this is where we get STRICTNESS and CPR pragma
  68 info for exported values).
  69 \end{enumerate}
  70
  71 \begin{code}
  72
  73 wwTopBinds :: DynFlags
  74            -> UniqSupply
  75            -> [CoreBind]
  76            -> IO [CoreBind]
  77
  78 wwTopBinds dflags us binds
  79   = do {
  80         showPass dflags "Worker Wrapper binds";
  81
  82         -- Create worker/wrappers, and mark binders with their
  83         -- "strictness info" [which encodes their worker/wrapper-ness]
  84         let { binds' = workersAndWrappers us binds };
  85
  86         endPass dflags "Worker Wrapper binds"
  87                 Opt_D_dump_worker_wrapper binds'
  88     }
  89 \end{code}
  90
  91
  92 \begin{code}
  93 workersAndWrappers :: UniqSupply -> [CoreBind] -> [CoreBind]
  94
  95 workersAndWrappers us top_binds
  96   = initUs_ us $
  97     mapUs wwBind top_binds `thenUs` \ top_binds' ->
  98     returnUs (concat top_binds')
  99 \end{code}
 100
 101 %************************************************************************
 102 %*                                                                      *
 103 \subsection[wwBind-wwExpr]{@wwBind@ and @wwExpr@}
 104 %*                                                                      *
 105 %************************************************************************
 106
 107 @wwBind@ works on a binding, trying each \tr{(binder, expr)} pair in
 108 turn.  Non-recursive case first, then recursive...
 109
 110 \begin{code}
 111 wwBind  :: CoreBind
 112         -> UniqSM [CoreBind]    -- returns a WwBinding intermediate form;
 113                                 -- the caller will convert to Expr/Binding,
 114                                 -- as appropriate.
 115
 116 wwBind (NonRec binder rhs)
 117   = wwExpr rhs                          `thenUs` \ new_rhs ->
 118     tryWW NonRecursive binder new_rhs   `thenUs` \ new_pairs ->
 119     returnUs [NonRec b e | (b,e) <- new_pairs]
 120       -- Generated bindings must be non-recursive
 121       -- because the original binding was.
 122
 123 wwBind (Rec pairs)
 124   = mapUs do_one pairs          `thenUs` \ new_pairs ->
 125     returnUs [Rec (concat new_pairs)]
 126   where
 127     do_one (binder, rhs) = wwExpr rhs   `thenUs` \ new_rhs ->
 128                            tryWW Recursive binder new_rhs
 129 \end{code}
 130
 131 @wwExpr@ basically just walks the tree, looking for appropriate
 132 annotations that can be used. Remember it is @wwBind@ that does the
 133 matching by looking for strict arguments of the correct type.
 134 @wwExpr@ is a version that just returns the ``Plain'' Tree.
 135
 136 \begin{code}
 137 wwExpr :: CoreExpr -> UniqSM CoreExpr
 138
 139 wwExpr e@(Type _)             = returnUs e
 140 wwExpr e@(Lit _)              = returnUs e
 141 wwExpr e@(Note InlineMe expr) = returnUs e
 142         -- Don't w/w inside InlineMe's
 143
 144 wwExpr e@(Var v)
 145   | v `hasKey` lazyIdKey = returnUs lazyIdUnfolding
 146   | otherwise            = returnUs e
 147         -- HACK alert: Inline 'lazy' after strictness analysis
 148         -- (but not inside InlineMe's)
 149
 150 wwExpr (Lam binder expr)
 151   = wwExpr expr                 `thenUs` \ new_expr ->
 152     returnUs (Lam binder new_expr)
 153
 154 wwExpr (App f a)
 155   = wwExpr f                    `thenUs` \ new_f ->
 156     wwExpr a                    `thenUs` \ new_a ->
 157     returnUs (App new_f new_a)
 158
 159 wwExpr (Note note expr)
 160   = wwExpr expr                 `thenUs` \ new_expr ->
 161     returnUs (Note note new_expr)
 162
 163 wwExpr (Cast expr co)
 164   = wwExpr expr                 `thenUs` \ new_expr ->
 165     returnUs (Cast new_expr co)
 166
 167 wwExpr (Let bind expr)
 168   = wwBind bind                 `thenUs` \ intermediate_bind ->
 169     wwExpr expr                 `thenUs` \ new_expr ->
 170     returnUs (mkLets intermediate_bind new_expr)
 171
 172 wwExpr (Case expr binder ty alts)
 173   = wwExpr expr                         `thenUs` \ new_expr ->
 174     mapUs ww_alt alts                   `thenUs` \ new_alts ->
 175     returnUs (Case new_expr binder ty new_alts)
 176   where
 177     ww_alt (con, binders, rhs)
 178       = wwExpr rhs                      `thenUs` \ new_rhs ->
 179         returnUs (con, binders, new_rhs)
 180 \end{code}
 181
 182 %************************************************************************
 183 %*                                                                      *
 184 \subsection[tryWW]{@tryWW@: attempt a worker/wrapper pair}
 185 %*                                                                      *
 186 %************************************************************************
 187
 188 @tryWW@ just accumulates arguments, converts strictness info from the
 189 front-end into the proper form, then calls @mkWwBodies@ to do
 190 the business.
 191
 192 We have to BE CAREFUL that we don't worker-wrapperize an Id that has
 193 already been w-w'd!  (You can end up with several liked-named Ids
 194 bouncing around at the same time---absolute mischief.)  So the
 195 criterion we use is: if an Id already has an unfolding (for whatever
 196 reason), then we don't w-w it.
 197
 198 The only reason this is monadised is for the unique supply.
 199
 200 Note [Don't w/w inline things]
 201 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 202 It's very important to refrain from w/w-ing an INLINE function
 203 If we do so by mistake we transform
 204         f = __inline (\x -> E)
 205 into
 206         f = __inline (\x -> case x of (a,b) -> fw E)
 207         fw = \ab -> (__inline (\x -> E)) (a,b)
 208 and the original __inline now vanishes, so E is no longer
 209 inside its __inline wrapper.  Death!  Disaster!
 210
 211 Furthermore, if the programmer has marked something as INLINE,
 212 we may lose by w/w'ing it.
 213
 214 If the strictness analyser is run twice, this test also prevents
 215 wrappers (which are INLINEd) from being re-done.
 216
 217 Notice that we refrain from w/w'ing an INLINE function even if it is
 218 in a recursive group.  It might not be the loop breaker.  (We could
 219 test for loop-breaker-hood, but I'm not sure that ever matters.)
 220
 221 \begin{code}
 222 tryWW   :: RecFlag
 223         -> Id                           -- The fn binder
 224         -> CoreExpr                     -- The bound rhs; its innards
 225                                         --   are already ww'd
 226         -> UniqSM [(Id, CoreExpr)]      -- either *one* or *two* pairs;
 227                                         -- if one, then no worker (only
 228                                         -- the orig "wrapper" lives on);
 229                                         -- if two, then a worker and a
 230                                         -- wrapper.
 231 tryWW is_rec fn_id rhs
 232   |  -- isNonRec is_rec &&      -- Now omitted: see Note [Don't w/w inline things]
 233      certainlyWillInline unfolding
 234
 235   || isNeverActive inline_prag
 236         -- No point in worker/wrappering if the thing is never inlined!
 237         -- Because the no-inline prag will prevent the wrapper ever
 238         -- being inlined at a call site.
 239   = returnUs [ (new_fn_id, rhs) ]
 240
 241   | is_thunk && worthSplittingThunk maybe_fn_dmd res_info
 242   = ASSERT2( isNonRec is_rec, ppr new_fn_id )   -- The thunk must be non-recursive
 243     splitThunk new_fn_id rhs
 244
 245   | is_fun && worthSplittingFun wrap_dmds res_info
 246   = splitFun new_fn_id fn_info wrap_dmds res_info inline_prag rhs
 247
 248   | otherwise
 249   = returnUs [ (new_fn_id, rhs) ]
 250
 251   where
 252     fn_info      = idInfo fn_id
 253     maybe_fn_dmd = newDemandInfo fn_info
 254     unfolding    = unfoldingInfo fn_info
 255     inline_prag  = inlinePragInfo fn_info
 256
 257         -- In practice it always will have a strictness
 258         -- signature, even if it's a uninformative one
 259     strict_sig  = newStrictnessInfo fn_info `orElse` topSig
 260     StrictSig (DmdType env wrap_dmds res_info) = strict_sig
 261
 262         -- new_fn_id has the DmdEnv zapped.
 263         --      (a) it is never used again
 264         --      (b) it wastes space
 265         --      (c) it becomes incorrect as things are cloned, because
 266         --          we don't push the substitution into it
 267     new_fn_id | isEmptyVarEnv env = fn_id
 268               | otherwise         = fn_id `setIdNewStrictness`
 269                                      StrictSig (mkTopDmdType wrap_dmds res_info)
 270
 271     is_fun    = notNull wrap_dmds
 272     is_thunk  = not is_fun && not (exprIsHNF rhs)
 273
 274 ---------------------
 275 splitFun fn_id fn_info wrap_dmds res_info inline_prag rhs
 276   = WARN( not (wrap_dmds `lengthIs` arity), ppr fn_id <+> (ppr arity $$ ppr wrap_dmds $$ ppr res_info) )
 277         -- The arity should match the signature
 278     mkWwBodies fun_ty wrap_dmds res_info one_shots      `thenUs` \ (work_demands, wrap_fn, work_fn) ->
 279     getUniqueUs                                         `thenUs` \ work_uniq ->
 280     let
 281         work_rhs = work_fn rhs
 282         work_id  = mkWorkerId work_uniq fn_id (exprType work_rhs)
 283                         `setInlinePragma` inline_prag
 284                                 -- Any inline pragma (which sets when inlining is active)
 285                                 -- on the original function is duplicated on the worker and wrapper
 286                                 -- It *matters* that the pragma stays on the wrapper
 287                                 -- It seems sensible to have it on the worker too, although we
 288                                 -- can't think of a compelling reason. (In ptic, INLINE things are
 289                                 -- not w/wd)
 290                         `setIdNewStrictness` StrictSig (mkTopDmdType work_demands work_res_info)
 291                                 -- Even though we may not be at top level,
 292                                 -- it's ok to give it an empty DmdEnv
 293                         `setIdArity` (exprArity work_rhs)
 294                                 -- Set the arity so that the Core Lint check that the
 295                                 -- arity is consistent with the demand type goes through
 296
 297         wrap_rhs = wrap_fn work_id
 298         wrap_id  = fn_id `setIdWorkerInfo` HasWorker work_id arity
 299
 300     in
 301     returnUs ([(work_id, work_rhs), (wrap_id, wrap_rhs)])
 302         -- Worker first, because wrapper mentions it
 303         -- mkWwBodies has already built a wrap_rhs with an INLINE pragma wrapped around it
 304   where
 305     fun_ty = idType fn_id
 306
 307     arity  = arityInfo fn_info  -- The arity is set by the simplifier using exprEtaExpandArity
 308                                 -- So it may be more than the number of top-level-visible lambdas
 309
 310     work_res_info | isBotRes res_info = BotRes  -- Cpr stuff done by wrapper
 311                   | otherwise         = TopRes
 312
 313     one_shots = get_one_shots rhs
 314
 315 -- If the original function has one-shot arguments, it is important to
 316 -- make the wrapper and worker have corresponding one-shot arguments too.
 317 -- Otherwise we spuriously float stuff out of case-expression join points,
 318 -- which is very annoying.
 319 get_one_shots (Lam b e)
 320   | isId b    = isOneShotLambda b : get_one_shots e
 321   | otherwise = get_one_shots e
 322 get_one_shots (Note _ e) = get_one_shots e
 323 get_one_shots other      = noOneShotInfo
 324 \end{code}
 325
 326 Thunk splitting
 327 ~~~~~~~~~~~~~~~
 328 Suppose x is used strictly (never mind whether it has the CPR
 329 property).
 330
 331       let
 332         x* = x-rhs
 333       in body
 334
 335 splitThunk transforms like this:
 336
 337       let
 338         x* = case x-rhs of { I# a -> I# a }
 339       in body
 340
 341 Now simplifier will transform to
 342
 343       case x-rhs of
 344         I# a -> let x* = I# a
 345                 in body
 346
 347 which is what we want. Now suppose x-rhs is itself a case:
 348
 349         x-rhs = case e of { T -> I# a; F -> I# b }
 350
 351 The join point will abstract over a, rather than over (which is
 352 what would have happened before) which is fine.
 353
 354 Notice that x certainly has the CPR property now!
 355
 356 In fact, splitThunk uses the function argument w/w splitting
 357 function, so that if x's demand is deeper (say U(U(L,L),L))
 358 then the splitting will go deeper too.
 359
 360 \begin{code}
 361 -- splitThunk converts the *non-recursive* binding
 362 --      x = e
 363 -- into
 364 --      x = let x = e
 365 --          in case x of
 366 --               I# y -> let x = I# y in x }
 367 -- See comments above. Is it not beautifully short?
 368
 369 splitThunk fn_id rhs
 370   = mkWWstr [fn_id]             `thenUs` \ (_, wrap_fn, work_fn) ->
 371     returnUs [ (fn_id, Let (NonRec fn_id rhs) (wrap_fn (work_fn (Var fn_id)))) ]
 372 \end{code}
 373
 374
 375 %************************************************************************
 376 %*                                                                      *
 377 \subsection{Functions over Demands}
 378 %*                                                                      *
 379 %************************************************************************
 380
 381 \begin{code}
 382 worthSplittingFun :: [Demand] -> DmdResult -> Bool
 383                 -- True <=> the wrapper would not be an identity function
 384 worthSplittingFun ds res
 385   = any worth_it ds || returnsCPR res
 386         -- worthSplitting returns False for an empty list of demands,
 387         -- and hence do_strict_ww is False if arity is zero and there is no CPR
 388   -- See Note [Worker-wrapper for bottoming functions]
 389   where
 390     worth_it Abs              = True    -- Absent arg
 391     worth_it (Eval (Prod ds)) = True    -- Product arg to evaluate
 392     worth_it other            = False
 393
 394 worthSplittingThunk :: Maybe Demand     -- Demand on the thunk
 395                     -> DmdResult        -- CPR info for the thunk
 396                     -> Bool
 397 worthSplittingThunk maybe_dmd res
 398   = worth_it maybe_dmd || returnsCPR res
 399   where
 400         -- Split if the thing is unpacked
 401     worth_it (Just (Eval (Prod ds))) = not (all isAbsent ds)
 402     worth_it other                   = False
 403 \end{code}
 404
 405 Note [Worker-wrapper for bottoming functions]
 406 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 407 We used not to split if the result is bottom.
 408 [Justification:  there's no efficiency to be gained.]
 409
 410 But it's sometimes bad not to make a wrapper.  Consider
 411         fw = \x# -> let x = I# x# in case e of
 412                                         p1 -> error_fn x
 413                                         p2 -> error_fn x
 414                                         p3 -> the real stuff
 415 The re-boxing code won't go away unless error_fn gets a wrapper too.
 416 [We don't do reboxing now, but in general it's better to pass an
 417 unboxed thing to f, and have it reboxed in the error cases....]
 418
 419
 420 %************************************************************************
 421 %*                                                                      *
 422 \subsection{The worker wrapper core}
 423 %*                                                                      *
 424 %************************************************************************
 425
 426 @mkWrapper@ is called when importing a function.  We have the type of
 427 the function and the name of its worker, and we want to make its body (the wrapper).
 428
 429 \begin{code}
 430 mkWrapper :: Type               -- Wrapper type
 431           -> StrictSig          -- Wrapper strictness info
 432           -> UniqSM (Id -> CoreExpr)    -- Wrapper body, missing worker Id
 433
 434 mkWrapper fun_ty (StrictSig (DmdType _ demands res_info))
 435   = mkWwBodies fun_ty demands res_info noOneShotInfo    `thenUs` \ (_, wrap_fn, _) ->
 436     returnUs wrap_fn
 437
 438 noOneShotInfo = repeat False
 439 \end{code}