compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         tcRnLookupName,
  13         tcRnGetInfo,
  14         getModuleExports,
  15         tcRnRecoverDataCon,
  16 #endif
  17         tcRnModule,
  18         tcTopSrcDecls,
  19         tcRnExtCore
  20     ) where
  21
  22 #include "HsVersions.h"
  23
  24 import IO
  25 #ifdef GHCI
  26 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  27 #endif
  28
  29 import DynFlags
  30 import StaticFlags
  31 import HsSyn
  32 import RdrHsSyn
  33
  34 import PrelNames
  35 import RdrName
  36 import TcHsSyn
  37 import TcExpr
  38 import TcRnMonad
  39 import TcType
  40 import Inst
  41 import FamInst
  42 import InstEnv
  43 import FamInstEnv
  44 import TcBinds
  45 import TcDefaults
  46 import TcEnv
  47 import TcRules
  48 import TcForeign
  49 import TcInstDcls
  50 import TcIface
  51 import MkIface
  52 import IfaceSyn
  53 import TcSimplify
  54 import TcTyClsDecls
  55 import LoadIface
  56 import RnNames
  57 import RnEnv
  58 import RnSource
  59 import RnHsDoc
  60 import PprCore
  61 import CoreSyn
  62 import ErrUtils
  63 import Id
  64 import Var
  65 import Module
  66 import UniqFM
  67 import Name
  68 import NameEnv
  69 import NameSet
  70 import TyCon
  71 import SrcLoc
  72 import HscTypes
  73 import ListSetOps
  74 import Outputable
  75
  76 #ifdef GHCI
  77 import Linker
  78 import DataCon
  79 import TcHsType
  80 import TcMType
  81 import TcMatches
  82 import TcGadt
  83 import RnTypes
  84 import RnExpr
  85 import IfaceEnv
  86 import MkId
  87 import TysWiredIn
  88 import IdInfo
  89 import {- Kind parts of -} Type
  90 import BasicTypes
  91 #endif
  92
  93 import FastString
  94 import Maybes
  95 import Util
  96 import Bag
  97
  98 import Control.Monad    ( unless )
  99 import Data.Maybe       ( isJust )
 100 import Foreign.Ptr      ( Ptr )
 101
 102 \end{code}
 103
 104
 105
 106 %************************************************************************
 107 %*                                                                      *
 108         Typecheck and rename a module
 109 %*                                                                      *
 110 %************************************************************************
 111
 112
 113 \begin{code}
 114 tcRnModule :: HscEnv
 115            -> HscSource
 116            -> Bool              -- True <=> save renamed syntax
 117            -> Located (HsModule RdrName)
 118            -> IO (Messages, Maybe TcGblEnv)
 119
 120 tcRnModule hsc_env hsc_src save_rn_syntax
 121          (L loc (HsModule maybe_mod export_ies
 122                           import_decls local_decls mod_deprec _
 123                           module_info maybe_doc))
 124  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 125
 126    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 127          this_mod = case maybe_mod of
 128                         Nothing  -> mAIN        -- 'module M where' is omitted
 129                         Just (L _ mod) -> mkModule this_pkg mod } ;
 130                                                 -- The normal case
 131
 132    initTc hsc_env hsc_src save_rn_syntax this_mod $
 133    setSrcSpan loc $
 134    do {         -- Deal with imports;
 135         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 136         setGblEnv tcg_env               $ do {
 137
 138                 -- Load the hi-boot interface for this module, if any
 139                 -- We do this now so that the boot_names can be passed
 140                 -- to tcTyAndClassDecls, because the boot_names are
 141                 -- automatically considered to be loop breakers
 142                 --
 143                 -- Do this *after* tcRnImports, so that we know whether
 144                 -- a module that we import imports us; and hence whether to
 145                 -- look for a hi-boot file
 146         boot_iface <- tcHiBootIface hsc_src this_mod ;
 147
 148                 -- Rename and type check the declarations
 149         traceRn (text "rn1a") ;
 150         tcg_env <- if isHsBoot hsc_src then
 151                         tcRnHsBootDecls local_decls
 152                    else
 153                         tcRnSrcDecls boot_iface local_decls ;
 154         setGblEnv tcg_env               $ do {
 155
 156                 -- Report the use of any deprecated things
 157                 -- We do this *before* processsing the export list so
 158                 -- that we don't bleat about re-exporting a deprecated
 159                 -- thing (especially via 'module Foo' export item)
 160                 -- That is, only uses in the *body* of the module are complained about
 161         traceRn (text "rn3") ;
 162         failIfErrsM ;   -- finishDeprecations crashes sometimes
 163                         -- as a result of typechecker repairs (e.g. unboundNames)
 164         tcg_env <- finishDeprecations (hsc_dflags hsc_env) mod_deprec tcg_env ;
 165
 166                 -- Process the export list
 167         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 168         traceRn (text "rn4") ;
 169
 170         -- Compare the hi-boot iface (if any) with the real thing
 171         -- Must be done after processing the exports
 172         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 173
 174         -- Make the new type env available to stuff slurped from interface files
 175         -- Must do this after checkHiBootIface, because the latter might add new
 176         -- bindings for boot_dfuns, which may be mentioned in imported unfoldings
 177         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 178
 179                 -- Rename the Haddock documentation
 180         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 181
 182                 -- Report unused names
 183         reportUnusedNames export_ies tcg_env ;
 184
 185                 -- Dump output and return
 186         tcDump tcg_env ;
 187         return tcg_env
 188     }}}}
 189 \end{code}
 190
 191
 192 %************************************************************************
 193 %*                                                                      *
 194                 Import declarations
 195 %*                                                                      *
 196 %************************************************************************
 197
 198 \begin{code}
 199 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 200 tcRnImports hsc_env this_mod import_decls
 201   = do  { (rn_imports, rdr_env, imports) <- rnImports import_decls ;
 202
 203         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 204               ; dep_mods = imp_dep_mods imports
 205
 206                 -- We want instance declarations from all home-package
 207                 -- modules below this one, including boot modules, except
 208                 -- ourselves.  The 'except ourselves' is so that we don't
 209                 -- get the instances from this module's hs-boot file
 210               ; want_instances :: ModuleName -> Bool
 211               ; want_instances mod = mod `elemUFM` dep_mods
 212                                    && mod /= moduleName this_mod
 213               ; (home_insts, home_fam_insts) = hptInstances hsc_env
 214                                                             want_instances
 215               } ;
 216
 217                 -- Record boot-file info in the EPS, so that it's
 218                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 219                 -- and any other incrementally-performed imports
 220         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 221
 222                 -- Update the gbl env
 223         ; updGblEnv ( \ gbl ->
 224             gbl {
 225               tcg_rdr_env      = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 226               tcg_imports      = tcg_imports gbl `plusImportAvails` imports,
 227               tcg_rn_imports   = fmap (const rn_imports) (tcg_rn_imports gbl),
 228               tcg_inst_env     = extendInstEnvList (tcg_inst_env gbl) home_insts,
 229               tcg_fam_inst_env = extendFamInstEnvList (tcg_fam_inst_env gbl)
 230                                                       home_fam_insts
 231             }) $ do {
 232
 233         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 234                 -- Fail if there are any errors so far
 235                 -- The error printing (if needed) takes advantage
 236                 -- of the tcg_env we have now set
 237 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 238         ; failIfErrsM
 239
 240                 -- Load any orphan-module and family instance-module
 241                 -- interfaces, so that their rules and instance decls will be
 242                 -- found.
 243         ; loadOrphanModules (imp_orphs  imports) False
 244         ; loadOrphanModules (imp_finsts imports) True
 245
 246                 -- Check type-familily consistency
 247         ; traceRn (text "rn1: checking family instance consistency")
 248         ; let { dir_imp_mods = map (\ (mod, _, _) -> mod)
 249                              . moduleEnvElts
 250                              . imp_mods
 251                              $ imports }
 252         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 253
 254         ; getGblEnv } }
 255 \end{code}
 256
 257
 258 %************************************************************************
 259 %*                                                                      *
 260         Type-checking external-core modules
 261 %*                                                                      *
 262 %************************************************************************
 263
 264 \begin{code}
 265 tcRnExtCore :: HscEnv
 266             -> HsExtCore RdrName
 267             -> IO (Messages, Maybe ModGuts)
 268         -- Nothing => some error occurred
 269
 270 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 271         -- The decls are IfaceDecls; all names are original names
 272  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 273
 274    initTc hsc_env ExtCoreFile False this_mod $ do {
 275
 276    let { ldecls  = map noLoc decls } ;
 277
 278         -- Deal with the type declarations; first bring their stuff
 279         -- into scope, then rname them, then type check them
 280    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 281
 282    setGblEnv tcg_env $ do {
 283
 284    rn_decls <- rnTyClDecls ldecls ;
 285    failIfErrsM ;
 286
 287         -- Dump trace of renaming part
 288    rnDump (ppr rn_decls) ;
 289
 290         -- Typecheck them all together so that
 291         -- any mutually recursive types are done right
 292    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 293         -- Make the new type env available to stuff slurped from interface files
 294
 295    setGblEnv tcg_env $ do {
 296
 297         -- Now the core bindings
 298    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 299
 300         -- Wrap up
 301    let {
 302         bndrs      = bindersOfBinds core_binds ;
 303         my_exports = map (Avail . idName) bndrs ;
 304                 -- ToDo: export the data types also?
 305
 306         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 307
 308         mod_guts = ModGuts {    mg_module    = this_mod,
 309                                 mg_boot      = False,
 310                                 mg_usages    = [],              -- ToDo: compute usage
 311                                 mg_dir_imps  = [],              -- ??
 312                                 mg_deps      = noDependencies,  -- ??
 313                                 mg_exports   = my_exports,
 314                                 mg_types     = final_type_env,
 315                                 mg_insts     = tcg_insts tcg_env,
 316                                 mg_fam_insts = tcg_fam_insts tcg_env,
 317                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 318                                 mg_rules     = [],
 319                                 mg_binds     = core_binds,
 320
 321                                 -- Stubs
 322                                 mg_rdr_env   = emptyGlobalRdrEnv,
 323                                 mg_fix_env   = emptyFixityEnv,
 324                                 mg_deprecs   = NoDeprecs,
 325                                 mg_foreign   = NoStubs,
 326                                 mg_hpc_info  = noHpcInfo,
 327                                 mg_modBreaks = emptyModBreaks,
 328                                 mg_vect_info = noVectInfo
 329                     } } ;
 330
 331    tcCoreDump mod_guts ;
 332
 333    return mod_guts
 334    }}}}
 335
 336 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 337   = emptyRdrGroup { hs_tyclds = decls }
 338 \end{code}
 339
 340
 341 %************************************************************************
 342 %*                                                                      *
 343         Type-checking the top level of a module
 344 %*                                                                      *
 345 %************************************************************************
 346
 347 \begin{code}
 348 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 349         -- Returns the variables free in the decls
 350         -- Reason: solely to report unused imports and bindings
 351 tcRnSrcDecls boot_iface decls
 352  = do {         -- Do all the declarations
 353         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 354
 355              --         Finish simplifying class constraints
 356              --
 357              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 358              -- How could there be ambiguous ones?  They can only arise if a
 359              -- top-level decl falls under the monomorphism restriction
 360              -- and no subsequent decl instantiates its type.
 361              --
 362              -- We do this after checkMain, so that we use the type info
 363              -- thaat checkMain adds
 364              --
 365              -- We do it with both global and local env in scope:
 366              --  * the global env exposes the instances to tcSimplifyTop
 367              --  * the local env exposes the local Ids to tcSimplifyTop,
 368              --    so that we get better error messages (monomorphism restriction)
 369         traceTc (text "Tc8") ;
 370         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 371
 372             -- Backsubstitution.  This must be done last.
 373             -- Even tcSimplifyTop may do some unification.
 374         traceTc (text "Tc9") ;
 375         let { (tcg_env, _) = tc_envs
 376             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 377                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 378             ; all_binds = binds `unionBags` inst_binds } ;
 379
 380         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 381
 382         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 383             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 384                                    tcg_binds = binds',
 385                                    tcg_rules = rules',
 386                                    tcg_fords = fords' } } ;
 387
 388         return (tcg_env' { tcg_binds = tcg_binds tcg_env' })
 389    }
 390
 391 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 392 -- Loops around dealing with each top level inter-splice group
 393 -- in turn, until it's dealt with the entire module
 394 tc_rn_src_decls boot_details ds
 395  = do { let { (first_group, group_tail) = findSplice ds } ;
 396                 -- If ds is [] we get ([], Nothing)
 397
 398         -- Deal with decls up to, but not including, the first splice
 399         (tcg_env, rn_decls) <- checkNoErrs $ rnTopSrcDecls first_group ;
 400                 -- checkNoErrs: stop if renaming fails
 401
 402         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 403                               tcTopSrcDecls boot_details rn_decls ;
 404
 405         -- If there is no splice, we're nearly done
 406         setEnvs (tcg_env, tcl_env) $
 407         case group_tail of {
 408            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 409                            return (tcg_env, tcl_env)
 410                       } ;
 411
 412         -- If there's a splice, we must carry on
 413            Just (SpliceDecl splice_expr, rest_ds) -> do {
 414 #ifndef GHCI
 415         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 416 #else
 417
 418         -- Rename the splice expression, and get its supporting decls
 419         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 420                 -- checkNoErrs: don't typecheck if renaming failed
 421         rnDump (ppr rn_splice_expr) ;
 422
 423         -- Execute the splice
 424         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 425
 426         -- Glue them on the front of the remaining decls and loop
 427         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 428         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 429 #endif /* GHCI */
 430     } } }
 431 \end{code}
 432
 433 %************************************************************************
 434 %*                                                                      *
 435         Compiling hs-boot source files, and
 436         comparing the hi-boot interface with the real thing
 437 %*                                                                      *
 438 %************************************************************************
 439
 440 \begin{code}
 441 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 442 tcRnHsBootDecls decls
 443    = do { let { (first_group, group_tail) = findSplice decls }
 444
 445         ; case group_tail of
 446              Just stuff -> spliceInHsBootErr stuff
 447              Nothing    -> return ()
 448
 449                 -- Rename the declarations
 450         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 451         ; setGblEnv tcg_env $ do {
 452
 453         -- Todo: check no foreign decls, no rules, no default decls
 454
 455                 -- Typecheck type/class decls
 456         ; traceTc (text "Tc2")
 457         ; let tycl_decls = hs_tyclds rn_group
 458         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 459         ; setGblEnv tcg_env     $ do {
 460
 461                 -- Typecheck instance decls
 462         ; traceTc (text "Tc3")
 463         ; (tcg_env, inst_infos, _deriv_binds)
 464             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 465         ; setGblEnv tcg_env     $ do {
 466
 467                 -- Typecheck value declarations
 468         ; traceTc (text "Tc5")
 469         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 470
 471                 -- Wrap up
 472                 -- No simplification or zonking to do
 473         ; traceTc (text "Tc7a")
 474         ; gbl_env <- getGblEnv
 475
 476                 -- Make the final type-env
 477                 -- Include the dfun_ids so that their type sigs
 478                 -- are written into the interface file
 479         ; let { type_env0 = tcg_type_env gbl_env
 480               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 481               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 482               ; dfun_ids = map iDFunId inst_infos }
 483         ; return (gbl_env { tcg_type_env = type_env2 })
 484    }}}}
 485
 486 spliceInHsBootErr (SpliceDecl (L loc _), _)
 487   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 488 \end{code}
 489
 490 Once we've typechecked the body of the module, we want to compare what
 491 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 492
 493 \begin{code}
 494 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 495 -- Compare the hi-boot file for this module (if there is one)
 496 -- with the type environment we've just come up with
 497 -- In the common case where there is no hi-boot file, the list
 498 -- of boot_names is empty.
 499 --
 500 -- The bindings we return give bindings for the dfuns defined in the
 501 -- hs-boot file, such as        $fbEqT = $fEqT
 502
 503 checkHiBootIface
 504         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 505                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 506                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 507         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 508                       md_types = boot_type_env, md_exports = boot_exports })
 509   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 510   = return tcg_env
 511
 512   | otherwise
 513   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 514                                 ppr boot_exports)) ;
 515
 516                 -- Check the exports of the boot module, one by one
 517         ; mapM_ check_export boot_exports
 518
 519                 -- Check instance declarations
 520         ; mb_dfun_prs <- mapM check_inst boot_insts
 521         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
 522                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
 523               dfun_prs   = catMaybes mb_dfun_prs
 524               boot_dfuns = map fst dfun_prs
 525               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 526                                      | (boot_dfun, dfun) <- dfun_prs ]
 527
 528                 -- Check for no family instances
 529         ; unless (null boot_fam_insts) $
 530             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 531                    "instances in boot files yet...")
 532             -- FIXME: Why?  The actual comparison is not hard, but what would
 533             --        be the equivalent to the dfun bindings returned for class
 534             --        instances?  We can't easily equate tycons...
 535
 536         ; return tcg_env' }
 537   where
 538     check_export boot_avail     -- boot_avail is exported by the boot iface
 539       | name `elem` dfun_names = return ()
 540       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 541                                                 -- 'error' is handled by a rather gross hack
 542                                                 -- (see comments in GHC.Err.hs-boot)
 543
 544         -- Check that the actual module exports the same thing
 545       | not (null missing_names)
 546       = addErrTc (missingBootThing (head missing_names) "exported by")
 547
 548         -- If the boot module does not *define* the thing, we are done
 549         -- (it simply re-exports it, and names match, so nothing further to do)
 550       | isNothing mb_boot_thing = return ()
 551
 552         -- Check that the actual module also defines the thing, and
 553         -- then compare the definitions
 554       | Just real_thing <- lookupTypeEnv local_type_env name
 555       = do { let boot_decl = tyThingToIfaceDecl (fromJust mb_boot_thing)
 556                  real_decl = tyThingToIfaceDecl real_thing
 557            ; checkTc (checkBootDecl boot_decl real_decl)
 558                      (bootMisMatch real_thing boot_decl real_decl) }
 559                 -- The easiest way to check compatibility is to convert to
 560                 -- iface syntax, where we already have good comparison functions
 561
 562       | otherwise
 563       = addErrTc (missingBootThing name "defined in")
 564       where
 565         name          = availName boot_avail
 566         mb_boot_thing = lookupTypeEnv boot_type_env name
 567         missing_names = case lookupNameEnv local_export_env name of
 568                           Nothing    -> [name]
 569                           Just avail -> availNames boot_avail `minusList` availNames avail
 570
 571     dfun_names = map getName boot_insts
 572
 573     local_export_env :: NameEnv AvailInfo
 574     local_export_env = availsToNameEnv local_exports
 575
 576     check_inst :: Instance -> TcM (Maybe (Id, Id))
 577         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 578     check_inst boot_inst
 579         = case [dfun | inst <- local_insts,
 580                        let dfun = instanceDFunId inst,
 581                        idType dfun `tcEqType` boot_inst_ty ] of
 582             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 583             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 584         where
 585           boot_dfun = instanceDFunId boot_inst
 586           boot_inst_ty = idType boot_dfun
 587           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 588
 589
 590 ----------------
 591 missingBootThing thing what
 592   = ppr thing <+> ptext SLIT("is exported by the hs-boot file, but not")
 593               <+> text what <+> ptext SLIT("the module")
 594
 595 bootMisMatch thing boot_decl real_decl
 596   = vcat [ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file"),
 597           ptext SLIT("Main module:") <+> ppr real_decl,
 598           ptext SLIT("Boot file:  ") <+> ppr boot_decl]
 599
 600 instMisMatch inst
 601   = hang (ppr inst)
 602        2 (ptext SLIT("is defined in the hs-boot file, but not in the module itself"))
 603 \end{code}
 604
 605
 606 %************************************************************************
 607 %*                                                                      *
 608         Type-checking the top level of a module
 609 %*                                                                      *
 610 %************************************************************************
 611
 612 tcRnGroup takes a bunch of top-level source-code declarations, and
 613  * renames them
 614  * gets supporting declarations from interface files
 615  * typechecks them
 616  * zonks them
 617  * and augments the TcGblEnv with the results
 618
 619 In Template Haskell it may be called repeatedly for each group of
 620 declarations.  It expects there to be an incoming TcGblEnv in the
 621 monad; it augments it and returns the new TcGblEnv.
 622
 623 \begin{code}
 624 ------------------------------------------------
 625 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 626 rnTopSrcDecls group
 627  = do {         -- Bring top level binders into scope
 628         tcg_env <- importsFromLocalDecls group ;
 629         setGblEnv tcg_env $ do {
 630
 631         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 632
 633                 -- Rename the source decls
 634         (tcg_env, rn_decls) <- rnSrcDecls group ;
 635         failIfErrsM ;
 636
 637                 -- save the renamed syntax, if we want it
 638         let { tcg_env'
 639                 | Just grp <- tcg_rn_decls tcg_env
 640                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 641                 | otherwise
 642                    = tcg_env };
 643
 644                 -- Dump trace of renaming part
 645         rnDump (ppr rn_decls) ;
 646
 647         return (tcg_env', rn_decls)
 648    }}
 649
 650 ------------------------------------------------
 651 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 652 tcTopSrcDecls boot_details
 653         (HsGroup { hs_tyclds = tycl_decls,
 654                    hs_instds = inst_decls,
 655                    hs_derivds = deriv_decls,
 656                    hs_fords  = foreign_decls,
 657                    hs_defds  = default_decls,
 658                    hs_ruleds = rule_decls,
 659                    hs_valds  = val_binds })
 660  = do {         -- Type-check the type and class decls, and all imported decls
 661                 -- The latter come in via tycl_decls
 662         traceTc (text "Tc2") ;
 663
 664         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 665         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 666         -- an error we'd better stop now, to avoid a cascade
 667
 668         -- Make these type and class decls available to stuff slurped from interface files
 669         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 670
 671
 672         setGblEnv tcg_env       $ do {
 673                 -- Source-language instances, including derivings,
 674                 -- and import the supporting declarations
 675         traceTc (text "Tc3") ;
 676         (tcg_env, inst_infos, deriv_binds)
 677             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 678         setGblEnv tcg_env       $ do {
 679
 680                 -- Foreign import declarations next.  No zonking necessary
 681                 -- here; we can tuck them straight into the global environment.
 682         traceTc (text "Tc4") ;
 683         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 684         tcExtendGlobalValEnv fi_ids     $ do {
 685
 686                 -- Default declarations
 687         traceTc (text "Tc4a") ;
 688         default_tys <- tcDefaults default_decls ;
 689         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 690
 691                 -- Value declarations next
 692                 -- We also typecheck any extra binds that came out
 693                 -- of the "deriving" process (deriv_binds)
 694         traceTc (text "Tc5") ;
 695         (tc_val_binds,   tcl_env) <- tcTopBinds val_binds ;
 696         setLclTypeEnv tcl_env   $ do {
 697
 698                 -- Now GHC-generated derived bindings and generics
 699                 -- Do not generate warnings from compiler-generated code
 700         (tc_deriv_binds, tcl_env) <- discardWarnings $ setOptM Opt_GlasgowExts $
 701                                      tcTopBinds deriv_binds ;
 702
 703                 -- Second pass over class and instance declarations,
 704         traceTc (text "Tc6") ;
 705         (inst_binds, tcl_env)     <- setLclTypeEnv tcl_env $ tcInstDecls2 tycl_decls inst_infos ;
 706         showLIE (text "after instDecls2") ;
 707
 708                 -- Foreign exports
 709                 -- They need to be zonked, so we return them
 710         traceTc (text "Tc7") ;
 711         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 712
 713                 -- Rules
 714         rules <- tcRules rule_decls ;
 715
 716                 -- Wrap up
 717         traceTc (text "Tc7a") ;
 718         tcg_env <- getGblEnv ;
 719         let { all_binds = tc_val_binds   `unionBags`
 720                           tc_deriv_binds `unionBags`
 721                           inst_binds     `unionBags`
 722                           foe_binds  ;
 723
 724                 -- Extend the GblEnv with the (as yet un-zonked)
 725                 -- bindings, rules, foreign decls
 726               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 727                                     tcg_rules = tcg_rules tcg_env ++ rules,
 728                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 729         return (tcg_env', tcl_env)
 730     }}}}}}
 731 \end{code}
 732
 733
 734 %************************************************************************
 735 %*                                                                      *
 736         Checking for 'main'
 737 %*                                                                      *
 738 %************************************************************************
 739
 740 \begin{code}
 741 checkMain :: TcM TcGblEnv
 742 -- If we are in module Main, check that 'main' is defined.
 743 checkMain
 744   = do { tcg_env   <- getGblEnv ;
 745          dflags    <- getDOpts ;
 746          let { main_mod = mainModIs dflags ;
 747                main_fn  = case mainFunIs dflags of {
 748                                 Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn)) ;
 749                                 Nothing -> main_RDR_Unqual } } ;
 750
 751          check_main dflags tcg_env main_mod main_fn
 752     }
 753
 754
 755 check_main dflags tcg_env main_mod main_fn
 756  | mod /= main_mod
 757  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 758    return tcg_env
 759
 760  | otherwise
 761  = addErrCtxt mainCtxt                  $
 762    do   { mb_main <- lookupSrcOcc_maybe main_fn
 763                 -- Check that 'main' is in scope
 764                 -- It might be imported from another module!
 765         ; case mb_main of {
 766              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 767                            ; complain_no_main
 768                            ; return tcg_env } ;
 769              Just main_name -> do
 770         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 771         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 772                         -- :Main.main :: IO () = runMainIO main
 773
 774         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 775                              tcInferRho rhs
 776
 777                 -- See Note [Root-main Id]
 778         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 779                                    (mkVarOccFS FSLIT("main"))
 780                                    (getSrcLoc main_name)
 781               ; root_main_id = Id.mkExportedLocalId root_main_name ty
 782               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 783
 784         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 785                                         `snocBag` main_bind,
 786                             tcg_dus   = tcg_dus tcg_env
 787                                         `plusDU` usesOnly (unitFV main_name)
 788                         -- Record the use of 'main', so that we don't
 789                         -- complain about it being defined but not used
 790                  })
 791     }}}
 792   where
 793     mod = tcg_mod tcg_env
 794
 795     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 796                      | otherwise = failWithTc noMainMsg
 797         -- In interactive mode, don't worry about the absence of 'main'
 798         -- In other modes, fail altogether, so that we don't go on
 799         -- and complain a second time when processing the export list.
 800
 801     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 802     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 803                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 804 \end{code}
 805
 806 Note [Root-main Id]
 807 ~~~~~~~~~~~~~~~~~~~
 808 The function that the RTS invokes is always :Main.main, which we call
 809 root_main_id.  (Because GHC allows the user to have a module not
 810 called Main as the main module, we can't rely on the main function
 811 being called "Main.main".  That's why root_main_id has a fixed module
 812 ":Main".)
 813
 814 This is unusual: it's a LocalId whose Name has a Module from another
 815 module.  Tiresomely, we must filter it out again in MkIface, les we
 816 get two defns for 'main' in the interface file!
 817
 818
 819 %*********************************************************
 820 %*                                                       *
 821                 GHCi stuff
 822 %*                                                       *
 823 %*********************************************************
 824
 825 \begin{code}
 826 #ifdef GHCI
 827 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 828 setInteractiveContext hsc_env icxt thing_inside
 829   = let
 830         -- Initialise the tcg_inst_env with instances
 831         -- from all home modules.  This mimics the more selective
 832         -- call to hptInstances in tcRnModule
 833         dfuns = fst (hptInstances hsc_env (\mod -> True))
 834     in
 835     updGblEnv (\env -> env {
 836         tcg_rdr_env  = ic_rn_gbl_env icxt,
 837         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 838
 839
 840     tcExtendIdEnv (ic_tmp_ids icxt) $
 841         -- tcExtendIdEnv does lots:
 842         --   - it extends the local type env (tcl_env) with the given Ids,
 843         --   - it extends the local rdr env (tcl_rdr) with the Names from
 844         --     the given Ids
 845         --   - it adds the free tyvars of the Ids to the tcl_tyvars
 846         --     set.
 847         --
 848         -- later ids in ic_tmp_ids must shadow earlier ones with the same
 849         -- OccName, and tcExtendIdEnv implements this behaviour.
 850
 851     do  { traceTc (text "setIC" <+> ppr (ic_tmp_ids icxt))
 852         ; thing_inside }
 853 \end{code}
 854
 855
 856 \begin{code}
 857 tcRnStmt :: HscEnv
 858          -> InteractiveContext
 859          -> LStmt RdrName
 860          -> IO (Maybe ([Id], LHsExpr Id))
 861                 -- The returned [Id] is the list of new Ids bound by
 862                 -- this statement.  It can be used to extend the
 863                 -- InteractiveContext via extendInteractiveContext.
 864                 --
 865                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 866                 -- a list of the bound values, coerced to ().
 867
 868 tcRnStmt hsc_env ictxt rdr_stmt
 869   = initTcPrintErrors hsc_env iNTERACTIVE $
 870     setInteractiveContext hsc_env ictxt $ do {
 871
 872     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 873     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 874     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 875     failIfErrsM ;
 876
 877     -- The real work is done here
 878     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 879     zonked_expr <- zonkTopLExpr tc_expr ;
 880     zonked_ids  <- zonkTopBndrs bound_ids ;
 881
 882         -- None of the Ids should be of unboxed type, because we
 883         -- cast them all to HValues in the end!
 884     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 885
 886     traceTc (text "tcs 1") ;
 887     let {       -- (a) Make all the bound ids "global" ids, now that
 888                 --     they're notionally top-level bindings.  This is
 889                 --     important: otherwise when we come to compile an expression
 890                 --     using these ids later, the byte code generator will consider
 891                 --     the occurrences to be free rather than global.
 892                 --
 893                 -- (b) Tidy their types; this is important, because :info may
 894                 --     ask to look at them, and :info expects the things it looks
 895                 --     up to have tidy types
 896         global_ids = map globaliseAndTidy zonked_ids ;
 897
 898 {- ---------------------------------------------
 899    At one stage I removed any shadowed bindings from the type_env;
 900    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
 901    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
 902    GHCi session
 903          Prelude> let f n = n * 2 :: Int
 904          Prelude> fName <- runQ [| f |]
 905          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 906          14
 907          Prelude> let f n = n * 3 :: Int
 908          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 909    In the last line we use 'fName', which resolves to the *first* 'f'
 910    in scope. If we delete it from the type env, GHCi crashes because
 911    it doesn't expect that.
 912
 913    Hence this code is commented out
 914
 915 -------------------------------------------------- -}
 916     } ;
 917
 918     dumpOptTcRn Opt_D_dump_tc
 919         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 920                text "Typechecked expr" <+> ppr zonked_expr]) ;
 921
 922     returnM (global_ids, zonked_expr)
 923     }
 924   where
 925     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 926                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 927
 928 globaliseAndTidy :: Id -> Id
 929 globaliseAndTidy id
 930 -- Give the Id a Global Name, and tidy its type
 931   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
 932   where
 933     tidy_type = tidyTopType (idType id)
 934 \end{code}
 935
 936 Here is the grand plan, implemented in tcUserStmt
 937
 938         What you type                   The IO [HValue] that hscStmt returns
 939         -------------                   ------------------------------------
 940         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 941                                         bindings: [x,y,...]
 942
 943         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 944                                         bindings: [x,y,...]
 945
 946         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 947           [NB: result not printed]      bindings: [it]
 948
 949         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 950           result showable)              bindings: [it]
 951
 952         expr (of non-IO type,
 953           result not showable)  ==>     error
 954
 955
 956 \begin{code}
 957 ---------------------------
 958 type PlanResult = ([Id], LHsExpr Id)
 959 type Plan = TcM PlanResult
 960
 961 runPlans :: [Plan] -> TcM PlanResult
 962 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 963 -- If one succeeds, take it.
 964 runPlans []     = panic "runPlans"
 965 runPlans [p]    = p
 966 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 967
 968 --------------------
 969 mkPlan :: LStmt Name -> TcM PlanResult
 970 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 971   = do  { uniq <- newUnique             -- is treated very specially
 972         ; let fresh_it  = itName uniq
 973               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 974               matches   = [mkMatch [] expr emptyLocalBinds]
 975               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 976               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 977                                            (HsVar bindIOName) noSyntaxExpr
 978               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 979                                            (HsVar thenIOName) placeHolderType
 980
 981         -- The plans are:
 982         --      [it <- e; print it]     but not if it::()
 983         --      [it <- e]
 984         --      [let it = e; print it]
 985         ; runPlans [    -- Plan A
 986                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 987                        ; it_ty <- zonkTcType (idType it_id)
 988                        ; ifM (isUnitTy it_ty) failM
 989                        ; return stuff },
 990
 991                         -- Plan B; a naked bind statment
 992                     tcGhciStmts [bind_stmt],
 993
 994                         -- Plan C; check that the let-binding is typeable all by itself.
 995                         -- If not, fail; if so, try to print it.
 996                         -- The two-step process avoids getting two errors: one from
 997                         -- the expression itself, and one from the 'print it' part
 998                         -- This two-step story is very clunky, alas
 999                     do { checkNoErrs (tcGhciStmts [let_stmt])
1000                                 --- checkNoErrs defeats the error recovery of let-bindings
1001                        ; tcGhciStmts [let_stmt, print_it] }
1002           ]}
1003
1004 mkPlan stmt@(L loc (BindStmt {}))
1005   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1006   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1007                                            (HsVar thenIOName) placeHolderType
1008
1009         ; print_bind_result <- doptM Opt_PrintBindResult
1010         ; let print_plan = do
1011                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1012                   ; v_ty <- zonkTcType (idType v_id)
1013                   ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1014                   ; return stuff }
1015
1016         -- The plans are:
1017         --      [stmt; print v]         but not if v::()
1018         --      [stmt]
1019         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1020                     [tcGhciStmts [stmt]])
1021         }
1022
1023 mkPlan stmt
1024   = tcGhciStmts [stmt]
1025
1026 ---------------------------
1027 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1028 tcGhciStmts stmts
1029  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1030         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1031         let {
1032             io_ty     = mkTyConApp ioTyCon [] ;
1033             ret_ty    = mkListTy unitTy ;
1034             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1035             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
1036                                         (emptyRefinement, io_ret_ty) ;
1037
1038             names = map unLoc (collectLStmtsBinders stmts) ;
1039
1040                 -- mk_return builds the expression
1041                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1042                 --
1043                 -- Despite the inconvenience of building the type applications etc,
1044                 -- this *has* to be done in type-annotated post-typecheck form
1045                 -- because we are going to return a list of *polymorphic* values
1046                 -- coerced to type (). If we built a *source* stmt
1047                 --      return [coerce x, ..., coerce z]
1048                 -- then the type checker would instantiate x..z, and we wouldn't
1049                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1050                 -- if they were overloaded, since they aren't applied to anything.)
1051             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1052                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1053             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1054                                  (nlHsVar id)
1055          } ;
1056
1057         -- OK, we're ready to typecheck the stmts
1058         traceTc (text "tcs 2") ;
1059         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1060                                            mappM tcLookupId names ;
1061                                         -- Look up the names right in the middle,
1062                                         -- where they will all be in scope
1063
1064         -- Simplify the context
1065         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1066                 -- checkNoErrs ensures that the plan fails if context redn fails
1067
1068         return (ids, mkHsDictLet const_binds $
1069                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1070     }
1071 \end{code}
1072
1073
1074 tcRnExpr just finds the type of an expression
1075
1076 \begin{code}
1077 tcRnExpr :: HscEnv
1078          -> InteractiveContext
1079          -> LHsExpr RdrName
1080          -> IO (Maybe Type)
1081 tcRnExpr hsc_env ictxt rdr_expr
1082   = initTcPrintErrors hsc_env iNTERACTIVE $
1083     setInteractiveContext hsc_env ictxt $ do {
1084
1085     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1086     failIfErrsM ;
1087
1088         -- Now typecheck the expression;
1089         -- it might have a rank-2 type (e.g. :t runST)
1090     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1091     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1092     tcSimplifyInteractive lie_top ;
1093
1094     let { all_expr_ty = mkForAllTys qtvs $
1095                         mkFunTys (map (idType . instToId) dict_insts)   $
1096                         res_ty } ;
1097     zonkTcType all_expr_ty
1098     }
1099   where
1100     smpl_doc = ptext SLIT("main expression")
1101 \end{code}
1102
1103 tcRnType just finds the kind of a type
1104
1105 \begin{code}
1106 tcRnType :: HscEnv
1107          -> InteractiveContext
1108          -> LHsType RdrName
1109          -> IO (Maybe Kind)
1110 tcRnType hsc_env ictxt rdr_type
1111   = initTcPrintErrors hsc_env iNTERACTIVE $
1112     setInteractiveContext hsc_env ictxt $ do {
1113
1114     rn_type <- rnLHsType doc rdr_type ;
1115     failIfErrsM ;
1116
1117         -- Now kind-check the type
1118     (ty', kind) <- kcHsType rn_type ;
1119     return kind
1120     }
1121   where
1122     doc = ptext SLIT("In GHCi input")
1123
1124 #endif /* GHCi */
1125 \end{code}
1126
1127
1128 %************************************************************************
1129 %*                                                                      *
1130         More GHCi stuff, to do with browsing and getting info
1131 %*                                                                      *
1132 %************************************************************************
1133
1134 \begin{code}
1135 #ifdef GHCI
1136 -- ASSUMES that the module is either in the HomePackageTable or is
1137 -- a package module with an interface on disk.  If neither of these is
1138 -- true, then the result will be an error indicating the interface
1139 -- could not be found.
1140 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1141 getModuleExports hsc_env mod
1142   = let
1143       ic        = hsc_IC hsc_env
1144       checkMods = ic_toplev_scope ic ++ ic_exports ic
1145     in
1146     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1147
1148 -- Get the export avail info and also load all orphan and family-instance
1149 -- modules.  Finally, check that the family instances of all modules in the
1150 -- interactive context are consistent (these modules are in the second
1151 -- argument).
1152 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1153 tcGetModuleExports mod directlyImpMods
1154   = do { let doc = ptext SLIT("context for compiling statements")
1155        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1156
1157                 -- Load any orphan-module and family instance-module
1158                 -- interfaces, so their instances are visible.
1159        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1160        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1161
1162                 -- Check that the family instances of all directly loaded
1163                 -- modules are consistent.
1164        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1165
1166        ; ifaceExportNames (mi_exports iface)
1167        }
1168
1169 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1170 tcRnLookupRdrName hsc_env rdr_name
1171   = initTcPrintErrors hsc_env iNTERACTIVE $
1172     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1173     lookup_rdr_name rdr_name
1174
1175 lookup_rdr_name rdr_name = do {
1176         -- If the identifier is a constructor (begins with an
1177         -- upper-case letter), then we need to consider both
1178         -- constructor and type class identifiers.
1179     let { rdr_names = dataTcOccs rdr_name } ;
1180
1181         -- results :: [Either Messages Name]
1182     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1183
1184     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1185         -- The successful lookups will be (Just name)
1186     let { (warns_s, good_names) = unzip [ (msgs, name)
1187                                         | (msgs, Just name) <- results] ;
1188           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1189
1190         -- Fail if nothing good happened, else add warnings
1191     if null good_names then
1192                 -- No lookup succeeded, so
1193                 -- pick the first error message and report it
1194                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1195                 --       while the other is "X is not in scope",
1196                 --       we definitely want the former; but we might pick the latter
1197         do { addMessages (head errs_s) ; failM }
1198       else                      -- Add deprecation warnings
1199         mapM_ addMessages warns_s ;
1200
1201     return good_names
1202  }
1203
1204 tcRnRecoverDataCon :: HscEnv -> Ptr () -> IO (Maybe DataCon)
1205 tcRnRecoverDataCon hsc_env ptr
1206   = initTcPrintErrors hsc_env iNTERACTIVE $
1207     setInteractiveContext hsc_env (hsc_IC hsc_env) $ do
1208         name <- dataConInfoPtrToName ptr
1209         tcLookupDataCon name
1210
1211 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1212 tcRnLookupName hsc_env name
1213   = initTcPrintErrors hsc_env iNTERACTIVE $
1214     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1215     tcRnLookupName' name
1216
1217 -- To look up a name we have to look in the local environment (tcl_lcl)
1218 -- as well as the global environment, which is what tcLookup does.
1219 -- But we also want a TyThing, so we have to convert:
1220
1221 tcRnLookupName' :: Name -> TcRn TyThing
1222 tcRnLookupName' name = do
1223    tcthing <- tcLookup name
1224    case tcthing of
1225      AGlobal thing    -> return thing
1226      ATcId{tct_id=id} -> return (AnId id)
1227      _ -> panic "tcRnLookupName'"
1228
1229 tcRnGetInfo :: HscEnv
1230             -> Name
1231             -> IO (Maybe (TyThing, Fixity, [Instance]))
1232
1233 -- Used to implemnent :info in GHCi
1234 --
1235 -- Look up a RdrName and return all the TyThings it might be
1236 -- A capitalised RdrName is given to us in the DataName namespace,
1237 -- but we want to treat it as *both* a data constructor
1238 --  *and* as a type or class constructor;
1239 -- hence the call to dataTcOccs, and we return up to two results
1240 tcRnGetInfo hsc_env name
1241   = initTcPrintErrors hsc_env iNTERACTIVE $
1242     let ictxt = hsc_IC hsc_env in
1243     setInteractiveContext hsc_env ictxt $ do
1244
1245         -- Load the interface for all unqualified types and classes
1246         -- That way we will find all the instance declarations
1247         -- (Packages have not orphan modules, and we assume that
1248         --  in the home package all relevant modules are loaded.)
1249     loadUnqualIfaces ictxt
1250
1251     thing <- tcRnLookupName' name
1252     fixity <- lookupFixityRn name
1253     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1254     return (thing, fixity, ispecs)
1255
1256 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1257 -- Filter the instances by the ones whose tycons (or clases resp)
1258 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1259 lookupInsts print_unqual (AClass cls)
1260   = do  { inst_envs <- tcGetInstEnvs
1261         ; return [ ispec
1262                  | ispec <- classInstances inst_envs cls
1263                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1264
1265 lookupInsts print_unqual (ATyCon tc)
1266   = do  { eps <- getEps -- Load all instances for all classes that are
1267                         -- in the type environment (which are all the ones
1268                         -- we've seen in any interface file so far)
1269         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1270         ; return [ ispec
1271                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1272                  , let dfun = instanceDFunId ispec
1273                  , relevant dfun
1274                  , plausibleDFun print_unqual dfun ] }
1275   where
1276     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1277     tc_name     = tyConName tc
1278
1279 lookupInsts print_unqual other = return []
1280
1281 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1282   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1283   where
1284     ok name | isBuiltInSyntax name = True
1285             | isExternalName name  =
1286                 isNothing $ fst print_unqual (nameModule name)
1287                                              (nameOccName name)
1288             | otherwise            = True
1289
1290 loadUnqualIfaces :: InteractiveContext -> TcM ()
1291 -- Load the home module for everything that is in scope unqualified
1292 -- This is so that we can accurately report the instances for
1293 -- something
1294 loadUnqualIfaces ictxt
1295   = initIfaceTcRn $
1296     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1297   where
1298     unqual_mods = [ nameModule name
1299                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1300                     let name = gre_name gre,
1301                     not (isInternalName name),
1302                     isTcOcc (nameOccName name),  -- Types and classes only
1303                     unQualOK gre ]               -- In scope unqualified
1304     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1305 #endif /* GHCI */
1306 \end{code}
1307
1308 %************************************************************************
1309 %*                                                                      *
1310                 Degugging output
1311 %*                                                                      *
1312 %************************************************************************
1313
1314 \begin{code}
1315 rnDump :: SDoc -> TcRn ()
1316 -- Dump, with a banner, if -ddump-rn
1317 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1318
1319 tcDump :: TcGblEnv -> TcRn ()
1320 tcDump env
1321  = do { dflags <- getDOpts ;
1322
1323         -- Dump short output if -ddump-types or -ddump-tc
1324         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1325             (dumpTcRn short_dump) ;
1326
1327         -- Dump bindings if -ddump-tc
1328         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1329    }
1330   where
1331     short_dump = pprTcGblEnv env
1332     full_dump  = pprLHsBinds (tcg_binds env)
1333         -- NB: foreign x-d's have undefined's in their types;
1334         --     hence can't show the tc_fords
1335
1336 tcCoreDump mod_guts
1337  = do { dflags <- getDOpts ;
1338         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1339             (dumpTcRn (pprModGuts mod_guts)) ;
1340
1341         -- Dump bindings if -ddump-tc
1342         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1343   where
1344     full_dump = pprCoreBindings (mg_binds mod_guts)
1345
1346 -- It's unpleasant having both pprModGuts and pprModDetails here
1347 pprTcGblEnv :: TcGblEnv -> SDoc
1348 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1349                         tcg_insts     = insts,
1350                         tcg_fam_insts = fam_insts,
1351                         tcg_rules     = rules,
1352                         tcg_imports   = imports })
1353   = vcat [ ppr_types insts type_env
1354          , ppr_tycons fam_insts type_env
1355          , ppr_insts insts
1356          , ppr_fam_insts fam_insts
1357          , vcat (map ppr rules)
1358          , ppr_gen_tycons (typeEnvTyCons type_env)
1359          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1360          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1361
1362 pprModGuts :: ModGuts -> SDoc
1363 pprModGuts (ModGuts { mg_types = type_env,
1364                       mg_rules = rules })
1365   = vcat [ ppr_types [] type_env,
1366            ppr_rules rules ]
1367
1368 ppr_types :: [Instance] -> TypeEnv -> SDoc
1369 ppr_types insts type_env
1370   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1371   where
1372     dfun_ids = map instanceDFunId insts
1373     ids = [id | id <- typeEnvIds type_env, want_sig id]
1374     want_sig id | opt_PprStyle_Debug = True
1375                 | otherwise          = isLocalId id &&
1376                                        isExternalName (idName id) &&
1377                                        not (id `elem` dfun_ids)
1378         -- isLocalId ignores data constructors, records selectors etc.
1379         -- The isExternalName ignores local dictionary and method bindings
1380         -- that the type checker has invented.  Top-level user-defined things
1381         -- have External names.
1382
1383 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1384 ppr_tycons fam_insts type_env
1385   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1386   where
1387     fi_tycons = map famInstTyCon fam_insts
1388     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1389     want_tycon tycon | opt_PprStyle_Debug = True
1390                      | otherwise          = not (isImplicitTyCon tycon) &&
1391                                             isExternalName (tyConName tycon) &&
1392                                             not (tycon `elem` fi_tycons)
1393
1394 ppr_insts :: [Instance] -> SDoc
1395 ppr_insts []     = empty
1396 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1397
1398 ppr_fam_insts :: [FamInst] -> SDoc
1399 ppr_fam_insts []        = empty
1400 ppr_fam_insts fam_insts =
1401   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1402
1403 ppr_sigs :: [Var] -> SDoc
1404 ppr_sigs ids
1405         -- Print type signatures; sort by OccName
1406   = vcat (map ppr_sig (sortLe le_sig ids))
1407   where
1408     le_sig id1 id2 = getOccName id1 <= getOccName id2
1409     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1410
1411 ppr_tydecls :: [TyCon] -> SDoc
1412 ppr_tydecls tycons
1413         -- Print type constructor info; sort by OccName
1414   = vcat (map ppr_tycon (sortLe le_sig tycons))
1415   where
1416     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1417     ppr_tycon tycon
1418       | isCoercionTyCon tycon = ptext SLIT("coercion") <+> ppr tycon
1419       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1420
1421 ppr_rules :: [CoreRule] -> SDoc
1422 ppr_rules [] = empty
1423 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1424                       nest 4 (pprRules rs),
1425                       ptext SLIT("#-}")]
1426
1427 ppr_gen_tycons []  = empty
1428 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1429                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1430 \end{code}