compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsDeriv,
  10         tcHsInstHead, tcHsQuantifiedType,
  11         UserTypeCtxt(..),
  12
  13                 -- Kind checking
  14         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  15         kcCheckHsType, kcHsContext, kcHsType,
  16
  17                 -- Typechecking kinded types
  18         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  19         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  20         tcDataKindSig,
  21
  22                 -- Pattern type signatures
  23         tcHsPatSigType, tcPatSig
  24    ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn
  29 import RnHsSyn
  30 import TcRnMonad
  31 import TcEnv
  32 import TcMType
  33 import TcUnify
  34 import TcIface
  35 import TcType
  36 import {- Kind parts of -} Type
  37 import Var
  38 import TyCon
  39 import Class
  40 import Name
  41 import OccName
  42 import NameSet
  43 import PrelNames
  44 import TysWiredIn
  45 import BasicTypes
  46 import SrcLoc
  47 import UniqSupply
  48 import Outputable
  49 \end{code}
  50
  51
  52         ----------------------------
  53                 General notes
  54         ----------------------------
  55
  56 Generally speaking we now type-check types in three phases
  57
  58   1.  kcHsType: kind check the HsType
  59         *includes* performing any TH type splices;
  60         so it returns a translated, and kind-annotated, type
  61
  62   2.  dsHsType: convert from HsType to Type:
  63         perform zonking
  64         expand type synonyms [mkGenTyApps]
  65         hoist the foralls [tcHsType]
  66
  67   3.  checkValidType: check the validity of the resulting type
  68
  69 Often these steps are done one after the other (tcHsSigType).
  70 But in mutually recursive groups of type and class decls we do
  71         1 kind-check the whole group
  72         2 build TyCons/Classes in a knot-tied way
  73         3 check the validity of types in the now-unknotted TyCons/Classes
  74
  75 For example, when we find
  76         (forall a m. m a -> m a)
  77 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  78 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  79 an environment that binds a and m suitably.
  80
  81 The kind checker passed to tcHsTyVars needs to look at enough to
  82 establish the kind of the tyvar:
  83   * For a group of type and class decls, it's just the group, not
  84         the rest of the program
  85   * For a tyvar bound in a pattern type signature, its the types
  86         mentioned in the other type signatures in that bunch of patterns
  87   * For a tyvar bound in a RULE, it's the type signatures on other
  88         universally quantified variables in the rule
  89
  90 Note that this may occasionally give surprising results.  For example:
  91
  92         data T a b = MkT (a b)
  93
  94 Here we deduce                  a::*->*,       b::*
  95 But equally valid would be      a::(*->*)-> *, b::*->*
  96
  97
  98 Validity checking
  99 ~~~~~~~~~~~~~~~~~
 100 Some of the validity check could in principle be done by the kind checker,
 101 but not all:
 102
 103 - During desugaring, we normalise by expanding type synonyms.  Only
 104   after this step can we check things like type-synonym saturation
 105   e.g.  type T k = k Int
 106         type S a = a
 107   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 108   and then S is saturated.  This is a GHC extension.
 109
 110 - Similarly, also a GHC extension, we look through synonyms before complaining
 111   about the form of a class or instance declaration
 112
 113 - Ambiguity checks involve functional dependencies, and it's easier to wait
 114   until knots have been resolved before poking into them
 115
 116 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 117 finished building the loop.  So to keep things simple, we postpone most validity
 118 checking until step (3).
 119
 120 Knot tying
 121 ~~~~~~~~~~
 122 During step (1) we might fault in a TyCon defined in another module, and it might
 123 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 124 knot around type declarations with ARecThing, so that the fault-in code can get
 125 the TyCon being defined.
 126
 127
 128 %************************************************************************
 129 %*                                                                      *
 130 \subsection{Checking types}
 131 %*                                                                      *
 132 %************************************************************************
 133
 134 \begin{code}
 135 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 136   -- Do kind checking, and hoist for-alls to the top
 137   -- NB: it's important that the foralls that come from the top-level
 138   --     HsForAllTy in hs_ty occur *first* in the returned type.
 139   --     See Note [Scoped] with TcSigInfo
 140 tcHsSigType ctxt hs_ty
 141   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 142     do  { kinded_ty <- kcTypeType hs_ty
 143         ; ty <- tcHsKindedType kinded_ty
 144         ; checkValidType ctxt ty
 145         ; returnM ty }
 146
 147 tcHsInstHead :: LHsType Name -> TcM ([TyVar], ThetaType, Type)
 148 -- Typecheck an instance head.  We can't use
 149 -- tcHsSigType, because it's not a valid user type.
 150 tcHsInstHead hs_ty
 151   = do  { kinded_ty <- kcHsSigType hs_ty
 152         ; poly_ty   <- tcHsKindedType kinded_ty
 153         ; return (tcSplitSigmaTy poly_ty) }
 154
 155 tcHsQuantifiedType :: [LHsTyVarBndr Name] -> LHsType Name -> TcM ([TyVar], Type)
 156 -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 157 -- except that we want to keep the tvs separate
 158 tcHsQuantifiedType tv_names hs_ty
 159   = kcHsTyVars tv_names $ \ tv_names' ->
 160     do  { kc_ty <- kcHsSigType hs_ty
 161         ; tcTyVarBndrs tv_names' $ \ tvs ->
 162     do  { ty <- dsHsType kc_ty
 163         ; return (tvs, ty) } }
 164
 165 -- Used for the deriving(...) items
 166 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 167 tcHsDeriv = addLocM (tc_hs_deriv [])
 168
 169 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 170   = kcHsTyVars tv_names                 $ \ tv_names' ->
 171     do  { cls_kind <- kcClass cls_name
 172         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 173         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 174     do  { arg_tys <- dsHsTypes tys
 175         ; cls <- tcLookupClass cls_name
 176         ; return (tyvars, cls, arg_tys) }}
 177
 178 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 179   =     -- Funny newtype deriving form
 180         --      forall a. C [a]
 181         -- where C has arity 2.  Hence can't use regular functions
 182     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 183
 184 tc_hs_deriv _ other
 185   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 186 \end{code}
 187
 188         These functions are used during knot-tying in
 189         type and class declarations, when we have to
 190         separate kind-checking, desugaring, and validity checking
 191
 192 \begin{code}
 193 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 194         -- Used for type signatures
 195 kcHsSigType ty       = kcTypeType ty
 196 kcHsLiftedSigType ty = kcLiftedType ty
 197
 198 tcHsKindedType :: LHsType Name -> TcM Type
 199   -- Don't do kind checking, nor validity checking.
 200   -- This is used in type and class decls, where kinding is
 201   -- done in advance, and validity checking is done later
 202   -- [Validity checking done later because of knot-tying issues.]
 203 tcHsKindedType hs_ty = dsHsType hs_ty
 204
 205 tcHsBangType :: LHsType Name -> TcM Type
 206 -- Permit a bang, but discard it
 207 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 208 tcHsBangType ty                       = tcHsKindedType ty
 209
 210 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 211 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 212 -- Does not do validity checking, like tcHsKindedType
 213 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 214 \end{code}
 215
 216
 217 %************************************************************************
 218 %*                                                                      *
 219                 The main kind checker: kcHsType
 220 %*                                                                      *
 221 %************************************************************************
 222
 223         First a couple of simple wrappers for kcHsType
 224
 225 \begin{code}
 226 ---------------------------
 227 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 228 -- The type ty must be a *lifted* *type*
 229 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 230
 231 ---------------------------
 232 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 233 -- The type ty must be a *type*, but it can be lifted or
 234 -- unlifted or an unboxed tuple.
 235 kcTypeType ty = kcCheckHsType ty openTypeKind
 236
 237 ---------------------------
 238 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 239 -- Check that the type has the specified kind
 240 -- Be sure to use checkExpectedKind, rather than simply unifying
 241 -- with OpenTypeKind, because it gives better error messages
 242 kcCheckHsType (L span ty) exp_kind
 243   = setSrcSpan span                             $
 244     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 245                 -- Add the context round the inner check only
 246                 -- because checkExpectedKind already mentions
 247                 -- 'ty' by name in any error message
 248
 249         ; checkExpectedKind (strip ty) act_kind exp_kind
 250         ; return (L span ty') }
 251   where
 252         -- Wrap a context around only if we want to show that contexts.
 253     add_ctxt (HsPredTy p)                thing = thing
 254         -- Omit invisble ones and ones user's won't grok (HsPred p).
 255     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 256         -- Omit wrapping if the theta-part is empty
 257         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 258         --         case of kc_hs_type, will do the wrapping instead
 259         --         and we don't want to duplicate
 260     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 261
 262         -- We infer the kind of the type, and then complain if it's
 263         -- not right.  But we don't want to complain about
 264         --      (ty) or !(ty) or forall a. ty
 265         -- when the real difficulty is with the 'ty' part.
 266     strip (HsParTy (L _ ty))          = strip ty
 267     strip (HsBangTy _ (L _ ty))       = strip ty
 268     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 269     strip ty                          = ty
 270 \end{code}
 271
 272         Here comes the main function
 273
 274 \begin{code}
 275 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 276 kcHsType ty = wrapLocFstM kc_hs_type ty
 277 -- kcHsType *returns* the kind of the type, rather than taking an expected
 278 -- kind as argument as tcExpr does.
 279 -- Reasons:
 280 --      (a) the kind of (->) is
 281 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 282 --          so we'd need to generate huge numbers of bx variables.
 283 --      (b) kinds are so simple that the error messages are fine
 284 --
 285 -- The translated type has explicitly-kinded type-variable binders
 286
 287 kc_hs_type (HsParTy ty)
 288  = kcHsType ty          `thenM` \ (ty', kind) ->
 289    returnM (HsParTy ty', kind)
 290
 291 kc_hs_type (HsTyVar name)
 292   = kcTyVar name        `thenM` \ kind ->
 293     returnM (HsTyVar name, kind)
 294
 295 kc_hs_type (HsListTy ty)
 296   = kcLiftedType ty                     `thenM` \ ty' ->
 297     returnM (HsListTy ty', liftedTypeKind)
 298
 299 kc_hs_type (HsPArrTy ty)
 300   = kcLiftedType ty                     `thenM` \ ty' ->
 301     returnM (HsPArrTy ty', liftedTypeKind)
 302
 303 kc_hs_type (HsNumTy n)
 304    = returnM (HsNumTy n, liftedTypeKind)
 305
 306 kc_hs_type (HsKindSig ty k)
 307   = kcCheckHsType ty k  `thenM` \ ty' ->
 308     returnM (HsKindSig ty' k, k)
 309
 310 kc_hs_type (HsTupleTy Boxed tys)
 311   = mappM kcLiftedType tys      `thenM` \ tys' ->
 312     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 313
 314 kc_hs_type (HsTupleTy Unboxed tys)
 315   = mappM kcTypeType tys        `thenM` \ tys' ->
 316     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 317
 318 kc_hs_type (HsFunTy ty1 ty2)
 319   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 320     kcTypeType ty2                      `thenM` \ ty2' ->
 321     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 322
 323 kc_hs_type ty@(HsOpTy ty1 op ty2)
 324   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 325     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 326     returnM (HsOpTy ty1' op ty2', res_kind)
 327
 328 kc_hs_type ty@(HsAppTy ty1 ty2)
 329   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 330     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 331     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 332   where
 333     (fun_ty, arg_tys) = split ty1 [ty2]
 334     split (L _ (HsAppTy f a)) as = split f (a:as)
 335     split f                   as = (f,as)
 336     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 337                                                 -- the application; they are never used
 338
 339 kc_hs_type (HsPredTy pred)
 340   = kcHsPred pred               `thenM` \ pred' ->
 341     returnM (HsPredTy pred', liftedTypeKind)
 342
 343 kc_hs_type (HsForAllTy exp tv_names context ty)
 344   = kcHsTyVars tv_names         $ \ tv_names' ->
 345     do  { ctxt' <- kcHsContext context
 346         ; ty'   <- kcLiftedType ty
 347              -- The body of a forall is usually a type, but in principle
 348              -- there's no reason to prohibit *unlifted* types.
 349              -- In fact, GHC can itself construct a function with an
 350              -- unboxed tuple inside a for-all (via CPR analyis; see
 351              -- typecheck/should_compile/tc170)
 352              --
 353              -- Still, that's only for internal interfaces, which aren't
 354              -- kind-checked, so we only allow liftedTypeKind here
 355
 356         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 357
 358 kc_hs_type (HsBangTy b ty)
 359   = do { (ty', kind) <- kcHsType ty
 360        ; return (HsBangTy b ty', kind) }
 361
 362 kc_hs_type ty@(HsSpliceTy _)
 363   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 364
 365 -- remove the doc nodes here, no need to worry about the location since
 366 -- its the same for a doc node and it's child type node
 367 kc_hs_type (HsDocTy ty _)
 368   = kc_hs_type (unLoc ty)
 369
 370 ---------------------------
 371 kcApps :: TcKind                        -- Function kind
 372        -> SDoc                          -- Function
 373        -> [LHsType Name]                -- Arg types
 374        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 375 kcApps fun_kind ppr_fun args
 376   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 377     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 378     returnM (args', res_kind)
 379   where
 380     split_fk fk 0 = returnM ([], fk)
 381     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 382                     case mb_fk of
 383                         Nothing       -> failWithTc too_many_args
 384                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 385                                          returnM (ak:aks, rk)
 386
 387     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 388
 389     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 390                     ptext SLIT("is applied to too many type arguments")
 391
 392 ---------------------------
 393 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 394 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 395
 396 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 397 kcHsLPred = wrapLocM kcHsPred
 398
 399 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 400 kcHsPred pred   -- Checks that the result is of kind liftedType
 401   = kc_pred pred                                `thenM` \ (pred', kind) ->
 402     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 403     returnM pred'
 404
 405 ---------------------------
 406 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 407         -- Does *not* check for a saturated
 408         -- application (reason: used from TcDeriv)
 409 kc_pred pred@(HsIParam name ty)
 410   = do { (ty', kind) <- kcHsType ty
 411        ; returnM (HsIParam name ty', kind)
 412        }
 413 kc_pred pred@(HsClassP cls tys)
 414   = do { kind <- kcClass cls
 415        ; (tys', res_kind) <- kcApps kind (ppr cls) tys
 416        ; returnM (HsClassP cls tys', res_kind)
 417        }
 418 kc_pred pred@(HsEqualP ty1 ty2)
 419   = do { (ty1', kind1) <- kcHsType ty1
 420 --       ; checkExpectedKind ty1 kind1 liftedTypeKind
 421        ; (ty2', kind2) <- kcHsType ty2
 422 --       ; checkExpectedKind ty2 kind2 liftedTypeKind
 423        ; checkExpectedKind ty2 kind2 kind1
 424        ; returnM (HsEqualP ty1' ty2', liftedTypeKind)
 425        }
 426
 427 ---------------------------
 428 kcTyVar :: Name -> TcM TcKind
 429 kcTyVar name    -- Could be a tyvar or a tycon
 430   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 431     tcLookup name       `thenM` \ thing ->
 432     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 433     case thing of
 434         ATyVar _ ty             -> returnM (typeKind ty)
 435         AThing kind             -> returnM kind
 436         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 437         other                   -> wrongThingErr "type" thing name
 438
 439 kcClass :: Name -> TcM TcKind
 440 kcClass cls     -- Must be a class
 441   = tcLookup cls                                `thenM` \ thing ->
 442     case thing of
 443         AThing kind             -> returnM kind
 444         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 445         other                   -> wrongThingErr "class" thing cls
 446 \end{code}
 447
 448
 449 %************************************************************************
 450 %*                                                                      *
 451                 Desugaring
 452 %*                                                                      *
 453 %************************************************************************
 454
 455 The type desugarer
 456
 457         * Transforms from HsType to Type
 458         * Zonks any kinds
 459
 460 It cannot fail, and does no validity checking, except for
 461 structural matters, such as
 462         (a) spurious ! annotations.
 463         (b) a class used as a type
 464
 465 \begin{code}
 466 dsHsType :: LHsType Name -> TcM Type
 467 -- All HsTyVarBndrs in the intput type are kind-annotated
 468 dsHsType ty = ds_type (unLoc ty)
 469
 470 ds_type ty@(HsTyVar name)
 471   = ds_app ty []
 472
 473 ds_type (HsParTy ty)            -- Remove the parentheses markers
 474   = dsHsType ty
 475
 476 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 477   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 478
 479 ds_type (HsKindSig ty k)
 480   = dsHsType ty -- Kind checking done already
 481
 482 ds_type (HsListTy ty)
 483   = dsHsType ty                 `thenM` \ tau_ty ->
 484     checkWiredInTyCon listTyCon `thenM_`
 485     returnM (mkListTy tau_ty)
 486
 487 ds_type (HsPArrTy ty)
 488   = dsHsType ty                 `thenM` \ tau_ty ->
 489     checkWiredInTyCon parrTyCon `thenM_`
 490     returnM (mkPArrTy tau_ty)
 491
 492 ds_type (HsTupleTy boxity tys)
 493   = dsHsTypes tys               `thenM` \ tau_tys ->
 494     checkWiredInTyCon tycon     `thenM_`
 495     returnM (mkTyConApp tycon tau_tys)
 496   where
 497     tycon = tupleTyCon boxity (length tys)
 498
 499 ds_type (HsFunTy ty1 ty2)
 500   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 501     dsHsType ty2                        `thenM` \ tau_ty2 ->
 502     returnM (mkFunTy tau_ty1 tau_ty2)
 503
 504 ds_type (HsOpTy ty1 (L span op) ty2)
 505   = dsHsType ty1                `thenM` \ tau_ty1 ->
 506     dsHsType ty2                `thenM` \ tau_ty2 ->
 507     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 508
 509 ds_type (HsNumTy n)
 510   = ASSERT(n==1)
 511     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 512     returnM (mkTyConApp tc [])
 513
 514 ds_type ty@(HsAppTy _ _)
 515   = ds_app ty []
 516
 517 ds_type (HsPredTy pred)
 518   = dsHsPred pred       `thenM` \ pred' ->
 519     returnM (mkPredTy pred')
 520
 521 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 522   = tcTyVarBndrs tv_names               $ \ tyvars ->
 523     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 524     dsHsType ty                         `thenM` \ tau ->
 525     returnM (mkSigmaTy tyvars theta tau)
 526
 527 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 528
 529 ds_type (HsDocTy ty _)  -- Remove the doc comment
 530   = dsHsType ty
 531
 532 dsHsTypes arg_tys = mappM dsHsType arg_tys
 533 \end{code}
 534
 535 Help functions for type applications
 536 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 537
 538 \begin{code}
 539 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 540 ds_app (HsAppTy ty1 ty2) tys
 541   = ds_app (unLoc ty1) (ty2:tys)
 542
 543 ds_app ty tys
 544   = dsHsTypes tys                       `thenM` \ arg_tys ->
 545     case ty of
 546         HsTyVar fun -> ds_var_app fun arg_tys
 547         other       -> ds_type ty               `thenM` \ fun_ty ->
 548                        returnM (mkAppTys fun_ty arg_tys)
 549
 550 ds_var_app :: Name -> [Type] -> TcM Type
 551 ds_var_app name arg_tys
 552  = tcLookup name                        `thenM` \ thing ->
 553     case thing of
 554         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 555         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 556         other               -> wrongThingErr "type" thing name
 557 \end{code}
 558
 559
 560 Contexts
 561 ~~~~~~~~
 562
 563 \begin{code}
 564 dsHsLPred :: LHsPred Name -> TcM PredType
 565 dsHsLPred pred = dsHsPred (unLoc pred)
 566
 567 dsHsPred pred@(HsClassP class_name tys)
 568   = do { arg_tys <- dsHsTypes tys
 569        ; clas <- tcLookupClass class_name
 570        ; returnM (ClassP clas arg_tys)
 571        }
 572 dsHsPred pred@(HsEqualP ty1 ty2)
 573   = do { arg_ty1 <- dsHsType ty1
 574        ; arg_ty2 <- dsHsType ty2
 575        ; returnM (EqPred arg_ty1 arg_ty2)
 576        }
 577 dsHsPred (HsIParam name ty)
 578   = do { arg_ty <- dsHsType ty
 579        ; returnM (IParam name arg_ty)
 580        }
 581 \end{code}
 582
 583 GADT constructor signatures
 584
 585 \begin{code}
 586 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 587 tcLHsConResTy res_ty
 588   = addErrCtxt (gadtResCtxt res_ty) $
 589     case get_largs res_ty [] of
 590            (HsTyVar tc_name, args)
 591               -> do { args' <- mapM dsHsType args
 592                     ; thing <- tcLookup tc_name
 593                     ; case thing of
 594                         AGlobal (ATyCon tc) -> return (tc, args')
 595                         other -> failWithTc (badGadtDecl res_ty) }
 596            other -> failWithTc (badGadtDecl res_ty)
 597   where
 598         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 599         -- because that causes a black hole, and for good reason.  Building
 600         -- the type means expanding type synonyms, and we can't do that
 601         -- inside the "knot".  So we have to work by steam.
 602     get_largs (L _ ty) args = get_args ty args
 603     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 604     get_args (HsParTy ty)                 args = get_largs ty  args
 605     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 606     get_args ty                           args = (ty, args)
 607
 608 gadtResCtxt ty
 609   = hang (ptext SLIT("In the result type of a data constructor:"))
 610        2 (ppr ty)
 611 badGadtDecl ty
 612   = hang (ptext SLIT("Malformed constructor result type:"))
 613        2 (ppr ty)
 614
 615 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 616 \end{code}
 617
 618 %************************************************************************
 619 %*                                                                      *
 620                 Type-variable binders
 621 %*                                                                      *
 622 %************************************************************************
 623
 624
 625 \begin{code}
 626 kcHsTyVars :: [LHsTyVarBndr Name]
 627            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 628                                                 -- They scope over the thing inside
 629            -> TcM r
 630 kcHsTyVars tvs thing_inside
 631   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 632     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 633
 634 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 635         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 636 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 637                                     returnM (KindedTyVar name kind)
 638 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 639
 640 ------------------
 641 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 642              -> ([TyVar] -> TcM r)
 643              -> TcM r
 644 -- Used when type-checking types/classes/type-decls
 645 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 646 tcTyVarBndrs bndrs thing_inside
 647   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 648     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 649   where
 650     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 651                                       ; return (mkTyVar name kind') }
 652     zonk (UserTyVar name) = WARN( True, ptext SLIT("Un-kinded tyvar") <+> ppr name )
 653                             return (mkTyVar name liftedTypeKind)
 654
 655 -----------------------------------
 656 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 657 -- GADT decls can have a (perhaps partial) kind signature
 658 --      e.g.  data T :: * -> * -> * where ...
 659 -- This function makes up suitable (kinded) type variables for
 660 -- the argument kinds, and checks that the result kind is indeed *.
 661 -- We use it also to make up argument type variables for for data instances.
 662 tcDataKindSig Nothing = return []
 663 tcDataKindSig (Just kind)
 664   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 665         ; span <- getSrcSpanM
 666         ; us   <- newUniqueSupply
 667         ; let uniqs = uniqsFromSupply us
 668         ; return [ mk_tv span uniq str kind
 669                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 670   where
 671     (arg_kinds, res_kind) = splitKindFunTys kind
 672     mk_tv loc uniq str kind = mkTyVar name kind
 673         where
 674            name = mkInternalName uniq occ loc
 675            occ  = mkOccName tvName str
 676
 677     names :: [String]   -- a,b,c...aa,ab,ac etc
 678     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 679
 680 badKindSig :: Kind -> SDoc
 681 badKindSig kind
 682  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 683         2 (ppr kind)
 684 \end{code}
 685
 686
 687 %************************************************************************
 688 %*                                                                      *
 689                 Scoped type variables
 690 %*                                                                      *
 691 %************************************************************************
 692
 693
 694 tcAddScopedTyVars is used for scoped type variables added by pattern
 695 type signatures
 696         e.g.  \ ((x::a), (y::a)) -> x+y
 697 They never have explicit kinds (because this is source-code only)
 698 They are mutable (because they can get bound to a more specific type).
 699
 700 Usually we kind-infer and expand type splices, and then
 701 tupecheck/desugar the type.  That doesn't work well for scoped type
 702 variables, because they scope left-right in patterns.  (e.g. in the
 703 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 704
 705 The current not-very-good plan is to
 706   * find all the types in the patterns
 707   * find their free tyvars
 708   * do kind inference
 709   * bring the kinded type vars into scope
 710   * BUT throw away the kind-checked type
 711         (we'll kind-check it again when we type-check the pattern)
 712
 713 This is bad because throwing away the kind checked type throws away
 714 its splices.  But too bad for now.  [July 03]
 715
 716 Historical note:
 717     We no longer specify that these type variables must be univerally
 718     quantified (lots of email on the subject).  If you want to put that
 719     back in, you need to
 720         a) Do a checkSigTyVars after thing_inside
 721         b) More insidiously, don't pass in expected_ty, else
 722            we unify with it too early and checkSigTyVars barfs
 723            Instead you have to pass in a fresh ty var, and unify
 724            it with expected_ty afterwards
 725
 726 \begin{code}
 727 tcHsPatSigType :: UserTypeCtxt
 728                -> LHsType Name          -- The type signature
 729                -> TcM ([TyVar],         -- Newly in-scope type variables
 730                         Type)           -- The signature
 731 -- Used for type-checking type signatures in
 732 -- (a) patterns           e.g  f (x::Int) = e
 733 -- (b) result signatures  e.g. g x :: Int = e
 734 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 735
 736 tcHsPatSigType ctxt hs_ty
 737   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 738     do  {       -- Find the type variables that are mentioned in the type
 739                 -- but not already in scope.  These are the ones that
 740                 -- should be bound by the pattern signature
 741           in_scope <- getInLocalScope
 742         ; let span = getLoc hs_ty
 743               sig_tvs = [ L span (UserTyVar n)
 744                         | n <- nameSetToList (extractHsTyVars hs_ty),
 745                           not (in_scope n) ]
 746
 747         ; (tyvars, sig_ty) <- tcHsQuantifiedType sig_tvs hs_ty
 748         ; checkValidType ctxt sig_ty
 749         ; return (tyvars, sig_ty)
 750       }
 751
 752 tcPatSig :: UserTypeCtxt
 753          -> LHsType Name
 754          -> BoxySigmaType
 755          -> TcM (TcType,           -- The type to use for "inside" the signature
 756                  [(Name,TcType)])  -- The new bit of type environment, binding
 757                                    -- the scoped type variables
 758 tcPatSig ctxt sig res_ty
 759   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 760
 761         ; if null sig_tvs then do {
 762                 -- The type signature binds no type variables,
 763                 -- and hence is rigid, so use it to zap the res_ty
 764                   boxyUnify sig_ty res_ty
 765                 ; return (sig_ty, [])
 766
 767         } else do {
 768                 -- Type signature binds at least one scoped type variable
 769
 770                 -- A pattern binding cannot bind scoped type variables
 771                 -- The renamer fails with a name-out-of-scope error
 772                 -- if a pattern binding tries to bind a type variable,
 773                 -- So we just have an ASSERT here
 774         ; let in_pat_bind = case ctxt of
 775                                 BindPatSigCtxt -> True
 776                                 other          -> False
 777         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 778
 779                 -- Check that pat_ty is rigid
 780         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 781
 782                 -- Now match the pattern signature against res_ty
 783                 -- For convenience, and uniform-looking error messages
 784                 -- we do the matching by allocating meta type variables,
 785                 -- unifying, and reading out the results.
 786                 -- This is a strictly local operation.
 787         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 788         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 789         ; sig_tv_tys <- mapM readFilledBox box_tvs
 790
 791                 -- Check that each is bound to a distinct type variable,
 792                 -- and one that is not already in scope
 793         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 794         ; binds_in_scope <- getScopedTyVarBinds
 795         ; check binds_in_scope tv_binds
 796
 797                 -- Phew!
 798         ; return (res_ty, tv_binds)
 799         } }
 800   where
 801     check in_scope []            = return ()
 802     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 803                                       ; check ((n,ty):in_scope) rest }
 804
 805     check_one in_scope n ty
 806         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 807                 -- Must bind to a type variable
 808
 809              ; checkTc (null dups) (dupInScope n (head dups) ty)
 810                 -- Must not bind to the same type variable
 811                 -- as some other in-scope type variable
 812
 813              ; return () }
 814         where
 815           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 816 \end{code}
 817
 818
 819 %************************************************************************
 820 %*                                                                      *
 821                 Scoped type variables
 822 %*                                                                      *
 823 %************************************************************************
 824
 825 \begin{code}
 826 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 827 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 828                                  nest 2 (pp_sig ctxt) ]
 829   where
 830     pp_sig (FunSigCtxt n)  = pp_n_colon n
 831     pp_sig (ConArgCtxt n)  = pp_n_colon n
 832     pp_sig (ForSigCtxt n)  = pp_n_colon n
 833     pp_sig other           = ppr (unLoc hs_ty)
 834
 835     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 836
 837
 838 wobblyPatSig sig_tvs
 839   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 840                 <+> pprQuotedList sig_tvs)
 841        2 (ptext SLIT("unless the pattern has a rigid type context"))
 842
 843 scopedNonVar n ty
 844   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 845                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 846           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 847
 848 dupInScope n n' ty
 849   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 850        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 851                 ptext SLIT("Distinct scoped type variables must be distinct")])
 852 \end{code}
 853