compiler/typecheck/TcHsSyn.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcHsSyn: Specialisations of the @HsSyn@ syntax for the typechecker
   7
   8 This module is an extension of @HsSyn@ syntax, for use in the type
   9 checker.
  10
  11 \begin{code}
  12 module TcHsSyn (
  13         mkHsConApp, mkHsDictLet, mkHsApp,
  14         hsLitType, hsLPatType, hsPatType,
  15         mkHsAppTy, mkSimpleHsAlt,
  16         nlHsIntLit, mkVanillaTuplePat,
  17         shortCutLit, hsOverLitName,
  18
  19         mkArbitraryType,        -- Put this elsewhere?
  20
  21         -- re-exported from TcMonad
  22         TcId, TcIdSet, TcDictBinds,
  23
  24         zonkTopDecls, zonkTopExpr, zonkTopLExpr,
  25         zonkId, zonkTopBndrs
  26   ) where
  27
  28 #include "HsVersions.h"
  29
  30 -- friends:
  31 import HsSyn    -- oodles of it
  32
  33 -- others:
  34 import Id
  35
  36 import TcRnMonad
  37 import PrelNames
  38 import Type
  39 import TcType
  40 import TcMType
  41 import TysPrim
  42 import TysWiredIn
  43 import TyCon
  44 import DataCon
  45 import Name
  46 import Var
  47 import VarSet
  48 import VarEnv
  49 import Literal
  50 import BasicTypes
  51 import Maybes
  52 import Unique
  53 import SrcLoc
  54 import Util
  55 import Bag
  56 import Outputable
  57 import FastString
  58 \end{code}
  59
  60 \begin{code}
  61 -- XXX
  62 thenM :: Monad a => a b -> (b -> a c) -> a c
  63 thenM = (>>=)
  64
  65 thenM_ :: Monad a => a b -> a c -> a c
  66 thenM_ = (>>)
  67
  68 returnM :: Monad m => a -> m a
  69 returnM = return
  70
  71 mappM :: (Monad m) => (a -> m b) -> [a] -> m [b]
  72 mappM = mapM
  73 \end{code}
  74
  75
  76 %************************************************************************
  77 %*                                                                      *
  78 \subsection[mkFailurePair]{Code for pattern-matching and other failures}
  79 %*                                                                      *
  80 %************************************************************************
  81
  82 Note: If @hsLPatType@ doesn't bear a strong resemblance to @exprType@,
  83 then something is wrong.
  84 \begin{code}
  85 mkVanillaTuplePat :: [OutPat Id] -> Boxity -> Pat Id
  86 -- A vanilla tuple pattern simply gets its type from its sub-patterns
  87 mkVanillaTuplePat pats box
  88   = TuplePat pats box (mkTupleTy box (length pats) (map hsLPatType pats))
  89
  90 hsLPatType :: OutPat Id -> Type
  91 hsLPatType (L _ pat) = hsPatType pat
  92
  93 hsPatType :: Pat Id -> Type
  94 hsPatType (ParPat pat)                = hsLPatType pat
  95 hsPatType (WildPat ty)                = ty
  96 hsPatType (VarPat var)                = idType var
  97 hsPatType (VarPatOut var _)           = idType var
  98 hsPatType (BangPat pat)               = hsLPatType pat
  99 hsPatType (LazyPat pat)               = hsLPatType pat
 100 hsPatType (LitPat lit)                = hsLitType lit
 101 hsPatType (AsPat var _)               = idType (unLoc var)
 102 hsPatType (ViewPat _ _ ty)            = ty
 103 hsPatType (ListPat _ ty)              = mkListTy ty
 104 hsPatType (PArrPat _ ty)              = mkPArrTy ty
 105 hsPatType (TuplePat _ _ ty)           = ty
 106 hsPatType (ConPatOut { pat_ty = ty }) = ty
 107 hsPatType (SigPatOut _ ty)            = ty
 108 hsPatType (NPat lit _ _)              = overLitType lit
 109 hsPatType (NPlusKPat id _ _ _)        = idType (unLoc id)
 110 hsPatType (CoPat _ _ ty)              = ty
 111 hsPatType p                           = pprPanic "hsPatType" (ppr p)
 112
 113 hsLitType :: HsLit -> TcType
 114 hsLitType (HsChar _)       = charTy
 115 hsLitType (HsCharPrim _)   = charPrimTy
 116 hsLitType (HsString _)     = stringTy
 117 hsLitType (HsStringPrim _) = addrPrimTy
 118 hsLitType (HsInt _)        = intTy
 119 hsLitType (HsIntPrim _)    = intPrimTy
 120 hsLitType (HsWordPrim _)   = wordPrimTy
 121 hsLitType (HsInteger _ ty) = ty
 122 hsLitType (HsRat _ ty)     = ty
 123 hsLitType (HsFloatPrim _)  = floatPrimTy
 124 hsLitType (HsDoublePrim _) = doublePrimTy
 125 \end{code}
 126
 127 Overloaded literals. Here mainly becuase it uses isIntTy etc
 128
 129 \begin{code}
 130 shortCutLit :: OverLitVal -> TcType -> Maybe (HsExpr TcId)
 131 shortCutLit (HsIntegral i) ty
 132   | isIntTy ty && inIntRange i   = Just (HsLit (HsInt i))
 133   | isWordTy ty && inWordRange i = Just (mkLit wordDataCon (HsWordPrim i))
 134   | isIntegerTy ty               = Just (HsLit (HsInteger i ty))
 135   | otherwise                    = shortCutLit (HsFractional (fromInteger i)) ty
 136         -- The 'otherwise' case is important
 137         -- Consider (3 :: Float).  Syntactically it looks like an IntLit,
 138         -- so we'll call shortCutIntLit, but of course it's a float
 139         -- This can make a big difference for programs with a lot of
 140         -- literals, compiled without -O
 141
 142 shortCutLit (HsFractional f) ty
 143   | isFloatTy ty  = Just (mkLit floatDataCon  (HsFloatPrim f))
 144   | isDoubleTy ty = Just (mkLit doubleDataCon (HsDoublePrim f))
 145   | otherwise     = Nothing
 146
 147 shortCutLit (HsIsString s) ty
 148   | isStringTy ty = Just (HsLit (HsString s))
 149   | otherwise     = Nothing
 150
 151 mkLit :: DataCon -> HsLit -> HsExpr Id
 152 mkLit con lit = HsApp (nlHsVar (dataConWrapId con)) (nlHsLit lit)
 153
 154 ------------------------------
 155 hsOverLitName :: OverLitVal -> Name
 156 -- Get the canonical 'fromX' name for a particular OverLitVal
 157 hsOverLitName (HsIntegral {})   = fromIntegerName
 158 hsOverLitName (HsFractional {}) = fromRationalName
 159 hsOverLitName (HsIsString {})   = fromStringName
 160 \end{code}
 161
 162 %************************************************************************
 163 %*                                                                      *
 164 \subsection[BackSubst-HsBinds]{Running a substitution over @HsBinds@}
 165 %*                                                                      *
 166 %************************************************************************
 167
 168 \begin{code}
 169 -- zonkId is used *during* typechecking just to zonk the Id's type
 170 zonkId :: TcId -> TcM TcId
 171 zonkId id
 172   = zonkTcType (idType id) `thenM` \ ty' ->
 173     returnM (Id.setIdType id ty')
 174 \end{code}
 175
 176 The rest of the zonking is done *after* typechecking.
 177 The main zonking pass runs over the bindings
 178
 179  a) to convert TcTyVars to TyVars etc, dereferencing any bindings etc
 180  b) convert unbound TcTyVar to Void
 181  c) convert each TcId to an Id by zonking its type
 182
 183 The type variables are converted by binding mutable tyvars to immutable ones
 184 and then zonking as normal.
 185
 186 The Ids are converted by binding them in the normal Tc envt; that
 187 way we maintain sharing; eg an Id is zonked at its binding site and they
 188 all occurrences of that Id point to the common zonked copy
 189
 190 It's all pretty boring stuff, because HsSyn is such a large type, and
 191 the environment manipulation is tiresome.
 192
 193 \begin{code}
 194 data ZonkEnv = ZonkEnv  (TcType -> TcM Type)    -- How to zonk a type
 195                         (IdEnv Id)              -- What variables are in scope
 196         -- Maps an Id to its zonked version; both have the same Name
 197         -- Is only consulted lazily; hence knot-tying
 198
 199 emptyZonkEnv :: ZonkEnv
 200 emptyZonkEnv = ZonkEnv zonkTypeZapping emptyVarEnv
 201
 202 extendZonkEnv :: ZonkEnv -> [Id] -> ZonkEnv
 203 extendZonkEnv (ZonkEnv zonk_ty env) ids
 204   = ZonkEnv zonk_ty (extendVarEnvList env [(id,id) | id <- ids])
 205
 206 extendZonkEnv1 :: ZonkEnv -> Id -> ZonkEnv
 207 extendZonkEnv1 (ZonkEnv zonk_ty env) id
 208   = ZonkEnv zonk_ty (extendVarEnv env id id)
 209
 210 setZonkType :: ZonkEnv -> (TcType -> TcM Type) -> ZonkEnv
 211 setZonkType (ZonkEnv _ env) zonk_ty = ZonkEnv zonk_ty env
 212
 213 zonkEnvIds :: ZonkEnv -> [Id]
 214 zonkEnvIds (ZonkEnv _ env) = varEnvElts env
 215
 216 zonkIdOcc :: ZonkEnv -> TcId -> Id
 217 -- Ids defined in this module should be in the envt;
 218 -- ignore others.  (Actually, data constructors are also
 219 -- not LocalVars, even when locally defined, but that is fine.)
 220 -- (Also foreign-imported things aren't currently in the ZonkEnv;
 221 --  that's ok because they don't need zonking.)
 222 --
 223 -- Actually, Template Haskell works in 'chunks' of declarations, and
 224 -- an earlier chunk won't be in the 'env' that the zonking phase
 225 -- carries around.  Instead it'll be in the tcg_gbl_env, already fully
 226 -- zonked.  There's no point in looking it up there (except for error
 227 -- checking), and it's not conveniently to hand; hence the simple
 228 -- 'orElse' case in the LocalVar branch.
 229 --
 230 -- Even without template splices, in module Main, the checking of
 231 -- 'main' is done as a separate chunk.
 232 zonkIdOcc (ZonkEnv _zonk_ty env) id
 233   | isLocalVar id = lookupVarEnv env id `orElse` id
 234   | otherwise     = id
 235
 236 zonkIdOccs :: ZonkEnv -> [TcId] -> [Id]
 237 zonkIdOccs env ids = map (zonkIdOcc env) ids
 238
 239 -- zonkIdBndr is used *after* typechecking to get the Id's type
 240 -- to its final form.  The TyVarEnv give
 241 zonkIdBndr :: ZonkEnv -> TcId -> TcM Id
 242 zonkIdBndr env id
 243   = zonkTcTypeToType env (idType id)    `thenM` \ ty' ->
 244     returnM (Id.setIdType id ty')
 245
 246 zonkIdBndrs :: ZonkEnv -> [TcId] -> TcM [Id]
 247 zonkIdBndrs env ids = mappM (zonkIdBndr env) ids
 248
 249 zonkDictBndrs :: ZonkEnv -> [Var] -> TcM [Var]
 250 -- "Dictionary" binders can be coercion variables or dictionary variables
 251 zonkDictBndrs env ids = mappM (zonkDictBndr env) ids
 252
 253 zonkDictBndr :: ZonkEnv -> Var -> TcM Var
 254 zonkDictBndr env var | isTyVar var = return var
 255                      | otherwise   = zonkIdBndr env var
 256
 257 zonkTopBndrs :: [TcId] -> TcM [Id]
 258 zonkTopBndrs ids = zonkIdBndrs emptyZonkEnv ids
 259 \end{code}
 260
 261
 262 \begin{code}
 263 zonkTopExpr :: HsExpr TcId -> TcM (HsExpr Id)
 264 zonkTopExpr e = zonkExpr emptyZonkEnv e
 265
 266 zonkTopLExpr :: LHsExpr TcId -> TcM (LHsExpr Id)
 267 zonkTopLExpr e = zonkLExpr emptyZonkEnv e
 268
 269 zonkTopDecls :: LHsBinds TcId -> [LRuleDecl TcId] -> [LForeignDecl TcId]
 270              -> TcM ([Id],
 271                      Bag (LHsBind  Id),
 272                      [LForeignDecl Id],
 273                      [LRuleDecl    Id])
 274 zonkTopDecls binds rules fords
 275   = do  { (env, binds') <- zonkRecMonoBinds emptyZonkEnv binds
 276                         -- Top level is implicitly recursive
 277         ; rules' <- zonkRules env rules
 278         ; fords' <- zonkForeignExports env fords
 279         ; return (zonkEnvIds env, binds', fords', rules') }
 280
 281 ---------------------------------------------
 282 zonkLocalBinds :: ZonkEnv -> HsLocalBinds TcId -> TcM (ZonkEnv, HsLocalBinds Id)
 283 zonkLocalBinds env EmptyLocalBinds
 284   = return (env, EmptyLocalBinds)
 285
 286 zonkLocalBinds env (HsValBinds binds)
 287   = do  { (env1, new_binds) <- zonkValBinds env binds
 288         ; return (env1, HsValBinds new_binds) }
 289
 290 zonkLocalBinds env (HsIPBinds (IPBinds binds dict_binds))
 291   = mappM (wrapLocM zonk_ip_bind) binds `thenM` \ new_binds ->
 292     let
 293         env1 = extendZonkEnv env [ipNameName n | L _ (IPBind n _) <- new_binds]
 294     in
 295     zonkRecMonoBinds env1 dict_binds    `thenM` \ (env2, new_dict_binds) ->
 296     returnM (env2, HsIPBinds (IPBinds new_binds new_dict_binds))
 297   where
 298     zonk_ip_bind (IPBind n e)
 299         = mapIPNameTc (zonkIdBndr env) n        `thenM` \ n' ->
 300           zonkLExpr env e                       `thenM` \ e' ->
 301           returnM (IPBind n' e')
 302
 303
 304 ---------------------------------------------
 305 zonkValBinds :: ZonkEnv -> HsValBinds TcId -> TcM (ZonkEnv, HsValBinds Id)
 306 zonkValBinds _ (ValBindsIn _ _)
 307   = panic "zonkValBinds" -- Not in typechecker output
 308 zonkValBinds env (ValBindsOut binds sigs)
 309   = do  { (env1, new_binds) <- go env binds
 310         ; return (env1, ValBindsOut new_binds sigs) }
 311   where
 312     go env []         = return (env, [])
 313     go env ((r,b):bs) = do { (env1, b')  <- zonkRecMonoBinds env b
 314                            ; (env2, bs') <- go env1 bs
 315                            ; return (env2, (r,b'):bs') }
 316
 317 ---------------------------------------------
 318 zonkRecMonoBinds :: ZonkEnv -> LHsBinds TcId -> TcM (ZonkEnv, LHsBinds Id)
 319 zonkRecMonoBinds env binds
 320  = fixM (\ ~(_, new_binds) -> do
 321         { let env1 = extendZonkEnv env (collectHsBindBinders new_binds)
 322         ; binds' <- zonkMonoBinds env1 binds
 323         ; return (env1, binds') })
 324
 325 ---------------------------------------------
 326 zonkMonoBinds :: ZonkEnv -> LHsBinds TcId -> TcM (LHsBinds Id)
 327 zonkMonoBinds env binds = mapBagM (wrapLocM (zonk_bind env)) binds
 328
 329 zonk_bind :: ZonkEnv -> HsBind TcId -> TcM (HsBind Id)
 330 zonk_bind env bind@(PatBind { pat_lhs = pat, pat_rhs = grhss, pat_rhs_ty = ty})
 331   = do  { (_env, new_pat) <- zonkPat env pat            -- Env already extended
 332         ; new_grhss <- zonkGRHSs env grhss
 333         ; new_ty    <- zonkTcTypeToType env ty
 334         ; return (bind { pat_lhs = new_pat, pat_rhs = new_grhss, pat_rhs_ty = new_ty }) }
 335
 336 zonk_bind env (VarBind { var_id = var, var_rhs = expr })
 337   = zonkIdBndr env var                  `thenM` \ new_var ->
 338     zonkLExpr env expr                  `thenM` \ new_expr ->
 339     returnM (VarBind { var_id = new_var, var_rhs = new_expr })
 340
 341 zonk_bind env bind@(FunBind { fun_id = var, fun_matches = ms, fun_co_fn = co_fn })
 342   = wrapLocM (zonkIdBndr env) var       `thenM` \ new_var ->
 343     zonkCoFn env co_fn                  `thenM` \ (env1, new_co_fn) ->
 344     zonkMatchGroup env1 ms              `thenM` \ new_ms ->
 345     returnM (bind { fun_id = new_var, fun_matches = new_ms, fun_co_fn = new_co_fn })
 346
 347 zonk_bind env (AbsBinds { abs_tvs = tyvars, abs_dicts = dicts,
 348                           abs_exports = exports, abs_binds = val_binds })
 349   = ASSERT( all isImmutableTyVar tyvars )
 350     zonkDictBndrs env dicts                     `thenM` \ new_dicts ->
 351     fixM (\ ~(new_val_binds, _) ->
 352         let
 353           env1 = extendZonkEnv env new_dicts
 354           env2 = extendZonkEnv env1 (collectHsBindBinders new_val_binds)
 355         in
 356         zonkMonoBinds env2 val_binds            `thenM` \ new_val_binds ->
 357         mappM (zonkExport env2) exports         `thenM` \ new_exports ->
 358         returnM (new_val_binds, new_exports)
 359     )                                           `thenM` \ (new_val_bind, new_exports) ->
 360     returnM (AbsBinds { abs_tvs = tyvars, abs_dicts = new_dicts,
 361                         abs_exports = new_exports, abs_binds = new_val_bind })
 362   where
 363     zonkExport env (tyvars, global, local, prags)
 364         -- The tyvars are already zonked
 365         = zonkIdBndr env global                 `thenM` \ new_global ->
 366           mapM zonk_prag prags                  `thenM` \ new_prags ->
 367           returnM (tyvars, new_global, zonkIdOcc env local, new_prags)
 368     zonk_prag prag@(L _ (InlinePrag {}))  = return prag
 369     zonk_prag (L loc (SpecPrag expr ty inl))
 370         = do { expr' <- zonkExpr env expr
 371              ; ty'   <- zonkTcTypeToType env ty
 372              ; return (L loc (SpecPrag expr' ty' inl)) }
 373 \end{code}
 374
 375 %************************************************************************
 376 %*                                                                      *
 377 \subsection[BackSubst-Match-GRHSs]{Match and GRHSs}
 378 %*                                                                      *
 379 %************************************************************************
 380
 381 \begin{code}
 382 zonkMatchGroup :: ZonkEnv -> MatchGroup TcId-> TcM (MatchGroup Id)
 383 zonkMatchGroup env (MatchGroup ms ty)
 384   = do  { ms' <- mapM (zonkMatch env) ms
 385         ; ty' <- zonkTcTypeToType env ty
 386         ; return (MatchGroup ms' ty') }
 387
 388 zonkMatch :: ZonkEnv -> LMatch TcId-> TcM (LMatch Id)
 389 zonkMatch env (L loc (Match pats _ grhss))
 390   = do  { (env1, new_pats) <- zonkPats env pats
 391         ; new_grhss <- zonkGRHSs env1 grhss
 392         ; return (L loc (Match new_pats Nothing new_grhss)) }
 393
 394 -------------------------------------------------------------------------
 395 zonkGRHSs :: ZonkEnv -> GRHSs TcId -> TcM (GRHSs Id)
 396
 397 zonkGRHSs env (GRHSs grhss binds)
 398   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 399     let
 400         zonk_grhs (GRHS guarded rhs)
 401           = zonkStmts new_env guarded   `thenM` \ (env2, new_guarded) ->
 402             zonkLExpr env2 rhs          `thenM` \ new_rhs ->
 403             returnM (GRHS new_guarded new_rhs)
 404     in
 405     mappM (wrapLocM zonk_grhs) grhss    `thenM` \ new_grhss ->
 406     returnM (GRHSs new_grhss new_binds)
 407 \end{code}
 408
 409 %************************************************************************
 410 %*                                                                      *
 411 \subsection[BackSubst-HsExpr]{Running a zonkitution over a TypeCheckedExpr}
 412 %*                                                                      *
 413 %************************************************************************
 414
 415 \begin{code}
 416 zonkLExprs :: ZonkEnv -> [LHsExpr TcId] -> TcM [LHsExpr Id]
 417 zonkLExpr  :: ZonkEnv -> LHsExpr TcId   -> TcM (LHsExpr Id)
 418 zonkExpr   :: ZonkEnv -> HsExpr TcId    -> TcM (HsExpr Id)
 419
 420 zonkLExprs env exprs = mappM (zonkLExpr env) exprs
 421 zonkLExpr  env expr  = wrapLocM (zonkExpr env) expr
 422
 423 zonkExpr env (HsVar id)
 424   = returnM (HsVar (zonkIdOcc env id))
 425
 426 zonkExpr env (HsIPVar id)
 427   = returnM (HsIPVar (mapIPName (zonkIdOcc env) id))
 428
 429 zonkExpr env (HsLit (HsRat f ty))
 430   = zonkTcTypeToType env ty        `thenM` \ new_ty  ->
 431     returnM (HsLit (HsRat f new_ty))
 432
 433 zonkExpr _ (HsLit lit)
 434   = returnM (HsLit lit)
 435
 436 zonkExpr env (HsOverLit lit)
 437   = do  { lit' <- zonkOverLit env lit
 438         ; return (HsOverLit lit') }
 439
 440 zonkExpr env (HsLam matches)
 441   = zonkMatchGroup env matches  `thenM` \ new_matches ->
 442     returnM (HsLam new_matches)
 443
 444 zonkExpr env (HsApp e1 e2)
 445   = zonkLExpr env e1    `thenM` \ new_e1 ->
 446     zonkLExpr env e2    `thenM` \ new_e2 ->
 447     returnM (HsApp new_e1 new_e2)
 448
 449 zonkExpr env (HsBracketOut body bs)
 450   = mappM zonk_b bs     `thenM` \ bs' ->
 451     returnM (HsBracketOut body bs')
 452   where
 453     zonk_b (n,e) = zonkLExpr env e      `thenM` \ e' ->
 454                    returnM (n,e')
 455
 456 zonkExpr _ (HsSpliceE s) = WARN( True, ppr s ) -- Should not happen
 457                              returnM (HsSpliceE s)
 458
 459 zonkExpr env (OpApp e1 op fixity e2)
 460   = zonkLExpr env e1    `thenM` \ new_e1 ->
 461     zonkLExpr env op    `thenM` \ new_op ->
 462     zonkLExpr env e2    `thenM` \ new_e2 ->
 463     returnM (OpApp new_e1 new_op fixity new_e2)
 464
 465 zonkExpr env (NegApp expr op)
 466   = zonkLExpr env expr  `thenM` \ new_expr ->
 467     zonkExpr env op     `thenM` \ new_op ->
 468     returnM (NegApp new_expr new_op)
 469
 470 zonkExpr env (HsPar e)
 471   = zonkLExpr env e     `thenM` \new_e ->
 472     returnM (HsPar new_e)
 473
 474 zonkExpr env (SectionL expr op)
 475   = zonkLExpr env expr  `thenM` \ new_expr ->
 476     zonkLExpr env op            `thenM` \ new_op ->
 477     returnM (SectionL new_expr new_op)
 478
 479 zonkExpr env (SectionR op expr)
 480   = zonkLExpr env op            `thenM` \ new_op ->
 481     zonkLExpr env expr          `thenM` \ new_expr ->
 482     returnM (SectionR new_op new_expr)
 483
 484 zonkExpr env (HsCase expr ms)
 485   = zonkLExpr env expr          `thenM` \ new_expr ->
 486     zonkMatchGroup env ms       `thenM` \ new_ms ->
 487     returnM (HsCase new_expr new_ms)
 488
 489 zonkExpr env (HsIf e1 e2 e3)
 490   = zonkLExpr env e1    `thenM` \ new_e1 ->
 491     zonkLExpr env e2    `thenM` \ new_e2 ->
 492     zonkLExpr env e3    `thenM` \ new_e3 ->
 493     returnM (HsIf new_e1 new_e2 new_e3)
 494
 495 zonkExpr env (HsLet binds expr)
 496   = zonkLocalBinds env binds    `thenM` \ (new_env, new_binds) ->
 497     zonkLExpr new_env expr      `thenM` \ new_expr ->
 498     returnM (HsLet new_binds new_expr)
 499
 500 zonkExpr env (HsDo do_or_lc stmts body ty)
 501   = zonkStmts env stmts         `thenM` \ (new_env, new_stmts) ->
 502     zonkLExpr new_env body      `thenM` \ new_body ->
 503     zonkTcTypeToType env ty     `thenM` \ new_ty   ->
 504     returnM (HsDo (zonkDo env do_or_lc)
 505                   new_stmts new_body new_ty)
 506
 507 zonkExpr env (ExplicitList ty exprs)
 508   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 509     zonkLExprs env exprs        `thenM` \ new_exprs ->
 510     returnM (ExplicitList new_ty new_exprs)
 511
 512 zonkExpr env (ExplicitPArr ty exprs)
 513   = zonkTcTypeToType env ty     `thenM` \ new_ty ->
 514     zonkLExprs env exprs        `thenM` \ new_exprs ->
 515     returnM (ExplicitPArr new_ty new_exprs)
 516
 517 zonkExpr env (ExplicitTuple exprs boxed)
 518   = zonkLExprs env exprs        `thenM` \ new_exprs ->
 519     returnM (ExplicitTuple new_exprs boxed)
 520
 521 zonkExpr env (RecordCon data_con con_expr rbinds)
 522   = do  { new_con_expr <- zonkExpr env con_expr
 523         ; new_rbinds   <- zonkRecFields env rbinds
 524         ; return (RecordCon data_con new_con_expr new_rbinds) }
 525
 526 zonkExpr env (RecordUpd expr rbinds cons in_tys out_tys)
 527   = do  { new_expr    <- zonkLExpr env expr
 528         ; new_in_tys  <- mapM (zonkTcTypeToType env) in_tys
 529         ; new_out_tys <- mapM (zonkTcTypeToType env) out_tys
 530         ; new_rbinds  <- zonkRecFields env rbinds
 531         ; return (RecordUpd new_expr new_rbinds cons new_in_tys new_out_tys) }
 532
 533 zonkExpr env (ExprWithTySigOut e ty)
 534   = do { e' <- zonkLExpr env e
 535        ; return (ExprWithTySigOut e' ty) }
 536
 537 zonkExpr _ (ExprWithTySig _ _) = panic "zonkExpr env:ExprWithTySig"
 538
 539 zonkExpr env (ArithSeq expr info)
 540   = zonkExpr env expr           `thenM` \ new_expr ->
 541     zonkArithSeq env info       `thenM` \ new_info ->
 542     returnM (ArithSeq new_expr new_info)
 543
 544 zonkExpr env (PArrSeq expr info)
 545   = zonkExpr env expr           `thenM` \ new_expr ->
 546     zonkArithSeq env info       `thenM` \ new_info ->
 547     returnM (PArrSeq new_expr new_info)
 548
 549 zonkExpr env (HsSCC lbl expr)
 550   = zonkLExpr env expr  `thenM` \ new_expr ->
 551     returnM (HsSCC lbl new_expr)
 552
 553 zonkExpr env (HsTickPragma info expr)
 554   = zonkLExpr env expr  `thenM` \ new_expr ->
 555     returnM (HsTickPragma info new_expr)
 556
 557 -- hdaume: core annotations
 558 zonkExpr env (HsCoreAnn lbl expr)
 559   = zonkLExpr env expr   `thenM` \ new_expr ->
 560     returnM (HsCoreAnn lbl new_expr)
 561
 562 -- arrow notation extensions
 563 zonkExpr env (HsProc pat body)
 564   = do  { (env1, new_pat) <- zonkPat env pat
 565         ; new_body <- zonkCmdTop env1 body
 566         ; return (HsProc new_pat new_body) }
 567
 568 zonkExpr env (HsArrApp e1 e2 ty ho rl)
 569   = zonkLExpr env e1                    `thenM` \ new_e1 ->
 570     zonkLExpr env e2                    `thenM` \ new_e2 ->
 571     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 572     returnM (HsArrApp new_e1 new_e2 new_ty ho rl)
 573
 574 zonkExpr env (HsArrForm op fixity args)
 575   = zonkLExpr env op                    `thenM` \ new_op ->
 576     mappM (zonkCmdTop env) args         `thenM` \ new_args ->
 577     returnM (HsArrForm new_op fixity new_args)
 578
 579 zonkExpr env (HsWrap co_fn expr)
 580   = zonkCoFn env co_fn  `thenM` \ (env1, new_co_fn) ->
 581     zonkExpr env1 expr  `thenM` \ new_expr ->
 582     return (HsWrap new_co_fn new_expr)
 583
 584 zonkExpr _ expr = pprPanic "zonkExpr" (ppr expr)
 585
 586 zonkCmdTop :: ZonkEnv -> LHsCmdTop TcId -> TcM (LHsCmdTop Id)
 587 zonkCmdTop env cmd = wrapLocM (zonk_cmd_top env) cmd
 588
 589 zonk_cmd_top :: ZonkEnv -> HsCmdTop TcId -> TcM (HsCmdTop Id)
 590 zonk_cmd_top env (HsCmdTop cmd stack_tys ty ids)
 591   = zonkLExpr env cmd                   `thenM` \ new_cmd ->
 592     zonkTcTypeToTypes env stack_tys     `thenM` \ new_stack_tys ->
 593     zonkTcTypeToType env ty             `thenM` \ new_ty ->
 594     mapSndM (zonkExpr env) ids          `thenM` \ new_ids ->
 595     returnM (HsCmdTop new_cmd new_stack_tys new_ty new_ids)
 596
 597 -------------------------------------------------------------------------
 598 zonkCoFn :: ZonkEnv -> HsWrapper -> TcM (ZonkEnv, HsWrapper)
 599 zonkCoFn env WpHole   = return (env, WpHole)
 600 zonkCoFn env WpInline = return (env, WpInline)
 601 zonkCoFn env (WpCompose c1 c2) = do { (env1, c1') <- zonkCoFn env c1
 602                                     ; (env2, c2') <- zonkCoFn env1 c2
 603                                     ; return (env2, WpCompose c1' c2') }
 604 zonkCoFn env (WpCast co)    = do { co' <- zonkTcTypeToType env co
 605                                  ; return (env, WpCast co') }
 606 zonkCoFn env (WpLam id)     = do { id' <- zonkDictBndr env id
 607                                  ; let env1 = extendZonkEnv1 env id'
 608                                  ; return (env1, WpLam id') }
 609 zonkCoFn env (WpTyLam tv)   = ASSERT( isImmutableTyVar tv )
 610                               return (env, WpTyLam tv)
 611 zonkCoFn env (WpApp v)
 612         | isTcTyVar v       = do { co <- zonkTcTyVar v
 613                                  ; return (env, WpTyApp co) }
 614                 -- Yuk!  A mutable coercion variable is a TcTyVar
 615                 --       not a CoVar, so don't use isCoVar!
 616                 -- Yuk!  A WpApp can't hold the zonked type,
 617                 --       so we switch to WpTyApp
 618         | otherwise         = return (env, WpApp (zonkIdOcc env v))
 619 zonkCoFn env (WpTyApp ty)   = do { ty' <- zonkTcTypeToType env ty
 620                                  ; return (env, WpTyApp ty') }
 621 zonkCoFn env (WpLet bs)     = do { (env1, bs') <- zonkRecMonoBinds env bs
 622                                  ; return (env1, WpLet bs') }
 623
 624
 625 -------------------------------------------------------------------------
 626 zonkDo :: ZonkEnv -> HsStmtContext Name -> HsStmtContext Name
 627 -- Only used for 'do', so the only Ids are in a MDoExpr table
 628 zonkDo env (MDoExpr tbl) = MDoExpr (mapSnd (zonkIdOcc env) tbl)
 629 zonkDo _   do_or_lc      = do_or_lc
 630
 631 -------------------------------------------------------------------------
 632 zonkOverLit :: ZonkEnv -> HsOverLit TcId -> TcM (HsOverLit Id)
 633 zonkOverLit env lit@(OverLit { ol_witness = e, ol_type = ty })
 634   = do  { ty' <- zonkTcTypeToType env ty
 635         ; e' <- zonkExpr env e
 636         ; return (lit { ol_witness = e', ol_type = ty' }) }
 637
 638 -------------------------------------------------------------------------
 639 zonkArithSeq :: ZonkEnv -> ArithSeqInfo TcId -> TcM (ArithSeqInfo Id)
 640
 641 zonkArithSeq env (From e)
 642   = zonkLExpr env e             `thenM` \ new_e ->
 643     returnM (From new_e)
 644
 645 zonkArithSeq env (FromThen e1 e2)
 646   = zonkLExpr env e1    `thenM` \ new_e1 ->
 647     zonkLExpr env e2    `thenM` \ new_e2 ->
 648     returnM (FromThen new_e1 new_e2)
 649
 650 zonkArithSeq env (FromTo e1 e2)
 651   = zonkLExpr env e1    `thenM` \ new_e1 ->
 652     zonkLExpr env e2    `thenM` \ new_e2 ->
 653     returnM (FromTo new_e1 new_e2)
 654
 655 zonkArithSeq env (FromThenTo e1 e2 e3)
 656   = zonkLExpr env e1    `thenM` \ new_e1 ->
 657     zonkLExpr env e2    `thenM` \ new_e2 ->
 658     zonkLExpr env e3    `thenM` \ new_e3 ->
 659     returnM (FromThenTo new_e1 new_e2 new_e3)
 660
 661
 662 -------------------------------------------------------------------------
 663 zonkStmts :: ZonkEnv -> [LStmt TcId] -> TcM (ZonkEnv, [LStmt Id])
 664 zonkStmts env []     = return (env, [])
 665 zonkStmts env (s:ss) = do { (env1, s')  <- wrapLocSndM (zonkStmt env) s
 666                           ; (env2, ss') <- zonkStmts env1 ss
 667                           ; return (env2, s' : ss') }
 668
 669 zonkStmt :: ZonkEnv -> Stmt TcId -> TcM (ZonkEnv, Stmt Id)
 670 zonkStmt env (ParStmt stmts_w_bndrs)
 671   = mappM zonk_branch stmts_w_bndrs     `thenM` \ new_stmts_w_bndrs ->
 672     let
 673         new_binders = concat (map snd new_stmts_w_bndrs)
 674         env1 = extendZonkEnv env new_binders
 675     in
 676     return (env1, ParStmt new_stmts_w_bndrs)
 677   where
 678     zonk_branch (stmts, bndrs) = zonkStmts env stmts    `thenM` \ (env1, new_stmts) ->
 679                                  returnM (new_stmts, zonkIdOccs env1 bndrs)
 680
 681 zonkStmt env (RecStmt segStmts lvs rvs rets binds)
 682   = zonkIdBndrs env rvs         `thenM` \ new_rvs ->
 683     let
 684         env1 = extendZonkEnv env new_rvs
 685     in
 686     zonkStmts env1 segStmts     `thenM` \ (env2, new_segStmts) ->
 687         -- Zonk the ret-expressions in an envt that
 688         -- has the polymorphic bindings in the envt
 689     mapM (zonkExpr env2) rets   `thenM` \ new_rets ->
 690     let
 691         new_lvs = zonkIdOccs env2 lvs
 692         env3 = extendZonkEnv env new_lvs        -- Only the lvs are needed
 693     in
 694     zonkRecMonoBinds env3 binds `thenM` \ (env4, new_binds) ->
 695     returnM (env4, RecStmt new_segStmts new_lvs new_rvs new_rets new_binds)
 696
 697 zonkStmt env (ExprStmt expr then_op ty)
 698   = zonkLExpr env expr          `thenM` \ new_expr ->
 699     zonkExpr env then_op        `thenM` \ new_then ->
 700     zonkTcTypeToType env ty     `thenM` \ new_ty ->
 701     returnM (env, ExprStmt new_expr new_then new_ty)
 702
 703 zonkStmt env (TransformStmt (stmts, binders) usingExpr maybeByExpr)
 704   = do { (env', stmts') <- zonkStmts env stmts
 705     ; let binders' = zonkIdOccs env' binders
 706     ; usingExpr' <- zonkLExpr env' usingExpr
 707     ; maybeByExpr' <- zonkMaybeLExpr env' maybeByExpr
 708     ; return (env', TransformStmt (stmts', binders') usingExpr' maybeByExpr') }
 709
 710 zonkStmt env (GroupStmt (stmts, binderMap) groupByClause)
 711   = do { (env', stmts') <- zonkStmts env stmts
 712     ; binderMap' <- mappM (zonkBinderMapEntry env') binderMap
 713     ; groupByClause' <-
 714         case groupByClause of
 715             GroupByNothing usingExpr -> (zonkLExpr env' usingExpr) >>= (return . GroupByNothing)
 716             GroupBySomething eitherUsingExpr byExpr -> do
 717                 eitherUsingExpr' <- mapEitherM (zonkLExpr env') (zonkExpr env') eitherUsingExpr
 718                 byExpr' <- zonkLExpr env' byExpr
 719                 return $ GroupBySomething eitherUsingExpr' byExpr'
 720
 721     ; let env'' = extendZonkEnv env' (map snd binderMap')
 722     ; return (env'', GroupStmt (stmts', binderMap') groupByClause') }
 723   where
 724     mapEitherM f g x = do
 725       case x of
 726         Left a -> f a >>= (return . Left)
 727         Right b -> g b >>= (return . Right)
 728
 729     zonkBinderMapEntry env (oldBinder, newBinder) = do
 730         let oldBinder' = zonkIdOcc env oldBinder
 731         newBinder' <- zonkIdBndr env newBinder
 732         return (oldBinder', newBinder')
 733
 734 zonkStmt env (LetStmt binds)
 735   = zonkLocalBinds env binds    `thenM` \ (env1, new_binds) ->
 736     returnM (env1, LetStmt new_binds)
 737
 738 zonkStmt env (BindStmt pat expr bind_op fail_op)
 739   = do  { new_expr <- zonkLExpr env expr
 740         ; (env1, new_pat) <- zonkPat env pat
 741         ; new_bind <- zonkExpr env bind_op
 742         ; new_fail <- zonkExpr env fail_op
 743         ; return (env1, BindStmt new_pat new_expr new_bind new_fail) }
 744
 745 zonkMaybeLExpr :: ZonkEnv -> Maybe (LHsExpr TcId) -> TcM (Maybe (LHsExpr Id))
 746 zonkMaybeLExpr _   Nothing  = return Nothing
 747 zonkMaybeLExpr env (Just e) = (zonkLExpr env e) >>= (return . Just)
 748
 749
 750 -------------------------------------------------------------------------
 751 zonkRecFields :: ZonkEnv -> HsRecordBinds TcId -> TcM (HsRecordBinds TcId)
 752 zonkRecFields env (HsRecFields flds dd)
 753   = do  { flds' <- mappM zonk_rbind flds
 754         ; return (HsRecFields flds' dd) }
 755   where
 756     zonk_rbind fld
 757       = do { new_expr <- zonkLExpr env (hsRecFieldArg fld)
 758            ; return (fld { hsRecFieldArg = new_expr }) }
 759         -- Field selectors have declared types; hence no zonking
 760
 761 -------------------------------------------------------------------------
 762 mapIPNameTc :: (a -> TcM b) -> IPName a -> TcM (IPName b)
 763 mapIPNameTc f (IPName n) = f n  `thenM` \ r -> returnM (IPName r)
 764 \end{code}
 765
 766
 767 %************************************************************************
 768 %*                                                                      *
 769 \subsection[BackSubst-Pats]{Patterns}
 770 %*                                                                      *
 771 %************************************************************************
 772
 773 \begin{code}
 774 zonkPat :: ZonkEnv -> OutPat TcId -> TcM (ZonkEnv, OutPat Id)
 775 -- Extend the environment as we go, because it's possible for one
 776 -- pattern to bind something that is used in another (inside or
 777 -- to the right)
 778 zonkPat env pat = wrapLocSndM (zonk_pat env) pat
 779
 780 zonk_pat :: ZonkEnv -> Pat TcId -> TcM (ZonkEnv, Pat Id)
 781 zonk_pat env (ParPat p)
 782   = do  { (env', p') <- zonkPat env p
 783         ; return (env', ParPat p') }
 784
 785 zonk_pat env (WildPat ty)
 786   = do  { ty' <- zonkTcTypeToType env ty
 787         ; return (env, WildPat ty') }
 788
 789 zonk_pat env (VarPat v)
 790   = do  { v' <- zonkIdBndr env v
 791         ; return (extendZonkEnv1 env v', VarPat v') }
 792
 793 zonk_pat env (VarPatOut v binds)
 794   = do  { v' <- zonkIdBndr env v
 795         ; (env', binds') <- zonkRecMonoBinds (extendZonkEnv1 env v') binds
 796         ; returnM (env', VarPatOut v' binds') }
 797
 798 zonk_pat env (LazyPat pat)
 799   = do  { (env', pat') <- zonkPat env pat
 800         ; return (env',  LazyPat pat') }
 801
 802 zonk_pat env (BangPat pat)
 803   = do  { (env', pat') <- zonkPat env pat
 804         ; return (env',  BangPat pat') }
 805
 806 zonk_pat env (AsPat (L loc v) pat)
 807   = do  { v' <- zonkIdBndr env v
 808         ; (env', pat') <- zonkPat (extendZonkEnv1 env v') pat
 809         ; return (env', AsPat (L loc v') pat') }
 810
 811 zonk_pat env (ViewPat expr pat ty)
 812   = do  { expr' <- zonkLExpr env expr
 813         ; (env', pat') <- zonkPat env pat
 814         ; return (env', ViewPat expr' pat' ty) }
 815
 816 zonk_pat env (ListPat pats ty)
 817   = do  { ty' <- zonkTcTypeToType env ty
 818         ; (env', pats') <- zonkPats env pats
 819         ; return (env', ListPat pats' ty') }
 820
 821 zonk_pat env (PArrPat pats ty)
 822   = do  { ty' <- zonkTcTypeToType env ty
 823         ; (env', pats') <- zonkPats env pats
 824         ; return (env', PArrPat pats' ty') }
 825
 826 zonk_pat env (TuplePat pats boxed ty)
 827   = do  { ty' <- zonkTcTypeToType env ty
 828         ; (env', pats') <- zonkPats env pats
 829         ; return (env', TuplePat pats' boxed ty') }
 830
 831 zonk_pat env p@(ConPatOut { pat_ty = ty, pat_dicts = dicts, pat_binds = binds, pat_args = args })
 832   = ASSERT( all isImmutableTyVar (pat_tvs p) )
 833     do  { new_ty <- zonkTcTypeToType env ty
 834         ; new_dicts <- zonkDictBndrs env dicts
 835         ; let env1 = extendZonkEnv env new_dicts
 836         ; (env2, new_binds) <- zonkRecMonoBinds env1 binds
 837         ; (env', new_args) <- zonkConStuff env2 args
 838         ; returnM (env', p { pat_ty = new_ty, pat_dicts = new_dicts,
 839                              pat_binds = new_binds, pat_args = new_args }) }
 840
 841 zonk_pat env (LitPat lit) = return (env, LitPat lit)
 842
 843 zonk_pat env (SigPatOut pat ty)
 844   = do  { ty' <- zonkTcTypeToType env ty
 845         ; (env', pat') <- zonkPat env pat
 846         ; return (env', SigPatOut pat' ty') }
 847
 848 zonk_pat env (NPat lit mb_neg eq_expr)
 849   = do  { lit' <- zonkOverLit env lit
 850         ; mb_neg' <- case mb_neg of
 851                         Nothing  -> return Nothing
 852                         Just neg -> do { neg' <- zonkExpr env neg
 853                                        ; return (Just neg') }
 854         ; eq_expr' <- zonkExpr env eq_expr
 855         ; return (env, NPat lit' mb_neg' eq_expr') }
 856
 857 zonk_pat env (NPlusKPat (L loc n) lit e1 e2)
 858   = do  { n' <- zonkIdBndr env n
 859         ; lit' <- zonkOverLit env lit
 860         ; e1' <- zonkExpr env e1
 861         ; e2' <- zonkExpr env e2
 862         ; return (extendZonkEnv1 env n', NPlusKPat (L loc n') lit' e1' e2') }
 863
 864 zonk_pat env (CoPat co_fn pat ty)
 865   = do { (env', co_fn') <- zonkCoFn env co_fn
 866        ; (env'', pat') <- zonkPat env' (noLoc pat)
 867        ; ty' <- zonkTcTypeToType env'' ty
 868        ; return (env'', CoPat co_fn' (unLoc pat') ty') }
 869
 870 zonk_pat _ pat = pprPanic "zonk_pat" (ppr pat)
 871
 872 ---------------------------
 873 zonkConStuff :: ZonkEnv
 874              -> HsConDetails (OutPat TcId) (HsRecFields id (OutPat TcId))
 875              -> TcM (ZonkEnv,
 876                      HsConDetails (OutPat Id) (HsRecFields id (OutPat Id)))
 877 zonkConStuff env (PrefixCon pats)
 878   = do  { (env', pats') <- zonkPats env pats
 879         ; return (env', PrefixCon pats') }
 880
 881 zonkConStuff env (InfixCon p1 p2)
 882   = do  { (env1, p1') <- zonkPat env  p1
 883         ; (env', p2') <- zonkPat env1 p2
 884         ; return (env', InfixCon p1' p2') }
 885
 886 zonkConStuff env (RecCon (HsRecFields rpats dd))
 887   = do  { (env', pats') <- zonkPats env (map hsRecFieldArg rpats)
 888         ; let rpats' = zipWith (\rp p' -> rp { hsRecFieldArg = p' }) rpats pats'
 889         ; returnM (env', RecCon (HsRecFields rpats' dd)) }
 890         -- Field selectors have declared types; hence no zonking
 891
 892 ---------------------------
 893 zonkPats :: ZonkEnv -> [OutPat TcId] -> TcM (ZonkEnv, [OutPat Id])
 894 zonkPats env []         = return (env, [])
 895 zonkPats env (pat:pats) = do { (env1, pat') <- zonkPat env pat
 896                      ; (env', pats') <- zonkPats env1 pats
 897                      ; return (env', pat':pats') }
 898 \end{code}
 899
 900 %************************************************************************
 901 %*                                                                      *
 902 \subsection[BackSubst-Foreign]{Foreign exports}
 903 %*                                                                      *
 904 %************************************************************************
 905
 906
 907 \begin{code}
 908 zonkForeignExports :: ZonkEnv -> [LForeignDecl TcId] -> TcM [LForeignDecl Id]
 909 zonkForeignExports env ls = mappM (wrapLocM (zonkForeignExport env)) ls
 910
 911 zonkForeignExport :: ZonkEnv -> ForeignDecl TcId -> TcM (ForeignDecl Id)
 912 zonkForeignExport env (ForeignExport i _hs_ty spec) =
 913    returnM (ForeignExport (fmap (zonkIdOcc env) i) undefined spec)
 914 zonkForeignExport _ for_imp
 915   = returnM for_imp     -- Foreign imports don't need zonking
 916 \end{code}
 917
 918 \begin{code}
 919 zonkRules :: ZonkEnv -> [LRuleDecl TcId] -> TcM [LRuleDecl Id]
 920 zonkRules env rs = mappM (wrapLocM (zonkRule env)) rs
 921
 922 zonkRule :: ZonkEnv -> RuleDecl TcId -> TcM (RuleDecl Id)
 923 zonkRule env (HsRule name act (vars{-::[RuleBndr TcId]-}) lhs fv_lhs rhs fv_rhs)
 924   = mappM zonk_bndr vars                `thenM` \ new_bndrs ->
 925     newMutVar emptyVarSet               `thenM` \ unbound_tv_set ->
 926     let
 927         env_rhs = extendZonkEnv env [id | b <- new_bndrs, let id = unLoc b, isId id]
 928         -- Type variables don't need an envt
 929         -- They are bound through the mutable mechanism
 930
 931         env_lhs = setZonkType env_rhs (zonkTypeCollecting unbound_tv_set)
 932         -- We need to gather the type variables mentioned on the LHS so we can
 933         -- quantify over them.  Example:
 934         --   data T a = C
 935         --
 936         --   foo :: T a -> Int
 937         --   foo C = 1
 938         --
 939         --   {-# RULES "myrule"  foo C = 1 #-}
 940         --
 941         -- After type checking the LHS becomes (foo a (C a))
 942         -- and we do not want to zap the unbound tyvar 'a' to (), because
 943         -- that limits the applicability of the rule.  Instead, we
 944         -- want to quantify over it!
 945         --
 946         -- It's easiest to find the free tyvars here. Attempts to do so earlier
 947         -- are tiresome, because (a) the data type is big and (b) finding the
 948         -- free type vars of an expression is necessarily monadic operation.
 949         --      (consider /\a -> f @ b, where b is side-effected to a)
 950     in
 951     zonkLExpr env_lhs lhs               `thenM` \ new_lhs ->
 952     zonkLExpr env_rhs rhs               `thenM` \ new_rhs ->
 953
 954     readMutVar unbound_tv_set           `thenM` \ unbound_tvs ->
 955     let
 956         final_bndrs :: [Located Var]
 957         final_bndrs = map noLoc (varSetElems unbound_tvs) ++ new_bndrs
 958     in
 959     returnM (HsRule name act (map RuleBndr final_bndrs) new_lhs fv_lhs new_rhs fv_rhs)
 960                 -- I hate this map RuleBndr stuff
 961   where
 962    zonk_bndr (RuleBndr v)
 963         | isId (unLoc v) = wrapLocM (zonkIdBndr env)   v
 964         | otherwise      = ASSERT( isImmutableTyVar (unLoc v) )
 965                            return v
 966    zonk_bndr (RuleBndrSig {}) = panic "zonk_bndr RuleBndrSig"
 967 \end{code}
 968
 969
 970 %************************************************************************
 971 %*                                                                      *
 972 \subsection[BackSubst-Foreign]{Foreign exports}
 973 %*                                                                      *
 974 %************************************************************************
 975
 976 \begin{code}
 977 zonkTcTypeToType :: ZonkEnv -> TcType -> TcM Type
 978 zonkTcTypeToType (ZonkEnv zonk_ty _) ty = zonk_ty ty
 979
 980 zonkTcTypeToTypes :: ZonkEnv -> [TcType] -> TcM [Type]
 981 zonkTcTypeToTypes env tys = mapM (zonkTcTypeToType env) tys
 982
 983 zonkTypeCollecting :: TcRef TyVarSet -> TcType -> TcM Type
 984 -- This variant collects unbound type variables in a mutable variable
 985 zonkTypeCollecting unbound_tv_set
 986   = zonkType zonk_unbound_tyvar
 987   where
 988     zonk_unbound_tyvar tv
 989         = zonkQuantifiedTyVar tv                                `thenM` \ tv' ->
 990           readMutVar unbound_tv_set                             `thenM` \ tv_set ->
 991           writeMutVar unbound_tv_set (extendVarSet tv_set tv')  `thenM_`
 992           return (mkTyVarTy tv')
 993
 994 zonkTypeZapping :: TcType -> TcM Type
 995 -- This variant is used for everything except the LHS of rules
 996 -- It zaps unbound type variables to (), or some other arbitrary type
 997 zonkTypeZapping ty
 998   = zonkType zonk_unbound_tyvar ty
 999   where
1000         -- Zonk a mutable but unbound type variable to an arbitrary type
1001         -- We know it's unbound even though we don't carry an environment,
1002         -- because at the binding site for a type variable we bind the
1003         -- mutable tyvar to a fresh immutable one.  So the mutable store
1004         -- plays the role of an environment.  If we come across a mutable
1005         -- type variable that isn't so bound, it must be completely free.
1006     zonk_unbound_tyvar tv = do { ty <- mkArbitraryType warn tv
1007                                ; writeMetaTyVar tv ty
1008                                ; return ty }
1009         where
1010             warn span msg = setSrcSpan span (addWarnTc msg)
1011
1012
1013 {-      Note [Strangely-kinded void TyCons]
1014         ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1015         See Trac #959 for more examples
1016
1017 When the type checker finds a type variable with no binding, which
1018 means it can be instantiated with an arbitrary type, it usually
1019 instantiates it to Void.  Eg.
1020
1021         length []
1022 ===>
1023         length Void (Nil Void)
1024
1025 But in really obscure programs, the type variable might have a kind
1026 other than *, so we need to invent a suitably-kinded type.
1027
1028 This commit uses
1029         Void for kind *
1030         List for kind *->*
1031         Tuple for kind *->...*->*
1032
1033 which deals with most cases.  (Previously, it only dealt with
1034 kind *.)
1035
1036 In the other cases, it just makes up a TyCon with a suitable kind.  If
1037 this gets into an interface file, anyone reading that file won't
1038 understand it.  This is fixable (by making the client of the interface
1039 file make up a TyCon too) but it is tiresome and never happens, so I
1040 am leaving it.
1041
1042 Meanwhile I have now fixed GHC to emit a civilized warning.
1043  -}
1044
1045 mkArbitraryType :: (SrcSpan -> SDoc -> TcRnIf g l a)    -- How to complain
1046                 -> TcTyVar
1047                 -> TcRnIf g l Type              -- Used by desugarer too
1048 -- Make up an arbitrary type whose kind is the same as the tyvar.
1049 -- We'll use this to instantiate the (unbound) tyvar.
1050 --
1051 -- Also used by the desugarer; hence the (tiresome) parameter
1052 -- to use when generating a warning
1053 mkArbitraryType warn tv
1054   | liftedTypeKind `isSubKind` kind             -- The vastly common case
1055   = return anyPrimTy
1056   | eqKind kind (tyConKind anyPrimTyCon1)       -- @*->*@
1057   = return (mkTyConApp anyPrimTyCon1 [])        --     No tuples this size
1058   | all isLiftedTypeKind args                   -- @*-> ... ->*->*@
1059   , isLiftedTypeKind res                        --    Horrible hack to make less use
1060   = return (mkTyConApp tup_tc [])               --    of mkAnyPrimTyCon
1061   | otherwise
1062   = do  { warn (getSrcSpan tv) msg
1063         ; return (mkTyConApp (mkAnyPrimTyCon (getUnique tv) kind) []) }
1064                 -- Same name as the tyvar, apart from making it start with a colon (sigh)
1065                 -- I dread to think what will happen if this gets out into an
1066                 -- interface file.  Catastrophe likely.  Major sigh.
1067   where
1068     kind       = tyVarKind tv
1069     (args,res) = splitKindFunTys kind
1070     tup_tc     = tupleTyCon Boxed (length args)
1071
1072     msg = vcat [ hang (ptext (sLit "Inventing strangely-kinded Any TyCon"))
1073                     2 (ptext (sLit "of kind") <+> quotes (ppr kind))
1074                , nest 2 (ptext (sLit "from an instantiation of type variable") <+> quotes (ppr tv))
1075                , ptext (sLit "This warning can be suppressed by a type signature fixing") <+> quotes (ppr tv)
1076                , nest 2 (ptext (sLit "but is harmless without -O (and usually harmless anyway)."))
1077                , ptext (sLit "See http://hackage.haskell.org/trac/ghc/ticket/959 for details")  ]
1078 \end{code}