compiler/typecheck/TcDeriv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Handles @deriving@ clauses on @data@ declarations.
   7
   8 \begin{code}
   9 module TcDeriv ( tcDeriving ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn
  14 import DynFlags
  15
  16 import Generics
  17 import TcRnMonad
  18 import TcEnv
  19 import TcClassDcl( tcAddDeclCtxt )      -- Small helper
  20 import TcGenDeriv                       -- Deriv stuff
  21 import InstEnv
  22 import Inst
  23 import TcHsType
  24 import TcMType
  25 import TcSimplify
  26
  27 import RnBinds
  28 import RnEnv
  29 import HscTypes
  30
  31 import Class
  32 import Type
  33 import ErrUtils
  34 import MkId
  35 import DataCon
  36 import Maybes
  37 import RdrName
  38 import Name
  39 import NameSet
  40 import TyCon
  41 import TcType
  42 import Var
  43 import VarSet
  44 import PrelNames
  45 import SrcLoc
  46 import Util
  47 import ListSetOps
  48 import Outputable
  49 import Bag
  50 \end{code}
  51
  52 %************************************************************************
  53 %*                                                                      *
  54 \subsection[TcDeriv-intro]{Introduction to how we do deriving}
  55 %*                                                                      *
  56 %************************************************************************
  57
  58 Consider
  59
  60         data T a b = C1 (Foo a) (Bar b)
  61                    | C2 Int (T b a)
  62                    | C3 (T a a)
  63                    deriving (Eq)
  64
  65 [NOTE: See end of these comments for what to do with
  66         data (C a, D b) => T a b = ...
  67 ]
  68
  69 We want to come up with an instance declaration of the form
  70
  71         instance (Ping a, Pong b, ...) => Eq (T a b) where
  72                 x == y = ...
  73
  74 It is pretty easy, albeit tedious, to fill in the code "...".  The
  75 trick is to figure out what the context for the instance decl is,
  76 namely @Ping@, @Pong@ and friends.
  77
  78 Let's call the context reqd for the T instance of class C at types
  79 (a,b, ...)  C (T a b).  Thus:
  80
  81         Eq (T a b) = (Ping a, Pong b, ...)
  82
  83 Now we can get a (recursive) equation from the @data@ decl:
  84
  85         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
  86                    u Eq (T b a) u Eq Int        -- From C2
  87                    u Eq (T a a)                 -- From C3
  88
  89 Foo and Bar may have explicit instances for @Eq@, in which case we can
  90 just substitute for them.  Alternatively, either or both may have
  91 their @Eq@ instances given by @deriving@ clauses, in which case they
  92 form part of the system of equations.
  93
  94 Now all we need do is simplify and solve the equations, iterating to
  95 find the least fixpoint.  Notice that the order of the arguments can
  96 switch around, as here in the recursive calls to T.
  97
  98 Let's suppose Eq (Foo a) = Eq a, and Eq (Bar b) = Ping b.
  99
 100 We start with:
 101
 102         Eq (T a b) = {}         -- The empty set
 103
 104 Next iteration:
 105         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 106                    u Eq (T b a) u Eq Int        -- From C2
 107                    u Eq (T a a)                 -- From C3
 108
 109         After simplification:
 110                    = Eq a u Ping b u {} u {} u {}
 111                    = Eq a u Ping b
 112
 113 Next iteration:
 114
 115         Eq (T a b) = Eq (Foo a) u Eq (Bar b)    -- From C1
 116                    u Eq (T b a) u Eq Int        -- From C2
 117                    u Eq (T a a)                 -- From C3
 118
 119         After simplification:
 120                    = Eq a u Ping b
 121                    u (Eq b u Ping a)
 122                    u (Eq a u Ping a)
 123
 124                    = Eq a u Ping b u Eq b u Ping a
 125
 126 The next iteration gives the same result, so this is the fixpoint.  We
 127 need to make a canonical form of the RHS to ensure convergence.  We do
 128 this by simplifying the RHS to a form in which
 129
 130         - the classes constrain only tyvars
 131         - the list is sorted by tyvar (major key) and then class (minor key)
 132         - no duplicates, of course
 133
 134 So, here are the synonyms for the ``equation'' structures:
 135
 136 \begin{code}
 137 type DerivRhs  = ThetaType
 138 type DerivSoln = DerivRhs
 139 type DerivEqn  = (SrcSpan, InstOrigin, Name, [TyVar], Class, Type, DerivRhs)
 140         -- (span, orig, df, tvs, C, ty, rhs)
 141         --    implies a dfun declaration of the form
 142         --       df :: forall tvs. rhs => C ty
 143         -- The Name is the name for the DFun we'll build
 144         -- The tyvars bind all the variables in the RHS
 145         -- For family indexes, the tycon is the *family* tycon
 146         --              (not the representation tycon)
 147
 148 pprDerivEqn :: DerivEqn -> SDoc
 149 pprDerivEqn (l, _, n, tvs, c, ty, rhs)
 150   = parens (hsep [ppr l, ppr n, ppr tvs, ppr c, ppr ty]
 151             <+> equals <+> ppr rhs)
 152 \end{code}
 153
 154
 155 [Data decl contexts] A note about contexts on data decls
 156 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 157 Consider
 158
 159         data (RealFloat a) => Complex a = !a :+ !a deriving( Read )
 160
 161 We will need an instance decl like:
 162
 163         instance (Read a, RealFloat a) => Read (Complex a) where
 164           ...
 165
 166 The RealFloat in the context is because the read method for Complex is bound
 167 to construct a Complex, and doing that requires that the argument type is
 168 in RealFloat.
 169
 170 But this ain't true for Show, Eq, Ord, etc, since they don't construct
 171 a Complex; they only take them apart.
 172
 173 Our approach: identify the offending classes, and add the data type
 174 context to the instance decl.  The "offending classes" are
 175
 176         Read, Enum?
 177
 178 FURTHER NOTE ADDED March 2002.  In fact, Haskell98 now requires that
 179 pattern matching against a constructor from a data type with a context
 180 gives rise to the constraints for that context -- or at least the thinned
 181 version.  So now all classes are "offending".
 182
 183 [Newtype deriving]
 184 ~~~~~~~~~~~~~~~~~~
 185 Consider this:
 186     class C a b
 187     instance C [a] Char
 188     newtype T = T Char deriving( C [a] )
 189
 190 Notice the free 'a' in the deriving.  We have to fill this out to
 191     newtype T = T Char deriving( forall a. C [a] )
 192
 193 And then translate it to:
 194     instance C [a] Char => C [a] T where ...
 195
 196
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201 \subsection[TcDeriv-driver]{Top-level function for \tr{derivings}}
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcDeriving  :: [LTyClDecl Name] -- All type constructors
 207             -> [LDerivDecl Name] -- All stand-alone deriving declarations
 208             -> TcM ([InstInfo],         -- The generated "instance decls"
 209                     HsValBinds Name)    -- Extra generated top-level bindings
 210
 211 tcDeriving tycl_decls deriv_decls
 212   = recoverM (returnM ([], emptyValBindsOut)) $
 213     do  {       -- Fish the "deriving"-related information out of the TcEnv
 214                 -- and make the necessary "equations".
 215         ; (ordinary_eqns, newtype_inst_info) <- makeDerivEqns tycl_decls deriv_decls
 216
 217         ; (ordinary_inst_info, deriv_binds)
 218                 <- extendLocalInstEnv (map iSpec newtype_inst_info)  $
 219                    deriveOrdinaryStuff ordinary_eqns
 220                 -- Add the newtype-derived instances to the inst env
 221                 -- before tacking the "ordinary" ones
 222
 223         ; let inst_info = newtype_inst_info ++ ordinary_inst_info
 224
 225         -- If we are compiling a hs-boot file,
 226         -- don't generate any derived bindings
 227         ; is_boot <- tcIsHsBoot
 228         ; if is_boot then
 229                 return (inst_info, emptyValBindsOut)
 230           else do
 231         {
 232
 233         -- Generate the generic to/from functions from each type declaration
 234         ; gen_binds <- mkGenericBinds tycl_decls
 235
 236         -- Rename these extra bindings, discarding warnings about unused bindings etc
 237         -- Set -fglasgow exts so that we can have type signatures in patterns,
 238         -- which is used in the generic binds
 239         ; rn_binds
 240                 <- discardWarnings $ setOptM Opt_GlasgowExts $ do
 241                         { (rn_deriv, _dus1) <- rnTopBinds (ValBindsIn deriv_binds [])
 242                         ; (rn_gen, dus_gen) <- rnTopBinds (ValBindsIn gen_binds   [])
 243                         ; keepAliveSetTc (duDefs dus_gen)       -- Mark these guys to
 244                                                                 -- be kept alive
 245                         ; return (rn_deriv `plusHsValBinds` rn_gen) }
 246
 247
 248         ; dflags <- getDOpts
 249         ; ioToTcRn (dumpIfSet_dyn dflags Opt_D_dump_deriv "Derived instances"
 250                    (ddump_deriving inst_info rn_binds))
 251
 252         ; returnM (inst_info, rn_binds)
 253         }}
 254   where
 255     ddump_deriving :: [InstInfo] -> HsValBinds Name -> SDoc
 256     ddump_deriving inst_infos extra_binds
 257       = vcat (map pprInstInfoDetails inst_infos) $$ ppr extra_binds
 258
 259 -----------------------------------------
 260 deriveOrdinaryStuff []  -- Short cut
 261   = returnM ([], emptyLHsBinds)
 262
 263 deriveOrdinaryStuff eqns
 264   = do  {       -- Take the equation list and solve it, to deliver a list of
 265                 -- solutions, a.k.a. the contexts for the instance decls
 266                 -- required for the corresponding equations.
 267           overlap_flag <- getOverlapFlag
 268         ; inst_specs <- solveDerivEqns overlap_flag eqns
 269
 270         -- Generate the InstInfo for each dfun,
 271         -- plus any auxiliary bindings it needs
 272         ; (inst_infos, aux_binds_s) <- mapAndUnzipM genInst inst_specs
 273
 274         -- Generate any extra not-one-inst-decl-specific binds,
 275         -- notably "con2tag" and/or "tag2con" functions.
 276         ; extra_binds <- genTaggeryBinds inst_infos
 277
 278         -- Done
 279         ; returnM (map fst inst_infos,
 280                    unionManyBags (extra_binds : aux_binds_s))
 281    }
 282
 283 -----------------------------------------
 284 mkGenericBinds tycl_decls
 285   = do  { tcs <- mapM tcLookupTyCon
 286                         [ tc_name |
 287                           L _ (TyData { tcdLName = L _ tc_name }) <- tycl_decls]
 288                 -- We are only interested in the data type declarations
 289         ; return (unionManyBags [ mkTyConGenericBinds tc |
 290                                   tc <- tcs, tyConHasGenerics tc ]) }
 291                 -- And then only in the ones whose 'has-generics' flag is on
 292 \end{code}
 293
 294
 295 %************************************************************************
 296 %*                                                                      *
 297 \subsection[TcDeriv-eqns]{Forming the equations}
 298 %*                                                                      *
 299 %************************************************************************
 300
 301 @makeDerivEqns@ fishes around to find the info about needed derived
 302 instances.  Complicating factors:
 303 \begin{itemize}
 304 \item
 305 We can only derive @Enum@ if the data type is an enumeration
 306 type (all nullary data constructors).
 307
 308 \item
 309 We can only derive @Ix@ if the data type is an enumeration {\em
 310 or} has just one data constructor (e.g., tuples).
 311 \end{itemize}
 312
 313 [See Appendix~E in the Haskell~1.2 report.] This code here deals w/
 314 all those.
 315
 316 Note [Newtype deriving superclasses]
 317 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 318 The 'tys' here come from the partial application in the deriving
 319 clause. The last arg is the new instance type.
 320
 321 We must pass the superclasses; the newtype might be an instance
 322 of them in a different way than the representation type
 323 E.g.            newtype Foo a = Foo a deriving( Show, Num, Eq )
 324 Then the Show instance is not done via isomorphism; it shows
 325         Foo 3 as "Foo 3"
 326 The Num instance is derived via isomorphism, but the Show superclass
 327 dictionary must the Show instance for Foo, *not* the Show dictionary
 328 gotten from the Num dictionary. So we must build a whole new dictionary
 329 not just use the Num one.  The instance we want is something like:
 330      instance (Num a, Show (Foo a), Eq (Foo a)) => Num (Foo a) where
 331         (+) = ((+)@a)
 332         ...etc...
 333 There may be a coercion needed which we get from the tycon for the newtype
 334 when the dict is constructed in TcInstDcls.tcInstDecl2
 335
 336
 337 \begin{code}
 338 makeDerivEqns :: [LTyClDecl Name]
 339               -> [LDerivDecl Name]
 340               -> TcM ([DerivEqn],       -- Ordinary derivings
 341                       [InstInfo])       -- Special newtype derivings
 342
 343 makeDerivEqns tycl_decls deriv_decls
 344   = do  { eqns1 <- mapM deriveTyData $
 345                    [ (p,d) | d@(L _ (TyData {tcdDerivs = Just preds})) <- tycl_decls
 346                            , p <- preds ]
 347         ; eqns2 <- mapM deriveStandalone deriv_decls
 348         ; return ([eqn  | (Just eqn, _)  <- eqns1 ++ eqns2],
 349                   [inst | (_, Just inst) <- eqns1 ++ eqns2]) }
 350
 351 ------------------------------------------------------------------
 352 deriveStandalone :: LDerivDecl Name -> TcM (Maybe DerivEqn, Maybe InstInfo)
 353 -- Standalone deriving declarations
 354 --      e.g.   derive instance Show T
 355 -- Rather like tcLocalInstDecl
 356 deriveStandalone (L loc (DerivDecl deriv_ty))
 357   = setSrcSpan loc                   $
 358     addErrCtxt (standaloneCtxt deriv_ty)  $
 359     do  { (tvs, theta, tau) <- tcHsInstHead deriv_ty
 360         ; (cls, inst_tys) <- checkValidInstHead tau
 361         ; let cls_tys = take (length inst_tys - 1) inst_tys
 362               inst_ty = last inst_tys
 363
 364         ; mkEqnHelp StandAloneDerivOrigin tvs cls cls_tys inst_ty }
 365
 366 ------------------------------------------------------------------
 367 deriveTyData :: (LHsType Name, LTyClDecl Name) -> TcM (Maybe DerivEqn, Maybe InstInfo)
 368 deriveTyData (deriv_pred, L loc decl@(TyData { tcdLName = L _ tycon_name,
 369                                                tcdTyVars = tv_names,
 370                                                tcdTyPats = ty_pats }))
 371   = setSrcSpan loc                   $
 372     tcAddDeclCtxt decl               $
 373     do  { let hs_ty_args = ty_pats `orElse` map (nlHsTyVar . hsLTyVarName) tv_names
 374               hs_app     = nlHsTyConApp tycon_name hs_ty_args
 375                 -- We get kinding info for the tyvars by typechecking (T a b)
 376                 -- Hence forming a tycon application and then dis-assembling it
 377         ; (tvs, tc_app) <- tcHsQuantifiedType tv_names hs_app
 378         ; tcExtendTyVarEnv tvs $        -- Deriving preds may (now) mention
 379                                         -- the type variables for the type constructor
 380     do  { (deriv_tvs, cls, cls_tys) <- tcHsDeriv deriv_pred
 381                 -- The "deriv_pred" is a LHsType to take account of the fact that for
 382                 -- newtype deriving we allow deriving (forall a. C [a]).
 383         ; mkEqnHelp DerivOrigin (tvs++deriv_tvs) cls cls_tys tc_app } }
 384
 385 ------------------------------------------------------------------
 386 mkEqnHelp orig tvs cls cls_tys tc_app
 387   | Just (tycon, tc_args) <- tcSplitTyConApp_maybe tc_app
 388   = do  {       -- Make tc_app saturated, because that's what the
 389                 -- mkDataTypeEqn things expect
 390                 -- It might not be saturated in the standalone deriving case
 391                 --      derive instance Monad (T a)
 392           let extra_tvs = dropList tc_args (tyConTyVars tycon)
 393               full_tc_args = tc_args ++ mkTyVarTys extra_tvs
 394               full_tvs = tvs ++ extra_tvs
 395
 396         ; (rep_tc, rep_tc_args) <- tcLookupFamInst tycon full_tc_args
 397
 398         ; gla_exts <- doptM Opt_GlasgowExts
 399         ; overlap_flag <- getOverlapFlag
 400         ; if isDataTyCon tycon then
 401                 mkDataTypeEqn orig gla_exts full_tvs cls cls_tys
 402                               tycon full_tc_args rep_tc rep_tc_args
 403           else
 404                 mkNewTypeEqn  orig gla_exts overlap_flag full_tvs cls cls_tys
 405                               tycon full_tc_args rep_tc rep_tc_args }
 406   | otherwise
 407   = baleOut (derivingThingErr cls cls_tys tc_app
 408                 (ptext SLIT("Last argument of the instance must be a type application")))
 409
 410 baleOut err = addErrTc err >> returnM (Nothing, Nothing)
 411 \end{code}
 412
 413
 414 %************************************************************************
 415 %*                                                                      *
 416                 Deriving data types
 417 %*                                                                      *
 418 %************************************************************************
 419
 420 \begin{code}
 421 mkDataTypeEqn orig gla_exts tvs cls cls_tys tycon tc_args rep_tc rep_tc_args
 422   | Just err <- checkSideConditions gla_exts cls cls_tys rep_tc
 423         -- NB: pass the *representation* tycon to checkSideConditions
 424   = baleOut (derivingThingErr cls cls_tys (mkTyConApp tycon tc_args) err)
 425
 426   | otherwise
 427   = ASSERT( null cls_tys )
 428     do  { loc <- getSrcSpanM
 429         ; eqn <- mk_data_eqn loc orig tvs cls tycon tc_args rep_tc rep_tc_args
 430         ; return (Just eqn, Nothing) }
 431
 432 mk_data_eqn :: SrcSpan -> InstOrigin -> [TyVar] -> Class
 433             -> TyCon -> [TcType] -> TyCon -> [TcType] -> TcM DerivEqn
 434 mk_data_eqn loc orig tvs cls tycon tc_args rep_tc rep_tc_args
 435   | cls `hasKey` typeableClassKey
 436   =     -- The Typeable class is special in several ways
 437         --        data T a b = ... deriving( Typeable )
 438         -- gives
 439         --        instance Typeable2 T where ...
 440         -- Notice that:
 441         -- 1. There are no constraints in the instance
 442         -- 2. There are no type variables either
 443         -- 3. The actual class we want to generate isn't necessarily
 444         --      Typeable; it depends on the arity of the type
 445     do  { real_clas <- tcLookupClass (typeableClassNames !! tyConArity tycon)
 446         ; dfun_name <- new_dfun_name real_clas tycon
 447         ; return (loc, orig, dfun_name, [], real_clas, mkTyConApp tycon [], []) }
 448
 449   | otherwise
 450   = do  { dfun_name <- new_dfun_name cls tycon
 451         ; let ordinary_constraints
 452                 = [ mkClassPred cls [arg_ty]
 453                   | data_con <- tyConDataCons rep_tc,
 454                     arg_ty   <- dataConInstOrigArgTys data_con rep_tc_args,
 455                     not (isUnLiftedType arg_ty) ] -- No constraints for unlifted types?
 456
 457               tiresome_subst = zipTopTvSubst (tyConTyVars rep_tc) rep_tc_args
 458               stupid_constraints = substTheta tiresome_subst (tyConStupidTheta rep_tc)
 459                  -- see note [Data decl contexts] above
 460
 461         ; return (loc, orig, dfun_name, tvs, cls, mkTyConApp tycon tc_args,
 462                   stupid_constraints ++ ordinary_constraints)
 463         }
 464
 465 ------------------------------------------------------------------
 466 -- Check side conditions that dis-allow derivability for particular classes
 467 -- This is *apart* from the newtype-deriving mechanism
 468 --
 469 -- Here we get the representation tycon in case of family instances as it has
 470 -- the data constructors - but we need to be careful to fall back to the
 471 -- family tycon (with indexes) in error messages.
 472
 473 checkSideConditions :: Bool -> Class -> [TcType] -> TyCon -> Maybe SDoc
 474 checkSideConditions gla_exts cls cls_tys rep_tc
 475   | notNull cls_tys
 476   = Just ty_args_why    -- e.g. deriving( Foo s )
 477   | otherwise
 478   = case [cond | (key,cond) <- sideConditions, key == getUnique cls] of
 479         []     -> Just (non_std_why cls)
 480         [cond] -> cond (gla_exts, rep_tc)
 481         other  -> pprPanic "checkSideConditions" (ppr cls)
 482   where
 483     ty_args_why = quotes (ppr (mkClassPred cls cls_tys)) <+> ptext SLIT("is not a class")
 484
 485 non_std_why cls = quotes (ppr cls) <+> ptext SLIT("is not a derivable class")
 486
 487 sideConditions :: [(Unique, Condition)]
 488 sideConditions
 489   = [   (eqClassKey,       cond_std),
 490         (ordClassKey,      cond_std),
 491         (readClassKey,     cond_std),
 492         (showClassKey,     cond_std),
 493         (enumClassKey,     cond_std `andCond` cond_isEnumeration),
 494         (ixClassKey,       cond_std `andCond` (cond_isEnumeration `orCond` cond_isProduct)),
 495         (boundedClassKey,  cond_std `andCond` (cond_isEnumeration `orCond` cond_isProduct)),
 496         (typeableClassKey, cond_glaExts `andCond` cond_typeableOK),
 497         (dataClassKey,     cond_glaExts `andCond` cond_std)
 498     ]
 499
 500 type Condition = (Bool, TyCon) -> Maybe SDoc
 501         -- Bool is gla-exts flag
 502         -- TyCon is the *representation* tycon if the
 503         --      data type is an indexed one
 504         -- Nothing => OK
 505
 506 orCond :: Condition -> Condition -> Condition
 507 orCond c1 c2 tc
 508   = case c1 tc of
 509         Nothing -> Nothing              -- c1 succeeds
 510         Just x  -> case c2 tc of        -- c1 fails
 511                      Nothing -> Nothing
 512                      Just y  -> Just (x $$ ptext SLIT("  and") $$ y)
 513                                         -- Both fail
 514
 515 andCond c1 c2 tc = case c1 tc of
 516                      Nothing -> c2 tc   -- c1 succeeds
 517                      Just x  -> Just x  -- c1 fails
 518
 519 cond_std :: Condition
 520 cond_std (gla_exts, rep_tc)
 521   | any (not . isVanillaDataCon) data_cons = Just existential_why
 522   | null data_cons                         = Just no_cons_why
 523   | otherwise                              = Nothing
 524   where
 525     data_cons       = tyConDataCons rep_tc
 526     no_cons_why     = quotes (pprSourceTyCon rep_tc) <+>
 527                       ptext SLIT("has no data constructors")
 528     existential_why = quotes (pprSourceTyCon rep_tc) <+>
 529                       ptext SLIT("has non-Haskell-98 constructor(s)")
 530
 531 cond_isEnumeration :: Condition
 532 cond_isEnumeration (gla_exts, rep_tc)
 533   | isEnumerationTyCon rep_tc = Nothing
 534   | otherwise                 = Just why
 535   where
 536     why = quotes (pprSourceTyCon rep_tc) <+>
 537           ptext SLIT("has non-nullary constructors")
 538
 539 cond_isProduct :: Condition
 540 cond_isProduct (gla_exts, rep_tc)
 541   | isProductTyCon rep_tc = Nothing
 542   | otherwise             = Just why
 543   where
 544     why = (pprSourceTyCon rep_tc) <+>
 545           ptext SLIT("has more than one constructor")
 546
 547 cond_typeableOK :: Condition
 548 -- OK for Typeable class
 549 -- Currently: (a) args all of kind *
 550 --            (b) 7 or fewer args
 551 cond_typeableOK (gla_exts, rep_tc)
 552   | tyConArity rep_tc > 7       = Just too_many
 553   | not (all (isSubArgTypeKind . tyVarKind) (tyConTyVars rep_tc))
 554                                 = Just bad_kind
 555   | isFamInstTyCon rep_tc       = Just fam_inst  -- no Typable for family insts
 556   | otherwise                   = Nothing
 557   where
 558     too_many = quotes (pprSourceTyCon rep_tc) <+>
 559                ptext SLIT("has too many arguments")
 560     bad_kind = quotes (pprSourceTyCon rep_tc) <+>
 561                ptext SLIT("has arguments of kind other than `*'")
 562     fam_inst = quotes (pprSourceTyCon rep_tc) <+>
 563                ptext SLIT("is a type family")
 564
 565 cond_glaExts :: Condition
 566 cond_glaExts (gla_exts, _rep_tc) | gla_exts  = Nothing
 567                                  | otherwise = Just why
 568   where
 569     why  = ptext SLIT("You need -fglasgow-exts to derive an instance for this class")
 570
 571 std_class_via_iso clas  -- These standard classes can be derived for a newtype
 572                         -- using the isomorphism trick *even if no -fglasgow-exts*
 573   = classKey clas `elem`  [eqClassKey, ordClassKey, ixClassKey, boundedClassKey]
 574         -- Not Read/Show because they respect the type
 575         -- Not Enum, because newtypes are never in Enum
 576
 577
 578 new_dfun_name clas tycon        -- Just a simple wrapper
 579   = newDFunName clas [mkTyConApp tycon []] (getSrcLoc tycon)
 580         -- The type passed to newDFunName is only used to generate
 581         -- a suitable string; hence the empty type arg list
 582 \end{code}
 583
 584
 585 %************************************************************************
 586 %*                                                                      *
 587                 Deriving newtypes
 588 %*                                                                      *
 589 %************************************************************************
 590
 591 \begin{code}
 592 mkNewTypeEqn orig gla_exts overlap_flag tvs cls cls_tys
 593              tycon tc_args
 594              rep_tycon rep_tc_args
 595   | can_derive_via_isomorphism && (gla_exts || std_class_via_iso cls)
 596   = do  { traceTc (text "newtype deriving:" <+> ppr tycon <+> ppr rep_tys)
 597         ;       -- Go ahead and use the isomorphism
 598            dfun_name <- new_dfun_name cls tycon
 599         ; return (Nothing, Just (InstInfo { iSpec  = mk_inst_spec dfun_name,
 600                                             iBinds = NewTypeDerived ntd_info })) }
 601
 602   | isNothing mb_std_err        -- Use the standard H98 method
 603   = do  { loc <- getSrcSpanM
 604         ; eqn <- mk_data_eqn loc orig tvs cls tycon tc_args rep_tycon rep_tc_args
 605         ; return (Just eqn, Nothing) }
 606
 607         -- Otherwise we can't derive
 608   | gla_exts  = baleOut cant_derive_err -- Too hard
 609   | otherwise = baleOut std_err         -- Just complain about being a non-std instance
 610   where
 611         mb_std_err = checkSideConditions gla_exts cls cls_tys rep_tycon
 612         std_err = derivingThingErr cls cls_tys tc_app $
 613                   vcat [fromJust mb_std_err,
 614                         ptext SLIT("Try -fglasgow-exts for GHC's newtype-deriving extension")]
 615
 616         -- Here is the plan for newtype derivings.  We see
 617         --        newtype T a1...an = MkT (t ak+1...an) deriving (.., C s1 .. sm, ...)
 618         -- where t is a type,
 619         --       ak+1...an is a suffix of a1..an, and are all tyars
 620         --       ak+1...an do not occur free in t, nor in the s1..sm
 621         --       (C s1 ... sm) is a  *partial applications* of class C
 622         --                      with the last parameter missing
 623         --       (T a1 .. ak) matches the kind of C's last argument
 624         --              (and hence so does t)
 625         --
 626         -- We generate the instance
 627         --       instance forall ({a1..ak} u fvs(s1..sm)).
 628         --                C s1 .. sm t => C s1 .. sm (T a1...ak)
 629         -- where T a1...ap is the partial application of
 630         --       the LHS of the correct kind and p >= k
 631         --
 632         --      NB: the variables below are:
 633         --              tc_tvs = [a1, ..., an]
 634         --              tyvars_to_keep = [a1, ..., ak]
 635         --              rep_ty = t ak .. an
 636         --              deriv_tvs = fvs(s1..sm) \ tc_tvs
 637         --              tys = [s1, ..., sm]
 638         --              rep_fn' = t
 639         --
 640         -- Running example: newtype T s a = MkT (ST s a) deriving( Monad )
 641         -- We generate the instance
 642         --      instance Monad (ST s) => Monad (T s) where
 643
 644         cls_tyvars = classTyVars cls
 645         kind = tyVarKind (last cls_tyvars)
 646                 -- Kind of the thing we want to instance
 647                 --   e.g. argument kind of Monad, *->*
 648
 649         (arg_kinds, _) = splitKindFunTys kind
 650         n_args_to_drop = length arg_kinds
 651                 -- Want to drop 1 arg from (T s a) and (ST s a)
 652                 -- to get       instance Monad (ST s) => Monad (T s)
 653
 654         -- Note [newtype representation]
 655         -- Need newTyConRhs *not* newTyConRep to get the representation
 656         -- type, because the latter looks through all intermediate newtypes
 657         -- For example
 658         --      newtype B = MkB Int
 659         --      newtype A = MkA B deriving( Num )
 660         -- We want the Num instance of B, *not* the Num instance of Int,
 661         -- when making the Num instance of A!
 662         rep_ty                = newTyConInstRhs rep_tycon rep_tc_args
 663         (rep_fn, rep_ty_args) = tcSplitAppTys rep_ty
 664
 665         n_tyargs_to_keep = tyConArity tycon - n_args_to_drop
 666         dropped_tc_args = drop n_tyargs_to_keep tc_args
 667         dropped_tvs     = tyVarsOfTypes dropped_tc_args
 668
 669         n_args_to_keep = length rep_ty_args - n_args_to_drop
 670         args_to_drop   = drop n_args_to_keep rep_ty_args
 671         args_to_keep   = take n_args_to_keep rep_ty_args
 672
 673         rep_fn'  = mkAppTys rep_fn args_to_keep
 674         rep_tys  = cls_tys ++ [rep_fn']
 675         rep_pred = mkClassPred cls rep_tys
 676                 -- rep_pred is the representation dictionary, from where
 677                 -- we are gong to get all the methods for the newtype
 678                 -- dictionary
 679
 680         tc_app = mkTyConApp tycon (take n_tyargs_to_keep tc_args)
 681
 682     -- Next we figure out what superclass dictionaries to use
 683     -- See Note [Newtype deriving superclasses] above
 684
 685         inst_tys = cls_tys ++ [tc_app]
 686         sc_theta = substTheta (zipOpenTvSubst cls_tyvars inst_tys)
 687                               (classSCTheta cls)
 688
 689                 -- If there are no tyvars, there's no need
 690                 -- to abstract over the dictionaries we need
 691                 -- Example:     newtype T = MkT Int deriving( C )
 692                 -- We get the derived instance
 693                 --              instance C T
 694                 -- rather than
 695                 --              instance C Int => C T
 696         dict_tvs = filterOut (`elemVarSet` dropped_tvs) tvs
 697         all_preds = rep_pred : sc_theta         -- NB: rep_pred comes first
 698         (dict_args, ntd_info) | null dict_tvs = ([], Just all_preds)
 699                               | otherwise     = (all_preds, Nothing)
 700
 701                 -- Finally! Here's where we build the dictionary Id
 702         mk_inst_spec dfun_name = mkLocalInstance dfun overlap_flag
 703           where
 704             dfun = mkDictFunId dfun_name dict_tvs dict_args cls inst_tys
 705
 706         -------------------------------------------------------------------
 707         --  Figuring out whether we can only do this newtype-deriving thing
 708
 709         right_arity = length cls_tys + 1 == classArity cls
 710
 711                 -- Never derive Read,Show,Typeable,Data this way
 712         non_iso_classes = [readClassKey, showClassKey, typeableClassKey, dataClassKey]
 713         can_derive_via_isomorphism
 714            =  not (getUnique cls `elem` non_iso_classes)
 715            && right_arity                       -- Well kinded;
 716                                                 -- eg not: newtype T ... deriving( ST )
 717                                                 --      because ST needs *2* type params
 718            && n_tyargs_to_keep >= 0             -- Type constructor has right kind:
 719                                                 -- eg not: newtype T = T Int deriving( Monad )
 720            && n_args_to_keep   >= 0             -- Rep type has right kind:
 721                                                 -- eg not: newtype T a = T Int deriving( Monad )
 722            && eta_ok                            -- Eta reduction works
 723            && not (isRecursiveTyCon tycon)      -- Does not work for recursive tycons:
 724                                                 --      newtype A = MkA [A]
 725                                                 -- Don't want
 726                                                 --      instance Eq [A] => Eq A !!
 727                         -- Here's a recursive newtype that's actually OK
 728                         --      newtype S1 = S1 [T1 ()]
 729                         --      newtype T1 a = T1 (StateT S1 IO a ) deriving( Monad )
 730                         -- It's currently rejected.  Oh well.
 731                         -- In fact we generate an instance decl that has method of form
 732                         --      meth @ instTy = meth @ repTy
 733                         -- (no coerce's).  We'd need a coerce if we wanted to handle
 734                         -- recursive newtypes too
 735
 736         -- Check that eta reduction is OK
 737         eta_ok = (args_to_drop `tcEqTypes` dropped_tc_args)
 738                 -- (a) the dropped-off args are identical in the source and rep type
 739                 --        newtype T a b = MkT (S [a] b) deriving( Monad )
 740                 --     Here the 'b' must be the same in the rep type (S [a] b)
 741
 742               && (tyVarsOfType rep_fn' `disjointVarSet` dropped_tvs)
 743                 -- (b) the remaining type args do not mention any of the dropped
 744                 --     type variables
 745
 746               && (tyVarsOfTypes cls_tys `disjointVarSet` dropped_tvs)
 747                 -- (c) the type class args do not mention any of the dropped type
 748                 --     variables
 749
 750               && all isTyVarTy dropped_tc_args
 751                 -- (d) in case of newtype family instances, the eta-dropped
 752                 --      arguments must be type variables (not more complex indexes)
 753
 754         cant_derive_err = derivingThingErr cls cls_tys tc_app
 755                                 (vcat [ptext SLIT("even with cunning newtype deriving:"),
 756                                         if isRecursiveTyCon tycon then
 757                                           ptext SLIT("the newtype may be recursive")
 758                                         else empty,
 759                                         if not right_arity then
 760                                           quotes (ppr (mkClassPred cls cls_tys)) <+> ptext SLIT("does not have arity 1")
 761                                         else empty,
 762                                         if not (n_tyargs_to_keep >= 0) then
 763                                           ptext SLIT("the type constructor has wrong kind")
 764                                         else if not (n_args_to_keep >= 0) then
 765                                           ptext SLIT("the representation type has wrong kind")
 766                                         else if not eta_ok then
 767                                           ptext SLIT("the eta-reduction property does not hold")
 768                                         else empty
 769                                       ])
 770 \end{code}
 771
 772
 773 %************************************************************************
 774 %*                                                                      *
 775 \subsection[TcDeriv-fixpoint]{Finding the fixed point of \tr{deriving} equations}
 776 %*                                                                      *
 777 %************************************************************************
 778
 779 A ``solution'' (to one of the equations) is a list of (k,TyVarTy tv)
 780 terms, which is the final correct RHS for the corresponding original
 781 equation.
 782 \begin{itemize}
 783 \item
 784 Each (k,TyVarTy tv) in a solution constrains only a type
 785 variable, tv.
 786
 787 \item
 788 The (k,TyVarTy tv) pairs in a solution are canonically
 789 ordered by sorting on type varible, tv, (major key) and then class, k,
 790 (minor key)
 791 \end{itemize}
 792
 793 \begin{code}
 794 solveDerivEqns :: OverlapFlag
 795                -> [DerivEqn]
 796                -> TcM [Instance]-- Solns in same order as eqns.
 797                                 -- This bunch is Absolutely minimal...
 798
 799 solveDerivEqns overlap_flag orig_eqns
 800   = do  { traceTc (text "solveDerivEqns" <+> vcat (map pprDerivEqn orig_eqns))
 801         ; iterateDeriv 1 initial_solutions }
 802   where
 803         -- The initial solutions for the equations claim that each
 804         -- instance has an empty context; this solution is certainly
 805         -- in canonical form.
 806     initial_solutions :: [DerivSoln]
 807     initial_solutions = [ [] | _ <- orig_eqns ]
 808
 809     ------------------------------------------------------------------
 810         -- iterateDeriv calculates the next batch of solutions,
 811         -- compares it with the current one; finishes if they are the
 812         -- same, otherwise recurses with the new solutions.
 813         -- It fails if any iteration fails
 814     iterateDeriv :: Int -> [DerivSoln] -> TcM [Instance]
 815     iterateDeriv n current_solns
 816       | n > 20  -- Looks as if we are in an infinite loop
 817                 -- This can happen if we have -fallow-undecidable-instances
 818                 -- (See TcSimplify.tcSimplifyDeriv.)
 819       = pprPanic "solveDerivEqns: probable loop"
 820                  (vcat (map pprDerivEqn orig_eqns) $$ ppr current_solns)
 821       | otherwise
 822       = let
 823             inst_specs = zipWithEqual "add_solns" mk_inst_spec
 824                                       orig_eqns current_solns
 825         in
 826         checkNoErrs (
 827                   -- Extend the inst info from the explicit instance decls
 828                   -- with the current set of solutions, and simplify each RHS
 829             extendLocalInstEnv inst_specs $
 830             mappM gen_soln orig_eqns
 831         )                               `thenM` \ new_solns ->
 832         if (current_solns == new_solns) then
 833             returnM inst_specs
 834         else
 835             iterateDeriv (n+1) new_solns
 836
 837     ------------------------------------------------------------------
 838     gen_soln :: DerivEqn -> TcM [PredType]
 839     gen_soln (loc, orig, _, tyvars, clas, inst_ty, deriv_rhs)
 840       = setSrcSpan loc  $
 841         do { theta <- tcSimplifyDeriv orig tyvars deriv_rhs
 842            ; addErrCtxt (derivInstCtxt theta clas [inst_ty]) $
 843         do { checkNoErrs (checkValidInstance tyvars theta clas [inst_ty])
 844                 -- See Note [Deriving context]
 845                 -- If this fails, don't continue
 846
 847                   -- Check for a bizarre corner case, when the derived instance decl should
 848                   -- have form  instance C a b => D (T a) where ...
 849                   -- Note that 'b' isn't a parameter of T.  This gives rise to all sorts
 850                   -- of problems; in particular, it's hard to compare solutions for
 851                   -- equality when finding the fixpoint.  So I just rule it out for now.
 852            ; let tv_set = mkVarSet tyvars
 853                  weird_preds = [pred | pred <- theta, not (tyVarsOfPred pred `subVarSet` tv_set)]
 854            ; mapM_ (addErrTc . badDerivedPred) weird_preds
 855
 856                 -- Claim: the result instance declaration is guaranteed valid
 857                 -- Hence no need to call:
 858                 --   checkValidInstance tyvars theta clas inst_tys
 859            ; return (sortLe (<=) theta) } }     -- Canonicalise before returning the solution
 860
 861     ------------------------------------------------------------------
 862     mk_inst_spec :: DerivEqn -> DerivSoln -> Instance
 863     mk_inst_spec (loc, orig, dfun_name, tyvars, clas, inst_ty, _) theta
 864         = mkLocalInstance dfun overlap_flag
 865         where
 866           dfun = mkDictFunId dfun_name tyvars theta clas [inst_ty]
 867
 868 extendLocalInstEnv :: [Instance] -> TcM a -> TcM a
 869 -- Add new locally-defined instances; don't bother to check
 870 -- for functional dependency errors -- that'll happen in TcInstDcls
 871 extendLocalInstEnv dfuns thing_inside
 872  = do { env <- getGblEnv
 873       ; let  inst_env' = extendInstEnvList (tcg_inst_env env) dfuns
 874              env'      = env { tcg_inst_env = inst_env' }
 875       ; setGblEnv env' thing_inside }
 876 \end{code}
 877
 878 Note [Deriving context]
 879 ~~~~~~~~~~~~~~~~~~~~~~~
 880 With -fglasgow-exts, we allow things like (C Int a) in the simplified
 881 context for a derived instance declaration, because at a use of this
 882 instance, we might know that a=Bool, and have an instance for (C Int
 883 Bool)
 884
 885 We nevertheless insist that each predicate meets the termination
 886 conditions. If not, the deriving mechanism generates larger and larger
 887 constraints.  Example:
 888   data Succ a = S a
 889   data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
 890
 891 Note the lack of a Show instance for Succ.  First we'll generate
 892   instance (Show (Succ a), Show a) => Show (Seq a)
 893 and then
 894   instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
 895 and so on.  Instead we want to complain of no instance for (Show (Succ a)).
 896
 897
 898 %************************************************************************
 899 %*                                                                      *
 900 \subsection[TcDeriv-normal-binds]{Bindings for the various classes}
 901 %*                                                                      *
 902 %************************************************************************
 903
 904 After all the trouble to figure out the required context for the
 905 derived instance declarations, all that's left is to chug along to
 906 produce them.  They will then be shoved into @tcInstDecls2@, which
 907 will do all its usual business.
 908
 909 There are lots of possibilities for code to generate.  Here are
 910 various general remarks.
 911
 912 PRINCIPLES:
 913 \begin{itemize}
 914 \item
 915 We want derived instances of @Eq@ and @Ord@ (both v common) to be
 916 ``you-couldn't-do-better-by-hand'' efficient.
 917
 918 \item
 919 Deriving @Show@---also pretty common--- should also be reasonable good code.
 920
 921 \item
 922 Deriving for the other classes isn't that common or that big a deal.
 923 \end{itemize}
 924
 925 PRAGMATICS:
 926
 927 \begin{itemize}
 928 \item
 929 Deriving @Ord@ is done mostly with the 1.3 @compare@ method.
 930
 931 \item
 932 Deriving @Eq@ also uses @compare@, if we're deriving @Ord@, too.
 933
 934 \item
 935 We {\em normally} generate code only for the non-defaulted methods;
 936 there are some exceptions for @Eq@ and (especially) @Ord@...
 937
 938 \item
 939 Sometimes we use a @_con2tag_<tycon>@ function, which returns a data
 940 constructor's numeric (@Int#@) tag.  These are generated by
 941 @gen_tag_n_con_binds@, and the heuristic for deciding if one of
 942 these is around is given by @hasCon2TagFun@.
 943
 944 The examples under the different sections below will make this
 945 clearer.
 946
 947 \item
 948 Much less often (really just for deriving @Ix@), we use a
 949 @_tag2con_<tycon>@ function.  See the examples.
 950
 951 \item
 952 We use the renamer!!!  Reason: we're supposed to be
 953 producing @LHsBinds Name@ for the methods, but that means
 954 producing correctly-uniquified code on the fly.  This is entirely
 955 possible (the @TcM@ monad has a @UniqueSupply@), but it is painful.
 956 So, instead, we produce @MonoBinds RdrName@ then heave 'em through
 957 the renamer.  What a great hack!
 958 \end{itemize}
 959
 960 \begin{code}
 961 -- Generate the InstInfo for the required instance paired with the
 962 --   *representation* tycon for that instance,
 963 -- plus any auxiliary bindings required
 964 --
 965 -- Representation tycons differ from the tycon in the instance signature in
 966 -- case of instances for indexed families.
 967 --
 968 genInst :: Instance -> TcM ((InstInfo, TyCon), LHsBinds RdrName)
 969 genInst spec
 970   = do  { fix_env <- getFixityEnv
 971         ; let
 972             (tyvars,_,clas,[ty])    = instanceHead spec
 973             clas_nm                 = className clas
 974             (visible_tycon, tyArgs) = tcSplitTyConApp ty
 975
 976           -- In case of a family instance, we need to use the representation
 977           -- tycon (after all, it has the data constructors)
 978         ; (tycon, _) <- tcLookupFamInst visible_tycon tyArgs
 979         ; let (meth_binds, aux_binds) = genDerivBinds clas fix_env tycon
 980
 981         -- Bring the right type variables into
 982         -- scope, and rename the method binds
 983         -- It's a bit yukky that we return *renamed* InstInfo, but
 984         -- *non-renamed* auxiliary bindings
 985         ; (rn_meth_binds, _fvs) <- discardWarnings $
 986                                    bindLocalNames (map Var.varName tyvars) $
 987                                    rnMethodBinds clas_nm (\n -> []) [] meth_binds
 988
 989         -- Build the InstInfo
 990         ; return ((InstInfo { iSpec = spec,
 991                               iBinds = VanillaInst rn_meth_binds [] }, tycon),
 992                   aux_binds)
 993         }
 994
 995 genDerivBinds clas fix_env tycon
 996   | className clas `elem` typeableClassNames
 997   = (gen_Typeable_binds tycon, emptyLHsBinds)
 998
 999   | otherwise
1000   = case assocMaybe gen_list (getUnique clas) of
1001         Just gen_fn -> gen_fn fix_env tycon
1002         Nothing     -> pprPanic "genDerivBinds: bad derived class" (ppr clas)
1003   where
1004     gen_list :: [(Unique, FixityEnv -> TyCon -> (LHsBinds RdrName, LHsBinds RdrName))]
1005     gen_list = [(eqClassKey,      no_aux_binds (ignore_fix_env gen_Eq_binds))
1006                ,(ordClassKey,     no_aux_binds (ignore_fix_env gen_Ord_binds))
1007                ,(enumClassKey,    no_aux_binds (ignore_fix_env gen_Enum_binds))
1008                ,(boundedClassKey, no_aux_binds (ignore_fix_env gen_Bounded_binds))
1009                ,(ixClassKey,      no_aux_binds (ignore_fix_env gen_Ix_binds))
1010                ,(typeableClassKey,no_aux_binds (ignore_fix_env gen_Typeable_binds))
1011                ,(showClassKey,    no_aux_binds gen_Show_binds)
1012                ,(readClassKey,    no_aux_binds gen_Read_binds)
1013                ,(dataClassKey,    gen_Data_binds)
1014                ]
1015
1016       -- no_aux_binds is used for generators that don't
1017       -- need to produce any auxiliary bindings
1018     no_aux_binds f fix_env tc = (f fix_env tc, emptyLHsBinds)
1019     ignore_fix_env f fix_env tc = f tc
1020 \end{code}
1021
1022
1023 %************************************************************************
1024 %*                                                                      *
1025 \subsection[TcDeriv-taggery-Names]{What con2tag/tag2con functions are available?}
1026 %*                                                                      *
1027 %************************************************************************
1028
1029
1030 data Foo ... = ...
1031
1032 con2tag_Foo :: Foo ... -> Int#
1033 tag2con_Foo :: Int -> Foo ...   -- easier if Int, not Int#
1034 maxtag_Foo  :: Int              -- ditto (NB: not unlifted)
1035
1036
1037 We have a @con2tag@ function for a tycon if:
1038 \begin{itemize}
1039 \item
1040 We're deriving @Eq@ and the tycon has nullary data constructors.
1041
1042 \item
1043 Or: we're deriving @Ord@ (unless single-constructor), @Enum@, @Ix@
1044 (enum type only????)
1045 \end{itemize}
1046
1047 We have a @tag2con@ function for a tycon if:
1048 \begin{itemize}
1049 \item
1050 We're deriving @Enum@, or @Ix@ (enum type only???)
1051 \end{itemize}
1052
1053 If we have a @tag2con@ function, we also generate a @maxtag@ constant.
1054
1055 \begin{code}
1056 genTaggeryBinds :: [(InstInfo, TyCon)] -> TcM (LHsBinds RdrName)
1057 genTaggeryBinds infos
1058   = do  { names_so_far <- foldlM do_con2tag []           tycons_of_interest
1059         ; nm_alist_etc <- foldlM do_tag2con names_so_far tycons_of_interest
1060         ; return (listToBag (map gen_tag_n_con_monobind nm_alist_etc)) }
1061   where
1062     all_CTs                 = [ (fst (simpleInstInfoClsTy info), tc)
1063                               | (info, tc) <- infos]
1064     all_tycons              = map snd all_CTs
1065     (tycons_of_interest, _) = removeDups compare all_tycons
1066
1067     do_con2tag acc_Names tycon
1068       | isDataTyCon tycon &&
1069         ((we_are_deriving eqClassKey tycon
1070             && any isNullarySrcDataCon (tyConDataCons tycon))
1071          || (we_are_deriving ordClassKey  tycon
1072             && not (isProductTyCon tycon))
1073          || (we_are_deriving enumClassKey tycon)
1074          || (we_are_deriving ixClassKey   tycon))
1075
1076       = returnM ((con2tag_RDR tycon, tycon, GenCon2Tag)
1077                    : acc_Names)
1078       | otherwise
1079       = returnM acc_Names
1080
1081     do_tag2con acc_Names tycon
1082       | isDataTyCon tycon &&
1083          (we_are_deriving enumClassKey tycon ||
1084           we_are_deriving ixClassKey   tycon
1085           && isEnumerationTyCon tycon)
1086       = returnM ( (tag2con_RDR tycon, tycon, GenTag2Con)
1087                  : (maxtag_RDR  tycon, tycon, GenMaxTag)
1088                  : acc_Names)
1089       | otherwise
1090       = returnM acc_Names
1091
1092     we_are_deriving clas_key tycon
1093       = is_in_eqns clas_key tycon all_CTs
1094       where
1095         is_in_eqns clas_key tycon [] = False
1096         is_in_eqns clas_key tycon ((c,t):cts)
1097           =  (clas_key == classKey c && tycon == t)
1098           || is_in_eqns clas_key tycon cts
1099 \end{code}
1100
1101 \begin{code}
1102 derivingThingErr clas tys ty why
1103   = sep [hsep [ptext SLIT("Can't make a derived instance of"),
1104                quotes (ppr pred)],
1105          nest 2 (parens why)]
1106   where
1107     pred = mkClassPred clas (tys ++ [ty])
1108
1109 standaloneCtxt :: LHsType Name -> SDoc
1110 standaloneCtxt ty = ptext SLIT("In the stand-alone deriving instance for") <+> quotes (ppr ty)
1111
1112 derivInstCtxt theta clas inst_tys
1113   = hang (ptext SLIT("In the derived instance:"))
1114          2 (pprThetaArrow theta <+> pprClassPred clas inst_tys)
1115 -- Used for the ...Thetas variants; all top level
1116
1117 badDerivedPred pred
1118   = vcat [ptext SLIT("Can't derive instances where the instance context mentions"),
1119           ptext SLIT("type variables that are not data type parameters"),
1120           nest 2 (ptext SLIT("Offending constraint:") <+> ppr pred)]
1121 \end{code}
1122
1123