compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsDeriv,
  10         UserTypeCtxt(..),
  11
  12                 -- Kind checking
  13         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  14         kcCheckHsType, kcHsContext, kcHsType,
  15
  16                 -- Typechecking kinded types
  17         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  18         tcTyVarBndrs, dsHsType, tcLHsConResTy,
  19         tcDataKindSig,
  20
  21                 -- Pattern type signatures
  22         tcHsPatSigType, tcPatSig
  23    ) where
  24
  25 #include "HsVersions.h"
  26
  27 import HsSyn
  28 import RnHsSyn
  29 import TcRnMonad
  30 import TcEnv
  31 import TcMType
  32 import TcUnify
  33 import TcIface
  34 import TcType
  35 import {- Kind parts of -} Type
  36 import Var
  37 import TyCon
  38 import Class
  39 import Name
  40 import OccName
  41 import NameSet
  42 import PrelNames
  43 import TysWiredIn
  44 import BasicTypes
  45 import SrcLoc
  46 import UniqSupply
  47 import Outputable
  48 \end{code}
  49
  50
  51         ----------------------------
  52                 General notes
  53         ----------------------------
  54
  55 Generally speaking we now type-check types in three phases
  56
  57   1.  kcHsType: kind check the HsType
  58         *includes* performing any TH type splices;
  59         so it returns a translated, and kind-annotated, type
  60
  61   2.  dsHsType: convert from HsType to Type:
  62         perform zonking
  63         expand type synonyms [mkGenTyApps]
  64         hoist the foralls [tcHsType]
  65
  66   3.  checkValidType: check the validity of the resulting type
  67
  68 Often these steps are done one after the other (tcHsSigType).
  69 But in mutually recursive groups of type and class decls we do
  70         1 kind-check the whole group
  71         2 build TyCons/Classes in a knot-tied way
  72         3 check the validity of types in the now-unknotted TyCons/Classes
  73
  74 For example, when we find
  75         (forall a m. m a -> m a)
  76 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  77 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  78 an environment that binds a and m suitably.
  79
  80 The kind checker passed to tcHsTyVars needs to look at enough to
  81 establish the kind of the tyvar:
  82   * For a group of type and class decls, it's just the group, not
  83         the rest of the program
  84   * For a tyvar bound in a pattern type signature, its the types
  85         mentioned in the other type signatures in that bunch of patterns
  86   * For a tyvar bound in a RULE, it's the type signatures on other
  87         universally quantified variables in the rule
  88
  89 Note that this may occasionally give surprising results.  For example:
  90
  91         data T a b = MkT (a b)
  92
  93 Here we deduce                  a::*->*,       b::*
  94 But equally valid would be      a::(*->*)-> *, b::*->*
  95
  96
  97 Validity checking
  98 ~~~~~~~~~~~~~~~~~
  99 Some of the validity check could in principle be done by the kind checker,
 100 but not all:
 101
 102 - During desugaring, we normalise by expanding type synonyms.  Only
 103   after this step can we check things like type-synonym saturation
 104   e.g.  type T k = k Int
 105         type S a = a
 106   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 107   and then S is saturated.  This is a GHC extension.
 108
 109 - Similarly, also a GHC extension, we look through synonyms before complaining
 110   about the form of a class or instance declaration
 111
 112 - Ambiguity checks involve functional dependencies, and it's easier to wait
 113   until knots have been resolved before poking into them
 114
 115 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 116 finished building the loop.  So to keep things simple, we postpone most validity
 117 checking until step (3).
 118
 119 Knot tying
 120 ~~~~~~~~~~
 121 During step (1) we might fault in a TyCon defined in another module, and it might
 122 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 123 knot around type declarations with ARecThing, so that the fault-in code can get
 124 the TyCon being defined.
 125
 126
 127 %************************************************************************
 128 %*                                                                      *
 129 \subsection{Checking types}
 130 %*                                                                      *
 131 %************************************************************************
 132
 133 \begin{code}
 134 tcHsSigType :: UserTypeCtxt -> LHsType Name -> TcM Type
 135   -- Do kind checking, and hoist for-alls to the top
 136   -- NB: it's important that the foralls that come from the top-level
 137   --     HsForAllTy in hs_ty occur *first* in the returned type.
 138   --     See Note [Scoped] with TcSigInfo
 139 tcHsSigType ctxt hs_ty
 140   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 141     do  { kinded_ty <- kcTypeType hs_ty
 142         ; ty <- tcHsKindedType kinded_ty
 143         ; checkValidType ctxt ty
 144         ; returnM ty }
 145
 146 -- Used for the deriving(...) items
 147 tcHsDeriv :: LHsType Name -> TcM ([TyVar], Class, [Type])
 148 tcHsDeriv = addLocM (tc_hs_deriv [])
 149
 150 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 151   = kcHsTyVars tv_names                 $ \ tv_names' ->
 152     do  { cls_kind <- kcClass cls_name
 153         ; (tys, res_kind) <- kcApps cls_kind (ppr cls_name) hs_tys
 154         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 155     do  { arg_tys <- dsHsTypes tys
 156         ; cls <- tcLookupClass cls_name
 157         ; return (tyvars, cls, arg_tys) }}
 158
 159 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 160   =     -- Funny newtype deriving form
 161         --      forall a. C [a]
 162         -- where C has arity 2.  Hence can't use regular functions
 163     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 164
 165 tc_hs_deriv _ other
 166   = failWithTc (ptext SLIT("Illegal deriving item") <+> ppr other)
 167 \end{code}
 168
 169         These functions are used during knot-tying in
 170         type and class declarations, when we have to
 171         separate kind-checking, desugaring, and validity checking
 172
 173 \begin{code}
 174 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 175         -- Used for type signatures
 176 kcHsSigType ty       = kcTypeType ty
 177 kcHsLiftedSigType ty = kcLiftedType ty
 178
 179 tcHsKindedType :: LHsType Name -> TcM Type
 180   -- Don't do kind checking, nor validity checking.
 181   -- This is used in type and class decls, where kinding is
 182   -- done in advance, and validity checking is done later
 183   -- [Validity checking done later because of knot-tying issues.]
 184 tcHsKindedType hs_ty = dsHsType hs_ty
 185
 186 tcHsBangType :: LHsType Name -> TcM Type
 187 -- Permit a bang, but discard it
 188 tcHsBangType (L span (HsBangTy b ty)) = tcHsKindedType ty
 189 tcHsBangType ty                       = tcHsKindedType ty
 190
 191 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 192 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 193 -- Does not do validity checking, like tcHsKindedType
 194 tcHsKindedContext hs_theta = addLocM (mappM dsHsLPred) hs_theta
 195 \end{code}
 196
 197
 198 %************************************************************************
 199 %*                                                                      *
 200                 The main kind checker: kcHsType
 201 %*                                                                      *
 202 %************************************************************************
 203
 204         First a couple of simple wrappers for kcHsType
 205
 206 \begin{code}
 207 ---------------------------
 208 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 209 -- The type ty must be a *lifted* *type*
 210 kcLiftedType ty = kcCheckHsType ty liftedTypeKind
 211
 212 ---------------------------
 213 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 214 -- The type ty must be a *type*, but it can be lifted or
 215 -- unlifted or an unboxed tuple.
 216 kcTypeType ty = kcCheckHsType ty openTypeKind
 217
 218 ---------------------------
 219 kcCheckHsType :: LHsType Name -> TcKind -> TcM (LHsType Name)
 220 -- Check that the type has the specified kind
 221 -- Be sure to use checkExpectedKind, rather than simply unifying
 222 -- with OpenTypeKind, because it gives better error messages
 223 kcCheckHsType (L span ty) exp_kind
 224   = setSrcSpan span                             $
 225     do  { (ty', act_kind) <- add_ctxt ty (kc_hs_type ty)
 226                 -- Add the context round the inner check only
 227                 -- because checkExpectedKind already mentions
 228                 -- 'ty' by name in any error message
 229
 230         ; checkExpectedKind (strip ty) act_kind exp_kind
 231         ; return (L span ty') }
 232   where
 233         -- Wrap a context around only if we want to show that contexts.
 234     add_ctxt (HsPredTy p)                thing = thing
 235         -- Omit invisble ones and ones user's won't grok (HsPred p).
 236     add_ctxt (HsForAllTy _ _ (L _ []) _) thing = thing
 237         -- Omit wrapping if the theta-part is empty
 238         -- Reason: the recursive call to kcLiftedType, in the ForAllTy
 239         --         case of kc_hs_type, will do the wrapping instead
 240         --         and we don't want to duplicate
 241     add_ctxt other_ty thing = addErrCtxt (typeCtxt other_ty) thing
 242
 243         -- We infer the kind of the type, and then complain if it's
 244         -- not right.  But we don't want to complain about
 245         --      (ty) or !(ty) or forall a. ty
 246         -- when the real difficulty is with the 'ty' part.
 247     strip (HsParTy (L _ ty))          = strip ty
 248     strip (HsBangTy _ (L _ ty))       = strip ty
 249     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 250     strip ty                          = ty
 251 \end{code}
 252
 253         Here comes the main function
 254
 255 \begin{code}
 256 kcHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 257 kcHsType ty = wrapLocFstM kc_hs_type ty
 258 -- kcHsType *returns* the kind of the type, rather than taking an expected
 259 -- kind as argument as tcExpr does.
 260 -- Reasons:
 261 --      (a) the kind of (->) is
 262 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 263 --          so we'd need to generate huge numbers of bx variables.
 264 --      (b) kinds are so simple that the error messages are fine
 265 --
 266 -- The translated type has explicitly-kinded type-variable binders
 267
 268 kc_hs_type (HsParTy ty)
 269  = kcHsType ty          `thenM` \ (ty', kind) ->
 270    returnM (HsParTy ty', kind)
 271
 272 kc_hs_type (HsTyVar name)
 273   = kcTyVar name        `thenM` \ kind ->
 274     returnM (HsTyVar name, kind)
 275
 276 kc_hs_type (HsListTy ty)
 277   = kcLiftedType ty                     `thenM` \ ty' ->
 278     returnM (HsListTy ty', liftedTypeKind)
 279
 280 kc_hs_type (HsPArrTy ty)
 281   = kcLiftedType ty                     `thenM` \ ty' ->
 282     returnM (HsPArrTy ty', liftedTypeKind)
 283
 284 kc_hs_type (HsNumTy n)
 285    = returnM (HsNumTy n, liftedTypeKind)
 286
 287 kc_hs_type (HsKindSig ty k)
 288   = kcCheckHsType ty k  `thenM` \ ty' ->
 289     returnM (HsKindSig ty' k, k)
 290
 291 kc_hs_type (HsTupleTy Boxed tys)
 292   = mappM kcLiftedType tys      `thenM` \ tys' ->
 293     returnM (HsTupleTy Boxed tys', liftedTypeKind)
 294
 295 kc_hs_type (HsTupleTy Unboxed tys)
 296   = mappM kcTypeType tys        `thenM` \ tys' ->
 297     returnM (HsTupleTy Unboxed tys', ubxTupleKind)
 298
 299 kc_hs_type (HsFunTy ty1 ty2)
 300   = kcCheckHsType ty1 argTypeKind       `thenM` \ ty1' ->
 301     kcTypeType ty2                      `thenM` \ ty2' ->
 302     returnM (HsFunTy ty1' ty2', liftedTypeKind)
 303
 304 kc_hs_type ty@(HsOpTy ty1 op ty2)
 305   = addLocM kcTyVar op                  `thenM` \ op_kind ->
 306     kcApps op_kind (ppr op) [ty1,ty2]   `thenM` \ ([ty1',ty2'], res_kind) ->
 307     returnM (HsOpTy ty1' op ty2', res_kind)
 308
 309 kc_hs_type ty@(HsAppTy ty1 ty2)
 310   = kcHsType fun_ty                       `thenM` \ (fun_ty', fun_kind) ->
 311     kcApps fun_kind (ppr fun_ty) arg_tys  `thenM` \ ((arg_ty':arg_tys'), res_kind) ->
 312     returnM (foldl mk_app (HsAppTy fun_ty' arg_ty') arg_tys', res_kind)
 313   where
 314     (fun_ty, arg_tys) = split ty1 [ty2]
 315     split (L _ (HsAppTy f a)) as = split f (a:as)
 316     split f                   as = (f,as)
 317     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 318                                                 -- the application; they are never used
 319
 320 kc_hs_type (HsPredTy pred)
 321   = kcHsPred pred               `thenM` \ pred' ->
 322     returnM (HsPredTy pred', liftedTypeKind)
 323
 324 kc_hs_type (HsForAllTy exp tv_names context ty)
 325   = kcHsTyVars tv_names         $ \ tv_names' ->
 326     do  { ctxt' <- kcHsContext context
 327         ; ty'   <- kcLiftedType ty
 328              -- The body of a forall is usually a type, but in principle
 329              -- there's no reason to prohibit *unlifted* types.
 330              -- In fact, GHC can itself construct a function with an
 331              -- unboxed tuple inside a for-all (via CPR analyis; see
 332              -- typecheck/should_compile/tc170)
 333              --
 334              -- Still, that's only for internal interfaces, which aren't
 335              -- kind-checked, so we only allow liftedTypeKind here
 336
 337         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 338
 339 kc_hs_type (HsBangTy b ty)
 340   = do { (ty', kind) <- kcHsType ty
 341        ; return (HsBangTy b ty', kind) }
 342
 343 kc_hs_type ty@(HsSpliceTy _)
 344   = failWithTc (ptext SLIT("Unexpected type splice:") <+> ppr ty)
 345
 346 -- remove the doc nodes here, no need to worry about the location since
 347 -- its the same for a doc node and it's child type node
 348 kc_hs_type (HsDocTy ty _)
 349   = kc_hs_type (unLoc ty)
 350
 351 ---------------------------
 352 kcApps :: TcKind                        -- Function kind
 353        -> SDoc                          -- Function
 354        -> [LHsType Name]                -- Arg types
 355        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 356 kcApps fun_kind ppr_fun args
 357   = split_fk fun_kind (length args)     `thenM` \ (arg_kinds, res_kind) ->
 358     zipWithM kc_arg args arg_kinds      `thenM` \ args' ->
 359     returnM (args', res_kind)
 360   where
 361     split_fk fk 0 = returnM ([], fk)
 362     split_fk fk n = unifyFunKind fk     `thenM` \ mb_fk ->
 363                     case mb_fk of
 364                         Nothing       -> failWithTc too_many_args
 365                         Just (ak,fk') -> split_fk fk' (n-1)     `thenM` \ (aks, rk) ->
 366                                          returnM (ak:aks, rk)
 367
 368     kc_arg arg arg_kind = kcCheckHsType arg arg_kind
 369
 370     too_many_args = ptext SLIT("Kind error:") <+> quotes ppr_fun <+>
 371                     ptext SLIT("is applied to too many type arguments")
 372
 373 ---------------------------
 374 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 375 kcHsContext ctxt = wrapLocM (mappM kcHsLPred) ctxt
 376
 377 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 378 kcHsLPred = wrapLocM kcHsPred
 379
 380 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 381 kcHsPred pred   -- Checks that the result is of kind liftedType
 382   = kc_pred pred                                `thenM` \ (pred', kind) ->
 383     checkExpectedKind pred kind liftedTypeKind  `thenM_`
 384     returnM pred'
 385
 386 ---------------------------
 387 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 388         -- Does *not* check for a saturated
 389         -- application (reason: used from TcDeriv)
 390 kc_pred pred@(HsIParam name ty)
 391   = kcHsType ty         `thenM` \ (ty', kind) ->
 392     returnM (HsIParam name ty', kind)
 393
 394 kc_pred pred@(HsClassP cls tys)
 395   = kcClass cls                 `thenM` \ kind ->
 396     kcApps kind (ppr cls) tys   `thenM` \ (tys', res_kind) ->
 397     returnM (HsClassP cls tys', res_kind)
 398
 399 ---------------------------
 400 kcTyVar :: Name -> TcM TcKind
 401 kcTyVar name    -- Could be a tyvar or a tycon
 402   = traceTc (text "lk1" <+> ppr name)   `thenM_`
 403     tcLookup name       `thenM` \ thing ->
 404     traceTc (text "lk2" <+> ppr name <+> ppr thing)     `thenM_`
 405     case thing of
 406         ATyVar _ ty             -> returnM (typeKind ty)
 407         AThing kind             -> returnM kind
 408         AGlobal (ATyCon tc)     -> returnM (tyConKind tc)
 409         other                   -> wrongThingErr "type" thing name
 410
 411 kcClass :: Name -> TcM TcKind
 412 kcClass cls     -- Must be a class
 413   = tcLookup cls                                `thenM` \ thing ->
 414     case thing of
 415         AThing kind             -> returnM kind
 416         AGlobal (AClass cls)    -> returnM (tyConKind (classTyCon cls))
 417         other                   -> wrongThingErr "class" thing cls
 418 \end{code}
 419
 420
 421 %************************************************************************
 422 %*                                                                      *
 423                 Desugaring
 424 %*                                                                      *
 425 %************************************************************************
 426
 427 The type desugarer
 428
 429         * Transforms from HsType to Type
 430         * Zonks any kinds
 431
 432 It cannot fail, and does no validity checking, except for
 433 structural matters, such as
 434         (a) spurious ! annotations.
 435         (b) a class used as a type
 436
 437 \begin{code}
 438 dsHsType :: LHsType Name -> TcM Type
 439 -- All HsTyVarBndrs in the intput type are kind-annotated
 440 dsHsType ty = ds_type (unLoc ty)
 441
 442 ds_type ty@(HsTyVar name)
 443   = ds_app ty []
 444
 445 ds_type (HsParTy ty)            -- Remove the parentheses markers
 446   = dsHsType ty
 447
 448 ds_type ty@(HsBangTy _ _)       -- No bangs should be here
 449   = failWithTc (ptext SLIT("Unexpected strictness annotation:") <+> ppr ty)
 450
 451 ds_type (HsKindSig ty k)
 452   = dsHsType ty -- Kind checking done already
 453
 454 ds_type (HsListTy ty)
 455   = dsHsType ty                 `thenM` \ tau_ty ->
 456     checkWiredInTyCon listTyCon `thenM_`
 457     returnM (mkListTy tau_ty)
 458
 459 ds_type (HsPArrTy ty)
 460   = dsHsType ty                 `thenM` \ tau_ty ->
 461     checkWiredInTyCon parrTyCon `thenM_`
 462     returnM (mkPArrTy tau_ty)
 463
 464 ds_type (HsTupleTy boxity tys)
 465   = dsHsTypes tys               `thenM` \ tau_tys ->
 466     checkWiredInTyCon tycon     `thenM_`
 467     returnM (mkTyConApp tycon tau_tys)
 468   where
 469     tycon = tupleTyCon boxity (length tys)
 470
 471 ds_type (HsFunTy ty1 ty2)
 472   = dsHsType ty1                        `thenM` \ tau_ty1 ->
 473     dsHsType ty2                        `thenM` \ tau_ty2 ->
 474     returnM (mkFunTy tau_ty1 tau_ty2)
 475
 476 ds_type (HsOpTy ty1 (L span op) ty2)
 477   = dsHsType ty1                `thenM` \ tau_ty1 ->
 478     dsHsType ty2                `thenM` \ tau_ty2 ->
 479     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 480
 481 ds_type (HsNumTy n)
 482   = ASSERT(n==1)
 483     tcLookupTyCon genUnitTyConName      `thenM` \ tc ->
 484     returnM (mkTyConApp tc [])
 485
 486 ds_type ty@(HsAppTy _ _)
 487   = ds_app ty []
 488
 489 ds_type (HsPredTy pred)
 490   = dsHsPred pred       `thenM` \ pred' ->
 491     returnM (mkPredTy pred')
 492
 493 ds_type full_ty@(HsForAllTy exp tv_names ctxt ty)
 494   = tcTyVarBndrs tv_names               $ \ tyvars ->
 495     mappM dsHsLPred (unLoc ctxt)        `thenM` \ theta ->
 496     dsHsType ty                         `thenM` \ tau ->
 497     returnM (mkSigmaTy tyvars theta tau)
 498
 499 ds_type (HsSpliceTy {}) = panic "ds_type: HsSpliceTy"
 500
 501 dsHsTypes arg_tys = mappM dsHsType arg_tys
 502 \end{code}
 503
 504 Help functions for type applications
 505 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 506
 507 \begin{code}
 508 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 509 ds_app (HsAppTy ty1 ty2) tys
 510   = ds_app (unLoc ty1) (ty2:tys)
 511
 512 ds_app ty tys
 513   = dsHsTypes tys                       `thenM` \ arg_tys ->
 514     case ty of
 515         HsTyVar fun -> ds_var_app fun arg_tys
 516         other       -> ds_type ty               `thenM` \ fun_ty ->
 517                        returnM (mkAppTys fun_ty arg_tys)
 518
 519 ds_var_app :: Name -> [Type] -> TcM Type
 520 ds_var_app name arg_tys
 521  = tcLookup name                        `thenM` \ thing ->
 522     case thing of
 523         ATyVar _ ty         -> returnM (mkAppTys ty arg_tys)
 524         AGlobal (ATyCon tc) -> returnM (mkTyConApp tc arg_tys)
 525         other               -> wrongThingErr "type" thing name
 526 \end{code}
 527
 528
 529 Contexts
 530 ~~~~~~~~
 531
 532 \begin{code}
 533 dsHsLPred :: LHsPred Name -> TcM PredType
 534 dsHsLPred pred = dsHsPred (unLoc pred)
 535
 536 dsHsPred pred@(HsClassP class_name tys)
 537   = dsHsTypes tys                       `thenM` \ arg_tys ->
 538     tcLookupClass class_name            `thenM` \ clas ->
 539     returnM (ClassP clas arg_tys)
 540
 541 dsHsPred (HsIParam name ty)
 542   = dsHsType ty                                 `thenM` \ arg_ty ->
 543     returnM (IParam name arg_ty)
 544 \end{code}
 545
 546 GADT constructor signatures
 547
 548 \begin{code}
 549 tcLHsConResTy :: LHsType Name -> TcM (TyCon, [TcType])
 550 tcLHsConResTy res_ty
 551   = addErrCtxt (gadtResCtxt res_ty) $
 552     case get_largs res_ty [] of
 553            (HsTyVar tc_name, args)
 554               -> do { args' <- mapM dsHsType args
 555                     ; thing <- tcLookup tc_name
 556                     ; case thing of
 557                         AGlobal (ATyCon tc) -> return (tc, args')
 558                         other -> failWithTc (badGadtDecl res_ty) }
 559            other -> failWithTc (badGadtDecl res_ty)
 560   where
 561         -- We can't call dsHsType on res_ty, and then do tcSplitTyConApp_maybe
 562         -- because that causes a black hole, and for good reason.  Building
 563         -- the type means expanding type synonyms, and we can't do that
 564         -- inside the "knot".  So we have to work by steam.
 565     get_largs (L _ ty) args = get_args ty args
 566     get_args (HsAppTy fun arg)            args = get_largs fun (arg:args)
 567     get_args (HsParTy ty)                 args = get_largs ty  args
 568     get_args (HsOpTy ty1 (L span tc) ty2) args = (HsTyVar tc, ty1:ty2:args)
 569     get_args ty                           args = (ty, args)
 570
 571 gadtResCtxt ty
 572   = hang (ptext SLIT("In the result type of a data constructor:"))
 573        2 (ppr ty)
 574 badGadtDecl ty
 575   = hang (ptext SLIT("Malformed constructor result type:"))
 576        2 (ppr ty)
 577
 578 typeCtxt ty = ptext SLIT("In the type") <+> quotes (ppr ty)
 579 \end{code}
 580
 581 %************************************************************************
 582 %*                                                                      *
 583                 Type-variable binders
 584 %*                                                                      *
 585 %************************************************************************
 586
 587
 588 \begin{code}
 589 kcHsTyVars :: [LHsTyVarBndr Name]
 590            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 591                                                 -- They scope over the thing inside
 592            -> TcM r
 593 kcHsTyVars tvs thing_inside
 594   = mappM (wrapLocM kcHsTyVar) tvs      `thenM` \ bndrs ->
 595     tcExtendKindEnvTvs bndrs (thing_inside bndrs)
 596
 597 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 598         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 599 kcHsTyVar (UserTyVar name)        = newKindVar  `thenM` \ kind ->
 600                                     returnM (KindedTyVar name kind)
 601 kcHsTyVar (KindedTyVar name kind) = returnM (KindedTyVar name kind)
 602
 603 ------------------
 604 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 605              -> ([TyVar] -> TcM r)
 606              -> TcM r
 607 -- Used when type-checking types/classes/type-decls
 608 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 609 tcTyVarBndrs bndrs thing_inside
 610   = mapM (zonk . unLoc) bndrs   `thenM` \ tyvars ->
 611     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 612   where
 613     zonk (KindedTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 614                                       ; return (mkTyVar name kind') }
 615     zonk (UserTyVar name) = pprTrace "Un-kinded tyvar" (ppr name) $
 616                             return (mkTyVar name liftedTypeKind)
 617
 618 -----------------------------------
 619 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 620 -- GADT decls can have a (perhaps partial) kind signature
 621 --      e.g.  data T :: * -> * -> * where ...
 622 -- This function makes up suitable (kinded) type variables for
 623 -- the argument kinds, and checks that the result kind is indeed *.
 624 -- We use it also to make up argument type variables for for data instances.
 625 tcDataKindSig Nothing = return []
 626 tcDataKindSig (Just kind)
 627   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 628         ; span <- getSrcSpanM
 629         ; us   <- newUniqueSupply
 630         ; let loc   = srcSpanStart span
 631               uniqs = uniqsFromSupply us
 632         ; return [ mk_tv loc uniq str kind
 633                  | ((kind, str), uniq) <- arg_kinds `zip` names `zip` uniqs ] }
 634   where
 635     (arg_kinds, res_kind) = splitKindFunTys kind
 636     mk_tv loc uniq str kind = mkTyVar name kind
 637         where
 638            name = mkInternalName uniq occ loc
 639            occ  = mkOccName tvName str
 640
 641     names :: [String]   -- a,b,c...aa,ab,ac etc
 642     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 643
 644 badKindSig :: Kind -> SDoc
 645 badKindSig kind
 646  = hang (ptext SLIT("Kind signature on data type declaration has non-* return kind"))
 647         2 (ppr kind)
 648 \end{code}
 649
 650
 651 %************************************************************************
 652 %*                                                                      *
 653                 Scoped type variables
 654 %*                                                                      *
 655 %************************************************************************
 656
 657
 658 tcAddScopedTyVars is used for scoped type variables added by pattern
 659 type signatures
 660         e.g.  \ ((x::a), (y::a)) -> x+y
 661 They never have explicit kinds (because this is source-code only)
 662 They are mutable (because they can get bound to a more specific type).
 663
 664 Usually we kind-infer and expand type splices, and then
 665 tupecheck/desugar the type.  That doesn't work well for scoped type
 666 variables, because they scope left-right in patterns.  (e.g. in the
 667 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 668
 669 The current not-very-good plan is to
 670   * find all the types in the patterns
 671   * find their free tyvars
 672   * do kind inference
 673   * bring the kinded type vars into scope
 674   * BUT throw away the kind-checked type
 675         (we'll kind-check it again when we type-check the pattern)
 676
 677 This is bad because throwing away the kind checked type throws away
 678 its splices.  But too bad for now.  [July 03]
 679
 680 Historical note:
 681     We no longer specify that these type variables must be univerally
 682     quantified (lots of email on the subject).  If you want to put that
 683     back in, you need to
 684         a) Do a checkSigTyVars after thing_inside
 685         b) More insidiously, don't pass in expected_ty, else
 686            we unify with it too early and checkSigTyVars barfs
 687            Instead you have to pass in a fresh ty var, and unify
 688            it with expected_ty afterwards
 689
 690 \begin{code}
 691 tcHsPatSigType :: UserTypeCtxt
 692                -> LHsType Name          -- The type signature
 693                -> TcM ([TyVar],         -- Newly in-scope type variables
 694                         Type)           -- The signature
 695 -- Used for type-checking type signatures in
 696 -- (a) patterns           e.g  f (x::Int) = e
 697 -- (b) result signatures  e.g. g x :: Int = e
 698 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 699
 700 tcHsPatSigType ctxt hs_ty
 701   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 702     do  {       -- Find the type variables that are mentioned in the type
 703                 -- but not already in scope.  These are the ones that
 704                 -- should be bound by the pattern signature
 705           in_scope <- getInLocalScope
 706         ; let span = getLoc hs_ty
 707               sig_tvs = [ L span (UserTyVar n)
 708                         | n <- nameSetToList (extractHsTyVars hs_ty),
 709                           not (in_scope n) ]
 710
 711         -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 712         -- except that we want to keep the tvs separate
 713         ; (kinded_tvs, kinded_ty) <- kcHsTyVars sig_tvs $ \ kinded_tvs -> do
 714                                     { kinded_ty <- kcTypeType hs_ty
 715                                     ; return (kinded_tvs, kinded_ty) }
 716         ; tcTyVarBndrs kinded_tvs $ \ tyvars -> do
 717         { sig_ty <- dsHsType kinded_ty
 718         ; checkValidType ctxt sig_ty
 719         ; return (tyvars, sig_ty)
 720       } }
 721
 722 tcPatSig :: UserTypeCtxt
 723          -> LHsType Name
 724          -> BoxySigmaType
 725          -> TcM (TcType,           -- The type to use for "inside" the signature
 726                  [(Name,TcType)])  -- The new bit of type environment, binding
 727                                    -- the scoped type variables
 728 tcPatSig ctxt sig res_ty
 729   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 730
 731         ; if null sig_tvs then do {
 732                 -- The type signature binds no type variables,
 733                 -- and hence is rigid, so use it to zap the res_ty
 734                   boxyUnify sig_ty res_ty
 735                 ; return (sig_ty, [])
 736
 737         } else do {
 738                 -- Type signature binds at least one scoped type variable
 739
 740                 -- A pattern binding cannot bind scoped type variables
 741                 -- The renamer fails with a name-out-of-scope error
 742                 -- if a pattern binding tries to bind a type variable,
 743                 -- So we just have an ASSERT here
 744         ; let in_pat_bind = case ctxt of
 745                                 BindPatSigCtxt -> True
 746                                 other          -> False
 747         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 748
 749                 -- Check that pat_ty is rigid
 750         ; checkTc (isRigidTy res_ty) (wobblyPatSig sig_tvs)
 751
 752                 -- Now match the pattern signature against res_ty
 753                 -- For convenience, and uniform-looking error messages
 754                 -- we do the matching by allocating meta type variables,
 755                 -- unifying, and reading out the results.
 756                 -- This is a strictly local operation.
 757         ; box_tvs <- mapM tcInstBoxyTyVar sig_tvs
 758         ; boxyUnify (substTyWith sig_tvs (mkTyVarTys box_tvs) sig_ty) res_ty
 759         ; sig_tv_tys <- mapM readFilledBox box_tvs
 760
 761                 -- Check that each is bound to a distinct type variable,
 762                 -- and one that is not already in scope
 763         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys
 764         ; binds_in_scope <- getScopedTyVarBinds
 765         ; check binds_in_scope tv_binds
 766
 767                 -- Phew!
 768         ; return (res_ty, tv_binds)
 769         } }
 770   where
 771     check in_scope []            = return ()
 772     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 773                                       ; check ((n,ty):in_scope) rest }
 774
 775     check_one in_scope n ty
 776         = do { checkTc (tcIsTyVarTy ty) (scopedNonVar n ty)
 777                 -- Must bind to a type variable
 778
 779              ; checkTc (null dups) (dupInScope n (head dups) ty)
 780                 -- Must not bind to the same type variable
 781                 -- as some other in-scope type variable
 782
 783              ; return () }
 784         where
 785           dups = [n' | (n',ty') <- in_scope, tcEqType ty' ty]
 786 \end{code}
 787
 788
 789 %************************************************************************
 790 %*                                                                      *
 791                 Scoped type variables
 792 %*                                                                      *
 793 %************************************************************************
 794
 795 \begin{code}
 796 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
 797 pprHsSigCtxt ctxt hs_ty = vcat [ ptext SLIT("In") <+> pprUserTypeCtxt ctxt <> colon,
 798                                  nest 2 (pp_sig ctxt) ]
 799   where
 800     pp_sig (FunSigCtxt n)  = pp_n_colon n
 801     pp_sig (ConArgCtxt n)  = pp_n_colon n
 802     pp_sig (ForSigCtxt n)  = pp_n_colon n
 803     pp_sig other           = ppr (unLoc hs_ty)
 804
 805     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
 806
 807
 808 wobblyPatSig sig_tvs
 809   = hang (ptext SLIT("A pattern type signature cannot bind scoped type variables")
 810                 <+> pprQuotedList sig_tvs)
 811        2 (ptext SLIT("unless the pattern has a rigid type context"))
 812
 813 scopedNonVar n ty
 814   = vcat [sep [ptext SLIT("The scoped type variable") <+> quotes (ppr n),
 815                nest 2 (ptext SLIT("is bound to the type") <+> quotes (ppr ty))],
 816           nest 2 (ptext SLIT("You can only bind scoped type variables to type variables"))]
 817
 818 dupInScope n n' ty
 819   = hang (ptext SLIT("The scoped type variables") <+> quotes (ppr n) <+> ptext SLIT("and") <+> quotes (ppr n'))
 820        2 (vcat [ptext SLIT("are bound to the same type (variable)"),
 821                 ptext SLIT("Distinct scoped type variables must be distinct")])
 822 \end{code}
 823