compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         tcRnLookupName,
  13         tcRnGetInfo,
  14         getModuleExports,
  15         tcRnRecoverDataCon,
  16 #endif
  17         tcRnModule,
  18         tcTopSrcDecls,
  19         tcRnExtCore
  20     ) where
  21
  22 #include "HsVersions.h"
  23
  24 import IO
  25 #ifdef GHCI
  26 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  27 #endif
  28
  29 import DynFlags
  30 import StaticFlags
  31 import HsSyn
  32 import RdrHsSyn
  33
  34 import PrelNames
  35 import RdrName
  36 import TcHsSyn
  37 import TcExpr
  38 import TcRnMonad
  39 import TcType
  40 import Inst
  41 import FamInst
  42 import InstEnv
  43 import FamInstEnv
  44 import TcBinds
  45 import TcDefaults
  46 import TcEnv
  47 import TcRules
  48 import TcForeign
  49 import TcInstDcls
  50 import TcIface
  51 import MkIface
  52 import IfaceSyn
  53 import TcSimplify
  54 import TcTyClsDecls
  55 import LoadIface
  56 import RnNames
  57 import RnEnv
  58 import RnSource
  59 import RnHsDoc
  60 import PprCore
  61 import CoreSyn
  62 import ErrUtils
  63 import Id
  64 import Var
  65 import Module
  66 import UniqFM
  67 import Name
  68 import NameEnv
  69 import NameSet
  70 import TyCon
  71 import SrcLoc
  72 import HscTypes
  73 import ListSetOps
  74 import Outputable
  75
  76 #ifdef GHCI
  77 import Linker
  78 import DataCon
  79 import TcHsType
  80 import TcMType
  81 import TcMatches
  82 import TcGadt
  83 import RnTypes
  84 import RnExpr
  85 import IfaceEnv
  86 import MkId
  87 import TysWiredIn
  88 import IdInfo
  89 import {- Kind parts of -} Type
  90 import BasicTypes
  91 #endif
  92
  93 import FastString
  94 import Maybes
  95 import Util
  96 import Bag
  97
  98 import Control.Monad    ( unless )
  99 import Data.Maybe       ( isJust )
 100 import Foreign.Ptr      ( Ptr )
 101
 102 \end{code}
 103
 104
 105
 106 %************************************************************************
 107 %*                                                                      *
 108         Typecheck and rename a module
 109 %*                                                                      *
 110 %************************************************************************
 111
 112
 113 \begin{code}
 114 tcRnModule :: HscEnv
 115            -> HscSource
 116            -> Bool              -- True <=> save renamed syntax
 117            -> Located (HsModule RdrName)
 118            -> IO (Messages, Maybe TcGblEnv)
 119
 120 tcRnModule hsc_env hsc_src save_rn_syntax
 121          (L loc (HsModule maybe_mod export_ies
 122                           import_decls local_decls mod_deprec _
 123                           module_info maybe_doc))
 124  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 125
 126    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 127          this_mod = case maybe_mod of
 128                         Nothing  -> mAIN        -- 'module M where' is omitted
 129                         Just (L _ mod) -> mkModule this_pkg mod } ;
 130                                                 -- The normal case
 131
 132    initTc hsc_env hsc_src save_rn_syntax this_mod $
 133    setSrcSpan loc $
 134    do {         -- Deal with imports;
 135         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 136         setGblEnv tcg_env               $ do {
 137
 138                 -- Load the hi-boot interface for this module, if any
 139                 -- We do this now so that the boot_names can be passed
 140                 -- to tcTyAndClassDecls, because the boot_names are
 141                 -- automatically considered to be loop breakers
 142                 --
 143                 -- Do this *after* tcRnImports, so that we know whether
 144                 -- a module that we import imports us; and hence whether to
 145                 -- look for a hi-boot file
 146         boot_iface <- tcHiBootIface hsc_src this_mod ;
 147
 148                 -- Rename and type check the declarations
 149         traceRn (text "rn1a") ;
 150         tcg_env <- if isHsBoot hsc_src then
 151                         tcRnHsBootDecls local_decls
 152                    else
 153                         tcRnSrcDecls boot_iface local_decls ;
 154         setGblEnv tcg_env               $ do {
 155
 156                 -- Report the use of any deprecated things
 157                 -- We do this *before* processsing the export list so
 158                 -- that we don't bleat about re-exporting a deprecated
 159                 -- thing (especially via 'module Foo' export item)
 160                 -- That is, only uses in the *body* of the module are complained about
 161         traceRn (text "rn3") ;
 162         failIfErrsM ;   -- finishDeprecations crashes sometimes
 163                         -- as a result of typechecker repairs (e.g. unboundNames)
 164         tcg_env <- finishDeprecations (hsc_dflags hsc_env) mod_deprec tcg_env ;
 165
 166                 -- Process the export list
 167         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 168         traceRn (text "rn4") ;
 169
 170         -- Compare the hi-boot iface (if any) with the real thing
 171         -- Must be done after processing the exports
 172         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 173
 174         -- Make the new type env available to stuff slurped from interface files
 175         -- Must do this after checkHiBootIface, because the latter might add new
 176         -- bindings for boot_dfuns, which may be mentioned in imported unfoldings
 177         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 178
 179                 -- Rename the Haddock documentation
 180         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 181
 182                 -- Report unused names
 183         reportUnusedNames export_ies tcg_env ;
 184
 185                 -- Dump output and return
 186         tcDump tcg_env ;
 187         return tcg_env
 188     }}}}
 189 \end{code}
 190
 191
 192 %************************************************************************
 193 %*                                                                      *
 194                 Import declarations
 195 %*                                                                      *
 196 %************************************************************************
 197
 198 \begin{code}
 199 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 200 tcRnImports hsc_env this_mod import_decls
 201   = do  { (rn_imports, rdr_env, imports) <- rnImports import_decls ;
 202
 203         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 204               ; dep_mods = imp_dep_mods imports
 205
 206                 -- We want instance declarations from all home-package
 207                 -- modules below this one, including boot modules, except
 208                 -- ourselves.  The 'except ourselves' is so that we don't
 209                 -- get the instances from this module's hs-boot file
 210               ; want_instances :: ModuleName -> Bool
 211               ; want_instances mod = mod `elemUFM` dep_mods
 212                                    && mod /= moduleName this_mod
 213               ; home_insts = hptInstances hsc_env want_instances
 214               } ;
 215
 216                 -- Record boot-file info in the EPS, so that it's
 217                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 218                 -- and any other incrementally-performed imports
 219         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 220
 221                 -- Update the gbl env
 222         ; updGblEnv ( \ gbl ->
 223                 gbl { tcg_rdr_env    = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 224                       tcg_imports    = tcg_imports gbl `plusImportAvails` imports,
 225                       tcg_rn_imports = fmap (const rn_imports) (tcg_rn_imports gbl),
 226                       tcg_inst_env   = extendInstEnvList (tcg_inst_env gbl) home_insts
 227                 }) $ do {
 228
 229         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 230                 -- Fail if there are any errors so far
 231                 -- The error printing (if needed) takes advantage
 232                 -- of the tcg_env we have now set
 233 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 234         ; failIfErrsM
 235
 236                 -- Load any orphan-module and family instance-module
 237                 -- interfaces, so that their rules and instance decls will be
 238                 -- found.
 239         ; loadOrphanModules (imp_orphs  imports) False
 240         ; loadOrphanModules (imp_finsts imports) True
 241
 242                 -- Check type-familily consistency
 243         ; traceRn (text "rn1: checking family instance consistency")
 244         ; let { dir_imp_mods = map (\ (mod, _, _) -> mod)
 245                              . moduleEnvElts
 246                              . imp_mods
 247                              $ imports }
 248         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 249
 250         ; getGblEnv } }
 251 \end{code}
 252
 253
 254 %************************************************************************
 255 %*                                                                      *
 256         Type-checking external-core modules
 257 %*                                                                      *
 258 %************************************************************************
 259
 260 \begin{code}
 261 tcRnExtCore :: HscEnv
 262             -> HsExtCore RdrName
 263             -> IO (Messages, Maybe ModGuts)
 264         -- Nothing => some error occurred
 265
 266 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 267         -- The decls are IfaceDecls; all names are original names
 268  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 269
 270    initTc hsc_env ExtCoreFile False this_mod $ do {
 271
 272    let { ldecls  = map noLoc decls } ;
 273
 274         -- Deal with the type declarations; first bring their stuff
 275         -- into scope, then rname them, then type check them
 276    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 277
 278    setGblEnv tcg_env $ do {
 279
 280    rn_decls <- rnTyClDecls ldecls ;
 281    failIfErrsM ;
 282
 283         -- Dump trace of renaming part
 284    rnDump (ppr rn_decls) ;
 285
 286         -- Typecheck them all together so that
 287         -- any mutually recursive types are done right
 288    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 289         -- Make the new type env available to stuff slurped from interface files
 290
 291    setGblEnv tcg_env $ do {
 292
 293         -- Now the core bindings
 294    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 295
 296         -- Wrap up
 297    let {
 298         bndrs      = bindersOfBinds core_binds ;
 299         my_exports = map (Avail . idName) bndrs ;
 300                 -- ToDo: export the data types also?
 301
 302         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 303
 304         mod_guts = ModGuts {    mg_module    = this_mod,
 305                                 mg_boot      = False,
 306                                 mg_usages    = [],              -- ToDo: compute usage
 307                                 mg_dir_imps  = [],              -- ??
 308                                 mg_deps      = noDependencies,  -- ??
 309                                 mg_exports   = my_exports,
 310                                 mg_types     = final_type_env,
 311                                 mg_insts     = tcg_insts tcg_env,
 312                                 mg_fam_insts = tcg_fam_insts tcg_env,
 313                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 314                                 mg_rules     = [],
 315                                 mg_binds     = core_binds,
 316
 317                                 -- Stubs
 318                                 mg_rdr_env   = emptyGlobalRdrEnv,
 319                                 mg_fix_env   = emptyFixityEnv,
 320                                 mg_deprecs   = NoDeprecs,
 321                                 mg_foreign   = NoStubs,
 322                                 mg_hpc_info  = noHpcInfo,
 323                                 mg_modBreaks = emptyModBreaks
 324                     } } ;
 325
 326    tcCoreDump mod_guts ;
 327
 328    return mod_guts
 329    }}}}
 330
 331 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 332   = emptyRdrGroup { hs_tyclds = decls }
 333 \end{code}
 334
 335
 336 %************************************************************************
 337 %*                                                                      *
 338         Type-checking the top level of a module
 339 %*                                                                      *
 340 %************************************************************************
 341
 342 \begin{code}
 343 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 344         -- Returns the variables free in the decls
 345         -- Reason: solely to report unused imports and bindings
 346 tcRnSrcDecls boot_iface decls
 347  = do {         -- Do all the declarations
 348         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 349
 350              --         Finish simplifying class constraints
 351              --
 352              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 353              -- How could there be ambiguous ones?  They can only arise if a
 354              -- top-level decl falls under the monomorphism restriction
 355              -- and no subsequent decl instantiates its type.
 356              --
 357              -- We do this after checkMain, so that we use the type info
 358              -- thaat checkMain adds
 359              --
 360              -- We do it with both global and local env in scope:
 361              --  * the global env exposes the instances to tcSimplifyTop
 362              --  * the local env exposes the local Ids to tcSimplifyTop,
 363              --    so that we get better error messages (monomorphism restriction)
 364         traceTc (text "Tc8") ;
 365         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 366
 367             -- Backsubstitution.  This must be done last.
 368             -- Even tcSimplifyTop may do some unification.
 369         traceTc (text "Tc9") ;
 370         let { (tcg_env, _) = tc_envs
 371             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 372                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 373             ; all_binds = binds `unionBags` inst_binds } ;
 374
 375         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 376
 377         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 378             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 379                                    tcg_binds = binds',
 380                                    tcg_rules = rules',
 381                                    tcg_fords = fords' } } ;
 382
 383         return (tcg_env' { tcg_binds = tcg_binds tcg_env' })
 384    }
 385
 386 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 387 -- Loops around dealing with each top level inter-splice group
 388 -- in turn, until it's dealt with the entire module
 389 tc_rn_src_decls boot_details ds
 390  = do { let { (first_group, group_tail) = findSplice ds } ;
 391                 -- If ds is [] we get ([], Nothing)
 392
 393         -- Deal with decls up to, but not including, the first splice
 394         (tcg_env, rn_decls) <- checkNoErrs $ rnTopSrcDecls first_group ;
 395                 -- checkNoErrs: stop if renaming fails
 396
 397         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 398                               tcTopSrcDecls boot_details rn_decls ;
 399
 400         -- If there is no splice, we're nearly done
 401         setEnvs (tcg_env, tcl_env) $
 402         case group_tail of {
 403            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 404                            return (tcg_env, tcl_env)
 405                       } ;
 406
 407         -- If there's a splice, we must carry on
 408            Just (SpliceDecl splice_expr, rest_ds) -> do {
 409 #ifndef GHCI
 410         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 411 #else
 412
 413         -- Rename the splice expression, and get its supporting decls
 414         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 415                 -- checkNoErrs: don't typecheck if renaming failed
 416         rnDump (ppr rn_splice_expr) ;
 417
 418         -- Execute the splice
 419         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 420
 421         -- Glue them on the front of the remaining decls and loop
 422         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 423         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 424 #endif /* GHCI */
 425     } } }
 426 \end{code}
 427
 428 %************************************************************************
 429 %*                                                                      *
 430         Compiling hs-boot source files, and
 431         comparing the hi-boot interface with the real thing
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 \begin{code}
 436 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 437 tcRnHsBootDecls decls
 438    = do { let { (first_group, group_tail) = findSplice decls }
 439
 440         ; case group_tail of
 441              Just stuff -> spliceInHsBootErr stuff
 442              Nothing    -> return ()
 443
 444                 -- Rename the declarations
 445         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 446         ; setGblEnv tcg_env $ do {
 447
 448         -- Todo: check no foreign decls, no rules, no default decls
 449
 450                 -- Typecheck type/class decls
 451         ; traceTc (text "Tc2")
 452         ; let tycl_decls = hs_tyclds rn_group
 453         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 454         ; setGblEnv tcg_env     $ do {
 455
 456                 -- Typecheck instance decls
 457         ; traceTc (text "Tc3")
 458         ; (tcg_env, inst_infos, _deriv_binds)
 459             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 460         ; setGblEnv tcg_env     $ do {
 461
 462                 -- Typecheck value declarations
 463         ; traceTc (text "Tc5")
 464         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 465
 466                 -- Wrap up
 467                 -- No simplification or zonking to do
 468         ; traceTc (text "Tc7a")
 469         ; gbl_env <- getGblEnv
 470
 471                 -- Make the final type-env
 472                 -- Include the dfun_ids so that their type sigs
 473                 -- are written into the interface file
 474         ; let { type_env0 = tcg_type_env gbl_env
 475               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 476               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 477               ; dfun_ids = map iDFunId inst_infos }
 478         ; return (gbl_env { tcg_type_env = type_env2 })
 479    }}}}
 480
 481 spliceInHsBootErr (SpliceDecl (L loc _), _)
 482   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 483 \end{code}
 484
 485 Once we've typechecked the body of the module, we want to compare what
 486 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 487
 488 \begin{code}
 489 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 490 -- Compare the hi-boot file for this module (if there is one)
 491 -- with the type environment we've just come up with
 492 -- In the common case where there is no hi-boot file, the list
 493 -- of boot_names is empty.
 494 --
 495 -- The bindings we return give bindings for the dfuns defined in the
 496 -- hs-boot file, such as        $fbEqT = $fEqT
 497
 498 checkHiBootIface
 499         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 500                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 501                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 502         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 503                       md_types = boot_type_env, md_exports = boot_exports })
 504   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 505   = return tcg_env
 506
 507   | otherwise
 508   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 509                                 ppr boot_exports)) ;
 510
 511                 -- Check the exports of the boot module, one by one
 512         ; mapM_ check_export boot_exports
 513
 514                 -- Check instance declarations
 515         ; mb_dfun_prs <- mapM check_inst boot_insts
 516         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
 517                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
 518               dfun_prs   = catMaybes mb_dfun_prs
 519               boot_dfuns = map fst dfun_prs
 520               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 521                                      | (boot_dfun, dfun) <- dfun_prs ]
 522
 523                 -- Check for no family instances
 524         ; unless (null boot_fam_insts) $
 525             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 526                    "instances in boot files yet...")
 527             -- FIXME: Why?  The actual comparison is not hard, but what would
 528             --        be the equivalent to the dfun bindings returned for class
 529             --        instances?  We can't easily equate tycons...
 530
 531         ; return tcg_env' }
 532   where
 533     check_export boot_avail     -- boot_avail is exported by the boot iface
 534       | name `elem` dfun_names = return ()
 535       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 536                                                 -- 'error' is handled by a rather gross hack
 537                                                 -- (see comments in GHC.Err.hs-boot)
 538
 539         -- Check that the actual module exports the same thing
 540       | not (null missing_names)
 541       = addErrTc (missingBootThing (head missing_names) "exported by")
 542
 543         -- If the boot module does not *define* the thing, we are done
 544         -- (it simply re-exports it, and names match, so nothing further to do)
 545       | isNothing mb_boot_thing = return ()
 546
 547         -- Check that the actual module also defines the thing, and
 548         -- then compare the definitions
 549       | Just real_thing <- lookupTypeEnv local_type_env name
 550       = do { let boot_decl = tyThingToIfaceDecl (fromJust mb_boot_thing)
 551                  real_decl = tyThingToIfaceDecl real_thing
 552            ; checkTc (checkBootDecl boot_decl real_decl)
 553                      (bootMisMatch real_thing boot_decl real_decl) }
 554                 -- The easiest way to check compatibility is to convert to
 555                 -- iface syntax, where we already have good comparison functions
 556
 557       | otherwise
 558       = addErrTc (missingBootThing name "defined in")
 559       where
 560         name          = availName boot_avail
 561         mb_boot_thing = lookupTypeEnv boot_type_env name
 562         missing_names = case lookupNameEnv local_export_env name of
 563                           Nothing    -> [name]
 564                           Just avail -> availNames boot_avail `minusList` availNames avail
 565
 566     dfun_names = map getName boot_insts
 567
 568     local_export_env :: NameEnv AvailInfo
 569     local_export_env = availsToNameEnv local_exports
 570
 571     check_inst :: Instance -> TcM (Maybe (Id, Id))
 572         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 573     check_inst boot_inst
 574         = case [dfun | inst <- local_insts,
 575                        let dfun = instanceDFunId inst,
 576                        idType dfun `tcEqType` boot_inst_ty ] of
 577             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 578             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 579         where
 580           boot_dfun = instanceDFunId boot_inst
 581           boot_inst_ty = idType boot_dfun
 582           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 583
 584
 585 ----------------
 586 missingBootThing thing what
 587   = ppr thing <+> ptext SLIT("is exported by the hs-boot file, but not")
 588               <+> text what <+> ptext SLIT("the module")
 589
 590 bootMisMatch thing boot_decl real_decl
 591   = vcat [ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file"),
 592           ptext SLIT("Main module:") <+> ppr real_decl,
 593           ptext SLIT("Boot file:  ") <+> ppr boot_decl]
 594
 595 instMisMatch inst
 596   = hang (ppr inst)
 597        2 (ptext SLIT("is defined in the hs-boot file, but not in the module itself"))
 598 \end{code}
 599
 600
 601 %************************************************************************
 602 %*                                                                      *
 603         Type-checking the top level of a module
 604 %*                                                                      *
 605 %************************************************************************
 606
 607 tcRnGroup takes a bunch of top-level source-code declarations, and
 608  * renames them
 609  * gets supporting declarations from interface files
 610  * typechecks them
 611  * zonks them
 612  * and augments the TcGblEnv with the results
 613
 614 In Template Haskell it may be called repeatedly for each group of
 615 declarations.  It expects there to be an incoming TcGblEnv in the
 616 monad; it augments it and returns the new TcGblEnv.
 617
 618 \begin{code}
 619 ------------------------------------------------
 620 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 621 rnTopSrcDecls group
 622  = do {         -- Bring top level binders into scope
 623         tcg_env <- importsFromLocalDecls group ;
 624         setGblEnv tcg_env $ do {
 625
 626         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 627
 628                 -- Rename the source decls
 629         (tcg_env, rn_decls) <- rnSrcDecls group ;
 630         failIfErrsM ;
 631
 632                 -- save the renamed syntax, if we want it
 633         let { tcg_env'
 634                 | Just grp <- tcg_rn_decls tcg_env
 635                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 636                 | otherwise
 637                    = tcg_env };
 638
 639                 -- Dump trace of renaming part
 640         rnDump (ppr rn_decls) ;
 641
 642         return (tcg_env', rn_decls)
 643    }}
 644
 645 ------------------------------------------------
 646 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 647 tcTopSrcDecls boot_details
 648         (HsGroup { hs_tyclds = tycl_decls,
 649                    hs_instds = inst_decls,
 650                    hs_derivds = deriv_decls,
 651                    hs_fords  = foreign_decls,
 652                    hs_defds  = default_decls,
 653                    hs_ruleds = rule_decls,
 654                    hs_valds  = val_binds })
 655  = do {         -- Type-check the type and class decls, and all imported decls
 656                 -- The latter come in via tycl_decls
 657         traceTc (text "Tc2") ;
 658
 659         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 660         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 661         -- an error we'd better stop now, to avoid a cascade
 662
 663         -- Make these type and class decls available to stuff slurped from interface files
 664         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 665
 666
 667         setGblEnv tcg_env       $ do {
 668                 -- Source-language instances, including derivings,
 669                 -- and import the supporting declarations
 670         traceTc (text "Tc3") ;
 671         (tcg_env, inst_infos, deriv_binds)
 672             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 673         setGblEnv tcg_env       $ do {
 674
 675                 -- Foreign import declarations next.  No zonking necessary
 676                 -- here; we can tuck them straight into the global environment.
 677         traceTc (text "Tc4") ;
 678         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 679         tcExtendGlobalValEnv fi_ids     $ do {
 680
 681                 -- Default declarations
 682         traceTc (text "Tc4a") ;
 683         default_tys <- tcDefaults default_decls ;
 684         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 685
 686                 -- Value declarations next
 687                 -- We also typecheck any extra binds that came out
 688                 -- of the "deriving" process (deriv_binds)
 689         traceTc (text "Tc5") ;
 690         (tc_val_binds,   tcl_env) <- tcTopBinds val_binds ;
 691         setLclTypeEnv tcl_env   $ do {
 692
 693                 -- Now GHC-generated derived bindings and generics
 694                 -- Do not generate warnings from compiler-generated code
 695         (tc_deriv_binds, tcl_env) <- discardWarnings $ setOptM Opt_GlasgowExts $
 696                                      tcTopBinds deriv_binds ;
 697
 698                 -- Second pass over class and instance declarations,
 699         traceTc (text "Tc6") ;
 700         (inst_binds, tcl_env)     <- setLclTypeEnv tcl_env $ tcInstDecls2 tycl_decls inst_infos ;
 701         showLIE (text "after instDecls2") ;
 702
 703                 -- Foreign exports
 704                 -- They need to be zonked, so we return them
 705         traceTc (text "Tc7") ;
 706         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 707
 708                 -- Rules
 709         rules <- tcRules rule_decls ;
 710
 711                 -- Wrap up
 712         traceTc (text "Tc7a") ;
 713         tcg_env <- getGblEnv ;
 714         let { all_binds = tc_val_binds   `unionBags`
 715                           tc_deriv_binds `unionBags`
 716                           inst_binds     `unionBags`
 717                           foe_binds  ;
 718
 719                 -- Extend the GblEnv with the (as yet un-zonked)
 720                 -- bindings, rules, foreign decls
 721               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 722                                     tcg_rules = tcg_rules tcg_env ++ rules,
 723                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 724         return (tcg_env', tcl_env)
 725     }}}}}}
 726 \end{code}
 727
 728
 729 %************************************************************************
 730 %*                                                                      *
 731         Checking for 'main'
 732 %*                                                                      *
 733 %************************************************************************
 734
 735 \begin{code}
 736 checkMain :: TcM TcGblEnv
 737 -- If we are in module Main, check that 'main' is defined.
 738 checkMain
 739   = do { tcg_env   <- getGblEnv ;
 740          dflags    <- getDOpts ;
 741          let { main_mod = mainModIs dflags ;
 742                main_fn  = case mainFunIs dflags of {
 743                                 Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn)) ;
 744                                 Nothing -> main_RDR_Unqual } } ;
 745
 746          check_main dflags tcg_env main_mod main_fn
 747     }
 748
 749
 750 check_main dflags tcg_env main_mod main_fn
 751  | mod /= main_mod
 752  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 753    return tcg_env
 754
 755  | otherwise
 756  = addErrCtxt mainCtxt                  $
 757    do   { mb_main <- lookupSrcOcc_maybe main_fn
 758                 -- Check that 'main' is in scope
 759                 -- It might be imported from another module!
 760         ; case mb_main of {
 761              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 762                            ; complain_no_main
 763                            ; return tcg_env } ;
 764              Just main_name -> do
 765         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 766         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 767                         -- :Main.main :: IO () = runMainIO main
 768
 769         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 770                              tcInferRho rhs
 771
 772                 -- See Note [Root-main Id]
 773         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 774                                    (mkVarOccFS FSLIT("main"))
 775                                    (getSrcLoc main_name)
 776               ; root_main_id = Id.mkExportedLocalId root_main_name ty
 777               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 778
 779         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 780                                         `snocBag` main_bind,
 781                             tcg_dus   = tcg_dus tcg_env
 782                                         `plusDU` usesOnly (unitFV main_name)
 783                         -- Record the use of 'main', so that we don't
 784                         -- complain about it being defined but not used
 785                  })
 786     }}}
 787   where
 788     mod = tcg_mod tcg_env
 789
 790     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 791                      | otherwise = failWithTc noMainMsg
 792         -- In interactive mode, don't worry about the absence of 'main'
 793         -- In other modes, fail altogether, so that we don't go on
 794         -- and complain a second time when processing the export list.
 795
 796     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 797     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 798                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 799 \end{code}
 800
 801 Note [Root-main Id]
 802 ~~~~~~~~~~~~~~~~~~~
 803 The function that the RTS invokes is always :Main.main, which we call
 804 root_main_id.  (Because GHC allows the user to have a module not
 805 called Main as the main module, we can't rely on the main function
 806 being called "Main.main".  That's why root_main_id has a fixed module
 807 ":Main".)
 808
 809 This is unusual: it's a LocalId whose Name has a Module from another
 810 module.  Tiresomely, we must filter it out again in MkIface, les we
 811 get two defns for 'main' in the interface file!
 812
 813
 814 %*********************************************************
 815 %*                                                       *
 816                 GHCi stuff
 817 %*                                                       *
 818 %*********************************************************
 819
 820 \begin{code}
 821 #ifdef GHCI
 822 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 823 setInteractiveContext hsc_env icxt thing_inside
 824   = let
 825         -- Initialise the tcg_inst_env with instances
 826         -- from all home modules.  This mimics the more selective
 827         -- call to hptInstances in tcRnModule
 828         dfuns = hptInstances hsc_env (\mod -> True)
 829     in
 830     updGblEnv (\env -> env {
 831         tcg_rdr_env  = ic_rn_gbl_env icxt,
 832         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 833
 834
 835     tcExtendIdEnv (ic_tmp_ids icxt) $
 836         -- tcExtendIdEnv does lots:
 837         --   - it extends the local type env (tcl_env) with the given Ids,
 838         --   - it extends the local rdr env (tcl_rdr) with the Names from
 839         --     the given Ids
 840         --   - it adds the free tyvars of the Ids to the tcl_tyvars
 841         --     set.
 842         --
 843         -- later ids in ic_tmp_ids must shadow earlier ones with the same
 844         -- OccName, and tcExtendIdEnv implements this behaviour.
 845
 846     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
 847         ; thing_inside }
 848 \end{code}
 849
 850
 851 \begin{code}
 852 tcRnStmt :: HscEnv
 853          -> InteractiveContext
 854          -> LStmt RdrName
 855          -> IO (Maybe ([Id], LHsExpr Id))
 856                 -- The returned [Id] is the list of new Ids bound by
 857                 -- this statement.  It can be used to extend the
 858                 -- InteractiveContext via extendInteractiveContext.
 859                 --
 860                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 861                 -- a list of the bound values, coerced to ().
 862
 863 tcRnStmt hsc_env ictxt rdr_stmt
 864   = initTcPrintErrors hsc_env iNTERACTIVE $
 865     setInteractiveContext hsc_env ictxt $ do {
 866
 867     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 868     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 869     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 870     failIfErrsM ;
 871
 872     -- The real work is done here
 873     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 874     zonked_expr <- zonkTopLExpr tc_expr ;
 875     zonked_ids  <- zonkTopBndrs bound_ids ;
 876
 877         -- None of the Ids should be of unboxed type, because we
 878         -- cast them all to HValues in the end!
 879     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 880
 881     traceTc (text "tcs 1") ;
 882     let {       -- (a) Make all the bound ids "global" ids, now that
 883                 --     they're notionally top-level bindings.  This is
 884                 --     important: otherwise when we come to compile an expression
 885                 --     using these ids later, the byte code generator will consider
 886                 --     the occurrences to be free rather than global.
 887                 --
 888                 -- (b) Tidy their types; this is important, because :info may
 889                 --     ask to look at them, and :info expects the things it looks
 890                 --     up to have tidy types
 891         global_ids = map globaliseAndTidy zonked_ids ;
 892
 893 {- ---------------------------------------------
 894    At one stage I removed any shadowed bindings from the type_env;
 895    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
 896    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
 897    GHCi session
 898          Prelude> let f n = n * 2 :: Int
 899          Prelude> fName <- runQ [| f |]
 900          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 901          14
 902          Prelude> let f n = n * 3 :: Int
 903          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 904    In the last line we use 'fName', which resolves to the *first* 'f'
 905    in scope. If we delete it from the type env, GHCi crashes because
 906    it doesn't expect that.
 907
 908    Hence this code is commented out
 909
 910 -------------------------------------------------- -}
 911     } ;
 912
 913     dumpOptTcRn Opt_D_dump_tc
 914         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 915                text "Typechecked expr" <+> ppr zonked_expr]) ;
 916
 917     returnM (global_ids, zonked_expr)
 918     }
 919   where
 920     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 921                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 922
 923 globaliseAndTidy :: Id -> Id
 924 globaliseAndTidy id
 925 -- Give the Id a Global Name, and tidy its type
 926   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
 927   where
 928     tidy_type = tidyTopType (idType id)
 929 \end{code}
 930
 931 Here is the grand plan, implemented in tcUserStmt
 932
 933         What you type                   The IO [HValue] that hscStmt returns
 934         -------------                   ------------------------------------
 935         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 936                                         bindings: [x,y,...]
 937
 938         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 939                                         bindings: [x,y,...]
 940
 941         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 942           [NB: result not printed]      bindings: [it]
 943
 944         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 945           result showable)              bindings: [it]
 946
 947         expr (of non-IO type,
 948           result not showable)  ==>     error
 949
 950
 951 \begin{code}
 952 ---------------------------
 953 type PlanResult = ([Id], LHsExpr Id)
 954 type Plan = TcM PlanResult
 955
 956 runPlans :: [Plan] -> TcM PlanResult
 957 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 958 -- If one succeeds, take it.
 959 runPlans []     = panic "runPlans"
 960 runPlans [p]    = p
 961 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 962
 963 --------------------
 964 mkPlan :: LStmt Name -> TcM PlanResult
 965 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 966   = do  { uniq <- newUnique             -- is treated very specially
 967         ; let fresh_it  = itName uniq
 968               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 969               matches   = [mkMatch [] expr emptyLocalBinds]
 970               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 971               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 972                                            (HsVar bindIOName) noSyntaxExpr
 973               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 974                                            (HsVar thenIOName) placeHolderType
 975
 976         -- The plans are:
 977         --      [it <- e; print it]     but not if it::()
 978         --      [it <- e]
 979         --      [let it = e; print it]
 980         ; runPlans [    -- Plan A
 981                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 982                        ; it_ty <- zonkTcType (idType it_id)
 983                        ; ifM (isUnitTy it_ty) failM
 984                        ; return stuff },
 985
 986                         -- Plan B; a naked bind statment
 987                     tcGhciStmts [bind_stmt],
 988
 989                         -- Plan C; check that the let-binding is typeable all by itself.
 990                         -- If not, fail; if so, try to print it.
 991                         -- The two-step process avoids getting two errors: one from
 992                         -- the expression itself, and one from the 'print it' part
 993                         -- This two-step story is very clunky, alas
 994                     do { checkNoErrs (tcGhciStmts [let_stmt])
 995                                 --- checkNoErrs defeats the error recovery of let-bindings
 996                        ; tcGhciStmts [let_stmt, print_it] }
 997           ]}
 998
 999 mkPlan stmt@(L loc (BindStmt {}))
1000   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1001   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1002                                            (HsVar thenIOName) placeHolderType
1003
1004         ; print_bind_result <- doptM Opt_PrintBindResult
1005         ; let print_plan = do
1006                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1007                   ; v_ty <- zonkTcType (idType v_id)
1008                   ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1009                   ; return stuff }
1010
1011         -- The plans are:
1012         --      [stmt; print v]         but not if v::()
1013         --      [stmt]
1014         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1015                     [tcGhciStmts [stmt]])
1016         }
1017
1018 mkPlan stmt
1019   = tcGhciStmts [stmt]
1020
1021 ---------------------------
1022 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1023 tcGhciStmts stmts
1024  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1025         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1026         let {
1027             io_ty     = mkTyConApp ioTyCon [] ;
1028             ret_ty    = mkListTy unitTy ;
1029             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1030             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
1031                                         (emptyRefinement, io_ret_ty) ;
1032
1033             names = map unLoc (collectLStmtsBinders stmts) ;
1034
1035                 -- mk_return builds the expression
1036                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1037                 --
1038                 -- Despite the inconvenience of building the type applications etc,
1039                 -- this *has* to be done in type-annotated post-typecheck form
1040                 -- because we are going to return a list of *polymorphic* values
1041                 -- coerced to type (). If we built a *source* stmt
1042                 --      return [coerce x, ..., coerce z]
1043                 -- then the type checker would instantiate x..z, and we wouldn't
1044                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1045                 -- if they were overloaded, since they aren't applied to anything.)
1046             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1047                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1048             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1049                                  (nlHsVar id)
1050          } ;
1051
1052         -- OK, we're ready to typecheck the stmts
1053         traceTc (text "tcs 2") ;
1054         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1055                                            mappM tcLookupId names ;
1056                                         -- Look up the names right in the middle,
1057                                         -- where they will all be in scope
1058
1059         -- Simplify the context
1060         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1061                 -- checkNoErrs ensures that the plan fails if context redn fails
1062
1063         return (ids, mkHsDictLet const_binds $
1064                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1065     }
1066 \end{code}
1067
1068
1069 tcRnExpr just finds the type of an expression
1070
1071 \begin{code}
1072 tcRnExpr :: HscEnv
1073          -> InteractiveContext
1074          -> LHsExpr RdrName
1075          -> IO (Maybe Type)
1076 tcRnExpr hsc_env ictxt rdr_expr
1077   = initTcPrintErrors hsc_env iNTERACTIVE $
1078     setInteractiveContext hsc_env ictxt $ do {
1079
1080     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1081     failIfErrsM ;
1082
1083         -- Now typecheck the expression;
1084         -- it might have a rank-2 type (e.g. :t runST)
1085     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1086     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1087     tcSimplifyInteractive lie_top ;
1088
1089     let { all_expr_ty = mkForAllTys qtvs $
1090                         mkFunTys (map (idType . instToId) dict_insts)   $
1091                         res_ty } ;
1092     zonkTcType all_expr_ty
1093     }
1094   where
1095     smpl_doc = ptext SLIT("main expression")
1096 \end{code}
1097
1098 tcRnType just finds the kind of a type
1099
1100 \begin{code}
1101 tcRnType :: HscEnv
1102          -> InteractiveContext
1103          -> LHsType RdrName
1104          -> IO (Maybe Kind)
1105 tcRnType hsc_env ictxt rdr_type
1106   = initTcPrintErrors hsc_env iNTERACTIVE $
1107     setInteractiveContext hsc_env ictxt $ do {
1108
1109     rn_type <- rnLHsType doc rdr_type ;
1110     failIfErrsM ;
1111
1112         -- Now kind-check the type
1113     (ty', kind) <- kcHsType rn_type ;
1114     return kind
1115     }
1116   where
1117     doc = ptext SLIT("In GHCi input")
1118
1119 #endif /* GHCi */
1120 \end{code}
1121
1122
1123 %************************************************************************
1124 %*                                                                      *
1125         More GHCi stuff, to do with browsing and getting info
1126 %*                                                                      *
1127 %************************************************************************
1128
1129 \begin{code}
1130 #ifdef GHCI
1131 -- ASSUMES that the module is either in the HomePackageTable or is
1132 -- a package module with an interface on disk.  If neither of these is
1133 -- true, then the result will be an error indicating the interface
1134 -- could not be found.
1135 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1136 getModuleExports hsc_env mod
1137   = let
1138       ic        = hsc_IC hsc_env
1139       checkMods = ic_toplev_scope ic ++ ic_exports ic
1140     in
1141     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1142
1143 -- Get the export avail info and also load all orphan and family-instance
1144 -- modules.  Finally, check that the family instances of all modules in the
1145 -- interactive context are consistent (these modules are in the second
1146 -- argument).
1147 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1148 tcGetModuleExports mod directlyImpMods
1149   = do { let doc = ptext SLIT("context for compiling statements")
1150        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1151
1152                 -- Load any orphan-module and family instance-module
1153                 -- interfaces, so their instances are visible.
1154        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1155        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1156
1157                 -- Check that the family instances of all directly loaded
1158                 -- modules are consistent.
1159        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1160
1161        ; ifaceExportNames (mi_exports iface)
1162        }
1163
1164 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1165 tcRnLookupRdrName hsc_env rdr_name
1166   = initTcPrintErrors hsc_env iNTERACTIVE $
1167     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1168     lookup_rdr_name rdr_name
1169
1170 lookup_rdr_name rdr_name = do {
1171         -- If the identifier is a constructor (begins with an
1172         -- upper-case letter), then we need to consider both
1173         -- constructor and type class identifiers.
1174     let { rdr_names = dataTcOccs rdr_name } ;
1175
1176         -- results :: [Either Messages Name]
1177     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1178
1179     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1180         -- The successful lookups will be (Just name)
1181     let { (warns_s, good_names) = unzip [ (msgs, name)
1182                                         | (msgs, Just name) <- results] ;
1183           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1184
1185         -- Fail if nothing good happened, else add warnings
1186     if null good_names then
1187                 -- No lookup succeeded, so
1188                 -- pick the first error message and report it
1189                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1190                 --       while the other is "X is not in scope",
1191                 --       we definitely want the former; but we might pick the latter
1192         do { addMessages (head errs_s) ; failM }
1193       else                      -- Add deprecation warnings
1194         mapM_ addMessages warns_s ;
1195
1196     return good_names
1197  }
1198
1199 tcRnRecoverDataCon :: HscEnv -> Ptr () -> IO (Maybe DataCon)
1200 tcRnRecoverDataCon hsc_env ptr
1201   = initTcPrintErrors hsc_env iNTERACTIVE $
1202     setInteractiveContext hsc_env (hsc_IC hsc_env) $ do
1203         name <- dataConInfoPtrToName ptr
1204         tcLookupDataCon name
1205
1206 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1207 tcRnLookupName hsc_env name
1208   = initTcPrintErrors hsc_env iNTERACTIVE $
1209     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1210     tcRnLookupName' name
1211
1212 -- To look up a name we have to look in the local environment (tcl_lcl)
1213 -- as well as the global environment, which is what tcLookup does.
1214 -- But we also want a TyThing, so we have to convert:
1215
1216 tcRnLookupName' :: Name -> TcRn TyThing
1217 tcRnLookupName' name = do
1218    tcthing <- tcLookup name
1219    case tcthing of
1220      AGlobal thing    -> return thing
1221      ATcId{tct_id=id} -> return (AnId id)
1222      _ -> panic "tcRnLookupName'"
1223
1224 tcRnGetInfo :: HscEnv
1225             -> Name
1226             -> IO (Maybe (TyThing, Fixity, [Instance]))
1227
1228 -- Used to implemnent :info in GHCi
1229 --
1230 -- Look up a RdrName and return all the TyThings it might be
1231 -- A capitalised RdrName is given to us in the DataName namespace,
1232 -- but we want to treat it as *both* a data constructor
1233 --  *and* as a type or class constructor;
1234 -- hence the call to dataTcOccs, and we return up to two results
1235 tcRnGetInfo hsc_env name
1236   = initTcPrintErrors hsc_env iNTERACTIVE $
1237     let ictxt = hsc_IC hsc_env in
1238     setInteractiveContext hsc_env ictxt $ do
1239
1240         -- Load the interface for all unqualified types and classes
1241         -- That way we will find all the instance declarations
1242         -- (Packages have not orphan modules, and we assume that
1243         --  in the home package all relevant modules are loaded.)
1244     loadUnqualIfaces ictxt
1245
1246     thing <- tcRnLookupName' name
1247     fixity <- lookupFixityRn name
1248     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1249     return (thing, fixity, ispecs)
1250
1251 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1252 -- Filter the instances by the ones whose tycons (or clases resp)
1253 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1254 lookupInsts print_unqual (AClass cls)
1255   = do  { inst_envs <- tcGetInstEnvs
1256         ; return [ ispec
1257                  | ispec <- classInstances inst_envs cls
1258                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1259
1260 lookupInsts print_unqual (ATyCon tc)
1261   = do  { eps <- getEps -- Load all instances for all classes that are
1262                         -- in the type environment (which are all the ones
1263                         -- we've seen in any interface file so far)
1264         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1265         ; return [ ispec
1266                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1267                  , let dfun = instanceDFunId ispec
1268                  , relevant dfun
1269                  , plausibleDFun print_unqual dfun ] }
1270   where
1271     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1272     tc_name     = tyConName tc
1273
1274 lookupInsts print_unqual other = return []
1275
1276 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1277   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1278   where
1279     ok name | isBuiltInSyntax name = True
1280             | isExternalName name  =
1281                 isNothing $ fst print_unqual (nameModule name)
1282                                              (nameOccName name)
1283             | otherwise            = True
1284
1285 loadUnqualIfaces :: InteractiveContext -> TcM ()
1286 -- Load the home module for everything that is in scope unqualified
1287 -- This is so that we can accurately report the instances for
1288 -- something
1289 loadUnqualIfaces ictxt
1290   = initIfaceTcRn $
1291     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1292   where
1293     unqual_mods = [ nameModule name
1294                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1295                     let name = gre_name gre,
1296                     not (isInternalName name),
1297                     isTcOcc (nameOccName name),  -- Types and classes only
1298                     unQualOK gre ]               -- In scope unqualified
1299     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1300 #endif /* GHCI */
1301 \end{code}
1302
1303 %************************************************************************
1304 %*                                                                      *
1305                 Degugging output
1306 %*                                                                      *
1307 %************************************************************************
1308
1309 \begin{code}
1310 rnDump :: SDoc -> TcRn ()
1311 -- Dump, with a banner, if -ddump-rn
1312 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1313
1314 tcDump :: TcGblEnv -> TcRn ()
1315 tcDump env
1316  = do { dflags <- getDOpts ;
1317
1318         -- Dump short output if -ddump-types or -ddump-tc
1319         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1320             (dumpTcRn short_dump) ;
1321
1322         -- Dump bindings if -ddump-tc
1323         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1324    }
1325   where
1326     short_dump = pprTcGblEnv env
1327     full_dump  = pprLHsBinds (tcg_binds env)
1328         -- NB: foreign x-d's have undefined's in their types;
1329         --     hence can't show the tc_fords
1330
1331 tcCoreDump mod_guts
1332  = do { dflags <- getDOpts ;
1333         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1334             (dumpTcRn (pprModGuts mod_guts)) ;
1335
1336         -- Dump bindings if -ddump-tc
1337         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1338   where
1339     full_dump = pprCoreBindings (mg_binds mod_guts)
1340
1341 -- It's unpleasant having both pprModGuts and pprModDetails here
1342 pprTcGblEnv :: TcGblEnv -> SDoc
1343 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1344                         tcg_insts     = insts,
1345                         tcg_fam_insts = fam_insts,
1346                         tcg_rules     = rules,
1347                         tcg_imports   = imports })
1348   = vcat [ ppr_types insts type_env
1349          , ppr_tycons fam_insts type_env
1350          , ppr_insts insts
1351          , ppr_fam_insts fam_insts
1352          , vcat (map ppr rules)
1353          , ppr_gen_tycons (typeEnvTyCons type_env)
1354          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1355          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1356
1357 pprModGuts :: ModGuts -> SDoc
1358 pprModGuts (ModGuts { mg_types = type_env,
1359                       mg_rules = rules })
1360   = vcat [ ppr_types [] type_env,
1361            ppr_rules rules ]
1362
1363 ppr_types :: [Instance] -> TypeEnv -> SDoc
1364 ppr_types insts type_env
1365   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1366   where
1367     dfun_ids = map instanceDFunId insts
1368     ids = [id | id <- typeEnvIds type_env, want_sig id]
1369     want_sig id | opt_PprStyle_Debug = True
1370                 | otherwise          = isLocalId id &&
1371                                        isExternalName (idName id) &&
1372                                        not (id `elem` dfun_ids)
1373         -- isLocalId ignores data constructors, records selectors etc.
1374         -- The isExternalName ignores local dictionary and method bindings
1375         -- that the type checker has invented.  Top-level user-defined things
1376         -- have External names.
1377
1378 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1379 ppr_tycons fam_insts type_env
1380   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1381   where
1382     fi_tycons = map famInstTyCon fam_insts
1383     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1384     want_tycon tycon | opt_PprStyle_Debug = True
1385                      | otherwise          = not (isImplicitTyCon tycon) &&
1386                                             isExternalName (tyConName tycon) &&
1387                                             not (tycon `elem` fi_tycons)
1388
1389 ppr_insts :: [Instance] -> SDoc
1390 ppr_insts []     = empty
1391 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1392
1393 ppr_fam_insts :: [FamInst] -> SDoc
1394 ppr_fam_insts []        = empty
1395 ppr_fam_insts fam_insts =
1396   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1397
1398 ppr_sigs :: [Var] -> SDoc
1399 ppr_sigs ids
1400         -- Print type signatures; sort by OccName
1401   = vcat (map ppr_sig (sortLe le_sig ids))
1402   where
1403     le_sig id1 id2 = getOccName id1 <= getOccName id2
1404     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1405
1406 ppr_tydecls :: [TyCon] -> SDoc
1407 ppr_tydecls tycons
1408         -- Print type constructor info; sort by OccName
1409   = vcat (map ppr_tycon (sortLe le_sig tycons))
1410   where
1411     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1412     ppr_tycon tycon
1413       | isCoercionTyCon tycon = ptext SLIT("coercion") <+> ppr tycon
1414       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1415
1416 ppr_rules :: [CoreRule] -> SDoc
1417 ppr_rules [] = empty
1418 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1419                       nest 4 (pprRules rs),
1420                       ptext SLIT("#-}")]
1421
1422 ppr_gen_tycons []  = empty
1423 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1424                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1425 \end{code}