compiler/typecheck/TcMType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 Monadic type operations
   7
   8 This module contains monadic operations over types that contain
   9 mutable type variables
  10
  11 \begin{code}
  12 module TcMType (
  13   TcTyVar, TcKind, TcType, TcTauType, TcThetaType, TcTyVarSet,
  14
  15   --------------------------------
  16   -- Creating new mutable type variables
  17   newFlexiTyVar,
  18   newFlexiTyVarTy,              -- Kind -> TcM TcType
  19   newFlexiTyVarTys,             -- Int -> Kind -> TcM [TcType]
  20   newKindVar, newKindVars,
  21   lookupTcTyVar, LookupTyVarResult(..),
  22
  23   newMetaTyVar, readMetaTyVar, writeMetaTyVar, isFilledMetaTyVar,
  24
  25   --------------------------------
  26   -- Boxy type variables
  27   newBoxyTyVar, newBoxyTyVars, newBoxyTyVarTys, readFilledBox,
  28
  29   --------------------------------
  30   -- Creating new coercion variables
  31   newCoVars, newMetaCoVar,
  32
  33   --------------------------------
  34   -- Instantiation
  35   tcInstTyVar, tcInstType, tcInstTyVars, tcInstBoxyTyVar,
  36   tcInstSigType,
  37   tcInstSkolTyVars, tcInstSkolType,
  38   tcSkolSigType, tcSkolSigTyVars, occurCheckErr,
  39
  40   --------------------------------
  41   -- Checking type validity
  42   Rank, UserTypeCtxt(..), checkValidType, checkValidMonoType,
  43   SourceTyCtxt(..), checkValidTheta, checkFreeness,
  44   checkValidInstHead, checkValidInstance,
  45   checkInstTermination, checkValidTypeInst, checkTyFamFreeness,
  46   checkUpdateMeta, updateMeta, checkTauTvUpdate, fillBoxWithTau, unifyKindCtxt,
  47   unifyKindMisMatch, validDerivPred, arityErr, notMonoType, notMonoArgs,
  48
  49   --------------------------------
  50   -- Zonking
  51   zonkType, zonkTcPredType,
  52   zonkTcTyVar, zonkTcTyVars, zonkTcTyVarsAndFV, zonkSigTyVar,
  53   zonkQuantifiedTyVar, zonkQuantifiedTyVars,
  54   zonkTcType, zonkTcTypes, zonkTcThetaType,
  55   zonkTcKindToKind, zonkTcKind, zonkTopTyVar,
  56
  57   readKindVar, writeKindVar
  58   ) where
  59
  60 #include "HsVersions.h"
  61
  62 -- friends:
  63 import TypeRep
  64 import TcType
  65 import Type
  66 import Coercion
  67 import Class
  68 import TyCon
  69 import Var
  70
  71 -- others:
  72 import TcRnMonad          -- TcType, amongst others
  73 import FunDeps
  74 import Name
  75 import VarEnv
  76 import VarSet
  77 import ErrUtils
  78 import DynFlags
  79 import Util
  80 import Maybes
  81 import ListSetOps
  82 import UniqSupply
  83 import SrcLoc
  84 import Outputable
  85 import FastString
  86
  87 import Control.Monad
  88 import Data.List        ( (\\) )
  89 \end{code}
  90
  91
  92 %************************************************************************
  93 %*                                                                      *
  94         Instantiation in general
  95 %*                                                                      *
  96 %************************************************************************
  97
  98 \begin{code}
  99 tcInstType :: ([TyVar] -> TcM [TcTyVar])                -- How to instantiate the type variables
 100            -> TcType                                    -- Type to instantiate
 101            -> TcM ([TcTyVar], TcThetaType, TcType)      -- Result
 102                 -- (type vars (excl coercion vars), preds (incl equalities), rho)
 103 tcInstType inst_tyvars ty
 104   = case tcSplitForAllTys ty of
 105         ([],     rho) -> let    -- There may be overloading despite no type variables;
 106                                 --      (?x :: Int) => Int -> Int
 107                            (theta, tau) = tcSplitPhiTy rho
 108                          in
 109                          return ([], theta, tau)
 110
 111         (tyvars, rho) -> do { tyvars' <- inst_tyvars tyvars
 112
 113                             ; let  tenv = zipTopTvSubst tyvars (mkTyVarTys tyvars')
 114                                 -- Either the tyvars are freshly made, by inst_tyvars,
 115                                 -- or (in the call from tcSkolSigType) any nested foralls
 116                                 -- have different binders.  Either way, zipTopTvSubst is ok
 117
 118                             ; let  (theta, tau) = tcSplitPhiTy (substTy tenv rho)
 119                             ; return (tyvars', theta, tau) }
 120 \end{code}
 121
 122
 123 %************************************************************************
 124 %*                                                                      *
 125         Updating tau types
 126 %*                                                                      *
 127 %************************************************************************
 128
 129 Can't be in TcUnify, as we also need it in TcTyFuns.
 130
 131 \begin{code}
 132 type SwapFlag = Bool
 133         -- False <=> the two args are (actual, expected) respectively
 134         -- True  <=> the two args are (expected, actual) respectively
 135
 136 checkUpdateMeta :: SwapFlag
 137                 -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 138 -- Update tv1, which is flexi; occurs check is alrady done
 139 -- The 'check' version does a kind check too
 140 -- We do a sub-kind check here: we might unify (a b) with (c d)
 141 --      where b::*->* and d::*; this should fail
 142
 143 checkUpdateMeta swapped tv1 ref1 ty2
 144   = do  { checkKinds swapped tv1 ty2
 145         ; updateMeta tv1 ref1 ty2 }
 146
 147 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
 148 updateMeta tv1 ref1 ty2
 149   = ASSERT( isMetaTyVar tv1 )
 150     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
 151     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
 152         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
 153         ; writeMutVar ref1 (Indirect ty2)
 154         }
 155
 156 ----------------
 157 checkKinds :: Bool -> TyVar -> Type -> TcM ()
 158 checkKinds swapped tv1 ty2
 159 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
 160 -- ty2 has been zonked at this stage, which ensures that
 161 -- its kind has as much boxity information visible as possible.
 162   | tk2 `isSubKind` tk1 = return ()
 163
 164   | otherwise
 165         -- Either the kinds aren't compatible
 166         --      (can happen if we unify (a b) with (c d))
 167         -- or we are unifying a lifted type variable with an
 168         --      unlifted type: e.g.  (id 3#) is illegal
 169   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
 170     unifyKindMisMatch k1 k2
 171   where
 172     (k1,k2) | swapped   = (tk2,tk1)
 173             | otherwise = (tk1,tk2)
 174     tk1 = tyVarKind tv1
 175     tk2 = typeKind ty2
 176
 177 ----------------
 178 checkTauTvUpdate :: TcTyVar -> TcType -> TcM (Maybe TcType)
 179 --    (checkTauTvUpdate tv ty)
 180 -- We are about to update the TauTv tv with ty.
 181 -- Check (a) that tv doesn't occur in ty (occurs check)
 182 --       (b) that ty is a monotype
 183 -- Furthermore, in the interest of (b), if you find an
 184 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
 185 --
 186 -- We have three possible outcomes:
 187 -- (1) Return the (non-boxy) type to update the type variable with,
 188 --     [we know the update is ok!]
 189 -- (2) return Nothing, or
 190 --     [we cannot tell whether the update is ok right now]
 191 -- (3) fails.
 192 --     [the update is definitely invalid]
 193 -- We return Nothing in case the tv occurs in ty *under* a type family
 194 -- application.  In this case, we must not update tv (to avoid a cyclic type
 195 -- term), but we also cannot fail claiming an infinite type.  Given
 196 --   type family F a
 197 --   type instance F Int = Int
 198 -- consider
 199 --   a ~ F a
 200 -- This is perfectly reasonable, if we later get a ~ Int.
 201
 202 checkTauTvUpdate orig_tv orig_ty
 203   = do { result <- go orig_ty
 204        ; case result of
 205            Right ty    -> return $ Just ty
 206            Left  True  -> return $ Nothing
 207            Left  False -> occurCheckErr (mkTyVarTy orig_tv) orig_ty
 208        }
 209   where
 210     go :: TcType -> TcM (Either Bool TcType)
 211     -- go returns
 212     --   Right ty    if everything is fine
 213     --   Left True   if orig_tv occurs in orig_ty, but under a type family app
 214     --   Left False  if orig_tv occurs in orig_ty (with no type family app)
 215     -- It fails if it encounters a forall type, except as an argument for a
 216     -- closed type synonym that expands to a tau type.
 217     go (TyConApp tc tys)
 218         | isSynTyCon tc  = go_syn tc tys
 219         | otherwise      = do { tys' <- mapM go tys
 220                               ; return $ occurs (TyConApp tc) tys' }
 221     go (PredTy p)             = do { p' <- go_pred p
 222                               ; return $ occurs1 PredTy p' }
 223     go (FunTy arg res)   = do { arg' <- go arg
 224                               ; res' <- go res
 225                               ; return $ occurs2 FunTy arg' res' }
 226     go (AppTy fun arg)   = do { fun' <- go fun
 227                               ; arg' <- go arg
 228                               ; return $ occurs2 mkAppTy fun' arg' }
 229                 -- NB the mkAppTy; we might have instantiated a
 230                 -- type variable to a type constructor, so we need
 231                 -- to pull the TyConApp to the top.
 232     go (ForAllTy _ _) = notMonoType orig_ty             -- (b)
 233
 234     go (TyVarTy tv)
 235         | orig_tv == tv = return $ Left False           -- (a)
 236         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
 237         | otherwise     = return $ Right (TyVarTy tv)
 238                  -- Ordinary (non Tc) tyvars
 239                  -- occur inside quantified types
 240
 241     go_pred (ClassP c tys) = do { tys' <- mapM go tys
 242                                 ; return $ occurs (ClassP c) tys' }
 243     go_pred (IParam n ty)  = do { ty' <- go ty
 244                                 ; return $ occurs1 (IParam n) ty' }
 245     go_pred (EqPred t1 t2) = do { t1' <- go t1
 246                                 ; t2' <- go t2
 247                                 ; return $ occurs2 EqPred t1' t2' }
 248
 249     go_tyvar tv (SkolemTv _) = return $ Right (TyVarTy tv)
 250     go_tyvar tv (MetaTv box ref)
 251         = do { cts <- readMutVar ref
 252              ; case cts of
 253                   Indirect ty -> go ty
 254                   Flexi -> case box of
 255                                 BoxTv -> do { ty <- fillBoxWithTau tv ref
 256                                             ; return $ Right ty }
 257                                 _     -> return $ Right (TyVarTy tv)
 258              }
 259
 260         -- go_syn is called for synonyms only
 261         -- See Note [Type synonyms and the occur check]
 262     go_syn tc tys
 263         | not (isTauTyCon tc)
 264         = notMonoType orig_ty   -- (b) again
 265         | otherwise
 266         = do { (_msgs, mb_tys') <- tryTc (mapM go tys)
 267              ; case mb_tys' of
 268
 269                 -- we had a type error => forall in type parameters
 270                 Nothing
 271                   | isOpenTyCon tc -> notMonoArgs (TyConApp tc tys)
 272                         -- Synonym families must have monotype args
 273                   | otherwise      -> go (expectJust "checkTauTvUpdate(1)"
 274                                             (tcView (TyConApp tc tys)))
 275                         -- Try again, expanding the synonym
 276
 277                 -- no type error, but need to test whether occurs check happend
 278                 Just tys' ->
 279                   case occurs id tys' of
 280                     Left _
 281                       | isOpenTyCon tc -> return $ Left True
 282                         -- Variable occured under type family application
 283                       | otherwise      -> go (expectJust "checkTauTvUpdate(2)"
 284                                                (tcView (TyConApp tc tys)))
 285                         -- Try again, expanding the synonym
 286                     Right raw_tys'     -> return $ Right (TyConApp tc raw_tys')
 287                         -- Retain the synonym (the common case)
 288              }
 289
 290     -- Left results (= occurrence of orig_ty) dominate and
 291     -- (Left False) (= fatal occurrence) dominates over (Left True)
 292     occurs :: ([a] -> b) -> [Either Bool a] -> Either Bool b
 293     occurs c = either Left (Right . c) . foldr combine (Right [])
 294       where
 295         combine (Left famInst1) (Left famInst2) = Left (famInst1 && famInst2)
 296         combine (Right _      ) (Left famInst)  = Left famInst
 297         combine (Left famInst)  (Right _)       = Left famInst
 298         combine (Right arg)     (Right args)    = Right (arg:args)
 299
 300     occurs1 c x   = occurs (\[x']     -> c x')    [x]
 301     occurs2 c x y = occurs (\[x', y'] -> c x' y') [x, y]
 302
 303 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
 304 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
 305 --  tau-type meta-variable, whose print-name is the same as tv
 306 -- Choosing the same name is good: when we instantiate a function
 307 -- we allocate boxy tyvars with the same print-name as the quantified
 308 -- tyvar; and then we often fill the box with a tau-tyvar, and again
 309 -- we want to choose the same name.
 310 fillBoxWithTau tv ref
 311   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
 312         ; let tau = mkTyVarTy tv'       -- name of the type variable
 313         ; writeMutVar ref (Indirect tau)
 314         ; return tau }
 315 \end{code}
 316
 317 Note [Type synonyms and the occur check]
 318 ~~~~~~~~~~~~~~~~~~~~
 319 Basically we want to update     tv1 := ps_ty2
 320 because ps_ty2 has type-synonym info, which improves later error messages
 321
 322 But consider
 323         type A a = ()
 324
 325         f :: (A a -> a -> ()) -> ()
 326         f = \ _ -> ()
 327
 328         x :: ()
 329         x = f (\ x p -> p x)
 330
 331 In the application (p x), we try to match "t" with "A t".  If we go
 332 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
 333 an infinite loop later.
 334 But we should not reject the program, because A t = ().
 335 Rather, we should bind t to () (= non_var_ty2).
 336
 337 --------------
 338
 339 Error mesages in case of kind mismatch.
 340
 341 \begin{code}
 342 unifyKindMisMatch :: TcKind -> TcKind -> TcM ()
 343 unifyKindMisMatch ty1 ty2 = do
 344     ty1' <- zonkTcKind ty1
 345     ty2' <- zonkTcKind ty2
 346     let
 347         msg = hang (ptext (sLit "Couldn't match kind"))
 348                    2 (sep [quotes (ppr ty1'),
 349                            ptext (sLit "against"),
 350                            quotes (ppr ty2')])
 351     failWithTc msg
 352
 353 unifyKindCtxt :: Bool -> TyVar -> Type -> TidyEnv -> TcM (TidyEnv, SDoc)
 354 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
 355         -- tv1 and ty2 are zonked already
 356   = return msg
 357   where
 358     msg = (env2, ptext (sLit "When matching the kinds of") <+>
 359                  sep [quotes pp_expected <+> ptext (sLit "and"), quotes pp_actual])
 360
 361     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
 362                              | otherwise = (pp1, pp2)
 363     (env1, tv1') = tidyOpenTyVar tidy_env tv1
 364     (env2, ty2') = tidyOpenType  env1 ty2
 365     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
 366     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
 367 \end{code}
 368
 369 Error message for failure due to an occurs check.
 370
 371 \begin{code}
 372 occurCheckErr :: TcType -> TcType -> TcM a
 373 occurCheckErr ty containingTy
 374   = do  { env0 <- tcInitTidyEnv
 375         ; ty'           <- zonkTcType ty
 376         ; containingTy' <- zonkTcType containingTy
 377         ; let (env1, tidy_ty1) = tidyOpenType env0 ty'
 378               (env2, tidy_ty2) = tidyOpenType env1 containingTy'
 379               extra = sep [ppr tidy_ty1, char '=', ppr tidy_ty2]
 380         ; failWithTcM (env2, hang msg 2 extra) }
 381   where
 382     msg = ptext (sLit "Occurs check: cannot construct the infinite type:")
 383 \end{code}
 384
 385 %************************************************************************
 386 %*                                                                      *
 387         Kind variables
 388 %*                                                                      *
 389 %************************************************************************
 390
 391 \begin{code}
 392 newCoVars :: [(TcType,TcType)] -> TcM [CoVar]
 393 newCoVars spec
 394   = do  { us <- newUniqueSupply
 395         ; return [ mkCoVar (mkSysTvName uniq (fsLit "co"))
 396                            (mkCoKind ty1 ty2)
 397                  | ((ty1,ty2), uniq) <- spec `zip` uniqsFromSupply us] }
 398
 399 newMetaCoVar :: TcType -> TcType -> TcM TcTyVar
 400 newMetaCoVar ty1 ty2 = newMetaTyVar TauTv (mkCoKind ty1 ty2)
 401
 402 newKindVar :: TcM TcKind
 403 newKindVar = do { uniq <- newUnique
 404                 ; ref <- newMutVar Flexi
 405                 ; return (mkTyVarTy (mkKindVar uniq ref)) }
 406
 407 newKindVars :: Int -> TcM [TcKind]
 408 newKindVars n = mapM (\ _ -> newKindVar) (nOfThem n ())
 409 \end{code}
 410
 411
 412 %************************************************************************
 413 %*                                                                      *
 414         SkolemTvs (immutable)
 415 %*                                                                      *
 416 %************************************************************************
 417
 418 \begin{code}
 419 mkSkolTyVar :: Name -> Kind -> SkolemInfo -> TcTyVar
 420 mkSkolTyVar name kind info = mkTcTyVar name kind (SkolemTv info)
 421
 422 tcSkolSigType :: SkolemInfo -> Type -> TcM ([TcTyVar], TcThetaType, TcType)
 423 -- Instantiate a type signature with skolem constants, but
 424 -- do *not* give them fresh names, because we want the name to
 425 -- be in the type environment -- it is lexically scoped.
 426 tcSkolSigType info ty = tcInstType (\tvs -> return (tcSkolSigTyVars info tvs)) ty
 427
 428 tcSkolSigTyVars :: SkolemInfo -> [TyVar] -> [TcTyVar]
 429 -- Make skolem constants, but do *not* give them new names, as above
 430 tcSkolSigTyVars info tyvars = [ mkSkolTyVar (tyVarName tv) (tyVarKind tv) info
 431                               | tv <- tyvars ]
 432
 433 tcInstSkolTyVar :: SkolemInfo -> (Name -> SrcSpan) -> TyVar -> TcM TcTyVar
 434 -- Instantiate the tyvar, using
 435 --      * the occ-name and kind of the supplied tyvar,
 436 --      * the unique from the monad,
 437 --      * the location either from the tyvar (mb_loc = Nothing)
 438 --        or from mb_loc (Just loc)
 439 tcInstSkolTyVar info get_loc tyvar
 440   = do  { uniq <- newUnique
 441         ; let old_name = tyVarName tyvar
 442               kind     = tyVarKind tyvar
 443               loc      = get_loc old_name
 444               new_name = mkInternalName uniq (nameOccName old_name) loc
 445         ; return (mkSkolTyVar new_name kind info) }
 446
 447 tcInstSkolTyVars :: SkolemInfo -> [TyVar] -> TcM [TcTyVar]
 448 -- Get the location from the monad
 449 tcInstSkolTyVars info tyvars
 450   = do  { span <- getSrcSpanM
 451         ; mapM (tcInstSkolTyVar info (const span)) tyvars }
 452
 453 tcInstSkolType :: SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcType)
 454 -- Instantiate a type with fresh skolem constants
 455 -- Binding location comes from the monad
 456 tcInstSkolType info ty = tcInstType (tcInstSkolTyVars info) ty
 457
 458 tcInstSigType :: Bool -> SkolemInfo -> TcType -> TcM ([TcTyVar], TcThetaType, TcRhoType)
 459 -- Instantiate with skolems or meta SigTvs; depending on use_skols
 460 -- Always take location info from the supplied tyvars
 461 tcInstSigType use_skols skol_info ty
 462   = tcInstType (mapM inst_tyvar) ty
 463   where
 464     inst_tyvar | use_skols = tcInstSkolTyVar skol_info getSrcSpan
 465                | otherwise = instMetaTyVar (SigTv skol_info)
 466 \end{code}
 467
 468
 469 %************************************************************************
 470 %*                                                                      *
 471         MetaTvs (meta type variables; mutable)
 472 %*                                                                      *
 473 %************************************************************************
 474
 475 \begin{code}
 476 newMetaTyVar :: BoxInfo -> Kind -> TcM TcTyVar
 477 -- Make a new meta tyvar out of thin air
 478 newMetaTyVar box_info kind
 479   = do  { uniq <- newUnique
 480         ; ref <- newMutVar Flexi
 481         ; let name = mkSysTvName uniq fs
 482               fs = case box_info of
 483                         BoxTv   -> fsLit "t"
 484                         TauTv   -> fsLit "t"
 485                         SigTv _ -> fsLit "a"
 486                 -- We give BoxTv and TauTv the same string, because
 487                 -- otherwise we get user-visible differences in error
 488                 -- messages, which are confusing.  If you want to see
 489                 -- the box_info of each tyvar, use -dppr-debug
 490         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 491
 492 instMetaTyVar :: BoxInfo -> TyVar -> TcM TcTyVar
 493 -- Make a new meta tyvar whose Name and Kind
 494 -- come from an existing TyVar
 495 instMetaTyVar box_info tyvar
 496   = do  { uniq <- newUnique
 497         ; ref <- newMutVar Flexi
 498         ; let name = setNameUnique (tyVarName tyvar) uniq
 499               kind = tyVarKind tyvar
 500         ; return (mkTcTyVar name kind (MetaTv box_info ref)) }
 501
 502 readMetaTyVar :: TyVar -> TcM MetaDetails
 503 readMetaTyVar tyvar = ASSERT2( isMetaTyVar tyvar, ppr tyvar )
 504                       readMutVar (metaTvRef tyvar)
 505
 506 isFilledMetaTyVar :: TyVar -> TcM Bool
 507 -- True of a filled-in (Indirect) meta type variable
 508 isFilledMetaTyVar tv
 509   | not (isTcTyVar tv) = return False
 510   | MetaTv _ ref <- tcTyVarDetails tv
 511   = do  { details <- readMutVar ref
 512         ; return (isIndirect details) }
 513   | otherwise = return False
 514
 515 writeMetaTyVar :: TcTyVar -> TcType -> TcM ()
 516 writeMetaTyVar tyvar ty
 517   | not debugIsOn = writeMutVar (metaTvRef tyvar) (Indirect ty)
 518 writeMetaTyVar tyvar ty
 519   | not (isMetaTyVar tyvar)
 520   = pprTrace "writeMetaTyVar" (ppr tyvar) $
 521     return ()
 522   | otherwise
 523   = ASSERT( isMetaTyVar tyvar )
 524     -- TOM: It should also work for coercions
 525     -- ASSERT2( k2 `isSubKind` k1, (ppr tyvar <+> ppr k1) $$ (ppr ty <+> ppr k2) )
 526     do  { ASSERTM2( do { details <- readMetaTyVar tyvar; return (isFlexi details) }, ppr tyvar )
 527         ; traceTc (text "writeMetaTyVar" <+> ppr tyvar <+> text ":=" <+> ppr ty)
 528         ; writeMutVar (metaTvRef tyvar) (Indirect ty) }
 529   where
 530     _k1 = tyVarKind tyvar
 531     _k2 = typeKind ty
 532 \end{code}
 533
 534
 535 %************************************************************************
 536 %*                                                                      *
 537         MetaTvs: TauTvs
 538 %*                                                                      *
 539 %************************************************************************
 540
 541 \begin{code}
 542 newFlexiTyVar :: Kind -> TcM TcTyVar
 543 newFlexiTyVar kind = newMetaTyVar TauTv kind
 544
 545 newFlexiTyVarTy  :: Kind -> TcM TcType
 546 newFlexiTyVarTy kind = do
 547     tc_tyvar <- newFlexiTyVar kind
 548     return (TyVarTy tc_tyvar)
 549
 550 newFlexiTyVarTys :: Int -> Kind -> TcM [TcType]
 551 newFlexiTyVarTys n kind = mapM newFlexiTyVarTy (nOfThem n kind)
 552
 553 tcInstTyVar :: TyVar -> TcM TcTyVar
 554 -- Instantiate with a META type variable
 555 tcInstTyVar tyvar = instMetaTyVar TauTv tyvar
 556
 557 tcInstTyVars :: [TyVar] -> TcM ([TcTyVar], [TcType], TvSubst)
 558 -- Instantiate with META type variables
 559 tcInstTyVars tyvars
 560   = do  { tc_tvs <- mapM tcInstTyVar tyvars
 561         ; let tys = mkTyVarTys tc_tvs
 562         ; return (tc_tvs, tys, zipTopTvSubst tyvars tys) }
 563                 -- Since the tyvars are freshly made,
 564                 -- they cannot possibly be captured by
 565                 -- any existing for-alls.  Hence zipTopTvSubst
 566 \end{code}
 567
 568
 569 %************************************************************************
 570 %*                                                                      *
 571         MetaTvs: SigTvs
 572 %*                                                                      *
 573 %************************************************************************
 574
 575 \begin{code}
 576 zonkSigTyVar :: TcTyVar -> TcM TcTyVar
 577 zonkSigTyVar sig_tv
 578   | isSkolemTyVar sig_tv
 579   = return sig_tv       -- Happens in the call in TcBinds.checkDistinctTyVars
 580   | otherwise
 581   = ASSERT( isSigTyVar sig_tv )
 582     do { ty <- zonkTcTyVar sig_tv
 583        ; return (tcGetTyVar "zonkSigTyVar" ty) }
 584         -- 'ty' is bound to be a type variable, because SigTvs
 585         -- can only be unified with type variables
 586 \end{code}
 587
 588
 589 %************************************************************************
 590 %*                                                                      *
 591         MetaTvs: BoxTvs
 592 %*                                                                      *
 593 %************************************************************************
 594
 595 \begin{code}
 596 newBoxyTyVar :: Kind -> TcM BoxyTyVar
 597 newBoxyTyVar kind = newMetaTyVar BoxTv kind
 598
 599 newBoxyTyVars :: [Kind] -> TcM [BoxyTyVar]
 600 newBoxyTyVars kinds = mapM newBoxyTyVar kinds
 601
 602 newBoxyTyVarTys :: [Kind] -> TcM [BoxyType]
 603 newBoxyTyVarTys kinds = do { tvs <- mapM newBoxyTyVar kinds; return (mkTyVarTys tvs) }
 604
 605 readFilledBox :: BoxyTyVar -> TcM TcType
 606 -- Read the contents of the box, which should be filled in by now
 607 readFilledBox box_tv = ASSERT( isBoxyTyVar box_tv )
 608                        do { cts <- readMetaTyVar box_tv
 609                           ; case cts of
 610                                 Flexi -> pprPanic "readFilledBox" (ppr box_tv)
 611                                 Indirect ty -> return ty }
 612
 613 tcInstBoxyTyVar :: TyVar -> TcM BoxyTyVar
 614 -- Instantiate with a BOXY type variable
 615 tcInstBoxyTyVar tyvar = instMetaTyVar BoxTv tyvar
 616 \end{code}
 617
 618
 619 %************************************************************************
 620 %*                                                                      *
 621 \subsection{Putting and getting  mutable type variables}
 622 %*                                                                      *
 623 %************************************************************************
 624
 625 But it's more fun to short out indirections on the way: If this
 626 version returns a TyVar, then that TyVar is unbound.  If it returns
 627 any other type, then there might be bound TyVars embedded inside it.
 628
 629 We return Nothing iff the original box was unbound.
 630
 631 \begin{code}
 632 data LookupTyVarResult  -- The result of a lookupTcTyVar call
 633   = DoneTv TcTyVarDetails       -- SkolemTv or virgin MetaTv
 634   | IndirectTv TcType
 635
 636 lookupTcTyVar :: TcTyVar -> TcM LookupTyVarResult
 637 lookupTcTyVar tyvar
 638   = ASSERT2( isTcTyVar tyvar, ppr tyvar )
 639     case details of
 640       SkolemTv _   -> return (DoneTv details)
 641       MetaTv _ ref -> do { meta_details <- readMutVar ref
 642                          ; case meta_details of
 643                             Indirect ty -> return (IndirectTv ty)
 644                             Flexi -> return (DoneTv details) }
 645   where
 646     details =  tcTyVarDetails tyvar
 647
 648 {-
 649 -- gaw 2004 We aren't shorting anything out anymore, at least for now
 650 getTcTyVar tyvar
 651   | not (isTcTyVar tyvar)
 652   = pprTrace "getTcTyVar" (ppr tyvar) $
 653     return (Just (mkTyVarTy tyvar))
 654
 655   | otherwise
 656   = ASSERT2( isTcTyVar tyvar, ppr tyvar ) do
 657     maybe_ty <- readMetaTyVar tyvar
 658     case maybe_ty of
 659         Just ty -> do ty' <- short_out ty
 660                       writeMetaTyVar tyvar (Just ty')
 661                       return (Just ty')
 662
 663         Nothing    -> return Nothing
 664
 665 short_out :: TcType -> TcM TcType
 666 short_out ty@(TyVarTy tyvar)
 667   | not (isTcTyVar tyvar)
 668   = return ty
 669
 670   | otherwise = do
 671     maybe_ty <- readMetaTyVar tyvar
 672     case maybe_ty of
 673         Just ty' -> do ty' <- short_out ty'
 674                        writeMetaTyVar tyvar (Just ty')
 675                        return ty'
 676
 677         other    -> return ty
 678
 679 short_out other_ty = return other_ty
 680 -}
 681 \end{code}
 682
 683
 684 %************************************************************************
 685 %*                                                                      *
 686 \subsection{Zonking -- the exernal interfaces}
 687 %*                                                                      *
 688 %************************************************************************
 689
 690 -----------------  Type variables
 691
 692 \begin{code}
 693 zonkTcTyVars :: [TcTyVar] -> TcM [TcType]
 694 zonkTcTyVars tyvars = mapM zonkTcTyVar tyvars
 695
 696 zonkTcTyVarsAndFV :: [TcTyVar] -> TcM TcTyVarSet
 697 zonkTcTyVarsAndFV tyvars = tyVarsOfTypes <$> mapM zonkTcTyVar tyvars
 698
 699 zonkTcTyVar :: TcTyVar -> TcM TcType
 700 zonkTcTyVar tyvar = ASSERT2( isTcTyVar tyvar, ppr tyvar)
 701                     zonk_tc_tyvar (\ tv -> return (TyVarTy tv)) tyvar
 702 \end{code}
 703
 704 -----------------  Types
 705
 706 \begin{code}
 707 zonkTcType :: TcType -> TcM TcType
 708 zonkTcType ty = zonkType (\ tv -> return (TyVarTy tv)) ty
 709
 710 zonkTcTypes :: [TcType] -> TcM [TcType]
 711 zonkTcTypes tys = mapM zonkTcType tys
 712
 713 zonkTcThetaType :: TcThetaType -> TcM TcThetaType
 714 zonkTcThetaType theta = mapM zonkTcPredType theta
 715
 716 zonkTcPredType :: TcPredType -> TcM TcPredType
 717 zonkTcPredType (ClassP c ts)  = ClassP c <$> zonkTcTypes ts
 718 zonkTcPredType (IParam n t)   = IParam n <$> zonkTcType t
 719 zonkTcPredType (EqPred t1 t2) = EqPred <$> zonkTcType t1 <*> zonkTcType t2
 720 \end{code}
 721
 722 -------------------  These ...ToType, ...ToKind versions
 723                      are used at the end of type checking
 724
 725 \begin{code}
 726 zonkTopTyVar :: TcTyVar -> TcM TcTyVar
 727 -- zonkTopTyVar is used, at the top level, on any un-instantiated meta type variables
 728 -- to default the kind of ? and ?? etc to *.  This is important to ensure that
 729 -- instance declarations match.  For example consider
 730 --      instance Show (a->b)
 731 --      foo x = show (\_ -> True)
 732 -- Then we'll get a constraint (Show (p ->q)) where p has argTypeKind (printed ??),
 733 -- and that won't match the typeKind (*) in the instance decl.
 734 --
 735 -- Because we are at top level, no further constraints are going to affect these
 736 -- type variables, so it's time to do it by hand.  However we aren't ready
 737 -- to default them fully to () or whatever, because the type-class defaulting
 738 -- rules have yet to run.
 739
 740 zonkTopTyVar tv
 741   | k `eqKind` default_k = return tv
 742   | otherwise
 743   = do  { tv' <- newFlexiTyVar default_k
 744         ; writeMetaTyVar tv (mkTyVarTy tv')
 745         ; return tv' }
 746   where
 747     k = tyVarKind tv
 748     default_k = defaultKind k
 749
 750 zonkQuantifiedTyVars :: [TcTyVar] -> TcM [TcTyVar]
 751 zonkQuantifiedTyVars = mapM zonkQuantifiedTyVar
 752
 753 zonkQuantifiedTyVar :: TcTyVar -> TcM TcTyVar
 754 -- zonkQuantifiedTyVar is applied to the a TcTyVar when quantifying over it.
 755 --
 756 -- The quantified type variables often include meta type variables
 757 -- we want to freeze them into ordinary type variables, and
 758 -- default their kind (e.g. from OpenTypeKind to TypeKind)
 759 --                      -- see notes with Kind.defaultKind
 760 -- The meta tyvar is updated to point to the new skolem TyVar.  Now any
 761 -- bound occurences of the original type variable will get zonked to
 762 -- the immutable version.
 763 --
 764 -- We leave skolem TyVars alone; they are immutable.
 765 zonkQuantifiedTyVar tv
 766   | ASSERT2( isTcTyVar tv, ppr tv )
 767     isSkolemTyVar tv
 768   = do { kind <- zonkTcType (tyVarKind tv)
 769        ; return $ setTyVarKind tv kind
 770        }
 771         -- It might be a skolem type variable,
 772         -- for example from a user type signature
 773
 774   | otherwise   -- It's a meta-type-variable
 775   = do  { details <- readMetaTyVar tv
 776
 777         -- Create the new, frozen, skolem type variable
 778         -- We zonk to a skolem, not to a regular TcVar
 779         -- See Note [Zonking to Skolem]
 780         ; let final_kind = defaultKind (tyVarKind tv)
 781               final_tv   = mkSkolTyVar (tyVarName tv) final_kind UnkSkol
 782
 783         -- Bind the meta tyvar to the new tyvar
 784         ; case details of
 785             Indirect ty -> WARN( True, ppr tv $$ ppr ty )
 786                            return ()
 787                 -- [Sept 04] I don't think this should happen
 788                 -- See note [Silly Type Synonym]
 789
 790             Flexi -> writeMetaTyVar tv (mkTyVarTy final_tv)
 791
 792         -- Return the new tyvar
 793         ; return final_tv }
 794 \end{code}
 795
 796 Note [Silly Type Synonyms]
 797 ~~~~~~~~~~~~~~~~~~~~~~~~~~
 798 Consider this:
 799         type C u a = u  -- Note 'a' unused
 800
 801         foo :: (forall a. C u a -> C u a) -> u
 802         foo x = ...
 803
 804         bar :: Num u => u
 805         bar = foo (\t -> t + t)
 806
 807 * From the (\t -> t+t) we get type  {Num d} =>  d -> d
 808   where d is fresh.
 809
 810 * Now unify with type of foo's arg, and we get:
 811         {Num (C d a)} =>  C d a -> C d a
 812   where a is fresh.
 813
 814 * Now abstract over the 'a', but float out the Num (C d a) constraint
 815   because it does not 'really' mention a.  (see exactTyVarsOfType)
 816   The arg to foo becomes
 817         \/\a -> \t -> t+t
 818
 819 * So we get a dict binding for Num (C d a), which is zonked to give
 820         a = ()
 821   [Note Sept 04: now that we are zonking quantified type variables
 822   on construction, the 'a' will be frozen as a regular tyvar on
 823   quantification, so the floated dict will still have type (C d a).
 824   Which renders this whole note moot; happily!]
 825
 826 * Then the \/\a abstraction has a zonked 'a' in it.
 827
 828 All very silly.   I think its harmless to ignore the problem.  We'll end up with
 829 a \/\a in the final result but all the occurrences of a will be zonked to ()
 830
 831 Note [Zonking to Skolem]
 832 ~~~~~~~~~~~~~~~~~~~~~~~~
 833 We used to zonk quantified type variables to regular TyVars.  However, this
 834 leads to problems.  Consider this program from the regression test suite:
 835
 836   eval :: Int -> String -> String -> String
 837   eval 0 root actual = evalRHS 0 root actual
 838
 839   evalRHS :: Int -> a
 840   evalRHS 0 root actual = eval 0 root actual
 841
 842 It leads to the deferral of an equality
 843
 844   (String -> String -> String) ~ a
 845
 846 which is propagated up to the toplevel (see TcSimplify.tcSimplifyInferCheck).
 847 In the meantime `a' is zonked and quantified to form `evalRHS's signature.
 848 This has the *side effect* of also zonking the `a' in the deferred equality
 849 (which at this point is being handed around wrapped in an implication
 850 constraint).
 851
 852 Finally, the equality (with the zonked `a') will be handed back to the
 853 simplifier by TcRnDriver.tcRnSrcDecls calling TcSimplify.tcSimplifyTop.
 854 If we zonk `a' with a regular type variable, we will have this regular type
 855 variable now floating around in the simplifier, which in many places assumes to
 856 only see proper TcTyVars.
 857
 858 We can avoid this problem by zonking with a skolem.  The skolem is rigid
 859 (which we requirefor a quantified variable), but is still a TcTyVar that the
 860 simplifier knows how to deal with.
 861
 862
 863 %************************************************************************
 864 %*                                                                      *
 865 \subsection{Zonking -- the main work-horses: zonkType, zonkTyVar}
 866 %*                                                                      *
 867 %*              For internal use only!                                  *
 868 %*                                                                      *
 869 %************************************************************************
 870
 871 \begin{code}
 872 -- For unbound, mutable tyvars, zonkType uses the function given to it
 873 -- For tyvars bound at a for-all, zonkType zonks them to an immutable
 874 --      type variable and zonks the kind too
 875
 876 zonkType :: (TcTyVar -> TcM Type)       -- What to do with unbound mutable type variables
 877                                         -- see zonkTcType, and zonkTcTypeToType
 878          -> TcType
 879          -> TcM Type
 880 zonkType unbound_var_fn ty
 881   = go ty
 882   where
 883     go (TyConApp tc tys) = do tys' <- mapM go tys
 884                               return (TyConApp tc tys')
 885
 886     go (PredTy p)        = do p' <- go_pred p
 887                               return (PredTy p')
 888
 889     go (FunTy arg res)   = do arg' <- go arg
 890                               res' <- go res
 891                               return (FunTy arg' res')
 892
 893     go (AppTy fun arg)   = do fun' <- go fun
 894                               arg' <- go arg
 895                               return (mkAppTy fun' arg')
 896                 -- NB the mkAppTy; we might have instantiated a
 897                 -- type variable to a type constructor, so we need
 898                 -- to pull the TyConApp to the top.
 899
 900         -- The two interesting cases!
 901     go (TyVarTy tyvar) | isTcTyVar tyvar = zonk_tc_tyvar unbound_var_fn tyvar
 902                        | otherwise       = liftM TyVarTy $
 903                                              zonkTyVar unbound_var_fn tyvar
 904                 -- Ordinary (non Tc) tyvars occur inside quantified types
 905
 906     go (ForAllTy tyvar ty) = ASSERT( isImmutableTyVar tyvar ) do
 907                              ty' <- go ty
 908                              tyvar' <- zonkTyVar unbound_var_fn tyvar
 909                              return (ForAllTy tyvar' ty')
 910
 911     go_pred (ClassP c tys)   = do tys' <- mapM go tys
 912                                   return (ClassP c tys')
 913     go_pred (IParam n ty)    = do ty' <- go ty
 914                                   return (IParam n ty')
 915     go_pred (EqPred ty1 ty2) = do ty1' <- go ty1
 916                                   ty2' <- go ty2
 917                                   return (EqPred ty1' ty2')
 918
 919 zonk_tc_tyvar :: (TcTyVar -> TcM Type)  -- What to do for an unbound mutable var
 920               -> TcTyVar -> TcM TcType
 921 zonk_tc_tyvar unbound_var_fn tyvar
 922   | not (isMetaTyVar tyvar)     -- Skolems
 923   = return (TyVarTy tyvar)
 924
 925   | otherwise                   -- Mutables
 926   = do  { cts <- readMetaTyVar tyvar
 927         ; case cts of
 928             Flexi       -> unbound_var_fn tyvar    -- Unbound meta type variable
 929             Indirect ty -> zonkType unbound_var_fn ty  }
 930
 931 -- Zonk the kind of a non-TC tyvar in case it is a coercion variable (their
 932 -- kind contains types).
 933 --
 934 zonkTyVar :: (TcTyVar -> TcM Type)      -- What to do for an unbound mutable var
 935           -> TyVar -> TcM TyVar
 936 zonkTyVar unbound_var_fn tv
 937   | isCoVar tv
 938   = do { kind <- zonkType unbound_var_fn (tyVarKind tv)
 939        ; return $ setTyVarKind tv kind
 940        }
 941   | otherwise = return tv
 942 \end{code}
 943
 944
 945
 946 %************************************************************************
 947 %*                                                                      *
 948                         Zonking kinds
 949 %*                                                                      *
 950 %************************************************************************
 951
 952 \begin{code}
 953 readKindVar  :: KindVar -> TcM (MetaDetails)
 954 writeKindVar :: KindVar -> TcKind -> TcM ()
 955 readKindVar  kv = readMutVar (kindVarRef kv)
 956 writeKindVar kv val = writeMutVar (kindVarRef kv) (Indirect val)
 957
 958 -------------
 959 zonkTcKind :: TcKind -> TcM TcKind
 960 zonkTcKind k = zonkTcType k
 961
 962 -------------
 963 zonkTcKindToKind :: TcKind -> TcM Kind
 964 -- When zonking a TcKind to a kind, we need to instantiate kind variables,
 965 -- Haskell specifies that * is to be used, so we follow that.
 966 zonkTcKindToKind k = zonkType (\ _ -> return liftedTypeKind) k
 967 \end{code}
 968
 969 %************************************************************************
 970 %*                                                                      *
 971 \subsection{Checking a user type}
 972 %*                                                                      *
 973 %************************************************************************
 974
 975 When dealing with a user-written type, we first translate it from an HsType
 976 to a Type, performing kind checking, and then check various things that should
 977 be true about it.  We don't want to perform these checks at the same time
 978 as the initial translation because (a) they are unnecessary for interface-file
 979 types and (b) when checking a mutually recursive group of type and class decls,
 980 we can't "look" at the tycons/classes yet.  Also, the checks are are rather
 981 diverse, and used to really mess up the other code.
 982
 983 One thing we check for is 'rank'.
 984
 985         Rank 0:         monotypes (no foralls)
 986         Rank 1:         foralls at the front only, Rank 0 inside
 987         Rank 2:         foralls at the front, Rank 1 on left of fn arrow,
 988
 989         basic ::= tyvar | T basic ... basic
 990
 991         r2  ::= forall tvs. cxt => r2a
 992         r2a ::= r1 -> r2a | basic
 993         r1  ::= forall tvs. cxt => r0
 994         r0  ::= r0 -> r0 | basic
 995
 996 Another thing is to check that type synonyms are saturated.
 997 This might not necessarily show up in kind checking.
 998         type A i = i
 999         data T k = MkT (k Int)
1000         f :: T A        -- BAD!
1001
1002
1003 \begin{code}
1004 checkValidType :: UserTypeCtxt -> Type -> TcM ()
1005 -- Checks that the type is valid for the given context
1006 checkValidType ctxt ty = do
1007     traceTc (text "checkValidType" <+> ppr ty)
1008     unboxed  <- doptM Opt_UnboxedTuples
1009     rank2    <- doptM Opt_Rank2Types
1010     rankn    <- doptM Opt_RankNTypes
1011     polycomp <- doptM Opt_PolymorphicComponents
1012     let
1013         gen_rank n | rankn     = ArbitraryRank
1014                    | rank2     = Rank 2
1015                    | otherwise = Rank n
1016         rank
1017           = case ctxt of
1018                  DefaultDeclCtxt-> MustBeMonoType
1019                  ResSigCtxt     -> MustBeMonoType
1020                  LamPatSigCtxt  -> gen_rank 0
1021                  BindPatSigCtxt -> gen_rank 0
1022                  TySynCtxt _    -> gen_rank 0
1023                  GenPatCtxt     -> gen_rank 1
1024                         -- This one is a bit of a hack
1025                         -- See the forall-wrapping in TcClassDcl.mkGenericInstance
1026
1027                  ExprSigCtxt    -> gen_rank 1
1028                  FunSigCtxt _   -> gen_rank 1
1029                  ConArgCtxt _   | polycomp -> gen_rank 2
1030                                 -- We are given the type of the entire
1031                                 -- constructor, hence rank 1
1032                                 | otherwise -> gen_rank 1
1033
1034                  ForSigCtxt _   -> gen_rank 1
1035                  SpecInstCtxt   -> gen_rank 1
1036
1037         actual_kind = typeKind ty
1038
1039         kind_ok = case ctxt of
1040                         TySynCtxt _  -> True -- Any kind will do
1041                         ResSigCtxt   -> isSubOpenTypeKind actual_kind
1042                         ExprSigCtxt  -> isSubOpenTypeKind actual_kind
1043                         GenPatCtxt   -> isLiftedTypeKind actual_kind
1044                         ForSigCtxt _ -> isLiftedTypeKind actual_kind
1045                         _            -> isSubArgTypeKind actual_kind
1046
1047         ubx_tup = case ctxt of
1048                       TySynCtxt _ | unboxed -> UT_Ok
1049                       ExprSigCtxt | unboxed -> UT_Ok
1050                       _                     -> UT_NotOk
1051
1052         -- Check that the thing has kind Type, and is lifted if necessary
1053     checkTc kind_ok (kindErr actual_kind)
1054
1055         -- Check the internal validity of the type itself
1056     check_type rank ubx_tup ty
1057
1058     traceTc (text "checkValidType done" <+> ppr ty)
1059
1060 checkValidMonoType :: Type -> TcM ()
1061 checkValidMonoType ty = check_mono_type MustBeMonoType ty
1062 \end{code}
1063
1064
1065 \begin{code}
1066 data Rank = ArbitraryRank         -- Any rank ok
1067           | MustBeMonoType        -- Monotype regardless of flags
1068           | TyConArgMonoType      -- Monotype but could be poly if -XImpredicativeTypes
1069           | SynArgMonoType        -- Monotype but could be poly if -XLiberalTypeSynonyms
1070           | Rank Int              -- Rank n, but could be more with -XRankNTypes
1071
1072 decRank :: Rank -> Rank           -- Function arguments
1073 decRank (Rank 0)   = Rank 0
1074 decRank (Rank n)   = Rank (n-1)
1075 decRank other_rank = other_rank
1076
1077 nonZeroRank :: Rank -> Bool
1078 nonZeroRank ArbitraryRank = True
1079 nonZeroRank (Rank n)      = n>0
1080 nonZeroRank _             = False
1081
1082 ----------------------------------------
1083 data UbxTupFlag = UT_Ok | UT_NotOk
1084         -- The "Ok" version means "ok if UnboxedTuples is on"
1085
1086 ----------------------------------------
1087 check_mono_type :: Rank -> Type -> TcM ()       -- No foralls anywhere
1088                                                 -- No unlifted types of any kind
1089 check_mono_type rank ty
1090    = do { check_type rank UT_NotOk ty
1091         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1092
1093 check_type :: Rank -> UbxTupFlag -> Type -> TcM ()
1094 -- The args say what the *type context* requires, independent
1095 -- of *flag* settings.  You test the flag settings at usage sites.
1096 --
1097 -- Rank is allowed rank for function args
1098 -- Rank 0 means no for-alls anywhere
1099
1100 check_type rank ubx_tup ty
1101   | not (null tvs && null theta)
1102   = do  { checkTc (nonZeroRank rank) (forAllTyErr rank ty)
1103                 -- Reject e.g. (Maybe (?x::Int => Int)),
1104                 -- with a decent error message
1105         ; check_valid_theta SigmaCtxt theta
1106         ; check_type rank ubx_tup tau   -- Allow foralls to right of arrow
1107         ; checkFreeness tvs theta
1108         ; checkAmbiguity tvs theta (tyVarsOfType tau) }
1109   where
1110     (tvs, theta, tau) = tcSplitSigmaTy ty
1111
1112 -- Naked PredTys don't usually show up, but they can as a result of
1113 --      {-# SPECIALISE instance Ord Char #-}
1114 -- The Right Thing would be to fix the way that SPECIALISE instance pragmas
1115 -- are handled, but the quick thing is just to permit PredTys here.
1116 check_type _ _ (PredTy sty)
1117   = do  { dflags <- getDOpts
1118         ; check_pred_ty dflags TypeCtxt sty }
1119
1120 check_type _ _ (TyVarTy _) = return ()
1121 check_type rank _ (FunTy arg_ty res_ty)
1122   = do  { check_type (decRank rank) UT_NotOk arg_ty
1123         ; check_type rank           UT_Ok    res_ty }
1124
1125 check_type rank _ (AppTy ty1 ty2)
1126   = do  { check_arg_type rank ty1
1127         ; check_arg_type rank ty2 }
1128
1129 check_type rank ubx_tup ty@(TyConApp tc tys)
1130   | isSynTyCon tc
1131   = do  {       -- Check that the synonym has enough args
1132                 -- This applies equally to open and closed synonyms
1133                 -- It's OK to have an *over-applied* type synonym
1134                 --      data Tree a b = ...
1135                 --      type Foo a = Tree [a]
1136                 --      f :: Foo a b -> ...
1137           checkTc (tyConArity tc <= length tys) arity_msg
1138
1139         -- See Note [Liberal type synonyms]
1140         ; liberal <- doptM Opt_LiberalTypeSynonyms
1141         ; if not liberal || isOpenSynTyCon tc then
1142                 -- For H98 and synonym families, do check the type args
1143                 mapM_ (check_mono_type SynArgMonoType) tys
1144
1145           else  -- In the liberal case (only for closed syns), expand then check
1146           case tcView ty of
1147              Just ty' -> check_type rank ubx_tup ty'
1148              Nothing  -> pprPanic "check_tau_type" (ppr ty)
1149     }
1150
1151   | isUnboxedTupleTyCon tc
1152   = do  { ub_tuples_allowed <- doptM Opt_UnboxedTuples
1153         ; checkTc (ubx_tup_ok ub_tuples_allowed) ubx_tup_msg
1154
1155         ; impred <- doptM Opt_ImpredicativeTypes
1156         ; let rank' = if impred then ArbitraryRank else TyConArgMonoType
1157                 -- c.f. check_arg_type
1158                 -- However, args are allowed to be unlifted, or
1159                 -- more unboxed tuples, so can't use check_arg_ty
1160         ; mapM_ (check_type rank' UT_Ok) tys }
1161
1162   | otherwise
1163   = mapM_ (check_arg_type rank) tys
1164
1165   where
1166     ubx_tup_ok ub_tuples_allowed = case ubx_tup of
1167                                    UT_Ok -> ub_tuples_allowed
1168                                    _     -> False
1169
1170     n_args    = length tys
1171     tc_arity  = tyConArity tc
1172
1173     arity_msg   = arityErr "Type synonym" (tyConName tc) tc_arity n_args
1174     ubx_tup_msg = ubxArgTyErr ty
1175
1176 check_type _ _ ty = pprPanic "check_type" (ppr ty)
1177
1178 ----------------------------------------
1179 check_arg_type :: Rank -> Type -> TcM ()
1180 -- The sort of type that can instantiate a type variable,
1181 -- or be the argument of a type constructor.
1182 -- Not an unboxed tuple, but now *can* be a forall (since impredicativity)
1183 -- Other unboxed types are very occasionally allowed as type
1184 -- arguments depending on the kind of the type constructor
1185 --
1186 -- For example, we want to reject things like:
1187 --
1188 --      instance Ord a => Ord (forall s. T s a)
1189 -- and
1190 --      g :: T s (forall b.b)
1191 --
1192 -- NB: unboxed tuples can have polymorphic or unboxed args.
1193 --     This happens in the workers for functions returning
1194 --     product types with polymorphic components.
1195 --     But not in user code.
1196 -- Anyway, they are dealt with by a special case in check_tau_type
1197
1198 check_arg_type rank ty
1199   = do  { impred <- doptM Opt_ImpredicativeTypes
1200         ; let rank' = if impred then ArbitraryRank  -- Arg of tycon can have arby rank, regardless
1201                       else case rank of             -- Predictive => must be monotype
1202                         MustBeMonoType -> MustBeMonoType
1203                         _              -> TyConArgMonoType
1204                         -- Make sure that MustBeMonoType is propagated,
1205                         -- so that we don't suggest -XImpredicativeTypes in
1206                         --    (Ord (forall a.a)) => a -> a
1207
1208         ; check_type rank' UT_NotOk ty
1209         ; checkTc (not (isUnLiftedType ty)) (unliftedArgErr ty) }
1210
1211 ----------------------------------------
1212 forAllTyErr :: Rank -> Type -> SDoc
1213 forAllTyErr rank ty
1214    = vcat [ hang (ptext (sLit "Illegal polymorphic or qualified type:")) 2 (ppr ty)
1215           , suggestion ]
1216   where
1217     suggestion = case rank of
1218                    Rank _ -> ptext (sLit "Perhaps you intended to use -XRankNTypes or -XRank2Types")
1219                    TyConArgMonoType -> ptext (sLit "Perhaps you intended to use -XImpredicativeTypes")
1220                    SynArgMonoType -> ptext (sLit "Perhaps you intended to use -XLiberalTypeSynonyms")
1221                    _ -> empty      -- Polytype is always illegal
1222
1223 unliftedArgErr, ubxArgTyErr :: Type -> SDoc
1224 unliftedArgErr  ty = sep [ptext (sLit "Illegal unlifted type:"), ppr ty]
1225 ubxArgTyErr     ty = sep [ptext (sLit "Illegal unboxed tuple type as function argument:"), ppr ty]
1226
1227 kindErr :: Kind -> SDoc
1228 kindErr kind       = sep [ptext (sLit "Expecting an ordinary type, but found a type of kind"), ppr kind]
1229 \end{code}
1230
1231 Note [Liberal type synonyms]
1232 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1233 If -XLiberalTypeSynonyms is on, expand closed type synonyms *before*
1234 doing validity checking.  This allows us to instantiate a synonym defn
1235 with a for-all type, or with a partially-applied type synonym.
1236         e.g.   type T a b = a
1237                type S m   = m ()
1238                f :: S (T Int)
1239 Here, T is partially applied, so it's illegal in H98.  But if you
1240 expand S first, then T we get just
1241                f :: Int
1242 which is fine.
1243
1244 IMPORTANT: suppose T is a type synonym.  Then we must do validity
1245 checking on an appliation (T ty1 ty2)
1246
1247         *either* before expansion (i.e. check ty1, ty2)
1248         *or* after expansion (i.e. expand T ty1 ty2, and then check)
1249         BUT NOT BOTH
1250
1251 If we do both, we get exponential behaviour!!
1252
1253   data TIACons1 i r c = c i ::: r c
1254   type TIACons2 t x = TIACons1 t (TIACons1 t x)
1255   type TIACons3 t x = TIACons2 t (TIACons1 t x)
1256   type TIACons4 t x = TIACons2 t (TIACons2 t x)
1257   type TIACons7 t x = TIACons4 t (TIACons3 t x)
1258
1259
1260 %************************************************************************
1261 %*                                                                      *
1262 \subsection{Checking a theta or source type}
1263 %*                                                                      *
1264 %************************************************************************
1265
1266 \begin{code}
1267 -- Enumerate the contexts in which a "source type", <S>, can occur
1268 --      Eq a
1269 -- or   ?x::Int
1270 -- or   r <: {x::Int}
1271 -- or   (N a) where N is a newtype
1272
1273 data SourceTyCtxt
1274   = ClassSCCtxt Name    -- Superclasses of clas
1275                         --      class <S> => C a where ...
1276   | SigmaCtxt           -- Theta part of a normal for-all type
1277                         --      f :: <S> => a -> a
1278   | DataTyCtxt Name     -- Theta part of a data decl
1279                         --      data <S> => T a = MkT a
1280   | TypeCtxt            -- Source type in an ordinary type
1281                         --      f :: N a -> N a
1282   | InstThetaCtxt       -- Context of an instance decl
1283                         --      instance <S> => C [a] where ...
1284
1285 pprSourceTyCtxt :: SourceTyCtxt -> SDoc
1286 pprSourceTyCtxt (ClassSCCtxt c) = ptext (sLit "the super-classes of class") <+> quotes (ppr c)
1287 pprSourceTyCtxt SigmaCtxt       = ptext (sLit "the context of a polymorphic type")
1288 pprSourceTyCtxt (DataTyCtxt tc) = ptext (sLit "the context of the data type declaration for") <+> quotes (ppr tc)
1289 pprSourceTyCtxt InstThetaCtxt   = ptext (sLit "the context of an instance declaration")
1290 pprSourceTyCtxt TypeCtxt        = ptext (sLit "the context of a type")
1291 \end{code}
1292
1293 \begin{code}
1294 checkValidTheta :: SourceTyCtxt -> ThetaType -> TcM ()
1295 checkValidTheta ctxt theta
1296   = addErrCtxt (checkThetaCtxt ctxt theta) (check_valid_theta ctxt theta)
1297
1298 -------------------------
1299 check_valid_theta :: SourceTyCtxt -> [PredType] -> TcM ()
1300 check_valid_theta _ []
1301   = return ()
1302 check_valid_theta ctxt theta = do
1303     dflags <- getDOpts
1304     warnTc (notNull dups) (dupPredWarn dups)
1305     mapM_ (check_pred_ty dflags ctxt) theta
1306   where
1307     (_,dups) = removeDups tcCmpPred theta
1308
1309 -------------------------
1310 check_pred_ty :: DynFlags -> SourceTyCtxt -> PredType -> TcM ()
1311 check_pred_ty dflags ctxt pred@(ClassP cls tys)
1312   = do {        -- Class predicates are valid in all contexts
1313        ; checkTc (arity == n_tys) arity_err
1314
1315                 -- Check the form of the argument types
1316        ; mapM_ checkValidMonoType tys
1317        ; checkTc (check_class_pred_tys dflags ctxt tys)
1318                  (predTyVarErr pred $$ how_to_allow)
1319        }
1320   where
1321     class_name = className cls
1322     arity      = classArity cls
1323     n_tys      = length tys
1324     arity_err  = arityErr "Class" class_name arity n_tys
1325     how_to_allow = parens (ptext (sLit "Use -XFlexibleContexts to permit this"))
1326
1327 check_pred_ty _ (ClassSCCtxt _) (EqPred _ _)
1328   =   -- We do not yet support superclass equalities.
1329     failWithTc $
1330       sep [ ptext (sLit "The current implementation of type families does not")
1331           , ptext (sLit "support equality constraints in superclass contexts.")
1332           , ptext (sLit "They are planned for a future release.")
1333           ]
1334
1335 check_pred_ty dflags _ pred@(EqPred ty1 ty2)
1336   = do {        -- Equational constraints are valid in all contexts if type
1337                 -- families are permitted
1338        ; checkTc (dopt Opt_TypeFamilies dflags) (eqPredTyErr pred)
1339
1340                 -- Check the form of the argument types
1341        ; checkValidMonoType ty1
1342        ; checkValidMonoType ty2
1343        }
1344
1345 check_pred_ty _ SigmaCtxt (IParam _ ty) = checkValidMonoType ty
1346         -- Implicit parameters only allowed in type
1347         -- signatures; not in instance decls, superclasses etc
1348         -- The reason for not allowing implicit params in instances is a bit
1349         -- subtle.
1350         -- If we allowed        instance (?x::Int, Eq a) => Foo [a] where ...
1351         -- then when we saw (e :: (?x::Int) => t) it would be unclear how to
1352         -- discharge all the potential usas of the ?x in e.   For example, a
1353         -- constraint Foo [Int] might come out of e,and applying the
1354         -- instance decl would show up two uses of ?x.
1355
1356 -- Catch-all
1357 check_pred_ty _ _ sty = failWithTc (badPredTyErr sty)
1358
1359 -------------------------
1360 check_class_pred_tys :: DynFlags -> SourceTyCtxt -> [Type] -> Bool
1361 check_class_pred_tys dflags ctxt tys
1362   = case ctxt of
1363         TypeCtxt      -> True   -- {-# SPECIALISE instance Eq (T Int) #-} is fine
1364         InstThetaCtxt -> flexible_contexts || undecidable_ok || all tcIsTyVarTy tys
1365                                 -- Further checks on head and theta in
1366                                 -- checkInstTermination
1367         _             -> flexible_contexts || all tyvar_head tys
1368   where
1369     flexible_contexts = dopt Opt_FlexibleContexts dflags
1370     undecidable_ok = dopt Opt_UndecidableInstances dflags
1371
1372 -------------------------
1373 tyvar_head :: Type -> Bool
1374 tyvar_head ty                   -- Haskell 98 allows predicates of form
1375   | tcIsTyVarTy ty = True       --      C (a ty1 .. tyn)
1376   | otherwise                   -- where a is a type variable
1377   = case tcSplitAppTy_maybe ty of
1378         Just (ty, _) -> tyvar_head ty
1379         Nothing      -> False
1380 \end{code}
1381
1382 Check for ambiguity
1383 ~~~~~~~~~~~~~~~~~~~
1384           forall V. P => tau
1385 is ambiguous if P contains generic variables
1386 (i.e. one of the Vs) that are not mentioned in tau
1387
1388 However, we need to take account of functional dependencies
1389 when we speak of 'mentioned in tau'.  Example:
1390         class C a b | a -> b where ...
1391 Then the type
1392         forall x y. (C x y) => x
1393 is not ambiguous because x is mentioned and x determines y
1394
1395 NB; the ambiguity check is only used for *user* types, not for types
1396 coming from inteface files.  The latter can legitimately have
1397 ambiguous types. Example
1398
1399    class S a where s :: a -> (Int,Int)
1400    instance S Char where s _ = (1,1)
1401    f:: S a => [a] -> Int -> (Int,Int)
1402    f (_::[a]) x = (a*x,b)
1403         where (a,b) = s (undefined::a)
1404
1405 Here the worker for f gets the type
1406         fw :: forall a. S a => Int -> (# Int, Int #)
1407
1408 If the list of tv_names is empty, we have a monotype, and then we
1409 don't need to check for ambiguity either, because the test can't fail
1410 (see is_ambig).
1411
1412
1413 \begin{code}
1414 checkAmbiguity :: [TyVar] -> ThetaType -> TyVarSet -> TcM ()
1415 checkAmbiguity forall_tyvars theta tau_tyvars
1416   = mapM_ complain (filter is_ambig theta)
1417   where
1418     complain pred     = addErrTc (ambigErr pred)
1419     extended_tau_vars = grow theta tau_tyvars
1420
1421         -- See Note [Implicit parameters and ambiguity] in TcSimplify
1422     is_ambig pred     = isClassPred  pred &&
1423                         any ambig_var (varSetElems (tyVarsOfPred pred))
1424
1425     ambig_var ct_var  = (ct_var `elem` forall_tyvars) &&
1426                         not (ct_var `elemVarSet` extended_tau_vars)
1427
1428 ambigErr :: PredType -> SDoc
1429 ambigErr pred
1430   = sep [ptext (sLit "Ambiguous constraint") <+> quotes (pprPred pred),
1431          nest 4 (ptext (sLit "At least one of the forall'd type variables mentioned by the constraint") $$
1432                  ptext (sLit "must be reachable from the type after the '=>'"))]
1433 \end{code}
1434
1435 In addition, GHC insists that at least one type variable
1436 in each constraint is in V.  So we disallow a type like
1437         forall a. Eq b => b -> b
1438 even in a scope where b is in scope.
1439
1440 \begin{code}
1441 checkFreeness :: [Var] -> [PredType] -> TcM ()
1442 checkFreeness forall_tyvars theta
1443   = do  { flexible_contexts <- doptM Opt_FlexibleContexts
1444         ; unless flexible_contexts $ mapM_ complain (filter is_free theta) }
1445   where
1446     is_free pred     =  not (isIPPred pred)
1447                      && not (any bound_var (varSetElems (tyVarsOfPred pred)))
1448     bound_var ct_var = ct_var `elem` forall_tyvars
1449     complain pred    = addErrTc (freeErr pred)
1450
1451 freeErr :: PredType -> SDoc
1452 freeErr pred
1453   = sep [ ptext (sLit "All of the type variables in the constraint") <+>
1454           quotes (pprPred pred)
1455         , ptext (sLit "are already in scope") <+>
1456           ptext (sLit "(at least one must be universally quantified here)")
1457         , nest 4 $
1458             ptext (sLit "(Use -XFlexibleContexts to lift this restriction)")
1459         ]
1460 \end{code}
1461
1462 \begin{code}
1463 checkThetaCtxt :: SourceTyCtxt -> ThetaType -> SDoc
1464 checkThetaCtxt ctxt theta
1465   = vcat [ptext (sLit "In the context:") <+> pprTheta theta,
1466           ptext (sLit "While checking") <+> pprSourceTyCtxt ctxt ]
1467
1468 badPredTyErr, eqPredTyErr, predTyVarErr :: PredType -> SDoc
1469 badPredTyErr sty = ptext (sLit "Illegal constraint") <+> pprPred sty
1470 eqPredTyErr  sty = ptext (sLit "Illegal equational constraint") <+> pprPred sty
1471                    $$
1472                    parens (ptext (sLit "Use -XTypeFamilies to permit this"))
1473 predTyVarErr pred  = sep [ptext (sLit "Non type-variable argument"),
1474                           nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1475 dupPredWarn :: [[PredType]] -> SDoc
1476 dupPredWarn dups   = ptext (sLit "Duplicate constraint(s):") <+> pprWithCommas pprPred (map head dups)
1477
1478 arityErr :: Outputable a => String -> a -> Int -> Int -> SDoc
1479 arityErr kind name n m
1480   = hsep [ text kind, quotes (ppr name), ptext (sLit "should have"),
1481            n_arguments <> comma, text "but has been given", int m]
1482     where
1483         n_arguments | n == 0 = ptext (sLit "no arguments")
1484                     | n == 1 = ptext (sLit "1 argument")
1485                     | True   = hsep [int n, ptext (sLit "arguments")]
1486
1487 -----------------
1488 notMonoType :: TcType -> TcM a
1489 notMonoType ty
1490   = do  { ty' <- zonkTcType ty
1491         ; env0 <- tcInitTidyEnv
1492         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1493               msg = ptext (sLit "Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1494         ; failWithTcM (env1, msg) }
1495
1496 notMonoArgs :: TcType -> TcM a
1497 notMonoArgs ty
1498   = do  { ty' <- zonkTcType ty
1499         ; env0 <- tcInitTidyEnv
1500         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1501               msg = ptext (sLit "Arguments of type synonym families must be monotypes") <+> quotes (ppr tidy_ty)
1502         ; failWithTcM (env1, msg) }
1503 \end{code}
1504
1505
1506 %************************************************************************
1507 %*                                                                      *
1508 \subsection{Checking for a decent instance head type}
1509 %*                                                                      *
1510 %************************************************************************
1511
1512 @checkValidInstHead@ checks the type {\em and} its syntactic constraints:
1513 it must normally look like: @instance Foo (Tycon a b c ...) ...@
1514
1515 The exceptions to this syntactic checking: (1)~if the @GlasgowExts@
1516 flag is on, or (2)~the instance is imported (they must have been
1517 compiled elsewhere). In these cases, we let them go through anyway.
1518
1519 We can also have instances for functions: @instance Foo (a -> b) ...@.
1520
1521 \begin{code}
1522 checkValidInstHead :: Type -> TcM (Class, [TcType])
1523
1524 checkValidInstHead ty   -- Should be a source type
1525   = case tcSplitPredTy_maybe ty of {
1526         Nothing -> failWithTc (instTypeErr (ppr ty) empty) ;
1527         Just pred ->
1528
1529     case getClassPredTys_maybe pred of {
1530         Nothing -> failWithTc (instTypeErr (pprPred pred) empty) ;
1531         Just (clas,tys) -> do
1532
1533     dflags <- getDOpts
1534     check_inst_head dflags clas tys
1535     return (clas, tys)
1536     }}
1537
1538 check_inst_head :: DynFlags -> Class -> [Type] -> TcM ()
1539 check_inst_head dflags clas tys
1540   = do { -- If GlasgowExts then check at least one isn't a type variable
1541        ; checkTc (dopt Opt_TypeSynonymInstances dflags ||
1542                   all tcInstHeadTyNotSynonym tys)
1543                  (instTypeErr (pprClassPred clas tys) head_type_synonym_msg)
1544        ; checkTc (dopt Opt_FlexibleInstances dflags ||
1545                   all tcInstHeadTyAppAllTyVars tys)
1546                  (instTypeErr (pprClassPred clas tys) head_type_args_tyvars_msg)
1547        ; checkTc (dopt Opt_MultiParamTypeClasses dflags ||
1548                   isSingleton tys)
1549                  (instTypeErr (pprClassPred clas tys) head_one_type_msg)
1550          -- May not contain type family applications
1551        ; mapM_ checkTyFamFreeness tys
1552
1553        ; mapM_ checkValidMonoType tys
1554         -- For now, I only allow tau-types (not polytypes) in
1555         -- the head of an instance decl.
1556         --      E.g.  instance C (forall a. a->a) is rejected
1557         -- One could imagine generalising that, but I'm not sure
1558         -- what all the consequences might be
1559        }
1560
1561   where
1562     head_type_synonym_msg = parens (
1563                 text "All instance types must be of the form (T t1 ... tn)" $$
1564                 text "where T is not a synonym." $$
1565                 text "Use -XTypeSynonymInstances if you want to disable this.")
1566
1567     head_type_args_tyvars_msg = parens (vcat [
1568                 text "All instance types must be of the form (T a1 ... an)",
1569                 text "where a1 ... an are type *variables*,",
1570                 text "and each type variable appears at most once in the instance head.",
1571                 text "Use -XFlexibleInstances if you want to disable this."])
1572
1573     head_one_type_msg = parens (
1574                 text "Only one type can be given in an instance head." $$
1575                 text "Use -XMultiParamTypeClasses if you want to allow more.")
1576
1577 instTypeErr :: SDoc -> SDoc -> SDoc
1578 instTypeErr pp_ty msg
1579   = sep [ptext (sLit "Illegal instance declaration for") <+> quotes pp_ty,
1580          nest 4 msg]
1581 \end{code}
1582
1583
1584 %************************************************************************
1585 %*                                                                      *
1586 \subsection{Checking instance for termination}
1587 %*                                                                      *
1588 %************************************************************************
1589
1590
1591 \begin{code}
1592 checkValidInstance :: [TyVar] -> ThetaType -> Class -> [TcType] -> TcM ()
1593 checkValidInstance tyvars theta clas inst_tys
1594   = do  { undecidable_ok <- doptM Opt_UndecidableInstances
1595
1596         ; checkValidTheta InstThetaCtxt theta
1597         ; checkAmbiguity tyvars theta (tyVarsOfTypes inst_tys)
1598
1599         -- Check that instance inference will terminate (if we care)
1600         -- For Haskell 98 this will already have been done by checkValidTheta,
1601         -- but as we may be using other extensions we need to check.
1602         ; unless undecidable_ok $
1603           mapM_ addErrTc (checkInstTermination inst_tys theta)
1604
1605         -- The Coverage Condition
1606         ; checkTc (undecidable_ok || checkInstCoverage clas inst_tys)
1607                   (instTypeErr (pprClassPred clas inst_tys) msg)
1608         }
1609   where
1610     msg  = parens (vcat [ptext (sLit "the Coverage Condition fails for one of the functional dependencies;"),
1611                          undecidableMsg])
1612 \end{code}
1613
1614 Termination test: the so-called "Paterson conditions" (see Section 5 of
1615 "Understanding functionsl dependencies via Constraint Handling Rules,
1616 JFP Jan 2007).
1617
1618 We check that each assertion in the context satisfies:
1619  (1) no variable has more occurrences in the assertion than in the head, and
1620  (2) the assertion has fewer constructors and variables (taken together
1621      and counting repetitions) than the head.
1622 This is only needed with -fglasgow-exts, as Haskell 98 restrictions
1623 (which have already been checked) guarantee termination.
1624
1625 The underlying idea is that
1626
1627     for any ground substitution, each assertion in the
1628     context has fewer type constructors than the head.
1629
1630
1631 \begin{code}
1632 checkInstTermination :: [TcType] -> ThetaType -> [Message]
1633 checkInstTermination tys theta
1634   = mapCatMaybes check theta
1635   where
1636    fvs  = fvTypes tys
1637    size = sizeTypes tys
1638    check pred
1639       | not (null (fvPred pred \\ fvs))
1640       = Just (predUndecErr pred nomoreMsg $$ parens undecidableMsg)
1641       | sizePred pred >= size
1642       = Just (predUndecErr pred smallerMsg $$ parens undecidableMsg)
1643       | otherwise
1644       = Nothing
1645
1646 predUndecErr :: PredType -> SDoc -> SDoc
1647 predUndecErr pred msg = sep [msg,
1648                         nest 2 (ptext (sLit "in the constraint:") <+> pprPred pred)]
1649
1650 nomoreMsg, smallerMsg, undecidableMsg :: SDoc
1651 nomoreMsg = ptext (sLit "Variable occurs more often in a constraint than in the instance head")
1652 smallerMsg = ptext (sLit "Constraint is no smaller than the instance head")
1653 undecidableMsg = ptext (sLit "Use -XUndecidableInstances to permit this")
1654 \end{code}
1655
1656
1657 %************************************************************************
1658 %*                                                                      *
1659         Checking the context of a derived instance declaration
1660 %*                                                                      *
1661 %************************************************************************
1662
1663 Note [Exotic derived instance contexts]
1664 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1665 In a 'derived' instance declaration, we *infer* the context.  It's a
1666 bit unclear what rules we should apply for this; the Haskell report is
1667 silent.  Obviously, constraints like (Eq a) are fine, but what about
1668         data T f a = MkT (f a) deriving( Eq )
1669 where we'd get an Eq (f a) constraint.  That's probably fine too.
1670
1671 One could go further: consider
1672         data T a b c = MkT (Foo a b c) deriving( Eq )
1673         instance (C Int a, Eq b, Eq c) => Eq (Foo a b c)
1674
1675 Notice that this instance (just) satisfies the Paterson termination
1676 conditions.  Then we *could* derive an instance decl like this:
1677
1678         instance (C Int a, Eq b, Eq c) => Eq (T a b c)
1679
1680 even though there is no instance for (C Int a), because there just
1681 *might* be an instance for, say, (C Int Bool) at a site where we
1682 need the equality instance for T's.
1683
1684 However, this seems pretty exotic, and it's quite tricky to allow
1685 this, and yet give sensible error messages in the (much more common)
1686 case where we really want that instance decl for C.
1687
1688 So for now we simply require that the derived instance context
1689 should have only type-variable constraints.
1690
1691 Here is another example:
1692         data Fix f = In (f (Fix f)) deriving( Eq )
1693 Here, if we are prepared to allow -XUndecidableInstances we
1694 could derive the instance
1695         instance Eq (f (Fix f)) => Eq (Fix f)
1696 but this is so delicate that I don't think it should happen inside
1697 'deriving'. If you want this, write it yourself!
1698
1699 NB: if you want to lift this condition, make sure you still meet the
1700 termination conditions!  If not, the deriving mechanism generates
1701 larger and larger constraints.  Example:
1702   data Succ a = S a
1703   data Seq a = Cons a (Seq (Succ a)) | Nil deriving Show
1704
1705 Note the lack of a Show instance for Succ.  First we'll generate
1706   instance (Show (Succ a), Show a) => Show (Seq a)
1707 and then
1708   instance (Show (Succ (Succ a)), Show (Succ a), Show a) => Show (Seq a)
1709 and so on.  Instead we want to complain of no instance for (Show (Succ a)).
1710
1711 The bottom line
1712 ~~~~~~~~~~~~~~~
1713 Allow constraints which consist only of type variables, with no repeats.
1714
1715 \begin{code}
1716 validDerivPred :: PredType -> Bool
1717 validDerivPred (ClassP _ tys) = hasNoDups fvs && sizeTypes tys == length fvs
1718                               where fvs = fvTypes tys
1719 validDerivPred _              = False
1720 \end{code}
1721
1722 %************************************************************************
1723 %*                                                                      *
1724         Checking type instance well-formedness and termination
1725 %*                                                                      *
1726 %************************************************************************
1727
1728 \begin{code}
1729 -- Check that a "type instance" is well-formed (which includes decidability
1730 -- unless -XUndecidableInstances is given).
1731 --
1732 checkValidTypeInst :: [Type] -> Type -> TcM ()
1733 checkValidTypeInst typats rhs
1734   = do { -- left-hand side contains no type family applications
1735          -- (vanilla synonyms are fine, though)
1736        ; mapM_ checkTyFamFreeness typats
1737
1738          -- the right-hand side is a tau type
1739        ; checkValidMonoType rhs
1740
1741          -- we have a decidable instance unless otherwise permitted
1742        ; undecidable_ok <- doptM Opt_UndecidableInstances
1743        ; unless undecidable_ok $
1744            mapM_ addErrTc (checkFamInst typats (tyFamInsts rhs))
1745        }
1746
1747 -- Make sure that each type family instance is
1748 --   (1) strictly smaller than the lhs,
1749 --   (2) mentions no type variable more often than the lhs, and
1750 --   (3) does not contain any further type family instances.
1751 --
1752 checkFamInst :: [Type]                  -- lhs
1753              -> [(TyCon, [Type])]       -- type family instances
1754              -> [Message]
1755 checkFamInst lhsTys famInsts
1756   = mapCatMaybes check famInsts
1757   where
1758    size = sizeTypes lhsTys
1759    fvs  = fvTypes lhsTys
1760    check (tc, tys)
1761       | not (all isTyFamFree tys)
1762       = Just (famInstUndecErr famInst nestedMsg $$ parens undecidableMsg)
1763       | not (null (fvTypes tys \\ fvs))
1764       = Just (famInstUndecErr famInst nomoreVarMsg $$ parens undecidableMsg)
1765       | size <= sizeTypes tys
1766       = Just (famInstUndecErr famInst smallerAppMsg $$ parens undecidableMsg)
1767       | otherwise
1768       = Nothing
1769       where
1770         famInst = TyConApp tc tys
1771
1772 -- Ensure that no type family instances occur in a type.
1773 --
1774 checkTyFamFreeness :: Type -> TcM ()
1775 checkTyFamFreeness ty
1776   = checkTc (isTyFamFree ty) $
1777       tyFamInstIllegalErr ty
1778
1779 -- Check that a type does not contain any type family applications.
1780 --
1781 isTyFamFree :: Type -> Bool
1782 isTyFamFree = null . tyFamInsts
1783
1784 -- Error messages
1785
1786 tyFamInstIllegalErr :: Type -> SDoc
1787 tyFamInstIllegalErr ty
1788   = hang (ptext (sLit "Illegal type synonym family application in instance") <>
1789          colon) 4 $
1790       ppr ty
1791
1792 famInstUndecErr :: Type -> SDoc -> SDoc
1793 famInstUndecErr ty msg
1794   = sep [msg,
1795          nest 2 (ptext (sLit "in the type family application:") <+>
1796                  pprType ty)]
1797
1798 nestedMsg, nomoreVarMsg, smallerAppMsg :: SDoc
1799 nestedMsg     = ptext (sLit "Nested type family application")
1800 nomoreVarMsg  = ptext (sLit "Variable occurs more often than in instance head")
1801 smallerAppMsg = ptext (sLit "Application is no smaller than the instance head")
1802 \end{code}
1803
1804
1805 %************************************************************************
1806 %*                                                                      *
1807 \subsection{Auxiliary functions}
1808 %*                                                                      *
1809 %************************************************************************
1810
1811 \begin{code}
1812 -- Free variables of a type, retaining repetitions, and expanding synonyms
1813 fvType :: Type -> [TyVar]
1814 fvType ty | Just exp_ty <- tcView ty = fvType exp_ty
1815 fvType (TyVarTy tv)        = [tv]
1816 fvType (TyConApp _ tys)    = fvTypes tys
1817 fvType (PredTy pred)       = fvPred pred
1818 fvType (FunTy arg res)     = fvType arg ++ fvType res
1819 fvType (AppTy fun arg)     = fvType fun ++ fvType arg
1820 fvType (ForAllTy tyvar ty) = filter (/= tyvar) (fvType ty)
1821
1822 fvTypes :: [Type] -> [TyVar]
1823 fvTypes tys                = concat (map fvType tys)
1824
1825 fvPred :: PredType -> [TyVar]
1826 fvPred (ClassP _ tys')     = fvTypes tys'
1827 fvPred (IParam _ ty)       = fvType ty
1828 fvPred (EqPred ty1 ty2)    = fvType ty1 ++ fvType ty2
1829
1830 -- Size of a type: the number of variables and constructors
1831 sizeType :: Type -> Int
1832 sizeType ty | Just exp_ty <- tcView ty = sizeType exp_ty
1833 sizeType (TyVarTy _)       = 1
1834 sizeType (TyConApp _ tys)  = sizeTypes tys + 1
1835 sizeType (PredTy pred)     = sizePred pred
1836 sizeType (FunTy arg res)   = sizeType arg + sizeType res + 1
1837 sizeType (AppTy fun arg)   = sizeType fun + sizeType arg
1838 sizeType (ForAllTy _ ty)   = sizeType ty
1839
1840 sizeTypes :: [Type] -> Int
1841 sizeTypes xs               = sum (map sizeType xs)
1842
1843 sizePred :: PredType -> Int
1844 sizePred (ClassP _ tys')   = sizeTypes tys'
1845 sizePred (IParam _ ty)     = sizeType ty
1846 sizePred (EqPred ty1 ty2)  = sizeType ty1 + sizeType ty2
1847 \end{code}