compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsSigTypeNC, tcHsDeriv,
  10         tcHsInstHead, tcHsQuantifiedType,
  11         UserTypeCtxt(..),
  12
  13                 -- Kind checking
  14         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  15         kcLHsType, kcCheckLHsType, kcHsContext,
  16
  17                 -- Typechecking kinded types
  18         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  19         tcTyVarBndrs, dsHsType, kcHsLPred, dsHsLPred,
  20         tcDataKindSig, ExpKind(..), EkCtxt(..),
  21
  22                 -- Pattern type signatures
  23         tcHsPatSigType, tcPatSig
  24    ) where
  25
  26 #include "HsVersions.h"
  27
  28 #ifdef GHCI     /* Only if bootstrapped */
  29 import {-# SOURCE #-}   TcSplice( kcSpliceType )
  30 #endif
  31
  32 import HsSyn
  33 import RnHsSyn
  34 import TcRnMonad
  35 import TcEnv
  36 import TcMType
  37 import TcUnify
  38 import TcIface
  39 import TcType
  40 import TysPrim ( ecKind )
  41 import {- Kind parts of -} Type
  42 import Var
  43 import VarSet
  44 import TyCon
  45 import Class
  46 import Name
  47 import NameSet
  48 import TysWiredIn
  49 import BasicTypes
  50 import SrcLoc
  51 import Util
  52 import UniqSupply
  53 import Outputable
  54 import FastString
  55 \end{code}
  56
  57
  58         ----------------------------
  59                 General notes
  60         ----------------------------
  61
  62 Generally speaking we now type-check types in three phases
  63
  64   1.  kcHsType: kind check the HsType
  65         *includes* performing any TH type splices;
  66         so it returns a translated, and kind-annotated, type
  67
  68   2.  dsHsType: convert from HsType to Type:
  69         perform zonking
  70         expand type synonyms [mkGenTyApps]
  71         hoist the foralls [tcHsType]
  72
  73   3.  checkValidType: check the validity of the resulting type
  74
  75 Often these steps are done one after the other (tcHsSigType).
  76 But in mutually recursive groups of type and class decls we do
  77         1 kind-check the whole group
  78         2 build TyCons/Classes in a knot-tied way
  79         3 check the validity of types in the now-unknotted TyCons/Classes
  80
  81 For example, when we find
  82         (forall a m. m a -> m a)
  83 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  84 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  85 an environment that binds a and m suitably.
  86
  87 The kind checker passed to tcHsTyVars needs to look at enough to
  88 establish the kind of the tyvar:
  89   * For a group of type and class decls, it's just the group, not
  90         the rest of the program
  91   * For a tyvar bound in a pattern type signature, its the types
  92         mentioned in the other type signatures in that bunch of patterns
  93   * For a tyvar bound in a RULE, it's the type signatures on other
  94         universally quantified variables in the rule
  95
  96 Note that this may occasionally give surprising results.  For example:
  97
  98         data T a b = MkT (a b)
  99
 100 Here we deduce                  a::*->*,       b::*
 101 But equally valid would be      a::(*->*)-> *, b::*->*
 102
 103
 104 Validity checking
 105 ~~~~~~~~~~~~~~~~~
 106 Some of the validity check could in principle be done by the kind checker,
 107 but not all:
 108
 109 - During desugaring, we normalise by expanding type synonyms.  Only
 110   after this step can we check things like type-synonym saturation
 111   e.g.  type T k = k Int
 112         type S a = a
 113   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 114   and then S is saturated.  This is a GHC extension.
 115
 116 - Similarly, also a GHC extension, we look through synonyms before complaining
 117   about the form of a class or instance declaration
 118
 119 - Ambiguity checks involve functional dependencies, and it's easier to wait
 120   until knots have been resolved before poking into them
 121
 122 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 123 finished building the loop.  So to keep things simple, we postpone most validity
 124 checking until step (3).
 125
 126 Knot tying
 127 ~~~~~~~~~~
 128 During step (1) we might fault in a TyCon defined in another module, and it might
 129 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 130 knot around type declarations with ARecThing, so that the fault-in code can get
 131 the TyCon being defined.
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{Checking types}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 \begin{code}
 141 tcHsSigType, tcHsSigTypeNC :: UserTypeCtxt -> LHsType Name -> TcM Type
 142   -- Do kind checking, and hoist for-alls to the top
 143   -- NB: it's important that the foralls that come from the top-level
 144   --     HsForAllTy in hs_ty occur *first* in the returned type.
 145   --     See Note [Scoped] with TcSigInfo
 146 tcHsSigType ctxt hs_ty
 147   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 148     tcHsSigTypeNC ctxt hs_ty
 149
 150 tcHsSigTypeNC ctxt hs_ty
 151   = do  { (kinded_ty, _kind) <- kc_lhs_type hs_ty
 152           -- The kind is checked by checkValidType, and isn't necessarily
 153           -- of kind * in a Template Haskell quote eg [t| Maybe |]
 154         ; ty <- tcHsKindedType kinded_ty
 155         ; checkValidType ctxt ty
 156         ; return ty }
 157
 158 tcHsInstHead :: LHsType Name -> TcM ([TyVar], ThetaType, Class, [Type])
 159 -- Typecheck an instance head.  We can't use
 160 -- tcHsSigType, because it's not a valid user type.
 161 tcHsInstHead (L loc hs_ty)
 162   = setSrcSpan loc   $  -- No need for an "In the type..." context
 163                         -- because that comes from the caller
 164     do { kinded_ty <- kc_inst_head hs_ty
 165        ; ds_inst_head kinded_ty }
 166   where
 167     kc_inst_head ty@(HsPredTy pred@(HsClassP {}))
 168       = do { (pred', kind) <- kc_pred pred
 169            ; checkExpectedKind ty kind ekLifted
 170            ; return (HsPredTy pred') }
 171     kc_inst_head (HsForAllTy exp tv_names context (L loc ty))
 172       = kcHsTyVars tv_names         $ \ tv_names' ->
 173         do { ctxt' <- kcHsContext context
 174            ; ty'   <- kc_inst_head ty
 175            ; return (HsForAllTy exp tv_names' ctxt' (L loc ty')) }
 176     kc_inst_head _ = failWithTc (ptext (sLit "Malformed instance type"))
 177
 178     ds_inst_head (HsPredTy (HsClassP cls_name tys))
 179       = do { clas <- tcLookupClass cls_name
 180            ; arg_tys <- dsHsTypes tys
 181            ; return ([], [], clas, arg_tys) }
 182     ds_inst_head (HsForAllTy _ tvs ctxt (L _ tau))
 183       = tcTyVarBndrs tvs  $ \ tvs' ->
 184         do { ctxt' <- mapM dsHsLPred (unLoc ctxt)
 185            ; (tvs_r, ctxt_r, cls, tys) <- ds_inst_head tau
 186            ; return (tvs' ++ tvs_r, ctxt' ++ ctxt_r , cls, tys) }
 187     ds_inst_head _ = panic "ds_inst_head"
 188
 189 tcHsQuantifiedType :: [LHsTyVarBndr Name] -> LHsType Name -> TcM ([TyVar], Type)
 190 -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 191 -- except that we want to keep the tvs separate
 192 tcHsQuantifiedType tv_names hs_ty
 193   = kcHsTyVars tv_names $ \ tv_names' ->
 194     do  { kc_ty <- kcHsSigType hs_ty
 195         ; tcTyVarBndrs tv_names' $ \ tvs ->
 196     do  { ty <- dsHsType kc_ty
 197         ; return (tvs, ty) } }
 198
 199 -- Used for the deriving(...) items
 200 tcHsDeriv :: HsType Name -> TcM ([TyVar], Class, [Type])
 201 tcHsDeriv = tc_hs_deriv []
 202
 203 tc_hs_deriv :: [LHsTyVarBndr Name] -> HsType Name
 204             -> TcM ([TyVar], Class, [Type])
 205 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 206   = kcHsTyVars tv_names                 $ \ tv_names' ->
 207     do  { cls_kind <- kcClass cls_name
 208         ; (tys, _res_kind) <- kcApps cls_name cls_kind hs_tys
 209         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 210     do  { arg_tys <- dsHsTypes tys
 211         ; cls <- tcLookupClass cls_name
 212         ; return (tyvars, cls, arg_tys) }}
 213
 214 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 215   =     -- Funny newtype deriving form
 216         --      forall a. C [a]
 217         -- where C has arity 2.  Hence can't use regular functions
 218     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 219
 220 tc_hs_deriv _ other
 221   = failWithTc (ptext (sLit "Illegal deriving item") <+> ppr other)
 222 \end{code}
 223
 224         These functions are used during knot-tying in
 225         type and class declarations, when we have to
 226         separate kind-checking, desugaring, and validity checking
 227
 228 \begin{code}
 229 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 230         -- Used for type signatures
 231 kcHsSigType ty       = addKcTypeCtxt ty $ kcTypeType ty
 232 kcHsLiftedSigType ty = addKcTypeCtxt ty $ kcLiftedType ty
 233
 234 tcHsKindedType :: LHsType Name -> TcM Type
 235   -- Don't do kind checking, nor validity checking.
 236   -- This is used in type and class decls, where kinding is
 237   -- done in advance, and validity checking is done later
 238   -- [Validity checking done later because of knot-tying issues.]
 239 tcHsKindedType hs_ty = dsHsType hs_ty
 240
 241 tcHsBangType :: LHsType Name -> TcM Type
 242 -- Permit a bang, but discard it
 243 tcHsBangType (L _ (HsBangTy _ ty)) = tcHsKindedType ty
 244 tcHsBangType ty                    = tcHsKindedType ty
 245
 246 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 247 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 248 -- Does not do validity checking, like tcHsKindedType
 249 tcHsKindedContext hs_theta = addLocM (mapM dsHsLPred) hs_theta
 250 \end{code}
 251
 252
 253 %************************************************************************
 254 %*                                                                      *
 255                 The main kind checker: kcHsType
 256 %*                                                                      *
 257 %************************************************************************
 258
 259         First a couple of simple wrappers for kcHsType
 260
 261 \begin{code}
 262 ---------------------------
 263 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 264 -- The type ty must be a *lifted* *type*
 265 kcLiftedType ty = kc_check_lhs_type ty ekLifted
 266
 267 ---------------------------
 268 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 269 -- The type ty must be a *type*, but it can be lifted or
 270 -- unlifted or an unboxed tuple.
 271 kcTypeType ty = kc_check_lhs_type ty ekOpen
 272
 273 ---------------------------
 274 kcCheckLHsType :: LHsType Name -> ExpKind -> TcM (LHsType Name)
 275 kcCheckLHsType ty kind = addKcTypeCtxt ty $ kc_check_lhs_type ty kind
 276
 277
 278 kc_check_lhs_type :: LHsType Name -> ExpKind -> TcM (LHsType Name)
 279 -- Check that the type has the specified kind
 280 -- Be sure to use checkExpectedKind, rather than simply unifying
 281 -- with OpenTypeKind, because it gives better error messages
 282 kc_check_lhs_type (L span ty) exp_kind
 283   = setSrcSpan span $
 284     do { ty' <- kc_check_hs_type ty exp_kind
 285        ; return (L span ty') }
 286
 287 kc_check_lhs_types :: [(LHsType Name, ExpKind)] -> TcM [LHsType Name]
 288 kc_check_lhs_types tys_w_kinds
 289   = mapM kc_arg tys_w_kinds
 290   where
 291     kc_arg (arg, arg_kind) = kc_check_lhs_type arg arg_kind
 292
 293
 294 ---------------------------
 295 kc_check_hs_type :: HsType Name -> ExpKind -> TcM (HsType Name)
 296
 297 -- First some special cases for better error messages
 298 -- when we know the expected kind
 299 kc_check_hs_type (HsParTy ty) exp_kind
 300   = do { ty' <- kc_check_lhs_type ty exp_kind; return (HsParTy ty') }
 301
 302 kc_check_hs_type ty@(HsAppTy ty1 ty2) exp_kind
 303   = do { let (fun_ty, arg_tys) = splitHsAppTys ty1 [ty2]
 304        ; (fun_ty', fun_kind) <- kc_lhs_type fun_ty
 305        ; arg_tys' <- kcCheckApps fun_ty fun_kind arg_tys ty exp_kind
 306        ; return (mkHsAppTys fun_ty' arg_tys') }
 307
 308 -- This is the general case: infer the kind and compare
 309 kc_check_hs_type ty exp_kind
 310   = do  { (ty', act_kind) <- kc_hs_type ty
 311                 -- Add the context round the inner check only
 312                 -- because checkExpectedKind already mentions
 313                 -- 'ty' by name in any error message
 314
 315         ; checkExpectedKind (strip ty) act_kind exp_kind
 316         ; return ty' }
 317   where
 318         -- We infer the kind of the type, and then complain if it's
 319         -- not right.  But we don't want to complain about
 320         --      (ty) or !(ty) or forall a. ty
 321         -- when the real difficulty is with the 'ty' part.
 322     strip (HsParTy (L _ ty))          = strip ty
 323     strip (HsBangTy _ (L _ ty))       = strip ty
 324     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 325     strip ty                          = ty
 326 \end{code}
 327
 328         Here comes the main function
 329
 330 \begin{code}
 331 kcLHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 332 -- Called from outside: set the context
 333 kcLHsType ty = addKcTypeCtxt ty (kc_lhs_type ty)
 334
 335 kc_lhs_type :: LHsType Name -> TcM (LHsType Name, TcKind)
 336 kc_lhs_type (L span ty)
 337   = setSrcSpan span $
 338     do { (ty', kind) <- kc_hs_type ty
 339        ; return (L span ty', kind) }
 340
 341 -- kc_hs_type *returns* the kind of the type, rather than taking an expected
 342 -- kind as argument as tcExpr does.
 343 -- Reasons:
 344 --      (a) the kind of (->) is
 345 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 346 --          so we'd need to generate huge numbers of bx variables.
 347 --      (b) kinds are so simple that the error messages are fine
 348 --
 349 -- The translated type has explicitly-kinded type-variable binders
 350
 351 kc_hs_type :: HsType Name -> TcM (HsType Name, TcKind)
 352 kc_hs_type (HsParTy ty) = do
 353    (ty', kind) <- kc_lhs_type ty
 354    return (HsParTy ty', kind)
 355
 356 kc_hs_type (HsTyVar name) = do
 357     kind <- kcTyVar name
 358     return (HsTyVar name, kind)
 359
 360 kc_hs_type (HsListTy ty) = do
 361     ty' <- kcLiftedType ty
 362     return (HsListTy ty', liftedTypeKind)
 363
 364 kc_hs_type (HsPArrTy ty) = do
 365     ty' <- kcLiftedType ty
 366     return (HsPArrTy ty', liftedTypeKind)
 367
 368 kc_hs_type (HsModalBoxType ecn ty) = do
 369     kc_check_hs_type (HsTyVar ecn) (EK ecKind EkUnk)
 370     ty' <- kcLiftedType ty
 371     return (HsModalBoxType ecn ty', liftedTypeKind)
 372
 373 kc_hs_type (HsKindSig ty k) = do
 374     ty' <- kc_check_lhs_type ty (EK k EkKindSig)
 375     return (HsKindSig ty' k, k)
 376
 377 kc_hs_type (HsTupleTy Boxed tys) = do
 378     tys' <- mapM kcLiftedType tys
 379     return (HsTupleTy Boxed tys', liftedTypeKind)
 380
 381 kc_hs_type (HsTupleTy Unboxed tys) = do
 382     tys' <- mapM kcTypeType tys
 383     return (HsTupleTy Unboxed tys', ubxTupleKind)
 384
 385 kc_hs_type (HsFunTy ty1 ty2) = do
 386     ty1' <- kc_check_lhs_type ty1 (EK argTypeKind EkUnk)
 387     ty2' <- kcTypeType ty2
 388     return (HsFunTy ty1' ty2', liftedTypeKind)
 389
 390 kc_hs_type (HsOpTy ty1 op ty2) = do
 391     op_kind <- addLocM kcTyVar op
 392     ([ty1',ty2'], res_kind) <- kcApps op op_kind [ty1,ty2]
 393     return (HsOpTy ty1' op ty2', res_kind)
 394
 395 kc_hs_type (HsAppTy ty1 ty2) = do
 396     let (fun_ty, arg_tys) = splitHsAppTys ty1 [ty2]
 397     (fun_ty', fun_kind) <- kc_lhs_type fun_ty
 398     (arg_tys', res_kind) <- kcApps fun_ty fun_kind arg_tys
 399     return (mkHsAppTys fun_ty' arg_tys', res_kind)
 400
 401 kc_hs_type (HsPredTy pred)
 402   = wrongPredErr pred
 403
 404 kc_hs_type (HsCoreTy ty)
 405   = return (HsCoreTy ty, typeKind ty)
 406
 407 kc_hs_type (HsForAllTy exp tv_names context ty)
 408   = kcHsTyVars tv_names         $ \ tv_names' ->
 409     do  { ctxt' <- kcHsContext context
 410         ; ty'   <- kcLiftedType ty
 411              -- The body of a forall is usually a type, but in principle
 412              -- there's no reason to prohibit *unlifted* types.
 413              -- In fact, GHC can itself construct a function with an
 414              -- unboxed tuple inside a for-all (via CPR analyis; see
 415              -- typecheck/should_compile/tc170)
 416              --
 417              -- Still, that's only for internal interfaces, which aren't
 418              -- kind-checked, so we only allow liftedTypeKind here
 419
 420         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 421
 422 kc_hs_type (HsBangTy b ty)
 423   = do { (ty', kind) <- kc_lhs_type ty
 424        ; return (HsBangTy b ty', kind) }
 425
 426 kc_hs_type ty@(HsRecTy _)
 427   = failWithTc (ptext (sLit "Unexpected record type") <+> ppr ty)
 428       -- Record types (which only show up temporarily in constructor signatures)
 429       -- should have been removed by now
 430
 431 #ifdef GHCI     /* Only if bootstrapped */
 432 kc_hs_type (HsSpliceTy sp fvs _) = kcSpliceType sp fvs
 433 #else
 434 kc_hs_type ty@(HsSpliceTy {}) = failWithTc (ptext (sLit "Unexpected type splice:") <+> ppr ty)
 435 #endif
 436
 437 kc_hs_type (HsQuasiQuoteTy {}) = panic "kc_hs_type"     -- Eliminated by renamer
 438
 439 -- remove the doc nodes here, no need to worry about the location since
 440 -- its the same for a doc node and it's child type node
 441 kc_hs_type (HsDocTy ty _)
 442   = kc_hs_type (unLoc ty)
 443
 444 ---------------------------
 445 kcApps :: Outputable a
 446        => a
 447        -> TcKind                        -- Function kind
 448        -> [LHsType Name]                -- Arg types
 449        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 450 kcApps the_fun fun_kind args
 451   = do { (args_w_kinds, res_kind) <- splitFunKind (ppr the_fun) 1 fun_kind args
 452        ; args' <- kc_check_lhs_types args_w_kinds
 453        ; return (args', res_kind) }
 454
 455 kcCheckApps :: Outputable a => a -> TcKind -> [LHsType Name]
 456             -> HsType Name     -- The type being checked (for err messages only)
 457             -> ExpKind         -- Expected kind
 458             -> TcM [LHsType Name]
 459 kcCheckApps the_fun fun_kind args ty exp_kind
 460   = do { (args_w_kinds, res_kind) <- splitFunKind (ppr the_fun) 1 fun_kind args
 461        ; checkExpectedKind ty res_kind exp_kind
 462              -- Check the result kind *before* checking argument kinds
 463              -- This improves error message; Trac #2994
 464        ; kc_check_lhs_types args_w_kinds }
 465
 466
 467 ---------------------------
 468 splitFunKind :: SDoc -> Int -> TcKind -> [b] -> TcM ([(b,ExpKind)], TcKind)
 469 splitFunKind _       _      fk [] = return ([], fk)
 470 splitFunKind the_fun arg_no fk (arg:args)
 471   = do { mb_fk <- matchExpectedFunKind fk
 472        ; case mb_fk of
 473             Nothing       -> failWithTc too_many_args
 474             Just (ak,fk') -> do { (aks, rk) <- splitFunKind the_fun (arg_no+1) fk' args
 475                                 ; return ((arg, EK ak (EkArg the_fun arg_no)):aks, rk) } }
 476   where
 477     too_many_args = quotes the_fun <+>
 478                     ptext (sLit "is applied to too many type arguments")
 479
 480 ---------------------------
 481 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 482 kcHsContext ctxt = wrapLocM (mapM kcHsLPred) ctxt
 483
 484 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 485 kcHsLPred = wrapLocM kcHsPred
 486
 487 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 488 kcHsPred pred = do      -- Checks that the result is a type kind
 489     (pred', kind) <- kc_pred pred
 490     checkExpectedKind pred kind ekOpen
 491     return pred'
 492
 493 ---------------------------
 494 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 495         -- Does *not* check for a saturated
 496         -- application (reason: used from TcDeriv)
 497 kc_pred (HsIParam name ty)
 498   = do { (ty', kind) <- kc_lhs_type ty
 499        ; return (HsIParam name ty', kind) }
 500 kc_pred (HsClassP cls tys)
 501   = do { kind <- kcClass cls
 502        ; (tys', res_kind) <- kcApps cls kind tys
 503        ; return (HsClassP cls tys', res_kind) }
 504 kc_pred (HsEqualP ty1 ty2)
 505   = do { (ty1', kind1) <- kc_lhs_type ty1
 506        ; (ty2', kind2) <- kc_lhs_type ty2
 507        ; checkExpectedKind ty2 kind2 (EK kind1 EkEqPred)
 508        ; return (HsEqualP ty1' ty2', unliftedTypeKind) }
 509
 510 ---------------------------
 511 kcTyVar :: Name -> TcM TcKind
 512 kcTyVar name = do       -- Could be a tyvar or a tycon
 513     traceTc "lk1" (ppr name)
 514     thing <- tcLookup name
 515     traceTc "lk2" (ppr name <+> ppr thing)
 516     case thing of
 517         ATyVar _ ty             -> return (typeKind ty)
 518         AThing kind             -> return kind
 519         AGlobal (ATyCon tc)     -> return (tyConKind tc)
 520         _                       -> wrongThingErr "type" thing name
 521
 522 kcClass :: Name -> TcM TcKind
 523 kcClass cls = do        -- Must be a class
 524     thing <- tcLookup cls
 525     case thing of
 526         AThing kind             -> return kind
 527         AGlobal (AClass cls)    -> return (tyConKind (classTyCon cls))
 528         _                       -> wrongThingErr "class" thing cls
 529 \end{code}
 530
 531
 532 %************************************************************************
 533 %*                                                                      *
 534                 Desugaring
 535 %*                                                                      *
 536 %************************************************************************
 537
 538 The type desugarer
 539
 540         * Transforms from HsType to Type
 541         * Zonks any kinds
 542
 543 It cannot fail, and does no validity checking, except for
 544 structural matters, such as
 545         (a) spurious ! annotations.
 546         (b) a class used as a type
 547
 548 \begin{code}
 549 dsHsType :: LHsType Name -> TcM Type
 550 -- All HsTyVarBndrs in the intput type are kind-annotated
 551 dsHsType ty = ds_type (unLoc ty)
 552
 553 ds_type :: HsType Name -> TcM Type
 554 ds_type ty@(HsTyVar _)
 555   = ds_app ty []
 556
 557 ds_type (HsParTy ty)            -- Remove the parentheses markers
 558   = dsHsType ty
 559
 560 ds_type ty@(HsBangTy {})    -- No bangs should be here
 561   = failWithTc (ptext (sLit "Unexpected strictness annotation:") <+> ppr ty)
 562
 563 ds_type ty@(HsRecTy {})     -- No bangs should be here
 564   = failWithTc (ptext (sLit "Unexpected record type:") <+> ppr ty)
 565
 566 ds_type (HsKindSig ty _)
 567   = dsHsType ty -- Kind checking done already
 568
 569 ds_type (HsListTy ty) = do
 570     tau_ty <- dsHsType ty
 571     checkWiredInTyCon listTyCon
 572     return (mkListTy tau_ty)
 573
 574 ds_type (HsPArrTy ty) = do
 575     tau_ty <- dsHsType ty
 576     checkWiredInTyCon parrTyCon
 577     return (mkPArrTy tau_ty)
 578
 579 ds_type (HsModalBoxType ecn ty) = do
 580     tau_ty <- dsHsType ty
 581     checkWiredInTyCon hetMetCodeTypeTyCon
 582     return (mkHetMetCodeTypeTy (mkTyVar ecn ecKind) tau_ty)
 583
 584 ds_type (HsTupleTy boxity tys) = do
 585     tau_tys <- dsHsTypes tys
 586     checkWiredInTyCon tycon
 587     return (mkTyConApp tycon tau_tys)
 588   where
 589     tycon = tupleTyCon boxity (length tys)
 590
 591 ds_type (HsFunTy ty1 ty2) = do
 592     tau_ty1 <- dsHsType ty1
 593     tau_ty2 <- dsHsType ty2
 594     return (mkFunTy tau_ty1 tau_ty2)
 595
 596 ds_type (HsOpTy ty1 (L span op) ty2) = do
 597     tau_ty1 <- dsHsType ty1
 598     tau_ty2 <- dsHsType ty2
 599     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 600
 601 ds_type ty@(HsAppTy _ _)
 602   = ds_app ty []
 603
 604 ds_type (HsPredTy pred) = do
 605     pred' <- dsHsPred pred
 606     return (mkPredTy pred')
 607
 608 ds_type (HsForAllTy _ tv_names ctxt ty)
 609   = tcTyVarBndrs tv_names               $ \ tyvars -> do
 610     theta <- mapM dsHsLPred (unLoc ctxt)
 611     tau <- dsHsType ty
 612     return (mkSigmaTy tyvars theta tau)
 613
 614 ds_type (HsDocTy ty _)  -- Remove the doc comment
 615   = dsHsType ty
 616
 617 ds_type (HsSpliceTy _ _ kind)
 618   = do { kind' <- zonkTcKindToKind kind
 619        ; newFlexiTyVarTy kind' }
 620
 621 ds_type (HsQuasiQuoteTy {}) = panic "ds_type"   -- Eliminated by renamer
 622 ds_type (HsCoreTy ty)       = return ty
 623
 624 dsHsTypes :: [LHsType Name] -> TcM [Type]
 625 dsHsTypes arg_tys = mapM dsHsType arg_tys
 626 \end{code}
 627
 628 Help functions for type applications
 629 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 630
 631 \begin{code}
 632 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 633 ds_app (HsAppTy ty1 ty2) tys
 634   = ds_app (unLoc ty1) (ty2:tys)
 635
 636 ds_app ty tys = do
 637     arg_tys <- dsHsTypes tys
 638     case ty of
 639         HsTyVar fun -> ds_var_app fun arg_tys
 640         _           -> do fun_ty <- ds_type ty
 641                           return (mkAppTys fun_ty arg_tys)
 642
 643 ds_var_app :: Name -> [Type] -> TcM Type
 644 ds_var_app name arg_tys = do
 645     thing <- tcLookup name
 646     case thing of
 647         ATyVar _ ty         -> return (mkAppTys ty arg_tys)
 648         AGlobal (ATyCon tc) -> return (mkTyConApp tc arg_tys)
 649         _                   -> wrongThingErr "type" thing name
 650 \end{code}
 651
 652
 653 Contexts
 654 ~~~~~~~~
 655
 656 \begin{code}
 657 dsHsLPred :: LHsPred Name -> TcM PredType
 658 dsHsLPred pred = dsHsPred (unLoc pred)
 659
 660 dsHsPred :: HsPred Name -> TcM PredType
 661 dsHsPred (HsClassP class_name tys)
 662   = do { arg_tys <- dsHsTypes tys
 663        ; clas <- tcLookupClass class_name
 664        ; return (ClassP clas arg_tys)
 665        }
 666 dsHsPred (HsEqualP ty1 ty2)
 667   = do { arg_ty1 <- dsHsType ty1
 668        ; arg_ty2 <- dsHsType ty2
 669        ; return (EqPred arg_ty1 arg_ty2)
 670        }
 671 dsHsPred (HsIParam name ty)
 672   = do { arg_ty <- dsHsType ty
 673        ; return (IParam name arg_ty)
 674        }
 675 \end{code}
 676
 677 \begin{code}
 678 addKcTypeCtxt :: LHsType Name -> TcM a -> TcM a
 679         -- Wrap a context around only if we want to show that contexts.
 680 addKcTypeCtxt (L _ (HsPredTy _)) thing = thing
 681         -- Omit invisble ones and ones user's won't grok (HsPred p).
 682 addKcTypeCtxt (L _ other_ty) thing = addErrCtxt (typeCtxt other_ty) thing
 683
 684 typeCtxt :: HsType Name -> SDoc
 685 typeCtxt ty = ptext (sLit "In the type") <+> quotes (ppr ty)
 686 \end{code}
 687
 688 %************************************************************************
 689 %*                                                                      *
 690                 Type-variable binders
 691 %*                                                                      *
 692 %************************************************************************
 693
 694
 695 \begin{code}
 696 kcHsTyVars :: [LHsTyVarBndr Name]
 697            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 698                                                 -- They scope over the thing inside
 699            -> TcM r
 700 kcHsTyVars tvs thing_inside
 701   = do { kinded_tvs <- mapM (wrapLocM kcHsTyVar) tvs
 702        ; tcExtendKindEnvTvs kinded_tvs thing_inside }
 703
 704 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 705         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 706 kcHsTyVar (UserTyVar name _)  = UserTyVar name <$> newKindVar
 707 kcHsTyVar tv@(KindedTyVar {}) = return tv
 708
 709 ------------------
 710 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 711              -> ([TyVar] -> TcM r)
 712              -> TcM r
 713 -- Used when type-checking types/classes/type-decls
 714 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 715 tcTyVarBndrs bndrs thing_inside = do
 716     tyvars <- mapM (zonk . unLoc) bndrs
 717     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 718   where
 719     zonk (UserTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 720                                     ; return (mkTyVar name kind') }
 721     zonk (KindedTyVar name kind) = return (mkTyVar name kind)
 722
 723 -----------------------------------
 724 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 725 -- GADT decls can have a (perhaps partial) kind signature
 726 --      e.g.  data T :: * -> * -> * where ...
 727 -- This function makes up suitable (kinded) type variables for
 728 -- the argument kinds, and checks that the result kind is indeed *.
 729 -- We use it also to make up argument type variables for for data instances.
 730 tcDataKindSig Nothing = return []
 731 tcDataKindSig (Just kind)
 732   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 733         ; span <- getSrcSpanM
 734         ; us   <- newUniqueSupply
 735         ; let uniqs = uniqsFromSupply us
 736         ; return [ mk_tv span uniq str kind
 737                  | ((kind, str), uniq) <- arg_kinds `zip` dnames `zip` uniqs ] }
 738   where
 739     (arg_kinds, res_kind) = splitKindFunTys kind
 740     mk_tv loc uniq str kind = mkTyVar name kind
 741         where
 742            name = mkInternalName uniq occ loc
 743            occ  = mkOccName tvName str
 744
 745     dnames = map ('$' :) names  -- Note [Avoid name clashes for associated data types]
 746
 747     names :: [String]
 748     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 749
 750 badKindSig :: Kind -> SDoc
 751 badKindSig kind
 752  = hang (ptext (sLit "Kind signature on data type declaration has non-* return kind"))
 753         2 (ppr kind)
 754 \end{code}
 755
 756 Note [Avoid name clashes for associated data types]
 757 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 758 Consider    class C a b where
 759                data D b :: * -> *
 760 When typechecking the decl for D, we'll invent an extra type variable for D,
 761 to fill out its kind.  We *don't* want this type variable to be 'a', because
 762 in an .hi file we'd get
 763             class C a b where
 764                data D b a
 765 which makes it look as if there are *two* type indices.  But there aren't!
 766 So we use $a instead, which cannot clash with a user-written type variable.
 767 Remember that type variable binders in interface files are just FastStrings,
 768 not proper Names.
 769
 770 (The tidying phase can't help here because we don't tidy TyCons.  Another
 771 alternative would be to record the number of indexing parameters in the
 772 interface file.)
 773
 774
 775 %************************************************************************
 776 %*                                                                      *
 777                 Scoped type variables
 778 %*                                                                      *
 779 %************************************************************************
 780
 781
 782 tcAddScopedTyVars is used for scoped type variables added by pattern
 783 type signatures
 784         e.g.  \ ((x::a), (y::a)) -> x+y
 785 They never have explicit kinds (because this is source-code only)
 786 They are mutable (because they can get bound to a more specific type).
 787
 788 Usually we kind-infer and expand type splices, and then
 789 tupecheck/desugar the type.  That doesn't work well for scoped type
 790 variables, because they scope left-right in patterns.  (e.g. in the
 791 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 792
 793 The current not-very-good plan is to
 794   * find all the types in the patterns
 795   * find their free tyvars
 796   * do kind inference
 797   * bring the kinded type vars into scope
 798   * BUT throw away the kind-checked type
 799         (we'll kind-check it again when we type-check the pattern)
 800
 801 This is bad because throwing away the kind checked type throws away
 802 its splices.  But too bad for now.  [July 03]
 803
 804 Historical note:
 805     We no longer specify that these type variables must be univerally
 806     quantified (lots of email on the subject).  If you want to put that
 807     back in, you need to
 808         a) Do a checkSigTyVars after thing_inside
 809         b) More insidiously, don't pass in expected_ty, else
 810            we unify with it too early and checkSigTyVars barfs
 811            Instead you have to pass in a fresh ty var, and unify
 812            it with expected_ty afterwards
 813
 814 \begin{code}
 815 tcHsPatSigType :: UserTypeCtxt
 816                -> LHsType Name          -- The type signature
 817                -> TcM ([TyVar],         -- Newly in-scope type variables
 818                         Type)           -- The signature
 819 -- Used for type-checking type signatures in
 820 -- (a) patterns           e.g  f (x::Int) = e
 821 -- (b) result signatures  e.g. g x :: Int = e
 822 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 823
 824 tcHsPatSigType ctxt hs_ty
 825   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 826     do  {       -- Find the type variables that are mentioned in the type
 827                 -- but not already in scope.  These are the ones that
 828                 -- should be bound by the pattern signature
 829           in_scope <- getInLocalScope
 830         ; let span = getLoc hs_ty
 831               sig_tvs = userHsTyVarBndrs $ map (L span) $
 832                         filterOut in_scope $
 833                         nameSetToList (extractHsTyVars hs_ty)
 834
 835         ; (tyvars, sig_ty) <- tcHsQuantifiedType sig_tvs hs_ty
 836         ; checkValidType ctxt sig_ty
 837         ; return (tyvars, sig_ty)
 838       }
 839
 840 tcPatSig :: UserTypeCtxt
 841          -> LHsType Name
 842          -> TcSigmaType
 843          -> TcM (TcType,           -- The type to use for "inside" the signature
 844                  [(Name, TcType)], -- The new bit of type environment, binding
 845                                    -- the scoped type variables
 846                  HsWrapper)        -- Coercion due to unification with actual ty
 847                                    -- Of shape:  res_ty ~ sig_ty
 848 tcPatSig ctxt sig res_ty
 849   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 850         -- sig_tvs are the type variables free in 'sig',
 851         -- and not already in scope. These are the ones
 852         -- that should be brought into scope
 853
 854         ; if null sig_tvs then do {
 855                 -- The type signature binds no type variables,
 856                 -- and hence is rigid, so use it to zap the res_ty
 857                   wrap <- tcSubType PatSigOrigin ctxt res_ty sig_ty
 858                 ; return (sig_ty, [], wrap)
 859         } else do {
 860                 -- Type signature binds at least one scoped type variable
 861
 862                 -- A pattern binding cannot bind scoped type variables
 863                 -- The renamer fails with a name-out-of-scope error
 864                 -- if a pattern binding tries to bind a type variable,
 865                 -- So we just have an ASSERT here
 866         ; let in_pat_bind = case ctxt of
 867                                 BindPatSigCtxt -> True
 868                                 _              -> False
 869         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 870
 871                 -- Check that all newly-in-scope tyvars are in fact
 872                 -- constrained by the pattern.  This catches tiresome
 873                 -- cases like
 874                 --      type T a = Int
 875                 --      f :: Int -> Int
 876                 --      f (x :: T a) = ...
 877                 -- Here 'a' doesn't get a binding.  Sigh
 878         ; let bad_tvs = filterOut (`elemVarSet` exactTyVarsOfType sig_ty) sig_tvs
 879         ; checkTc (null bad_tvs) (badPatSigTvs sig_ty bad_tvs)
 880
 881         -- Now do a subsumption check of the pattern signature against res_ty
 882         ; sig_tvs' <- tcInstSigTyVars sig_tvs
 883         ; let sig_ty' = substTyWith sig_tvs sig_tv_tys' sig_ty
 884               sig_tv_tys' = mkTyVarTys sig_tvs'
 885         ; wrap <- tcSubType PatSigOrigin ctxt res_ty sig_ty'
 886
 887         -- Check that each is bound to a distinct type variable,
 888         -- and one that is not already in scope
 889         ; binds_in_scope <- getScopedTyVarBinds
 890         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys'
 891         ; check binds_in_scope tv_binds
 892
 893         -- Phew!
 894         ; return (sig_ty', tv_binds, wrap)
 895         } }
 896   where
 897     check _ [] = return ()
 898     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 899                                       ; check ((n,ty):in_scope) rest }
 900
 901     check_one in_scope n ty
 902         = checkTc (null dups) (dupInScope n (head dups) ty)
 903                 -- Must not bind to the same type variable
 904                 -- as some other in-scope type variable
 905         where
 906           dups = [n' | (n',ty') <- in_scope, eqType ty' ty]
 907 \end{code}
 908
 909
 910 %************************************************************************
 911 %*                                                                      *
 912         Checking kinds
 913 %*                                                                      *
 914 %************************************************************************
 915
 916 We would like to get a decent error message from
 917   (a) Under-applied type constructors
 918              f :: (Maybe, Maybe)
 919   (b) Over-applied type constructors
 920              f :: Int x -> Int x
 921
 922 \begin{code}
 923 -- The ExpKind datatype means "expected kind" and contains
 924 -- some info about just why that kind is expected, to improve
 925 -- the error message on a mis-match
 926 data ExpKind = EK TcKind EkCtxt
 927 data EkCtxt  = EkUnk            -- Unknown context
 928              | EkEqPred         -- Second argument of an equality predicate
 929              | EkKindSig        -- Kind signature
 930              | EkArg SDoc Int   -- Function, arg posn, expected kind
 931
 932
 933 ekLifted, ekOpen :: ExpKind
 934 ekLifted = EK liftedTypeKind EkUnk
 935 ekOpen   = EK openTypeKind   EkUnk
 936
 937 checkExpectedKind :: Outputable a => a -> TcKind -> ExpKind -> TcM ()
 938 -- A fancy wrapper for 'unifyKind', which tries
 939 -- to give decent error messages.
 940 --      (checkExpectedKind ty act_kind exp_kind)
 941 -- checks that the actual kind act_kind is compatible
 942 --      with the expected kind exp_kind
 943 -- The first argument, ty, is used only in the error message generation
 944 checkExpectedKind ty act_kind (EK exp_kind ek_ctxt)
 945   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
 946   = return ()
 947   | otherwise = do
 948     (_errs, mb_r) <- tryTc (unifyKind exp_kind act_kind)
 949     case mb_r of
 950         Just _  -> return ()  -- Unification succeeded
 951         Nothing -> do
 952
 953         -- So there's definitely an error
 954         -- Now to find out what sort
 955            exp_kind <- zonkTcKind exp_kind
 956            act_kind <- zonkTcKind act_kind
 957
 958            env0 <- tcInitTidyEnv
 959            let (exp_as, _) = splitKindFunTys exp_kind
 960                (act_as, _) = splitKindFunTys act_kind
 961                n_exp_as = length exp_as
 962                n_act_as = length act_as
 963
 964                (env1, tidy_exp_kind) = tidyKind env0 exp_kind
 965                (env2, tidy_act_kind) = tidyKind env1 act_kind
 966
 967                err | n_exp_as < n_act_as     -- E.g. [Maybe]
 968                    = quotes (ppr ty) <+> ptext (sLit "is not applied to enough type arguments")
 969
 970                      -- Now n_exp_as >= n_act_as. In the next two cases,
 971                      -- n_exp_as == 0, and hence so is n_act_as
 972                    | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
 973                    = ptext (sLit "Expecting a lifted type, but") <+> quotes (ppr ty)
 974                        <+> ptext (sLit "is unlifted")
 975
 976                    | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
 977                    = ptext (sLit "Expecting an unlifted type, but") <+> quotes (ppr ty)
 978                        <+> ptext (sLit "is lifted")
 979
 980                    | otherwise               -- E.g. Monad [Int]
 981                    = ptext (sLit "Kind mis-match")
 982
 983                more_info = sep [ expected_herald ek_ctxt <+> ptext (sLit "kind")
 984                                     <+> quotes (pprKind tidy_exp_kind) <> comma,
 985                                  ptext (sLit "but") <+> quotes (ppr ty) <+>
 986                                      ptext (sLit "has kind") <+> quotes (pprKind tidy_act_kind)]
 987
 988                expected_herald EkUnk     = ptext (sLit "Expected")
 989                expected_herald EkKindSig = ptext (sLit "An enclosing kind signature specified")
 990                expected_herald EkEqPred  = ptext (sLit "The left argument of the equality predicate had")
 991                expected_herald (EkArg fun arg_no)
 992                  = ptext (sLit "The") <+> speakNth arg_no <+> ptext (sLit "argument of")
 993                    <+> quotes fun <+> ptext (sLit ("should have"))
 994
 995            failWithTcM (env2, err $$ more_info)
 996 \end{code}
 997
 998 %************************************************************************
 999 %*                                                                      *
1000                 Scoped type variables
1001 %*                                                                      *
1002 %************************************************************************
1003
1004 \begin{code}
1005 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
1006 pprHsSigCtxt ctxt hs_ty = sep [ ptext (sLit "In") <+> pprUserTypeCtxt ctxt <> colon,
1007                                  nest 2 (pp_sig ctxt) ]
1008   where
1009     pp_sig (FunSigCtxt n)  = pp_n_colon n
1010     pp_sig (ConArgCtxt n)  = pp_n_colon n
1011     pp_sig (ForSigCtxt n)  = pp_n_colon n
1012     pp_sig _               = ppr (unLoc hs_ty)
1013
1014     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
1015
1016 badPatSigTvs :: TcType -> [TyVar] -> SDoc
1017 badPatSigTvs sig_ty bad_tvs
1018   = vcat [ fsep [ptext (sLit "The type variable") <> plural bad_tvs,
1019                  quotes (pprWithCommas ppr bad_tvs),
1020                  ptext (sLit "should be bound by the pattern signature") <+> quotes (ppr sig_ty),
1021                  ptext (sLit "but are actually discarded by a type synonym") ]
1022          , ptext (sLit "To fix this, expand the type synonym")
1023          , ptext (sLit "[Note: I hope to lift this restriction in due course]") ]
1024
1025 dupInScope :: Name -> Name -> Type -> SDoc
1026 dupInScope n n' _
1027   = hang (ptext (sLit "The scoped type variables") <+> quotes (ppr n) <+> ptext (sLit "and") <+> quotes (ppr n'))
1028        2 (vcat [ptext (sLit "are bound to the same type (variable)"),
1029                 ptext (sLit "Distinct scoped type variables must be distinct")])
1030
1031 wrongPredErr :: HsPred Name -> TcM (HsType Name, TcKind)
1032 wrongPredErr pred = failWithTc (text "Predicate used as a type:" <+> ppr pred)
1033 \end{code}
1034