fix haddock submodule pointer
[ghc-hetmet.git] / compiler / typecheck / TcInstDcls.lhs
1 %
2 % (c) The University of Glasgow 2006
3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
4 %
5
6 TcInstDecls: Typechecking instance declarations
7
8 \begin{code}
9 module TcInstDcls ( tcInstDecls1, tcInstDecls2 ) where
10
11 import HsSyn
12 import TcBinds
13 import TcTyClsDecls
14 import TcClassDcl
15 import TcPat( addInlinePrags )
16 import TcRnMonad
17 import TcMType
18 import TcType
19 import BuildTyCl
20 import Inst
21 import InstEnv
22 import FamInst
23 import FamInstEnv
24 import TcDeriv
25 import TcEnv
26 import RnSource ( addTcgDUs )
27 import TcHsType
28 import TcUnify
29 import MkCore   ( nO_METHOD_BINDING_ERROR_ID )
30 import Type
31 import Coercion
32 import TyCon
33 import DataCon
34 import Class
35 import Var
36 import Pair
37 import VarSet
38 import CoreUtils  ( mkPiTypes )
39 import CoreUnfold ( mkDFunUnfolding )
40 import CoreSyn    ( Expr(Var), DFunArg(..), CoreExpr )
41 import Id
42 import MkId
43 import Name
44 import NameSet
45 import DynFlags
46 import SrcLoc
47 import Util
48 import Outputable
49 import Bag
50 import BasicTypes
51 import HscTypes
52 import FastString
53 import Maybes   ( orElse )
54 import Data.Maybe
55 import Control.Monad
56 import Data.List
57
58 #include "HsVersions.h"
59 \end{code}
60
61 Typechecking instance declarations is done in two passes. The first
62 pass, made by @tcInstDecls1@, collects information to be used in the
63 second pass.
64
65 This pre-processed info includes the as-yet-unprocessed bindings
66 inside the instance declaration.  These are type-checked in the second
67 pass, when the class-instance envs and GVE contain all the info from
68 all the instance and value decls.  Indeed that's the reason we need
69 two passes over the instance decls.
70
71
72 Note [How instance declarations are translated]
73 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
74 Here is how we translation instance declarations into Core
75
76 Running example:
77         class C a where
78            op1, op2 :: Ix b => a -> b -> b
79            op2 = <dm-rhs>
80
81         instance C a => C [a]
82            {-# INLINE [2] op1 #-}
83            op1 = <rhs>
84 ===>
85         -- Method selectors
86         op1,op2 :: forall a. C a => forall b. Ix b => a -> b -> b
87         op1 = ...
88         op2 = ...
89
90         -- Default methods get the 'self' dictionary as argument
91         -- so they can call other methods at the same type
92         -- Default methods get the same type as their method selector
93         $dmop2 :: forall a. C a => forall b. Ix b => a -> b -> b
94         $dmop2 = /\a. \(d:C a). /\b. \(d2: Ix b). <dm-rhs>
95                -- NB: type variables 'a' and 'b' are *both* in scope in <dm-rhs>
96                -- Note [Tricky type variable scoping]
97
98         -- A top-level definition for each instance method
99         -- Here op1_i, op2_i are the "instance method Ids"
100         -- The INLINE pragma comes from the user pragma
101         {-# INLINE [2] op1_i #-}  -- From the instance decl bindings
102         op1_i, op2_i :: forall a. C a => forall b. Ix b => [a] -> b -> b
103         op1_i = /\a. \(d:C a). 
104                let this :: C [a]
105                    this = df_i a d
106                      -- Note [Subtle interaction of recursion and overlap]
107
108                    local_op1 :: forall b. Ix b => [a] -> b -> b
109                    local_op1 = <rhs>
110                      -- Source code; run the type checker on this
111                      -- NB: Type variable 'a' (but not 'b') is in scope in <rhs>
112                      -- Note [Tricky type variable scoping]
113
114                in local_op1 a d
115
116         op2_i = /\a \d:C a. $dmop2 [a] (df_i a d) 
117
118         -- The dictionary function itself
119         {-# NOINLINE CONLIKE df_i #-}   -- Never inline dictionary functions
120         df_i :: forall a. C a -> C [a]
121         df_i = /\a. \d:C a. MkC (op1_i a d) (op2_i a d)
122                 -- But see Note [Default methods in instances]
123                 -- We can't apply the type checker to the default-method call
124
125         -- Use a RULE to short-circuit applications of the class ops
126         {-# RULE "op1@C[a]" forall a, d:C a. 
127                             op1 [a] (df_i d) = op1_i a d #-}
128
129 Note [Instances and loop breakers]
130 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
131 * Note that df_i may be mutually recursive with both op1_i and op2_i.
132   It's crucial that df_i is not chosen as the loop breaker, even 
133   though op1_i has a (user-specified) INLINE pragma.
134
135 * Instead the idea is to inline df_i into op1_i, which may then select
136   methods from the MkC record, and thereby break the recursion with
137   df_i, leaving a *self*-recurisve op1_i.  (If op1_i doesn't call op at
138   the same type, it won't mention df_i, so there won't be recursion in
139   the first place.)  
140
141 * If op1_i is marked INLINE by the user there's a danger that we won't
142   inline df_i in it, and that in turn means that (since it'll be a
143   loop-breaker because df_i isn't), op1_i will ironically never be 
144   inlined.  But this is OK: the recursion breaking happens by way of
145   a RULE (the magic ClassOp rule above), and RULES work inside InlineRule
146   unfoldings. See Note [RULEs enabled in SimplGently] in SimplUtils
147
148 Note [ClassOp/DFun selection]
149 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
150 One thing we see a lot is stuff like
151     op2 (df d1 d2)
152 where 'op2' is a ClassOp and 'df' is DFun.  Now, we could inline *both*
153 'op2' and 'df' to get
154      case (MkD ($cop1 d1 d2) ($cop2 d1 d2) ... of
155        MkD _ op2 _ _ _ -> op2
156 And that will reduce to ($cop2 d1 d2) which is what we wanted.
157
158 But it's tricky to make this work in practice, because it requires us to 
159 inline both 'op2' and 'df'.  But neither is keen to inline without having
160 seen the other's result; and it's very easy to get code bloat (from the 
161 big intermediate) if you inline a bit too much.
162
163 Instead we use a cunning trick.
164  * We arrange that 'df' and 'op2' NEVER inline.  
165
166  * We arrange that 'df' is ALWAYS defined in the sylised form
167       df d1 d2 = MkD ($cop1 d1 d2) ($cop2 d1 d2) ...
168
169  * We give 'df' a magical unfolding (DFunUnfolding [$cop1, $cop2, ..])
170    that lists its methods.
171
172  * We make CoreUnfold.exprIsConApp_maybe spot a DFunUnfolding and return
173    a suitable constructor application -- inlining df "on the fly" as it 
174    were.
175
176  * We give the ClassOp 'op2' a BuiltinRule that extracts the right piece
177    iff its argument satisfies exprIsConApp_maybe.  This is done in
178    MkId mkDictSelId
179
180  * We make 'df' CONLIKE, so that shared uses stil match; eg
181       let d = df d1 d2
182       in ...(op2 d)...(op1 d)...
183
184 Note [Single-method classes]
185 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
186 If the class has just one method (or, more accurately, just one element
187 of {superclasses + methods}), then we use a different strategy.
188
189    class C a where op :: a -> a
190    instance C a => C [a] where op = <blah>
191
192 We translate the class decl into a newtype, which just gives a
193 top-level axiom. The "constructor" MkC expands to a cast, as does the
194 class-op selector.
195
196    axiom Co:C a :: C a ~ (a->a)
197
198    op :: forall a. C a -> (a -> a)
199    op a d = d |> (Co:C a)
200
201    MkC :: forall a. (a->a) -> C a
202    MkC = /\a.\op. op |> (sym Co:C a)
203
204 The clever RULE stuff doesn't work now, because ($df a d) isn't
205 a constructor application, so exprIsConApp_maybe won't return 
206 Just <blah>.
207
208 Instead, we simply rely on the fact that casts are cheap:
209
210    $df :: forall a. C a => C [a]
211    {-# INLINE df #-}  -- NB: INLINE this
212    $df = /\a. \d. MkC [a] ($cop_list a d)
213        = $cop_list |> forall a. C a -> (sym (Co:C [a]))
214
215    $cop_list :: forall a. C a => [a] -> [a]
216    $cop_list = <blah>
217
218 So if we see
219    (op ($df a d))
220 we'll inline 'op' and '$df', since both are simply casts, and
221 good things happen.
222
223 Why do we use this different strategy?  Because otherwise we
224 end up with non-inlined dictionaries that look like
225     $df = $cop |> blah
226 which adds an extra indirection to every use, which seems stupid.  See
227 Trac #4138 for an example (although the regression reported there
228 wasn't due to the indirction).
229
230 There is an awkward wrinkle though: we want to be very 
231 careful when we have
232     instance C a => C [a] where
233       {-# INLINE op #-}
234       op = ...
235 then we'll get an INLINE pragma on $cop_list but it's important that
236 $cop_list only inlines when it's applied to *two* arguments (the
237 dictionary and the list argument).  So we nust not eta-expand $df
238 above.  We ensure that this doesn't happen by putting an INLINE 
239 pragma on the dfun itself; after all, it ends up being just a cast.
240
241 There is one more dark corner to the INLINE story, even more deeply 
242 buried.  Consider this (Trac #3772):
243
244     class DeepSeq a => C a where
245       gen :: Int -> a
246
247     instance C a => C [a] where
248       gen n = ...
249
250     class DeepSeq a where
251       deepSeq :: a -> b -> b
252
253     instance DeepSeq a => DeepSeq [a] where
254       {-# INLINE deepSeq #-}
255       deepSeq xs b = foldr deepSeq b xs
256
257 That gives rise to these defns:
258
259     $cdeepSeq :: DeepSeq a -> [a] -> b -> b
260     -- User INLINE( 3 args )!
261     $cdeepSeq a (d:DS a) b (x:[a]) (y:b) = ...
262
263     $fDeepSeq[] :: DeepSeq a -> DeepSeq [a]
264     -- DFun (with auto INLINE pragma)
265     $fDeepSeq[] a d = $cdeepSeq a d |> blah
266
267     $cp1 a d :: C a => DeepSep [a]
268     -- We don't want to eta-expand this, lest
269     -- $cdeepSeq gets inlined in it!
270     $cp1 a d = $fDeepSep[] a (scsel a d)
271
272     $fC[] :: C a => C [a]
273     -- Ordinary DFun
274     $fC[] a d = MkC ($cp1 a d) ($cgen a d)
275
276 Here $cp1 is the code that generates the superclass for C [a].  The
277 issue is this: we must not eta-expand $cp1 either, or else $fDeepSeq[]
278 and then $cdeepSeq will inline there, which is definitely wrong.  Like
279 on the dfun, we solve this by adding an INLINE pragma to $cp1.
280
281 Note [Subtle interaction of recursion and overlap]
282 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
283 Consider this
284   class C a where { op1,op2 :: a -> a }
285   instance C a => C [a] where
286     op1 x = op2 x ++ op2 x
287     op2 x = ...
288   instance C [Int] where
289     ...
290
291 When type-checking the C [a] instance, we need a C [a] dictionary (for
292 the call of op2).  If we look up in the instance environment, we find
293 an overlap.  And in *general* the right thing is to complain (see Note
294 [Overlapping instances] in InstEnv).  But in *this* case it's wrong to
295 complain, because we just want to delegate to the op2 of this same
296 instance.  
297
298 Why is this justified?  Because we generate a (C [a]) constraint in 
299 a context in which 'a' cannot be instantiated to anything that matches
300 other overlapping instances, or else we would not be excecuting this
301 version of op1 in the first place.
302
303 It might even be a bit disguised:
304
305   nullFail :: C [a] => [a] -> [a]
306   nullFail x = op2 x ++ op2 x
307
308   instance C a => C [a] where
309     op1 x = nullFail x
310
311 Precisely this is used in package 'regex-base', module Context.hs.
312 See the overlapping instances for RegexContext, and the fact that they
313 call 'nullFail' just like the example above.  The DoCon package also
314 does the same thing; it shows up in module Fraction.hs
315
316 Conclusion: when typechecking the methods in a C [a] instance, we want to
317 treat the 'a' as an *existential* type variable, in the sense described
318 by Note [Binding when looking up instances].  That is why isOverlappableTyVar
319 responds True to an InstSkol, which is the kind of skolem we use in
320 tcInstDecl2.
321
322
323 Note [Tricky type variable scoping]
324 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
325 In our example
326         class C a where
327            op1, op2 :: Ix b => a -> b -> b
328            op2 = <dm-rhs>
329
330         instance C a => C [a]
331            {-# INLINE [2] op1 #-}
332            op1 = <rhs>
333
334 note that 'a' and 'b' are *both* in scope in <dm-rhs>, but only 'a' is
335 in scope in <rhs>.  In particular, we must make sure that 'b' is in
336 scope when typechecking <dm-rhs>.  This is achieved by subFunTys,
337 which brings appropriate tyvars into scope. This happens for both
338 <dm-rhs> and for <rhs>, but that doesn't matter: the *renamer* will have
339 complained if 'b' is mentioned in <rhs>.
340
341
342
343 %************************************************************************
344 %*                                                                      *
345 \subsection{Extracting instance decls}
346 %*                                                                      *
347 %************************************************************************
348
349 Gather up the instance declarations from their various sources
350
351 \begin{code}
352 tcInstDecls1    -- Deal with both source-code and imported instance decls
353    :: [LTyClDecl Name]          -- For deriving stuff
354    -> [LInstDecl Name]          -- Source code instance decls
355    -> [LDerivDecl Name]         -- Source code stand-alone deriving decls
356    -> TcM (TcGblEnv,            -- The full inst env
357            [InstInfo Name],     -- Source-code instance decls to process;
358                                 -- contains all dfuns for this module
359            HsValBinds Name)     -- Supporting bindings for derived instances
360
361 tcInstDecls1 tycl_decls inst_decls deriv_decls
362   = checkNoErrs $
363     do {        -- Stop if addInstInfos etc discovers any errors
364                 -- (they recover, so that we get more than one error each
365                 -- round)
366
367                 -- (1) Do class and family instance declarations
368        ; idx_tycons        <- mapAndRecoverM (tcFamInstDecl TopLevel) $
369                               filter (isFamInstDecl . unLoc) tycl_decls 
370        ; local_info_tycons <- mapAndRecoverM tcLocalInstDecl1  inst_decls
371
372        ; let { (local_info,
373                 at_tycons_s)   = unzip local_info_tycons
374              ; at_idx_tycons   = concat at_tycons_s ++ idx_tycons
375              ; implicit_things = concatMap implicitTyConThings at_idx_tycons
376              ; aux_binds       = mkRecSelBinds at_idx_tycons  }
377
378                 -- (2) Add the tycons of indexed types and their implicit
379                 --     tythings to the global environment
380        ; tcExtendGlobalEnv (map ATyCon at_idx_tycons ++ implicit_things) $ do {
381
382
383                 -- Next, construct the instance environment so far, consisting
384                 -- of
385                 --   (a) local instance decls
386                 --   (b) local family instance decls
387        ; addInsts local_info         $
388          addFamInsts at_idx_tycons   $ do {
389
390                 -- (3) Compute instances from "deriving" clauses;
391                 -- This stuff computes a context for the derived instance
392                 -- decl, so it needs to know about all the instances possible
393                 -- NB: class instance declarations can contain derivings as
394                 --     part of associated data type declarations
395          failIfErrsM    -- If the addInsts stuff gave any errors, don't
396                         -- try the deriving stuff, because that may give
397                         -- more errors still
398        ; (deriv_inst_info, deriv_binds, deriv_dus, deriv_tys, deriv_ty_insts) 
399               <- tcDeriving tycl_decls inst_decls deriv_decls
400
401        -- Extend the global environment also with the generated datatypes for
402        -- the generic representation
403        ; let all_tycons = map ATyCon (deriv_tys ++ deriv_ty_insts)
404        ; gbl_env <- tcExtendGlobalEnv all_tycons $
405                     tcExtendGlobalEnv (concatMap implicitTyThings all_tycons) $
406                     addFamInsts deriv_ty_insts $
407                     addInsts deriv_inst_info getGblEnv
408        ; return ( addTcgDUs gbl_env deriv_dus,
409                   deriv_inst_info ++ local_info,
410                   aux_binds `plusHsValBinds` deriv_binds)
411     }}}
412
413 addInsts :: [InstInfo Name] -> TcM a -> TcM a
414 addInsts infos thing_inside
415   = tcExtendLocalInstEnv (map iSpec infos) thing_inside
416
417 addFamInsts :: [TyCon] -> TcM a -> TcM a
418 addFamInsts tycons thing_inside
419   = tcExtendLocalFamInstEnv (map mkLocalFamInst tycons) thing_inside
420 \end{code}
421
422 \begin{code}
423 tcLocalInstDecl1 :: LInstDecl Name
424                  -> TcM (InstInfo Name, [TyCon])
425         -- A source-file instance declaration
426         -- Type-check all the stuff before the "where"
427         --
428         -- We check for respectable instance type, and context
429 tcLocalInstDecl1 (L loc (InstDecl poly_ty binds uprags ats))
430   = setSrcSpan loc                      $
431     addErrCtxt (instDeclCtxt1 poly_ty)  $
432
433     do  { is_boot <- tcIsHsBoot
434         ; checkTc (not is_boot || (isEmptyLHsBinds binds && null uprags))
435                   badBootDeclErr
436
437         ; (tyvars, theta, clas, inst_tys) <- tcHsInstHead poly_ty
438         ; checkValidInstance poly_ty tyvars theta clas inst_tys
439
440         -- Next, process any associated types.
441         ; idx_tycons <- recoverM (return []) $
442                      do { idx_tycons <- checkNoErrs $ 
443                                         mapAndRecoverM (tcFamInstDecl NotTopLevel) ats
444                         ; checkValidAndMissingATs clas (tyvars, inst_tys)
445                                                   (zip ats idx_tycons)
446                         ; return idx_tycons }
447
448         -- Finally, construct the Core representation of the instance.
449         -- (This no longer includes the associated types.)
450         ; dfun_name <- newDFunName clas inst_tys (getLoc poly_ty)
451                 -- Dfun location is that of instance *header*
452         ; overlap_flag <- getOverlapFlag
453         ; let (eq_theta,dict_theta) = partition isEqPred theta
454               theta'         = eq_theta ++ dict_theta
455               dfun           = mkDictFunId dfun_name tyvars theta' clas inst_tys
456               ispec          = mkLocalInstance dfun overlap_flag
457
458         ; return (InstInfo { iSpec  = ispec, iBinds = VanillaInst binds uprags False },
459                   idx_tycons)
460         }
461   where
462     -- We pass in the source form and the type checked form of the ATs.  We
463     -- really need the source form only to be able to produce more informative
464     -- error messages.
465     checkValidAndMissingATs :: Class
466                             -> ([TyVar], [TcType])     -- instance types
467                             -> [(LTyClDecl Name,       -- source form of AT
468                                  TyCon)]               -- Core form of AT
469                             -> TcM ()
470     checkValidAndMissingATs clas inst_tys ats
471       = do { -- Issue a warning for each class AT that is not defined in this
472              -- instance.
473            ; let class_ats   = map tyConName (classATs clas)
474                  defined_ats = listToNameSet . map (tcdName.unLoc.fst)  $ ats
475                  omitted     = filterOut (`elemNameSet` defined_ats) class_ats
476            ; warn <- doptM Opt_WarnMissingMethods
477            ; mapM_ (warnTc warn . omittedATWarn) omitted
478
479              -- Ensure that all AT indexes that correspond to class parameters
480              -- coincide with the types in the instance head.  All remaining
481              -- AT arguments must be variables.  Also raise an error for any
482              -- type instances that are not associated with this class.
483            ; mapM_ (checkIndexes clas inst_tys) ats
484            }
485
486     checkIndexes clas inst_tys (hsAT, tycon)
487 -- !!!TODO: check that this does the Right Thing for indexed synonyms, too!
488       = checkIndexes' clas inst_tys hsAT
489                       (tyConTyVars tycon,
490                        snd . fromJust . tyConFamInst_maybe $ tycon)
491
492     checkIndexes' clas (instTvs, instTys) hsAT (atTvs, atTys)
493       = let atName = tcdName . unLoc $ hsAT
494         in
495         setSrcSpan (getLoc hsAT)       $
496         addErrCtxt (atInstCtxt atName) $
497         case find ((atName ==) . tyConName) (classATs clas) of
498           Nothing     -> addErrTc $ badATErr clas atName  -- not in this class
499           Just atycon ->
500                 -- The following is tricky!  We need to deal with three
501                 -- complications: (1) The AT possibly only uses a subset of
502                 -- the class parameters as indexes and those it uses may be in
503                 -- a different order; (2) the AT may have extra arguments,
504                 -- which must be type variables; and (3) variables in AT and
505                 -- instance head will be different `Name's even if their
506                 -- source lexemes are identical.
507                 --
508                 -- e.g.    class C a b c where 
509                 --           data D b a :: * -> *           -- NB (1) b a, omits c
510                 --         instance C [x] Bool Char where 
511                 --           data D Bool [x] v = MkD x [v]  -- NB (2) v
512                 --                -- NB (3) the x in 'instance C...' have differnt
513                 --                --        Names to x's in 'data D...'
514                 --
515                 -- Re (1), `poss' contains a permutation vector to extract the
516                 -- class parameters in the right order.
517                 --
518                 -- Re (2), we wrap the (permuted) class parameters in a Maybe
519                 -- type and use Nothing for any extra AT arguments.  (First
520                 -- equation of `checkIndex' below.)
521                 --
522                 -- Re (3), we replace any type variable in the AT parameters
523                 -- that has the same source lexeme as some variable in the
524                 -- instance types with the instance type variable sharing its
525                 -- source lexeme.
526                 --
527                 let poss :: [Int]
528                     -- For *associated* type families, gives the position
529                     -- of that 'TyVar' in the class argument list (0-indexed)
530                     -- e.g.  class C a b c where { type F c a :: *->* }
531                     --       Then we get Just [2,0]
532                     poss = catMaybes [ tv `elemIndex` classTyVars clas 
533                                      | tv <- tyConTyVars atycon]
534                        -- We will get Nothings for the "extra" type 
535                        -- variables in an associated data type
536                        -- e.g. class C a where { data D a :: *->* }
537                        -- here D gets arity 2 and has two tyvars
538
539                     relevantInstTys = map (instTys !!) poss
540                     instArgs        = map Just relevantInstTys ++
541                                       repeat Nothing  -- extra arguments
542                     renaming        = substSameTyVar atTvs instTvs
543                 in
544                 zipWithM_ checkIndex (substTys renaming atTys) instArgs
545
546     checkIndex ty Nothing
547       | isTyVarTy ty         = return ()
548       | otherwise            = addErrTc $ mustBeVarArgErr ty
549     checkIndex ty (Just instTy)
550       | ty `eqType` instTy = return ()
551       | otherwise          = addErrTc $ wrongATArgErr ty instTy
552
553     listToNameSet = addListToNameSet emptyNameSet
554
555     substSameTyVar []       _            = emptyTvSubst
556     substSameTyVar (tv:tvs) replacingTvs =
557       let replacement = case find (tv `sameLexeme`) replacingTvs of
558                         Nothing  -> mkTyVarTy tv
559                         Just rtv -> mkTyVarTy rtv
560           --
561           tv1 `sameLexeme` tv2 =
562             nameOccName (tyVarName tv1) == nameOccName (tyVarName tv2)
563       in
564       TcType.extendTvSubst (substSameTyVar tvs replacingTvs) tv replacement
565 \end{code}
566
567
568 %************************************************************************
569 %*                                                                      *
570                Type checking family instances
571 %*                                                                      *
572 %************************************************************************
573
574 Family instances are somewhat of a hybrid.  They are processed together with
575 class instance heads, but can contain data constructors and hence they share a
576 lot of kinding and type checking code with ordinary algebraic data types (and
577 GADTs).
578
579 \begin{code}
580 tcFamInstDecl :: TopLevelFlag -> LTyClDecl Name -> TcM TyCon
581 tcFamInstDecl top_lvl (L loc decl)
582   =     -- Prime error recovery, set source location
583     setSrcSpan loc                              $
584     tcAddDeclCtxt decl                          $
585     do { -- type family instances require -XTypeFamilies
586          -- and can't (currently) be in an hs-boot file
587        ; type_families <- xoptM Opt_TypeFamilies
588        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
589        ; checkTc type_families $ badFamInstDecl (tcdLName decl)
590        ; checkTc (not is_boot) $ badBootFamInstDeclErr
591
592          -- Perform kind and type checking
593        ; tc <- tcFamInstDecl1 decl
594        ; checkValidTyCon tc     -- Remember to check validity;
595                                 -- no recursion to worry about here
596
597        -- Check that toplevel type instances are not for associated types.
598        ; when (isTopLevel top_lvl && isAssocFamily tc)
599               (addErr $ assocInClassErr (tcdName decl))
600
601        ; return tc }
602
603 isAssocFamily :: TyCon -> Bool  -- Is an assocaited type
604 isAssocFamily tycon
605   = case tyConFamInst_maybe tycon of
606           Nothing       -> panic "isAssocFamily: no family?!?"
607           Just (fam, _) -> isTyConAssoc fam
608
609 assocInClassErr :: Name -> SDoc
610 assocInClassErr name
611  = ptext (sLit "Associated type") <+> quotes (ppr name) <+>
612    ptext (sLit "must be inside a class instance")
613
614
615
616 tcFamInstDecl1 :: TyClDecl Name -> TcM TyCon
617
618   -- "type instance"
619 tcFamInstDecl1 (decl@TySynonym {tcdLName = L loc tc_name})
620   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
621     do { -- check that the family declaration is for a synonym
622          checkTc (isFamilyTyCon family) (notFamily family)
623        ; checkTc (isSynTyCon family) (wrongKindOfFamily family)
624
625        ; -- (1) kind check the right-hand side of the type equation
626        ; k_rhs <- kcCheckLHsType (tcdSynRhs decl) (EK resKind EkUnk)
627                   -- ToDo: the ExpKind could be better
628
629          -- we need the exact same number of type parameters as the family
630          -- declaration 
631        ; let famArity = tyConArity family
632        ; checkTc (length k_typats == famArity) $ 
633            wrongNumberOfParmsErr famArity
634
635          -- (2) type check type equation
636        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
637        ; t_typats <- mapM tcHsKindedType k_typats
638        ; t_rhs    <- tcHsKindedType k_rhs
639
640          -- (3) check the well-formedness of the instance
641        ; checkValidTypeInst t_typats t_rhs
642
643          -- (4) construct representation tycon
644        ; rep_tc_name <- newFamInstTyConName tc_name t_typats loc
645        ; buildSynTyCon rep_tc_name t_tvs (SynonymTyCon t_rhs) 
646                        (typeKind t_rhs) 
647                        NoParentTyCon (Just (family, t_typats))
648        }}
649
650   -- "newtype instance" and "data instance"
651 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
652                              tcdCons = cons})
653   = kcIdxTyPats decl $ \k_tvs k_typats resKind fam_tycon ->
654     do { -- check that the family declaration is for the right kind
655          checkTc (isFamilyTyCon fam_tycon) (notFamily fam_tycon)
656        ; checkTc (isAlgTyCon fam_tycon) (wrongKindOfFamily fam_tycon)
657
658        ; -- (1) kind check the data declaration as usual
659        ; k_decl <- kcDataDecl decl k_tvs
660        ; let k_ctxt = tcdCtxt k_decl
661              k_cons = tcdCons k_decl
662
663          -- result kind must be '*' (otherwise, we have too few patterns)
664        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr (tyConArity fam_tycon)
665
666          -- (2) type check indexed data type declaration
667        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
668
669          -- kind check the type indexes and the context
670        ; t_typats     <- mapM tcHsKindedType k_typats
671        ; stupid_theta <- tcHsKindedContext k_ctxt
672
673          -- (3) Check that
674          --     (a) left-hand side contains no type family applications
675          --         (vanilla synonyms are fine, though, and we checked for
676          --         foralls earlier)
677        ; mapM_ checkTyFamFreeness t_typats
678
679        ; dataDeclChecks tc_name new_or_data stupid_theta k_cons
680
681          -- (4) construct representation tycon
682        ; rep_tc_name <- newFamInstTyConName tc_name t_typats loc
683        ; let ex_ok = True       -- Existentials ok for type families!
684        ; fixM (\ rep_tycon -> do 
685              { let orig_res_ty = mkTyConApp fam_tycon t_typats
686              ; data_cons <- tcConDecls ex_ok rep_tycon
687                                        (t_tvs, orig_res_ty) k_cons
688              ; tc_rhs <-
689                  case new_or_data of
690                    DataType -> return (mkDataTyConRhs data_cons)
691                    NewType  -> ASSERT( not (null data_cons) )
692                                mkNewTyConRhs rep_tc_name rep_tycon (head data_cons)
693              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
694                              h98_syntax NoParentTyCon (Just (fam_tycon, t_typats))
695                  -- We always assume that indexed types are recursive.  Why?
696                  -- (1) Due to their open nature, we can never be sure that a
697                  -- further instance might not introduce a new recursive
698                  -- dependency.  (2) They are always valid loop breakers as
699                  -- they involve a coercion.
700              })
701        }}
702        where
703          h98_syntax = case cons of      -- All constructors have same shape
704                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
705                         _ -> True
706
707 tcFamInstDecl1 d = pprPanic "tcFamInstDecl1" (ppr d)
708
709 -- Kind checking of indexed types
710 -- -
711
712 -- Kind check type patterns and kind annotate the embedded type variables.
713 --
714 -- * Here we check that a type instance matches its kind signature, but we do
715 --   not check whether there is a pattern for each type index; the latter
716 --   check is only required for type synonym instances.
717
718 kcIdxTyPats :: TyClDecl Name
719             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
720                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
721             -> TcM a
722 kcIdxTyPats decl thing_inside
723   = kcHsTyVars (tcdTyVars decl) $ \tvs -> 
724     do { let tc_name = tcdLName decl
725        ; fam_tycon <- tcLookupLocatedTyCon tc_name
726        ; let { (kinds, resKind) = splitKindFunTys (tyConKind fam_tycon)
727              ; hs_typats        = fromJust $ tcdTyPats decl }
728
729          -- we may not have more parameters than the kind indicates
730        ; checkTc (length kinds >= length hs_typats) $
731            tooManyParmsErr (tcdLName decl)
732
733          -- type functions can have a higher-kinded result
734        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
735        ; typats <- zipWithM kcCheckLHsType hs_typats 
736                             [ EK kind (EkArg (ppr tc_name) n) 
737                             | (kind,n) <- kinds `zip` [1..]]
738        ; thing_inside tvs typats resultKind fam_tycon
739        }
740 \end{code}
741
742
743 %************************************************************************
744 %*                                                                      *
745       Type-checking instance declarations, pass 2
746 %*                                                                      *
747 %************************************************************************
748
749 \begin{code}
750 tcInstDecls2 :: [LTyClDecl Name] -> [InstInfo Name]
751              -> TcM (LHsBinds Id)
752 -- (a) From each class declaration,
753 --      generate any default-method bindings
754 -- (b) From each instance decl
755 --      generate the dfun binding
756
757 tcInstDecls2 tycl_decls inst_decls
758   = do  { -- (a) Default methods from class decls
759           let class_decls = filter (isClassDecl . unLoc) tycl_decls
760         ; dm_binds_s <- mapM tcClassDecl2 class_decls
761         ; let dm_binds = unionManyBags dm_binds_s
762                                     
763           -- (b) instance declarations
764         ; let dm_ids = collectHsBindsBinders dm_binds
765               -- Add the default method Ids (again)
766               -- See Note [Default methods and instances]
767         ; inst_binds_s <- tcExtendIdEnv dm_ids $
768                           mapM tcInstDecl2 inst_decls
769
770           -- Done
771         ; return (dm_binds `unionBags` unionManyBags inst_binds_s) }
772 \end{code}
773
774 See Note [Default methods and instances]
775 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
776 The default method Ids are already in the type environment (see Note
777 [Default method Ids and Template Haskell] in TcTyClsDcls), BUT they
778 don't have their InlinePragmas yet.  Usually that would not matter,
779 because the simplifier propagates information from binding site to
780 use.  But, unusually, when compiling instance decls we *copy* the
781 INLINE pragma from the default method to the method for that
782 particular operation (see Note [INLINE and default methods] below).
783
784 So right here in tcInstDecl2 we must re-extend the type envt with
785 the default method Ids replete with their INLINE pragmas.  Urk.
786
787 \begin{code}
788
789 tcInstDecl2 :: InstInfo Name -> TcM (LHsBinds Id)
790             -- Returns a binding for the dfun
791 tcInstDecl2 (InstInfo { iSpec = ispec, iBinds = ibinds })
792   = recoverM (return emptyLHsBinds)             $
793     setSrcSpan loc                              $
794     addErrCtxt (instDeclCtxt2 (idType dfun_id)) $ 
795     do {  -- Instantiate the instance decl with skolem constants
796        ; (inst_tyvars, dfun_theta, inst_head) <- tcSkolDFunType (idType dfun_id)
797                      -- We instantiate the dfun_id with superSkolems.
798                      -- See Note [Subtle interaction of recursion and overlap]
799                      -- and Note [Binding when looking up instances]
800        ; let (clas, inst_tys) = tcSplitDFunHead inst_head
801              (class_tyvars, sc_theta, _, op_items) = classBigSig clas
802              sc_theta' = substTheta (zipOpenTvSubst class_tyvars inst_tys) sc_theta
803              n_ty_args = length inst_tyvars
804              n_silent  = dfunNSilent dfun_id
805              (silent_theta, orig_theta) = splitAt n_silent dfun_theta
806
807        ; silent_ev_vars <- mapM newSilentGiven silent_theta
808        ; orig_ev_vars   <- newEvVars orig_theta
809        ; let dfun_ev_vars = silent_ev_vars ++ orig_ev_vars
810
811        ; (sc_dicts, sc_args)
812              <- mapAndUnzipM (tcSuperClass n_ty_args dfun_ev_vars) sc_theta'
813
814        -- Check that any superclasses gotten from a silent arguemnt
815        -- can be deduced from the originally-specified dfun arguments
816        ; ct_loc <- getCtLoc ScOrigin
817        ; _ <- checkConstraints skol_info inst_tyvars orig_ev_vars $
818               emitFlats $ listToBag $
819               [ mkEvVarX sc ct_loc | sc <- sc_dicts, isSilentEvVar sc ]
820
821        -- Deal with 'SPECIALISE instance' pragmas
822        -- See Note [SPECIALISE instance pragmas]
823        ; spec_info@(spec_inst_prags,_) <- tcSpecInstPrags dfun_id ibinds
824
825         -- Typecheck the methods
826        ; (meth_ids, meth_binds) 
827            <- tcExtendTyVarEnv inst_tyvars $
828                 -- The inst_tyvars scope over the 'where' part
829                 -- Those tyvars are inside the dfun_id's type, which is a bit
830                 -- bizarre, but OK so long as you realise it!
831               tcInstanceMethods dfun_id clas inst_tyvars dfun_ev_vars
832                                 inst_tys spec_info
833                                 op_items ibinds
834
835        -- Create the result bindings
836        ; self_dict <- newEvVar (ClassP clas inst_tys)
837        ; let class_tc      = classTyCon clas
838              [dict_constr] = tyConDataCons class_tc
839              dict_bind     = mkVarBind self_dict dict_rhs
840              dict_rhs      = foldl mk_app inst_constr $
841                              map HsVar sc_dicts ++ map (wrapId arg_wrapper) meth_ids
842              inst_constr   = L loc $ wrapId (mkWpTyApps inst_tys)
843                                             (dataConWrapId dict_constr)
844                      -- We don't produce a binding for the dict_constr; instead we
845                      -- rely on the simplifier to unfold this saturated application
846                      -- We do this rather than generate an HsCon directly, because
847                      -- it means that the special cases (e.g. dictionary with only one
848                      -- member) are dealt with by the common MkId.mkDataConWrapId 
849                      -- code rather than needing to be repeated here.
850
851              mk_app :: LHsExpr Id -> HsExpr Id -> LHsExpr Id
852              mk_app fun arg = L loc (HsApp fun (L loc arg))
853
854              arg_wrapper = mkWpEvVarApps dfun_ev_vars <.> mkWpTyApps (mkTyVarTys inst_tyvars)
855
856                 -- Do not inline the dfun; instead give it a magic DFunFunfolding
857                 -- See Note [ClassOp/DFun selection]
858                 -- See also note [Single-method classes]
859              dfun_id_w_fun
860                 | isNewTyCon class_tc
861                 = dfun_id `setInlinePragma` alwaysInlinePragma { inl_sat = Just 0 }
862                 | otherwise
863                 = dfun_id `setIdUnfolding`  mkDFunUnfolding dfun_ty (sc_args ++ meth_args)
864                           `setInlinePragma` dfunInlinePragma
865              meth_args = map (DFunPolyArg . Var) meth_ids
866
867              main_bind = AbsBinds { abs_tvs = inst_tyvars
868                                   , abs_ev_vars = dfun_ev_vars
869                                   , abs_exports = [(inst_tyvars, dfun_id_w_fun, self_dict,
870                                                     SpecPrags spec_inst_prags)]
871                                   , abs_ev_binds = emptyTcEvBinds
872                                   , abs_binds = unitBag dict_bind }
873
874        ; return (unitBag (L loc main_bind) `unionBags`
875                  listToBag meth_binds)
876        }
877  where
878    skol_info = InstSkol         
879    dfun_ty   = idType dfun_id
880    dfun_id   = instanceDFunId ispec
881    loc       = getSrcSpan dfun_id
882
883 ------------------------------
884 tcSuperClass :: Int -> [EvVar] -> PredType -> TcM (EvVar, DFunArg CoreExpr)
885 -- All superclasses should be either
886 --   (a) be one of the arguments to the dfun, of
887 --   (b) be a constant, soluble at top level
888 tcSuperClass n_ty_args ev_vars pred
889   | Just (ev, i) <- find n_ty_args ev_vars
890   = return (ev, DFunLamArg i)
891   | otherwise
892   = ASSERT2( isEmptyVarSet (tyVarsOfPred pred), ppr pred)       -- Constant!
893     do { sc_dict  <- emitWanted ScOrigin pred
894        ; return (sc_dict, DFunConstArg (Var sc_dict)) }
895   where
896     find _ [] = Nothing
897     find i (ev:evs) | pred `eqPred` evVarPred ev = Just (ev, i)
898                     | otherwise                  = find (i+1) evs
899
900 ------------------------------
901 tcSpecInstPrags :: DFunId -> InstBindings Name
902                 -> TcM ([Located TcSpecPrag], PragFun)
903 tcSpecInstPrags _ (NewTypeDerived {})
904   = return ([], \_ -> [])
905 tcSpecInstPrags dfun_id (VanillaInst binds uprags _)
906   = do { spec_inst_prags <- mapM (wrapLocM (tcSpecInst dfun_id)) $
907                             filter isSpecInstLSig uprags
908              -- The filter removes the pragmas for methods
909        ; return (spec_inst_prags, mkPragFun uprags binds) }
910 \end{code}
911
912 Note [Silent Superclass Arguments]
913 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
914 Consider the following (extreme) situation:
915         class C a => D a where ...
916         instance D [a] => D [a] where ...
917 Although this looks wrong (assume D [a] to prove D [a]), it is only a
918 more extreme case of what happens with recursive dictionaries.
919
920 To implement the dfun we must generate code for the superclass C [a],
921 which we can get by superclass selection from the supplied argument!
922 So we’d generate:
923        dfun :: forall a. D [a] -> D [a]
924        dfun = \d::D [a] -> MkD (scsel d) ..
925
926 However this means that if we later encounter a situation where
927 we have a [Wanted] dw::D [a] we could solve it thus:
928      dw := dfun dw
929 Although recursive, this binding would pass the TcSMonadisGoodRecEv
930 check because it appears as guarded.  But in reality, it will make a
931 bottom superclass. The trouble is that isGoodRecEv can't "see" the
932 superclass-selection inside dfun.
933
934 Our solution to this problem is to change the way ‘dfuns’ are created
935 for instances, so that we pass as first arguments to the dfun some
936 ``silent superclass arguments’’, which are the immediate superclasses
937 of the dictionary we are trying to construct. In our example:
938        dfun :: forall a. (C [a], D [a] -> D [a]
939        dfun = \(dc::C [a]) (dd::D [a]) -> DOrd dc ...
940
941 This gives us:
942
943      -----------------------------------------------------------
944      DFun Superclass Invariant
945      ~~~~~~~~~~~~~~~~~~~~~~~~
946      In the body of a DFun, every superclass argument to the
947      returned dictionary is
948        either   * one of the arguments of the DFun,
949        or       * constant, bound at top level
950      -----------------------------------------------------------
951
952 This means that no superclass is hidden inside a dfun application, so
953 the counting argument in isGoodRecEv (more dfun calls than superclass
954 selections) works correctly.
955
956 The extra arguments required to satisfy the DFun Superclass Invariant
957 always come first, and are called the "silent" arguments.  DFun types
958 are built (only) by MkId.mkDictFunId, so that is where we decide
959 what silent arguments are to be added.
960
961 This net effect is that it is safe to treat a dfun application as
962 wrapping a dictionary constructor around its arguments (in particular,
963 a dfun never picks superclasses from the arguments under the dictionary
964 constructor).
965
966 In our example, if we had  [Wanted] dw :: D [a] we would get via the instance:
967     dw := dfun d1 d2
968     [Wanted] (d1 :: C [a])
969     [Wanted] (d2 :: D [a])
970     [Derived] (d :: D [a])
971     [Derived] (scd :: C [a])   scd  := scsel d
972     [Derived] (scd2 :: C [a])  scd2 := scsel d2
973
974 And now, though we *can* solve: 
975      d2 := dw
976 we will get an isGoodRecEv failure when we try to solve:
977     d1 := scsel d 
978  or
979     d1 := scsel d2 
980
981 Test case SCLoop tests this fix. 
982          
983 Note [SPECIALISE instance pragmas]
984 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
985 Consider
986
987    instance (Ix a, Ix b) => Ix (a,b) where
988      {-# SPECIALISE instance Ix (Int,Int) #-}
989      range (x,y) = ...
990
991 We do *not* want to make a specialised version of the dictionary
992 function.  Rather, we want specialised versions of each method.
993 Thus we should generate something like this:
994
995   $dfIx :: (Ix a, Ix x) => Ix (a,b)
996   {- DFUN [$crange, ...] -}
997   $dfIx da db = Ix ($crange da db) (...other methods...)
998
999   $dfIxPair :: (Ix a, Ix x) => Ix (a,b)
1000   {- DFUN [$crangePair, ...] -}
1001   $dfIxPair = Ix ($crangePair da db) (...other methods...)
1002
1003   $crange :: (Ix a, Ix b) -> ((a,b),(a,b)) -> [(a,b)]
1004   {-# SPECIALISE $crange :: ((Int,Int),(Int,Int)) -> [(Int,Int)] #-}
1005   $crange da db = <blah>
1006
1007   {-# RULE  range ($dfIx da db) = $crange da db #-}
1008
1009 Note that  
1010
1011   * The RULE is unaffected by the specialisation.  We don't want to
1012     specialise $dfIx, because then it would need a specialised RULE
1013     which is a pain.  The single RULE works fine at all specialisations.
1014     See Note [How instance declarations are translated] above
1015
1016   * Instead, we want to specialise the *method*, $crange
1017
1018 In practice, rather than faking up a SPECIALISE pragama for each
1019 method (which is painful, since we'd have to figure out its
1020 specialised type), we call tcSpecPrag *as if* were going to specialise
1021 $dfIx -- you can see that in the call to tcSpecInst.  That generates a
1022 SpecPrag which, as it turns out, can be used unchanged for each method.
1023 The "it turns out" bit is delicate, but it works fine!
1024
1025 \begin{code}
1026 tcSpecInst :: Id -> Sig Name -> TcM TcSpecPrag
1027 tcSpecInst dfun_id prag@(SpecInstSig hs_ty) 
1028   = addErrCtxt (spec_ctxt prag) $
1029     do  { let name = idName dfun_id
1030         ; (tyvars, theta, clas, tys) <- tcHsInstHead hs_ty
1031         ; let (_, spec_dfun_ty) = mkDictFunTy tyvars theta clas tys
1032
1033         ; co_fn <- tcSubType (SpecPragOrigin name) SpecInstCtxt
1034                              (idType dfun_id) spec_dfun_ty
1035         ; return (SpecPrag dfun_id co_fn defaultInlinePragma) }
1036   where
1037     spec_ctxt prag = hang (ptext (sLit "In the SPECIALISE pragma")) 2 (ppr prag)
1038
1039 tcSpecInst _  _ = panic "tcSpecInst"
1040 \end{code}
1041
1042 %************************************************************************
1043 %*                                                                      *
1044       Type-checking an instance method
1045 %*                                                                      *
1046 %************************************************************************
1047
1048 tcInstanceMethod
1049 - Make the method bindings, as a [(NonRec, HsBinds)], one per method
1050 - Remembering to use fresh Name (the instance method Name) as the binder
1051 - Bring the instance method Ids into scope, for the benefit of tcInstSig
1052 - Use sig_fn mapping instance method Name -> instance tyvars
1053 - Ditto prag_fn
1054 - Use tcValBinds to do the checking
1055
1056 \begin{code}
1057 tcInstanceMethods :: DFunId -> Class -> [TcTyVar]
1058                   -> [EvVar]
1059                   -> [TcType]
1060                   -> ([Located TcSpecPrag], PragFun)
1061                   -> [(Id, DefMeth)]
1062                   -> InstBindings Name 
1063                   -> TcM ([Id], [LHsBind Id])
1064         -- The returned inst_meth_ids all have types starting
1065         --      forall tvs. theta => ...
1066 tcInstanceMethods dfun_id clas tyvars dfun_ev_vars inst_tys 
1067                   (spec_inst_prags, prag_fn)
1068                   op_items (VanillaInst binds _ standalone_deriv)
1069   = mapAndUnzipM tc_item op_items
1070   where
1071     ----------------------
1072     tc_item :: (Id, DefMeth) -> TcM (Id, LHsBind Id)
1073     tc_item (sel_id, dm_info)
1074       = case findMethodBind (idName sel_id) binds of
1075             Just user_bind -> tc_body sel_id standalone_deriv user_bind
1076             Nothing        -> tc_default sel_id dm_info
1077
1078     ----------------------
1079     tc_body :: Id -> Bool -> LHsBind Name -> TcM (TcId, LHsBind Id)
1080     tc_body sel_id generated_code rn_bind 
1081       = add_meth_ctxt sel_id generated_code rn_bind $
1082         do { (meth_id, local_meth_id) <- mkMethIds clas tyvars dfun_ev_vars 
1083                                                    inst_tys sel_id
1084            ; let prags = prag_fn (idName sel_id)
1085            ; meth_id1 <- addInlinePrags meth_id prags
1086            ; spec_prags <- tcSpecPrags meth_id1 prags
1087            ; bind <- tcInstanceMethodBody InstSkol
1088                           tyvars dfun_ev_vars
1089                           meth_id1 local_meth_id meth_sig_fn 
1090                           (mk_meth_spec_prags meth_id1 spec_prags)
1091                           rn_bind 
1092            ; return (meth_id1, bind) }
1093
1094     ----------------------
1095     tc_default :: Id -> DefMeth -> TcM (TcId, LHsBind Id)
1096
1097     tc_default sel_id (GenDefMeth dm_name)
1098       = do { meth_bind <- mkGenericDefMethBind clas inst_tys sel_id dm_name
1099            ; tc_body sel_id False {- Not generated code? -} meth_bind }
1100 {-
1101     tc_default sel_id GenDefMeth    -- Derivable type classes stuff
1102       = do { meth_bind <- mkGenericDefMethBind clas inst_tys sel_id
1103            ; tc_body sel_id False {- Not generated code? -} meth_bind }
1104 -}
1105     tc_default sel_id NoDefMeth     -- No default method at all
1106       = do { warnMissingMethod sel_id
1107            ; (meth_id, _) <- mkMethIds clas tyvars dfun_ev_vars 
1108                                          inst_tys sel_id
1109            ; return (meth_id, mkVarBind meth_id $ 
1110                               mkLHsWrap lam_wrapper error_rhs) }
1111       where
1112         error_rhs    = L loc $ HsApp error_fun error_msg
1113         error_fun    = L loc $ wrapId (WpTyApp meth_tau) nO_METHOD_BINDING_ERROR_ID
1114         error_msg    = L loc (HsLit (HsStringPrim (mkFastString error_string)))
1115         meth_tau     = funResultTy (applyTys (idType sel_id) inst_tys)
1116         error_string = showSDoc (hcat [ppr loc, text "|", ppr sel_id ])
1117         lam_wrapper  = mkWpTyLams tyvars <.> mkWpLams dfun_ev_vars
1118
1119     tc_default sel_id (DefMeth dm_name) -- A polymorphic default method
1120       = do {   -- Build the typechecked version directly, 
1121                  -- without calling typecheck_method; 
1122                  -- see Note [Default methods in instances]
1123                  -- Generate   /\as.\ds. let self = df as ds
1124                  --                      in $dm inst_tys self
1125                  -- The 'let' is necessary only because HsSyn doesn't allow
1126                  -- you to apply a function to a dictionary *expression*.
1127
1128            ; self_dict <- newEvVar (ClassP clas inst_tys)
1129            ; let self_ev_bind = EvBind self_dict $
1130                                 EvDFunApp dfun_id (mkTyVarTys tyvars) dfun_ev_vars
1131
1132            ; (meth_id, local_meth_id) <- mkMethIds clas tyvars dfun_ev_vars 
1133                                                    inst_tys sel_id
1134            ; dm_id <- tcLookupId dm_name
1135            ; let dm_inline_prag = idInlinePragma dm_id
1136                  rhs = HsWrap (mkWpEvVarApps [self_dict] <.> mkWpTyApps inst_tys) $
1137                          HsVar dm_id 
1138
1139                  meth_bind = L loc $ VarBind { var_id = local_meth_id
1140                                              , var_rhs = L loc rhs 
1141                                              , var_inline = False }
1142                  meth_id1 = meth_id `setInlinePragma` dm_inline_prag
1143                             -- Copy the inline pragma (if any) from the default
1144                             -- method to this version. Note [INLINE and default methods]
1145                             
1146                  bind = AbsBinds { abs_tvs = tyvars, abs_ev_vars =  dfun_ev_vars
1147                                  , abs_exports = [( tyvars, meth_id1, local_meth_id
1148                                                   , mk_meth_spec_prags meth_id1 [])]
1149                                  , abs_ev_binds = EvBinds (unitBag self_ev_bind)
1150                                  , abs_binds    = unitBag meth_bind }
1151              -- Default methods in an instance declaration can't have their own 
1152              -- INLINE or SPECIALISE pragmas. It'd be possible to allow them, but
1153              -- currently they are rejected with 
1154              --           "INLINE pragma lacks an accompanying binding"
1155
1156            ; return (meth_id1, L loc bind) } 
1157
1158     ----------------------
1159     mk_meth_spec_prags :: Id -> [LTcSpecPrag] -> TcSpecPrags
1160         -- Adapt the SPECIALISE pragmas to work for this method Id
1161         -- There are two sources: 
1162         --   * spec_inst_prags: {-# SPECIALISE instance :: <blah> #-}
1163         --     These ones have the dfun inside, but [perhaps surprisingly] 
1164         --     the correct wrapper
1165         --   * spec_prags_for_me: {-# SPECIALISE op :: <blah> #-}
1166     mk_meth_spec_prags meth_id spec_prags_for_me
1167       = SpecPrags (spec_prags_for_me ++ 
1168                    [ L loc (SpecPrag meth_id wrap inl)
1169                    | L loc (SpecPrag _ wrap inl) <- spec_inst_prags])
1170    
1171     loc = getSrcSpan dfun_id
1172     meth_sig_fn _ = Just ([],loc)       -- The 'Just' says "yes, there's a type sig"
1173         -- But there are no scoped type variables from local_method_id
1174         -- Only the ones from the instance decl itself, which are already
1175         -- in scope.  Example:
1176         --      class C a where { op :: forall b. Eq b => ... }
1177         --      instance C [c] where { op = <rhs> }
1178         -- In <rhs>, 'c' is scope but 'b' is not!
1179
1180         -- For instance decls that come from standalone deriving clauses
1181         -- we want to print out the full source code if there's an error
1182         -- because otherwise the user won't see the code at all
1183     add_meth_ctxt sel_id generated_code rn_bind thing 
1184       | generated_code = addLandmarkErrCtxt (derivBindCtxt sel_id clas inst_tys rn_bind) thing
1185       | otherwise      = thing
1186
1187
1188 tcInstanceMethods dfun_id clas tyvars dfun_ev_vars inst_tys 
1189                   _ op_items (NewTypeDerived coi _)
1190
1191 -- Running example:
1192 --   class Show b => Foo a b where
1193 --     op :: a -> b -> b
1194 --   newtype N a = MkN (Tree [a]) 
1195 --   deriving instance (Show p, Foo Int p) => Foo Int (N p)
1196 --               -- NB: standalone deriving clause means
1197 --               --     that the contex is user-specified
1198 -- Hence op :: forall a b. Foo a b => a -> b -> b
1199 --
1200 -- We're going to make an instance like
1201 --   instance (Show p, Foo Int p) => Foo Int (N p)
1202 --      op = $copT
1203 --
1204 --   $copT :: forall p. (Show p, Foo Int p) => Int -> N p -> N p
1205 --   $copT p (d1:Show p) (d2:Foo Int p) 
1206 --     = op Int (Tree [p]) rep_d |> op_co
1207 --     where 
1208 --       rep_d :: Foo Int (Tree [p]) = ...d1...d2...
1209 --       op_co :: (Int -> Tree [p] -> Tree [p]) ~ (Int -> T p -> T p)
1210 -- We get op_co by substituting [Int/a] and [co/b] in type for op
1211 -- where co : [p] ~ T p
1212 --
1213 -- Notice that the dictionary bindings "..d1..d2.." must be generated
1214 -- by the constraint solver, since the <context> may be
1215 -- user-specified.
1216
1217   = do { rep_d_stuff <- checkConstraints InstSkol tyvars dfun_ev_vars $
1218                         emitWanted ScOrigin rep_pred
1219                          
1220        ; mapAndUnzipM (tc_item rep_d_stuff) op_items }
1221   where
1222      loc = getSrcSpan dfun_id
1223
1224      inst_tvs = fst (tcSplitForAllTys (idType dfun_id))
1225      Just (init_inst_tys, _) = snocView inst_tys
1226      rep_ty   = pFst (coercionKind co)  -- [p]
1227      rep_pred = mkClassPred clas (init_inst_tys ++ [rep_ty])
1228
1229      -- co : [p] ~ T p
1230      co = substCoWithTys inst_tvs (mkTyVarTys tyvars) $
1231           mkSymCo coi
1232
1233      ----------------
1234      tc_item :: (TcEvBinds, EvVar) -> (Id, DefMeth) -> TcM (TcId, LHsBind TcId)
1235      tc_item (rep_ev_binds, rep_d) (sel_id, _)
1236        = do { (meth_id, local_meth_id) <- mkMethIds clas tyvars dfun_ev_vars 
1237                                                     inst_tys sel_id
1238
1239             ; let meth_rhs  = wrapId (mk_op_wrapper sel_id rep_d) sel_id
1240                   meth_bind = VarBind { var_id = local_meth_id
1241                                       , var_rhs = L loc meth_rhs
1242                                       , var_inline = False }
1243
1244                   bind = AbsBinds { abs_tvs = tyvars, abs_ev_vars = dfun_ev_vars
1245                                    , abs_exports = [(tyvars, meth_id, 
1246                                                      local_meth_id, noSpecPrags)]
1247                                    , abs_ev_binds = rep_ev_binds
1248                                    , abs_binds = unitBag $ L loc meth_bind }
1249
1250             ; return (meth_id, L loc bind) }
1251
1252      ----------------
1253      mk_op_wrapper :: Id -> EvVar -> HsWrapper
1254      mk_op_wrapper sel_id rep_d 
1255        = WpCast (liftCoSubstWith sel_tvs (map mkReflCo init_inst_tys ++ [co])
1256                                local_meth_ty)
1257          <.> WpEvApp (EvId rep_d)
1258          <.> mkWpTyApps (init_inst_tys ++ [rep_ty]) 
1259        where
1260          (sel_tvs, sel_rho) = tcSplitForAllTys (idType sel_id)
1261          (_, local_meth_ty) = tcSplitPredFunTy_maybe sel_rho
1262                               `orElse` pprPanic "tcInstanceMethods" (ppr sel_id)
1263
1264 ----------------------
1265 mkMethIds :: Class -> [TcTyVar] -> [EvVar] -> [TcType] -> Id -> TcM (TcId, TcId)
1266 mkMethIds clas tyvars dfun_ev_vars inst_tys sel_id
1267   = do  { uniq <- newUnique
1268         ; let meth_name = mkDerivedInternalName mkClassOpAuxOcc uniq sel_name
1269         ; local_meth_name <- newLocalName sel_name
1270                   -- Base the local_meth_name on the selector name, becuase
1271                   -- type errors from tcInstanceMethodBody come from here
1272
1273         ; let meth_id       = mkLocalId meth_name meth_ty
1274               local_meth_id = mkLocalId local_meth_name local_meth_ty
1275         ; return (meth_id, local_meth_id) }
1276   where
1277     local_meth_ty = instantiateMethod clas sel_id inst_tys
1278     meth_ty = mkForAllTys tyvars $ mkPiTypes dfun_ev_vars local_meth_ty
1279     sel_name = idName sel_id
1280
1281 ----------------------
1282 wrapId :: HsWrapper -> id -> HsExpr id
1283 wrapId wrapper id = mkHsWrap wrapper (HsVar id)
1284
1285 derivBindCtxt :: Id -> Class -> [Type ] -> LHsBind Name -> SDoc
1286 derivBindCtxt sel_id clas tys _bind
1287    = vcat [ ptext (sLit "When typechecking the code for ") <+> quotes (ppr sel_id)
1288           , nest 2 (ptext (sLit "in a standalone derived instance for")
1289                     <+> quotes (pprClassPred clas tys) <> colon)
1290           , nest 2 $ ptext (sLit "To see the code I am typechecking, use -ddump-deriv") ]
1291
1292 -- Too voluminous
1293 --        , nest 2 $ pprSetDepth AllTheWay $ ppr bind ]
1294
1295 warnMissingMethod :: Id -> TcM ()
1296 warnMissingMethod sel_id
1297   = do { warn <- doptM Opt_WarnMissingMethods           
1298        ; warnTc (warn  -- Warn only if -fwarn-missing-methods
1299                  && not (startsWithUnderscore (getOccName sel_id)))
1300                                         -- Don't warn about _foo methods
1301                 (ptext (sLit "No explicit method nor default method for")
1302                  <+> quotes (ppr sel_id)) }
1303 \end{code}
1304
1305 Note [Export helper functions]
1306 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1307 We arrange to export the "helper functions" of an instance declaration,
1308 so that they are not subject to preInlineUnconditionally, even if their
1309 RHS is trivial.  Reason: they are mentioned in the DFunUnfolding of
1310 the dict fun as Ids, not as CoreExprs, so we can't substitute a 
1311 non-variable for them.
1312
1313 We could change this by making DFunUnfoldings have CoreExprs, but it
1314 seems a bit simpler this way.
1315
1316 Note [Default methods in instances]
1317 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1318 Consider this
1319
1320    class Baz v x where
1321       foo :: x -> x
1322       foo y = <blah>
1323
1324    instance Baz Int Int
1325
1326 From the class decl we get
1327
1328    $dmfoo :: forall v x. Baz v x => x -> x
1329    $dmfoo y = <blah>
1330
1331 Notice that the type is ambiguous.  That's fine, though. The instance
1332 decl generates
1333
1334    $dBazIntInt = MkBaz fooIntInt
1335    fooIntInt = $dmfoo Int Int $dBazIntInt
1336
1337 BUT this does mean we must generate the dictionary translation of
1338 fooIntInt directly, rather than generating source-code and
1339 type-checking it.  That was the bug in Trac #1061. In any case it's
1340 less work to generate the translated version!
1341
1342 Note [INLINE and default methods]
1343 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1344 Default methods need special case.  They are supposed to behave rather like
1345 macros.  For exmample
1346
1347   class Foo a where
1348     op1, op2 :: Bool -> a -> a
1349
1350     {-# INLINE op1 #-}
1351     op1 b x = op2 (not b) x
1352
1353   instance Foo Int where
1354     -- op1 via default method
1355     op2 b x = <blah>
1356    
1357 The instance declaration should behave
1358
1359    just as if 'op1' had been defined with the
1360    code, and INLINE pragma, from its original
1361    definition. 
1362
1363 That is, just as if you'd written
1364
1365   instance Foo Int where
1366     op2 b x = <blah>
1367
1368     {-# INLINE op1 #-}
1369     op1 b x = op2 (not b) x
1370
1371 So for the above example we generate:
1372
1373
1374   {-# INLINE $dmop1 #-}
1375   -- $dmop1 has an InlineCompulsory unfolding
1376   $dmop1 d b x = op2 d (not b) x
1377
1378   $fFooInt = MkD $cop1 $cop2
1379
1380   {-# INLINE $cop1 #-}
1381   $cop1 = $dmop1 $fFooInt
1382
1383   $cop2 = <blah>
1384
1385 Note carefullly:
1386
1387 * We *copy* any INLINE pragma from the default method $dmop1 to the
1388   instance $cop1.  Otherwise we'll just inline the former in the
1389   latter and stop, which isn't what the user expected
1390
1391 * Regardless of its pragma, we give the default method an 
1392   unfolding with an InlineCompulsory source. That means
1393   that it'll be inlined at every use site, notably in
1394   each instance declaration, such as $cop1.  This inlining
1395   must happen even though 
1396     a) $dmop1 is not saturated in $cop1
1397     b) $cop1 itself has an INLINE pragma
1398
1399   It's vital that $dmop1 *is* inlined in this way, to allow the mutual
1400   recursion between $fooInt and $cop1 to be broken
1401
1402 * To communicate the need for an InlineCompulsory to the desugarer
1403   (which makes the Unfoldings), we use the IsDefaultMethod constructor
1404   in TcSpecPrags.
1405
1406
1407 %************************************************************************
1408 %*                                                                      *
1409 \subsection{Error messages}
1410 %*                                                                      *
1411 %************************************************************************
1412
1413 \begin{code}
1414 instDeclCtxt1 :: LHsType Name -> SDoc
1415 instDeclCtxt1 hs_inst_ty
1416   = inst_decl_ctxt (case unLoc hs_inst_ty of
1417                         HsForAllTy _ _ _ (L _ (HsPredTy pred)) -> ppr pred
1418                         HsPredTy pred                    -> ppr pred
1419                         _                                -> ppr hs_inst_ty)     -- Don't expect this
1420 instDeclCtxt2 :: Type -> SDoc
1421 instDeclCtxt2 dfun_ty
1422   = inst_decl_ctxt (ppr (mkClassPred cls tys))
1423   where
1424     (_,_,cls,tys) = tcSplitDFunTy dfun_ty
1425
1426 inst_decl_ctxt :: SDoc -> SDoc
1427 inst_decl_ctxt doc = ptext (sLit "In the instance declaration for") <+> quotes doc
1428
1429 atInstCtxt :: Name -> SDoc
1430 atInstCtxt name = ptext (sLit "In the associated type instance for") <+>
1431                   quotes (ppr name)
1432
1433 mustBeVarArgErr :: Type -> SDoc
1434 mustBeVarArgErr ty =
1435   sep [ ptext (sLit "Arguments that do not correspond to a class parameter") <+>
1436         ptext (sLit "must be variables")
1437       , ptext (sLit "Instead of a variable, found") <+> ppr ty
1438       ]
1439
1440 wrongATArgErr :: Type -> Type -> SDoc
1441 wrongATArgErr ty instTy =
1442   sep [ ptext (sLit "Type indexes must match class instance head")
1443       , ptext (sLit "Found") <+> quotes (ppr ty)
1444         <+> ptext (sLit "but expected") <+> quotes (ppr instTy)
1445       ]
1446
1447 tooManyParmsErr :: Located Name -> SDoc
1448 tooManyParmsErr tc_name
1449   = ptext (sLit "Family instance has too many parameters:") <+> 
1450     quotes (ppr tc_name)
1451
1452 tooFewParmsErr :: Arity -> SDoc
1453 tooFewParmsErr arity
1454   = ptext (sLit "Family instance has too few parameters; expected") <+> 
1455     ppr arity
1456
1457 wrongNumberOfParmsErr :: Arity -> SDoc
1458 wrongNumberOfParmsErr exp_arity
1459   = ptext (sLit "Number of parameters must match family declaration; expected")
1460     <+> ppr exp_arity
1461
1462 badBootFamInstDeclErr :: SDoc
1463 badBootFamInstDeclErr
1464   = ptext (sLit "Illegal family instance in hs-boot file")
1465
1466 notFamily :: TyCon -> SDoc
1467 notFamily tycon
1468   = vcat [ ptext (sLit "Illegal family instance for") <+> quotes (ppr tycon)
1469          , nest 2 $ parens (ppr tycon <+> ptext (sLit "is not an indexed type family"))]
1470   
1471 wrongKindOfFamily :: TyCon -> SDoc
1472 wrongKindOfFamily family
1473   = ptext (sLit "Wrong category of family instance; declaration was for a")
1474     <+> kindOfFamily
1475   where
1476     kindOfFamily | isSynTyCon family = ptext (sLit "type synonym")
1477                  | isAlgTyCon family = ptext (sLit "data type")
1478                  | otherwise = pprPanic "wrongKindOfFamily" (ppr family)
1479 \end{code}