compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 {-# OPTIONS -w #-}
   9 -- The above warning supression flag is a temporary kludge.
  10 -- While working on this module you are encouraged to remove it and fix
  11 -- any warnings in the module. See
  12 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
  13 -- for details
  14
  15 module TcRnDriver (
  16 #ifdef GHCI
  17         tcRnStmt, tcRnExpr, tcRnType,
  18         tcRnLookupRdrName,
  19         tcRnLookupName,
  20         tcRnGetInfo,
  21         getModuleExports,
  22 #endif
  23         tcRnModule,
  24         tcTopSrcDecls,
  25         tcRnExtCore
  26     ) where
  27
  28 #include "HsVersions.h"
  29
  30 import IO
  31 #ifdef GHCI
  32 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  33 #endif
  34
  35 import DynFlags
  36 import StaticFlags
  37 import HsSyn
  38 import RdrHsSyn
  39
  40 import PrelNames
  41 import RdrName
  42 import TcHsSyn
  43 import TcExpr
  44 import TcRnMonad
  45 import TcType
  46 import Inst
  47 import FamInst
  48 import InstEnv
  49 import FamInstEnv
  50 import TcBinds
  51 import TcDefaults
  52 import TcEnv
  53 import TcRules
  54 import TcForeign
  55 import TcInstDcls
  56 import TcIface
  57 import MkIface
  58 import IfaceSyn
  59 import TcSimplify
  60 import TcTyClsDecls
  61 import LoadIface
  62 import RnNames
  63 import RnEnv
  64 import RnSource
  65 import RnHsDoc
  66 import PprCore
  67 import CoreSyn
  68 import ErrUtils
  69 import Id
  70 import Var
  71 import Module
  72 import UniqFM
  73 import Name
  74 import NameEnv
  75 import NameSet
  76 import TyCon
  77 import SrcLoc
  78 import HscTypes
  79 import ListSetOps
  80 import Outputable
  81
  82 #ifdef GHCI
  83 import Linker
  84 import DataCon
  85 import TcHsType
  86 import TcMType
  87 import TcMatches
  88 import TcGadt
  89 import RnTypes
  90 import RnExpr
  91 import IfaceEnv
  92 import MkId
  93 import TysWiredIn
  94 import IdInfo
  95 import {- Kind parts of -} Type
  96 import BasicTypes
  97 import Foreign.Ptr( Ptr )
  98 #endif
  99
 100 import FastString
 101 import Maybes
 102 import Util
 103 import Bag
 104
 105 import Control.Monad    ( unless )
 106 import Data.Maybe       ( isJust )
 107
 108 \end{code}
 109
 110
 111
 112 %************************************************************************
 113 %*                                                                      *
 114         Typecheck and rename a module
 115 %*                                                                      *
 116 %************************************************************************
 117
 118
 119 \begin{code}
 120 tcRnModule :: HscEnv
 121            -> HscSource
 122            -> Bool              -- True <=> save renamed syntax
 123            -> Located (HsModule RdrName)
 124            -> IO (Messages, Maybe TcGblEnv)
 125
 126 tcRnModule hsc_env hsc_src save_rn_syntax
 127          (L loc (HsModule maybe_mod export_ies
 128                           import_decls local_decls mod_deprec
 129                           module_info maybe_doc))
 130  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 131
 132    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 133          this_mod = case maybe_mod of
 134                         Nothing  -> mAIN        -- 'module M where' is omitted
 135                         Just (L _ mod) -> mkModule this_pkg mod } ;
 136                                                 -- The normal case
 137
 138    initTc hsc_env hsc_src save_rn_syntax this_mod $
 139    setSrcSpan loc $
 140    do {         -- Deal with imports;
 141         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 142         setGblEnv tcg_env               $ do {
 143
 144                 -- Load the hi-boot interface for this module, if any
 145                 -- We do this now so that the boot_names can be passed
 146                 -- to tcTyAndClassDecls, because the boot_names are
 147                 -- automatically considered to be loop breakers
 148                 --
 149                 -- Do this *after* tcRnImports, so that we know whether
 150                 -- a module that we import imports us; and hence whether to
 151                 -- look for a hi-boot file
 152         boot_iface <- tcHiBootIface hsc_src this_mod ;
 153
 154                 -- Rename and type check the declarations
 155         traceRn (text "rn1a") ;
 156         tcg_env <- if isHsBoot hsc_src then
 157                         tcRnHsBootDecls local_decls
 158                    else
 159                         tcRnSrcDecls boot_iface local_decls ;
 160         setGblEnv tcg_env               $ do {
 161
 162                 -- Report the use of any deprecated things
 163                 -- We do this *before* processsing the export list so
 164                 -- that we don't bleat about re-exporting a deprecated
 165                 -- thing (especially via 'module Foo' export item)
 166                 -- That is, only uses in the *body* of the module are complained about
 167         traceRn (text "rn3") ;
 168         failIfErrsM ;   -- finishDeprecations crashes sometimes
 169                         -- as a result of typechecker repairs (e.g. unboundNames)
 170         tcg_env <- finishDeprecations (hsc_dflags hsc_env) mod_deprec tcg_env ;
 171
 172                 -- Process the export list
 173        traceRn (text "rn4a: before exports");
 174         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 175         traceRn (text "rn4b: after exportss") ;
 176
 177         -- Compare the hi-boot iface (if any) with the real thing
 178         -- Must be done after processing the exports
 179         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 180
 181         -- Make the new type env available to stuff slurped from interface files
 182         -- Must do this after checkHiBootIface, because the latter might add new
 183         -- bindings for boot_dfuns, which may be mentioned in imported unfoldings
 184         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 185
 186                 -- Rename the Haddock documentation
 187         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 188
 189                 -- Report unused names
 190         reportUnusedNames export_ies tcg_env ;
 191
 192                 -- Dump output and return
 193         tcDump tcg_env ;
 194         return tcg_env
 195     }}}}
 196 \end{code}
 197
 198
 199 %************************************************************************
 200 %*                                                                      *
 201                 Import declarations
 202 %*                                                                      *
 203 %************************************************************************
 204
 205 \begin{code}
 206 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 207 tcRnImports hsc_env this_mod import_decls
 208   = do  { (rn_imports, rdr_env, imports,hpc_info) <- rnImports import_decls ;
 209
 210         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 211               ; dep_mods = imp_dep_mods imports
 212
 213                 -- We want instance declarations from all home-package
 214                 -- modules below this one, including boot modules, except
 215                 -- ourselves.  The 'except ourselves' is so that we don't
 216                 -- get the instances from this module's hs-boot file
 217               ; want_instances :: ModuleName -> Bool
 218               ; want_instances mod = mod `elemUFM` dep_mods
 219                                    && mod /= moduleName this_mod
 220               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 221                                                             want_instances
 222               } ;
 223
 224                 -- Record boot-file info in the EPS, so that it's
 225                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 226                 -- and any other incrementally-performed imports
 227         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 228
 229                 -- Update the gbl env
 230         ; updGblEnv ( \ gbl ->
 231             gbl {
 232               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 233               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 234               tcg_rn_imports   = fmap (const rn_imports) (tcg_rn_imports gbl),
 235               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 236               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 237                                                       home_fam_insts,
 238               tcg_hpc          = hpc_info
 239             }) $ do {
 240
 241         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 242                 -- Fail if there are any errors so far
 243                 -- The error printing (if needed) takes advantage
 244                 -- of the tcg_env we have now set
 245 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 246         ; failIfErrsM
 247
 248                 -- Load any orphan-module and family instance-module
 249                 -- interfaces, so that their rules and instance decls will be
 250                 -- found.
 251         ; loadOrphanModules (imp_orphs  imports) False
 252         ; loadOrphanModules (imp_finsts imports) True
 253
 254                 -- Check type-familily consistency
 255         ; traceRn (text "rn1: checking family instance consistency")
 256         ; let { dir_imp_mods = map (\ (mod, _) -> mod)
 257                              . moduleEnvElts
 258                              . imp_mods
 259                              $ imports }
 260         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 261
 262         ; getGblEnv } }
 263 \end{code}
 264
 265
 266 %************************************************************************
 267 %*                                                                      *
 268         Type-checking external-core modules
 269 %*                                                                      *
 270 %************************************************************************
 271
 272 \begin{code}
 273 tcRnExtCore :: HscEnv
 274             -> HsExtCore RdrName
 275             -> IO (Messages, Maybe ModGuts)
 276         -- Nothing => some error occurred
 277
 278 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 279         -- The decls are IfaceDecls; all names are original names
 280  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 281
 282    initTc hsc_env ExtCoreFile False this_mod $ do {
 283
 284    let { ldecls  = map noLoc decls } ;
 285
 286        -- bring the type and class decls into scope
 287        -- ToDo: check that this doesn't need to extract the val binds.
 288        --       It seems that only the type and class decls need to be in scope below because
 289        --          (a) tcTyAndClassDecls doesn't need the val binds, and
 290        --          (b) tcExtCoreBindings doesn't need anything
 291        --              (in fact, it might not even need to be in the scope of
 292        --               this tcg_env at all)
 293    tcg_env  <- importsFromLocalDecls False (mkFakeGroup ldecls)
 294                emptyUFM {- no fixity decls -} ;
 295
 296    setGblEnv tcg_env $ do {
 297
 298    rn_decls <- checkNoErrs $ rnTyClDecls ldecls ;
 299
 300         -- Dump trace of renaming part
 301    rnDump (ppr rn_decls) ;
 302
 303         -- Typecheck them all together so that
 304         -- any mutually recursive types are done right
 305    tcg_env <- tcTyAndClassDecls emptyModDetails rn_decls ;
 306         -- Make the new type env available to stuff slurped from interface files
 307
 308    setGblEnv tcg_env $ do {
 309
 310         -- Now the core bindings
 311    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 312
 313         -- Wrap up
 314    let {
 315         bndrs      = bindersOfBinds core_binds ;
 316         my_exports = map (Avail . idName) bndrs ;
 317                 -- ToDo: export the data types also?
 318
 319         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 320
 321         mod_guts = ModGuts {    mg_module    = this_mod,
 322                                 mg_boot      = False,
 323                                 mg_used_names = emptyNameSet, -- ToDo: compute usage
 324                                 mg_dir_imps  = emptyModuleEnv, -- ??
 325                                 mg_deps      = noDependencies,  -- ??
 326                                 mg_exports   = my_exports,
 327                                 mg_types     = final_type_env,
 328                                 mg_insts     = tcg_insts tcg_env,
 329                                 mg_fam_insts = tcg_fam_insts tcg_env,
 330                                 mg_inst_env  = tcg_inst_env tcg_env,
 331                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 332                                 mg_rules     = [],
 333                                 mg_binds     = core_binds,
 334
 335                                 -- Stubs
 336                                 mg_rdr_env   = emptyGlobalRdrEnv,
 337                                 mg_fix_env   = emptyFixityEnv,
 338                                 mg_deprecs   = NoDeprecs,
 339                                 mg_foreign   = NoStubs,
 340                                 mg_hpc_info  = emptyHpcInfo False,
 341                                 mg_modBreaks = emptyModBreaks,
 342                                 mg_vect_info = noVectInfo
 343                     } } ;
 344
 345    tcCoreDump mod_guts ;
 346
 347    return mod_guts
 348    }}}}
 349
 350 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 351   = emptyRdrGroup { hs_tyclds = decls }
 352 \end{code}
 353
 354
 355 %************************************************************************
 356 %*                                                                      *
 357         Type-checking the top level of a module
 358 %*                                                                      *
 359 %************************************************************************
 360
 361 \begin{code}
 362 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 363         -- Returns the variables free in the decls
 364         -- Reason: solely to report unused imports and bindings
 365 tcRnSrcDecls boot_iface decls
 366  = do {         -- Do all the declarations
 367         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 368
 369              --         Finish simplifying class constraints
 370              --
 371              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 372              -- How could there be ambiguous ones?  They can only arise if a
 373              -- top-level decl falls under the monomorphism restriction
 374              -- and no subsequent decl instantiates its type.
 375              --
 376              -- We do this after checkMain, so that we use the type info
 377              -- thaat checkMain adds
 378              --
 379              -- We do it with both global and local env in scope:
 380              --  * the global env exposes the instances to tcSimplifyTop
 381              --  * the local env exposes the local Ids to tcSimplifyTop,
 382              --    so that we get better error messages (monomorphism restriction)
 383         traceTc (text "Tc8") ;
 384         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 385
 386             -- Backsubstitution.  This must be done last.
 387             -- Even tcSimplifyTop may do some unification.
 388         traceTc (text "Tc9") ;
 389         let { (tcg_env, _) = tc_envs
 390             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 391                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 392             ; all_binds = binds `unionBags` inst_binds } ;
 393
 394         failIfErrsM ;   -- Don't zonk if there have been errors
 395                         -- It's a waste of time; and we may get debug warnings
 396                         -- about strangely-typed TyCons!
 397
 398         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 399
 400         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 401             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 402                                    tcg_binds = binds',
 403                                    tcg_rules = rules',
 404                                    tcg_fords = fords' } } ;
 405
 406         return (tcg_env' { tcg_binds = tcg_binds tcg_env' })
 407    }
 408
 409 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 410 -- Loops around dealing with each top level inter-splice group
 411 -- in turn, until it's dealt with the entire module
 412 tc_rn_src_decls boot_details ds
 413  = do { let { (first_group, group_tail) = findSplice ds } ;
 414                 -- If ds is [] we get ([], Nothing)
 415
 416         -- Deal with decls up to, but not including, the first splice
 417         (tcg_env, rn_decls) <- rnTopSrcDecls first_group ;
 418                 -- rnTopSrcDecls fails if there are any errors
 419
 420         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 421                               tcTopSrcDecls boot_details rn_decls ;
 422
 423         -- If there is no splice, we're nearly done
 424         setEnvs (tcg_env, tcl_env) $
 425         case group_tail of {
 426            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 427                            return (tcg_env, tcl_env)
 428                       } ;
 429
 430         -- If there's a splice, we must carry on
 431            Just (SpliceDecl splice_expr, rest_ds) -> do {
 432 #ifndef GHCI
 433         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 434 #else
 435
 436         -- Rename the splice expression, and get its supporting decls
 437         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 438                 -- checkNoErrs: don't typecheck if renaming failed
 439         rnDump (ppr rn_splice_expr) ;
 440
 441         -- Execute the splice
 442         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 443
 444         -- Glue them on the front of the remaining decls and loop
 445         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 446         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 447 #endif /* GHCI */
 448     } } }
 449 \end{code}
 450
 451 %************************************************************************
 452 %*                                                                      *
 453         Compiling hs-boot source files, and
 454         comparing the hi-boot interface with the real thing
 455 %*                                                                      *
 456 %************************************************************************
 457
 458 \begin{code}
 459 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 460 tcRnHsBootDecls decls
 461    = do { let { (first_group, group_tail) = findSplice decls }
 462
 463         ; case group_tail of
 464              Just stuff -> spliceInHsBootErr stuff
 465              Nothing    -> return ()
 466
 467                 -- Rename the declarations
 468         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 469         ; setGblEnv tcg_env $ do {
 470
 471         -- Todo: check no foreign decls, no rules, no default decls
 472
 473                 -- Typecheck type/class decls
 474         ; traceTc (text "Tc2")
 475         ; let tycl_decls = hs_tyclds rn_group
 476         ; tcg_env <- tcTyAndClassDecls emptyModDetails tycl_decls
 477         ; setGblEnv tcg_env     $ do {
 478
 479                 -- Typecheck instance decls
 480         ; traceTc (text "Tc3")
 481         ; (tcg_env, inst_infos, _deriv_binds)
 482             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 483         ; setGblEnv tcg_env     $ do {
 484
 485                 -- Typecheck value declarations
 486         ; traceTc (text "Tc5")
 487         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 488
 489                 -- Wrap up
 490                 -- No simplification or zonking to do
 491         ; traceTc (text "Tc7a")
 492         ; gbl_env <- getGblEnv
 493
 494                 -- Make the final type-env
 495                 -- Include the dfun_ids so that their type sigs
 496                 -- are written into the interface file
 497         ; let { type_env0 = tcg_type_env gbl_env
 498               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 499               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 500               ; dfun_ids = map iDFunId inst_infos }
 501         ; return (gbl_env { tcg_type_env = type_env2 })
 502    }}}}
 503
 504 spliceInHsBootErr (SpliceDecl (L loc _), _)
 505   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 506 \end{code}
 507
 508 Once we've typechecked the body of the module, we want to compare what
 509 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 510
 511 \begin{code}
 512 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 513 -- Compare the hi-boot file for this module (if there is one)
 514 -- with the type environment we've just come up with
 515 -- In the common case where there is no hi-boot file, the list
 516 -- of boot_names is empty.
 517 --
 518 -- The bindings we return give bindings for the dfuns defined in the
 519 -- hs-boot file, such as        $fbEqT = $fEqT
 520
 521 checkHiBootIface
 522         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 523                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 524                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 525         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 526                       md_types = boot_type_env, md_exports = boot_exports })
 527   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 528   = return tcg_env
 529
 530   | otherwise
 531   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 532                                 ppr boot_exports)) ;
 533
 534                 -- Check the exports of the boot module, one by one
 535         ; mapM_ check_export boot_exports
 536
 537                 -- Check instance declarations
 538         ; mb_dfun_prs <- mapM check_inst boot_insts
 539         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
 540                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
 541               dfun_prs   = catMaybes mb_dfun_prs
 542               boot_dfuns = map fst dfun_prs
 543               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 544                                      | (boot_dfun, dfun) <- dfun_prs ]
 545
 546                 -- Check for no family instances
 547         ; unless (null boot_fam_insts) $
 548             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 549                    "instances in boot files yet...")
 550             -- FIXME: Why?  The actual comparison is not hard, but what would
 551             --        be the equivalent to the dfun bindings returned for class
 552             --        instances?  We can't easily equate tycons...
 553
 554         ; return tcg_env' }
 555   where
 556     check_export boot_avail     -- boot_avail is exported by the boot iface
 557       | name `elem` dfun_names = return ()
 558       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 559                                                 -- 'error' is handled by a rather gross hack
 560                                                 -- (see comments in GHC.Err.hs-boot)
 561
 562         -- Check that the actual module exports the same thing
 563       | not (null missing_names)
 564       = addErrTc (missingBootThing (head missing_names) "exported by")
 565
 566         -- If the boot module does not *define* the thing, we are done
 567         -- (it simply re-exports it, and names match, so nothing further to do)
 568       | isNothing mb_boot_thing = return ()
 569
 570         -- Check that the actual module also defines the thing, and
 571         -- then compare the definitions
 572       | Just real_thing <- lookupTypeEnv local_type_env name
 573       = do { let boot_decl = tyThingToIfaceDecl (fromJust mb_boot_thing)
 574                  real_decl = tyThingToIfaceDecl real_thing
 575            ; checkTc (checkBootDecl boot_decl real_decl)
 576                      (bootMisMatch real_thing boot_decl real_decl) }
 577                 -- The easiest way to check compatibility is to convert to
 578                 -- iface syntax, where we already have good comparison functions
 579
 580       | otherwise
 581       = addErrTc (missingBootThing name "defined in")
 582       where
 583         name          = availName boot_avail
 584         mb_boot_thing = lookupTypeEnv boot_type_env name
 585         missing_names = case lookupNameEnv local_export_env name of
 586                           Nothing    -> [name]
 587                           Just avail -> availNames boot_avail `minusList` availNames avail
 588
 589     dfun_names = map getName boot_insts
 590
 591     local_export_env :: NameEnv AvailInfo
 592     local_export_env = availsToNameEnv local_exports
 593
 594     check_inst :: Instance -> TcM (Maybe (Id, Id))
 595         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 596     check_inst boot_inst
 597         = case [dfun | inst <- local_insts,
 598                        let dfun = instanceDFunId inst,
 599                        idType dfun `tcEqType` boot_inst_ty ] of
 600             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 601             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 602         where
 603           boot_dfun = instanceDFunId boot_inst
 604           boot_inst_ty = idType boot_dfun
 605           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 606
 607
 608 ----------------
 609 missingBootThing thing what
 610   = ppr thing <+> ptext SLIT("is exported by the hs-boot file, but not")
 611               <+> text what <+> ptext SLIT("the module")
 612
 613 bootMisMatch thing boot_decl real_decl
 614   = vcat [ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file"),
 615           ptext SLIT("Main module:") <+> ppr real_decl,
 616           ptext SLIT("Boot file:  ") <+> ppr boot_decl]
 617
 618 instMisMatch inst
 619   = hang (ppr inst)
 620        2 (ptext SLIT("is defined in the hs-boot file, but not in the module itself"))
 621 \end{code}
 622
 623
 624 %************************************************************************
 625 %*                                                                      *
 626         Type-checking the top level of a module
 627 %*                                                                      *
 628 %************************************************************************
 629
 630 tcRnGroup takes a bunch of top-level source-code declarations, and
 631  * renames them
 632  * gets supporting declarations from interface files
 633  * typechecks them
 634  * zonks them
 635  * and augments the TcGblEnv with the results
 636
 637 In Template Haskell it may be called repeatedly for each group of
 638 declarations.  It expects there to be an incoming TcGblEnv in the
 639 monad; it augments it and returns the new TcGblEnv.
 640
 641 \begin{code}
 642 ------------------------------------------------
 643 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 644 -- Fails if there are any errors
 645 rnTopSrcDecls group
 646  = do { -- Rename the source decls (with no shadowing; error on duplicates)
 647         (tcg_env, rn_decls) <- checkNoErrs $ rnSrcDecls False group ;
 648
 649         -- save the renamed syntax, if we want it
 650         let { tcg_env'
 651                 | Just grp <- tcg_rn_decls tcg_env
 652                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 653                 | otherwise
 654                    = tcg_env };
 655
 656                 -- Dump trace of renaming part
 657         rnDump (ppr rn_decls) ;
 658
 659         return (tcg_env', rn_decls)
 660    }
 661
 662 ------------------------------------------------
 663 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 664 tcTopSrcDecls boot_details
 665         (HsGroup { hs_tyclds = tycl_decls,
 666                    hs_instds = inst_decls,
 667                    hs_derivds = deriv_decls,
 668                    hs_fords  = foreign_decls,
 669                    hs_defds  = default_decls,
 670                    hs_ruleds = rule_decls,
 671                    hs_valds  = val_binds })
 672  = do {         -- Type-check the type and class decls, and all imported decls
 673                 -- The latter come in via tycl_decls
 674         traceTc (text "Tc2") ;
 675
 676         tcg_env <- tcTyAndClassDecls boot_details tycl_decls ;
 677                 -- If there are any errors, tcTyAndClassDecls fails here
 678
 679         -- Make these type and class decls available to stuff slurped from interface files
 680         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 681
 682
 683         setGblEnv tcg_env       $ do {
 684                 -- Source-language instances, including derivings,
 685                 -- and import the supporting declarations
 686         traceTc (text "Tc3") ;
 687         (tcg_env, inst_infos, deriv_binds)
 688             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 689         setGblEnv tcg_env       $ do {
 690
 691                 -- Foreign import declarations next.  No zonking necessary
 692                 -- here; we can tuck them straight into the global environment.
 693         traceTc (text "Tc4") ;
 694         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 695         tcExtendGlobalValEnv fi_ids     $ do {
 696
 697                 -- Default declarations
 698         traceTc (text "Tc4a") ;
 699         default_tys <- tcDefaults default_decls ;
 700         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 701
 702                 -- Value declarations next
 703                 -- We also typecheck any extra binds that came out
 704                 -- of the "deriving" process (deriv_binds)
 705         traceTc (text "Tc5") ;
 706         (tc_val_binds,   tcl_env) <- tcTopBinds val_binds ;
 707         setLclTypeEnv tcl_env   $ do {
 708
 709                 -- Now GHC-generated derived bindings and generics.
 710                 -- Do not generate warnings from compiler-generated code.
 711         (tc_deriv_binds, tcl_env) <- discardWarnings $
 712                                  tcTopBinds deriv_binds ;
 713
 714                 -- Second pass over class and instance declarations,
 715         traceTc (text "Tc6") ;
 716         (inst_binds, tcl_env)     <- setLclTypeEnv tcl_env $ tcInstDecls2 tycl_decls inst_infos ;
 717         showLIE (text "after instDecls2") ;
 718
 719                 -- Foreign exports
 720                 -- They need to be zonked, so we return them
 721         traceTc (text "Tc7") ;
 722         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 723
 724                 -- Rules
 725         rules <- tcRules rule_decls ;
 726
 727                 -- Wrap up
 728         traceTc (text "Tc7a") ;
 729         tcg_env <- getGblEnv ;
 730         let { all_binds = tc_val_binds   `unionBags`
 731                           tc_deriv_binds `unionBags`
 732                           inst_binds     `unionBags`
 733                           foe_binds  ;
 734
 735                 -- Extend the GblEnv with the (as yet un-zonked)
 736                 -- bindings, rules, foreign decls
 737               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 738                                     tcg_rules = tcg_rules tcg_env ++ rules,
 739                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 740         return (tcg_env', tcl_env)
 741     }}}}}}
 742 \end{code}
 743
 744
 745 %************************************************************************
 746 %*                                                                      *
 747         Checking for 'main'
 748 %*                                                                      *
 749 %************************************************************************
 750
 751 \begin{code}
 752 checkMain :: TcM TcGblEnv
 753 -- If we are in module Main, check that 'main' is defined.
 754 checkMain
 755   = do { tcg_env   <- getGblEnv ;
 756          dflags    <- getDOpts ;
 757          check_main dflags tcg_env
 758     }
 759
 760 check_main dflags tcg_env
 761  | mod /= main_mod
 762  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 763    return tcg_env
 764
 765  | otherwise
 766  = do   { mb_main <- lookupSrcOcc_maybe main_fn
 767                 -- Check that 'main' is in scope
 768                 -- It might be imported from another module!
 769         ; case mb_main of {
 770              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 771                            ; complain_no_main
 772                            ; return tcg_env } ;
 773              Just main_name -> do
 774
 775         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 776         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 777                         -- :Main.main :: IO () = runMainIO main
 778
 779         ; (main_expr, ty) <- addErrCtxt mainCtxt                        $
 780                              setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 781                              tcInferRho rhs
 782
 783                 -- See Note [Root-main Id]
 784         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 785                                    (mkVarOccFS FSLIT("main"))
 786                                    (getSrcSpan main_name)
 787               ; root_main_id = Id.mkExportedLocalId root_main_name ty
 788               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 789
 790         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 791                                         `snocBag` main_bind,
 792                             tcg_dus   = tcg_dus tcg_env
 793                                         `plusDU` usesOnly (unitFV main_name)
 794                         -- Record the use of 'main', so that we don't
 795                         -- complain about it being defined but not used
 796                  })
 797     }}}
 798   where
 799     mod          = tcg_mod tcg_env
 800     main_mod     = mainModIs dflags
 801     main_is_flag = mainFunIs dflags
 802
 803     main_fn  = case main_is_flag of
 804                   Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn))
 805                   Nothing -> main_RDR_Unqual
 806
 807     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 808                      | otherwise = failWithTc noMainMsg
 809         -- In interactive mode, don't worry about the absence of 'main'
 810         -- In other modes, fail altogether, so that we don't go on
 811         -- and complain a second time when processing the export list.
 812
 813     mainCtxt  = ptext SLIT("When checking the type of the") <+> pp_main_fn
 814     noMainMsg = ptext SLIT("The") <+> pp_main_fn
 815                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 816     pp_main_fn | isJust main_is_flag = ptext SLIT("main function") <+> quotes (ppr main_fn)
 817                | otherwise           = ptext SLIT("function") <+> quotes (ppr main_fn)
 818 \end{code}
 819
 820 Note [Root-main Id]
 821 ~~~~~~~~~~~~~~~~~~~
 822 The function that the RTS invokes is always :Main.main, which we call
 823 root_main_id.  (Because GHC allows the user to have a module not
 824 called Main as the main module, we can't rely on the main function
 825 being called "Main.main".  That's why root_main_id has a fixed module
 826 ":Main".)
 827
 828 This is unusual: it's a LocalId whose Name has a Module from another
 829 module.  Tiresomely, we must filter it out again in MkIface, les we
 830 get two defns for 'main' in the interface file!
 831
 832
 833 %*********************************************************
 834 %*                                                       *
 835                 GHCi stuff
 836 %*                                                       *
 837 %*********************************************************
 838
 839 \begin{code}
 840 #ifdef GHCI
 841 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 842 setInteractiveContext hsc_env icxt thing_inside
 843   = let -- Initialise the tcg_inst_env with instances from all home modules.
 844         -- This mimics the more selective call to hptInstances in tcRnModule.
 845         (home_insts, home_fam_insts) = hptInstances hsc_env (\mod -> True)
 846     in
 847     updGblEnv (\env -> env {
 848         tcg_rdr_env      = ic_rn_gbl_env icxt,
 849         tcg_inst_env     = extendInstEnvList    (tcg_inst_env env) home_insts,
 850         tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env env)
 851                                                 home_fam_insts
 852       }) $
 853
 854     tcExtendGhciEnv (ic_tmp_ids icxt) $
 855         -- tcExtendGhciEnv does lots:
 856         --   - it extends the local type env (tcl_env) with the given Ids,
 857         --   - it extends the local rdr env (tcl_rdr) with the Names from
 858         --     the given Ids
 859         --   - it adds the free tyvars of the Ids to the tcl_tyvars
 860         --     set.
 861         --
 862         -- later ids in ic_tmp_ids must shadow earlier ones with the same
 863         -- OccName, and tcExtendIdEnv implements this behaviour.
 864
 865     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
 866         ; thing_inside }
 867 \end{code}
 868
 869
 870 \begin{code}
 871 tcRnStmt :: HscEnv
 872          -> InteractiveContext
 873          -> LStmt RdrName
 874          -> IO (Maybe ([Id], LHsExpr Id))
 875                 -- The returned [Id] is the list of new Ids bound by
 876                 -- this statement.  It can be used to extend the
 877                 -- InteractiveContext via extendInteractiveContext.
 878                 --
 879                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 880                 -- a list of the bound values, coerced to ().
 881
 882 tcRnStmt hsc_env ictxt rdr_stmt
 883   = initTcPrintErrors hsc_env iNTERACTIVE $
 884     setInteractiveContext hsc_env ictxt $ do {
 885
 886     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 887     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 888     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 889     failIfErrsM ;
 890     rnDump (ppr rn_stmt) ;
 891
 892     -- The real work is done here
 893     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 894     zonked_expr <- zonkTopLExpr tc_expr ;
 895     zonked_ids  <- zonkTopBndrs bound_ids ;
 896
 897         -- None of the Ids should be of unboxed type, because we
 898         -- cast them all to HValues in the end!
 899     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 900
 901     traceTc (text "tcs 1") ;
 902     let { global_ids = map globaliseAndTidy zonked_ids } ;
 903
 904 {- ---------------------------------------------
 905    At one stage I removed any shadowed bindings from the type_env;
 906    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
 907    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
 908    GHCi session
 909          Prelude> let f n = n * 2 :: Int
 910          Prelude> fName <- runQ [| f |]
 911          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 912          14
 913          Prelude> let f n = n * 3 :: Int
 914          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 915    In the last line we use 'fName', which resolves to the *first* 'f'
 916    in scope. If we delete it from the type env, GHCi crashes because
 917    it doesn't expect that.
 918
 919    Hence this code is commented out
 920
 921 -------------------------------------------------- -}
 922
 923     dumpOptTcRn Opt_D_dump_tc
 924         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 925                text "Typechecked expr" <+> ppr zonked_expr]) ;
 926
 927     returnM (global_ids, zonked_expr)
 928     }
 929   where
 930     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 931                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 932
 933 globaliseAndTidy :: Id -> Id
 934 globaliseAndTidy id     -- Note [Interactively-bound Ids in GHCi]
 935   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
 936   where
 937     tidy_type = tidyTopType (idType id)
 938 \end{code}
 939
 940 Note [Interactively-bound Ids in GHCi]
 941 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 942 The Ids bound by previous Stmts in Template Haskell are currently
 943         a) GlobalIds
 944         b) with an Internal Name (not External)
 945         c) and a tidied type
 946
 947  (a) They must be GlobalIds (not LocalIds) otherwise when we come to
 948      compile an expression using these ids later, the byte code
 949      generator will consider the occurrences to be free rather than
 950      global.
 951
 952  (b) They retain their Internal names becuase we don't have a suitable
 953      Module to name them with.  We could revisit this choice.
 954
 955  (c) Their types are tidied.  This is important, because :info may ask
 956      to look at them, and :info expects the things it looks up to have
 957      tidy types
 958
 959
 960 --------------------------------------------------------------------------
 961                 Typechecking Stmts in GHCi
 962
 963 Here is the grand plan, implemented in tcUserStmt
 964
 965         What you type                   The IO [HValue] that hscStmt returns
 966         -------------                   ------------------------------------
 967         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 968                                         bindings: [x,y,...]
 969
 970         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 971                                         bindings: [x,y,...]
 972
 973         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 974           [NB: result not printed]      bindings: [it]
 975
 976         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 977           result showable)              bindings: [it]
 978
 979         expr (of non-IO type,
 980           result not showable)  ==>     error
 981
 982
 983 \begin{code}
 984 ---------------------------
 985 type PlanResult = ([Id], LHsExpr Id)
 986 type Plan = TcM PlanResult
 987
 988 runPlans :: [Plan] -> TcM PlanResult
 989 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 990 -- If one succeeds, take it.
 991 runPlans []     = panic "runPlans"
 992 runPlans [p]    = p
 993 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 994
 995 --------------------
 996 mkPlan :: LStmt Name -> TcM PlanResult
 997 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 998   = do  { uniq <- newUnique             -- is treated very specially
 999         ; let fresh_it  = itName uniq
1000               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
1001               matches   = [mkMatch [] expr emptyLocalBinds]
1002               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
1003               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
1004                                            (HsVar bindIOName) noSyntaxExpr
1005               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
1006                                            (HsVar thenIOName) placeHolderType
1007
1008         -- The plans are:
1009         --      [it <- e; print it]     but not if it::()
1010         --      [it <- e]
1011         --      [let it = e; print it]
1012         ; runPlans [    -- Plan A
1013                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
1014                        ; it_ty <- zonkTcType (idType it_id)
1015                        ; ifM (isUnitTy it_ty) failM
1016                        ; return stuff },
1017
1018                         -- Plan B; a naked bind statment
1019                     tcGhciStmts [bind_stmt],
1020
1021                         -- Plan C; check that the let-binding is typeable all by itself.
1022                         -- If not, fail; if so, try to print it.
1023                         -- The two-step process avoids getting two errors: one from
1024                         -- the expression itself, and one from the 'print it' part
1025                         -- This two-step story is very clunky, alas
1026                     do { checkNoErrs (tcGhciStmts [let_stmt])
1027                                 --- checkNoErrs defeats the error recovery of let-bindings
1028                        ; tcGhciStmts [let_stmt, print_it] }
1029           ]}
1030
1031 mkPlan stmt@(L loc (BindStmt {}))
1032   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1033   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1034                                            (HsVar thenIOName) placeHolderType
1035
1036         ; print_bind_result <- doptM Opt_PrintBindResult
1037         ; let print_plan = do
1038                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1039                   ; v_ty <- zonkTcType (idType v_id)
1040                   ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1041                   ; return stuff }
1042
1043         -- The plans are:
1044         --      [stmt; print v]         but not if v::()
1045         --      [stmt]
1046         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1047                     [tcGhciStmts [stmt]])
1048         }
1049
1050 mkPlan stmt
1051   = tcGhciStmts [stmt]
1052
1053 ---------------------------
1054 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1055 tcGhciStmts stmts
1056  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1057         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1058         let {
1059             io_ty     = mkTyConApp ioTyCon [] ;
1060             ret_ty    = mkListTy unitTy ;
1061             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1062             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
1063                                         (emptyRefinement, io_ret_ty) ;
1064
1065             names = map unLoc (collectLStmtsBinders stmts) ;
1066
1067                 -- mk_return builds the expression
1068                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1069                 --
1070                 -- Despite the inconvenience of building the type applications etc,
1071                 -- this *has* to be done in type-annotated post-typecheck form
1072                 -- because we are going to return a list of *polymorphic* values
1073                 -- coerced to type (). If we built a *source* stmt
1074                 --      return [coerce x, ..., coerce z]
1075                 -- then the type checker would instantiate x..z, and we wouldn't
1076                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1077                 -- if they were overloaded, since they aren't applied to anything.)
1078             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1079                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1080             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1081                                  (nlHsVar id)
1082          } ;
1083
1084         -- OK, we're ready to typecheck the stmts
1085         traceTc (text "TcRnDriver.tcGhciStmts: tc stmts") ;
1086         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1087                                            mappM tcLookupId names ;
1088                                         -- Look up the names right in the middle,
1089                                         -- where they will all be in scope
1090
1091         -- Simplify the context
1092         traceTc (text "TcRnDriver.tcGhciStmts: simplify ctxt") ;
1093         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1094                 -- checkNoErrs ensures that the plan fails if context redn fails
1095
1096         traceTc (text "TcRnDriver.tcGhciStmts: done") ;
1097         return (ids, mkHsDictLet const_binds $
1098                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1099     }
1100 \end{code}
1101
1102
1103 tcRnExpr just finds the type of an expression
1104
1105 \begin{code}
1106 tcRnExpr :: HscEnv
1107          -> InteractiveContext
1108          -> LHsExpr RdrName
1109          -> IO (Maybe Type)
1110 tcRnExpr hsc_env ictxt rdr_expr
1111   = initTcPrintErrors hsc_env iNTERACTIVE $
1112     setInteractiveContext hsc_env ictxt $ do {
1113
1114     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1115     failIfErrsM ;
1116
1117         -- Now typecheck the expression;
1118         -- it might have a rank-2 type (e.g. :t runST)
1119     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1120     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1121     tcSimplifyInteractive lie_top ;
1122
1123     let { all_expr_ty = mkForAllTys qtvs $
1124                         mkFunTys (map (idType . instToId) dict_insts)   $
1125                         res_ty } ;
1126     zonkTcType all_expr_ty
1127     }
1128   where
1129     smpl_doc = ptext SLIT("main expression")
1130 \end{code}
1131
1132 tcRnType just finds the kind of a type
1133
1134 \begin{code}
1135 tcRnType :: HscEnv
1136          -> InteractiveContext
1137          -> LHsType RdrName
1138          -> IO (Maybe Kind)
1139 tcRnType hsc_env ictxt rdr_type
1140   = initTcPrintErrors hsc_env iNTERACTIVE $
1141     setInteractiveContext hsc_env ictxt $ do {
1142
1143     rn_type <- rnLHsType doc rdr_type ;
1144     failIfErrsM ;
1145
1146         -- Now kind-check the type
1147     (ty', kind) <- kcHsType rn_type ;
1148     return kind
1149     }
1150   where
1151     doc = ptext SLIT("In GHCi input")
1152
1153 #endif /* GHCi */
1154 \end{code}
1155
1156
1157 %************************************************************************
1158 %*                                                                      *
1159         More GHCi stuff, to do with browsing and getting info
1160 %*                                                                      *
1161 %************************************************************************
1162
1163 \begin{code}
1164 #ifdef GHCI
1165 -- ASSUMES that the module is either in the HomePackageTable or is
1166 -- a package module with an interface on disk.  If neither of these is
1167 -- true, then the result will be an error indicating the interface
1168 -- could not be found.
1169 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1170 getModuleExports hsc_env mod
1171   = let
1172       ic        = hsc_IC hsc_env
1173       checkMods = ic_toplev_scope ic ++ ic_exports ic
1174     in
1175     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1176
1177 -- Get the export avail info and also load all orphan and family-instance
1178 -- modules.  Finally, check that the family instances of all modules in the
1179 -- interactive context are consistent (these modules are in the second
1180 -- argument).
1181 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1182 tcGetModuleExports mod directlyImpMods
1183   = do { let doc = ptext SLIT("context for compiling statements")
1184        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1185
1186                 -- Load any orphan-module and family instance-module
1187                 -- interfaces, so their instances are visible.
1188        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1189        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1190
1191                 -- Check that the family instances of all directly loaded
1192                 -- modules are consistent.
1193        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1194
1195        ; ifaceExportNames (mi_exports iface)
1196        }
1197
1198 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1199 tcRnLookupRdrName hsc_env rdr_name
1200   = initTcPrintErrors hsc_env iNTERACTIVE $
1201     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1202     lookup_rdr_name rdr_name
1203
1204 lookup_rdr_name rdr_name = do {
1205         -- If the identifier is a constructor (begins with an
1206         -- upper-case letter), then we need to consider both
1207         -- constructor and type class identifiers.
1208     let { rdr_names = dataTcOccs rdr_name } ;
1209
1210         -- results :: [Either Messages Name]
1211     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1212
1213     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1214         -- The successful lookups will be (Just name)
1215     let { (warns_s, good_names) = unzip [ (msgs, name)
1216                                         | (msgs, Just name) <- results] ;
1217           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1218
1219         -- Fail if nothing good happened, else add warnings
1220     if null good_names then
1221                 -- No lookup succeeded, so
1222                 -- pick the first error message and report it
1223                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1224                 --       while the other is "X is not in scope",
1225                 --       we definitely want the former; but we might pick the latter
1226         do { addMessages (head errs_s) ; failM }
1227       else                      -- Add deprecation warnings
1228         mapM_ addMessages warns_s ;
1229
1230     return good_names
1231  }
1232
1233 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1234 tcRnLookupName hsc_env name
1235   = initTcPrintErrors hsc_env iNTERACTIVE $
1236     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1237     tcRnLookupName' name
1238
1239 -- To look up a name we have to look in the local environment (tcl_lcl)
1240 -- as well as the global environment, which is what tcLookup does.
1241 -- But we also want a TyThing, so we have to convert:
1242
1243 tcRnLookupName' :: Name -> TcRn TyThing
1244 tcRnLookupName' name = do
1245    tcthing <- tcLookup name
1246    case tcthing of
1247      AGlobal thing    -> return thing
1248      ATcId{tct_id=id} -> return (AnId id)
1249      _ -> panic "tcRnLookupName'"
1250
1251 tcRnGetInfo :: HscEnv
1252             -> Name
1253             -> IO (Maybe (TyThing, Fixity, [Instance]))
1254
1255 -- Used to implemnent :info in GHCi
1256 --
1257 -- Look up a RdrName and return all the TyThings it might be
1258 -- A capitalised RdrName is given to us in the DataName namespace,
1259 -- but we want to treat it as *both* a data constructor
1260 --  *and* as a type or class constructor;
1261 -- hence the call to dataTcOccs, and we return up to two results
1262 tcRnGetInfo hsc_env name
1263   = initTcPrintErrors hsc_env iNTERACTIVE $
1264     let ictxt = hsc_IC hsc_env in
1265     setInteractiveContext hsc_env ictxt $ do
1266
1267         -- Load the interface for all unqualified types and classes
1268         -- That way we will find all the instance declarations
1269         -- (Packages have not orphan modules, and we assume that
1270         --  in the home package all relevant modules are loaded.)
1271     loadUnqualIfaces ictxt
1272
1273     thing  <- tcRnLookupName' name
1274     fixity <- lookupFixityRn name
1275     ispecs <- lookupInsts thing
1276     return (thing, fixity, ispecs)
1277
1278 lookupInsts :: TyThing -> TcM [Instance]
1279 lookupInsts (AClass cls)
1280   = do  { inst_envs <- tcGetInstEnvs
1281         ; return (classInstances inst_envs cls) }
1282
1283 lookupInsts (ATyCon tc)
1284   = do  { eps <- getEps -- Load all instances for all classes that are
1285                         -- in the type environment (which are all the ones
1286                         -- we've seen in any interface file so far)
1287         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1288         ; return [ ispec
1289                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1290                  , let dfun = instanceDFunId ispec
1291                  , relevant dfun ] }
1292   where
1293     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1294     tc_name     = tyConName tc
1295
1296 lookupInsts other = return []
1297
1298 loadUnqualIfaces :: InteractiveContext -> TcM ()
1299 -- Load the home module for everything that is in scope unqualified
1300 -- This is so that we can accurately report the instances for
1301 -- something
1302 loadUnqualIfaces ictxt
1303   = initIfaceTcRn $
1304     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1305   where
1306     unqual_mods = [ nameModule name
1307                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1308                     let name = gre_name gre,
1309                     not (isInternalName name),
1310                     isTcOcc (nameOccName name),  -- Types and classes only
1311                     unQualOK gre ]               -- In scope unqualified
1312     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1313 #endif /* GHCI */
1314 \end{code}
1315
1316 %************************************************************************
1317 %*                                                                      *
1318                 Degugging output
1319 %*                                                                      *
1320 %************************************************************************
1321
1322 \begin{code}
1323 rnDump :: SDoc -> TcRn ()
1324 -- Dump, with a banner, if -ddump-rn
1325 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1326
1327 tcDump :: TcGblEnv -> TcRn ()
1328 tcDump env
1329  = do { dflags <- getDOpts ;
1330
1331         -- Dump short output if -ddump-types or -ddump-tc
1332         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1333             (dumpTcRn short_dump) ;
1334
1335         -- Dump bindings if -ddump-tc
1336         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1337    }
1338   where
1339     short_dump = pprTcGblEnv env
1340     full_dump  = pprLHsBinds (tcg_binds env)
1341         -- NB: foreign x-d's have undefined's in their types;
1342         --     hence can't show the tc_fords
1343
1344 tcCoreDump mod_guts
1345  = do { dflags <- getDOpts ;
1346         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1347             (dumpTcRn (pprModGuts mod_guts)) ;
1348
1349         -- Dump bindings if -ddump-tc
1350         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1351   where
1352     full_dump = pprCoreBindings (mg_binds mod_guts)
1353
1354 -- It's unpleasant having both pprModGuts and pprModDetails here
1355 pprTcGblEnv :: TcGblEnv -> SDoc
1356 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1357                         tcg_insts     = insts,
1358                         tcg_fam_insts = fam_insts,
1359                         tcg_rules     = rules,
1360                         tcg_imports   = imports })
1361   = vcat [ ppr_types insts type_env
1362          , ppr_tycons fam_insts type_env
1363          , ppr_insts insts
1364          , ppr_fam_insts fam_insts
1365          , vcat (map ppr rules)
1366          , ppr_gen_tycons (typeEnvTyCons type_env)
1367          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1368          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1369
1370 pprModGuts :: ModGuts -> SDoc
1371 pprModGuts (ModGuts { mg_types = type_env,
1372                       mg_rules = rules })
1373   = vcat [ ppr_types [] type_env,
1374            ppr_rules rules ]
1375
1376 ppr_types :: [Instance] -> TypeEnv -> SDoc
1377 ppr_types insts type_env
1378   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1379   where
1380     dfun_ids = map instanceDFunId insts
1381     ids = [id | id <- typeEnvIds type_env, want_sig id]
1382     want_sig id | opt_PprStyle_Debug = True
1383                 | otherwise          = isLocalId id &&
1384                                        isExternalName (idName id) &&
1385                                        not (id `elem` dfun_ids)
1386         -- isLocalId ignores data constructors, records selectors etc.
1387         -- The isExternalName ignores local dictionary and method bindings
1388         -- that the type checker has invented.  Top-level user-defined things
1389         -- have External names.
1390
1391 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1392 ppr_tycons fam_insts type_env
1393   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1394   where
1395     fi_tycons = map famInstTyCon fam_insts
1396     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1397     want_tycon tycon | opt_PprStyle_Debug = True
1398                      | otherwise          = not (isImplicitTyCon tycon) &&
1399                                             isExternalName (tyConName tycon) &&
1400                                             not (tycon `elem` fi_tycons)
1401
1402 ppr_insts :: [Instance] -> SDoc
1403 ppr_insts []     = empty
1404 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1405
1406 ppr_fam_insts :: [FamInst] -> SDoc
1407 ppr_fam_insts []        = empty
1408 ppr_fam_insts fam_insts =
1409   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1410
1411 ppr_sigs :: [Var] -> SDoc
1412 ppr_sigs ids
1413         -- Print type signatures; sort by OccName
1414   = vcat (map ppr_sig (sortLe le_sig ids))
1415   where
1416     le_sig id1 id2 = getOccName id1 <= getOccName id2
1417     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1418
1419 ppr_tydecls :: [TyCon] -> SDoc
1420 ppr_tydecls tycons
1421         -- Print type constructor info; sort by OccName
1422   = vcat (map ppr_tycon (sortLe le_sig tycons))
1423   where
1424     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1425     ppr_tycon tycon
1426       | isCoercionTyCon tycon = ptext SLIT("coercion") <+> ppr tycon
1427       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1428
1429 ppr_rules :: [CoreRule] -> SDoc
1430 ppr_rules [] = empty
1431 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1432                       nest 4 (pprRules rs),
1433                       ptext SLIT("#-}")]
1434
1435 ppr_gen_tycons []  = empty
1436 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1437                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1438 \end{code}