compiler/typecheck/TcExpr.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcExpr]{Typecheck an expression}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcExpr ( tcPolyExpr, tcPolyExprNC, tcMonoExpr, tcMonoExprNC, tcInferRho, tcInferRhoNC, tcSyntaxOp, addExprErrCtxt ) where
  16
  17 #include "HsVersions.h"
  18
  19 #ifdef GHCI     /* Only if bootstrapped */
  20 import {-# SOURCE #-}   TcSplice( tcSpliceExpr, tcBracket )
  21 import qualified DsMeta
  22 #endif
  23
  24 import HsSyn
  25 import TcHsSyn
  26 import TcRnMonad
  27 import TcUnify
  28 import BasicTypes
  29 import Inst
  30 import TcBinds
  31 import TcEnv
  32 import TcArrows
  33 import TcMatches
  34 import TcHsType
  35 import TcPat
  36 import TcMType
  37 import TcType
  38 import TcIface  ( checkWiredInTyCon )
  39 import Id
  40 import DataCon
  41 import Name
  42 import TyCon
  43 import Type
  44 import TypeRep
  45 import Coercion
  46 import Var
  47 import VarSet
  48 import TysWiredIn
  49 import PrelNames
  50 import PrimOp
  51 import DynFlags
  52 import StaticFlags
  53 import HscTypes
  54 import SrcLoc
  55 import Util
  56 import ListSetOps
  57 import Maybes
  58 import Outputable
  59 import FastString
  60
  61 import Data.List( partition )
  62 import Control.Monad
  63 \end{code}
  64
  65 %************************************************************************
  66 %*                                                                      *
  67 \subsection{Main wrappers}
  68 %*                                                                      *
  69 %************************************************************************
  70
  71 \begin{code}
  72 tcPolyExpr, tcPolyExprNC
  73          :: LHsExpr Name                -- Expession to type check
  74          -> BoxySigmaType               -- Expected type (could be a polytpye)
  75          -> TcM (LHsExpr TcId)  -- Generalised expr with expected type
  76
  77 -- tcPolyExpr is a convenient place (frequent but not too frequent) place
  78 -- to add context information.
  79 -- The NC version does not do so, usually because the caller wants
  80 -- to do so himself.
  81
  82 tcPolyExpr expr res_ty
  83   = addExprErrCtxt expr $
  84     (do {traceTc (text "tcPolyExpr") ; tcPolyExprNC expr res_ty })
  85
  86 tcPolyExprNC expr res_ty
  87   | isSigmaTy res_ty
  88   = do  { traceTc (text "tcPolyExprNC" <+> ppr res_ty)
  89         ; (gen_fn, expr') <- tcGen res_ty emptyVarSet Nothing $ \ _ res_ty ->
  90                              tcPolyExprNC expr res_ty
  91                 -- Note the recursive call to tcPolyExpr, because the
  92                 -- type may have multiple layers of for-alls
  93                 -- E.g. forall a. Eq a => forall b. Ord b => ....
  94         ; return (mkLHsWrap gen_fn expr') }
  95
  96   | otherwise
  97   = tcMonoExprNC expr res_ty
  98
  99 ---------------
 100 tcPolyExprs :: [LHsExpr Name] -> [TcType] -> TcM [LHsExpr TcId]
 101 tcPolyExprs [] [] = return []
 102 tcPolyExprs (expr:exprs) (ty:tys)
 103  = do   { expr'  <- tcPolyExpr  expr  ty
 104         ; exprs' <- tcPolyExprs exprs tys
 105         ; return (expr':exprs') }
 106 tcPolyExprs exprs tys = pprPanic "tcPolyExprs" (ppr exprs $$ ppr tys)
 107
 108 ---------------
 109 tcMonoExpr, tcMonoExprNC
 110     :: LHsExpr Name     -- Expression to type check
 111     -> BoxyRhoType      -- Expected type (could be a type variable)
 112                         -- Definitely no foralls at the top
 113                         -- Can contain boxes, which will be filled in
 114     -> TcM (LHsExpr TcId)
 115
 116 tcMonoExpr expr res_ty
 117   = addErrCtxt (exprCtxt expr) $
 118     tcMonoExprNC expr res_ty
 119
 120 tcMonoExprNC (L loc expr) res_ty
 121   = ASSERT( not (isSigmaTy res_ty) )
 122     setSrcSpan loc $
 123     do  { expr' <- tcExpr expr res_ty
 124         ; return (L loc expr') }
 125
 126 ---------------
 127 tcInferRho, tcInferRhoNC :: LHsExpr Name -> TcM (LHsExpr TcId, TcRhoType)
 128 tcInferRho   expr = tcInfer (tcMonoExpr expr)
 129 tcInferRhoNC expr = tcInfer (tcMonoExprNC expr)
 130 \end{code}
 131
 132
 133 %************************************************************************
 134 %*                                                                      *
 135         tcExpr: the main expression typechecker
 136 %*                                                                      *
 137 %************************************************************************
 138
 139 \begin{code}
 140 tcExpr :: HsExpr Name -> BoxyRhoType -> TcM (HsExpr TcId)
 141 tcExpr e res_ty | debugIsOn && isSigmaTy res_ty     -- Sanity check
 142                 = pprPanic "tcExpr: sigma" (ppr res_ty $$ ppr e)
 143
 144 tcExpr (HsVar name)     res_ty = tcId (OccurrenceOf name) name res_ty
 145
 146 tcExpr (HsLit lit)      res_ty = do { let lit_ty = hsLitType lit
 147                                     ; coi <- boxyUnify lit_ty res_ty
 148                                     ; return $ mkHsWrapCoI coi (HsLit lit)
 149                                     }
 150
 151 tcExpr (HsPar expr)     res_ty = do { expr' <- tcMonoExprNC expr res_ty
 152                                     ; return (HsPar expr') }
 153
 154 tcExpr (HsSCC lbl expr) res_ty = do { expr' <- tcMonoExpr expr res_ty
 155                                     ; return (HsSCC lbl expr') }
 156 tcExpr (HsTickPragma info expr) res_ty
 157                                = do { expr' <- tcMonoExpr expr res_ty
 158                                     ; return (HsTickPragma info expr') }
 159
 160 tcExpr (HsCoreAnn lbl expr) res_ty       -- hdaume: core annotation
 161   = do  { expr' <- tcMonoExpr expr res_ty
 162         ; return (HsCoreAnn lbl expr') }
 163
 164 tcExpr (HsOverLit lit) res_ty
 165   = do  { lit' <- tcOverloadedLit (LiteralOrigin lit) lit res_ty
 166         ; return (HsOverLit lit') }
 167
 168 tcExpr (NegApp expr neg_expr) res_ty
 169   = do  { neg_expr' <- tcSyntaxOp NegateOrigin neg_expr
 170                                   (mkFunTy res_ty res_ty)
 171         ; expr' <- tcMonoExpr expr res_ty
 172         ; return (NegApp expr' neg_expr') }
 173
 174 tcExpr (HsIPVar ip) res_ty
 175   = do  { let origin = IPOccOrigin ip
 176                 -- Implicit parameters must have a *tau-type* not a
 177                 -- type scheme.  We enforce this by creating a fresh
 178                 -- type variable as its type.  (Because res_ty may not
 179                 -- be a tau-type.)
 180         ; ip_ty <- newFlexiTyVarTy argTypeKind  -- argTypeKind: it can't be an unboxed tuple
 181         ; co_fn <- tcSubExp origin ip_ty res_ty
 182         ; (ip', inst) <- newIPDict origin ip ip_ty
 183         ; extendLIE inst
 184         ; return (mkHsWrap co_fn (HsIPVar ip')) }
 185
 186 tcExpr (HsApp e1 e2) res_ty
 187   = go e1 [e2]
 188   where
 189     go :: LHsExpr Name -> [LHsExpr Name] -> TcM (HsExpr TcId)
 190     go (L _ (HsApp e1 e2)) args = go e1 (e2:args)
 191     go lfun@(L loc fun) args
 192         = do { (fun', args') <- -- addErrCtxt (callCtxt lfun args) $
 193                                 tcApp fun (length args) (tcArgs lfun args) res_ty
 194              ; traceTc (text "tcExpr args': " <+> ppr args')
 195              ; return (unLoc (foldl mkHsApp (L loc fun') args')) }
 196
 197 tcExpr (HsLam match) res_ty
 198   = do  { (co_fn, match') <- tcMatchLambda match res_ty
 199         ; return (mkHsWrap co_fn (HsLam match')) }
 200
 201 tcExpr in_expr@(ExprWithTySig expr sig_ty) res_ty
 202  = do   { sig_tc_ty <- tcHsSigType ExprSigCtxt sig_ty
 203
 204         -- Remember to extend the lexical type-variable environment
 205         ; (gen_fn, expr') <- tcGen sig_tc_ty emptyVarSet (Just ExprSigCtxt) $ \ skol_tvs res_ty ->
 206                              tcExtendTyVarEnv2 (hsExplicitTvs sig_ty `zip` mkTyVarTys skol_tvs) $
 207                                 -- See Note [More instantiated than scoped] in TcBinds
 208                              tcMonoExprNC expr res_ty
 209
 210         ; co_fn <- tcSubExp ExprSigOrigin sig_tc_ty res_ty
 211         ; return (mkHsWrap co_fn (ExprWithTySigOut (mkLHsWrap gen_fn expr') sig_ty)) }
 212
 213 tcExpr (HsType ty) res_ty
 214   = failWithTc (text "Can't handle type argument:" <+> ppr ty)
 215         -- This is the syntax for type applications that I was planning
 216         -- but there are difficulties (e.g. what order for type args)
 217         -- so it's not enabled yet.
 218         -- Can't eliminate it altogether from the parser, because the
 219         -- same parser parses *patterns*.
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225                 Infix operators and sections
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 \begin{code}
 230 tcExpr in_expr@(OpApp arg1 lop@(L loc op) fix arg2) res_ty
 231   = do  { (op', [arg1', arg2']) <- tcApp op 2 (tcArgs lop [arg1,arg2]) res_ty
 232         ; return (OpApp arg1' (L loc op') fix arg2') }
 233
 234 -- Left sections, equivalent to
 235 --      \ x -> e op x,
 236 -- or
 237 --      \ x -> op e x,
 238 -- or, if PostfixOperators is enabled, just
 239 --      op e
 240 --
 241 -- With PostfixOperators we don't
 242 -- actually require the function to take two arguments
 243 -- at all.  For example, (x `not`) means (not x);
 244 -- you get postfix operators!  Not Haskell 98,
 245 -- but it's less work and kind of useful.
 246
 247 tcExpr in_expr@(SectionL arg1 lop@(L loc op)) res_ty
 248   = do dflags <- getDOpts
 249        if dopt Opt_PostfixOperators dflags
 250            then do (op', [arg1']) <- tcApp op 1 (tcArgs lop [arg1]) res_ty
 251                    return (SectionL arg1' (L loc op'))
 252            else do (co_fn, (op', arg1'))
 253                        <- subFunTys doc 1 res_ty Nothing
 254                         $ \ [arg2_ty'] res_ty' ->
 255                               tcApp op 2 (tc_args arg2_ty') res_ty'
 256                    return (mkHsWrap co_fn (SectionL arg1' (L loc op')))
 257   where
 258     doc = ptext (sLit "The section") <+> quotes (ppr in_expr)
 259                 <+> ptext (sLit "takes one argument")
 260     tc_args arg2_ty' qtvs qtys [arg1_ty, arg2_ty]
 261         = do { boxyUnify arg2_ty' (substTyWith qtvs qtys arg2_ty)
 262              ; arg1' <- tcArg lop 2 arg1 qtvs qtys arg1_ty
 263              ; qtys' <- mapM refineBox qtys     -- c.f. tcArgs
 264              ; return (qtys', arg1') }
 265     tc_args _ _ _ _ = panic "tcExpr SectionL"
 266
 267 -- Right sections, equivalent to \ x -> x `op` expr, or
 268 --      \ x -> op x expr
 269
 270 tcExpr in_expr@(SectionR lop@(L loc op) arg2) res_ty
 271   = do  { (co_fn, (op', arg2')) <- subFunTys doc 1 res_ty Nothing $ \ [arg1_ty'] res_ty' ->
 272                                    tcApp op 2 (tc_args arg1_ty') res_ty'
 273         ; return (mkHsWrap co_fn (SectionR (L loc op') arg2')) }
 274   where
 275     doc = ptext (sLit "The section") <+> quotes (ppr in_expr)
 276                 <+> ptext (sLit "takes one argument")
 277     tc_args arg1_ty' qtvs qtys [arg1_ty, arg2_ty]
 278         = do { boxyUnify arg1_ty' (substTyWith qtvs qtys arg1_ty)
 279              ; arg2' <- tcArg lop 2 arg2 qtvs qtys arg2_ty
 280              ; qtys' <- mapM refineBox qtys     -- c.f. tcArgs
 281              ; return (qtys', arg2') }
 282     tc_args arg1_ty' _ _ _ = panic "tcExpr SectionR"
 283 \end{code}
 284
 285 \begin{code}
 286 tcExpr (HsLet binds expr) res_ty
 287   = do  { (binds', expr') <- tcLocalBinds binds $
 288                              tcMonoExpr expr res_ty
 289         ; return (HsLet binds' expr') }
 290
 291 tcExpr (HsCase scrut matches) exp_ty
 292   = do  {  -- We used to typecheck the case alternatives first.
 293            -- The case patterns tend to give good type info to use
 294            -- when typechecking the scrutinee.  For example
 295            --   case (map f) of
 296            --     (x:xs) -> ...
 297            -- will report that map is applied to too few arguments
 298            --
 299            -- But now, in the GADT world, we need to typecheck the scrutinee
 300            -- first, to get type info that may be refined in the case alternatives
 301           (scrut', scrut_ty) <- tcInferRho scrut
 302
 303         ; traceTc (text "HsCase" <+> ppr scrut_ty)
 304         ; matches' <- tcMatchesCase match_ctxt scrut_ty matches exp_ty
 305         ; return (HsCase scrut' matches') }
 306  where
 307     match_ctxt = MC { mc_what = CaseAlt,
 308                       mc_body = tcBody }
 309
 310 tcExpr (HsIf pred b1 b2) res_ty
 311   = do  { pred' <- tcMonoExpr pred boolTy
 312         ; b1' <- tcMonoExpr b1 res_ty
 313         ; b2' <- tcMonoExpr b2 res_ty
 314         ; return (HsIf pred' b1' b2') }
 315
 316 tcExpr (HsDo do_or_lc stmts body _) res_ty
 317   = tcDoStmts do_or_lc stmts body res_ty
 318
 319 tcExpr in_expr@(ExplicitList _ exprs) res_ty
 320   = do  { (elt_ty, coi) <- boxySplitListTy res_ty
 321         ; exprs' <- mapM (tc_elt elt_ty) exprs
 322         ; when (null exprs) (zapToMonotype elt_ty >> return ())
 323                 -- If there are no expressions in the comprehension
 324                 -- we must still fill in the box
 325                 --
 326                 -- The GHC front end never generates an empty ExplicitList
 327                 -- (instead it generates the [] data constructor) but
 328                 -- Template Haskell might.  We could fix the bit of
 329                 -- TH that generates ExplicitList, but it seems less
 330                 -- fragile to just handle the case here.
 331         ; return $ mkHsWrapCoI coi (ExplicitList elt_ty exprs') }
 332   where
 333     tc_elt elt_ty expr = tcPolyExpr expr elt_ty
 334
 335 tcExpr in_expr@(ExplicitPArr _ exprs) res_ty    -- maybe empty
 336   = do  { (elt_ty, coi) <- boxySplitPArrTy res_ty
 337         ; exprs' <- mapM (tc_elt elt_ty) exprs
 338         ; when (null exprs) (zapToMonotype elt_ty >> return ())
 339                 -- If there are no expressions in the comprehension
 340                 -- we must still fill in the box
 341                 -- (Not needed for [] and () becuase they happen
 342                 --  to parse as data constructors.)
 343         ; return $ mkHsWrapCoI coi (ExplicitPArr elt_ty exprs') }
 344   where
 345     tc_elt elt_ty expr = tcPolyExpr expr elt_ty
 346
 347 -- For tuples, take care to preserve rigidity
 348 -- E.g.         case (x,y) of ....
 349 --         The scrutinee should have a rigid type if x,y do
 350 -- The general scheme is the same as in tcIdApp
 351 tcExpr (ExplicitTuple exprs boxity) res_ty
 352   = do  { let kind = case boxity of { Boxed   -> liftedTypeKind
 353                                     ; Unboxed -> argTypeKind }
 354         ; tvs <- newBoxyTyVars [kind | e <- exprs]
 355         ; let tup_tc     = tupleTyCon boxity (length exprs)
 356               tup_res_ty = mkTyConApp tup_tc (mkTyVarTys tvs)
 357         ; checkWiredInTyCon tup_tc      -- Ensure instances are available
 358         ; arg_tys  <- preSubType tvs (mkVarSet tvs) tup_res_ty res_ty
 359         ; exprs'   <- tcPolyExprs exprs arg_tys
 360         ; arg_tys' <- mapM refineBox arg_tys
 361         ; co_fn    <- tcSubExp TupleOrigin (mkTyConApp tup_tc arg_tys') res_ty
 362         ; return (mkHsWrap co_fn (ExplicitTuple exprs' boxity)) }
 363
 364 tcExpr (HsProc pat cmd) res_ty
 365   = do  { (pat', cmd', coi) <- tcProc pat cmd res_ty
 366         ; return $ mkHsWrapCoI coi (HsProc pat' cmd') }
 367
 368 tcExpr e@(HsArrApp _ _ _ _ _) _
 369   = failWithTc (vcat [ptext (sLit "The arrow command"), nest 2 (ppr e),
 370                       ptext (sLit "was found where an expression was expected")])
 371
 372 tcExpr e@(HsArrForm _ _ _) _
 373   = failWithTc (vcat [ptext (sLit "The arrow command"), nest 2 (ppr e),
 374                       ptext (sLit "was found where an expression was expected")])
 375 \end{code}
 376
 377 %************************************************************************
 378 %*                                                                      *
 379                 Record construction and update
 380 %*                                                                      *
 381 %************************************************************************
 382
 383 \begin{code}
 384 tcExpr expr@(RecordCon (L loc con_name) _ rbinds) res_ty
 385   = do  { data_con <- tcLookupDataCon con_name
 386
 387         -- Check for missing fields
 388         ; checkMissingFields data_con rbinds
 389
 390         ; let arity = dataConSourceArity data_con
 391               check_fields qtvs qtys arg_tys
 392                   = do  { let arg_tys' = substTys (zipOpenTvSubst qtvs qtys) arg_tys
 393                         ; rbinds' <- tcRecordBinds data_con arg_tys' rbinds
 394                         ; qtys' <- mapM refineBoxToTau qtys
 395                         ; return (qtys', rbinds') }
 396                 -- The refineBoxToTau ensures that all the boxes in arg_tys are indeed
 397                 -- filled, which is the invariant expected by tcIdApp
 398                 -- How could this not be the case?  Consider a record construction
 399                 -- that does not mention all the fields.
 400
 401         ; (con_expr, rbinds') <- tcIdApp con_name arity check_fields res_ty
 402
 403         ; return (RecordCon (L loc (dataConWrapId data_con)) con_expr rbinds') }
 404 \end{code}
 405
 406 Note [Type of a record update]
 407 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 408 The main complication with RecordUpd is that we need to explicitly
 409 handle the *non-updated* fields.  Consider:
 410
 411         data T a b c = MkT1 { fa :: a, fb :: (b,c) }
 412                      | MkT2 { fa :: a, fb :: (b,c), fc :: c -> c }
 413                      | MkT3 { fd :: a }
 414
 415         upd :: T a b c -> (b',c) -> T a b' c
 416         upd t x = t { fb = x}
 417
 418 The result type should be (T a b' c)
 419 not (T a b c),   because 'b' *is not* mentioned in a non-updated field
 420 not (T a b' c'), becuase 'c' *is*     mentioned in a non-updated field
 421 NB that it's not good enough to look at just one constructor; we must
 422 look at them all; cf Trac #3219
 423
 424 After all, upd should be equivalent to:
 425         upd t x = case t of
 426                         MkT1 p q -> MkT1 p x
 427                         MkT2 a b -> MkT2 p b
 428                         MkT3 d   -> error ...
 429
 430 So we need to give a completely fresh type to the result record,
 431 and then constrain it by the fields that are *not* updated ("p" above).
 432 We call these the "fixed" type variables, and compute them in getFixedTyVars.
 433
 434 Note that because MkT3 doesn't contain all the fields being updated,
 435 its RHS is simply an error, so it doesn't impose any type constraints.
 436 Hence the use of 'relevant_cont'.
 437
 438 Note [Implict type sharing]
 439 ~~~~~~~~~~~~~~~~~~~~~~~~~~~
 440 We also take into account any "implicit" non-update fields.  For example
 441         data T a b where { MkT { f::a } :: T a a; ... }
 442 So the "real" type of MkT is: forall ab. (a~b) => a -> T a b
 443
 444 Then consider
 445         upd t x = t { f=x }
 446 We infer the type
 447         upd :: T a b -> a -> T a b
 448         upd (t::T a b) (x::a)
 449            = case t of { MkT (co:a~b) (_:a) -> MkT co x }
 450 We can't give it the more general type
 451         upd :: T a b -> c -> T c b
 452
 453 Note [Criteria for update]
 454 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 455 We want to allow update for existentials etc, provided the updated
 456 field isn't part of the existential. For example, this should be ok.
 457   data T a where { MkT { f1::a, f2::b->b } :: T a }
 458   f :: T a -> b -> T b
 459   f t b = t { f1=b }
 460 The criterion we use is this:
 461
 462   The types of the updated fields
 463   mention only the universally-quantified type variables
 464   of the data constructor
 465
 466 In principle one could go further, and allow
 467   g :: T a -> T a
 468   g t = t { f2 = \x -> x }
 469 because the expression is polymorphic...but that seems a bridge too far.
 470
 471 Note [Data family example]
 472 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 473     data instance T (a,b) = MkT { x::a, y::b }
 474   --->
 475     data :TP a b = MkT { a::a, y::b }
 476     coTP a b :: T (a,b) ~ :TP a b
 477
 478 Suppose r :: T (t1,t2), e :: t3
 479 Then  r { x=e } :: T (t3,t1)
 480   --->
 481       case r |> co1 of
 482         MkT x y -> MkT e y |> co2
 483       where co1 :: T (t1,t2) ~ :TP t1 t2
 484             co2 :: :TP t3 t2 ~ T (t3,t2)
 485 The wrapping with co2 is done by the constructor wrapper for MkT
 486
 487 Outgoing invariants
 488 ~~~~~~~~~~~~~~~~~~~
 489 In the outgoing (HsRecordUpd scrut binds cons in_inst_tys out_inst_tys):
 490
 491   * cons are the data constructors to be updated
 492
 493   * in_inst_tys, out_inst_tys have same length, and instantiate the
 494         *representation* tycon of the data cons.  In Note [Data
 495         family example], in_inst_tys = [t1,t2], out_inst_tys = [t3,t2]
 496
 497 \begin{code}
 498 tcExpr expr@(RecordUpd record_expr rbinds _ _ _) res_ty
 499   = ASSERT( notNull upd_fld_names )
 500     do  {
 501         -- STEP 0
 502         -- Check that the field names are really field names
 503         ; sel_ids <- mapM tcLookupField upd_fld_names
 504                         -- The renamer has already checked that
 505                         -- selectors are all in scope
 506         ; let bad_guys = [ setSrcSpan loc $ addErrTc (notSelector fld_name)
 507                          | (fld, sel_id) <- rec_flds rbinds `zip` sel_ids,
 508                            not (isRecordSelector sel_id),       -- Excludes class ops
 509                            let L loc fld_name = hsRecFieldId fld ]
 510         ; unless (null bad_guys) (sequence bad_guys >> failM)
 511
 512         -- STEP 1
 513         -- Figure out the tycon and data cons from the first field name
 514         ; let   -- It's OK to use the non-tc splitters here (for a selector)
 515               sel_id : _  = sel_ids
 516               (tycon, _)  = recordSelectorFieldLabel sel_id     -- We've failed already if
 517               data_cons   = tyConDataCons tycon                 -- it's not a field label
 518                 -- NB: for a data type family, the tycon is the instance tycon
 519
 520               relevant_cons   = filter is_relevant data_cons
 521               is_relevant con = all (`elem` dataConFieldLabels con) upd_fld_names
 522                 -- A constructor is only relevant to this process if
 523                 -- it contains *all* the fields that are being updated
 524                 -- Other ones will cause a runtime error if they occur
 525
 526                 -- Take apart a representative constructor
 527               con1 = ASSERT( not (null relevant_cons) ) head relevant_cons
 528               (con1_tvs, _, _, _, _, con1_arg_tys, _) = dataConFullSig con1
 529               con1_flds = dataConFieldLabels con1
 530               con1_res_ty = mkFamilyTyConApp tycon (mkTyVarTys con1_tvs)
 531
 532         -- STEP 2
 533         -- Check that at least one constructor has all the named fields
 534         -- i.e. has an empty set of bad fields returned by badFields
 535         ; checkTc (not (null relevant_cons)) (badFieldsUpd rbinds)
 536
 537         -- STEP 3    Note [Criteria for update]
 538         -- Check that each updated field is polymorphic; that is, its type
 539         -- mentions only the universally-quantified variables of the data con
 540         ; let flds1_w_tys = zipEqual "tcExpr:RecConUpd" con1_flds con1_arg_tys
 541               (upd_flds1_w_tys, fixed_flds1_w_tys) = partition is_updated flds1_w_tys
 542               is_updated (fld,ty) = fld `elem` upd_fld_names
 543
 544               bad_upd_flds = filter bad_fld upd_flds1_w_tys
 545               con1_tv_set = mkVarSet con1_tvs
 546               bad_fld (fld, ty) = fld `elem` upd_fld_names &&
 547                                       not (tyVarsOfType ty `subVarSet` con1_tv_set)
 548         ; checkTc (null bad_upd_flds) (badFieldTypes bad_upd_flds)
 549
 550         -- STEP 4  Note [Type of a record update]
 551         -- Figure out types for the scrutinee and result
 552         -- Both are of form (T a b c), with fresh type variables, but with
 553         -- common variables where the scrutinee and result must have the same type
 554         -- These are variables that appear in *any* arg of *any* of the
 555         -- relevant constructors *except* in the updated fields
 556         --
 557         ; let fixed_tvs = getFixedTyVars con1_tvs relevant_cons
 558               is_fixed_tv tv = tv `elemVarSet` fixed_tvs
 559               mk_inst_ty tv result_inst_ty
 560                 | is_fixed_tv tv = return result_inst_ty            -- Same as result type
 561                 | otherwise      = newFlexiTyVarTy (tyVarKind tv)  -- Fresh type, of correct kind
 562
 563         ; (_, result_inst_tys, result_inst_env) <- tcInstTyVars con1_tvs
 564         ; scrut_inst_tys <- zipWithM mk_inst_ty con1_tvs result_inst_tys
 565
 566         ; let result_ty     = substTy result_inst_env con1_res_ty
 567               con1_arg_tys' = map (substTy result_inst_env) con1_arg_tys
 568               scrut_subst   = zipTopTvSubst con1_tvs scrut_inst_tys
 569               scrut_ty      = substTy scrut_subst con1_res_ty
 570
 571         -- STEP 5
 572         -- Typecheck the thing to be updated, and the bindings
 573         ; record_expr' <- tcMonoExpr record_expr scrut_ty
 574         ; rbinds'      <- tcRecordBinds con1 con1_arg_tys' rbinds
 575
 576         ; let origin = RecordUpdOrigin
 577         ; co_fn <- tcSubExp origin result_ty res_ty
 578
 579         -- STEP 6: Deal with the stupid theta
 580         ; let theta' = substTheta scrut_subst (dataConStupidTheta con1)
 581         ; instStupidTheta origin theta'
 582
 583         -- Step 7: make a cast for the scrutinee, in the case that it's from a type family
 584         ; let scrut_co | Just co_con <- tyConFamilyCoercion_maybe tycon
 585                        = WpCast $ mkTyConApp co_con scrut_inst_tys
 586                        | otherwise
 587                        = idHsWrapper
 588
 589         -- Phew!
 590         ; return (mkHsWrap co_fn (RecordUpd (mkLHsWrap scrut_co record_expr') rbinds'
 591                                         relevant_cons scrut_inst_tys result_inst_tys)) }
 592   where
 593     upd_fld_names = hsRecFields rbinds
 594
 595     getFixedTyVars :: [TyVar] -> [DataCon] -> TyVarSet
 596     -- These tyvars must not change across the updates
 597     getFixedTyVars tvs1 cons
 598       = mkVarSet [tv1 | con <- cons
 599                       , let (tvs, theta, arg_tys, _) = dataConSig con
 600                             flds = dataConFieldLabels con
 601                             fixed_tvs = exactTyVarsOfTypes fixed_tys
 602                                     -- fixed_tys: See Note [Type of a record update]
 603                                         `unionVarSet` tyVarsOfTheta theta
 604                                     -- Universally-quantified tyvars that
 605                                     -- appear in any of the *implicit*
 606                                     -- arguments to the constructor are fixed
 607                                     -- See Note [Implict type sharing]
 608
 609                             fixed_tys = [ty | (fld,ty) <- zip flds arg_tys
 610                                             , not (fld `elem` upd_fld_names)]
 611                       , (tv1,tv) <- tvs1 `zip` tvs      -- Discards existentials in tvs
 612                       , tv `elemVarSet` fixed_tvs ]
 613 \end{code}
 614
 615 %************************************************************************
 616 %*                                                                      *
 617         Arithmetic sequences                    e.g. [a,b..]
 618         and their parallel-array counterparts   e.g. [: a,b.. :]
 619
 620 %*                                                                      *
 621 %************************************************************************
 622
 623 \begin{code}
 624 tcExpr (ArithSeq _ seq@(From expr)) res_ty
 625   = do  { (elt_ty, coi) <- boxySplitListTy res_ty
 626         ; expr' <- tcPolyExpr expr elt_ty
 627         ; enum_from <- newMethodFromName (ArithSeqOrigin seq)
 628                               elt_ty enumFromName
 629         ; return $ mkHsWrapCoI coi (ArithSeq (HsVar enum_from) (From expr')) }
 630
 631 tcExpr in_expr@(ArithSeq _ seq@(FromThen expr1 expr2)) res_ty
 632   = do  { (elt_ty, coi) <- boxySplitListTy res_ty
 633         ; expr1' <- tcPolyExpr expr1 elt_ty
 634         ; expr2' <- tcPolyExpr expr2 elt_ty
 635         ; enum_from_then <- newMethodFromName (ArithSeqOrigin seq)
 636                               elt_ty enumFromThenName
 637         ; return $ mkHsWrapCoI coi
 638                     (ArithSeq (HsVar enum_from_then) (FromThen expr1' expr2')) }
 639
 640 tcExpr in_expr@(ArithSeq _ seq@(FromTo expr1 expr2)) res_ty
 641   = do  { (elt_ty, coi) <- boxySplitListTy res_ty
 642         ; expr1' <- tcPolyExpr expr1 elt_ty
 643         ; expr2' <- tcPolyExpr expr2 elt_ty
 644         ; enum_from_to <- newMethodFromName (ArithSeqOrigin seq)
 645                               elt_ty enumFromToName
 646         ; return $ mkHsWrapCoI coi
 647                      (ArithSeq (HsVar enum_from_to) (FromTo expr1' expr2')) }
 648
 649 tcExpr in_expr@(ArithSeq _ seq@(FromThenTo expr1 expr2 expr3)) res_ty
 650   = do  { (elt_ty, coi) <- boxySplitListTy res_ty
 651         ; expr1' <- tcPolyExpr expr1 elt_ty
 652         ; expr2' <- tcPolyExpr expr2 elt_ty
 653         ; expr3' <- tcPolyExpr expr3 elt_ty
 654         ; eft <- newMethodFromName (ArithSeqOrigin seq)
 655                       elt_ty enumFromThenToName
 656         ; return $ mkHsWrapCoI coi
 657                      (ArithSeq (HsVar eft) (FromThenTo expr1' expr2' expr3')) }
 658
 659 tcExpr in_expr@(PArrSeq _ seq@(FromTo expr1 expr2)) res_ty
 660   = do  { (elt_ty, coi) <- boxySplitPArrTy res_ty
 661         ; expr1' <- tcPolyExpr expr1 elt_ty
 662         ; expr2' <- tcPolyExpr expr2 elt_ty
 663         ; enum_from_to <- newMethodFromName (PArrSeqOrigin seq)
 664                                       elt_ty enumFromToPName
 665         ; return $ mkHsWrapCoI coi
 666                      (PArrSeq (HsVar enum_from_to) (FromTo expr1' expr2')) }
 667
 668 tcExpr in_expr@(PArrSeq _ seq@(FromThenTo expr1 expr2 expr3)) res_ty
 669   = do  { (elt_ty, coi) <- boxySplitPArrTy res_ty
 670         ; expr1' <- tcPolyExpr expr1 elt_ty
 671         ; expr2' <- tcPolyExpr expr2 elt_ty
 672         ; expr3' <- tcPolyExpr expr3 elt_ty
 673         ; eft <- newMethodFromName (PArrSeqOrigin seq)
 674                       elt_ty enumFromThenToPName
 675         ; return $ mkHsWrapCoI coi
 676                      (PArrSeq (HsVar eft) (FromThenTo expr1' expr2' expr3')) }
 677
 678 tcExpr (PArrSeq _ _) _
 679   = panic "TcExpr.tcMonoExpr: Infinite parallel array!"
 680     -- the parser shouldn't have generated it and the renamer shouldn't have
 681     -- let it through
 682 \end{code}
 683
 684
 685 %************************************************************************
 686 %*                                                                      *
 687                 Template Haskell
 688 %*                                                                      *
 689 %************************************************************************
 690
 691 \begin{code}
 692 #ifdef GHCI     /* Only if bootstrapped */
 693         -- Rename excludes these cases otherwise
 694 tcExpr (HsSpliceE splice) res_ty = tcSpliceExpr splice res_ty
 695 tcExpr (HsBracket brack)  res_ty = do   { e <- tcBracket brack res_ty
 696                                         ; return (unLoc e) }
 697 tcExpr e@(HsQuasiQuoteE _) res_ty =
 698     pprPanic "Should never see HsQuasiQuoteE in type checker" (ppr e)
 699 #endif /* GHCI */
 700 \end{code}
 701
 702
 703 %************************************************************************
 704 %*                                                                      *
 705                 Catch-all
 706 %*                                                                      *
 707 %************************************************************************
 708
 709 \begin{code}
 710 tcExpr other _ = pprPanic "tcMonoExpr" (ppr other)
 711 \end{code}
 712
 713
 714 %************************************************************************
 715 %*                                                                      *
 716                 Applications
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 \begin{code}
 721 ---------------------------
 722 tcApp :: HsExpr Name                            -- Function
 723       -> Arity                                  -- Number of args reqd
 724       -> ArgChecker results
 725       -> BoxyRhoType                            -- Result type
 726       -> TcM (HsExpr TcId, results)
 727
 728 -- (tcFun fun n_args arg_checker res_ty)
 729 -- The argument type checker, arg_checker, will be passed exactly n_args types
 730
 731 tcApp (HsVar fun_name) n_args arg_checker res_ty
 732   = tcIdApp fun_name n_args arg_checker res_ty
 733
 734 tcApp fun n_args arg_checker res_ty     -- The vanilla case (rula APP)
 735   = do  { arg_boxes  <- newBoxyTyVars (replicate n_args argTypeKind)
 736         ; fun'       <- tcExpr fun (mkFunTys (mkTyVarTys arg_boxes) res_ty)
 737         ; arg_tys'   <- mapM readFilledBox arg_boxes
 738         ; (_, args') <- arg_checker [] [] arg_tys'      -- Yuk
 739         ; return (fun', args') }
 740
 741 ---------------------------
 742 tcIdApp :: Name                                 -- Function
 743         -> Arity                                -- Number of args reqd
 744         -> ArgChecker results   -- The arg-checker guarantees to fill all boxes in the arg types
 745         -> BoxyRhoType                          -- Result type
 746         -> TcM (HsExpr TcId, results)
 747
 748 -- Call         (f e1 ... en) :: res_ty
 749 -- Type         f :: forall a b c. theta => fa_1 -> ... -> fa_k -> fres
 750 --                      (where k <= n; fres has the rest)
 751 -- NB:  if k < n then the function doesn't have enough args, and
 752 --      presumably fres is a type variable that we are going to
 753 --      instantiate with a function type
 754 --
 755 -- Then         fres <= bx_(k+1) -> ... -> bx_n -> res_ty
 756
 757 tcIdApp fun_name n_args arg_checker res_ty
 758   = do  { let orig = OccurrenceOf fun_name
 759         ; (fun, fun_ty) <- lookupFun orig fun_name
 760
 761         -- Split up the function type
 762         ; let (tv_theta_prs, rho) = tcMultiSplitSigmaTy fun_ty
 763               (fun_arg_tys, fun_res_ty) = tcSplitFunTysN rho n_args
 764
 765               qtvs = concatMap fst tv_theta_prs         -- Quantified tyvars
 766               arg_qtvs = exactTyVarsOfTypes fun_arg_tys
 767               res_qtvs = exactTyVarsOfType fun_res_ty
 768                 -- NB: exactTyVarsOfType.  See Note [Silly type synonyms in smart-app]
 769               tau_qtvs = arg_qtvs `unionVarSet` res_qtvs
 770               k              = length fun_arg_tys       -- k <= n_args
 771               n_missing_args = n_args - k               -- Always >= 0
 772
 773         -- Match the result type of the function with the
 774         -- result type of the context, to get an inital substitution
 775         ; extra_arg_boxes <- newBoxyTyVars (replicate n_missing_args argTypeKind)
 776         ; let extra_arg_tys' = mkTyVarTys extra_arg_boxes
 777               res_ty'        = mkFunTys extra_arg_tys' res_ty
 778         ; qtys' <- preSubType qtvs tau_qtvs fun_res_ty res_ty'
 779
 780         -- Typecheck the arguments!
 781         -- Doing so will fill arg_qtvs and extra_arg_tys'
 782         ; (qtys'', args') <- arg_checker qtvs qtys' (fun_arg_tys ++ extra_arg_tys')
 783
 784         -- Strip boxes from the qtvs that have been filled in by the arg checking
 785         ; extra_arg_tys'' <- mapM readFilledBox extra_arg_boxes
 786
 787         -- Result subsumption
 788         -- This fills in res_qtvs
 789         ; let res_subst = zipOpenTvSubst qtvs qtys''
 790               fun_res_ty'' = substTy res_subst fun_res_ty
 791               res_ty'' = mkFunTys extra_arg_tys'' res_ty
 792         ; co_fn <- tcSubExp orig fun_res_ty'' res_ty''
 793
 794         -- And pack up the results
 795         -- By applying the coercion just to the *function* we can make
 796         -- tcFun work nicely for OpApp and Sections too
 797         ; fun' <- instFun orig fun res_subst tv_theta_prs
 798         ; co_fn' <- wrapFunResCoercion (substTys res_subst fun_arg_tys) co_fn
 799         ; traceTc (text "tcIdApp: " <+> ppr (mkHsWrap co_fn' fun') <+> ppr tv_theta_prs <+> ppr co_fn' <+> ppr fun')
 800         ; return (mkHsWrap co_fn' fun', args') }
 801 \end{code}
 802
 803 Note [Silly type synonyms in smart-app]
 804 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 805 When we call sripBoxyType, all of the boxes should be filled
 806 in.  But we need to be careful about type synonyms:
 807         type T a = Int
 808         f :: T a -> Int
 809         ...(f x)...
 810 In the call (f x) we'll typecheck x, expecting it to have type
 811 (T box).  Usually that would fill in the box, but in this case not;
 812 because 'a' is discarded by the silly type synonym T.  So we must
 813 use exactTyVarsOfType to figure out which type variables are free
 814 in the argument type.
 815
 816 \begin{code}
 817 -- tcId is a specialisation of tcIdApp when there are no arguments
 818 -- tcId f ty = do { (res, _) <- tcIdApp f [] (\[] -> return ()) ty
 819 --                ; return res }
 820
 821 tcId :: InstOrigin
 822      -> Name                                    -- Function
 823      -> BoxyRhoType                             -- Result type
 824      -> TcM (HsExpr TcId)
 825 tcId orig fun_name res_ty
 826   = do  { traceTc (text "tcId" <+> ppr fun_name <+> ppr res_ty)
 827         ; (fun, fun_ty) <- lookupFun orig fun_name
 828
 829         -- Split up the function type
 830         ; let (tv_theta_prs, fun_tau) = tcMultiSplitSigmaTy fun_ty
 831               qtvs = concatMap fst tv_theta_prs -- Quantified tyvars
 832               tau_qtvs = exactTyVarsOfType fun_tau      -- Mentioned in the tau part
 833         ; qtv_tys <- preSubType qtvs tau_qtvs fun_tau res_ty
 834
 835         -- Do the subsumption check wrt the result type
 836         ; let res_subst = zipTopTvSubst qtvs qtv_tys
 837               fun_tau'  = substTy res_subst fun_tau
 838
 839         ; co_fn <- tcSubExp orig fun_tau' res_ty
 840
 841         -- And pack up the results
 842         ; fun' <- instFun orig fun res_subst tv_theta_prs
 843         ; traceTc (text "tcId yields" <+> ppr (mkHsWrap co_fn fun'))
 844         ; return (mkHsWrap co_fn fun') }
 845
 846 --      Note [Push result type in]
 847 --
 848 -- Unify with expected result before (was: after) type-checking the args
 849 -- so that the info from res_ty (was: args) percolates to args (was actual_res_ty).
 850 -- This is when we might detect a too-few args situation.
 851 -- (One can think of cases when the opposite order would give
 852 -- a better error message.)
 853 -- [March 2003: I'm experimenting with putting this first.  Here's an
 854 --              example where it actually makes a real difference
 855 --    class C t a b | t a -> b
 856 --    instance C Char a Bool
 857 --
 858 --    data P t a = forall b. (C t a b) => MkP b
 859 --    data Q t   = MkQ (forall a. P t a)
 860
 861 --    f1, f2 :: Q Char;
 862 --    f1 = MkQ (MkP True)
 863 --    f2 = MkQ (MkP True :: forall a. P Char a)
 864 --
 865 -- With the change, f1 will type-check, because the 'Char' info from
 866 -- the signature is propagated into MkQ's argument. With the check
 867 -- in the other order, the extra signature in f2 is reqd.]
 868
 869 ---------------------------
 870 tcSyntaxOp :: InstOrigin -> HsExpr Name -> TcType -> TcM (HsExpr TcId)
 871 -- Typecheck a syntax operator, checking that it has the specified type
 872 -- The operator is always a variable at this stage (i.e. renamer output)
 873 tcSyntaxOp orig (HsVar op) ty = tcId orig op ty
 874 tcSyntaxOp orig other      ty = pprPanic "tcSyntaxOp" (ppr other)
 875
 876 ---------------------------
 877 instFun :: InstOrigin
 878         -> HsExpr TcId
 879         -> TvSubst                -- The instantiating substitution
 880         -> [([TyVar], ThetaType)] -- Stuff to instantiate
 881         -> TcM (HsExpr TcId)
 882
 883 instFun orig fun subst []
 884   = return fun          -- Common short cut
 885
 886 instFun orig fun subst tv_theta_prs
 887   = do  { let ty_theta_prs' = map subst_pr tv_theta_prs
 888         ; traceTc (text "instFun" <+> ppr ty_theta_prs')
 889                 -- Make two ad-hoc checks
 890         ; doStupidChecks fun ty_theta_prs'
 891
 892                 -- Now do normal instantiation
 893         ; method_sharing <- doptM Opt_MethodSharing
 894         ; result <- go method_sharing True fun ty_theta_prs'
 895         ; traceTc (text "instFun result" <+> ppr result)
 896         ; return result
 897         }
 898   where
 899     subst_pr (tvs, theta)
 900         = (substTyVars subst tvs, substTheta subst theta)
 901
 902     go _ _ fun [] = do {traceTc (text "go _ _ fun [] returns" <+> ppr fun) ; return fun }
 903
 904     go method_sharing True (HsVar fun_id) ((tys,theta) : prs)
 905         | want_method_inst method_sharing theta
 906         = do { traceTc (text "go (HsVar fun_id) ((tys,theta) : prs) | want_method_inst theta")
 907              ; meth_id <- newMethodWithGivenTy orig fun_id tys
 908              ; go method_sharing False (HsVar meth_id) prs }
 909                 -- Go round with 'False' to prevent further use
 910                 -- of newMethod: see Note [Multiple instantiation]
 911
 912     go method_sharing _ fun ((tys, theta) : prs)
 913         = do { co_fn <- instCall orig tys theta
 914              ; traceTc (text "go yields co_fn" <+> ppr co_fn)
 915              ; go method_sharing False (HsWrap co_fn fun) prs }
 916
 917         -- See Note [No method sharing]
 918     want_method_inst method_sharing theta =  not (null theta)   -- Overloaded
 919                                           && method_sharing
 920 \end{code}
 921
 922 Note [Multiple instantiation]
 923 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 924 We are careful never to make a MethodInst that has, as its meth_id, another MethodInst.
 925 For example, consider
 926         f :: forall a. Eq a => forall b. Ord b => a -> b
 927 At a call to f, at say [Int, Bool], it's tempting to translate the call to
 928
 929         f_m1
 930   where
 931         f_m1 :: forall b. Ord b => Int -> b
 932         f_m1 = f Int dEqInt
 933
 934         f_m2 :: Int -> Bool
 935         f_m2 = f_m1 Bool dOrdBool
 936
 937 But notice that f_m2 has f_m1 as its meth_id.  Now the danger is that if we do
 938 a tcSimplCheck with a Given f_mx :: f Int dEqInt, we may make a binding
 939         f_m1 = f_mx
 940 But it's entirely possible that f_m2 will continue to float out, because it
 941 mentions no type variables.  Result, f_m1 isn't in scope.
 942
 943 Here's a concrete example that does this (test tc200):
 944
 945     class C a where
 946       f :: Eq b => b -> a -> Int
 947       baz :: Eq a => Int -> a -> Int
 948
 949     instance C Int where
 950       baz = f
 951
 952 Current solution: only do the "method sharing" thing for the first type/dict
 953 application, not for the iterated ones.  A horribly subtle point.
 954
 955 Note [No method sharing]
 956 ~~~~~~~~~~~~~~~~~~~~~~~~
 957 The -fno-method-sharing flag controls what happens so far as the LIE
 958 is concerned.  The default case is that for an overloaded function we
 959 generate a "method" Id, and add the Method Inst to the LIE.  So you get
 960 something like
 961         f :: Num a => a -> a
 962         f = /\a (d:Num a) -> let m = (+) a d in \ (x:a) -> m x x
 963 If you specify -fno-method-sharing, the dictionary application
 964 isn't shared, so we get
 965         f :: Num a => a -> a
 966         f = /\a (d:Num a) (x:a) -> (+) a d x x
 967 This gets a bit less sharing, but
 968         a) it's better for RULEs involving overloaded functions
 969         b) perhaps fewer separated lambdas
 970
 971 Note [Left to right]
 972 ~~~~~~~~~~~~~~~~~~~~
 973 tcArgs implements a left-to-right order, which goes beyond what is described in the
 974 impredicative type inference paper.  In particular, it allows
 975         runST $ foo
 976 where runST :: (forall s. ST s a) -> a
 977 When typechecking the application of ($)::(a->b) -> a -> b, we first check that
 978 runST has type (a->b), thereby filling in a=forall s. ST s a.  Then we un-box this type
 979 before checking foo.  The left-to-right order really helps here.
 980
 981 \begin{code}
 982 tcArgs :: LHsExpr Name                          -- The function (for error messages)
 983        -> [LHsExpr Name]                        -- Actual args
 984        -> ArgChecker [LHsExpr TcId]
 985
 986 type ArgChecker results
 987    = [TyVar] -> [TcSigmaType]           -- Current instantiation
 988    -> [TcSigmaType]                     -- Expected arg types (**before** applying the instantiation)
 989    -> TcM ([TcSigmaType], results)      -- Resulting instaniation and args
 990
 991 tcArgs fun args qtvs qtys arg_tys
 992   = go 1 qtys args arg_tys
 993   where
 994     go n qtys [] [] = return (qtys, [])
 995     go n qtys (arg:args) (arg_ty:arg_tys)
 996         = do { arg' <- tcArg fun n arg qtvs qtys arg_ty
 997              ; qtys' <- mapM refineBox qtys     -- Exploit new info
 998              ; (qtys'', args') <- go (n+1) qtys' args arg_tys
 999              ; return (qtys'', arg':args') }
1000     go n qtys args arg_tys = panic "tcArgs"
1001
1002 tcArg :: LHsExpr Name                           -- The function
1003       -> Int                                    --   and arg number (for error messages)
1004       -> LHsExpr Name
1005       -> [TyVar] -> [TcSigmaType]               -- Instantiate the arg type like this
1006       -> BoxySigmaType
1007       -> TcM (LHsExpr TcId)                     -- Resulting argument
1008 tcArg fun arg_no arg qtvs qtys ty
1009   = addErrCtxt (funAppCtxt fun arg arg_no) $
1010     tcPolyExprNC arg (substTyWith qtvs qtys ty)
1011 \end{code}
1012
1013
1014 Note [tagToEnum#]
1015 ~~~~~~~~~~~~~~~~~
1016 Nasty check to ensure that tagToEnum# is applied to a type that is an
1017 enumeration TyCon.  Unification may refine the type later, but this
1018 check won't see that, alas.  It's crude but it works.
1019
1020 Here's are two cases that should fail
1021         f :: forall a. a
1022         f = tagToEnum# 0        -- Can't do tagToEnum# at a type variable
1023
1024         g :: Int
1025         g = tagToEnum# 0        -- Int is not an enumeration
1026
1027
1028 \begin{code}
1029 doStupidChecks :: HsExpr TcId
1030                -> [([TcType], ThetaType)]
1031                -> TcM ()
1032 -- Check two tiresome and ad-hoc cases
1033 -- (a) the "stupid theta" for a data con; add the constraints
1034 --     from the "stupid theta" of a data constructor (sigh)
1035 -- (b) deal with the tagToEnum# problem: see Note [tagToEnum#]
1036
1037 doStupidChecks (HsVar fun_id) ((tys,_):_)
1038   | Just con <- isDataConId_maybe fun_id   -- (a)
1039   = addDataConStupidTheta con tys
1040
1041   | fun_id `hasKey` tagToEnumKey           -- (b)
1042   = do  { tys' <- zonkTcTypes tys
1043         ; checkTc (ok tys') (tagToEnumError tys')
1044         }
1045   where
1046     ok []       = False
1047     ok (ty:tys) = case tcSplitTyConApp_maybe ty of
1048                         Just (tc,_) -> isEnumerationTyCon tc
1049                         Nothing     -> False
1050
1051 doStupidChecks fun tv_theta_prs
1052   = return () -- The common case
1053
1054
1055 tagToEnumError tys
1056   = hang (ptext (sLit "Bad call to tagToEnum#") <+> at_type)
1057          2 (vcat [ptext (sLit "Specify the type by giving a type signature"),
1058                   ptext (sLit "e.g. (tagToEnum# x) :: Bool")])
1059   where
1060     at_type | null tys = empty  -- Probably never happens
1061             | otherwise = ptext (sLit "at type") <+> ppr (head tys)
1062 \end{code}
1063
1064 %************************************************************************
1065 %*                                                                      *
1066 \subsection{@tcId@ typechecks an identifier occurrence}
1067 %*                                                                      *
1068 %************************************************************************
1069
1070 \begin{code}
1071 lookupFun :: InstOrigin -> Name -> TcM (HsExpr TcId, TcType)
1072 lookupFun orig id_name
1073   = do  { thing <- tcLookup id_name
1074         ; case thing of
1075             AGlobal (ADataCon con) -> return (HsVar wrap_id, idType wrap_id)
1076                                    where
1077                                       wrap_id = dataConWrapId con
1078
1079             AGlobal (AnId id)
1080                 | isNaughtyRecordSelector id -> failWithTc (naughtyRecordSel id)
1081                 | otherwise                  -> return (HsVar id, idType id)
1082                 -- A global cannot possibly be ill-staged
1083                 -- nor does it need the 'lifting' treatment
1084
1085             ATcId { tct_id = id, tct_type = ty, tct_co = mb_co, tct_level = lvl }
1086                 | isNaughtyRecordSelector id -> failWithTc (naughtyRecordSel id)
1087                                           -- Note [Local record selectors]
1088                 | otherwise
1089                 -> do { thLocalId orig id ty lvl
1090                       ; case mb_co of
1091                           Unrefineable    -> return (HsVar id, ty)
1092                           Rigid co        -> return (mkHsWrap co (HsVar id), ty)
1093                           Wobbly          -> traceTc (text "lookupFun" <+> ppr id) >> return (HsVar id, ty)     -- Wobbly, or no free vars
1094                           WobblyInvisible -> failWithTc (ppr id_name <+> ptext (sLit " not in scope because it has a wobbly type (solution: add a type annotation)"))
1095                       }
1096
1097             other -> failWithTc (ppr other <+> ptext (sLit "used where a value identifer was expected"))
1098     }
1099
1100 #ifndef GHCI  /* GHCI and TH is off */
1101 --------------------------------------
1102 -- thLocalId : Check for cross-stage lifting
1103 thLocalId orig id id_ty th_bind_lvl
1104   = return ()
1105
1106 #else         /* GHCI and TH is on */
1107 thLocalId orig id id_ty th_bind_lvl
1108   = do  { use_stage <- getStage -- TH case
1109         ; case use_stage of
1110             Brack use_lvl ps_var lie_var | use_lvl > th_bind_lvl
1111                   -> thBrackId orig id ps_var lie_var
1112             other -> do { checkWellStaged (quotes (ppr id)) th_bind_lvl use_stage
1113                         ; return id }
1114         }
1115
1116 --------------------------------------
1117 thBrackId orig id ps_var lie_var
1118   | thTopLevelId id
1119   =     -- Top-level identifiers in this module,
1120         -- (which have External Names)
1121         -- are just like the imported case:
1122         -- no need for the 'lifting' treatment
1123         -- E.g.  this is fine:
1124         --   f x = x
1125         --   g y = [| f 3 |]
1126         -- But we do need to put f into the keep-alive
1127         -- set, because after desugaring the code will
1128         -- only mention f's *name*, not f itself.
1129     do  { keepAliveTc id; return id }
1130
1131   | otherwise
1132   =     -- Nested identifiers, such as 'x' in
1133         -- E.g. \x -> [| h x |]
1134         -- We must behave as if the reference to x was
1135         --      h $(lift x)
1136         -- We use 'x' itself as the splice proxy, used by
1137         -- the desugarer to stitch it all back together.
1138         -- If 'x' occurs many times we may get many identical
1139         -- bindings of the same splice proxy, but that doesn't
1140         -- matter, although it's a mite untidy.
1141     do  { let id_ty = idType id
1142         ; checkTc (isTauTy id_ty) (polySpliceErr id)
1143                -- If x is polymorphic, its occurrence sites might
1144                -- have different instantiations, so we can't use plain
1145                -- 'x' as the splice proxy name.  I don't know how to
1146                -- solve this, and it's probably unimportant, so I'm
1147                -- just going to flag an error for now
1148
1149         ; id_ty' <- zapToMonotype id_ty
1150                 -- The id_ty might have an OpenTypeKind, but we
1151                 -- can't instantiate the Lift class at that kind,
1152                 -- so we zap it to a LiftedTypeKind monotype
1153                 -- C.f. the call in TcPat.newLitInst
1154
1155         ; lift <- if isStringTy id_ty' then
1156                      tcLookupId DsMeta.liftStringName
1157                      -- See Note [Lifting strings]
1158                   else
1159                      setLIEVar lie_var  $ do  -- Put the 'lift' constraint into the right LIE
1160                      newMethodFromName orig id_ty' DsMeta.liftName
1161
1162                    -- Update the pending splices
1163         ; ps <- readMutVar ps_var
1164         ; writeMutVar ps_var ((idName id, nlHsApp (nlHsVar lift) (nlHsVar id)) : ps)
1165
1166         ; return id }
1167 #endif /* GHCI */
1168 \end{code}
1169
1170 Note [Lifting strings]
1171 ~~~~~~~~~~~~~~~~~~~~~~
1172 If we see $(... [| s |] ...) where s::String, we don't want to
1173 generate a mass of Cons (CharL 'x') (Cons (CharL 'y') ...)) etc.
1174 So this conditional short-circuits the lifting mechanism to generate
1175 (liftString "xy") in that case.  I didn't want to use overlapping instances
1176 for the Lift class in TH.Syntax, because that can lead to overlapping-instance
1177 errors in a polymorphic situation.
1178
1179 If this check fails (which isn't impossible) we get another chance; see
1180 Note [Converting strings] in Convert.lhs
1181
1182 Local record selectors
1183 ~~~~~~~~~~~~~~~~~~~~~~
1184 Record selectors for TyCons in this module are ordinary local bindings,
1185 which show up as ATcIds rather than AGlobals.  So we need to check for
1186 naughtiness in both branches.  c.f. TcTyClsBindings.mkAuxBinds.
1187
1188
1189 %************************************************************************
1190 %*                                                                      *
1191 \subsection{Record bindings}
1192 %*                                                                      *
1193 %************************************************************************
1194
1195 Game plan for record bindings
1196 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1197 1. Find the TyCon for the bindings, from the first field label.
1198
1199 2. Instantiate its tyvars and unify (T a1 .. an) with expected_ty.
1200
1201 For each binding field = value
1202
1203 3. Instantiate the field type (from the field label) using the type
1204    envt from step 2.
1205
1206 4  Type check the value using tcArg, passing the field type as
1207    the expected argument type.
1208
1209 This extends OK when the field types are universally quantified.
1210
1211
1212 \begin{code}
1213 tcRecordBinds
1214         :: DataCon
1215         -> [TcType]     -- Expected type for each field
1216         -> HsRecordBinds Name
1217         -> TcM (HsRecordBinds TcId)
1218
1219 tcRecordBinds data_con arg_tys (HsRecFields rbinds dd)
1220   = do  { mb_binds <- mapM do_bind rbinds
1221         ; return (HsRecFields (catMaybes mb_binds) dd) }
1222   where
1223     flds_w_tys = zipEqual "tcRecordBinds" (dataConFieldLabels data_con) arg_tys
1224     do_bind fld@(HsRecField { hsRecFieldId = L loc field_lbl, hsRecFieldArg = rhs })
1225       | Just field_ty <- assocMaybe flds_w_tys field_lbl
1226       = addErrCtxt (fieldCtxt field_lbl)        $
1227         do { rhs' <- tcPolyExprNC rhs field_ty
1228            ; let field_id = mkUserLocal (nameOccName field_lbl)
1229                                         (nameUnique field_lbl)
1230                                         field_ty loc
1231                 -- Yuk: the field_id has the *unique* of the selector Id
1232                 --          (so we can find it easily)
1233                 --      but is a LocalId with the appropriate type of the RHS
1234                 --          (so the desugarer knows the type of local binder to make)
1235            ; return (Just (fld { hsRecFieldId = L loc field_id, hsRecFieldArg = rhs' })) }
1236       | otherwise
1237       = do { addErrTc (badFieldCon data_con field_lbl)
1238            ; return Nothing }
1239
1240 checkMissingFields :: DataCon -> HsRecordBinds Name -> TcM ()
1241 checkMissingFields data_con rbinds
1242   | null field_labels   -- Not declared as a record;
1243                         -- But C{} is still valid if no strict fields
1244   = if any isMarkedStrict field_strs then
1245         -- Illegal if any arg is strict
1246         addErrTc (missingStrictFields data_con [])
1247     else
1248         return ()
1249
1250   | otherwise = do              -- A record
1251     unless (null missing_s_fields)
1252            (addErrTc (missingStrictFields data_con missing_s_fields))
1253
1254     warn <- doptM Opt_WarnMissingFields
1255     unless (not (warn && notNull missing_ns_fields))
1256            (warnTc True (missingFields data_con missing_ns_fields))
1257
1258   where
1259     missing_s_fields
1260         = [ fl | (fl, str) <- field_info,
1261                  isMarkedStrict str,
1262                  not (fl `elem` field_names_used)
1263           ]
1264     missing_ns_fields
1265         = [ fl | (fl, str) <- field_info,
1266                  not (isMarkedStrict str),
1267                  not (fl `elem` field_names_used)
1268           ]
1269
1270     field_names_used = hsRecFields rbinds
1271     field_labels     = dataConFieldLabels data_con
1272
1273     field_info = zipEqual "missingFields"
1274                           field_labels
1275                           field_strs
1276
1277     field_strs = dataConStrictMarks data_con
1278 \end{code}
1279
1280 %************************************************************************
1281 %*                                                                      *
1282 \subsection{Errors and contexts}
1283 %*                                                                      *
1284 %************************************************************************
1285
1286 Boring and alphabetical:
1287 \begin{code}
1288 addExprErrCtxt :: OutputableBndr id => LHsExpr id -> TcM a -> TcM a
1289 addExprErrCtxt expr = addErrCtxt (exprCtxt (unLoc expr))
1290
1291 exprCtxt expr
1292   = hang (ptext (sLit "In the expression:")) 4 (ppr expr)
1293
1294 fieldCtxt field_name
1295   = ptext (sLit "In the") <+> quotes (ppr field_name) <+> ptext (sLit "field of a record")
1296
1297 funAppCtxt fun arg arg_no
1298   = hang (hsep [ ptext (sLit "In the"), speakNth arg_no, ptext (sLit "argument of"),
1299                     quotes (ppr fun) <> text ", namely"])
1300          4 (quotes (ppr arg))
1301
1302 badFieldTypes prs
1303   = hang (ptext (sLit "Record update for insufficiently polymorphic field")
1304                          <> plural prs <> colon)
1305        2 (vcat [ ppr f <+> dcolon <+> ppr ty | (f,ty) <- prs ])
1306
1307 badFieldsUpd rbinds
1308   = hang (ptext (sLit "No constructor has all these fields:"))
1309          4 (pprQuotedList (hsRecFields rbinds))
1310
1311 naughtyRecordSel sel_id
1312   = ptext (sLit "Cannot use record selector") <+> quotes (ppr sel_id) <+>
1313     ptext (sLit "as a function due to escaped type variables") $$
1314     ptext (sLit "Probable fix: use pattern-matching syntax instead")
1315
1316 notSelector field
1317   = hsep [quotes (ppr field), ptext (sLit "is not a record selector")]
1318
1319 missingStrictFields :: DataCon -> [FieldLabel] -> SDoc
1320 missingStrictFields con fields
1321   = header <> rest
1322   where
1323     rest | null fields = empty  -- Happens for non-record constructors
1324                                 -- with strict fields
1325          | otherwise   = colon <+> pprWithCommas ppr fields
1326
1327     header = ptext (sLit "Constructor") <+> quotes (ppr con) <+>
1328              ptext (sLit "does not have the required strict field(s)")
1329
1330 missingFields :: DataCon -> [FieldLabel] -> SDoc
1331 missingFields con fields
1332   = ptext (sLit "Fields of") <+> quotes (ppr con) <+> ptext (sLit "not initialised:")
1333         <+> pprWithCommas ppr fields
1334
1335 -- callCtxt fun args = ptext (sLit "In the call") <+> parens (ppr (foldl mkHsApp fun args))
1336
1337 #ifdef GHCI
1338 polySpliceErr :: Id -> SDoc
1339 polySpliceErr id
1340   = ptext (sLit "Can't splice the polymorphic local variable") <+> quotes (ppr id)
1341 #endif
1342 \end{code}