compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsDeriv,
  10         tcHsInstHead, tcHsQuantifiedType,
  11         UserTypeCtxt(..),
  12
  13                 -- Kind checking
  14         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  15         kcCheckHsType, kcHsContext, kcHsType,
  16
  17                 -- Typechecking kinded types
  18         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  19         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  20         tcDataKindSig,
  21
  22                 -- Pattern type signatures
  23         tcHsPatSigType, tcPatSig
  24    ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn
  29 import RnHsSyn
  30 import TcRnMonad
  31 import TcEnv
  32 import TcMType
  33 import TcUnify
  34 import TcIface
  35 import TcType
  36 import {- Kind parts of -} Type
  37 import Var
  38 import Coercion
  39 import TyCon
  40 import Class
  41 import Name
  42 import OccName
  43 import NameSet
  44 import PrelNames
  45 import TysWiredIn
  46 import BasicTypes
  47 import SrcLoc
  48 import UniqSupply
  49 import Outputable
  50 import FastString
  51
  52 import Control.Monad
  53 \end{code}
  54
  55
  56         ----------------------------
  57                 General notes
  58         ----------------------------
  59
  60 Generally speaking we now type-check types in three phases
  61
  62   1.  kcHsType: kind check the HsType
  63         *includes* performing any TH type splices;
  64         so it returns a translated, and kind-annotated, type
  65
  66   2.  dsHsType: convert from HsType to Type:
  67         perform zonking
  68         expand type synonyms [mkGenTyApps]
  69         hoist the foralls [tcHsType]
  70
  71   3.  checkValidType: check the validity of the resulting type
  72
  73 Often these steps are done one after the other (tcHsSigType).
  74 But in mutually recursive groups of type and class decls we do
  75         1 kind-check the whole group
  76         2 build TyCons/Classes in a knot-tied way
  77         3 check the validity of types in the now-unknotted TyCons/Classes
  78
  79 For example, when we find
  80         (forall a m. m a -> m a)
  81 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  82 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  83 an environment that binds a and m suitably.
  84
  85 The kind checker passed to tcHsTyVars needs to look at enough to
  86 establish the kind of the tyvar:
  87   * For a group of type and class decls, it's just the group, not
  88         the rest of the program
  89   * For a tyvar bound in a pattern type signature, its the types
  90         mentioned in the other type signatures in that bunch of patterns
  91   * For a tyvar bound in a RULE, it's the type signatures on other
  92         universally quantified variables in the rule
  93
  94 Note that this may occasionally give surprising results.  For example:
  95
  96         data T a b = MkT (a b)
  97
  98 Here we deduce                  a::*->*,       b::*
  99 But equally valid would be      a::(*->*)-> *, b::*->*
 100
 101
 102 Validity checking
 103 ~~~~~~~~~~~~~~~~~
 104 Some of the validity check could in principle be done by the kind checker,
 105 but not all:
 106
 107 - During desugaring, we normalise by expanding type synonyms.  Only
 108   after this step can we check things like type-synonym saturation
 109   e.g.  type T k = k Int
 110         type S a = a
 111   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 112   and then S is saturated.  This is a GHC extension.
 113
 114 - Similarly, also a GHC extension, we look through synonyms before complaining
 115   about the form of a class or instance declaration
 116
 117 - Ambiguity checks involve functional dependencies, and it's easier to wait
 118   until knots have been resolved before poking into them
 119
 120 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 121 finished building the loop.  So to keep things simple, we postpone most validity
 122 checking until step (3).
 123
 124 Knot tying
 125 ~~~~~~~~~~
 126 During step (1) we might fault in a TyCon defined in another module, and it might
 127 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 128 knot around type declarations with ARecThing, so that the fault-in code can get
 129 the TyCon being defined.
 130
 131
 132 %************************************************************************
 133 %*                                                                      *
 134 \subsection{Checking types}
 135 %*                                                                      *
 136 %************************************************************************
 137
 138 \begin{code}
 139 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 140   -- Do kind checking, and hoist for-alls to the top
 141   -- NB: it's important that the foralls that come from the top-level
 142   --     HsForAllTy in hs_ty occur *first* in the returned type.
 143   --     See Note [Scoped] with TcSigInfo
 144 tcHsSigType ctxt hs_ty
 145   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 146     do  { kinded_ty <- kcTypeType hs_ty
 147         ; ty <- tcHsKindedType kinded_ty
 148         ; checkValidType ctxt ty
 149         ; return ty }
 150
 151 tcHsInstHead :: LHsType Name -> TcM ([TyVar], ThetaType, Type)
 152 -- Typecheck an instance head.  We can't use
 153 -- tcHsSigType, because it's not a valid user type.
 154 tcHsInstHead hs_ty
 155   = do  { kinded_ty <- kcHsSigType hs_ty
 156         ; poly_ty   <- tcHsKindedType kinded_ty
 157         ; return (tcSplitSigmaTy poly_ty) }
 158
 159 tcHsQuantifiedType :: [LHsTyVarBndr Name] -> LHsType Name -> TcM ([TyVar], Type)
 160 -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 161 -- except that we want to keep the tvs separate
 162 tcHsQuantifiedType tv_names hs_ty
 163   = kcHsTyVars tv_names $ \ tv_names' ->
 164     do  { kc_ty <- kcHsSigType hs_ty
 165         ; tcTyVarBndrs tv_names' $ \ tvs ->
 166     do  { ty <- dsHsType kc_ty
 167         ; return (tvs, ty) } }
 168
 169 -- Used for the deriving(...) items
 170 tcHsDeriv :: HsType Name -> TcM ([TyVar], Class, [Type])
 171 tcHsDeriv = tc_hs_deriv []
 172
 173 tc_hs_deriv :: [LHsTyVarBndr Name] -> HsType Name
 174             -> TcM ([TyVar], Class, [Type])
 175 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 176   = kcHsTyVars tv_names                 $ \ tv_names' ->
 177     do  { cls_kind <- kcClass cls_name
 178         ; (tys, _res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 179         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 180     do  { arg_tys <- dsHsTypes tys
 181         ; cls <- tcLookupClass cls_name
 182         ; return (tyvars, cls, arg_tys) }}
 183
 184 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 185   =     -- Funny newtype deriving form
 186         --      forall a. C [a]
 187         -- where C has arity 2.  Hence can't use regular functions
 188     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 189
 190 tc_hs_deriv _ other
 191   = failWithTc (ptext (sLit "Illegal deriving item") <+> ppr other)
 192 \end{code}
 193
 194         These functions are used during knot-tying in
 195         type and class declarations, when we have to
 196         separate kind-checking, desugaring, and validity checking
 197
 198 \begin{code}
 199 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 200         -- Used for type signatures
 201 kcHsSigType ty       = kcTypeType ty
 202 kcHsLiftedSigType ty = kcLiftedType ty
 203
 204 tcHsKindedType :: LHsType Name -> TcM Type
 205   -- Don't do kind checking, nor validity checking.
 206   -- This is used in type and class decls, where kinding is
 207   -- done in advance, and validity checking is done later
 208   -- [Validity checking done later because of knot-tying issues.]
 209 tcHsKindedType hs_ty = dsHsType hs_ty
 210
 211 tcHsBangType :: LHsType Name -> TcM Type
 212 -- Permit a bang, but discard it
 213 tcHsBangType (L _ (HsBangTy _ ty)) = tcHsKindedType ty
 214 tcHsBangType ty                    = tcHsKindedType ty
 215
 216 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 217 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 218 -- Does not do validity checking, like tcHsKindedType
 219 tcHsKindedContext hs_theta = addLocM (mapM dsHsLPred) hs_theta
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225                 The main kind checker: kcHsType
 226 %*                                                                      *
 227 %************************************************************************
 228
 229         First a couple of simple wrappers for kcHsType
 230
 231 \begin{code}
 232 ---------------------------
 233 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 234 -- The type ty must be a *lifted* *type*
 235 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 236
 237 ---------------------------
 238 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 239 -- The type ty must be a *type*, but it can be lifted or
 240 -- unlifted or an unboxed tuple.
 241 kcTypeType ty = kcCheckHsType ty openTypeKind
 242
 243 ---------------------------
 244 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 245 -- Check that the type has the specified kind
 246 -- Be sure to use checkExpectedKind, rather than simply unifying
 247 -- with OpenTypeKind, because it gives better error messages
 248 kcCheckHsType (L span ty) exp_kind
 249   = setSrcSpan span                             $
 250     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 251                 -- Add the context round the inner check only
 252                 -- because checkExpectedKind already mentions
 253                 -- 'ty' by name in any error message
 254
 255         ; checkExpectedKind (strip ty) act_kind exp_kind
 256         ; return (L span ty') }
 257   where
 258         -- Wrap a context around only if we want to show that contexts.
 259     add_ctxt (HsPredTy _) thing = thing
 260         -- Omit invisble ones and ones user's won't grok (HsPred p).
 261     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 262         -- Omit wrapping if the theta-part is empty
 263         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 264         --         case of kc_hs_type, will do the wrapping instead
 265         --         and we don't want to duplicate
 266     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 267
 268         -- We infer the kind of the type, and then complain if it's
 269         -- not right.  But we don't want to complain about
 270         --      (ty) or !(ty) or forall a. ty
 271         -- when the real difficulty is with the 'ty' part.
 272     strip (HsParTy (L _ ty))          = strip ty
 273     strip (HsBangTy _ (L _ ty))       = strip ty
 274     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 275     strip ty                          = ty
 276 \end{code}
 277
 278         Here comes the main function
 279
 280 \begin{code}
 281 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 282 kcHsType ty = wrapLocFstM kc_hs_type ty
 283 -- kcHsType *returns* the kind of the type, rather than taking an expected
 284 -- kind as argument as tcExpr does.
 285 -- Reasons:
 286 --      (a) the kind of (->) is
 287 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 288 --          so we'd need to generate huge numbers of bx variables.
 289 --      (b) kinds are so simple that the error messages are fine
 290 --
 291 -- The translated type has explicitly-kinded type-variable binders
 292
 293 kc_hs_type :: HsType Name -> TcM (HsType Name, TcKind)
 294 kc_hs_type (HsParTy ty) = do
 295    (ty', kind) <- kcHsType ty
 296    return (HsParTy ty', kind)
 297
 298 kc_hs_type (HsTyVar name) = do
 299     kind <- kcTyVar name
 300     return (HsTyVar name, kind)
 301
 302 kc_hs_type (HsListTy ty) = do
 303     ty' <- kcLiftedType ty
 304     return (HsListTy ty', liftedTypeKind)
 305
 306 kc_hs_type (HsPArrTy ty) = do
 307     ty' <- kcLiftedType ty
 308     return (HsPArrTy ty', liftedTypeKind)
 309
 310 kc_hs_type (HsNumTy n)
 311    = return (HsNumTy n, liftedTypeKind)
 312
 313 kc_hs_type (HsKindSig ty k) = do
 314     ty' <- kcCheckHsType ty k
 315     return (HsKindSig ty' k, k)
 316
 317 kc_hs_type (HsTupleTy Boxed tys) = do
 318     tys' <- mapM kcLiftedType tys
 319     return (HsTupleTy Boxed tys', liftedTypeKind)
 320
 321 kc_hs_type (HsTupleTy Unboxed tys) = do
 322     tys' <- mapM kcTypeType tys
 323     return (HsTupleTy Unboxed tys', ubxTupleKind)
 324
 325 kc_hs_type (HsFunTy ty1 ty2) = do
 326     ty1' <- kcCheckHsType ty1 argTypeKind
 327     ty2' <- kcTypeType ty2
 328     return (HsFunTy ty1' ty2', liftedTypeKind)
 329
 330 kc_hs_type (HsOpTy ty1 op ty2) = do
 331     op_kind <- addLocM kcTyVar op
 332     ([ty1',ty2'], res_kind) <- kcApps op_kind (ppr op) [ty1,ty2]
 333     return (HsOpTy ty1' op ty2', res_kind)
 334
 335 kc_hs_type (HsAppTy ty1 ty2) = do
 336     (fun_ty', fun_kind) <- kcHsType fun_ty
 337     ((arg_ty':arg_tys'), res_kind) <- kcApps fun_kind (ppr fun_ty) arg_tys
 338     return (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 339   where
 340     (fun_ty, arg_tys) = split ty1 [ty2]
 341     split (L _ (HsAppTy f a)) as = split f (a:as)
 342     split f                   as = (f,as)
 343     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 344                                                 -- the application; they are
 345                                                 -- never used
 346
 347 kc_hs_type (HsPredTy (HsEqualP _ _))
 348   = wrongEqualityErr
 349
 350 kc_hs_type (HsPredTy pred) = do
 351     pred' <- kcHsPred pred
 352     return (HsPredTy pred', liftedTypeKind)
 353
 354 kc_hs_type (HsForAllTy exp tv_names context ty)
 355   = kcHsTyVars tv_names         $ \ tv_names' ->
 356     do  { ctxt' <- kcHsContext context
 357         ; ty'   <- kcLiftedType ty
 358              -- The body of a forall is usually a type, but in principle
 359              -- there's no reason to prohibit *unlifted* types.
 360              -- In fact, GHC can itself construct a function with an
 361              -- unboxed tuple inside a for-all (via CPR analyis; see
 362              -- typecheck/should_compile/tc170)
 363              --
 364              -- Still, that's only for internal interfaces, which aren't
 365              -- kind-checked, so we only allow liftedTypeKind here
 366
 367         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 368
 369 kc_hs_type (HsBangTy b ty) = do
 370     (ty', kind) <- kcHsType ty
 371     return (HsBangTy b ty', kind)
 372
 373 kc_hs_type ty@(HsSpliceTy _)
 374   = failWithTc (ptext (sLit "Unexpected type splice:") <+> ppr ty)
 375
 376 -- remove the doc nodes here, no need to worry about the location since
 377 -- its the same for a doc node and it's child type node
 378 kc_hs_type (HsDocTy ty _)
 379   = kc_hs_type (unLoc ty)
 380
 381 ---------------------------
 382 kcApps :: TcKind                        -- Function kind
 383        -> SDoc                          -- Function
 384        -> [LHsType Name]                -- Arg types
 385        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 386 kcApps fun_kind ppr_fun args = do
 387     (arg_kinds, res_kind) <- split_fk fun_kind (length args)
 388     args' <- zipWithM kc_arg args arg_kinds
 389     return (args', res_kind)
 390   where
 391     split_fk fk 0 = return ([], fk)
 392     split_fk fk n = do mb_fk <- unifyFunKind fk
 393                        case mb_fk of
 394                           Nothing       -> failWithTc too_many_args
 395                           Just (ak,fk') -> do (aks, rk) <- split_fk fk' (n-1)
 396                                               return (ak:aks, rk)
 397
 398     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 399
 400     too_many_args = ptext (sLit "Kind error:") <+> quotes ppr_fun <+>
 401                     ptext (sLit "is applied to too many type arguments")
 402
 403 ---------------------------
 404 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 405 kcHsContext ctxt = wrapLocM (mapM kcHsLPred) ctxt
 406
 407 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 408 kcHsLPred = wrapLocM kcHsPred
 409
 410 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 411 kcHsPred pred = do      -- Checks that the result is of kind liftedType
 412     (pred', kind) <- kc_pred pred
 413     checkExpectedKind pred kind liftedTypeKind
 414     return pred'
 415
 416 ---------------------------
 417 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 418         -- Does *not* check for a saturated
 419         -- application (reason: used from TcDeriv)
 420 kc_pred (HsIParam name ty)
 421   = do { (ty', kind) <- kcHsType ty
 422        ; return (HsIParam name ty', kind)
 423        }
 424 kc_pred (HsClassP cls tys)
 425   = do { kind <- kcClass cls
 426        ; (tys', res_kind) <- kcApps kind (ppr cls) tys
 427        ; return (HsClassP cls tys', res_kind)
 428        }
 429 kc_pred (HsEqualP ty1 ty2)
 430   = do { (ty1', kind1) <- kcHsType ty1
 431 --       ; checkExpectedKind ty1 kind1 liftedTypeKind
 432        ; (ty2', kind2) <- kcHsType ty2
 433 --       ; checkExpectedKind ty2 kind2 liftedTypeKind
 434        ; checkExpectedKind ty2 kind2 kind1
 435        ; return (HsEqualP ty1' ty2', liftedTypeKind)
 436        }
 437
 438 ---------------------------
 439 kcTyVar :: Name -> TcM TcKind
 440 kcTyVar name = do       -- Could be a tyvar or a tycon
 441     traceTc (text "lk1" <+> ppr name)
 442     thing <- tcLookup name
 443     traceTc (text "lk2" <+> ppr name <+> ppr thing)
 444     case thing of
 445         ATyVar _ ty             -> return (typeKind ty)
 446         AThing kind             -> return kind
 447         AGlobal (ATyCon tc)     -> return (tyConKind tc)
 448         _                       -> wrongThingErr "type" thing name
 449
 450 kcClass :: Name -> TcM TcKind
 451 kcClass cls = do        -- Must be a class
 452     thing <- tcLookup cls
 453     case thing of
 454         AThing kind             -> return kind
 455         AGlobal (AClass cls)    -> return (tyConKind (classTyCon cls))
 456         _                       -> wrongThingErr "class" thing cls
 457 \end{code}
 458
 459
 460 %************************************************************************
 461 %*                                                                      *
 462                 Desugaring
 463 %*                                                                      *
 464 %************************************************************************
 465
 466 The type desugarer
 467
 468         * Transforms from HsType to Type
 469         * Zonks any kinds
 470
 471 It cannot fail, and does no validity checking, except for
 472 structural matters, such as
 473         (a) spurious ! annotations.
 474         (b) a class used as a type
 475
 476 \begin{code}
 477 dsHsType :: LHsType Name -> TcM Type
 478 -- All HsTyVarBndrs in the intput type are kind-annotated
 479 dsHsType ty = ds_type (unLoc ty)
 480
 481 ds_type :: HsType Name -> TcM Type
 482 ds_type ty@(HsTyVar _)
 483   = ds_app ty []
 484
 485 ds_type (HsParTy ty)            -- Remove the parentheses markers
 486   = dsHsType ty
 487
 488 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 489   = failWithTc (ptext (sLit "Unexpected strictness annotation:") <+> ppr ty)
 490
 491 ds_type (HsKindSig ty _)
 492   = dsHsType ty -- Kind checking done already
 493
 494 ds_type (HsListTy ty) = do
 495     tau_ty <- dsHsType ty
 496     checkWiredInTyCon listTyCon
 497     return (mkListTy tau_ty)
 498
 499 ds_type (HsPArrTy ty) = do
 500     tau_ty <- dsHsType ty
 501     checkWiredInTyCon parrTyCon
 502     return (mkPArrTy tau_ty)
 503
 504 ds_type (HsTupleTy boxity tys) = do
 505     tau_tys <- dsHsTypes tys
 506     checkWiredInTyCon tycon
 507     return (mkTyConApp tycon tau_tys)
 508   where
 509     tycon = tupleTyCon boxity (length tys)
 510
 511 ds_type (HsFunTy ty1 ty2) = do
 512     tau_ty1 <- dsHsType ty1
 513     tau_ty2 <- dsHsType ty2
 514     return (mkFunTy tau_ty1 tau_ty2)
 515
 516 ds_type (HsOpTy ty1 (L span op) ty2) = do
 517     tau_ty1 <- dsHsType ty1
 518     tau_ty2 <- dsHsType ty2
 519     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 520
 521 ds_type (HsNumTy n)
 522   = ASSERT(n==1) do
 523     tc <- tcLookupTyCon genUnitTyConName
 524     return (mkTyConApp tc [])
 525
 526 ds_type ty@(HsAppTy _ _)
 527   = ds_app ty []
 528
 529 ds_type (HsPredTy pred) = do
 530     pred' <- dsHsPred pred
 531     return (mkPredTy pred')
 532
 533 ds_type (HsForAllTy _ tv_names ctxt ty)
 534   = tcTyVarBndrs tv_names               $ \ tyvars -> do
 535     theta <- mapM dsHsLPred (unLoc ctxt)
 536     tau <- dsHsType ty
 537     return (mkSigmaTy tyvars theta tau)
 538
 539 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 540
 541 ds_type (HsDocTy ty _)  -- Remove the doc comment
 542   = dsHsType ty
 543
 544 dsHsTypes :: [LHsType Name] -> TcM [Type]
 545 dsHsTypes arg_tys = mapM dsHsType arg_tys
 546 \end{code}
 547
 548 Help functions for type applications
 549 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 550
 551 \begin{code}
 552 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 553 ds_app (HsAppTy ty1 ty2) tys
 554   = ds_app (unLoc ty1) (ty2:tys)
 555
 556 ds_app ty tys = do
 557     arg_tys <- dsHsTypes tys
 558     case ty of
 559         HsTyVar fun -> ds_var_app fun arg_tys
 560         _           -> do fun_ty <- ds_type ty
 561                           return (mkAppTys fun_ty arg_tys)
 562
 563 ds_var_app :: Name -> [Type] -> TcM Type
 564 ds_var_app name arg_tys = do
 565     thing <- tcLookup name
 566     case thing of
 567         ATyVar _ ty         -> return (mkAppTys ty arg_tys)
 568         AGlobal (ATyCon tc) -> return (mkTyConApp tc arg_tys)
 569         _                   -> wrongThingErr "type" thing name
 570 \end{code}
 571
 572
 573 Contexts
 574 ~~~~~~~~
 575
 576 \begin{code}
 577 dsHsLPred :: LHsPred Name -> TcM PredType
 578 dsHsLPred pred = dsHsPred (unLoc pred)
 579
 580 dsHsPred :: HsPred Name -> TcM PredType
 581 dsHsPred (HsClassP class_name tys)
 582   = do { arg_tys <- dsHsTypes tys
 583        ; clas <- tcLookupClass class_name
 584        ; return (ClassP clas arg_tys)
 585        }
 586 dsHsPred (HsEqualP ty1 ty2)
 587   = do { arg_ty1 <- dsHsType ty1
 588        ; arg_ty2 <- dsHsType ty2
 589        ; return (EqPred arg_ty1 arg_ty2)
 590        }
 591 dsHsPred (HsIParam name ty)
 592   = do { arg_ty <- dsHsType ty
 593        ; return (IParam name arg_ty)
 594        }
 595 \end{code}
 596
 597 GADT constructor signatures
 598
 599 \begin{code}
 600 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 601 tcLHsConResTy (L span res_ty)
 602   = setSrcSpan span $
 603     case get_args res_ty [] of
 604            (HsTyVar tc_name, args)
 605               -> do { args' <- mapM dsHsType args
 606                     ; thing <- tcLookup tc_name
 607                     ; case thing of
 608                         AGlobal (ATyCon tc) -> return (tc, args')
 609                         _ -> failWithTc (badGadtDecl res_ty) }
 610            _ -> failWithTc (badGadtDecl res_ty)
 611   where
 612         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 613         -- because that causes a black hole, and for good reason.  Building
 614         -- the type means expanding type synonyms, and we can't do that
 615         -- inside the "knot".  So we have to work by steam.
 616     get_args (HsAppTy (L _ fun) arg)   args = get_args fun (arg:args)
 617     get_args (HsParTy (L _ ty))        args = get_args ty  args
 618     get_args (HsOpTy ty1 (L _ tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 619     get_args ty                        args = (ty, args)
 620
 621 badGadtDecl :: HsType Name -> SDoc
 622 badGadtDecl ty
 623   = hang (ptext (sLit "Malformed constructor result type:"))
 624        2 (ppr ty)
 625
 626 typeCtxt :: HsType Name -> SDoc
 627 typeCtxt ty = ptext (sLit "In the type") <+> quotes (ppr ty)
 628 \end{code}
 629
 630 %************************************************************************
 631 %*                                                                      *
 632                 Type-variable binders
 633 %*                                                                      *
 634 %************************************************************************
 635
 636
 637 \begin{code}
 638 kcHsTyVars :: [LHsTyVarBndr Name]
 639            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 640                                                 -- They scope over the thing inside
 641            -> TcM r
 642 kcHsTyVars tvs thing_inside  = do
 643     bndrs <- mapM (wrapLocM kcHsTyVar) tvs
 644     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 645
 646 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 647         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 648 kcHsTyVar (UserTyVar name)        = KindedTyVar name <$> newKindVar
 649 kcHsTyVar (KindedTyVar name kind) = return (KindedTyVar name kind)
 650
 651 ------------------
 652 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 653              -> ([TyVar] -> TcM r)
 654              -> TcM r
 655 -- Used when type-checking types/classes/type-decls
 656 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 657 tcTyVarBndrs bndrs thing_inside = do
 658     tyvars <- mapM (zonk . unLoc) bndrs
 659     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 660   where
 661     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 662                                       ; return (mkTyVar name kind') }
 663     zonk (UserTyVar name) = WARN( True, ptext (sLit "Un-kinded tyvar") <+> ppr name )
 664                             return (mkTyVar name liftedTypeKind)
 665
 666 -----------------------------------
 667 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 668 -- GADT decls can have a (perhaps partial) kind signature
 669 --      e.g.  data T :: * -> * -> * where ...
 670 -- This function makes up suitable (kinded) type variables for
 671 -- the argument kinds, and checks that the result kind is indeed *.
 672 -- We use it also to make up argument type variables for for data instances.
 673 tcDataKindSig Nothing = return []
 674 tcDataKindSig (Just kind)
 675   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 676         ; span <- getSrcSpanM
 677         ; us   <- newUniqueSupply
 678         ; let uniqs = uniqsFromSupply us
 679         ; return [ mk_tv span uniq str kind
 680                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 681   where
 682     (arg_kinds, res_kind) = splitKindFunTys kind
 683     mk_tv loc uniq str kind = mkTyVar name kind
 684         where
 685            name = mkInternalName uniq occ loc
 686            occ  = mkOccName tvName str
 687
 688     names :: [String]   -- a,b,c...aa,ab,ac etc
 689     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 690
 691 badKindSig :: Kind -> SDoc
 692 badKindSig kind
 693  = hang (ptext (sLit "Kind signature on data type declaration has non-* return kind"))
 694         2 (ppr kind)
 695 \end{code}
 696
 697
 698 %************************************************************************
 699 %*                                                                      *
 700                 Scoped type variables
 701 %*                                                                      *
 702 %************************************************************************
 703
 704
 705 tcAddScopedTyVars is used for scoped type variables added by pattern
 706 type signatures
 707         e.g.  \ ((x::a), (y::a)) -> x+y
 708 They never have explicit kinds (because this is source-code only)
 709 They are mutable (because they can get bound to a more specific type).
 710
 711 Usually we kind-infer and expand type splices, and then
 712 tupecheck/desugar the type.  That doesn't work well for scoped type
 713 variables, because they scope left-right in patterns.  (e.g. in the
 714 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 715
 716 The current not-very-good plan is to
 717   * find all the types in the patterns
 718   * find their free tyvars
 719   * do kind inference
 720   * bring the kinded type vars into scope
 721   * BUT throw away the kind-checked type
 722         (we'll kind-check it again when we type-check the pattern)
 723
 724 This is bad because throwing away the kind checked type throws away
 725 its splices.  But too bad for now.  [July 03]
 726
 727 Historical note:
 728     We no longer specify that these type variables must be univerally
 729     quantified (lots of email on the subject).  If you want to put that
 730     back in, you need to
 731         a) Do a checkSigTyVars after thing_inside
 732         b) More insidiously, don't pass in expected_ty, else
 733            we unify with it too early and checkSigTyVars barfs
 734            Instead you have to pass in a fresh ty var, and unify
 735            it with expected_ty afterwards
 736
 737 \begin{code}
 738 tcHsPatSigType :: UserTypeCtxt
 739                -> LHsType Name          -- The type signature
 740                -> TcM ([TyVar],         -- Newly in-scope type variables
 741                         Type)           -- The signature
 742 -- Used for type-checking type signatures in
 743 -- (a) patterns           e.g  f (x::Int) = e
 744 -- (b) result signatures  e.g. g x :: Int = e
 745 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 746
 747 tcHsPatSigType ctxt hs_ty
 748   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 749     do  {       -- Find the type variables that are mentioned in the type
 750                 -- but not already in scope.  These are the ones that
 751                 -- should be bound by the pattern signature
 752           in_scope <- getInLocalScope
 753         ; let span = getLoc hs_ty
 754               sig_tvs = [ L span (UserTyVar n)
 755                         | n <- nameSetToList (extractHsTyVars hs_ty),
 756                           not (in_scope n) ]
 757
 758         ; (tyvars, sig_ty) <- tcHsQuantifiedType sig_tvs hs_ty
 759         ; checkValidType ctxt sig_ty
 760         ; return (tyvars, sig_ty)
 761       }
 762
 763 tcPatSig :: UserTypeCtxt
 764          -> LHsType Name
 765          -> BoxySigmaType
 766          -> TcM (TcType,           -- The type to use for "inside" the signature
 767                  [(Name, TcType)], -- The new bit of type environment, binding
 768                                    -- the scoped type variables
 769                  CoercionI)        -- Coercion due to unification with actual ty
 770 tcPatSig ctxt sig res_ty
 771   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 772
 773         ; if null sig_tvs then do {
 774                 -- The type signature binds no type variables,
 775                 -- and hence is rigid, so use it to zap the res_ty
 776                   coi <- boxyUnify sig_ty res_ty
 777                 ; return (sig_ty, [], coi)
 778
 779         } else do {
 780                 -- Type signature binds at least one scoped type variable
 781
 782                 -- A pattern binding cannot bind scoped type variables
 783                 -- The renamer fails with a name-out-of-scope error
 784                 -- if a pattern binding tries to bind a type variable,
 785                 -- So we just have an ASSERT here
 786         ; let in_pat_bind = case ctxt of
 787                                 BindPatSigCtxt -> True
 788                                 _              -> False
 789         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 790
 791                 -- Check that pat_ty is rigid
 792         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 793
 794                 -- Now match the pattern signature against res_ty
 795                 -- For convenience, and uniform-looking error messages
 796                 -- we do the matching by allocating meta type variables,
 797                 -- unifying, and reading out the results.
 798                 -- This is a strictly local operation.
 799         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 800         ; coi <- boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty)
 801                            res_ty
 802         ; sig_tv_tys <- mapM readFilledBox box_tvs
 803
 804                 -- Check that each is bound to a distinct type variable,
 805                 -- and one that is not already in scope
 806         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 807         ; binds_in_scope <- getScopedTyVarBinds
 808         ; check binds_in_scope tv_binds
 809
 810                 -- Phew!
 811         ; return (res_ty, tv_binds, coi)
 812         } }
 813   where
 814     check _ [] = return ()
 815     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 816                                       ; check ((n,ty):in_scope) rest }
 817
 818     check_one in_scope n ty
 819         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 820                 -- Must bind to a type variable
 821
 822              ; checkTc (null dups) (dupInScope n (head dups) ty)
 823                 -- Must not bind to the same type variable
 824                 -- as some other in-scope type variable
 825
 826              ; return () }
 827         where
 828           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 829 \end{code}
 830
 831
 832 %************************************************************************
 833 %*                                                                      *
 834                 Scoped type variables
 835 %*                                                                      *
 836 %************************************************************************
 837
 838 \begin{code}
 839 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 840 pprHsSigCtxt ctxt hs_ty = vcat [ ptext (sLit "In") <+> pprUserTypeCtxt ctxt <> colon,
 841                                  nest 2 (pp_sig ctxt) ]
 842   where
 843     pp_sig (FunSigCtxt n)  = pp_n_colon n
 844     pp_sig (ConArgCtxt n)  = pp_n_colon n
 845     pp_sig (ForSigCtxt n)  = pp_n_colon n
 846     pp_sig _               = ppr (unLoc hs_ty)
 847
 848     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 849
 850 wobblyPatSig :: [Var] -> SDoc
 851 wobblyPatSig sig_tvs
 852   = hang (ptext (sLit "A pattern type signature cannot bind scoped type variables")
 853                 <+> pprQuotedList sig_tvs)
 854        2 (ptext (sLit "unless the pattern has a rigid type context"))
 855
 856 scopedNonVar :: Name -> Type -> SDoc
 857 scopedNonVar n ty
 858   = vcat [sep [ptext (sLit "The scoped type variable") <+> quotes (ppr n),
 859                nest 2 (ptext (sLit "is bound to the type") <+> quotes (ppr ty))],
 860           nest 2 (ptext (sLit "You can only bind scoped type variables to type variables"))]
 861
 862 dupInScope :: Name -> Name -> Type -> SDoc
 863 dupInScope n n' _
 864   = hang (ptext (sLit "The scoped type variables") <+> quotes (ppr n) <+> ptext (sLit "and") <+> quotes (ppr n'))
 865        2 (vcat [ptext (sLit "are bound to the same type (variable)"),
 866                 ptext (sLit "Distinct scoped type variables must be distinct")])
 867
 868 wrongEqualityErr :: TcM (HsType Name, TcKind)
 869 wrongEqualityErr
 870   = failWithTc (text "Equality predicate used as a type")
 871 \end{code}
 872