compiler/typecheck/TcPat.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 TcPat: Typechecking patterns
   7
   8 \begin{code}
   9 module TcPat ( tcLetPat, tcLamPat, tcLamPats, tcOverloadedLit,
  10                addDataConStupidTheta, badFieldCon, polyPatSig ) where
  11
  12 #include "HsVersions.h"
  13
  14 import {-# SOURCE #-}   TcExpr( tcSyntaxOp )
  15
  16 import HsSyn
  17 import TcHsSyn
  18 import TcRnMonad
  19 import Inst
  20 import Id
  21 import Var
  22 import CoreFVs
  23 import Name
  24 import TcSimplify
  25 import TcEnv
  26 import TcMType
  27 import TcType
  28 import VarSet
  29 import TcUnify
  30 import TcHsType
  31 import TysWiredIn
  32 import TcGadt
  33 import Type
  34 import StaticFlags
  35 import TyCon
  36 import DataCon
  37 import PrelNames
  38 import BasicTypes hiding (SuccessFlag(..))
  39 import SrcLoc
  40 import ErrUtils
  41 import Util
  42 import Maybes
  43 import Outputable
  44 import FastString
  45 \end{code}
  46
  47
  48 %************************************************************************
  49 %*                                                                      *
  50                 External interface
  51 %*                                                                      *
  52 %************************************************************************
  53
  54 \begin{code}
  55 tcLetPat :: (Name -> Maybe TcRhoType)
  56          -> LPat Name -> BoxySigmaType
  57          -> TcM a
  58          -> TcM (LPat TcId, a)
  59 tcLetPat sig_fn pat pat_ty thing_inside
  60   = do  { let init_state = PS { pat_ctxt = LetPat sig_fn,
  61                                 pat_reft = emptyRefinement }
  62         ; (pat', ex_tvs, res) <- tc_lpat pat pat_ty init_state (\ _ -> thing_inside)
  63
  64         -- Don't know how to deal with pattern-bound existentials yet
  65         ; checkTc (null ex_tvs) (existentialExplode pat)
  66
  67         ; return (pat', res) }
  68
  69 -----------------
  70 tcLamPats :: [LPat Name]                                -- Patterns,
  71           -> [BoxySigmaType]                            --   and their types
  72           -> BoxyRhoType                                -- Result type,
  73           -> ((Refinement, BoxyRhoType) -> TcM a)       --   and the checker for the body
  74           -> TcM ([LPat TcId], a)
  75
  76 -- This is the externally-callable wrapper function
  77 -- Typecheck the patterns, extend the environment to bind the variables,
  78 -- do the thing inside, use any existentially-bound dictionaries to
  79 -- discharge parts of the returning LIE, and deal with pattern type
  80 -- signatures
  81
  82 --   1. Initialise the PatState
  83 --   2. Check the patterns
  84 --   3. Apply the refinement to the environment and result type
  85 --   4. Check the body
  86 --   5. Check that no existentials escape
  87
  88 tcLamPats pats tys res_ty thing_inside
  89   = tc_lam_pats (zipEqual "tcLamPats" pats tys)
  90                 (emptyRefinement, res_ty) thing_inside
  91
  92 tcLamPat :: LPat Name -> BoxySigmaType
  93          -> (Refinement,BoxyRhoType)            -- Result type
  94          -> ((Refinement,BoxyRhoType) -> TcM a) -- Checker for body, given its result type
  95          -> TcM (LPat TcId, a)
  96 tcLamPat pat pat_ty res_ty thing_inside
  97   = do  { ([pat'],thing) <- tc_lam_pats [(pat, pat_ty)] res_ty thing_inside
  98         ; return (pat', thing) }
  99
 100 -----------------
 101 tc_lam_pats :: [(LPat Name,BoxySigmaType)]
 102             -> (Refinement,BoxyRhoType)                 -- Result type
 103             -> ((Refinement,BoxyRhoType) -> TcM a)      -- Checker for body, given its result type
 104             -> TcM ([LPat TcId], a)
 105 tc_lam_pats pat_ty_prs (reft, res_ty) thing_inside
 106   =  do { let init_state = PS { pat_ctxt = LamPat, pat_reft = reft }
 107
 108         ; (pats', ex_tvs, res) <- tcMultiple tc_lpat_pr pat_ty_prs init_state $ \ pstate' ->
 109                                   refineEnvironment (pat_reft pstate') $
 110                                   thing_inside (pat_reft pstate', res_ty)
 111
 112         ; let tys = map snd pat_ty_prs
 113         ; tcCheckExistentialPat pats' ex_tvs tys res_ty
 114
 115         ; returnM (pats', res) }
 116
 117
 118 -----------------
 119 tcCheckExistentialPat :: [LPat TcId]            -- Patterns (just for error message)
 120                       -> [TcTyVar]              -- Existentially quantified tyvars bound by pattern
 121                       -> [BoxySigmaType]        -- Types of the patterns
 122                       -> BoxyRhoType            -- Type of the body of the match
 123                                                 -- Tyvars in either of these must not escape
 124                       -> TcM ()
 125 -- NB: we *must* pass "pats_tys" not just "body_ty" to tcCheckExistentialPat
 126 -- For example, we must reject this program:
 127 --      data C = forall a. C (a -> Int)
 128 --      f (C g) x = g x
 129 -- Here, result_ty will be simply Int, but expected_ty is (C -> a -> Int).
 130
 131 tcCheckExistentialPat pats [] pat_tys body_ty
 132   = return ()   -- Short cut for case when there are no existentials
 133
 134 tcCheckExistentialPat pats ex_tvs pat_tys body_ty
 135   = addErrCtxtM (sigPatCtxt pats ex_tvs pat_tys body_ty)        $
 136     checkSigTyVarsWrt (tcTyVarsOfTypes (body_ty:pat_tys)) ex_tvs
 137
 138 data PatState = PS {
 139         pat_ctxt :: PatCtxt,
 140         pat_reft :: Refinement  -- Binds rigid TcTyVars to their refinements
 141   }
 142
 143 data PatCtxt
 144   = LamPat
 145   | LetPat (Name -> Maybe TcRhoType)    -- Used for let(rec) bindings
 146
 147 patSigCtxt :: PatState -> UserTypeCtxt
 148 patSigCtxt (PS { pat_ctxt = LetPat _ }) = BindPatSigCtxt
 149 patSigCtxt other                        = LamPatSigCtxt
 150 \end{code}
 151
 152
 153
 154 %************************************************************************
 155 %*                                                                      *
 156                 Binders
 157 %*                                                                      *
 158 %************************************************************************
 159
 160 \begin{code}
 161 tcPatBndr :: PatState -> Name -> BoxySigmaType -> TcM TcId
 162 tcPatBndr (PS { pat_ctxt = LamPat }) bndr_name pat_ty
 163   = do  { pat_ty' <- unBoxPatBndrType pat_ty bndr_name
 164                 -- We have an undecorated binder, so we do rule ABS1,
 165                 -- by unboxing the boxy type, forcing any un-filled-in
 166                 -- boxes to become monotypes
 167                 -- NB that pat_ty' can still be a polytype:
 168                 --      data T = MkT (forall a. a->a)
 169                 --      f t = case t of { MkT g -> ... }
 170                 -- Here, the 'g' must get type (forall a. a->a) from the
 171                 -- MkT context
 172         ; return (Id.mkLocalId bndr_name pat_ty') }
 173
 174 tcPatBndr (PS { pat_ctxt = LetPat lookup_sig }) bndr_name pat_ty
 175   | Just mono_ty <- lookup_sig bndr_name
 176   = do  { mono_name <- newLocalName bndr_name
 177         ; boxyUnify mono_ty pat_ty
 178         ; return (Id.mkLocalId mono_name mono_ty) }
 179
 180   | otherwise
 181   = do  { pat_ty' <- unBoxPatBndrType pat_ty bndr_name
 182         ; mono_name <- newLocalName bndr_name
 183         ; return (Id.mkLocalId mono_name pat_ty') }
 184
 185
 186 -------------------
 187 bindInstsOfPatId :: TcId -> TcM a -> TcM (a, LHsBinds TcId)
 188 bindInstsOfPatId id thing_inside
 189   | not (isOverloadedTy (idType id))
 190   = do { res <- thing_inside; return (res, emptyLHsBinds) }
 191   | otherwise
 192   = do  { (res, lie) <- getLIE thing_inside
 193         ; binds <- bindInstsOfLocalFuns lie [id]
 194         ; return (res, binds) }
 195
 196 -------------------
 197 unBoxPatBndrType  ty name = unBoxArgType ty (ptext SLIT("The variable") <+> quotes (ppr name))
 198 unBoxWildCardType ty      = unBoxArgType ty (ptext SLIT("A wild-card pattern"))
 199
 200 unBoxArgType :: BoxyType -> SDoc -> TcM TcType
 201 -- In addition to calling unbox, unBoxArgType ensures that the type is of ArgTypeKind;
 202 -- that is, it can't be an unboxed tuple.  For example,
 203 --      case (f x) of r -> ...
 204 -- should fail if 'f' returns an unboxed tuple.
 205 unBoxArgType ty pp_this
 206   = do  { ty' <- unBox ty       -- Returns a zonked type
 207
 208         -- Neither conditional is strictly necesssary (the unify alone will do)
 209         -- but they improve error messages, and allocate fewer tyvars
 210         ; if isUnboxedTupleType ty' then
 211                 failWithTc msg
 212           else if isSubArgTypeKind (typeKind ty') then
 213                 return ty'
 214           else do       -- OpenTypeKind, so constrain it
 215         { ty2 <- newFlexiTyVarTy argTypeKind
 216         ; unifyType ty' ty2
 217         ; return ty' }}
 218   where
 219     msg = pp_this <+> ptext SLIT("cannot be bound to an unboxed tuple")
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225                 The main worker functions
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 Note [Nesting]
 230 ~~~~~~~~~~~~~~
 231 tcPat takes a "thing inside" over which the patter scopes.  This is partly
 232 so that tcPat can extend the environment for the thing_inside, but also
 233 so that constraints arising in the thing_inside can be discharged by the
 234 pattern.
 235
 236 This does not work so well for the ErrCtxt carried by the monad: we don't
 237 want the error-context for the pattern to scope over the RHS.
 238 Hence the getErrCtxt/setErrCtxt stuff in tc_lpats.
 239
 240 \begin{code}
 241 --------------------
 242 type Checker inp out =  forall r.
 243                           inp
 244                        -> PatState
 245                        -> (PatState -> TcM r)
 246                        -> TcM (out, [TcTyVar], r)
 247
 248 tcMultiple :: Checker inp out -> Checker [inp] [out]
 249 tcMultiple tc_pat args pstate thing_inside
 250   = do  { err_ctxt <- getErrCtxt
 251         ; let loop pstate []
 252                 = do { res <- thing_inside pstate
 253                      ; return ([], [], res) }
 254
 255               loop pstate (arg:args)
 256                 = do { (p', p_tvs, (ps', ps_tvs, res))
 257                                 <- tc_pat arg pstate $ \ pstate' ->
 258                                    setErrCtxt err_ctxt $
 259                                    loop pstate' args
 260                 -- setErrCtxt: restore context before doing the next pattern
 261                 -- See note [Nesting] above
 262
 263                      ; return (p':ps', p_tvs ++ ps_tvs, res) }
 264
 265         ; loop pstate args }
 266
 267 --------------------
 268 tc_lpat_pr :: (LPat Name, BoxySigmaType)
 269            -> PatState
 270            -> (PatState -> TcM a)
 271            -> TcM (LPat TcId, [TcTyVar], a)
 272 tc_lpat_pr (pat, ty) = tc_lpat pat ty
 273
 274 tc_lpat :: LPat Name
 275         -> BoxySigmaType
 276         -> PatState
 277         -> (PatState -> TcM a)
 278         -> TcM (LPat TcId, [TcTyVar], a)
 279 tc_lpat (L span pat) pat_ty pstate thing_inside
 280   = setSrcSpan span               $
 281     maybeAddErrCtxt (patCtxt pat) $
 282     do  { let mb_reft = refineType (pat_reft pstate) pat_ty
 283               pat_ty' = case mb_reft of { Just (_, ty') -> ty'; Nothing -> pat_ty }
 284
 285                 -- Make sure the result type reflects the current refinement
 286                 -- We must do this here, so that it correctly ``sees'' all
 287                 -- the refinements to the left.  Example:
 288                 -- Suppose C :: forall a. T a -> a -> Foo
 289                 -- Pattern      C a p1 True
 290                 -- So p1 might refine 'a' to True, and the True
 291                 -- pattern had better see it.
 292
 293         ; (pat', tvs, res) <- tc_pat pstate pat pat_ty' thing_inside
 294         ; let final_pat = case mb_reft of
 295                                 Nothing     -> pat'
 296                                 Just (co,_) -> CoPat (WpCo co) pat' pat_ty
 297         ; return (L span final_pat, tvs, res) }
 298
 299 --------------------
 300 tc_pat  :: PatState
 301         -> Pat Name -> BoxySigmaType    -- Fully refined result type
 302         -> (PatState -> TcM a)  -- Thing inside
 303         -> TcM (Pat TcId,       -- Translated pattern
 304                 [TcTyVar],      -- Existential binders
 305                 a)              -- Result of thing inside
 306
 307 tc_pat pstate (VarPat name) pat_ty thing_inside
 308   = do  { id <- tcPatBndr pstate name pat_ty
 309         ; (res, binds) <- bindInstsOfPatId id $
 310                           tcExtendIdEnv1 name id $
 311                           (traceTc (text "binding" <+> ppr name <+> ppr (idType id))
 312                            >> thing_inside pstate)
 313         ; let pat' | isEmptyLHsBinds binds = VarPat id
 314                    | otherwise             = VarPatOut id binds
 315         ; return (pat', [], res) }
 316
 317 tc_pat pstate (ParPat pat) pat_ty thing_inside
 318   = do  { (pat', tvs, res) <- tc_lpat pat pat_ty pstate thing_inside
 319         ; return (ParPat pat', tvs, res) }
 320
 321 tc_pat pstate (BangPat pat) pat_ty thing_inside
 322   = do  { (pat', tvs, res) <- tc_lpat pat pat_ty pstate thing_inside
 323         ; return (BangPat pat', tvs, res) }
 324
 325 -- There's a wrinkle with irrefutable patterns, namely that we
 326 -- must not propagate type refinement from them.  For example
 327 --      data T a where { T1 :: Int -> T Int; ... }
 328 --      f :: T a -> Int -> a
 329 --      f ~(T1 i) y = y
 330 -- It's obviously not sound to refine a to Int in the right
 331 -- hand side, because the arugment might not match T1 at all!
 332 --
 333 -- Nor should a lazy pattern bind any existential type variables
 334 -- because they won't be in scope when we do the desugaring
 335 tc_pat pstate lpat@(LazyPat pat) pat_ty thing_inside
 336   = do  { (pat', pat_tvs, res) <- tc_lpat pat pat_ty pstate $ \ _ ->
 337                                   thing_inside pstate
 338                                         -- Ignore refined pstate',
 339                                         -- revert to pstate
 340         -- Check no existentials
 341         ; if (null pat_tvs) then return ()
 342           else lazyPatErr lpat pat_tvs
 343
 344         -- Check that the pattern has a lifted type
 345         ; pat_tv <- newBoxyTyVar liftedTypeKind
 346         ; boxyUnify pat_ty (mkTyVarTy pat_tv)
 347
 348         ; return (LazyPat pat', [], res) }
 349
 350 tc_pat pstate (WildPat _) pat_ty thing_inside
 351   = do  { pat_ty' <- unBoxWildCardType pat_ty   -- Make sure it's filled in with monotypes
 352         ; res <- thing_inside pstate
 353         ; return (WildPat pat_ty', [], res) }
 354
 355 tc_pat pstate (AsPat (L nm_loc name) pat) pat_ty thing_inside
 356   = do  { bndr_id <- setSrcSpan nm_loc (tcPatBndr pstate name pat_ty)
 357         ; (pat', tvs, res) <- tcExtendIdEnv1 name bndr_id $
 358                               tc_lpat pat (idType bndr_id) pstate thing_inside
 359             -- NB: if we do inference on:
 360             --          \ (y@(x::forall a. a->a)) = e
 361             -- we'll fail.  The as-pattern infers a monotype for 'y', which then
 362             -- fails to unify with the polymorphic type for 'x'.  This could
 363             -- perhaps be fixed, but only with a bit more work.
 364             --
 365             -- If you fix it, don't forget the bindInstsOfPatIds!
 366         ; return (AsPat (L nm_loc bndr_id) pat', tvs, res) }
 367
 368 -- Type signatures in patterns
 369 -- See Note [Pattern coercions] below
 370 tc_pat pstate (SigPatIn pat sig_ty) pat_ty thing_inside
 371   = do  { (inner_ty, tv_binds) <- tcPatSig (patSigCtxt pstate) sig_ty pat_ty
 372         ; (pat', tvs, res) <- tcExtendTyVarEnv2 tv_binds $
 373                               tc_lpat pat inner_ty pstate thing_inside
 374         ; return (SigPatOut pat' inner_ty, tvs, res) }
 375
 376 tc_pat pstate pat@(TypePat ty) pat_ty thing_inside
 377   = failWithTc (badTypePat pat)
 378
 379 ------------------------
 380 -- Lists, tuples, arrays
 381 tc_pat pstate (ListPat pats _) pat_ty thing_inside
 382   = do  { elt_ty <- boxySplitListTy pat_ty
 383         ; (pats', pats_tvs, res) <- tcMultiple (\p -> tc_lpat p elt_ty)
 384                                                 pats pstate thing_inside
 385         ; return (ListPat pats' elt_ty, pats_tvs, res) }
 386
 387 tc_pat pstate (PArrPat pats _) pat_ty thing_inside
 388   = do  { [elt_ty] <- boxySplitTyConApp parrTyCon pat_ty
 389         ; (pats', pats_tvs, res) <- tcMultiple (\p -> tc_lpat p elt_ty)
 390                                                 pats pstate thing_inside
 391         ; ifM (null pats) (zapToMonotype pat_ty)        -- c.f. ExplicitPArr in TcExpr
 392         ; return (PArrPat pats' elt_ty, pats_tvs, res) }
 393
 394 tc_pat pstate (TuplePat pats boxity _) pat_ty thing_inside
 395   = do  { arg_tys <- boxySplitTyConApp (tupleTyCon boxity (length pats)) pat_ty
 396         ; (pats', pats_tvs, res) <- tcMultiple tc_lpat_pr (pats `zip` arg_tys)
 397                                                pstate thing_inside
 398
 399         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
 400         -- so that we can experiment with lazy tuple-matching.
 401         -- This is a pretty odd place to make the switch, but
 402         -- it was easy to do.
 403         ; let unmangled_result = TuplePat pats' boxity pat_ty
 404               possibly_mangled_result
 405                 | opt_IrrefutableTuples && isBoxed boxity = LazyPat (noLoc unmangled_result)
 406                 | otherwise                               = unmangled_result
 407
 408         ; ASSERT( length arg_tys == length pats )       -- Syntactically enforced
 409           return (possibly_mangled_result, pats_tvs, res) }
 410
 411 ------------------------
 412 -- Data constructors
 413 tc_pat pstate pat_in@(ConPatIn (L con_span con_name) arg_pats) pat_ty thing_inside
 414   = do  { data_con <- tcLookupDataCon con_name
 415         ; let tycon = dataConTyCon data_con
 416         ; tcConPat pstate con_span data_con tycon pat_ty arg_pats thing_inside }
 417
 418 ------------------------
 419 -- Literal patterns
 420 tc_pat pstate (LitPat simple_lit) pat_ty thing_inside
 421   = do  { boxyUnify (hsLitType simple_lit) pat_ty
 422         ; res <- thing_inside pstate
 423         ; returnM (LitPat simple_lit, [], res) }
 424
 425 ------------------------
 426 -- Overloaded patterns: n, and n+k
 427 tc_pat pstate pat@(NPat over_lit mb_neg eq _) pat_ty thing_inside
 428   = do  { let orig = LiteralOrigin over_lit
 429         ; lit'    <- tcOverloadedLit orig over_lit pat_ty
 430         ; eq'     <- tcSyntaxOp orig eq (mkFunTys [pat_ty, pat_ty] boolTy)
 431         ; mb_neg' <- case mb_neg of
 432                         Nothing  -> return Nothing      -- Positive literal
 433                         Just neg ->     -- Negative literal
 434                                         -- The 'negate' is re-mappable syntax
 435                             do { neg' <- tcSyntaxOp orig neg (mkFunTy pat_ty pat_ty)
 436                                ; return (Just neg') }
 437         ; res <- thing_inside pstate
 438         ; returnM (NPat lit' mb_neg' eq' pat_ty, [], res) }
 439
 440 tc_pat pstate pat@(NPlusKPat (L nm_loc name) lit ge minus) pat_ty thing_inside
 441   = do  { bndr_id <- setSrcSpan nm_loc (tcPatBndr pstate name pat_ty)
 442         ; let pat_ty' = idType bndr_id
 443               orig    = LiteralOrigin lit
 444         ; lit' <- tcOverloadedLit orig lit pat_ty'
 445
 446         -- The '>=' and '-' parts are re-mappable syntax
 447         ; ge'    <- tcSyntaxOp orig ge    (mkFunTys [pat_ty', pat_ty'] boolTy)
 448         ; minus' <- tcSyntaxOp orig minus (mkFunTys [pat_ty', pat_ty'] pat_ty')
 449
 450         -- The Report says that n+k patterns must be in Integral
 451         -- We may not want this when using re-mappable syntax, though (ToDo?)
 452         ; icls <- tcLookupClass integralClassName
 453         ; instStupidTheta orig [mkClassPred icls [pat_ty']]
 454
 455         ; res <- tcExtendIdEnv1 name bndr_id (thing_inside pstate)
 456         ; returnM (NPlusKPat (L nm_loc bndr_id) lit' ge' minus', [], res) }
 457
 458 tc_pat _ _other_pat _ _ = panic "tc_pat"        -- DictPat, ConPatOut, SigPatOut, VarPatOut
 459 \end{code}
 460
 461
 462 %************************************************************************
 463 %*                                                                      *
 464         Most of the work for constructors is here
 465         (the rest is in the ConPatIn case of tc_pat)
 466 %*                                                                      *
 467 %************************************************************************
 468
 469 [Pattern matching indexed data types]
 470 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 471 Consider the following declarations:
 472
 473   data family Map k :: * -> *
 474   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 475
 476 and a case expression
 477
 478   case x :: Map (Int, c) w of MapPair m -> ...
 479
 480 As explained by [Wrappers for data instance tycons] in MkIds.lhs, the
 481 worker/wrapper types for MapPair are
 482
 483   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 484   $wMapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 485
 486 So, the type of the scrutinee is Map (Int, c) w, but the tycon of MapPair is
 487 :R123Map, which means the straight use of boxySplitTyConApp would give a type
 488 error.  Hence, the smart wrapper function boxySplitTyConAppWithFamily calls
 489 boxySplitTyConApp with the family tycon Map instead, which gives us the family
 490 type list {(Int, c), w}.  To get the correct split for :R123Map, we need to
 491 unify the family type list {(Int, c), w} with the instance types {(a, b), v}
 492 (provided by tyConFamInst_maybe together with the family tycon).  This
 493 unification yields the substitution [a -> Int, b -> c, v -> w], which gives us
 494 the split arguments for the representation tycon :R123Map as {Int, c, w}
 495
 496 In other words, boxySplitTyConAppWithFamily implicitly takes the coercion
 497
 498   Co123Map a b v :: {Map (a, b) v :=: :R123Map a b v}
 499
 500 moving between representation and family type into account.  To produce type
 501 correct Core, this coercion needs to be used to case the type of the scrutinee
 502 from the family to the representation type.  This is achieved by
 503 unwrapFamInstScrutinee using a CoPat around the result pattern.
 504
 505 Now it might appear seem as if we could have used the existing GADT type
 506 refinement infrastructure of refineAlt and friends instead of the explicit
 507 unification and CoPat generation.  However, that would be wrong.  Why?  The
 508 whole point of GADT refinement is that the refinement is local to the case
 509 alternative.  In contrast, the substitution generated by the unification of
 510 the family type list and instance types needs to be propagated to the outside.
 511 Imagine that in the above example, the type of the scrutinee would have been
 512 (Map x w), then we would have unified {x, w} with {(a, b), v}, yielding the
 513 substitution [x -> (a, b), v -> w].  In contrast to GADT matching, the
 514 instantiation of x with (a, b) must be global; ie, it must be valid in *all*
 515 alternatives of the case expression, whereas in the GADT case it might vary
 516 between alternatives.
 517
 518 In fact, if we have a data instance declaration defining a GADT, eq_spec will
 519 be non-empty and we will get a mixture of global instantiations and local
 520 refinement from a single match.  This neatly reflects that, as soon as we
 521 have constrained the type of the scrutinee to the required type index, all
 522 further type refinement is local to the alternative.
 523
 524 \begin{code}
 525 --      Running example:
 526 -- MkT :: forall a b c. (a:=:[b]) => b -> c -> T a
 527 --       with scrutinee of type (T ty)
 528
 529 tcConPat :: PatState -> SrcSpan -> DataCon -> TyCon
 530          -> BoxySigmaType       -- Type of the pattern
 531          -> HsConDetails Name (LPat Name) -> (PatState -> TcM a)
 532          -> TcM (Pat TcId, [TcTyVar], a)
 533 tcConPat pstate con_span data_con tycon pat_ty arg_pats thing_inside
 534   = do  { let (univ_tvs, ex_tvs, eq_spec, theta, arg_tys) = dataConFullSig data_con
 535               skol_info = PatSkol data_con
 536               origin    = SigOrigin skol_info
 537
 538           -- Instantiate the constructor type variables [a->ty]
 539         ; ctxt_res_tys <- boxySplitTyConAppWithFamily tycon pat_ty
 540         ; ex_tvs' <- tcInstSkolTyVars skol_info ex_tvs  -- Get location from monad,
 541                                                         -- not from ex_tvs
 542         ; let tenv     = zipTopTvSubst (univ_tvs ++ ex_tvs)
 543                                       (ctxt_res_tys ++ mkTyVarTys ex_tvs')
 544               eq_spec' = substEqSpec tenv eq_spec
 545               theta'   = substTheta  tenv theta
 546               arg_tys' = substTys    tenv arg_tys
 547
 548         ; co_vars <- newCoVars eq_spec' -- Make coercion variables
 549         ; pstate' <- refineAlt data_con pstate ex_tvs' co_vars pat_ty
 550
 551         ; ((arg_pats', inner_tvs, res), lie_req) <- getLIE $
 552                 tcConArgs data_con arg_tys' arg_pats pstate' thing_inside
 553
 554         ; loc <- getInstLoc origin
 555         ; dicts <- newDictBndrs loc theta'
 556         ; dict_binds <- tcSimplifyCheckPat loc co_vars (pat_reft pstate')
 557                                            ex_tvs' dicts lie_req
 558
 559         ; addDataConStupidTheta data_con ctxt_res_tys
 560
 561         ; return
 562             (unwrapFamInstScrutinee tycon ctxt_res_tys $
 563                ConPatOut { pat_con = L con_span data_con,
 564                            pat_tvs = ex_tvs' ++ co_vars,
 565                            pat_dicts = map instToId dicts,
 566                            pat_binds = dict_binds,
 567                            pat_args = arg_pats', pat_ty = pat_ty },
 568              ex_tvs' ++ inner_tvs, res)
 569         }
 570   where
 571     -- Split against the family tycon if the pattern constructor belongs to a
 572     -- representation tycon.
 573     --
 574     boxySplitTyConAppWithFamily tycon pat_ty =
 575       traceTc traceMsg >>
 576       case tyConFamInst_maybe tycon of
 577         Nothing                   -> boxySplitTyConApp tycon pat_ty
 578         Just (fam_tycon, instTys) ->
 579           do { scrutinee_arg_tys <- boxySplitTyConApp fam_tycon pat_ty
 580              ; (_, freshTvs, subst) <- tcInstTyVars (tyConTyVars tycon)
 581              ; boxyUnifyList (substTys subst instTys) scrutinee_arg_tys
 582              ; return freshTvs
 583              }
 584       where
 585         traceMsg = sep [ text "tcConPat:boxySplitTyConAppWithFamily:" <+>
 586                          ppr tycon <+> ppr pat_ty
 587                        , text "  family instance:" <+>
 588                          ppr (tyConFamInst_maybe tycon)
 589                        ]
 590
 591     -- Wraps the pattern (which must be a ConPatOut pattern) in a coercion
 592     -- pattern if the tycon is an instance of a family.
 593     --
 594     unwrapFamInstScrutinee :: TyCon -> [Type] -> Pat Id -> Pat Id
 595     unwrapFamInstScrutinee tycon args pat
 596       | Just co_con <- tyConFamilyCoercion_maybe tycon
 597 --      , not (isNewTyCon tycon)       -- newtypes are explicitly unwrapped by
 598                                      -- the desugarer
 599           -- NB: We can use CoPat directly, rather than mkCoPat, as we know the
 600           --     coercion is not the identity; mkCoPat is inconvenient as it
 601           --     wants a located pattern.
 602       = CoPat (WpCo $ mkTyConApp co_con args)       -- co fam ty to repr ty
 603               (pat {pat_ty = mkTyConApp tycon args})    -- representation type
 604               pat_ty                                    -- family inst type
 605       | otherwise
 606       = pat
 607
 608
 609 tcConArgs :: DataCon -> [TcSigmaType]
 610           -> Checker (HsConDetails Name (LPat Name))
 611                      (HsConDetails Id (LPat Id))
 612
 613 tcConArgs data_con arg_tys (PrefixCon arg_pats) pstate thing_inside
 614   = do  { checkTc (con_arity == no_of_args)     -- Check correct arity
 615                   (arityErr "Constructor" data_con con_arity no_of_args)
 616         ; let pats_w_tys = zipEqual "tcConArgs" arg_pats arg_tys
 617         ; (arg_pats', tvs, res) <- tcMultiple tcConArg pats_w_tys
 618                                               pstate thing_inside
 619         ; return (PrefixCon arg_pats', tvs, res) }
 620   where
 621     con_arity  = dataConSourceArity data_con
 622     no_of_args = length arg_pats
 623
 624 tcConArgs data_con [arg_ty1,arg_ty2] (InfixCon p1 p2) pstate thing_inside
 625   = do  { checkTc (con_arity == 2)      -- Check correct arity
 626                   (arityErr "Constructor" data_con con_arity 2)
 627         ; ([p1',p2'], tvs, res) <- tcMultiple tcConArg [(p1,arg_ty1),(p2,arg_ty2)]
 628                                               pstate thing_inside
 629         ; return (InfixCon p1' p2', tvs, res) }
 630   where
 631     con_arity  = dataConSourceArity data_con
 632
 633 tcConArgs data_con other_args (InfixCon p1 p2) pstate thing_inside
 634   = pprPanic "tcConArgs" (ppr data_con) -- InfixCon always has two arguments
 635
 636 tcConArgs data_con arg_tys (RecCon rpats) pstate thing_inside
 637   = do  { (rpats', tvs, res) <- tcMultiple tc_field rpats pstate thing_inside
 638         ; return (RecCon rpats', tvs, res) }
 639   where
 640     -- doc comments are typechecked to Nothing here
 641     tc_field :: Checker (HsRecField FieldLabel (LPat Name)) (HsRecField TcId (LPat TcId))
 642     tc_field (HsRecField field_lbl pat _) pstate thing_inside
 643       = do { (sel_id, pat_ty) <- wrapLocFstM find_field_ty field_lbl
 644            ; (pat', tvs, res) <- tcConArg (pat, pat_ty) pstate thing_inside
 645            ; return (mkRecField sel_id pat', tvs, res) }
 646
 647     find_field_ty :: FieldLabel -> TcM (Id, TcType)
 648     find_field_ty field_lbl
 649         = case [ty | (f,ty) <- field_tys, f == field_lbl] of
 650
 651                 -- No matching field; chances are this field label comes from some
 652                 -- other record type (or maybe none).  As well as reporting an
 653                 -- error we still want to typecheck the pattern, principally to
 654                 -- make sure that all the variables it binds are put into the
 655                 -- environment, else the type checker crashes later:
 656                 --      f (R { foo = (a,b) }) = a+b
 657                 -- If foo isn't one of R's fields, we don't want to crash when
 658                 -- typechecking the "a+b".
 659            [] -> do { addErrTc (badFieldCon data_con field_lbl)
 660                     ; bogus_ty <- newFlexiTyVarTy liftedTypeKind
 661                     ; return (error "Bogus selector Id", bogus_ty) }
 662
 663                 -- The normal case, when the field comes from the right constructor
 664            (pat_ty : extras) ->
 665                 ASSERT( null extras )
 666                 do { sel_id <- tcLookupField field_lbl
 667                    ; return (sel_id, pat_ty) }
 668
 669     field_tys :: [(FieldLabel, TcType)]
 670     field_tys = zip (dataConFieldLabels data_con) arg_tys
 671         -- Don't use zipEqual! If the constructor isn't really a record, then
 672         -- dataConFieldLabels will be empty (and each field in the pattern
 673         -- will generate an error below).
 674
 675 tcConArg :: Checker (LPat Name, BoxySigmaType) (LPat Id)
 676 tcConArg (arg_pat, arg_ty) pstate thing_inside
 677   = tc_lpat arg_pat arg_ty pstate thing_inside
 678         -- NB: the tc_lpat will refine pat_ty if necessary
 679         --     based on the current pstate, which may include
 680         --     refinements from peer argument patterns to the left
 681 \end{code}
 682
 683 \begin{code}
 684 addDataConStupidTheta :: DataCon -> [TcType] -> TcM ()
 685 -- Instantiate the "stupid theta" of the data con, and throw
 686 -- the constraints into the constraint set
 687 addDataConStupidTheta data_con inst_tys
 688   | null stupid_theta = return ()
 689   | otherwise         = instStupidTheta origin inst_theta
 690   where
 691     origin = OccurrenceOf (dataConName data_con)
 692         -- The origin should always report "occurrence of C"
 693         -- even when C occurs in a pattern
 694     stupid_theta = dataConStupidTheta data_con
 695     tenv = zipTopTvSubst (dataConUnivTyVars data_con) inst_tys
 696     inst_theta = substTheta tenv stupid_theta
 697 \end{code}
 698
 699
 700 %************************************************************************
 701 %*                                                                      *
 702                 Type refinement
 703 %*                                                                      *
 704 %************************************************************************
 705
 706 \begin{code}
 707 refineAlt :: DataCon            -- For tracing only
 708           -> PatState
 709           -> [TcTyVar]          -- Existentials
 710           -> [CoVar]            -- Equational constraints
 711           -> BoxySigmaType      -- Pattern type
 712           -> TcM PatState
 713
 714 refineAlt con pstate ex_tvs [] pat_ty
 715   = return pstate       -- Common case: no equational constraints
 716
 717 refineAlt con pstate ex_tvs co_vars pat_ty
 718   | not (isRigidTy pat_ty)
 719   = failWithTc (nonRigidMatch con)
 720         -- We are matching against a GADT constructor with non-trivial
 721         -- constraints, but pattern type is wobbly.  For now we fail.
 722         -- We can make sense of this, however:
 723         -- Suppose MkT :: forall a b. (a:=:[b]) => b -> T a
 724         --      (\x -> case x of { MkT v -> v })
 725         -- We can infer that x must have type T [c], for some wobbly 'c'
 726         -- and translate to
 727         --      (\(x::T [c]) -> case x of
 728         --                        MkT b (g::([c]:=:[b])) (v::b) -> v `cast` sym g
 729         -- To implement this, we'd first instantiate the equational
 730         -- constraints with *wobbly* type variables for the existentials;
 731         -- then unify these constraints to make pat_ty the right shape;
 732         -- then proceed exactly as in the rigid case
 733
 734   | otherwise   -- In the rigid case, we perform type refinement
 735   = case gadtRefine (pat_reft pstate) ex_tvs co_vars of {
 736             Failed msg     -> failWithTc (inaccessibleAlt msg) ;
 737             Succeeded reft -> do { traceTc trace_msg
 738                                  ; return (pstate { pat_reft = reft }) }
 739                     -- DO NOT refine the envt right away, because we
 740                     -- might be inside a lazy pattern.  Instead, refine pstate
 741                 where
 742
 743                     trace_msg = text "refineAlt:match" <+>
 744                                 vcat [ ppr con <+> ppr ex_tvs,
 745                                        ppr [(v, tyVarKind v) | v <- co_vars],
 746                                        ppr reft]
 747         }
 748 \end{code}
 749
 750
 751 %************************************************************************
 752 %*                                                                      *
 753                 Overloaded literals
 754 %*                                                                      *
 755 %************************************************************************
 756
 757 In tcOverloadedLit we convert directly to an Int or Integer if we
 758 know that's what we want.  This may save some time, by not
 759 temporarily generating overloaded literals, but it won't catch all
 760 cases (the rest are caught in lookupInst).
 761
 762 \begin{code}
 763 tcOverloadedLit :: InstOrigin
 764                  -> HsOverLit Name
 765                  -> BoxyRhoType
 766                  -> TcM (HsOverLit TcId)
 767 tcOverloadedLit orig lit@(HsIntegral i fi) res_ty
 768   | not (fi `isHsVar` fromIntegerName)  -- Do not generate a LitInst for rebindable syntax.
 769         -- Reason: If we do, tcSimplify will call lookupInst, which
 770         --         will call tcSyntaxName, which does unification,
 771         --         which tcSimplify doesn't like
 772         -- ToDo: noLoc sadness
 773   = do  { integer_ty <- tcMetaTy integerTyConName
 774         ; fi' <- tcSyntaxOp orig fi (mkFunTy integer_ty res_ty)
 775         ; return (HsIntegral i (HsApp (noLoc fi') (nlHsLit (HsInteger i integer_ty)))) }
 776
 777   | Just expr <- shortCutIntLit i res_ty
 778   = return (HsIntegral i expr)
 779
 780   | otherwise
 781   = do  { expr <- newLitInst orig lit res_ty
 782         ; return (HsIntegral i expr) }
 783
 784 tcOverloadedLit orig lit@(HsFractional r fr) res_ty
 785   | not (fr `isHsVar` fromRationalName) -- c.f. HsIntegral case
 786   = do  { rat_ty <- tcMetaTy rationalTyConName
 787         ; fr' <- tcSyntaxOp orig fr (mkFunTy rat_ty res_ty)
 788                 -- Overloaded literals must have liftedTypeKind, because
 789                 -- we're instantiating an overloaded function here,
 790                 -- whereas res_ty might be openTypeKind. This was a bug in 6.2.2
 791                 -- However this'll be picked up by tcSyntaxOp if necessary
 792         ; return (HsFractional r (HsApp (noLoc fr') (nlHsLit (HsRat r rat_ty)))) }
 793
 794   | Just expr <- shortCutFracLit r res_ty
 795   = return (HsFractional r expr)
 796
 797   | otherwise
 798   = do  { expr <- newLitInst orig lit res_ty
 799         ; return (HsFractional r expr) }
 800
 801 newLitInst :: InstOrigin -> HsOverLit Name -> BoxyRhoType -> TcM (HsExpr TcId)
 802 newLitInst orig lit res_ty      -- Make a LitInst
 803   = do  { loc <- getInstLoc orig
 804         ; res_tau <- zapToMonotype res_ty
 805         ; new_uniq <- newUnique
 806         ; let   lit_nm   = mkSystemVarName new_uniq FSLIT("lit")
 807                 lit_inst = LitInst {tci_name = lit_nm, tci_lit = lit,
 808                                     tci_ty = res_tau, tci_loc = loc}
 809         ; extendLIE lit_inst
 810         ; return (HsVar (instToId lit_inst)) }
 811 \end{code}
 812
 813
 814 %************************************************************************
 815 %*                                                                      *
 816                 Note [Pattern coercions]
 817 %*                                                                      *
 818 %************************************************************************
 819
 820 In principle, these program would be reasonable:
 821
 822         f :: (forall a. a->a) -> Int
 823         f (x :: Int->Int) = x 3
 824
 825         g :: (forall a. [a]) -> Bool
 826         g [] = True
 827
 828 In both cases, the function type signature restricts what arguments can be passed
 829 in a call (to polymorphic ones).  The pattern type signature then instantiates this
 830 type.  For example, in the first case,  (forall a. a->a) <= Int -> Int, and we
 831 generate the translated term
 832         f = \x' :: (forall a. a->a).  let x = x' Int in x 3
 833
 834 From a type-system point of view, this is perfectly fine, but it's *very* seldom useful.
 835 And it requires a significant amount of code to implement, becuase we need to decorate
 836 the translated pattern with coercion functions (generated from the subsumption check
 837 by tcSub).
 838
 839 So for now I'm just insisting on type *equality* in patterns.  No subsumption.
 840
 841 Old notes about desugaring, at a time when pattern coercions were handled:
 842
 843 A SigPat is a type coercion and must be handled one at at time.  We can't
 844 combine them unless the type of the pattern inside is identical, and we don't
 845 bother to check for that.  For example:
 846
 847         data T = T1 Int | T2 Bool
 848         f :: (forall a. a -> a) -> T -> t
 849         f (g::Int->Int)   (T1 i) = T1 (g i)
 850         f (g::Bool->Bool) (T2 b) = T2 (g b)
 851
 852 We desugar this as follows:
 853
 854         f = \ g::(forall a. a->a) t::T ->
 855             let gi = g Int
 856             in case t of { T1 i -> T1 (gi i)
 857                            other ->
 858             let gb = g Bool
 859             in case t of { T2 b -> T2 (gb b)
 860                            other -> fail }}
 861
 862 Note that we do not treat the first column of patterns as a
 863 column of variables, because the coerced variables (gi, gb)
 864 would be of different types.  So we get rather grotty code.
 865 But I don't think this is a common case, and if it was we could
 866 doubtless improve it.
 867
 868 Meanwhile, the strategy is:
 869         * treat each SigPat coercion (always non-identity coercions)
 870                 as a separate block
 871         * deal with the stuff inside, and then wrap a binding round
 872                 the result to bind the new variable (gi, gb, etc)
 873
 874
 875 %************************************************************************
 876 %*                                                                      *
 877 \subsection{Errors and contexts}
 878 %*                                                                      *
 879 %************************************************************************
 880
 881 \begin{code}
 882 patCtxt :: Pat Name -> Maybe Message    -- Not all patterns are worth pushing a context
 883 patCtxt (VarPat _)  = Nothing
 884 patCtxt (ParPat _)  = Nothing
 885 patCtxt (AsPat _ _) = Nothing
 886 patCtxt pat         = Just (hang (ptext SLIT("In the pattern:"))
 887                                4 (ppr pat))
 888
 889 -----------------------------------------------
 890
 891 existentialExplode pat
 892   = hang (vcat [text "My brain just exploded.",
 893                 text "I can't handle pattern bindings for existentially-quantified constructors.",
 894                 text "In the binding group for"])
 895         4 (ppr pat)
 896
 897 sigPatCtxt pats bound_tvs pat_tys body_ty tidy_env
 898   = do  { pat_tys' <- mapM zonkTcType pat_tys
 899         ; body_ty' <- zonkTcType body_ty
 900         ; let (env1,  tidy_tys)    = tidyOpenTypes tidy_env (map idType show_ids)
 901               (env2, tidy_pat_tys) = tidyOpenTypes env1 pat_tys'
 902               (env3, tidy_body_ty) = tidyOpenType  env2 body_ty'
 903         ; return (env3,
 904                  sep [ptext SLIT("When checking an existential match that binds"),
 905                       nest 4 (vcat (zipWith ppr_id show_ids tidy_tys)),
 906                       ptext SLIT("The pattern(s) have type(s):") <+> vcat (map ppr tidy_pat_tys),
 907                       ptext SLIT("The body has type:") <+> ppr tidy_body_ty,
 908                       ppr pats
 909                 ]) }
 910   where
 911     bound_ids = collectPatsBinders pats
 912     show_ids = filter is_interesting bound_ids
 913     is_interesting id = any (`elemVarSet` idFreeTyVars id) bound_tvs
 914
 915     ppr_id id ty = ppr id <+> dcolon <+> ppr ty
 916         -- Don't zonk the types so we get the separate, un-unified versions
 917
 918 badFieldCon :: DataCon -> Name -> SDoc
 919 badFieldCon con field
 920   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
 921           ptext SLIT("does not have field"), quotes (ppr field)]
 922
 923 polyPatSig :: TcType -> SDoc
 924 polyPatSig sig_ty
 925   = hang (ptext SLIT("Illegal polymorphic type signature in pattern:"))
 926          4 (ppr sig_ty)
 927
 928 badTypePat pat = ptext SLIT("Illegal type pattern") <+> ppr pat
 929
 930 lazyPatErr pat tvs
 931   = failWithTc $
 932     hang (ptext SLIT("A lazy (~) pattern connot bind existential type variables"))
 933        2 (vcat (map pprSkolTvBinding tvs))
 934
 935 nonRigidMatch con
 936   =  hang (ptext SLIT("GADT pattern match in non-rigid context for") <+> quotes (ppr con))
 937         2 (ptext SLIT("Tell GHC HQ if you'd like this to unify the context"))
 938
 939 inaccessibleAlt msg
 940   = hang (ptext SLIT("Inaccessible case alternative:")) 2 msg
 941 \end{code}