compiler/typecheck/TcPat.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5
   6 TcPat: Typechecking patterns
   7
   8 \begin{code}
   9 module TcPat ( tcLetPat, tcLamPat, tcLamPats, tcOverloadedLit,
  10                addDataConStupidTheta, badFieldCon, polyPatSig ) where
  11
  12 #include "HsVersions.h"
  13
  14 import {-# SOURCE #-}   TcExpr( tcSyntaxOp )
  15
  16 import HsSyn
  17 import TcHsSyn
  18 import TcRnMonad
  19 import Inst
  20 import Id
  21 import Var
  22 import CoreFVs
  23 import Name
  24 import TcSimplify
  25 import TcEnv
  26 import TcMType
  27 import TcType
  28 import VarSet
  29 import TcUnify
  30 import TcHsType
  31 import TysWiredIn
  32 import TcGadt
  33 import Type
  34 import StaticFlags
  35 import TyCon
  36 import DataCon
  37 import PrelNames
  38 import BasicTypes hiding (SuccessFlag(..))
  39 import SrcLoc
  40 import ErrUtils
  41 import Util
  42 import Maybes
  43 import Outputable
  44 import FastString
  45 \end{code}
  46
  47
  48 %************************************************************************
  49 %*                                                                      *
  50                 External interface
  51 %*                                                                      *
  52 %************************************************************************
  53
  54 \begin{code}
  55 tcLetPat :: (Name -> Maybe TcRhoType)
  56          -> LPat Name -> BoxySigmaType
  57          -> TcM a
  58          -> TcM (LPat TcId, a)
  59 tcLetPat sig_fn pat pat_ty thing_inside
  60   = do  { let init_state = PS { pat_ctxt = LetPat sig_fn,
  61                                 pat_reft = emptyRefinement }
  62         ; (pat', ex_tvs, res) <- tc_lpat pat pat_ty init_state (\ _ -> thing_inside)
  63
  64         -- Don't know how to deal with pattern-bound existentials yet
  65         ; checkTc (null ex_tvs) (existentialExplode pat)
  66
  67         ; return (pat', res) }
  68
  69 -----------------
  70 tcLamPats :: [LPat Name]                                -- Patterns,
  71           -> [BoxySigmaType]                            --   and their types
  72           -> BoxyRhoType                                -- Result type,
  73           -> ((Refinement, BoxyRhoType) -> TcM a)       --   and the checker for the body
  74           -> TcM ([LPat TcId], a)
  75
  76 -- This is the externally-callable wrapper function
  77 -- Typecheck the patterns, extend the environment to bind the variables,
  78 -- do the thing inside, use any existentially-bound dictionaries to
  79 -- discharge parts of the returning LIE, and deal with pattern type
  80 -- signatures
  81
  82 --   1. Initialise the PatState
  83 --   2. Check the patterns
  84 --   3. Apply the refinement to the environment and result type
  85 --   4. Check the body
  86 --   5. Check that no existentials escape
  87
  88 tcLamPats pats tys res_ty thing_inside
  89   = tc_lam_pats (zipEqual "tcLamPats" pats tys)
  90                 (emptyRefinement, res_ty) thing_inside
  91
  92 tcLamPat :: LPat Name -> BoxySigmaType
  93          -> (Refinement,BoxyRhoType)            -- Result type
  94          -> ((Refinement,BoxyRhoType) -> TcM a) -- Checker for body, given its result type
  95          -> TcM (LPat TcId, a)
  96 tcLamPat pat pat_ty res_ty thing_inside
  97   = do  { ([pat'],thing) <- tc_lam_pats [(pat, pat_ty)] res_ty thing_inside
  98         ; return (pat', thing) }
  99
 100 -----------------
 101 tc_lam_pats :: [(LPat Name,BoxySigmaType)]
 102             -> (Refinement,BoxyRhoType)                 -- Result type
 103             -> ((Refinement,BoxyRhoType) -> TcM a)      -- Checker for body, given its result type
 104             -> TcM ([LPat TcId], a)
 105 tc_lam_pats pat_ty_prs (reft, res_ty) thing_inside
 106   =  do { let init_state = PS { pat_ctxt = LamPat, pat_reft = reft }
 107
 108         ; (pats', ex_tvs, res) <- tcMultiple tc_lpat_pr pat_ty_prs init_state $ \ pstate' ->
 109                                   refineEnvironment (pat_reft pstate') $
 110                                   thing_inside (pat_reft pstate', res_ty)
 111
 112         ; let tys = map snd pat_ty_prs
 113         ; tcCheckExistentialPat pats' ex_tvs tys res_ty
 114
 115         ; returnM (pats', res) }
 116
 117
 118 -----------------
 119 tcCheckExistentialPat :: [LPat TcId]            -- Patterns (just for error message)
 120                       -> [TcTyVar]              -- Existentially quantified tyvars bound by pattern
 121                       -> [BoxySigmaType]        -- Types of the patterns
 122                       -> BoxyRhoType            -- Type of the body of the match
 123                                                 -- Tyvars in either of these must not escape
 124                       -> TcM ()
 125 -- NB: we *must* pass "pats_tys" not just "body_ty" to tcCheckExistentialPat
 126 -- For example, we must reject this program:
 127 --      data C = forall a. C (a -> Int)
 128 --      f (C g) x = g x
 129 -- Here, result_ty will be simply Int, but expected_ty is (C -> a -> Int).
 130
 131 tcCheckExistentialPat pats [] pat_tys body_ty
 132   = return ()   -- Short cut for case when there are no existentials
 133
 134 tcCheckExistentialPat pats ex_tvs pat_tys body_ty
 135   = addErrCtxtM (sigPatCtxt pats ex_tvs pat_tys body_ty)        $
 136     checkSigTyVarsWrt (tcTyVarsOfTypes (body_ty:pat_tys)) ex_tvs
 137
 138 data PatState = PS {
 139         pat_ctxt :: PatCtxt,
 140         pat_reft :: Refinement  -- Binds rigid TcTyVars to their refinements
 141   }
 142
 143 data PatCtxt
 144   = LamPat
 145   | LetPat (Name -> Maybe TcRhoType)    -- Used for let(rec) bindings
 146
 147 patSigCtxt :: PatState -> UserTypeCtxt
 148 patSigCtxt (PS { pat_ctxt = LetPat _ }) = BindPatSigCtxt
 149 patSigCtxt other                        = LamPatSigCtxt
 150 \end{code}
 151
 152
 153
 154 %************************************************************************
 155 %*                                                                      *
 156                 Binders
 157 %*                                                                      *
 158 %************************************************************************
 159
 160 \begin{code}
 161 tcPatBndr :: PatState -> Name -> BoxySigmaType -> TcM TcId
 162 tcPatBndr (PS { pat_ctxt = LamPat }) bndr_name pat_ty
 163   = do  { pat_ty' <- unBoxPatBndrType pat_ty bndr_name
 164                 -- We have an undecorated binder, so we do rule ABS1,
 165                 -- by unboxing the boxy type, forcing any un-filled-in
 166                 -- boxes to become monotypes
 167                 -- NB that pat_ty' can still be a polytype:
 168                 --      data T = MkT (forall a. a->a)
 169                 --      f t = case t of { MkT g -> ... }
 170                 -- Here, the 'g' must get type (forall a. a->a) from the
 171                 -- MkT context
 172         ; return (Id.mkLocalId bndr_name pat_ty') }
 173
 174 tcPatBndr (PS { pat_ctxt = LetPat lookup_sig }) bndr_name pat_ty
 175   | Just mono_ty <- lookup_sig bndr_name
 176   = do  { mono_name <- newLocalName bndr_name
 177         ; boxyUnify mono_ty pat_ty
 178         ; return (Id.mkLocalId mono_name mono_ty) }
 179
 180   | otherwise
 181   = do  { pat_ty' <- unBoxPatBndrType pat_ty bndr_name
 182         ; mono_name <- newLocalName bndr_name
 183         ; return (Id.mkLocalId mono_name pat_ty') }
 184
 185
 186 -------------------
 187 bindInstsOfPatId :: TcId -> TcM a -> TcM (a, LHsBinds TcId)
 188 bindInstsOfPatId id thing_inside
 189   | not (isOverloadedTy (idType id))
 190   = do { res <- thing_inside; return (res, emptyLHsBinds) }
 191   | otherwise
 192   = do  { (res, lie) <- getLIE thing_inside
 193         ; binds <- bindInstsOfLocalFuns lie [id]
 194         ; return (res, binds) }
 195
 196 -------------------
 197 unBoxPatBndrType  ty name = unBoxArgType ty (ptext SLIT("The variable") <+> quotes (ppr name))
 198 unBoxWildCardType ty      = unBoxArgType ty (ptext SLIT("A wild-card pattern"))
 199
 200 unBoxArgType :: BoxyType -> SDoc -> TcM TcType
 201 -- In addition to calling unbox, unBoxArgType ensures that the type is of ArgTypeKind;
 202 -- that is, it can't be an unboxed tuple.  For example,
 203 --      case (f x) of r -> ...
 204 -- should fail if 'f' returns an unboxed tuple.
 205 unBoxArgType ty pp_this
 206   = do  { ty' <- unBox ty       -- Returns a zonked type
 207
 208         -- Neither conditional is strictly necesssary (the unify alone will do)
 209         -- but they improve error messages, and allocate fewer tyvars
 210         ; if isUnboxedTupleType ty' then
 211                 failWithTc msg
 212           else if isSubArgTypeKind (typeKind ty') then
 213                 return ty'
 214           else do       -- OpenTypeKind, so constrain it
 215         { ty2 <- newFlexiTyVarTy argTypeKind
 216         ; unifyType ty' ty2
 217         ; return ty' }}
 218   where
 219     msg = pp_this <+> ptext SLIT("cannot be bound to an unboxed tuple")
 220 \end{code}
 221
 222
 223 %************************************************************************
 224 %*                                                                      *
 225                 The main worker functions
 226 %*                                                                      *
 227 %************************************************************************
 228
 229 Note [Nesting]
 230 ~~~~~~~~~~~~~~
 231 tcPat takes a "thing inside" over which the pattern scopes.  This is partly
 232 so that tcPat can extend the environment for the thing_inside, but also
 233 so that constraints arising in the thing_inside can be discharged by the
 234 pattern.
 235
 236 This does not work so well for the ErrCtxt carried by the monad: we don't
 237 want the error-context for the pattern to scope over the RHS.
 238 Hence the getErrCtxt/setErrCtxt stuff in tc_lpats.
 239
 240 \begin{code}
 241 --------------------
 242 type Checker inp out =  forall r.
 243                           inp
 244                        -> PatState
 245                        -> (PatState -> TcM r)
 246                        -> TcM (out, [TcTyVar], r)
 247
 248 tcMultiple :: Checker inp out -> Checker [inp] [out]
 249 tcMultiple tc_pat args pstate thing_inside
 250   = do  { err_ctxt <- getErrCtxt
 251         ; let loop pstate []
 252                 = do { res <- thing_inside pstate
 253                      ; return ([], [], res) }
 254
 255               loop pstate (arg:args)
 256                 = do { (p', p_tvs, (ps', ps_tvs, res))
 257                                 <- tc_pat arg pstate $ \ pstate' ->
 258                                    setErrCtxt err_ctxt $
 259                                    loop pstate' args
 260                 -- setErrCtxt: restore context before doing the next pattern
 261                 -- See note [Nesting] above
 262
 263                      ; return (p':ps', p_tvs ++ ps_tvs, res) }
 264
 265         ; loop pstate args }
 266
 267 --------------------
 268 tc_lpat_pr :: (LPat Name, BoxySigmaType)
 269            -> PatState
 270            -> (PatState -> TcM a)
 271            -> TcM (LPat TcId, [TcTyVar], a)
 272 tc_lpat_pr (pat, ty) = tc_lpat pat ty
 273
 274 tc_lpat :: LPat Name
 275         -> BoxySigmaType
 276         -> PatState
 277         -> (PatState -> TcM a)
 278         -> TcM (LPat TcId, [TcTyVar], a)
 279 tc_lpat (L span pat) pat_ty pstate thing_inside
 280   = setSrcSpan span               $
 281     maybeAddErrCtxt (patCtxt pat) $
 282     do  { let mb_reft = refineType (pat_reft pstate) pat_ty
 283               pat_ty' = case mb_reft of { Just (_, ty') -> ty'; Nothing -> pat_ty }
 284
 285                 -- Make sure the result type reflects the current refinement
 286                 -- We must do this here, so that it correctly ``sees'' all
 287                 -- the refinements to the left.  Example:
 288                 -- Suppose C :: forall a. T a -> a -> Foo
 289                 -- Pattern      C a p1 True
 290                 -- So p1 might refine 'a' to True, and the True
 291                 -- pattern had better see it.
 292
 293         ; (pat', tvs, res) <- tc_pat pstate pat pat_ty' thing_inside
 294         ; let final_pat = case mb_reft of
 295                                 Nothing     -> pat'
 296                                 Just (co,_) -> CoPat (WpCo co) pat' pat_ty
 297         ; return (L span final_pat, tvs, res) }
 298
 299 --------------------
 300 tc_pat  :: PatState
 301         -> Pat Name -> BoxySigmaType    -- Fully refined result type
 302         -> (PatState -> TcM a)  -- Thing inside
 303         -> TcM (Pat TcId,       -- Translated pattern
 304                 [TcTyVar],      -- Existential binders
 305                 a)              -- Result of thing inside
 306
 307 tc_pat pstate (VarPat name) pat_ty thing_inside
 308   = do  { id <- tcPatBndr pstate name pat_ty
 309         ; (res, binds) <- bindInstsOfPatId id $
 310                           tcExtendIdEnv1 name id $
 311                           (traceTc (text "binding" <+> ppr name <+> ppr (idType id))
 312                            >> thing_inside pstate)
 313         ; let pat' | isEmptyLHsBinds binds = VarPat id
 314                    | otherwise             = VarPatOut id binds
 315         ; return (pat', [], res) }
 316
 317 tc_pat pstate (ParPat pat) pat_ty thing_inside
 318   = do  { (pat', tvs, res) <- tc_lpat pat pat_ty pstate thing_inside
 319         ; return (ParPat pat', tvs, res) }
 320
 321 tc_pat pstate (BangPat pat) pat_ty thing_inside
 322   = do  { (pat', tvs, res) <- tc_lpat pat pat_ty pstate thing_inside
 323         ; return (BangPat pat', tvs, res) }
 324
 325 -- There's a wrinkle with irrefutable patterns, namely that we
 326 -- must not propagate type refinement from them.  For example
 327 --      data T a where { T1 :: Int -> T Int; ... }
 328 --      f :: T a -> Int -> a
 329 --      f ~(T1 i) y = y
 330 -- It's obviously not sound to refine a to Int in the right
 331 -- hand side, because the arugment might not match T1 at all!
 332 --
 333 -- Nor should a lazy pattern bind any existential type variables
 334 -- because they won't be in scope when we do the desugaring
 335 --
 336 -- Note [Hopping the LIE in lazy patterns]
 337 -- ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 338 -- In a lazy pattern, we must *not* discharge constraints from the RHS
 339 -- from dictionaries bound in the pattern.  E.g.
 340 --      f ~(C x) = 3
 341 -- We can't discharge the Num constraint from dictionaries bound by
 342 -- the pattern C!
 343 --
 344 -- So we have to make the constraints from thing_inside "hop around"
 345 -- the pattern.  Hence the getLLE and extendLIEs later.
 346
 347 tc_pat pstate lpat@(LazyPat pat) pat_ty thing_inside
 348   = do  { (pat', pat_tvs, (res,lie))
 349                 <- tc_lpat pat pat_ty pstate $ \ _ ->
 350                    getLIE (thing_inside pstate)
 351                 -- Ignore refined pstate', revert to pstate
 352         ; extendLIEs lie
 353         -- getLIE/extendLIEs: see Note [Hopping the LIE in lazy patterns]
 354
 355         -- Check no existentials
 356         ; if (null pat_tvs) then return ()
 357           else lazyPatErr lpat pat_tvs
 358
 359         -- Check that the pattern has a lifted type
 360         ; pat_tv <- newBoxyTyVar liftedTypeKind
 361         ; boxyUnify pat_ty (mkTyVarTy pat_tv)
 362
 363         ; return (LazyPat pat', [], res) }
 364
 365 tc_pat pstate (WildPat _) pat_ty thing_inside
 366   = do  { pat_ty' <- unBoxWildCardType pat_ty   -- Make sure it's filled in with monotypes
 367         ; res <- thing_inside pstate
 368         ; return (WildPat pat_ty', [], res) }
 369
 370 tc_pat pstate (AsPat (L nm_loc name) pat) pat_ty thing_inside
 371   = do  { bndr_id <- setSrcSpan nm_loc (tcPatBndr pstate name pat_ty)
 372         ; (pat', tvs, res) <- tcExtendIdEnv1 name bndr_id $
 373                               tc_lpat pat (idType bndr_id) pstate thing_inside
 374             -- NB: if we do inference on:
 375             --          \ (y@(x::forall a. a->a)) = e
 376             -- we'll fail.  The as-pattern infers a monotype for 'y', which then
 377             -- fails to unify with the polymorphic type for 'x'.  This could
 378             -- perhaps be fixed, but only with a bit more work.
 379             --
 380             -- If you fix it, don't forget the bindInstsOfPatIds!
 381         ; return (AsPat (L nm_loc bndr_id) pat', tvs, res) }
 382
 383 -- Type signatures in patterns
 384 -- See Note [Pattern coercions] below
 385 tc_pat pstate (SigPatIn pat sig_ty) pat_ty thing_inside
 386   = do  { (inner_ty, tv_binds) <- tcPatSig (patSigCtxt pstate) sig_ty pat_ty
 387         ; (pat', tvs, res) <- tcExtendTyVarEnv2 tv_binds $
 388                               tc_lpat pat inner_ty pstate thing_inside
 389         ; return (SigPatOut pat' inner_ty, tvs, res) }
 390
 391 tc_pat pstate pat@(TypePat ty) pat_ty thing_inside
 392   = failWithTc (badTypePat pat)
 393
 394 ------------------------
 395 -- Lists, tuples, arrays
 396 tc_pat pstate (ListPat pats _) pat_ty thing_inside
 397   = do  { elt_ty <- boxySplitListTy pat_ty
 398         ; (pats', pats_tvs, res) <- tcMultiple (\p -> tc_lpat p elt_ty)
 399                                                 pats pstate thing_inside
 400         ; return (ListPat pats' elt_ty, pats_tvs, res) }
 401
 402 tc_pat pstate (PArrPat pats _) pat_ty thing_inside
 403   = do  { [elt_ty] <- boxySplitTyConApp parrTyCon pat_ty
 404         ; (pats', pats_tvs, res) <- tcMultiple (\p -> tc_lpat p elt_ty)
 405                                                 pats pstate thing_inside
 406         ; ifM (null pats) (zapToMonotype pat_ty)        -- c.f. ExplicitPArr in TcExpr
 407         ; return (PArrPat pats' elt_ty, pats_tvs, res) }
 408
 409 tc_pat pstate (TuplePat pats boxity _) pat_ty thing_inside
 410   = do  { arg_tys <- boxySplitTyConApp (tupleTyCon boxity (length pats)) pat_ty
 411         ; (pats', pats_tvs, res) <- tcMultiple tc_lpat_pr (pats `zip` arg_tys)
 412                                                pstate thing_inside
 413
 414         -- Under flag control turn a pattern (x,y,z) into ~(x,y,z)
 415         -- so that we can experiment with lazy tuple-matching.
 416         -- This is a pretty odd place to make the switch, but
 417         -- it was easy to do.
 418         ; let unmangled_result = TuplePat pats' boxity pat_ty
 419               possibly_mangled_result
 420                 | opt_IrrefutableTuples && isBoxed boxity = LazyPat (noLoc unmangled_result)
 421                 | otherwise                               = unmangled_result
 422
 423         ; ASSERT( length arg_tys == length pats )       -- Syntactically enforced
 424           return (possibly_mangled_result, pats_tvs, res) }
 425
 426 ------------------------
 427 -- Data constructors
 428 tc_pat pstate pat_in@(ConPatIn (L con_span con_name) arg_pats) pat_ty thing_inside
 429   = do  { data_con <- tcLookupDataCon con_name
 430         ; let tycon = dataConTyCon data_con
 431         ; tcConPat pstate con_span data_con tycon pat_ty arg_pats thing_inside }
 432
 433 ------------------------
 434 -- Literal patterns
 435 tc_pat pstate (LitPat simple_lit) pat_ty thing_inside
 436   = do  { boxyUnify (hsLitType simple_lit) pat_ty
 437         ; res <- thing_inside pstate
 438         ; returnM (LitPat simple_lit, [], res) }
 439
 440 ------------------------
 441 -- Overloaded patterns: n, and n+k
 442 tc_pat pstate pat@(NPat over_lit mb_neg eq _) pat_ty thing_inside
 443   = do  { let orig = LiteralOrigin over_lit
 444         ; lit'    <- tcOverloadedLit orig over_lit pat_ty
 445         ; eq'     <- tcSyntaxOp orig eq (mkFunTys [pat_ty, pat_ty] boolTy)
 446         ; mb_neg' <- case mb_neg of
 447                         Nothing  -> return Nothing      -- Positive literal
 448                         Just neg ->     -- Negative literal
 449                                         -- The 'negate' is re-mappable syntax
 450                             do { neg' <- tcSyntaxOp orig neg (mkFunTy pat_ty pat_ty)
 451                                ; return (Just neg') }
 452         ; res <- thing_inside pstate
 453         ; returnM (NPat lit' mb_neg' eq' pat_ty, [], res) }
 454
 455 tc_pat pstate pat@(NPlusKPat (L nm_loc name) lit ge minus) pat_ty thing_inside
 456   = do  { bndr_id <- setSrcSpan nm_loc (tcPatBndr pstate name pat_ty)
 457         ; let pat_ty' = idType bndr_id
 458               orig    = LiteralOrigin lit
 459         ; lit' <- tcOverloadedLit orig lit pat_ty'
 460
 461         -- The '>=' and '-' parts are re-mappable syntax
 462         ; ge'    <- tcSyntaxOp orig ge    (mkFunTys [pat_ty', pat_ty'] boolTy)
 463         ; minus' <- tcSyntaxOp orig minus (mkFunTys [pat_ty', pat_ty'] pat_ty')
 464
 465         -- The Report says that n+k patterns must be in Integral
 466         -- We may not want this when using re-mappable syntax, though (ToDo?)
 467         ; icls <- tcLookupClass integralClassName
 468         ; instStupidTheta orig [mkClassPred icls [pat_ty']]
 469
 470         ; res <- tcExtendIdEnv1 name bndr_id (thing_inside pstate)
 471         ; returnM (NPlusKPat (L nm_loc bndr_id) lit' ge' minus', [], res) }
 472
 473 tc_pat _ _other_pat _ _ = panic "tc_pat"        -- DictPat, ConPatOut, SigPatOut, VarPatOut
 474 \end{code}
 475
 476
 477 %************************************************************************
 478 %*                                                                      *
 479         Most of the work for constructors is here
 480         (the rest is in the ConPatIn case of tc_pat)
 481 %*                                                                      *
 482 %************************************************************************
 483
 484 [Pattern matching indexed data types]
 485 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 486 Consider the following declarations:
 487
 488   data family Map k :: * -> *
 489   data instance Map (a, b) v = MapPair (Map a (Pair b v))
 490
 491 and a case expression
 492
 493   case x :: Map (Int, c) w of MapPair m -> ...
 494
 495 As explained by [Wrappers for data instance tycons] in MkIds.lhs, the
 496 worker/wrapper types for MapPair are
 497
 498   $WMapPair :: forall a b v. Map a (Map a b v) -> Map (a, b) v
 499   $wMapPair :: forall a b v. Map a (Map a b v) -> :R123Map a b v
 500
 501 So, the type of the scrutinee is Map (Int, c) w, but the tycon of MapPair is
 502 :R123Map, which means the straight use of boxySplitTyConApp would give a type
 503 error.  Hence, the smart wrapper function boxySplitTyConAppWithFamily calls
 504 boxySplitTyConApp with the family tycon Map instead, which gives us the family
 505 type list {(Int, c), w}.  To get the correct split for :R123Map, we need to
 506 unify the family type list {(Int, c), w} with the instance types {(a, b), v}
 507 (provided by tyConFamInst_maybe together with the family tycon).  This
 508 unification yields the substitution [a -> Int, b -> c, v -> w], which gives us
 509 the split arguments for the representation tycon :R123Map as {Int, c, w}
 510
 511 In other words, boxySplitTyConAppWithFamily implicitly takes the coercion
 512
 513   Co123Map a b v :: {Map (a, b) v :=: :R123Map a b v}
 514
 515 moving between representation and family type into account.  To produce type
 516 correct Core, this coercion needs to be used to case the type of the scrutinee
 517 from the family to the representation type.  This is achieved by
 518 unwrapFamInstScrutinee using a CoPat around the result pattern.
 519
 520 Now it might appear seem as if we could have used the existing GADT type
 521 refinement infrastructure of refineAlt and friends instead of the explicit
 522 unification and CoPat generation.  However, that would be wrong.  Why?  The
 523 whole point of GADT refinement is that the refinement is local to the case
 524 alternative.  In contrast, the substitution generated by the unification of
 525 the family type list and instance types needs to be propagated to the outside.
 526 Imagine that in the above example, the type of the scrutinee would have been
 527 (Map x w), then we would have unified {x, w} with {(a, b), v}, yielding the
 528 substitution [x -> (a, b), v -> w].  In contrast to GADT matching, the
 529 instantiation of x with (a, b) must be global; ie, it must be valid in *all*
 530 alternatives of the case expression, whereas in the GADT case it might vary
 531 between alternatives.
 532
 533 In fact, if we have a data instance declaration defining a GADT, eq_spec will
 534 be non-empty and we will get a mixture of global instantiations and local
 535 refinement from a single match.  This neatly reflects that, as soon as we
 536 have constrained the type of the scrutinee to the required type index, all
 537 further type refinement is local to the alternative.
 538
 539 \begin{code}
 540 --      Running example:
 541 -- MkT :: forall a b c. (a:=:[b]) => b -> c -> T a
 542 --       with scrutinee of type (T ty)
 543
 544 tcConPat :: PatState -> SrcSpan -> DataCon -> TyCon
 545          -> BoxySigmaType       -- Type of the pattern
 546          -> HsConDetails Name (LPat Name) -> (PatState -> TcM a)
 547          -> TcM (Pat TcId, [TcTyVar], a)
 548 tcConPat pstate con_span data_con tycon pat_ty arg_pats thing_inside
 549   = do  { let (univ_tvs, ex_tvs, eq_spec, theta, arg_tys, _) = dataConFullSig data_con
 550               skol_info = PatSkol data_con
 551               origin    = SigOrigin skol_info
 552
 553           -- Instantiate the constructor type variables [a->ty]
 554         ; ctxt_res_tys <- boxySplitTyConAppWithFamily tycon pat_ty
 555         ; ex_tvs' <- tcInstSkolTyVars skol_info ex_tvs  -- Get location from monad,
 556                                                         -- not from ex_tvs
 557         ; let tenv     = zipTopTvSubst (univ_tvs ++ ex_tvs)
 558                                        (ctxt_res_tys ++ mkTyVarTys ex_tvs')
 559               eq_spec' = substEqSpec tenv eq_spec
 560               theta'   = substTheta  tenv theta
 561               arg_tys' = substTys    tenv arg_tys
 562
 563         ; co_vars <- newCoVars eq_spec' -- Make coercion variables
 564         ; pstate' <- refineAlt data_con pstate ex_tvs' co_vars pat_ty
 565
 566         ; ((arg_pats', inner_tvs, res), lie_req) <- getLIE $
 567                 tcConArgs data_con arg_tys' arg_pats pstate' thing_inside
 568
 569         ; loc <- getInstLoc origin
 570         ; dicts <- newDictBndrs loc theta'
 571         ; dict_binds <- tcSimplifyCheckPat loc co_vars (pat_reft pstate')
 572                                            ex_tvs' dicts lie_req
 573
 574         ; addDataConStupidTheta data_con ctxt_res_tys
 575
 576         ; return
 577             (unwrapFamInstScrutinee tycon ctxt_res_tys $
 578                ConPatOut { pat_con = L con_span data_con,
 579                            pat_tvs = ex_tvs' ++ co_vars,
 580                            pat_dicts = map instToId dicts,
 581                            pat_binds = dict_binds,
 582                            pat_args = arg_pats', pat_ty = pat_ty },
 583              ex_tvs' ++ inner_tvs, res)
 584         }
 585   where
 586     -- Split against the family tycon if the pattern constructor
 587     -- belongs to a family instance tycon.
 588     boxySplitTyConAppWithFamily tycon pat_ty =
 589       traceTc traceMsg >>
 590       case tyConFamInst_maybe tycon of
 591         Nothing                   -> boxySplitTyConApp tycon pat_ty
 592         Just (fam_tycon, instTys) ->
 593           do { scrutinee_arg_tys <- boxySplitTyConApp fam_tycon pat_ty
 594              ; (_, freshTvs, subst) <- tcInstTyVars (tyConTyVars tycon)
 595              ; boxyUnifyList (substTys subst instTys) scrutinee_arg_tys
 596              ; return freshTvs
 597              }
 598       where
 599         traceMsg = sep [ text "tcConPat:boxySplitTyConAppWithFamily:" <+>
 600                          ppr tycon <+> ppr pat_ty
 601                        , text "  family instance:" <+>
 602                          ppr (tyConFamInst_maybe tycon)
 603                        ]
 604
 605     -- Wraps the pattern (which must be a ConPatOut pattern) in a coercion
 606     -- pattern if the tycon is an instance of a family.
 607     --
 608     unwrapFamInstScrutinee :: TyCon -> [Type] -> Pat Id -> Pat Id
 609     unwrapFamInstScrutinee tycon args pat
 610       | Just co_con <- tyConFamilyCoercion_maybe tycon
 611 --      , not (isNewTyCon tycon)       -- newtypes are explicitly unwrapped by
 612                                      -- the desugarer
 613           -- NB: We can use CoPat directly, rather than mkCoPat, as we know the
 614           --     coercion is not the identity; mkCoPat is inconvenient as it
 615           --     wants a located pattern.
 616       = CoPat (WpCo $ mkTyConApp co_con args)       -- co fam ty to repr ty
 617               (pat {pat_ty = mkTyConApp tycon args})    -- representation type
 618               pat_ty                                    -- family inst type
 619       | otherwise
 620       = pat
 621
 622
 623 tcConArgs :: DataCon -> [TcSigmaType]
 624           -> Checker (HsConDetails Name (LPat Name))
 625                      (HsConDetails Id (LPat Id))
 626
 627 tcConArgs data_con arg_tys (PrefixCon arg_pats) pstate thing_inside
 628   = do  { checkTc (con_arity == no_of_args)     -- Check correct arity
 629                   (arityErr "Constructor" data_con con_arity no_of_args)
 630         ; let pats_w_tys = zipEqual "tcConArgs" arg_pats arg_tys
 631         ; (arg_pats', tvs, res) <- tcMultiple tcConArg pats_w_tys
 632                                               pstate thing_inside
 633         ; return (PrefixCon arg_pats', tvs, res) }
 634   where
 635     con_arity  = dataConSourceArity data_con
 636     no_of_args = length arg_pats
 637
 638 tcConArgs data_con [arg_ty1,arg_ty2] (InfixCon p1 p2) pstate thing_inside
 639   = do  { checkTc (con_arity == 2)      -- Check correct arity
 640                   (arityErr "Constructor" data_con con_arity 2)
 641         ; ([p1',p2'], tvs, res) <- tcMultiple tcConArg [(p1,arg_ty1),(p2,arg_ty2)]
 642                                               pstate thing_inside
 643         ; return (InfixCon p1' p2', tvs, res) }
 644   where
 645     con_arity  = dataConSourceArity data_con
 646
 647 tcConArgs data_con other_args (InfixCon p1 p2) pstate thing_inside
 648   = pprPanic "tcConArgs" (ppr data_con) -- InfixCon always has two arguments
 649
 650 tcConArgs data_con arg_tys (RecCon rpats) pstate thing_inside
 651   = do  { (rpats', tvs, res) <- tcMultiple tc_field rpats pstate thing_inside
 652         ; return (RecCon rpats', tvs, res) }
 653   where
 654     -- doc comments are typechecked to Nothing here
 655     tc_field :: Checker (HsRecField FieldLabel (LPat Name)) (HsRecField TcId (LPat TcId))
 656     tc_field (HsRecField field_lbl pat _) pstate thing_inside
 657       = do { (sel_id, pat_ty) <- wrapLocFstM find_field_ty field_lbl
 658            ; (pat', tvs, res) <- tcConArg (pat, pat_ty) pstate thing_inside
 659            ; return (mkRecField sel_id pat', tvs, res) }
 660
 661     find_field_ty :: FieldLabel -> TcM (Id, TcType)
 662     find_field_ty field_lbl
 663         = case [ty | (f,ty) <- field_tys, f == field_lbl] of
 664
 665                 -- No matching field; chances are this field label comes from some
 666                 -- other record type (or maybe none).  As well as reporting an
 667                 -- error we still want to typecheck the pattern, principally to
 668                 -- make sure that all the variables it binds are put into the
 669                 -- environment, else the type checker crashes later:
 670                 --      f (R { foo = (a,b) }) = a+b
 671                 -- If foo isn't one of R's fields, we don't want to crash when
 672                 -- typechecking the "a+b".
 673            [] -> do { addErrTc (badFieldCon data_con field_lbl)
 674                     ; bogus_ty <- newFlexiTyVarTy liftedTypeKind
 675                     ; return (error "Bogus selector Id", bogus_ty) }
 676
 677                 -- The normal case, when the field comes from the right constructor
 678            (pat_ty : extras) ->
 679                 ASSERT( null extras )
 680                 do { sel_id <- tcLookupField field_lbl
 681                    ; return (sel_id, pat_ty) }
 682
 683     field_tys :: [(FieldLabel, TcType)]
 684     field_tys = zip (dataConFieldLabels data_con) arg_tys
 685         -- Don't use zipEqual! If the constructor isn't really a record, then
 686         -- dataConFieldLabels will be empty (and each field in the pattern
 687         -- will generate an error below).
 688
 689 tcConArg :: Checker (LPat Name, BoxySigmaType) (LPat Id)
 690 tcConArg (arg_pat, arg_ty) pstate thing_inside
 691   = tc_lpat arg_pat arg_ty pstate thing_inside
 692         -- NB: the tc_lpat will refine pat_ty if necessary
 693         --     based on the current pstate, which may include
 694         --     refinements from peer argument patterns to the left
 695 \end{code}
 696
 697 \begin{code}
 698 addDataConStupidTheta :: DataCon -> [TcType] -> TcM ()
 699 -- Instantiate the "stupid theta" of the data con, and throw
 700 -- the constraints into the constraint set
 701 addDataConStupidTheta data_con inst_tys
 702   | null stupid_theta = return ()
 703   | otherwise         = instStupidTheta origin inst_theta
 704   where
 705     origin = OccurrenceOf (dataConName data_con)
 706         -- The origin should always report "occurrence of C"
 707         -- even when C occurs in a pattern
 708     stupid_theta = dataConStupidTheta data_con
 709     tenv = zipTopTvSubst (dataConUnivTyVars data_con) inst_tys
 710     inst_theta = substTheta tenv stupid_theta
 711 \end{code}
 712
 713
 714 %************************************************************************
 715 %*                                                                      *
 716                 Type refinement
 717 %*                                                                      *
 718 %************************************************************************
 719
 720 \begin{code}
 721 refineAlt :: DataCon            -- For tracing only
 722           -> PatState
 723           -> [TcTyVar]          -- Existentials
 724           -> [CoVar]            -- Equational constraints
 725           -> BoxySigmaType      -- Pattern type
 726           -> TcM PatState
 727
 728 refineAlt con pstate ex_tvs [] pat_ty
 729   = return pstate       -- Common case: no equational constraints
 730
 731 refineAlt con pstate ex_tvs co_vars pat_ty
 732   | not (isRigidTy pat_ty)
 733   = failWithTc (nonRigidMatch con)
 734         -- We are matching against a GADT constructor with non-trivial
 735         -- constraints, but pattern type is wobbly.  For now we fail.
 736         -- We can make sense of this, however:
 737         -- Suppose MkT :: forall a b. (a:=:[b]) => b -> T a
 738         --      (\x -> case x of { MkT v -> v })
 739         -- We can infer that x must have type T [c], for some wobbly 'c'
 740         -- and translate to
 741         --      (\(x::T [c]) -> case x of
 742         --                        MkT b (g::([c]:=:[b])) (v::b) -> v `cast` sym g
 743         -- To implement this, we'd first instantiate the equational
 744         -- constraints with *wobbly* type variables for the existentials;
 745         -- then unify these constraints to make pat_ty the right shape;
 746         -- then proceed exactly as in the rigid case
 747
 748   | otherwise   -- In the rigid case, we perform type refinement
 749   = case gadtRefine (pat_reft pstate) ex_tvs co_vars of {
 750             Failed msg     -> failWithTc (inaccessibleAlt msg) ;
 751             Succeeded reft -> do { traceTc trace_msg
 752                                  ; return (pstate { pat_reft = reft }) }
 753                     -- DO NOT refine the envt right away, because we
 754                     -- might be inside a lazy pattern.  Instead, refine pstate
 755                 where
 756
 757                     trace_msg = text "refineAlt:match" <+>
 758                                 vcat [ ppr con <+> ppr ex_tvs,
 759                                        ppr [(v, tyVarKind v) | v <- co_vars],
 760                                        ppr reft]
 761         }
 762 \end{code}
 763
 764
 765 %************************************************************************
 766 %*                                                                      *
 767                 Overloaded literals
 768 %*                                                                      *
 769 %************************************************************************
 770
 771 In tcOverloadedLit we convert directly to an Int or Integer if we
 772 know that's what we want.  This may save some time, by not
 773 temporarily generating overloaded literals, but it won't catch all
 774 cases (the rest are caught in lookupInst).
 775
 776 \begin{code}
 777 tcOverloadedLit :: InstOrigin
 778                  -> HsOverLit Name
 779                  -> BoxyRhoType
 780                  -> TcM (HsOverLit TcId)
 781 tcOverloadedLit orig lit@(HsIntegral i fi) res_ty
 782   | not (fi `isHsVar` fromIntegerName)  -- Do not generate a LitInst for rebindable syntax.
 783         -- Reason: If we do, tcSimplify will call lookupInst, which
 784         --         will call tcSyntaxName, which does unification,
 785         --         which tcSimplify doesn't like
 786         -- ToDo: noLoc sadness
 787   = do  { integer_ty <- tcMetaTy integerTyConName
 788         ; fi' <- tcSyntaxOp orig fi (mkFunTy integer_ty res_ty)
 789         ; return (HsIntegral i (HsApp (noLoc fi') (nlHsLit (HsInteger i integer_ty)))) }
 790
 791   | Just expr <- shortCutIntLit i res_ty
 792   = return (HsIntegral i expr)
 793
 794   | otherwise
 795   = do  { expr <- newLitInst orig lit res_ty
 796         ; return (HsIntegral i expr) }
 797
 798 tcOverloadedLit orig lit@(HsFractional r fr) res_ty
 799   | not (fr `isHsVar` fromRationalName) -- c.f. HsIntegral case
 800   = do  { rat_ty <- tcMetaTy rationalTyConName
 801         ; fr' <- tcSyntaxOp orig fr (mkFunTy rat_ty res_ty)
 802                 -- Overloaded literals must have liftedTypeKind, because
 803                 -- we're instantiating an overloaded function here,
 804                 -- whereas res_ty might be openTypeKind. This was a bug in 6.2.2
 805                 -- However this'll be picked up by tcSyntaxOp if necessary
 806         ; return (HsFractional r (HsApp (noLoc fr') (nlHsLit (HsRat r rat_ty)))) }
 807
 808   | Just expr <- shortCutFracLit r res_ty
 809   = return (HsFractional r expr)
 810
 811   | otherwise
 812   = do  { expr <- newLitInst orig lit res_ty
 813         ; return (HsFractional r expr) }
 814
 815 tcOverloadedLit orig lit@(HsIsString s fr) res_ty
 816   | not (fr `isHsVar` fromStringName)   -- c.f. HsIntegral case
 817   = do  { str_ty <- tcMetaTy stringTyConName
 818         ; fr' <- tcSyntaxOp orig fr (mkFunTy str_ty res_ty)
 819         ; return (HsIsString s (HsApp (noLoc fr') (nlHsLit (HsString s)))) }
 820
 821   | Just expr <- shortCutStringLit s res_ty
 822   = return (HsIsString s expr)
 823
 824   | otherwise
 825   = do  { expr <- newLitInst orig lit res_ty
 826         ; return (HsIsString s expr) }
 827
 828 newLitInst :: InstOrigin -> HsOverLit Name -> BoxyRhoType -> TcM (HsExpr TcId)
 829 newLitInst orig lit res_ty      -- Make a LitInst
 830   = do  { loc <- getInstLoc orig
 831         ; res_tau <- zapToMonotype res_ty
 832         ; new_uniq <- newUnique
 833         ; let   lit_nm   = mkSystemVarName new_uniq FSLIT("lit")
 834                 lit_inst = LitInst {tci_name = lit_nm, tci_lit = lit,
 835                                     tci_ty = res_tau, tci_loc = loc}
 836         ; extendLIE lit_inst
 837         ; return (HsVar (instToId lit_inst)) }
 838 \end{code}
 839
 840
 841 %************************************************************************
 842 %*                                                                      *
 843                 Note [Pattern coercions]
 844 %*                                                                      *
 845 %************************************************************************
 846
 847 In principle, these program would be reasonable:
 848
 849         f :: (forall a. a->a) -> Int
 850         f (x :: Int->Int) = x 3
 851
 852         g :: (forall a. [a]) -> Bool
 853         g [] = True
 854
 855 In both cases, the function type signature restricts what arguments can be passed
 856 in a call (to polymorphic ones).  The pattern type signature then instantiates this
 857 type.  For example, in the first case,  (forall a. a->a) <= Int -> Int, and we
 858 generate the translated term
 859         f = \x' :: (forall a. a->a).  let x = x' Int in x 3
 860
 861 From a type-system point of view, this is perfectly fine, but it's *very* seldom useful.
 862 And it requires a significant amount of code to implement, becuase we need to decorate
 863 the translated pattern with coercion functions (generated from the subsumption check
 864 by tcSub).
 865
 866 So for now I'm just insisting on type *equality* in patterns.  No subsumption.
 867
 868 Old notes about desugaring, at a time when pattern coercions were handled:
 869
 870 A SigPat is a type coercion and must be handled one at at time.  We can't
 871 combine them unless the type of the pattern inside is identical, and we don't
 872 bother to check for that.  For example:
 873
 874         data T = T1 Int | T2 Bool
 875         f :: (forall a. a -> a) -> T -> t
 876         f (g::Int->Int)   (T1 i) = T1 (g i)
 877         f (g::Bool->Bool) (T2 b) = T2 (g b)
 878
 879 We desugar this as follows:
 880
 881         f = \ g::(forall a. a->a) t::T ->
 882             let gi = g Int
 883             in case t of { T1 i -> T1 (gi i)
 884                            other ->
 885             let gb = g Bool
 886             in case t of { T2 b -> T2 (gb b)
 887                            other -> fail }}
 888
 889 Note that we do not treat the first column of patterns as a
 890 column of variables, because the coerced variables (gi, gb)
 891 would be of different types.  So we get rather grotty code.
 892 But I don't think this is a common case, and if it was we could
 893 doubtless improve it.
 894
 895 Meanwhile, the strategy is:
 896         * treat each SigPat coercion (always non-identity coercions)
 897                 as a separate block
 898         * deal with the stuff inside, and then wrap a binding round
 899                 the result to bind the new variable (gi, gb, etc)
 900
 901
 902 %************************************************************************
 903 %*                                                                      *
 904 \subsection{Errors and contexts}
 905 %*                                                                      *
 906 %************************************************************************
 907
 908 \begin{code}
 909 patCtxt :: Pat Name -> Maybe Message    -- Not all patterns are worth pushing a context
 910 patCtxt (VarPat _)  = Nothing
 911 patCtxt (ParPat _)  = Nothing
 912 patCtxt (AsPat _ _) = Nothing
 913 patCtxt pat         = Just (hang (ptext SLIT("In the pattern:"))
 914                                4 (ppr pat))
 915
 916 -----------------------------------------------
 917
 918 existentialExplode pat
 919   = hang (vcat [text "My brain just exploded.",
 920                 text "I can't handle pattern bindings for existentially-quantified constructors.",
 921                 text "In the binding group for"])
 922         4 (ppr pat)
 923
 924 sigPatCtxt pats bound_tvs pat_tys body_ty tidy_env
 925   = do  { pat_tys' <- mapM zonkTcType pat_tys
 926         ; body_ty' <- zonkTcType body_ty
 927         ; let (env1,  tidy_tys)    = tidyOpenTypes tidy_env (map idType show_ids)
 928               (env2, tidy_pat_tys) = tidyOpenTypes env1 pat_tys'
 929               (env3, tidy_body_ty) = tidyOpenType  env2 body_ty'
 930         ; return (env3,
 931                  sep [ptext SLIT("When checking an existential match that binds"),
 932                       nest 4 (vcat (zipWith ppr_id show_ids tidy_tys)),
 933                       ptext SLIT("The pattern(s) have type(s):") <+> vcat (map ppr tidy_pat_tys),
 934                       ptext SLIT("The body has type:") <+> ppr tidy_body_ty
 935                 ]) }
 936   where
 937     bound_ids = collectPatsBinders pats
 938     show_ids = filter is_interesting bound_ids
 939     is_interesting id = any (`elemVarSet` varTypeTyVars id) bound_tvs
 940
 941     ppr_id id ty = ppr id <+> dcolon <+> ppr ty
 942         -- Don't zonk the types so we get the separate, un-unified versions
 943
 944 badFieldCon :: DataCon -> Name -> SDoc
 945 badFieldCon con field
 946   = hsep [ptext SLIT("Constructor") <+> quotes (ppr con),
 947           ptext SLIT("does not have field"), quotes (ppr field)]
 948
 949 polyPatSig :: TcType -> SDoc
 950 polyPatSig sig_ty
 951   = hang (ptext SLIT("Illegal polymorphic type signature in pattern:"))
 952          4 (ppr sig_ty)
 953
 954 badTypePat pat = ptext SLIT("Illegal type pattern") <+> ppr pat
 955
 956 lazyPatErr pat tvs
 957   = failWithTc $
 958     hang (ptext SLIT("A lazy (~) pattern cannot bind existential type variables"))
 959        2 (vcat (map pprSkolTvBinding tvs))
 960
 961 nonRigidMatch con
 962   =  hang (ptext SLIT("GADT pattern match in non-rigid context for") <+> quotes (ppr con))
 963         2 (ptext SLIT("Tell GHC HQ if you'd like this to unify the context"))
 964
 965 inaccessibleAlt msg
 966   = hang (ptext SLIT("Inaccessible case alternative:")) 2 msg
 967 \end{code}