compiler/typecheck/TcHsType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcMonoType]{Typechecking user-specified @MonoTypes@}
   6
   7 \begin{code}
   8 module TcHsType (
   9         tcHsSigType, tcHsSigTypeNC, tcHsDeriv,
  10         tcHsInstHead, tcHsQuantifiedType,
  11         UserTypeCtxt(..),
  12
  13                 -- Kind checking
  14         kcHsTyVars, kcHsSigType, kcHsLiftedSigType,
  15         kcLHsType, kcCheckLHsType, kcHsContext,
  16
  17                 -- Typechecking kinded types
  18         tcHsKindedContext, tcHsKindedType, tcHsBangType,
  19         tcTyVarBndrs, dsHsType, kcHsLPred, dsHsLPred,
  20         tcDataKindSig, ExpKind(..), EkCtxt(..),
  21
  22                 -- Pattern type signatures
  23         tcHsPatSigType, tcPatSig
  24    ) where
  25
  26 #include "HsVersions.h"
  27
  28 #ifdef GHCI     /* Only if bootstrapped */
  29 import {-# SOURCE #-}   TcSplice( kcSpliceType )
  30 #endif
  31
  32 import HsSyn
  33 import RnHsSyn
  34 import TcRnMonad
  35 import TcEnv
  36 import TcMType
  37 import TcUnify
  38 import TcIface
  39 import TcType
  40 import {- Kind parts of -} Type
  41 import Var
  42 import VarSet
  43 import TyCon
  44 import Class
  45 import Name
  46 import NameSet
  47 import PrelNames
  48 import TysWiredIn
  49 import BasicTypes
  50 import SrcLoc
  51 import Util
  52 import UniqSupply
  53 import Outputable
  54 import FastString
  55 \end{code}
  56
  57
  58         ----------------------------
  59                 General notes
  60         ----------------------------
  61
  62 Generally speaking we now type-check types in three phases
  63
  64   1.  kcHsType: kind check the HsType
  65         *includes* performing any TH type splices;
  66         so it returns a translated, and kind-annotated, type
  67
  68   2.  dsHsType: convert from HsType to Type:
  69         perform zonking
  70         expand type synonyms [mkGenTyApps]
  71         hoist the foralls [tcHsType]
  72
  73   3.  checkValidType: check the validity of the resulting type
  74
  75 Often these steps are done one after the other (tcHsSigType).
  76 But in mutually recursive groups of type and class decls we do
  77         1 kind-check the whole group
  78         2 build TyCons/Classes in a knot-tied way
  79         3 check the validity of types in the now-unknotted TyCons/Classes
  80
  81 For example, when we find
  82         (forall a m. m a -> m a)
  83 we bind a,m to kind varibles and kind-check (m a -> m a).  This makes
  84 a get kind *, and m get kind *->*.  Now we typecheck (m a -> m a) in
  85 an environment that binds a and m suitably.
  86
  87 The kind checker passed to tcHsTyVars needs to look at enough to
  88 establish the kind of the tyvar:
  89   * For a group of type and class decls, it's just the group, not
  90         the rest of the program
  91   * For a tyvar bound in a pattern type signature, its the types
  92         mentioned in the other type signatures in that bunch of patterns
  93   * For a tyvar bound in a RULE, it's the type signatures on other
  94         universally quantified variables in the rule
  95
  96 Note that this may occasionally give surprising results.  For example:
  97
  98         data T a b = MkT (a b)
  99
 100 Here we deduce                  a::*->*,       b::*
 101 But equally valid would be      a::(*->*)-> *, b::*->*
 102
 103
 104 Validity checking
 105 ~~~~~~~~~~~~~~~~~
 106 Some of the validity check could in principle be done by the kind checker,
 107 but not all:
 108
 109 - During desugaring, we normalise by expanding type synonyms.  Only
 110   after this step can we check things like type-synonym saturation
 111   e.g.  type T k = k Int
 112         type S a = a
 113   Then (T S) is ok, because T is saturated; (T S) expands to (S Int);
 114   and then S is saturated.  This is a GHC extension.
 115
 116 - Similarly, also a GHC extension, we look through synonyms before complaining
 117   about the form of a class or instance declaration
 118
 119 - Ambiguity checks involve functional dependencies, and it's easier to wait
 120   until knots have been resolved before poking into them
 121
 122 Also, in a mutually recursive group of types, we can't look at the TyCon until we've
 123 finished building the loop.  So to keep things simple, we postpone most validity
 124 checking until step (3).
 125
 126 Knot tying
 127 ~~~~~~~~~~
 128 During step (1) we might fault in a TyCon defined in another module, and it might
 129 (via a loop) refer back to a TyCon defined in this module. So when we tie a big
 130 knot around type declarations with ARecThing, so that the fault-in code can get
 131 the TyCon being defined.
 132
 133
 134 %************************************************************************
 135 %*                                                                      *
 136 \subsection{Checking types}
 137 %*                                                                      *
 138 %************************************************************************
 139
 140 \begin{code}
 141 tcHsSigType, tcHsSigTypeNC :: UserTypeCtxt -> LHsType Name -> TcM Type
 142   -- Do kind checking, and hoist for-alls to the top
 143   -- NB: it's important that the foralls that come from the top-level
 144   --     HsForAllTy in hs_ty occur *first* in the returned type.
 145   --     See Note [Scoped] with TcSigInfo
 146 tcHsSigType ctxt hs_ty
 147   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 148     tcHsSigTypeNC ctxt hs_ty
 149
 150 tcHsSigTypeNC ctxt hs_ty
 151   = do  { (kinded_ty, _kind) <- kc_lhs_type hs_ty
 152           -- The kind is checked by checkValidType, and isn't necessarily
 153           -- of kind * in a Template Haskell quote eg [t| Maybe |]
 154         ; ty <- tcHsKindedType kinded_ty
 155         ; checkValidType ctxt ty
 156         ; return ty }
 157
 158 tcHsInstHead :: LHsType Name -> TcM ([TyVar], ThetaType, Class, [Type])
 159 -- Typecheck an instance head.  We can't use
 160 -- tcHsSigType, because it's not a valid user type.
 161 tcHsInstHead (L loc hs_ty)
 162   = setSrcSpan loc   $  -- No need for an "In the type..." context
 163                         -- because that comes from the caller
 164     do { kinded_ty <- kc_inst_head hs_ty
 165        ; ds_inst_head kinded_ty }
 166   where
 167     kc_inst_head ty@(HsPredTy pred@(HsClassP {}))
 168       = do { (pred', kind) <- kc_pred pred
 169            ; checkExpectedKind ty kind ekLifted
 170            ; return (HsPredTy pred') }
 171     kc_inst_head (HsForAllTy exp tv_names context (L loc ty))
 172       = kcHsTyVars tv_names         $ \ tv_names' ->
 173         do { ctxt' <- kcHsContext context
 174            ; ty'   <- kc_inst_head ty
 175            ; return (HsForAllTy exp tv_names' ctxt' (L loc ty')) }
 176     kc_inst_head _ = failWithTc (ptext (sLit "Malformed instance type"))
 177
 178     ds_inst_head (HsPredTy (HsClassP cls_name tys))
 179       = do { clas <- tcLookupClass cls_name
 180            ; arg_tys <- dsHsTypes tys
 181            ; return ([], [], clas, arg_tys) }
 182     ds_inst_head (HsForAllTy _ tvs ctxt (L _ tau))
 183       = tcTyVarBndrs tvs  $ \ tvs' ->
 184         do { ctxt' <- mapM dsHsLPred (unLoc ctxt)
 185            ; (tvs_r, ctxt_r, cls, tys) <- ds_inst_head tau
 186            ; return (tvs' ++ tvs_r, ctxt' ++ ctxt_r , cls, tys) }
 187     ds_inst_head _ = panic "ds_inst_head"
 188
 189 tcHsQuantifiedType :: [LHsTyVarBndr Name] -> LHsType Name -> TcM ([TyVar], Type)
 190 -- Behave very like type-checking (HsForAllTy sig_tvs hs_ty),
 191 -- except that we want to keep the tvs separate
 192 tcHsQuantifiedType tv_names hs_ty
 193   = kcHsTyVars tv_names $ \ tv_names' ->
 194     do  { kc_ty <- kcHsSigType hs_ty
 195         ; tcTyVarBndrs tv_names' $ \ tvs ->
 196     do  { ty <- dsHsType kc_ty
 197         ; return (tvs, ty) } }
 198
 199 -- Used for the deriving(...) items
 200 tcHsDeriv :: HsType Name -> TcM ([TyVar], Class, [Type])
 201 tcHsDeriv = tc_hs_deriv []
 202
 203 tc_hs_deriv :: [LHsTyVarBndr Name] -> HsType Name
 204             -> TcM ([TyVar], Class, [Type])
 205 tc_hs_deriv tv_names (HsPredTy (HsClassP cls_name hs_tys))
 206   = kcHsTyVars tv_names                 $ \ tv_names' ->
 207     do  { cls_kind <- kcClass cls_name
 208         ; (tys, _res_kind) <- kcApps cls_name cls_kind hs_tys
 209         ; tcTyVarBndrs tv_names'        $ \ tyvars ->
 210     do  { arg_tys <- dsHsTypes tys
 211         ; cls <- tcLookupClass cls_name
 212         ; return (tyvars, cls, arg_tys) }}
 213
 214 tc_hs_deriv tv_names1 (HsForAllTy _ tv_names2 (L _ []) (L _ ty))
 215   =     -- Funny newtype deriving form
 216         --      forall a. C [a]
 217         -- where C has arity 2.  Hence can't use regular functions
 218     tc_hs_deriv (tv_names1 ++ tv_names2) ty
 219
 220 tc_hs_deriv _ other
 221   = failWithTc (ptext (sLit "Illegal deriving item") <+> ppr other)
 222 \end{code}
 223
 224         These functions are used during knot-tying in
 225         type and class declarations, when we have to
 226         separate kind-checking, desugaring, and validity checking
 227
 228 \begin{code}
 229 kcHsSigType, kcHsLiftedSigType :: LHsType Name -> TcM (LHsType Name)
 230         -- Used for type signatures
 231 kcHsSigType ty       = addKcTypeCtxt ty $ kcTypeType ty
 232 kcHsLiftedSigType ty = addKcTypeCtxt ty $ kcLiftedType ty
 233
 234 tcHsKindedType :: LHsType Name -> TcM Type
 235   -- Don't do kind checking, nor validity checking.
 236   -- This is used in type and class decls, where kinding is
 237   -- done in advance, and validity checking is done later
 238   -- [Validity checking done later because of knot-tying issues.]
 239 tcHsKindedType hs_ty = dsHsType hs_ty
 240
 241 tcHsBangType :: LHsType Name -> TcM Type
 242 -- Permit a bang, but discard it
 243 tcHsBangType (L _ (HsBangTy _ ty)) = tcHsKindedType ty
 244 tcHsBangType ty                    = tcHsKindedType ty
 245
 246 tcHsKindedContext :: LHsContext Name -> TcM ThetaType
 247 -- Used when we are expecting a ClassContext (i.e. no implicit params)
 248 -- Does not do validity checking, like tcHsKindedType
 249 tcHsKindedContext hs_theta = addLocM (mapM dsHsLPred) hs_theta
 250 \end{code}
 251
 252
 253 %************************************************************************
 254 %*                                                                      *
 255                 The main kind checker: kcHsType
 256 %*                                                                      *
 257 %************************************************************************
 258
 259         First a couple of simple wrappers for kcHsType
 260
 261 \begin{code}
 262 ---------------------------
 263 kcLiftedType :: LHsType Name -> TcM (LHsType Name)
 264 -- The type ty must be a *lifted* *type*
 265 kcLiftedType ty = kc_check_lhs_type ty ekLifted
 266
 267 ---------------------------
 268 kcTypeType :: LHsType Name -> TcM (LHsType Name)
 269 -- The type ty must be a *type*, but it can be lifted or
 270 -- unlifted or an unboxed tuple.
 271 kcTypeType ty = kc_check_lhs_type ty ekOpen
 272
 273 ---------------------------
 274 kcCheckLHsType :: LHsType Name -> ExpKind -> TcM (LHsType Name)
 275 kcCheckLHsType ty kind = addKcTypeCtxt ty $ kc_check_lhs_type ty kind
 276
 277
 278 kc_check_lhs_type :: LHsType Name -> ExpKind -> TcM (LHsType Name)
 279 -- Check that the type has the specified kind
 280 -- Be sure to use checkExpectedKind, rather than simply unifying
 281 -- with OpenTypeKind, because it gives better error messages
 282 kc_check_lhs_type (L span ty) exp_kind
 283   = setSrcSpan span $
 284     do { ty' <- kc_check_hs_type ty exp_kind
 285        ; return (L span ty') }
 286
 287 kc_check_lhs_types :: [(LHsType Name, ExpKind)] -> TcM [LHsType Name]
 288 kc_check_lhs_types tys_w_kinds
 289   = mapM kc_arg tys_w_kinds
 290   where
 291     kc_arg (arg, arg_kind) = kc_check_lhs_type arg arg_kind
 292
 293
 294 ---------------------------
 295 kc_check_hs_type :: HsType Name -> ExpKind -> TcM (HsType Name)
 296
 297 -- First some special cases for better error messages
 298 -- when we know the expected kind
 299 kc_check_hs_type (HsParTy ty) exp_kind
 300   = do { ty' <- kc_check_lhs_type ty exp_kind; return (HsParTy ty') }
 301
 302 kc_check_hs_type ty@(HsAppTy ty1 ty2) exp_kind
 303   = do { let (fun_ty, arg_tys) = splitHsAppTys ty1 ty2
 304        ; (fun_ty', fun_kind) <- kc_lhs_type fun_ty
 305        ; arg_tys' <- kcCheckApps fun_ty fun_kind arg_tys ty exp_kind
 306        ; return (mkHsAppTys fun_ty' arg_tys') }
 307
 308 -- This is the general case: infer the kind and compare
 309 kc_check_hs_type ty exp_kind
 310   = do  { (ty', act_kind) <- kc_hs_type ty
 311                 -- Add the context round the inner check only
 312                 -- because checkExpectedKind already mentions
 313                 -- 'ty' by name in any error message
 314
 315         ; checkExpectedKind (strip ty) act_kind exp_kind
 316         ; return ty' }
 317   where
 318         -- We infer the kind of the type, and then complain if it's
 319         -- not right.  But we don't want to complain about
 320         --      (ty) or !(ty) or forall a. ty
 321         -- when the real difficulty is with the 'ty' part.
 322     strip (HsParTy (L _ ty))          = strip ty
 323     strip (HsBangTy _ (L _ ty))       = strip ty
 324     strip (HsForAllTy _ _ _ (L _ ty)) = strip ty
 325     strip ty                          = ty
 326 \end{code}
 327
 328         Here comes the main function
 329
 330 \begin{code}
 331 kcLHsType :: LHsType Name -> TcM (LHsType Name, TcKind)
 332 -- Called from outside: set the context
 333 kcLHsType ty = addKcTypeCtxt ty (kc_lhs_type ty)
 334
 335 kc_lhs_type :: LHsType Name -> TcM (LHsType Name, TcKind)
 336 kc_lhs_type (L span ty)
 337   = setSrcSpan span $
 338     do { (ty', kind) <- kc_hs_type ty
 339        ; return (L span ty', kind) }
 340
 341 -- kc_hs_type *returns* the kind of the type, rather than taking an expected
 342 -- kind as argument as tcExpr does.
 343 -- Reasons:
 344 --      (a) the kind of (->) is
 345 --              forall bx1 bx2. Type bx1 -> Type bx2 -> Type Boxed
 346 --          so we'd need to generate huge numbers of bx variables.
 347 --      (b) kinds are so simple that the error messages are fine
 348 --
 349 -- The translated type has explicitly-kinded type-variable binders
 350
 351 kc_hs_type :: HsType Name -> TcM (HsType Name, TcKind)
 352 kc_hs_type (HsParTy ty) = do
 353    (ty', kind) <- kc_lhs_type ty
 354    return (HsParTy ty', kind)
 355
 356 kc_hs_type (HsTyVar name) = do
 357     kind <- kcTyVar name
 358     return (HsTyVar name, kind)
 359
 360 kc_hs_type (HsListTy ty) = do
 361     ty' <- kcLiftedType ty
 362     return (HsListTy ty', liftedTypeKind)
 363
 364 kc_hs_type (HsPArrTy ty) = do
 365     ty' <- kcLiftedType ty
 366     return (HsPArrTy ty', liftedTypeKind)
 367
 368 kc_hs_type (HsNumTy n)
 369    = return (HsNumTy n, liftedTypeKind)
 370
 371 kc_hs_type (HsKindSig ty k) = do
 372     ty' <- kc_check_lhs_type ty (EK k EkKindSig)
 373     return (HsKindSig ty' k, k)
 374
 375 kc_hs_type (HsTupleTy Boxed tys) = do
 376     tys' <- mapM kcLiftedType tys
 377     return (HsTupleTy Boxed tys', liftedTypeKind)
 378
 379 kc_hs_type (HsTupleTy Unboxed tys) = do
 380     tys' <- mapM kcTypeType tys
 381     return (HsTupleTy Unboxed tys', ubxTupleKind)
 382
 383 kc_hs_type (HsFunTy ty1 ty2) = do
 384     ty1' <- kc_check_lhs_type ty1 (EK argTypeKind EkUnk)
 385     ty2' <- kcTypeType ty2
 386     return (HsFunTy ty1' ty2', liftedTypeKind)
 387
 388 kc_hs_type (HsOpTy ty1 op ty2) = do
 389     op_kind <- addLocM kcTyVar op
 390     ([ty1',ty2'], res_kind) <- kcApps op op_kind [ty1,ty2]
 391     return (HsOpTy ty1' op ty2', res_kind)
 392
 393 kc_hs_type (HsAppTy ty1 ty2) = do
 394     (fun_ty', fun_kind) <- kc_lhs_type fun_ty
 395     (arg_tys', res_kind) <- kcApps fun_ty fun_kind arg_tys
 396     return (mkHsAppTys fun_ty' arg_tys', res_kind)
 397   where
 398     (fun_ty, arg_tys) = splitHsAppTys ty1 ty2
 399
 400 kc_hs_type (HsPredTy pred)
 401   = wrongPredErr pred
 402
 403 kc_hs_type (HsCoreTy ty)
 404   = return (HsCoreTy ty, typeKind ty)
 405
 406 kc_hs_type (HsForAllTy exp tv_names context ty)
 407   = kcHsTyVars tv_names         $ \ tv_names' ->
 408     do  { ctxt' <- kcHsContext context
 409         ; ty'   <- kcLiftedType ty
 410              -- The body of a forall is usually a type, but in principle
 411              -- there's no reason to prohibit *unlifted* types.
 412              -- In fact, GHC can itself construct a function with an
 413              -- unboxed tuple inside a for-all (via CPR analyis; see
 414              -- typecheck/should_compile/tc170)
 415              --
 416              -- Still, that's only for internal interfaces, which aren't
 417              -- kind-checked, so we only allow liftedTypeKind here
 418
 419         ; return (HsForAllTy exp tv_names' ctxt' ty', liftedTypeKind) }
 420
 421 kc_hs_type (HsBangTy b ty)
 422   = do { (ty', kind) <- kc_lhs_type ty
 423        ; return (HsBangTy b ty', kind) }
 424
 425 kc_hs_type ty@(HsRecTy _)
 426   = failWithTc (ptext (sLit "Unexpected record type") <+> ppr ty)
 427       -- Record types (which only show up temporarily in constructor signatures)
 428       -- should have been removed by now
 429
 430 #ifdef GHCI     /* Only if bootstrapped */
 431 kc_hs_type (HsSpliceTy sp fvs _) = kcSpliceType sp fvs
 432 #else
 433 kc_hs_type ty@(HsSpliceTy {}) = failWithTc (ptext (sLit "Unexpected type splice:") <+> ppr ty)
 434 #endif
 435
 436 kc_hs_type (HsQuasiQuoteTy {}) = panic "kc_hs_type"     -- Eliminated by renamer
 437
 438 -- remove the doc nodes here, no need to worry about the location since
 439 -- its the same for a doc node and it's child type node
 440 kc_hs_type (HsDocTy ty _)
 441   = kc_hs_type (unLoc ty)
 442
 443 ---------------------------
 444 kcApps :: Outputable a
 445        => a
 446        -> TcKind                        -- Function kind
 447        -> [LHsType Name]                -- Arg types
 448        -> TcM ([LHsType Name], TcKind)  -- Kind-checked args
 449 kcApps the_fun fun_kind args
 450   = do { (args_w_kinds, res_kind) <- splitFunKind (ppr the_fun) 1 fun_kind args
 451        ; args' <- kc_check_lhs_types args_w_kinds
 452        ; return (args', res_kind) }
 453
 454 kcCheckApps :: Outputable a => a -> TcKind -> [LHsType Name]
 455             -> HsType Name     -- The type being checked (for err messages only)
 456             -> ExpKind         -- Expected kind
 457             -> TcM [LHsType Name]
 458 kcCheckApps the_fun fun_kind args ty exp_kind
 459   = do { (args_w_kinds, res_kind) <- splitFunKind (ppr the_fun) 1 fun_kind args
 460        ; checkExpectedKind ty res_kind exp_kind
 461              -- Check the result kind *before* checking argument kinds
 462              -- This improves error message; Trac #2994
 463        ; kc_check_lhs_types args_w_kinds }
 464
 465 splitHsAppTys :: LHsType Name -> LHsType Name -> (LHsType Name, [LHsType Name])
 466 splitHsAppTys fun_ty arg_ty = split fun_ty [arg_ty]
 467   where
 468     split (L _ (HsAppTy f a)) as = split f (a:as)
 469     split f                   as = (f,as)
 470
 471 mkHsAppTys :: LHsType Name -> [LHsType Name] -> HsType Name
 472 mkHsAppTys fun_ty [] = pprPanic "mkHsAppTys" (ppr fun_ty)
 473 mkHsAppTys fun_ty (arg_ty:arg_tys)
 474   = foldl mk_app (HsAppTy fun_ty arg_ty) arg_tys
 475   where
 476     mk_app fun arg = HsAppTy (noLoc fun) arg    -- Add noLocs for inner nodes of
 477                                                 -- the application; they are
 478                                                 -- never used
 479
 480 ---------------------------
 481 splitFunKind :: SDoc -> Int -> TcKind -> [b] -> TcM ([(b,ExpKind)], TcKind)
 482 splitFunKind _       _      fk [] = return ([], fk)
 483 splitFunKind the_fun arg_no fk (arg:args)
 484   = do { mb_fk <- matchExpectedFunKind fk
 485        ; case mb_fk of
 486             Nothing       -> failWithTc too_many_args
 487             Just (ak,fk') -> do { (aks, rk) <- splitFunKind the_fun (arg_no+1) fk' args
 488                                 ; return ((arg, EK ak (EkArg the_fun arg_no)):aks, rk) } }
 489   where
 490     too_many_args = quotes the_fun <+>
 491                     ptext (sLit "is applied to too many type arguments")
 492
 493 ---------------------------
 494 kcHsContext :: LHsContext Name -> TcM (LHsContext Name)
 495 kcHsContext ctxt = wrapLocM (mapM kcHsLPred) ctxt
 496
 497 kcHsLPred :: LHsPred Name -> TcM (LHsPred Name)
 498 kcHsLPred = wrapLocM kcHsPred
 499
 500 kcHsPred :: HsPred Name -> TcM (HsPred Name)
 501 kcHsPred pred = do      -- Checks that the result is a type kind
 502     (pred', kind) <- kc_pred pred
 503     checkExpectedKind pred kind ekOpen
 504     return pred'
 505
 506 ---------------------------
 507 kc_pred :: HsPred Name -> TcM (HsPred Name, TcKind)
 508         -- Does *not* check for a saturated
 509         -- application (reason: used from TcDeriv)
 510 kc_pred (HsIParam name ty)
 511   = do { (ty', kind) <- kc_lhs_type ty
 512        ; return (HsIParam name ty', kind) }
 513 kc_pred (HsClassP cls tys)
 514   = do { kind <- kcClass cls
 515        ; (tys', res_kind) <- kcApps cls kind tys
 516        ; return (HsClassP cls tys', res_kind) }
 517 kc_pred (HsEqualP ty1 ty2)
 518   = do { (ty1', kind1) <- kc_lhs_type ty1
 519        ; (ty2', kind2) <- kc_lhs_type ty2
 520        ; checkExpectedKind ty2 kind2 (EK kind1 EkEqPred)
 521        ; return (HsEqualP ty1' ty2', unliftedTypeKind) }
 522
 523 ---------------------------
 524 kcTyVar :: Name -> TcM TcKind
 525 kcTyVar name = do       -- Could be a tyvar or a tycon
 526     traceTc "lk1" (ppr name)
 527     thing <- tcLookup name
 528     traceTc "lk2" (ppr name <+> ppr thing)
 529     case thing of
 530         ATyVar _ ty             -> return (typeKind ty)
 531         AThing kind             -> return kind
 532         AGlobal (ATyCon tc)     -> return (tyConKind tc)
 533         _                       -> wrongThingErr "type" thing name
 534
 535 kcClass :: Name -> TcM TcKind
 536 kcClass cls = do        -- Must be a class
 537     thing <- tcLookup cls
 538     case thing of
 539         AThing kind             -> return kind
 540         AGlobal (AClass cls)    -> return (tyConKind (classTyCon cls))
 541         _                       -> wrongThingErr "class" thing cls
 542 \end{code}
 543
 544
 545 %************************************************************************
 546 %*                                                                      *
 547                 Desugaring
 548 %*                                                                      *
 549 %************************************************************************
 550
 551 The type desugarer
 552
 553         * Transforms from HsType to Type
 554         * Zonks any kinds
 555
 556 It cannot fail, and does no validity checking, except for
 557 structural matters, such as
 558         (a) spurious ! annotations.
 559         (b) a class used as a type
 560
 561 \begin{code}
 562 dsHsType :: LHsType Name -> TcM Type
 563 -- All HsTyVarBndrs in the intput type are kind-annotated
 564 dsHsType ty = ds_type (unLoc ty)
 565
 566 ds_type :: HsType Name -> TcM Type
 567 ds_type ty@(HsTyVar _)
 568   = ds_app ty []
 569
 570 ds_type (HsParTy ty)            -- Remove the parentheses markers
 571   = dsHsType ty
 572
 573 ds_type ty@(HsBangTy {})    -- No bangs should be here
 574   = failWithTc (ptext (sLit "Unexpected strictness annotation:") <+> ppr ty)
 575
 576 ds_type ty@(HsRecTy {})     -- No bangs should be here
 577   = failWithTc (ptext (sLit "Unexpected record type:") <+> ppr ty)
 578
 579 ds_type (HsKindSig ty _)
 580   = dsHsType ty -- Kind checking done already
 581
 582 ds_type (HsListTy ty) = do
 583     tau_ty <- dsHsType ty
 584     checkWiredInTyCon listTyCon
 585     return (mkListTy tau_ty)
 586
 587 ds_type (HsPArrTy ty) = do
 588     tau_ty <- dsHsType ty
 589     checkWiredInTyCon parrTyCon
 590     return (mkPArrTy tau_ty)
 591
 592 ds_type (HsTupleTy boxity tys) = do
 593     tau_tys <- dsHsTypes tys
 594     checkWiredInTyCon tycon
 595     return (mkTyConApp tycon tau_tys)
 596   where
 597     tycon = tupleTyCon boxity (length tys)
 598
 599 ds_type (HsFunTy ty1 ty2) = do
 600     tau_ty1 <- dsHsType ty1
 601     tau_ty2 <- dsHsType ty2
 602     return (mkFunTy tau_ty1 tau_ty2)
 603
 604 ds_type (HsOpTy ty1 (L span op) ty2) = do
 605     tau_ty1 <- dsHsType ty1
 606     tau_ty2 <- dsHsType ty2
 607     setSrcSpan span (ds_var_app op [tau_ty1,tau_ty2])
 608
 609 ds_type (HsNumTy n)
 610   = ASSERT(n==1) do
 611     tc <- tcLookupTyCon genUnitTyConName
 612     return (mkTyConApp tc [])
 613
 614 ds_type ty@(HsAppTy _ _)
 615   = ds_app ty []
 616
 617 ds_type (HsPredTy pred) = do
 618     pred' <- dsHsPred pred
 619     return (mkPredTy pred')
 620
 621 ds_type (HsForAllTy _ tv_names ctxt ty)
 622   = tcTyVarBndrs tv_names               $ \ tyvars -> do
 623     theta <- mapM dsHsLPred (unLoc ctxt)
 624     tau <- dsHsType ty
 625     return (mkSigmaTy tyvars theta tau)
 626
 627 ds_type (HsDocTy ty _)  -- Remove the doc comment
 628   = dsHsType ty
 629
 630 ds_type (HsSpliceTy _ _ kind)
 631   = do { kind' <- zonkTcKindToKind kind
 632        ; newFlexiTyVarTy kind' }
 633
 634 ds_type (HsQuasiQuoteTy {}) = panic "ds_type"   -- Eliminated by renamer
 635 ds_type (HsCoreTy ty)       = return ty
 636
 637 dsHsTypes :: [LHsType Name] -> TcM [Type]
 638 dsHsTypes arg_tys = mapM dsHsType arg_tys
 639 \end{code}
 640
 641 Help functions for type applications
 642 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 643
 644 \begin{code}
 645 ds_app :: HsType Name -> [LHsType Name] -> TcM Type
 646 ds_app (HsAppTy ty1 ty2) tys
 647   = ds_app (unLoc ty1) (ty2:tys)
 648
 649 ds_app ty tys = do
 650     arg_tys <- dsHsTypes tys
 651     case ty of
 652         HsTyVar fun -> ds_var_app fun arg_tys
 653         _           -> do fun_ty <- ds_type ty
 654                           return (mkAppTys fun_ty arg_tys)
 655
 656 ds_var_app :: Name -> [Type] -> TcM Type
 657 ds_var_app name arg_tys = do
 658     thing <- tcLookup name
 659     case thing of
 660         ATyVar _ ty         -> return (mkAppTys ty arg_tys)
 661         AGlobal (ATyCon tc) -> return (mkTyConApp tc arg_tys)
 662         _                   -> wrongThingErr "type" thing name
 663 \end{code}
 664
 665
 666 Contexts
 667 ~~~~~~~~
 668
 669 \begin{code}
 670 dsHsLPred :: LHsPred Name -> TcM PredType
 671 dsHsLPred pred = dsHsPred (unLoc pred)
 672
 673 dsHsPred :: HsPred Name -> TcM PredType
 674 dsHsPred (HsClassP class_name tys)
 675   = do { arg_tys <- dsHsTypes tys
 676        ; clas <- tcLookupClass class_name
 677        ; return (ClassP clas arg_tys)
 678        }
 679 dsHsPred (HsEqualP ty1 ty2)
 680   = do { arg_ty1 <- dsHsType ty1
 681        ; arg_ty2 <- dsHsType ty2
 682        ; return (EqPred arg_ty1 arg_ty2)
 683        }
 684 dsHsPred (HsIParam name ty)
 685   = do { arg_ty <- dsHsType ty
 686        ; return (IParam name arg_ty)
 687        }
 688 \end{code}
 689
 690 \begin{code}
 691 addKcTypeCtxt :: LHsType Name -> TcM a -> TcM a
 692         -- Wrap a context around only if we want to show that contexts.
 693 addKcTypeCtxt (L _ (HsPredTy _)) thing = thing
 694         -- Omit invisble ones and ones user's won't grok (HsPred p).
 695 addKcTypeCtxt (L _ other_ty) thing = addErrCtxt (typeCtxt other_ty) thing
 696
 697 typeCtxt :: HsType Name -> SDoc
 698 typeCtxt ty = ptext (sLit "In the type") <+> quotes (ppr ty)
 699 \end{code}
 700
 701 %************************************************************************
 702 %*                                                                      *
 703                 Type-variable binders
 704 %*                                                                      *
 705 %************************************************************************
 706
 707
 708 \begin{code}
 709 kcHsTyVars :: [LHsTyVarBndr Name]
 710            -> ([LHsTyVarBndr Name] -> TcM r)    -- These binders are kind-annotated
 711                                                 -- They scope over the thing inside
 712            -> TcM r
 713 kcHsTyVars tvs thing_inside
 714   = do { kinded_tvs <- mapM (wrapLocM kcHsTyVar) tvs
 715        ; tcExtendKindEnvTvs kinded_tvs thing_inside }
 716
 717 kcHsTyVar :: HsTyVarBndr Name -> TcM (HsTyVarBndr Name)
 718         -- Return a *kind-annotated* binder, and a tyvar with a mutable kind in it
 719 kcHsTyVar (UserTyVar name _)  = UserTyVar name <$> newKindVar
 720 kcHsTyVar tv@(KindedTyVar {}) = return tv
 721
 722 ------------------
 723 tcTyVarBndrs :: [LHsTyVarBndr Name]     -- Kind-annotated binders, which need kind-zonking
 724              -> ([TyVar] -> TcM r)
 725              -> TcM r
 726 -- Used when type-checking types/classes/type-decls
 727 -- Brings into scope immutable TyVars, not mutable ones that require later zonking
 728 tcTyVarBndrs bndrs thing_inside = do
 729     tyvars <- mapM (zonk . unLoc) bndrs
 730     tcExtendTyVarEnv tyvars (thing_inside tyvars)
 731   where
 732     zonk (UserTyVar name kind) = do { kind' <- zonkTcKindToKind kind
 733                                     ; return (mkTyVar name kind') }
 734     zonk (KindedTyVar name kind) = return (mkTyVar name kind)
 735
 736 -----------------------------------
 737 tcDataKindSig :: Maybe Kind -> TcM [TyVar]
 738 -- GADT decls can have a (perhaps partial) kind signature
 739 --      e.g.  data T :: * -> * -> * where ...
 740 -- This function makes up suitable (kinded) type variables for
 741 -- the argument kinds, and checks that the result kind is indeed *.
 742 -- We use it also to make up argument type variables for for data instances.
 743 tcDataKindSig Nothing = return []
 744 tcDataKindSig (Just kind)
 745   = do  { checkTc (isLiftedTypeKind res_kind) (badKindSig kind)
 746         ; span <- getSrcSpanM
 747         ; us   <- newUniqueSupply
 748         ; let uniqs = uniqsFromSupply us
 749         ; return [ mk_tv span uniq str kind
 750                  | ((kind, str), uniq) <- arg_kinds `zip` dnames `zip` uniqs ] }
 751   where
 752     (arg_kinds, res_kind) = splitKindFunTys kind
 753     mk_tv loc uniq str kind = mkTyVar name kind
 754         where
 755            name = mkInternalName uniq occ loc
 756            occ  = mkOccName tvName str
 757
 758     dnames = map ('$' :) names  -- Note [Avoid name clashes for associated data types]
 759
 760     names :: [String]
 761     names = [ c:cs | cs <- "" : names, c <- ['a'..'z'] ]
 762
 763 badKindSig :: Kind -> SDoc
 764 badKindSig kind
 765  = hang (ptext (sLit "Kind signature on data type declaration has non-* return kind"))
 766         2 (ppr kind)
 767 \end{code}
 768
 769 Note [Avoid name clashes for associated data types]
 770 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 771 Consider    class C a b where
 772                data D b :: * -> *
 773 When typechecking the decl for D, we'll invent an extra type variable for D,
 774 to fill out its kind.  We *don't* want this type variable to be 'a', because
 775 in an .hi file we'd get
 776             class C a b where
 777                data D b a
 778 which makes it look as if there are *two* type indices.  But there aren't!
 779 So we use $a instead, which cannot clash with a user-written type variable.
 780 Remember that type variable binders in interface files are just FastStrings,
 781 not proper Names.
 782
 783 (The tidying phase can't help here because we don't tidy TyCons.  Another
 784 alternative would be to record the number of indexing parameters in the
 785 interface file.)
 786
 787
 788 %************************************************************************
 789 %*                                                                      *
 790                 Scoped type variables
 791 %*                                                                      *
 792 %************************************************************************
 793
 794
 795 tcAddScopedTyVars is used for scoped type variables added by pattern
 796 type signatures
 797         e.g.  \ ((x::a), (y::a)) -> x+y
 798 They never have explicit kinds (because this is source-code only)
 799 They are mutable (because they can get bound to a more specific type).
 800
 801 Usually we kind-infer and expand type splices, and then
 802 tupecheck/desugar the type.  That doesn't work well for scoped type
 803 variables, because they scope left-right in patterns.  (e.g. in the
 804 example above, the 'a' in (y::a) is bound by the 'a' in (x::a).
 805
 806 The current not-very-good plan is to
 807   * find all the types in the patterns
 808   * find their free tyvars
 809   * do kind inference
 810   * bring the kinded type vars into scope
 811   * BUT throw away the kind-checked type
 812         (we'll kind-check it again when we type-check the pattern)
 813
 814 This is bad because throwing away the kind checked type throws away
 815 its splices.  But too bad for now.  [July 03]
 816
 817 Historical note:
 818     We no longer specify that these type variables must be univerally
 819     quantified (lots of email on the subject).  If you want to put that
 820     back in, you need to
 821         a) Do a checkSigTyVars after thing_inside
 822         b) More insidiously, don't pass in expected_ty, else
 823            we unify with it too early and checkSigTyVars barfs
 824            Instead you have to pass in a fresh ty var, and unify
 825            it with expected_ty afterwards
 826
 827 \begin{code}
 828 tcHsPatSigType :: UserTypeCtxt
 829                -> LHsType Name          -- The type signature
 830                -> TcM ([TyVar],         -- Newly in-scope type variables
 831                         Type)           -- The signature
 832 -- Used for type-checking type signatures in
 833 -- (a) patterns           e.g  f (x::Int) = e
 834 -- (b) result signatures  e.g. g x :: Int = e
 835 -- (c) RULE forall bndrs  e.g. forall (x::Int). f x = x
 836
 837 tcHsPatSigType ctxt hs_ty
 838   = addErrCtxt (pprHsSigCtxt ctxt hs_ty) $
 839     do  {       -- Find the type variables that are mentioned in the type
 840                 -- but not already in scope.  These are the ones that
 841                 -- should be bound by the pattern signature
 842           in_scope <- getInLocalScope
 843         ; let span = getLoc hs_ty
 844               sig_tvs = userHsTyVarBndrs $ map (L span) $
 845                         filterOut in_scope $
 846                         nameSetToList (extractHsTyVars hs_ty)
 847
 848         ; (tyvars, sig_ty) <- tcHsQuantifiedType sig_tvs hs_ty
 849         ; checkValidType ctxt sig_ty
 850         ; return (tyvars, sig_ty)
 851       }
 852
 853 tcPatSig :: UserTypeCtxt
 854          -> LHsType Name
 855          -> TcSigmaType
 856          -> TcM (TcType,           -- The type to use for "inside" the signature
 857                  [(Name, TcType)], -- The new bit of type environment, binding
 858                                    -- the scoped type variables
 859                  HsWrapper)        -- Coercion due to unification with actual ty
 860                                    -- Of shape:  res_ty ~ sig_ty
 861 tcPatSig ctxt sig res_ty
 862   = do  { (sig_tvs, sig_ty) <- tcHsPatSigType ctxt sig
 863         -- sig_tvs are the type variables free in 'sig',
 864         -- and not already in scope. These are the ones
 865         -- that should be brought into scope
 866
 867         ; if null sig_tvs then do {
 868                 -- The type signature binds no type variables,
 869                 -- and hence is rigid, so use it to zap the res_ty
 870                   wrap <- tcSubType PatSigOrigin ctxt res_ty sig_ty
 871                 ; return (sig_ty, [], wrap)
 872         } else do {
 873                 -- Type signature binds at least one scoped type variable
 874
 875                 -- A pattern binding cannot bind scoped type variables
 876                 -- The renamer fails with a name-out-of-scope error
 877                 -- if a pattern binding tries to bind a type variable,
 878                 -- So we just have an ASSERT here
 879         ; let in_pat_bind = case ctxt of
 880                                 BindPatSigCtxt -> True
 881                                 _              -> False
 882         ; ASSERT( not in_pat_bind || null sig_tvs ) return ()
 883
 884                 -- Check that all newly-in-scope tyvars are in fact
 885                 -- constrained by the pattern.  This catches tiresome
 886                 -- cases like
 887                 --      type T a = Int
 888                 --      f :: Int -> Int
 889                 --      f (x :: T a) = ...
 890                 -- Here 'a' doesn't get a binding.  Sigh
 891         ; let bad_tvs = filterOut (`elemVarSet` exactTyVarsOfType sig_ty) sig_tvs
 892         ; checkTc (null bad_tvs) (badPatSigTvs sig_ty bad_tvs)
 893
 894         -- Now do a subsumption check of the pattern signature against res_ty
 895         ; sig_tvs' <- tcInstSigTyVars sig_tvs
 896         ; let sig_ty' = substTyWith sig_tvs sig_tv_tys' sig_ty
 897               sig_tv_tys' = mkTyVarTys sig_tvs'
 898         ; wrap <- tcSubType PatSigOrigin ctxt res_ty sig_ty'
 899
 900         -- Check that each is bound to a distinct type variable,
 901         -- and one that is not already in scope
 902         ; binds_in_scope <- getScopedTyVarBinds
 903         ; let tv_binds = map tyVarName sig_tvs `zip` sig_tv_tys'
 904         ; check binds_in_scope tv_binds
 905
 906         -- Phew!
 907         ; return (sig_ty', tv_binds, wrap)
 908         } }
 909   where
 910     check _ [] = return ()
 911     check in_scope ((n,ty):rest) = do { check_one in_scope n ty
 912                                       ; check ((n,ty):in_scope) rest }
 913
 914     check_one in_scope n ty
 915         = checkTc (null dups) (dupInScope n (head dups) ty)
 916                 -- Must not bind to the same type variable
 917                 -- as some other in-scope type variable
 918         where
 919           dups = [n' | (n',ty') <- in_scope, eqType ty' ty]
 920 \end{code}
 921
 922
 923 %************************************************************************
 924 %*                                                                      *
 925         Checking kinds
 926 %*                                                                      *
 927 %************************************************************************
 928
 929 We would like to get a decent error message from
 930   (a) Under-applied type constructors
 931              f :: (Maybe, Maybe)
 932   (b) Over-applied type constructors
 933              f :: Int x -> Int x
 934
 935 \begin{code}
 936 -- The ExpKind datatype means "expected kind" and contains
 937 -- some info about just why that kind is expected, to improve
 938 -- the error message on a mis-match
 939 data ExpKind = EK TcKind EkCtxt
 940 data EkCtxt  = EkUnk            -- Unknown context
 941              | EkEqPred         -- Second argument of an equality predicate
 942              | EkKindSig        -- Kind signature
 943              | EkArg SDoc Int   -- Function, arg posn, expected kind
 944
 945
 946 ekLifted, ekOpen :: ExpKind
 947 ekLifted = EK liftedTypeKind EkUnk
 948 ekOpen   = EK openTypeKind   EkUnk
 949
 950 checkExpectedKind :: Outputable a => a -> TcKind -> ExpKind -> TcM ()
 951 -- A fancy wrapper for 'unifyKind', which tries
 952 -- to give decent error messages.
 953 --      (checkExpectedKind ty act_kind exp_kind)
 954 -- checks that the actual kind act_kind is compatible
 955 --      with the expected kind exp_kind
 956 -- The first argument, ty, is used only in the error message generation
 957 checkExpectedKind ty act_kind (EK exp_kind ek_ctxt)
 958   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
 959   = return ()
 960   | otherwise = do
 961     (_errs, mb_r) <- tryTc (unifyKind exp_kind act_kind)
 962     case mb_r of
 963         Just _  -> return ()  -- Unification succeeded
 964         Nothing -> do
 965
 966         -- So there's definitely an error
 967         -- Now to find out what sort
 968            exp_kind <- zonkTcKind exp_kind
 969            act_kind <- zonkTcKind act_kind
 970
 971            env0 <- tcInitTidyEnv
 972            let (exp_as, _) = splitKindFunTys exp_kind
 973                (act_as, _) = splitKindFunTys act_kind
 974                n_exp_as = length exp_as
 975                n_act_as = length act_as
 976
 977                (env1, tidy_exp_kind) = tidyKind env0 exp_kind
 978                (env2, tidy_act_kind) = tidyKind env1 act_kind
 979
 980                err | n_exp_as < n_act_as     -- E.g. [Maybe]
 981                    = quotes (ppr ty) <+> ptext (sLit "is not applied to enough type arguments")
 982
 983                      -- Now n_exp_as >= n_act_as. In the next two cases,
 984                      -- n_exp_as == 0, and hence so is n_act_as
 985                    | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
 986                    = ptext (sLit "Expecting a lifted type, but") <+> quotes (ppr ty)
 987                        <+> ptext (sLit "is unlifted")
 988
 989                    | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
 990                    = ptext (sLit "Expecting an unlifted type, but") <+> quotes (ppr ty)
 991                        <+> ptext (sLit "is lifted")
 992
 993                    | otherwise               -- E.g. Monad [Int]
 994                    = ptext (sLit "Kind mis-match")
 995
 996                more_info = sep [ expected_herald ek_ctxt <+> ptext (sLit "kind")
 997                                     <+> quotes (pprKind tidy_exp_kind) <> comma,
 998                                  ptext (sLit "but") <+> quotes (ppr ty) <+>
 999                                      ptext (sLit "has kind") <+> quotes (pprKind tidy_act_kind)]
1000
1001                expected_herald EkUnk     = ptext (sLit "Expected")
1002                expected_herald EkKindSig = ptext (sLit "An enclosing kind signature specified")
1003                expected_herald EkEqPred  = ptext (sLit "The left argument of the equality predicate had")
1004                expected_herald (EkArg fun arg_no)
1005                  = ptext (sLit "The") <+> speakNth arg_no <+> ptext (sLit "argument of")
1006                    <+> quotes fun <+> ptext (sLit ("should have"))
1007
1008            failWithTcM (env2, err $$ more_info)
1009 \end{code}
1010
1011 %************************************************************************
1012 %*                                                                      *
1013                 Scoped type variables
1014 %*                                                                      *
1015 %************************************************************************
1016
1017 \begin{code}
1018 pprHsSigCtxt :: UserTypeCtxt -> LHsType Name -> SDoc
1019 pprHsSigCtxt ctxt hs_ty = sep [ ptext (sLit "In") <+> pprUserTypeCtxt ctxt <> colon,
1020                                  nest 2 (pp_sig ctxt) ]
1021   where
1022     pp_sig (FunSigCtxt n)  = pp_n_colon n
1023     pp_sig (ConArgCtxt n)  = pp_n_colon n
1024     pp_sig (ForSigCtxt n)  = pp_n_colon n
1025     pp_sig _               = ppr (unLoc hs_ty)
1026
1027     pp_n_colon n = ppr n <+> dcolon <+> ppr (unLoc hs_ty)
1028
1029 badPatSigTvs :: TcType -> [TyVar] -> SDoc
1030 badPatSigTvs sig_ty bad_tvs
1031   = vcat [ fsep [ptext (sLit "The type variable") <> plural bad_tvs,
1032                  quotes (pprWithCommas ppr bad_tvs),
1033                  ptext (sLit "should be bound by the pattern signature") <+> quotes (ppr sig_ty),
1034                  ptext (sLit "but are actually discarded by a type synonym") ]
1035          , ptext (sLit "To fix this, expand the type synonym")
1036          , ptext (sLit "[Note: I hope to lift this restriction in due course]") ]
1037
1038 dupInScope :: Name -> Name -> Type -> SDoc
1039 dupInScope n n' _
1040   = hang (ptext (sLit "The scoped type variables") <+> quotes (ppr n) <+> ptext (sLit "and") <+> quotes (ppr n'))
1041        2 (vcat [ptext (sLit "are bound to the same type (variable)"),
1042                 ptext (sLit "Distinct scoped type variables must be distinct")])
1043
1044 wrongPredErr :: HsPred Name -> TcM (HsType Name, TcKind)
1045 wrongPredErr pred = failWithTc (text "Predicate used as a type:" <+> ppr pred)
1046 \end{code}
1047