compiler/typecheck/TcEnv.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 %
   4
   5 \begin{code}
   6 module TcEnv(
   7         TyThing(..), TcTyThing(..), TcId,
   8
   9         -- Instance environment, and InstInfo type
  10         InstInfo(..), iDFunId, pprInstInfo, pprInstInfoDetails,
  11         simpleInstInfoClsTy, simpleInstInfoTy, simpleInstInfoTyCon,
  12         InstBindings(..),
  13
  14         -- Global environment
  15         tcExtendGlobalEnv, setGlobalTypeEnv,
  16         tcExtendGlobalValEnv,
  17         tcLookupLocatedGlobal,  tcLookupGlobal,
  18         tcLookupField, tcLookupTyCon, tcLookupClass, tcLookupDataCon,
  19         tcLookupLocatedGlobalId, tcLookupLocatedTyCon,
  20         tcLookupLocatedClass, tcLookupFamInst,
  21
  22         -- Local environment
  23         tcExtendKindEnv, tcExtendKindEnvTvs,
  24         tcExtendTyVarEnv, tcExtendTyVarEnv2,
  25         tcExtendGhciEnv,
  26         tcExtendIdEnv, tcExtendIdEnv1, tcExtendIdEnv2,
  27         tcLookup, tcLookupLocated, tcLookupLocalIds,
  28         tcLookupId, tcLookupTyVar, getScopedTyVarBinds,
  29         lclEnvElts, getInLocalScope, findGlobals,
  30         wrongThingErr, pprBinders,
  31
  32         tcExtendRecEnv,         -- For knot-tying
  33
  34         -- Rules
  35         tcExtendRules,
  36
  37         -- Global type variables
  38         tcGetGlobalTyVars,
  39
  40         -- Template Haskell stuff
  41         checkWellStaged, spliceOK, bracketOK, tcMetaTy, thLevel,
  42         topIdLvl, thTopLevelId,
  43
  44         -- New Ids
  45         newLocalName, newDFunName, newFamInstTyConName,
  46         mkStableIdFromString, mkStableIdFromName
  47   ) where
  48
  49 #include "HsVersions.h"
  50
  51 import HsSyn
  52 import TcIface
  53 import IfaceEnv
  54 import TcRnMonad
  55 import TcMType
  56 import TcType
  57 -- import TcSuspension
  58 import qualified Type
  59 import Id
  60 import Var
  61 import VarSet
  62 import VarEnv
  63 import RdrName
  64 import InstEnv
  65 import FamInstEnv
  66 import DataCon
  67 import TyCon
  68 import TypeRep
  69 import Class
  70 import Name
  71 import PrelNames
  72 import NameEnv
  73 import OccName
  74 import HscTypes
  75 import SrcLoc
  76 import Outputable
  77 import Maybes
  78 import Unique
  79 import FastString
  80 \end{code}
  81
  82
  83 %************************************************************************
  84 %*                                                                      *
  85 %*                      tcLookupGlobal                                  *
  86 %*                                                                      *
  87 %************************************************************************
  88
  89 Using the Located versions (eg. tcLookupLocatedGlobal) is preferred,
  90 unless you know that the SrcSpan in the monad is already set to the
  91 span of the Name.
  92
  93 \begin{code}
  94 tcLookupLocatedGlobal :: Located Name -> TcM TyThing
  95 -- c.f. IfaceEnvEnv.tcIfaceGlobal
  96 tcLookupLocatedGlobal name
  97   = addLocM tcLookupGlobal name
  98
  99 tcLookupGlobal :: Name -> TcM TyThing
 100 -- The Name is almost always an ExternalName, but not always
 101 -- In GHCi, we may make command-line bindings (ghci> let x = True)
 102 -- that bind a GlobalId, but with an InternalName
 103 tcLookupGlobal name
 104   = do  { env <- getGblEnv
 105
 106                 -- Try local envt
 107         ; case lookupNameEnv (tcg_type_env env) name of {
 108                 Just thing -> return thing ;
 109                 Nothing    -> do
 110
 111                 -- Try global envt
 112         { hsc_env <- getTopEnv
 113         ; mb_thing <- liftIO (lookupTypeHscEnv hsc_env name)
 114         ; case mb_thing of  {
 115             Just thing -> return thing ;
 116             Nothing    -> do
 117
 118                 -- Should it have been in the local envt?
 119         { case nameModule_maybe name of
 120                 Nothing -> notFound name env -- Internal names can happen in GHCi
 121
 122                 Just mod | mod == tcg_mod env   -- Names from this module
 123                          -> notFound name env -- should be in tcg_type_env
 124                          | mod == thFAKE        -- Names bound in TH declaration brackets
 125                          -> notFound name env -- should be in tcg_env
 126                          | otherwise
 127                          -> tcImportDecl name   -- Go find it in an interface
 128         }}}}}
 129
 130 tcLookupField :: Name -> TcM Id         -- Returns the selector Id
 131 tcLookupField name = do
 132     thing <- tcLookup name      -- Note [Record field lookup]
 133     case thing of
 134         AGlobal (AnId id) -> return id
 135         thing -> wrongThingErr "field name" thing name
 136
 137 {- Note [Record field lookup]
 138    ~~~~~~~~~~~~~~~~~~~~~~~~~~
 139 You might think we should have tcLookupGlobal here, since record fields
 140 are always top level.  But consider
 141         f = e { f = True }
 142 Then the renamer (which does not keep track of what is a record selector
 143 and what is not) will rename the definition thus
 144         f_7 = e { f_7 = True }
 145 Now the type checker will find f_7 in the *local* type environment, not
 146 the global one. It's wrong, of course, but we want to report a tidy
 147 error, not in TcEnv.notFound.  -}
 148
 149 tcLookupDataCon :: Name -> TcM DataCon
 150 tcLookupDataCon name = do
 151     thing <- tcLookupGlobal name
 152     case thing of
 153         ADataCon con -> return con
 154         _            -> wrongThingErr "data constructor" (AGlobal thing) name
 155
 156 tcLookupClass :: Name -> TcM Class
 157 tcLookupClass name = do
 158     thing <- tcLookupGlobal name
 159     case thing of
 160         AClass cls -> return cls
 161         _          -> wrongThingErr "class" (AGlobal thing) name
 162
 163 tcLookupTyCon :: Name -> TcM TyCon
 164 tcLookupTyCon name = do
 165     thing <- tcLookupGlobal name
 166     case thing of
 167         ATyCon tc -> return tc
 168         _         -> wrongThingErr "type constructor" (AGlobal thing) name
 169
 170 tcLookupLocatedGlobalId :: Located Name -> TcM Id
 171 tcLookupLocatedGlobalId = addLocM tcLookupId
 172
 173 tcLookupLocatedClass :: Located Name -> TcM Class
 174 tcLookupLocatedClass = addLocM tcLookupClass
 175
 176 tcLookupLocatedTyCon :: Located Name -> TcM TyCon
 177 tcLookupLocatedTyCon = addLocM tcLookupTyCon
 178
 179 -- Look up the instance tycon of a family instance.
 180 --
 181 -- The match must be unique - ie, match exactly one instance - but the
 182 -- type arguments used for matching may be more specific than those of
 183 -- the family instance declaration.
 184 --
 185 -- Return the instance tycon and its type instance.  For example, if we have
 186 --
 187 --  tcLookupFamInst 'T' '[Int]' yields (':R42T', 'Int')
 188 --
 189 -- then we have a coercion (ie, type instance of family instance coercion)
 190 --
 191 --  :Co:R42T Int :: T [Int] ~ :R42T Int
 192 --
 193 -- which implies that :R42T was declared as 'data instance T [a]'.
 194 --
 195 tcLookupFamInst :: TyCon -> [Type] -> TcM (Maybe (TyCon, [Type]))
 196 tcLookupFamInst tycon tys
 197   | not (isOpenTyCon tycon)
 198   = return Nothing
 199   | otherwise
 200   = do { env <- getGblEnv
 201        ; eps <- getEps
 202        ; let instEnv = (eps_fam_inst_env eps, tcg_fam_inst_env env)
 203        ; case lookupFamInstEnv instEnv tycon tys of
 204            [(fam_inst, rep_tys)] -> return $ Just (famInstTyCon fam_inst,
 205                                                    rep_tys)
 206            _                     -> return Nothing
 207        }
 208 \end{code}
 209
 210 %************************************************************************
 211 %*                                                                      *
 212                 Extending the global environment
 213 %*                                                                      *
 214 %************************************************************************
 215
 216
 217 \begin{code}
 218 setGlobalTypeEnv :: TcGblEnv -> TypeEnv -> TcM TcGblEnv
 219 -- Use this to update the global type env
 220 -- It updates both  * the normal tcg_type_env field
 221 --                  * the tcg_type_env_var field seen by interface files
 222 setGlobalTypeEnv tcg_env new_type_env
 223   = do  {     -- Sync the type-envt variable seen by interface files
 224            writeMutVar (tcg_type_env_var tcg_env) new_type_env
 225          ; return (tcg_env { tcg_type_env = new_type_env }) }
 226
 227 tcExtendGlobalEnv :: [TyThing] -> TcM r -> TcM r
 228   -- Given a mixture of Ids, TyCons, Classes, all from the
 229   -- module being compiled, extend the global environment
 230 tcExtendGlobalEnv things thing_inside
 231    = do { tcg_env <- getGblEnv
 232         ; let ge'  = extendTypeEnvList (tcg_type_env tcg_env) things
 233         ; tcg_env' <- setGlobalTypeEnv tcg_env ge'
 234         ; setGblEnv tcg_env' thing_inside }
 235
 236 tcExtendGlobalValEnv :: [Id] -> TcM a -> TcM a
 237   -- Same deal as tcExtendGlobalEnv, but for Ids
 238 tcExtendGlobalValEnv ids thing_inside
 239   = tcExtendGlobalEnv [AnId id | id <- ids] thing_inside
 240
 241 tcExtendRecEnv :: [(Name,TyThing)] -> TcM r -> TcM r
 242 -- Extend the global environments for the type/class knot tying game
 243 -- Just like tcExtendGlobalEnv, except the argument is a list of pairs
 244 tcExtendRecEnv gbl_stuff thing_inside
 245  = do  { tcg_env <- getGblEnv
 246        ; let ge' = extendNameEnvList (tcg_type_env tcg_env) gbl_stuff
 247        ; tcg_env' <- setGlobalTypeEnv tcg_env ge'
 248        ; setGblEnv tcg_env' thing_inside }
 249 \end{code}
 250
 251
 252 %************************************************************************
 253 %*                                                                      *
 254 \subsection{The local environment}
 255 %*                                                                      *
 256 %************************************************************************
 257
 258 \begin{code}
 259 tcLookupLocated :: Located Name -> TcM TcTyThing
 260 tcLookupLocated = addLocM tcLookup
 261
 262 tcLookup :: Name -> TcM TcTyThing
 263 tcLookup name = do
 264     local_env <- getLclEnv
 265     case lookupNameEnv (tcl_env local_env) name of
 266         Just thing -> return thing
 267         Nothing    -> AGlobal <$> tcLookupGlobal name
 268
 269 tcLookupTyVar :: Name -> TcM TcTyVar
 270 tcLookupTyVar name = do
 271     thing <- tcLookup name
 272     case thing of
 273         ATyVar _ ty -> return (tcGetTyVar "tcLookupTyVar" ty)
 274         _           -> pprPanic "tcLookupTyVar" (ppr name)
 275
 276 tcLookupId :: Name -> TcM Id
 277 -- Used when we aren't interested in the binding level, nor refinement.
 278 -- The "no refinement" part means that we return the un-refined Id regardless
 279 --
 280 -- The Id is never a DataCon. (Why does that matter? see TcExpr.tcId)
 281 tcLookupId name = do
 282     thing <- tcLookup name
 283     case thing of
 284         ATcId { tct_id = id} -> return id
 285         AGlobal (AnId id)    -> return id
 286         _                    -> pprPanic "tcLookupId" (ppr name)
 287
 288 tcLookupLocalIds :: [Name] -> TcM [TcId]
 289 -- We expect the variables to all be bound, and all at
 290 -- the same level as the lookup.  Only used in one place...
 291 tcLookupLocalIds ns = do
 292     env <- getLclEnv
 293     return (map (lookup (tcl_env env) (thLevel (tcl_th_ctxt env))) ns)
 294   where
 295     lookup lenv lvl name
 296         = case lookupNameEnv lenv name of
 297                 Just (ATcId { tct_id = id, tct_level = lvl1 })
 298                         -> ASSERT( lvl == lvl1 ) id
 299                 _ -> pprPanic "tcLookupLocalIds" (ppr name)
 300
 301 lclEnvElts :: TcLclEnv -> [TcTyThing]
 302 lclEnvElts env = nameEnvElts (tcl_env env)
 303
 304 getInLocalScope :: TcM (Name -> Bool)
 305   -- Ids only
 306 getInLocalScope = do
 307     env <- getLclEnv
 308     let lcl_env = tcl_env env
 309     return (`elemNameEnv` lcl_env)
 310 \end{code}
 311
 312 \begin{code}
 313 tcExtendKindEnv :: [(Name, TcKind)] -> TcM r -> TcM r
 314 tcExtendKindEnv things thing_inside
 315   = updLclEnv upd thing_inside
 316   where
 317     upd lcl_env = lcl_env { tcl_env = extend (tcl_env lcl_env) }
 318     extend env  = extendNameEnvList env [(n, AThing k) | (n,k) <- things]
 319
 320 tcExtendKindEnvTvs :: [LHsTyVarBndr Name] -> TcM r -> TcM r
 321 tcExtendKindEnvTvs bndrs thing_inside
 322   = updLclEnv upd thing_inside
 323   where
 324     upd lcl_env = lcl_env { tcl_env = extend (tcl_env lcl_env) }
 325     extend env  = extendNameEnvList env pairs
 326     pairs       = [(n, AThing k) | L _ (KindedTyVar n k) <- bndrs]
 327
 328 tcExtendTyVarEnv :: [TyVar] -> TcM r -> TcM r
 329 tcExtendTyVarEnv tvs thing_inside
 330   = tcExtendTyVarEnv2 [(tyVarName tv, mkTyVarTy tv) | tv <- tvs] thing_inside
 331
 332 tcExtendTyVarEnv2 :: [(Name,TcType)] -> TcM r -> TcM r
 333 tcExtendTyVarEnv2 binds thing_inside = do
 334     env@(TcLclEnv {tcl_env = le,
 335                    tcl_tyvars = gtvs,
 336                    tcl_rdr = rdr_env}) <- getLclEnv
 337     let
 338         rdr_env'   = extendLocalRdrEnv rdr_env (map fst binds)
 339         new_tv_set = tcTyVarsOfTypes (map snd binds)
 340         le'        = extendNameEnvList le [(name, ATyVar name ty) | (name, ty) <- binds]
 341
 342         -- It's important to add the in-scope tyvars to the global tyvar set
 343         -- as well.  Consider
 344         --      f (_::r) = let g y = y::r in ...
 345         -- Here, g mustn't be generalised.  This is also important during
 346         -- class and instance decls, when we mustn't generalise the class tyvars
 347         -- when typechecking the methods.
 348     gtvs' <- tc_extend_gtvs gtvs new_tv_set
 349     setLclEnv (env {tcl_env = le', tcl_tyvars = gtvs', tcl_rdr = rdr_env'}) thing_inside
 350
 351 getScopedTyVarBinds :: TcM [(Name, TcType)]
 352 getScopedTyVarBinds
 353   = do  { lcl_env <- getLclEnv
 354         ; return [(name, ty) | ATyVar name ty <- nameEnvElts (tcl_env lcl_env)] }
 355 \end{code}
 356
 357
 358 \begin{code}
 359 tcExtendIdEnv :: [TcId] -> TcM a -> TcM a
 360 tcExtendIdEnv ids thing_inside = tcExtendIdEnv2 [(idName id, id) | id <- ids] thing_inside
 361
 362 tcExtendIdEnv1 :: Name -> TcId -> TcM a -> TcM a
 363 tcExtendIdEnv1 name id thing_inside = tcExtendIdEnv2 [(name,id)] thing_inside
 364
 365 tcExtendIdEnv2 :: [(Name,TcId)] -> TcM a -> TcM a
 366 -- Invariant: the TcIds are fully zonked (see tcExtendIdEnv above)
 367 tcExtendIdEnv2 names_w_ids thing_inside
 368   = do  { env <- getLclEnv
 369         ; tc_extend_local_id_env env (thLevel (tcl_th_ctxt env)) names_w_ids thing_inside }
 370
 371 tcExtendGhciEnv :: [TcId] -> TcM a -> TcM a
 372 -- Used to bind Ids for GHCi identifiers bound earlier in the user interaction
 373 -- Note especially that we bind them at TH level 'impLevel'.  That's because it's
 374 -- OK to use a variable bound earlier in the interaction in a splice, becuase
 375 -- GHCi has already compiled it to bytecode
 376 tcExtendGhciEnv ids thing_inside
 377   = do  { env <- getLclEnv
 378         ; tc_extend_local_id_env env impLevel [(idName id, id) | id <- ids] thing_inside }
 379
 380 tc_extend_local_id_env          -- This is the guy who does the work
 381         :: TcLclEnv
 382         -> ThLevel
 383         -> [(Name,TcId)]
 384         -> TcM a -> TcM a
 385 -- Invariant: the TcIds are fully zonked. Reasons:
 386 --      (a) The kinds of the forall'd type variables are defaulted
 387 --          (see Kind.defaultKind, done in zonkQuantifiedTyVar)
 388 --      (b) There are no via-Indirect occurrences of the bound variables
 389 --          in the types, because instantiation does not look through such things
 390 --      (c) The call to tyVarsOfTypes is ok without looking through refs
 391
 392 tc_extend_local_id_env env th_lvl names_w_ids thing_inside
 393   = do  { traceTc (text "env2")
 394         ; traceTc (text "env3" <+> ppr extra_env)
 395         ; gtvs' <- tc_extend_gtvs (tcl_tyvars env) extra_global_tyvars
 396         ; let env' = env {tcl_env = le', tcl_tyvars = gtvs', tcl_rdr = rdr_env'}
 397         ; setLclEnv env' thing_inside }
 398   where
 399     extra_global_tyvars = tcTyVarsOfTypes [idType id | (_,id) <- names_w_ids]
 400     extra_env       = [ (name, ATcId { tct_id = id,
 401                                        tct_level = th_lvl,
 402                                        tct_type = id_ty,
 403                                        tct_co = case isRefineableTy id_ty of
 404                                                   (True,_) -> Unrefineable
 405                                                   (_,True) -> Rigid idHsWrapper
 406                                                   _        -> Wobbly})
 407                       | (name,id) <- names_w_ids, let id_ty = idType id]
 408     le'             = extendNameEnvList (tcl_env env) extra_env
 409     rdr_env'        = extendLocalRdrEnv (tcl_rdr env) [name | (name,_) <- names_w_ids]
 410 \end{code}
 411
 412
 413 \begin{code}
 414 -----------------------
 415 -- findGlobals looks at the value environment and finds values
 416 -- whose types mention the offending type variable.  It has to be
 417 -- careful to zonk the Id's type first, so it has to be in the monad.
 418 -- We must be careful to pass it a zonked type variable, too.
 419
 420 findGlobals :: TcTyVarSet
 421             -> TidyEnv
 422             -> TcM (TidyEnv, [SDoc])
 423
 424 findGlobals tvs tidy_env = do
 425     lcl_env <- getLclEnv
 426     go tidy_env [] (lclEnvElts lcl_env)
 427   where
 428     go tidy_env acc [] = return (tidy_env, acc)
 429     go tidy_env acc (thing : things) = do
 430         (tidy_env1, maybe_doc) <- find_thing ignore_it tidy_env thing
 431         case maybe_doc of
 432           Just d  -> go tidy_env1 (d:acc) things
 433           Nothing -> go tidy_env1 acc     things
 434
 435     ignore_it ty = tvs `disjointVarSet` tyVarsOfType ty
 436
 437 -----------------------
 438 find_thing :: (TcType -> Bool) -> TidyEnv -> TcTyThing
 439            -> TcM (TidyEnv, Maybe SDoc)
 440 find_thing ignore_it tidy_env (ATcId { tct_id = id }) = do
 441     id_ty <- zonkTcType  (idType id)
 442     if ignore_it id_ty then
 443         return (tidy_env, Nothing)
 444      else let
 445         (tidy_env', tidy_ty) = tidyOpenType tidy_env id_ty
 446         msg = sep [ppr id <+> dcolon <+> ppr tidy_ty,
 447                    nest 2 (parens (ptext (sLit "bound at") <+>
 448                                    ppr (getSrcLoc id)))]
 449      in
 450       return (tidy_env', Just msg)
 451
 452 find_thing ignore_it tidy_env (ATyVar tv ty) = do
 453     tv_ty <- zonkTcType ty
 454     if ignore_it tv_ty then
 455         return (tidy_env, Nothing)
 456      else let
 457         -- The name tv is scoped, so we don't need to tidy it
 458         (tidy_env1, tidy_ty) = tidyOpenType  tidy_env tv_ty
 459         msg = sep [ptext (sLit "Scoped type variable") <+> quotes (ppr tv) <+> eq_stuff, nest 2 bound_at]
 460
 461         eq_stuff | Just tv' <- Type.getTyVar_maybe tv_ty,
 462                    getOccName tv == getOccName tv' = empty
 463                  | otherwise = equals <+> ppr tidy_ty
 464                 -- It's ok to use Type.getTyVar_maybe because ty is zonked by now
 465         bound_at = parens $ ptext (sLit "bound at:") <+> ppr (getSrcLoc tv)
 466      in
 467        return (tidy_env1, Just msg)
 468
 469 find_thing _ _ thing = pprPanic "find_thing" (ppr thing)
 470 \end{code}
 471
 472 %************************************************************************
 473 %*                                                                      *
 474 \subsection{The global tyvars}
 475 %*                                                                      *
 476 %************************************************************************
 477
 478 \begin{code}
 479 tc_extend_gtvs :: IORef VarSet -> VarSet -> TcM (IORef VarSet)
 480 tc_extend_gtvs gtvs extra_global_tvs = do
 481     global_tvs <- readMutVar gtvs
 482     newMutVar (global_tvs `unionVarSet` extra_global_tvs)
 483 \end{code}
 484
 485 @tcGetGlobalTyVars@ returns a fully-zonked set of tyvars free in the environment.
 486 To improve subsequent calls to the same function it writes the zonked set back into
 487 the environment.
 488
 489 \begin{code}
 490 tcGetGlobalTyVars :: TcM TcTyVarSet
 491 tcGetGlobalTyVars = do
 492     (TcLclEnv {tcl_tyvars = gtv_var}) <- getLclEnv
 493     gbl_tvs  <- readMutVar gtv_var
 494     gbl_tvs' <- zonkTcTyVarsAndFV (varSetElems gbl_tvs)
 495     writeMutVar gtv_var gbl_tvs'
 496     return gbl_tvs'
 497 \end{code}
 498
 499
 500 %************************************************************************
 501 %*                                                                      *
 502 \subsection{Rules}
 503 %*                                                                      *
 504 %************************************************************************
 505
 506 \begin{code}
 507 tcExtendRules :: [LRuleDecl Id] -> TcM a -> TcM a
 508         -- Just pop the new rules into the EPS and envt resp
 509         -- All the rules come from an interface file, not soruce
 510         -- Nevertheless, some may be for this module, if we read
 511         -- its interface instead of its source code
 512 tcExtendRules lcl_rules thing_inside
 513  = do { env <- getGblEnv
 514       ; let
 515           env' = env { tcg_rules = lcl_rules ++ tcg_rules env }
 516       ; setGblEnv env' thing_inside }
 517 \end{code}
 518
 519
 520 %************************************************************************
 521 %*                                                                      *
 522                 Meta level
 523 %*                                                                      *
 524 %************************************************************************
 525
 526 \begin{code}
 527 instance Outputable ThStage where
 528    ppr Comp          = text "Comp"
 529    ppr (Brack l _ _) = text "Brack" <+> int l
 530    ppr (Splice l)    = text "Splice" <+> int l
 531
 532
 533 thLevel :: ThStage -> ThLevel
 534 thLevel Comp          = topLevel
 535 thLevel (Splice l)    = l
 536 thLevel (Brack l _ _) = l
 537
 538
 539 checkWellStaged :: SDoc         -- What the stage check is for
 540                 -> ThLevel      -- Binding level (increases inside brackets)
 541                 -> ThStage      -- Use stage
 542                 -> TcM ()       -- Fail if badly staged, adding an error
 543 checkWellStaged pp_thing bind_lvl use_stage
 544   | use_lvl >= bind_lvl         -- OK! Used later than bound
 545   = return ()                   -- E.g.  \x -> [| $(f x) |]
 546
 547   | bind_lvl == topLevel        -- GHC restriction on top level splices
 548   = failWithTc $
 549     sep [ptext (sLit "GHC stage restriction:") <+>  pp_thing,
 550          nest 2 (ptext (sLit "is used in a top-level splice, and must be imported, not defined locally"))]
 551
 552   | otherwise                   -- Badly staged
 553   = failWithTc $                -- E.g.  \x -> $(f x)
 554     ptext (sLit "Stage error:") <+> pp_thing <+>
 555         hsep   [ptext (sLit "is bound at stage") <+> ppr bind_lvl,
 556                 ptext (sLit "but used at stage") <+> ppr use_lvl]
 557   where
 558     use_lvl = thLevel use_stage
 559
 560
 561 topIdLvl :: Id -> ThLevel
 562 -- Globals may either be imported, or may be from an earlier "chunk"
 563 -- (separated by declaration splices) of this module.  The former
 564 --  *can* be used inside a top-level splice, but the latter cannot.
 565 -- Hence we give the former impLevel, but the latter topLevel
 566 -- E.g. this is bad:
 567 --      x = [| foo |]
 568 --      $( f x )
 569 -- By the time we are prcessing the $(f x), the binding for "x"
 570 -- will be in the global env, not the local one.
 571 topIdLvl id | isLocalId id = topLevel
 572             | otherwise    = impLevel
 573
 574 -- Indicates the legal transitions on bracket( [| |] ).
 575 bracketOK :: ThStage -> Maybe ThLevel
 576 bracketOK (Brack _ _ _) = Nothing       -- Bracket illegal inside a bracket
 577 bracketOK stage         = Just (thLevel stage + 1)
 578
 579 -- Indicates the legal transitions on splice($).
 580 spliceOK :: ThStage -> Maybe ThLevel
 581 spliceOK (Splice _) = Nothing   -- Splice illegal inside splice
 582 spliceOK stage      = Just (thLevel stage - 1)
 583
 584 tcMetaTy :: Name -> TcM Type
 585 -- Given the name of a Template Haskell data type,
 586 -- return the type
 587 -- E.g. given the name "Expr" return the type "Expr"
 588 tcMetaTy tc_name = do
 589     t <- tcLookupTyCon tc_name
 590     return (mkTyConApp t [])
 591
 592 thTopLevelId :: Id -> Bool
 593 -- See Note [What is a top-level Id?] in TcSplice
 594 thTopLevelId id = isGlobalId id || isExternalName (idName id)
 595 \end{code}
 596
 597
 598 %************************************************************************
 599 %*                                                                      *
 600 \subsection{The InstInfo type}
 601 %*                                                                      *
 602 %************************************************************************
 603
 604 The InstInfo type summarises the information in an instance declaration
 605
 606     instance c => k (t tvs) where b
 607
 608 It is used just for *local* instance decls (not ones from interface files).
 609 But local instance decls includes
 610         - derived ones
 611         - generic ones
 612 as well as explicit user written ones.
 613
 614 \begin{code}
 615 data InstInfo a
 616   = InstInfo {
 617       iSpec  :: Instance,               -- Includes the dfun id.  Its forall'd type
 618       iBinds :: InstBindings a          -- variables scope over the stuff in InstBindings!
 619     }
 620
 621 iDFunId :: InstInfo a -> DFunId
 622 iDFunId info = instanceDFunId (iSpec info)
 623
 624 data InstBindings a
 625   = VanillaInst                 -- The normal case
 626         (LHsBinds a)            -- Bindings for the instance methods
 627         [LSig a]                -- User pragmas recorded for generating
 628                                 -- specialised instances
 629
 630   | NewTypeDerived              -- Used for deriving instances of newtypes, where the
 631                                 -- witness dictionary is identical to the argument
 632                                 -- dictionary.  Hence no bindings, no pragmas.
 633
 634 pprInstInfo :: InstInfo a -> SDoc
 635 pprInstInfo info = vcat [ptext (sLit "InstInfo:") <+> ppr (idType (iDFunId info))]
 636
 637 pprInstInfoDetails :: OutputableBndr a => InstInfo a -> SDoc
 638 pprInstInfoDetails info = pprInstInfo info $$ nest 2 (details (iBinds info))
 639   where
 640     details (VanillaInst b _) = pprLHsBinds b
 641     details NewTypeDerived    = text "Derived from the representation type"
 642
 643 simpleInstInfoClsTy :: InstInfo a -> (Class, Type)
 644 simpleInstInfoClsTy info = case instanceHead (iSpec info) of
 645                            (_, _, cls, [ty]) -> (cls, ty)
 646                            _ -> panic "simpleInstInfoClsTy"
 647
 648 simpleInstInfoTy :: InstInfo a -> Type
 649 simpleInstInfoTy info = snd (simpleInstInfoClsTy info)
 650
 651 simpleInstInfoTyCon :: InstInfo a -> TyCon
 652   -- Gets the type constructor for a simple instance declaration,
 653   -- i.e. one of the form       instance (...) => C (T a b c) where ...
 654 simpleInstInfoTyCon inst = tcTyConAppTyCon (simpleInstInfoTy inst)
 655 \end{code}
 656
 657 Make a name for the dict fun for an instance decl.  It's an *external*
 658 name, like otber top-level names, and hence must be made with newGlobalBinder.
 659
 660 \begin{code}
 661 newDFunName :: Class -> [Type] -> SrcSpan -> TcM Name
 662 newDFunName clas (ty:_) loc
 663   = do  { index   <- nextDFunIndex
 664         ; is_boot <- tcIsHsBoot
 665         ; mod     <- getModule
 666         ; let info_string = occNameString (getOccName clas) ++
 667                             occNameString (getDFunTyKey ty)
 668               dfun_occ = mkDFunOcc info_string is_boot index
 669
 670         ; newGlobalBinder mod dfun_occ loc }
 671
 672 newDFunName clas [] loc = pprPanic "newDFunName" (ppr clas <+> ppr loc)
 673 \end{code}
 674
 675 Make a name for the representation tycon of a family instance.  It's an
 676 *external* name, like otber top-level names, and hence must be made with
 677 newGlobalBinder.
 678
 679 \begin{code}
 680 newFamInstTyConName :: Name -> SrcSpan -> TcM Name
 681 newFamInstTyConName tc_name loc
 682   = do  { index <- nextDFunIndex
 683         ; mod   <- getModule
 684         ; let occ = nameOccName tc_name
 685         ; newGlobalBinder mod (mkInstTyTcOcc index occ) loc }
 686 \end{code}
 687
 688 Stable names used for foreign exports and annotations.
 689 For stable names, the name must be unique (see #1533).  If the
 690 same thing has several stable Ids based on it, the
 691 top-level bindings generated must not have the same name.
 692 Hence we create an External name (doesn't change), and we
 693 append a Unique to the string right here.
 694
 695 \begin{code}
 696 mkStableIdFromString :: String -> Type -> SrcSpan -> (OccName -> OccName) -> TcM TcId
 697 mkStableIdFromString str sig_ty loc occ_wrapper = do
 698     uniq <- newUnique
 699     mod <- getModule
 700     let uniq_str = showSDoc (pprUnique uniq) :: String
 701         occ = mkVarOcc (str ++ '_' : uniq_str) :: OccName
 702         gnm = mkExternalName uniq mod (occ_wrapper occ) loc :: Name
 703         id  = mkExportedLocalId gnm sig_ty :: Id
 704     return id
 705
 706 mkStableIdFromName :: Name -> Type -> SrcSpan -> (OccName -> OccName) -> TcM TcId
 707 mkStableIdFromName nm = mkStableIdFromString (getOccString nm)
 708 \end{code}
 709
 710 %************************************************************************
 711 %*                                                                      *
 712 \subsection{Errors}
 713 %*                                                                      *
 714 %************************************************************************
 715
 716 \begin{code}
 717 pprBinders :: [Name] -> SDoc
 718 -- Used in error messages
 719 -- Use quotes for a single one; they look a bit "busy" for several
 720 pprBinders [bndr] = quotes (ppr bndr)
 721 pprBinders bndrs  = pprWithCommas ppr bndrs
 722
 723 notFound :: Name -> TcGblEnv -> TcM TyThing
 724 notFound name env
 725   = failWithTc (vcat[ptext (sLit "GHC internal error:") <+> quotes (ppr name) <+>
 726                      ptext (sLit "is not in scope during type checking, but it passed the renamer"),
 727                      ptext (sLit "tcg_type_env of environment:") <+> ppr (tcg_type_env env)]
 728                     )
 729
 730 wrongThingErr :: String -> TcTyThing -> Name -> TcM a
 731 wrongThingErr expected thing name
 732   = failWithTc (pprTcTyThingCategory thing <+> quotes (ppr name) <+>
 733                 ptext (sLit "used as a") <+> text expected)
 734 \end{code}