compiler/typecheck/TcRnDriver.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcModule]{Typechecking a whole module}
   6
   7 \begin{code}
   8 module TcRnDriver (
   9 #ifdef GHCI
  10         tcRnStmt, tcRnExpr, tcRnType,
  11         tcRnLookupRdrName,
  12         tcRnLookupName,
  13         tcRnGetInfo,
  14         getModuleExports,
  15         tcRnRecoverDataCon,
  16 #endif
  17         tcRnModule,
  18         tcTopSrcDecls,
  19         tcRnExtCore
  20     ) where
  21
  22 #include "HsVersions.h"
  23
  24 import IO
  25 #ifdef GHCI
  26 import {-# SOURCE #-} TcSplice ( tcSpliceDecls )
  27 #endif
  28
  29 import DynFlags
  30 import StaticFlags
  31 import HsSyn
  32 import RdrHsSyn
  33
  34 import PrelNames
  35 import RdrName
  36 import TcHsSyn
  37 import TcExpr
  38 import TcRnMonad
  39 import TcType
  40 import Inst
  41 import FamInst
  42 import InstEnv
  43 import FamInstEnv
  44 import TcBinds
  45 import TcDefaults
  46 import TcEnv
  47 import TcRules
  48 import TcForeign
  49 import TcInstDcls
  50 import TcIface
  51 import MkIface
  52 import IfaceSyn
  53 import TcSimplify
  54 import TcTyClsDecls
  55 import LoadIface
  56 import RnNames
  57 import RnEnv
  58 import RnSource
  59 import RnHsDoc
  60 import PprCore
  61 import CoreSyn
  62 import ErrUtils
  63 import Id
  64 import Var
  65 import Module
  66 import UniqFM
  67 import Name
  68 import NameEnv
  69 import NameSet
  70 import TyCon
  71 import SrcLoc
  72 import HscTypes
  73 import ListSetOps
  74 import Outputable
  75
  76 #ifdef GHCI
  77 import Linker
  78 import DataCon
  79 import TcHsType
  80 import TcMType
  81 import TcMatches
  82 import TcGadt
  83 import RnTypes
  84 import RnExpr
  85 import IfaceEnv
  86 import MkId
  87 import TysWiredIn
  88 import IdInfo
  89 import {- Kind parts of -} Type
  90 import BasicTypes
  91 #endif
  92
  93 import FastString
  94 import Maybes
  95 import Util
  96 import Bag
  97
  98 import Control.Monad    ( unless )
  99 import Data.Maybe       ( isJust )
 100 import Foreign.Ptr      ( Ptr )
 101
 102 \end{code}
 103
 104
 105
 106 %************************************************************************
 107 %*                                                                      *
 108         Typecheck and rename a module
 109 %*                                                                      *
 110 %************************************************************************
 111
 112
 113 \begin{code}
 114 tcRnModule :: HscEnv
 115            -> HscSource
 116            -> Bool              -- True <=> save renamed syntax
 117            -> Located (HsModule RdrName)
 118            -> IO (Messages, Maybe TcGblEnv)
 119
 120 tcRnModule hsc_env hsc_src save_rn_syntax
 121          (L loc (HsModule maybe_mod export_ies
 122                           import_decls local_decls mod_deprec _
 123                           module_info maybe_doc))
 124  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 125
 126    let { this_pkg = thisPackage (hsc_dflags hsc_env) ;
 127          this_mod = case maybe_mod of
 128                         Nothing  -> mAIN        -- 'module M where' is omitted
 129                         Just (L _ mod) -> mkModule this_pkg mod } ;
 130                                                 -- The normal case
 131
 132    initTc hsc_env hsc_src save_rn_syntax this_mod $
 133    setSrcSpan loc $
 134    do {         -- Deal with imports;
 135         tcg_env <- tcRnImports hsc_env this_mod import_decls ;
 136         setGblEnv tcg_env               $ do {
 137
 138                 -- Load the hi-boot interface for this module, if any
 139                 -- We do this now so that the boot_names can be passed
 140                 -- to tcTyAndClassDecls, because the boot_names are
 141                 -- automatically considered to be loop breakers
 142                 --
 143                 -- Do this *after* tcRnImports, so that we know whether
 144                 -- a module that we import imports us; and hence whether to
 145                 -- look for a hi-boot file
 146         boot_iface <- tcHiBootIface hsc_src this_mod ;
 147
 148                 -- Rename and type check the declarations
 149         traceRn (text "rn1a") ;
 150         tcg_env <- if isHsBoot hsc_src then
 151                         tcRnHsBootDecls local_decls
 152                    else
 153                         tcRnSrcDecls boot_iface local_decls ;
 154         setGblEnv tcg_env               $ do {
 155
 156                 -- Report the use of any deprecated things
 157                 -- We do this *before* processsing the export list so
 158                 -- that we don't bleat about re-exporting a deprecated
 159                 -- thing (especially via 'module Foo' export item)
 160                 -- That is, only uses in the *body* of the module are complained about
 161         traceRn (text "rn3") ;
 162         failIfErrsM ;   -- finishDeprecations crashes sometimes
 163                         -- as a result of typechecker repairs (e.g. unboundNames)
 164         tcg_env <- finishDeprecations (hsc_dflags hsc_env) mod_deprec tcg_env ;
 165
 166                 -- Process the export list
 167         tcg_env <- rnExports (isJust maybe_mod) export_ies tcg_env ;
 168         traceRn (text "rn4") ;
 169
 170         -- Compare the hi-boot iface (if any) with the real thing
 171         -- Must be done after processing the exports
 172         tcg_env <- checkHiBootIface tcg_env boot_iface ;
 173
 174         -- Make the new type env available to stuff slurped from interface files
 175         -- Must do this after checkHiBootIface, because the latter might add new
 176         -- bindings for boot_dfuns, which may be mentioned in imported unfoldings
 177         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 178
 179                 -- Rename the Haddock documentation
 180         tcg_env <- rnHaddock module_info maybe_doc tcg_env ;
 181
 182                 -- Report unused names
 183         reportUnusedNames export_ies tcg_env ;
 184
 185                 -- Dump output and return
 186         tcDump tcg_env ;
 187         return tcg_env
 188     }}}}
 189 \end{code}
 190
 191
 192 %************************************************************************
 193 %*                                                                      *
 194                 Import declarations
 195 %*                                                                      *
 196 %************************************************************************
 197
 198 \begin{code}
 199 tcRnImports :: HscEnv -> Module -> [LImportDecl RdrName] -> TcM TcGblEnv
 200 tcRnImports hsc_env this_mod import_decls
 201   = do  { (rn_imports, rdr_env, imports) <- rnImports import_decls ;
 202
 203         ; let { dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface)
 204               ; dep_mods = imp_dep_mods imports
 205
 206                 -- We want instance declarations from all home-package
 207                 -- modules below this one, including boot modules, except
 208                 -- ourselves.  The 'except ourselves' is so that we don't
 209                 -- get the instances from this module's hs-boot file
 210               ; want_instances :: ModuleName -> Bool
 211               ; want_instances mod = mod `elemUFM` dep_mods
 212                                    && mod /= moduleName this_mod
 213               ; home_insts = hptInstances hsc_env want_instances
 214               } ;
 215
 216                 -- Record boot-file info in the EPS, so that it's
 217                 -- visible to loadHiBootInterface in tcRnSrcDecls,
 218                 -- and any other incrementally-performed imports
 219         ; updateEps_ (\eps -> eps { eps_is_boot = dep_mods }) ;
 220
 221                 -- Update the gbl env
 222         ; updGblEnv ( \ gbl ->
 223                 gbl { tcg_rdr_env    = plusOccEnv (tcg_rdr_env gbl) rdr_env,
 224                       tcg_imports    = tcg_imports gbl `plusImportAvails` imports,
 225                       tcg_rn_imports = fmap (const rn_imports) (tcg_rn_imports gbl),
 226                       tcg_inst_env   = extendInstEnvList (tcg_inst_env gbl) home_insts
 227                 }) $ do {
 228
 229         ; traceRn (text "rn1" <+> ppr (imp_dep_mods imports))
 230                 -- Fail if there are any errors so far
 231                 -- The error printing (if needed) takes advantage
 232                 -- of the tcg_env we have now set
 233 --      ; traceIf (text "rdr_env: " <+> ppr rdr_env)
 234         ; failIfErrsM
 235
 236                 -- Load any orphan-module and family instance-module
 237                 -- interfaces, so that their rules and instance decls will be
 238                 -- found.
 239         ; loadOrphanModules (imp_orphs  imports) False
 240         ; loadOrphanModules (imp_finsts imports) True
 241
 242                 -- Check type-familily consistency
 243         ; traceRn (text "rn1: checking family instance consistency")
 244         ; let { dir_imp_mods = map (\ (mod, _, _) -> mod)
 245                              . moduleEnvElts
 246                              . imp_mods
 247                              $ imports }
 248         ; checkFamInstConsistency (imp_finsts imports) dir_imp_mods ;
 249
 250         ; getGblEnv } }
 251 \end{code}
 252
 253
 254 %************************************************************************
 255 %*                                                                      *
 256         Type-checking external-core modules
 257 %*                                                                      *
 258 %************************************************************************
 259
 260 \begin{code}
 261 tcRnExtCore :: HscEnv
 262             -> HsExtCore RdrName
 263             -> IO (Messages, Maybe ModGuts)
 264         -- Nothing => some error occurred
 265
 266 tcRnExtCore hsc_env (HsExtCore this_mod decls src_binds)
 267         -- The decls are IfaceDecls; all names are original names
 268  = do { showPass (hsc_dflags hsc_env) "Renamer/typechecker" ;
 269
 270    initTc hsc_env ExtCoreFile False this_mod $ do {
 271
 272    let { ldecls  = map noLoc decls } ;
 273
 274         -- Deal with the type declarations; first bring their stuff
 275         -- into scope, then rname them, then type check them
 276    tcg_env  <- importsFromLocalDecls (mkFakeGroup ldecls) ;
 277
 278    setGblEnv tcg_env $ do {
 279
 280    rn_decls <- rnTyClDecls ldecls ;
 281    failIfErrsM ;
 282
 283         -- Dump trace of renaming part
 284    rnDump (ppr rn_decls) ;
 285
 286         -- Typecheck them all together so that
 287         -- any mutually recursive types are done right
 288    tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails rn_decls) ;
 289         -- Make the new type env available to stuff slurped from interface files
 290
 291    setGblEnv tcg_env $ do {
 292
 293         -- Now the core bindings
 294    core_binds <- initIfaceExtCore (tcExtCoreBindings src_binds) ;
 295
 296         -- Wrap up
 297    let {
 298         bndrs      = bindersOfBinds core_binds ;
 299         my_exports = map (Avail . idName) bndrs ;
 300                 -- ToDo: export the data types also?
 301
 302         final_type_env = extendTypeEnvWithIds (tcg_type_env tcg_env) bndrs ;
 303
 304         mod_guts = ModGuts {    mg_module    = this_mod,
 305                                 mg_boot      = False,
 306                                 mg_usages    = [],              -- ToDo: compute usage
 307                                 mg_dir_imps  = [],              -- ??
 308                                 mg_deps      = noDependencies,  -- ??
 309                                 mg_exports   = my_exports,
 310                                 mg_types     = final_type_env,
 311                                 mg_insts     = tcg_insts tcg_env,
 312                                 mg_fam_insts = tcg_fam_insts tcg_env,
 313                                 mg_fam_inst_env = tcg_fam_inst_env tcg_env,
 314                                 mg_rules     = [],
 315                                 mg_binds     = core_binds,
 316
 317                                 -- Stubs
 318                                 mg_rdr_env   = emptyGlobalRdrEnv,
 319                                 mg_fix_env   = emptyFixityEnv,
 320                                 mg_deprecs   = NoDeprecs,
 321                                 mg_foreign   = NoStubs,
 322                                 mg_hpc_info  = noHpcInfo,
 323                                 mg_modBreaks = emptyModBreaks
 324                     } } ;
 325
 326    tcCoreDump mod_guts ;
 327
 328    return mod_guts
 329    }}}}
 330
 331 mkFakeGroup decls -- Rather clumsy; lots of unused fields
 332   = emptyRdrGroup { hs_tyclds = decls }
 333 \end{code}
 334
 335
 336 %************************************************************************
 337 %*                                                                      *
 338         Type-checking the top level of a module
 339 %*                                                                      *
 340 %************************************************************************
 341
 342 \begin{code}
 343 tcRnSrcDecls :: ModDetails -> [LHsDecl RdrName] -> TcM TcGblEnv
 344         -- Returns the variables free in the decls
 345         -- Reason: solely to report unused imports and bindings
 346 tcRnSrcDecls boot_iface decls
 347  = do {         -- Do all the declarations
 348         (tc_envs, lie) <- getLIE $ tc_rn_src_decls boot_iface decls ;
 349
 350              --         Finish simplifying class constraints
 351              --
 352              -- tcSimplifyTop deals with constant or ambiguous InstIds.
 353              -- How could there be ambiguous ones?  They can only arise if a
 354              -- top-level decl falls under the monomorphism restriction
 355              -- and no subsequent decl instantiates its type.
 356              --
 357              -- We do this after checkMain, so that we use the type info
 358              -- thaat checkMain adds
 359              --
 360              -- We do it with both global and local env in scope:
 361              --  * the global env exposes the instances to tcSimplifyTop
 362              --  * the local env exposes the local Ids to tcSimplifyTop,
 363              --    so that we get better error messages (monomorphism restriction)
 364         traceTc (text "Tc8") ;
 365         inst_binds <- setEnvs tc_envs (tcSimplifyTop lie) ;
 366
 367             -- Backsubstitution.  This must be done last.
 368             -- Even tcSimplifyTop may do some unification.
 369         traceTc (text "Tc9") ;
 370         let { (tcg_env, _) = tc_envs
 371             ; TcGblEnv { tcg_type_env = type_env, tcg_binds = binds,
 372                          tcg_rules = rules, tcg_fords = fords } = tcg_env
 373             ; all_binds = binds `unionBags` inst_binds } ;
 374
 375         (bind_ids, binds', fords', rules') <- zonkTopDecls all_binds rules fords ;
 376
 377         let { final_type_env = extendTypeEnvWithIds type_env bind_ids
 378             ; tcg_env' = tcg_env { tcg_type_env = final_type_env,
 379                                    tcg_binds = binds',
 380                                    tcg_rules = rules',
 381                                    tcg_fords = fords' } } ;
 382
 383         return (tcg_env' { tcg_binds = tcg_binds tcg_env' })
 384    }
 385
 386 tc_rn_src_decls :: ModDetails -> [LHsDecl RdrName] -> TcM (TcGblEnv, TcLclEnv)
 387 -- Loops around dealing with each top level inter-splice group
 388 -- in turn, until it's dealt with the entire module
 389 tc_rn_src_decls boot_details ds
 390  = do { let { (first_group, group_tail) = findSplice ds } ;
 391                 -- If ds is [] we get ([], Nothing)
 392
 393         -- Deal with decls up to, but not including, the first splice
 394         (tcg_env, rn_decls) <- checkNoErrs $ rnTopSrcDecls first_group ;
 395                 -- checkNoErrs: stop if renaming fails
 396
 397         (tcg_env, tcl_env) <- setGblEnv tcg_env $
 398                               tcTopSrcDecls boot_details rn_decls ;
 399
 400         -- If there is no splice, we're nearly done
 401         setEnvs (tcg_env, tcl_env) $
 402         case group_tail of {
 403            Nothing -> do { tcg_env <- checkMain ;       -- Check for `main'
 404                            return (tcg_env, tcl_env)
 405                       } ;
 406
 407         -- If there's a splice, we must carry on
 408            Just (SpliceDecl splice_expr, rest_ds) -> do {
 409 #ifndef GHCI
 410         failWithTc (text "Can't do a top-level splice; need a bootstrapped compiler")
 411 #else
 412
 413         -- Rename the splice expression, and get its supporting decls
 414         (rn_splice_expr, splice_fvs) <- checkNoErrs (rnLExpr splice_expr) ;
 415                 -- checkNoErrs: don't typecheck if renaming failed
 416         rnDump (ppr rn_splice_expr) ;
 417
 418         -- Execute the splice
 419         spliced_decls <- tcSpliceDecls rn_splice_expr ;
 420
 421         -- Glue them on the front of the remaining decls and loop
 422         setGblEnv (tcg_env `addTcgDUs` usesOnly splice_fvs) $
 423         tc_rn_src_decls boot_details (spliced_decls ++ rest_ds)
 424 #endif /* GHCI */
 425     } } }
 426 \end{code}
 427
 428 %************************************************************************
 429 %*                                                                      *
 430         Compiling hs-boot source files, and
 431         comparing the hi-boot interface with the real thing
 432 %*                                                                      *
 433 %************************************************************************
 434
 435 \begin{code}
 436 tcRnHsBootDecls :: [LHsDecl RdrName] -> TcM TcGblEnv
 437 tcRnHsBootDecls decls
 438    = do { let { (first_group, group_tail) = findSplice decls }
 439
 440         ; case group_tail of
 441              Just stuff -> spliceInHsBootErr stuff
 442              Nothing    -> return ()
 443
 444                 -- Rename the declarations
 445         ; (tcg_env, rn_group) <- rnTopSrcDecls first_group
 446         ; setGblEnv tcg_env $ do {
 447
 448         -- Todo: check no foreign decls, no rules, no default decls
 449
 450                 -- Typecheck type/class decls
 451         ; traceTc (text "Tc2")
 452         ; let tycl_decls = hs_tyclds rn_group
 453         ; tcg_env <- checkNoErrs (tcTyAndClassDecls emptyModDetails tycl_decls)
 454         ; setGblEnv tcg_env     $ do {
 455
 456                 -- Typecheck instance decls
 457         ; traceTc (text "Tc3")
 458         ; (tcg_env, inst_infos, _deriv_binds)
 459             <- tcInstDecls1 tycl_decls (hs_instds rn_group) (hs_derivds rn_group)
 460         ; setGblEnv tcg_env     $ do {
 461
 462                 -- Typecheck value declarations
 463         ; traceTc (text "Tc5")
 464         ; val_ids <- tcHsBootSigs (hs_valds rn_group)
 465
 466                 -- Wrap up
 467                 -- No simplification or zonking to do
 468         ; traceTc (text "Tc7a")
 469         ; gbl_env <- getGblEnv
 470
 471                 -- Make the final type-env
 472                 -- Include the dfun_ids so that their type sigs
 473                 -- are written into the interface file
 474         ; let { type_env0 = tcg_type_env gbl_env
 475               ; type_env1 = extendTypeEnvWithIds type_env0 val_ids
 476               ; type_env2 = extendTypeEnvWithIds type_env1 dfun_ids
 477               ; dfun_ids = map iDFunId inst_infos }
 478         ; return (gbl_env { tcg_type_env = type_env2 })
 479    }}}}
 480
 481 spliceInHsBootErr (SpliceDecl (L loc _), _)
 482   = addErrAt loc (ptext SLIT("Splices are not allowed in hs-boot files"))
 483 \end{code}
 484
 485 Once we've typechecked the body of the module, we want to compare what
 486 we've found (gathered in a TypeEnv) with the hi-boot details (if any).
 487
 488 \begin{code}
 489 checkHiBootIface :: TcGblEnv -> ModDetails -> TcM TcGblEnv
 490 -- Compare the hi-boot file for this module (if there is one)
 491 -- with the type environment we've just come up with
 492 -- In the common case where there is no hi-boot file, the list
 493 -- of boot_names is empty.
 494 --
 495 -- The bindings we return give bindings for the dfuns defined in the
 496 -- hs-boot file, such as        $fbEqT = $fEqT
 497
 498 checkHiBootIface
 499         tcg_env@(TcGblEnv { tcg_src = hs_src, tcg_binds = binds,
 500                             tcg_insts = local_insts, tcg_fam_insts = local_fam_insts,
 501                             tcg_type_env = local_type_env, tcg_exports = local_exports })
 502         (ModDetails { md_insts = boot_insts, md_fam_insts = boot_fam_insts,
 503                       md_types = boot_type_env, md_exports = boot_exports })
 504   | isHsBoot hs_src     -- Current module is already a hs-boot file!
 505   = return tcg_env
 506
 507   | otherwise
 508   = do  { traceTc (text "checkHiBootIface" <+> (ppr boot_type_env $$ ppr boot_insts $$
 509                                 ppr boot_exports)) ;
 510
 511                 -- Check the exports of the boot module, one by one
 512         ; mapM_ check_export boot_exports
 513
 514                 -- Check instance declarations
 515         ; mb_dfun_prs <- mapM check_inst boot_insts
 516         ; let tcg_env' = tcg_env { tcg_binds    = binds `unionBags` dfun_binds,
 517                                    tcg_type_env = extendTypeEnvWithIds local_type_env boot_dfuns }
 518               dfun_prs   = catMaybes mb_dfun_prs
 519               boot_dfuns = map fst dfun_prs
 520               dfun_binds = listToBag [ noLoc $ VarBind boot_dfun (nlHsVar dfun)
 521                                      | (boot_dfun, dfun) <- dfun_prs ]
 522
 523                 -- Check for no family instances
 524         ; unless (null boot_fam_insts) $
 525             panic ("TcRnDriver.checkHiBootIface: Cannot handle family " ++
 526                    "instances in boot files yet...")
 527             -- FIXME: Why?  The actual comparison is not hard, but what would
 528             --        be the equivalent to the dfun bindings returned for class
 529             --        instances?  We can't easily equate tycons...
 530
 531         ; return tcg_env' }
 532   where
 533     check_export boot_avail     -- boot_avail is exported by the boot iface
 534       | name `elem` dfun_names = return ()
 535       | isWiredInName name     = return ()      -- No checking for wired-in names.  In particular,
 536                                                 -- 'error' is handled by a rather gross hack
 537                                                 -- (see comments in GHC.Err.hs-boot)
 538
 539         -- Check that the actual module exports the same thing
 540       | not (null missing_names)
 541       = addErrTc (missingBootThing (head missing_names) "exported by")
 542
 543         -- If the boot module does not *define* the thing, we are done
 544         -- (it simply re-exports it, and names match, so nothing further to do)
 545       | isNothing mb_boot_thing = return ()
 546
 547         -- Check that the actual module also defines the thing, and
 548         -- then compare the definitions
 549       | Just real_thing <- lookupTypeEnv local_type_env name
 550       = do { let boot_decl = tyThingToIfaceDecl (fromJust mb_boot_thing)
 551                  real_decl = tyThingToIfaceDecl real_thing
 552            ; checkTc (checkBootDecl boot_decl real_decl)
 553                      (bootMisMatch real_thing boot_decl real_decl) }
 554                 -- The easiest way to check compatibility is to convert to
 555                 -- iface syntax, where we already have good comparison functions
 556
 557       | otherwise
 558       = addErrTc (missingBootThing name "defined in")
 559       where
 560         name          = availName boot_avail
 561         mb_boot_thing = lookupTypeEnv boot_type_env name
 562         missing_names = case lookupNameEnv local_export_env name of
 563                           Nothing    -> [name]
 564                           Just avail -> availNames boot_avail `minusList` availNames avail
 565
 566     dfun_names = map getName boot_insts
 567
 568     local_export_env :: NameEnv AvailInfo
 569     local_export_env = availsToNameEnv local_exports
 570
 571     check_inst :: Instance -> TcM (Maybe (Id, Id))
 572         -- Returns a pair of the boot dfun in terms of the equivalent real dfun
 573     check_inst boot_inst
 574         = case [dfun | inst <- local_insts,
 575                        let dfun = instanceDFunId inst,
 576                        idType dfun `tcEqType` boot_inst_ty ] of
 577             [] -> do { addErrTc (instMisMatch boot_inst); return Nothing }
 578             (dfun:_) -> return (Just (local_boot_dfun, dfun))
 579         where
 580           boot_dfun = instanceDFunId boot_inst
 581           boot_inst_ty = idType boot_dfun
 582           local_boot_dfun = Id.mkExportedLocalId (idName boot_dfun) boot_inst_ty
 583
 584
 585 ----------------
 586 missingBootThing thing what
 587   = ppr thing <+> ptext SLIT("is exported by the hs-boot file, but not")
 588               <+> text what <+> ptext SLIT("the module")
 589
 590 bootMisMatch thing boot_decl real_decl
 591   = vcat [ppr thing <+> ptext SLIT("has conflicting definitions in the module and its hs-boot file"),
 592           ptext SLIT("Main module:") <+> ppr real_decl,
 593           ptext SLIT("Boot file:  ") <+> ppr boot_decl]
 594
 595 instMisMatch inst
 596   = hang (ppr inst)
 597        2 (ptext SLIT("is defined in the hs-boot file, but not in the module itself"))
 598 \end{code}
 599
 600
 601 %************************************************************************
 602 %*                                                                      *
 603         Type-checking the top level of a module
 604 %*                                                                      *
 605 %************************************************************************
 606
 607 tcRnGroup takes a bunch of top-level source-code declarations, and
 608  * renames them
 609  * gets supporting declarations from interface files
 610  * typechecks them
 611  * zonks them
 612  * and augments the TcGblEnv with the results
 613
 614 In Template Haskell it may be called repeatedly for each group of
 615 declarations.  It expects there to be an incoming TcGblEnv in the
 616 monad; it augments it and returns the new TcGblEnv.
 617
 618 \begin{code}
 619 ------------------------------------------------
 620 rnTopSrcDecls :: HsGroup RdrName -> TcM (TcGblEnv, HsGroup Name)
 621 rnTopSrcDecls group
 622  = do {         -- Bring top level binders into scope
 623         tcg_env <- importsFromLocalDecls group ;
 624         setGblEnv tcg_env $ do {
 625
 626         failIfErrsM ;   -- No point in continuing if (say) we have duplicate declarations
 627
 628                 -- Rename the source decls
 629         (tcg_env, rn_decls) <- rnSrcDecls group ;
 630         failIfErrsM ;
 631
 632                 -- save the renamed syntax, if we want it
 633         let { tcg_env'
 634                 | Just grp <- tcg_rn_decls tcg_env
 635                   = tcg_env{ tcg_rn_decls = Just (appendGroups grp rn_decls) }
 636                 | otherwise
 637                    = tcg_env };
 638
 639                 -- Dump trace of renaming part
 640         rnDump (ppr rn_decls) ;
 641
 642         return (tcg_env', rn_decls)
 643    }}
 644
 645 ------------------------------------------------
 646 tcTopSrcDecls :: ModDetails -> HsGroup Name -> TcM (TcGblEnv, TcLclEnv)
 647 tcTopSrcDecls boot_details
 648         (HsGroup { hs_tyclds = tycl_decls,
 649                    hs_instds = inst_decls,
 650                    hs_derivds = deriv_decls,
 651                    hs_fords  = foreign_decls,
 652                    hs_defds  = default_decls,
 653                    hs_ruleds = rule_decls,
 654                    hs_valds  = val_binds })
 655  = do {         -- Type-check the type and class decls, and all imported decls
 656                 -- The latter come in via tycl_decls
 657         traceTc (text "Tc2") ;
 658
 659         tcg_env <- checkNoErrs (tcTyAndClassDecls boot_details tycl_decls) ;
 660         -- tcTyAndClassDecls recovers internally, but if anything gave rise to
 661         -- an error we'd better stop now, to avoid a cascade
 662
 663         -- Make these type and class decls available to stuff slurped from interface files
 664         writeMutVar (tcg_type_env_var tcg_env) (tcg_type_env tcg_env) ;
 665
 666
 667         setGblEnv tcg_env       $ do {
 668                 -- Source-language instances, including derivings,
 669                 -- and import the supporting declarations
 670         traceTc (text "Tc3") ;
 671         (tcg_env, inst_infos, deriv_binds)
 672             <- tcInstDecls1 tycl_decls inst_decls deriv_decls;
 673         setGblEnv tcg_env       $ do {
 674
 675                 -- Foreign import declarations next.  No zonking necessary
 676                 -- here; we can tuck them straight into the global environment.
 677         traceTc (text "Tc4") ;
 678         (fi_ids, fi_decls) <- tcForeignImports foreign_decls ;
 679         tcExtendGlobalValEnv fi_ids     $ do {
 680
 681                 -- Default declarations
 682         traceTc (text "Tc4a") ;
 683         default_tys <- tcDefaults default_decls ;
 684         updGblEnv (\gbl -> gbl { tcg_default = default_tys }) $ do {
 685
 686                 -- Value declarations next
 687                 -- We also typecheck any extra binds that came out
 688                 -- of the "deriving" process (deriv_binds)
 689         traceTc (text "Tc5") ;
 690         (tc_val_binds, tcl_env) <- tcTopBinds (val_binds `plusHsValBinds` deriv_binds) ;
 691         setLclTypeEnv tcl_env   $ do {
 692
 693                 -- Second pass over class and instance declarations,
 694         traceTc (text "Tc6") ;
 695         (inst_binds, tcl_env) <- tcInstDecls2 tycl_decls inst_infos ;
 696         showLIE (text "after instDecls2") ;
 697
 698                 -- Foreign exports
 699                 -- They need to be zonked, so we return them
 700         traceTc (text "Tc7") ;
 701         (foe_binds, foe_decls) <- tcForeignExports foreign_decls ;
 702
 703                 -- Rules
 704         rules <- tcRules rule_decls ;
 705
 706                 -- Wrap up
 707         traceTc (text "Tc7a") ;
 708         tcg_env <- getGblEnv ;
 709         let { all_binds = tc_val_binds   `unionBags`
 710                           inst_binds     `unionBags`
 711                           foe_binds  ;
 712
 713                 -- Extend the GblEnv with the (as yet un-zonked)
 714                 -- bindings, rules, foreign decls
 715               tcg_env' = tcg_env {  tcg_binds = tcg_binds tcg_env `unionBags` all_binds,
 716                                     tcg_rules = tcg_rules tcg_env ++ rules,
 717                                     tcg_fords = tcg_fords tcg_env ++ foe_decls ++ fi_decls } } ;
 718         return (tcg_env', tcl_env)
 719     }}}}}}
 720 \end{code}
 721
 722
 723 %************************************************************************
 724 %*                                                                      *
 725         Checking for 'main'
 726 %*                                                                      *
 727 %************************************************************************
 728
 729 \begin{code}
 730 checkMain :: TcM TcGblEnv
 731 -- If we are in module Main, check that 'main' is defined.
 732 checkMain
 733   = do { tcg_env   <- getGblEnv ;
 734          dflags    <- getDOpts ;
 735          let { main_mod = mainModIs dflags ;
 736                main_fn  = case mainFunIs dflags of {
 737                                 Just fn -> mkRdrUnqual (mkVarOccFS (mkFastString fn)) ;
 738                                 Nothing -> main_RDR_Unqual } } ;
 739
 740          check_main dflags tcg_env main_mod main_fn
 741     }
 742
 743
 744 check_main dflags tcg_env main_mod main_fn
 745  | mod /= main_mod
 746  = traceTc (text "checkMain not" <+> ppr main_mod <+> ppr mod) >>
 747    return tcg_env
 748
 749  | otherwise
 750  = addErrCtxt mainCtxt                  $
 751    do   { mb_main <- lookupSrcOcc_maybe main_fn
 752                 -- Check that 'main' is in scope
 753                 -- It might be imported from another module!
 754         ; case mb_main of {
 755              Nothing -> do { traceTc (text "checkMain fail" <+> ppr main_mod <+> ppr main_fn)
 756                            ; complain_no_main
 757                            ; return tcg_env } ;
 758              Just main_name -> do
 759         { traceTc (text "checkMain found" <+> ppr main_mod <+> ppr main_fn)
 760         ; let { rhs = nlHsApp (nlHsVar runMainIOName) (nlHsVar main_name) }
 761                         -- :Main.main :: IO () = runMainIO main
 762
 763         ; (main_expr, ty) <- setSrcSpan (srcLocSpan (getSrcLoc main_name)) $
 764                              tcInferRho rhs
 765
 766                 -- See Note [Root-main Id]
 767         ; let { root_main_name =  mkExternalName rootMainKey rOOT_MAIN
 768                                    (mkVarOccFS FSLIT("main"))
 769                                    (getSrcLoc main_name)
 770               ; root_main_id = Id.mkExportedLocalId root_main_name ty
 771               ; main_bind    = noLoc (VarBind root_main_id main_expr) }
 772
 773         ; return (tcg_env { tcg_binds = tcg_binds tcg_env
 774                                         `snocBag` main_bind,
 775                             tcg_dus   = tcg_dus tcg_env
 776                                         `plusDU` usesOnly (unitFV main_name)
 777                         -- Record the use of 'main', so that we don't
 778                         -- complain about it being defined but not used
 779                  })
 780     }}}
 781   where
 782     mod = tcg_mod tcg_env
 783
 784     complain_no_main | ghcLink dflags == LinkInMemory = return ()
 785                      | otherwise = failWithTc noMainMsg
 786         -- In interactive mode, don't worry about the absence of 'main'
 787         -- In other modes, fail altogether, so that we don't go on
 788         -- and complain a second time when processing the export list.
 789
 790     mainCtxt  = ptext SLIT("When checking the type of the main function") <+> quotes (ppr main_fn)
 791     noMainMsg = ptext SLIT("The main function") <+> quotes (ppr main_fn)
 792                 <+> ptext SLIT("is not defined in module") <+> quotes (ppr main_mod)
 793 \end{code}
 794
 795 Note [Root-main Id]
 796 ~~~~~~~~~~~~~~~~~~~
 797 The function that the RTS invokes is always :Main.main, which we call
 798 root_main_id.  (Because GHC allows the user to have a module not
 799 called Main as the main module, we can't rely on the main function
 800 being called "Main.main".  That's why root_main_id has a fixed module
 801 ":Main".)
 802
 803 This is unusual: it's a LocalId whose Name has a Module from another
 804 module.  Tiresomely, we must filter it out again in MkIface, les we
 805 get two defns for 'main' in the interface file!
 806
 807
 808 %*********************************************************
 809 %*                                                       *
 810                 GHCi stuff
 811 %*                                                       *
 812 %*********************************************************
 813
 814 \begin{code}
 815 #ifdef GHCI
 816 setInteractiveContext :: HscEnv -> InteractiveContext -> TcRn a -> TcRn a
 817 setInteractiveContext hsc_env icxt thing_inside
 818   = let
 819         -- Initialise the tcg_inst_env with instances
 820         -- from all home modules.  This mimics the more selective
 821         -- call to hptInstances in tcRnModule
 822         dfuns = hptInstances hsc_env (\mod -> True)
 823     in
 824     updGblEnv (\env -> env {
 825         tcg_rdr_env  = ic_rn_gbl_env icxt,
 826         tcg_type_env = ic_type_env   icxt,
 827         tcg_inst_env = extendInstEnvList (tcg_inst_env env) dfuns }) $
 828
 829     updLclEnv (\env -> env { tcl_rdr = ic_rn_local_env icxt })  $
 830
 831     do  { traceTc (text "setIC" <+> ppr (ic_type_env icxt))
 832         ; thing_inside }
 833 \end{code}
 834
 835
 836 \begin{code}
 837 tcRnStmt :: HscEnv
 838          -> InteractiveContext
 839          -> LStmt RdrName
 840          -> IO (Maybe (InteractiveContext, [Name], LHsExpr Id))
 841                 -- The returned [Name] is the same as the input except for
 842                 -- ExprStmt, in which case the returned [Name] is [itName]
 843                 --
 844                 -- The returned TypecheckedHsExpr is of type IO [ () ],
 845                 -- a list of the bound values, coerced to ().
 846
 847 tcRnStmt hsc_env ictxt rdr_stmt
 848   = initTcPrintErrors hsc_env iNTERACTIVE $
 849     setInteractiveContext hsc_env ictxt $ do {
 850
 851     -- Rename; use CmdLineMode because tcRnStmt is only used interactively
 852     (([rn_stmt], _), fvs) <- rnStmts DoExpr [rdr_stmt] (return ((), emptyFVs)) ;
 853     traceRn (text "tcRnStmt" <+> vcat [ppr rdr_stmt, ppr rn_stmt, ppr fvs]) ;
 854     failIfErrsM ;
 855
 856     -- The real work is done here
 857     (bound_ids, tc_expr) <- mkPlan rn_stmt ;
 858     zonked_expr <- zonkTopLExpr tc_expr ;
 859     zonked_ids  <- zonkTopBndrs bound_ids ;
 860
 861         -- None of the Ids should be of unboxed type, because we
 862         -- cast them all to HValues in the end!
 863     mappM bad_unboxed (filter (isUnLiftedType . idType) zonked_ids) ;
 864
 865     traceTc (text "tcs 1") ;
 866     let {       -- (a) Make all the bound ids "global" ids, now that
 867                 --     they're notionally top-level bindings.  This is
 868                 --     important: otherwise when we come to compile an expression
 869                 --     using these ids later, the byte code generator will consider
 870                 --     the occurrences to be free rather than global.
 871                 --
 872                 -- (b) Tidy their types; this is important, because :info may
 873                 --     ask to look at them, and :info expects the things it looks
 874                 --     up to have tidy types
 875         global_ids = map globaliseAndTidy zonked_ids ;
 876
 877                 -- Update the interactive context
 878         rn_env   = ic_rn_local_env ictxt ;
 879         type_env = ic_type_env ictxt ;
 880
 881         bound_names = map idName global_ids ;
 882         new_rn_env  = extendLocalRdrEnv rn_env bound_names ;
 883
 884 {- ---------------------------------------------
 885    At one stage I removed any shadowed bindings from the type_env;
 886    they are inaccessible but might, I suppose, cause a space leak if we leave them there.
 887    However, with Template Haskell they aren't necessarily inaccessible.  Consider this
 888    GHCi session
 889          Prelude> let f n = n * 2 :: Int
 890          Prelude> fName <- runQ [| f |]
 891          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 892          14
 893          Prelude> let f n = n * 3 :: Int
 894          Prelude> $(return $ AppE fName (LitE (IntegerL 7)))
 895    In the last line we use 'fName', which resolves to the *first* 'f'
 896    in scope. If we delete it from the type env, GHCi crashes because
 897    it doesn't expect that.
 898
 899    Hence this code is commented out
 900
 901         shadowed = [ n | name <- bound_names,
 902                          let rdr_name = mkRdrUnqual (nameOccName name),
 903                          Just n <- [lookupLocalRdrEnv rn_env rdr_name] ] ;
 904         filtered_type_env = delListFromNameEnv type_env shadowed ;
 905 -------------------------------------------------- -}
 906
 907         new_type_env = extendTypeEnvWithIds type_env global_ids ;
 908         new_ic = ictxt { ic_rn_local_env = new_rn_env,
 909                          ic_type_env     = new_type_env }
 910     } ;
 911
 912     dumpOptTcRn Opt_D_dump_tc
 913         (vcat [text "Bound Ids" <+> pprWithCommas ppr global_ids,
 914                text "Typechecked expr" <+> ppr zonked_expr]) ;
 915
 916     returnM (new_ic, bound_names, zonked_expr)
 917     }
 918   where
 919     bad_unboxed id = addErr (sep [ptext SLIT("GHCi can't bind a variable of unlifted type:"),
 920                                   nest 2 (ppr id <+> dcolon <+> ppr (idType id))])
 921
 922 globaliseAndTidy :: Id -> Id
 923 globaliseAndTidy id
 924 -- Give the Id a Global Name, and tidy its type
 925   = Id.setIdType (globaliseId VanillaGlobal id) tidy_type
 926   where
 927     tidy_type = tidyTopType (idType id)
 928 \end{code}
 929
 930 Here is the grand plan, implemented in tcUserStmt
 931
 932         What you type                   The IO [HValue] that hscStmt returns
 933         -------------                   ------------------------------------
 934         let pat = expr          ==>     let pat = expr in return [coerce HVal x, coerce HVal y, ...]
 935                                         bindings: [x,y,...]
 936
 937         pat <- expr             ==>     expr >>= \ pat -> return [coerce HVal x, coerce HVal y, ...]
 938                                         bindings: [x,y,...]
 939
 940         expr (of IO type)       ==>     expr >>= \ it -> return [coerce HVal it]
 941           [NB: result not printed]      bindings: [it]
 942
 943         expr (of non-IO type,   ==>     let it = expr in print it >> return [coerce HVal it]
 944           result showable)              bindings: [it]
 945
 946         expr (of non-IO type,
 947           result not showable)  ==>     error
 948
 949
 950 \begin{code}
 951 ---------------------------
 952 type PlanResult = ([Id], LHsExpr Id)
 953 type Plan = TcM PlanResult
 954
 955 runPlans :: [Plan] -> TcM PlanResult
 956 -- Try the plans in order.  If one fails (by raising an exn), try the next.
 957 -- If one succeeds, take it.
 958 runPlans []     = panic "runPlans"
 959 runPlans [p]    = p
 960 runPlans (p:ps) = tryTcLIE_ (runPlans ps) p
 961
 962 --------------------
 963 mkPlan :: LStmt Name -> TcM PlanResult
 964 mkPlan (L loc (ExprStmt expr _ _))      -- An expression typed at the prompt
 965   = do  { uniq <- newUnique             -- is treated very specially
 966         ; let fresh_it  = itName uniq
 967               the_bind  = L loc $ mkFunBind (L loc fresh_it) matches
 968               matches   = [mkMatch [] expr emptyLocalBinds]
 969               let_stmt  = L loc $ LetStmt (HsValBinds (ValBindsOut [(NonRecursive,unitBag the_bind)] []))
 970               bind_stmt = L loc $ BindStmt (nlVarPat fresh_it) expr
 971                                            (HsVar bindIOName) noSyntaxExpr
 972               print_it  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar fresh_it))
 973                                            (HsVar thenIOName) placeHolderType
 974
 975         -- The plans are:
 976         --      [it <- e; print it]     but not if it::()
 977         --      [it <- e]
 978         --      [let it = e; print it]
 979         ; runPlans [    -- Plan A
 980                     do { stuff@([it_id], _) <- tcGhciStmts [bind_stmt, print_it]
 981                        ; it_ty <- zonkTcType (idType it_id)
 982                        ; ifM (isUnitTy it_ty) failM
 983                        ; return stuff },
 984
 985                         -- Plan B; a naked bind statment
 986                     tcGhciStmts [bind_stmt],
 987
 988                         -- Plan C; check that the let-binding is typeable all by itself.
 989                         -- If not, fail; if so, try to print it.
 990                         -- The two-step process avoids getting two errors: one from
 991                         -- the expression itself, and one from the 'print it' part
 992                         -- This two-step story is very clunky, alas
 993                     do { checkNoErrs (tcGhciStmts [let_stmt])
 994                                 --- checkNoErrs defeats the error recovery of let-bindings
 995                        ; tcGhciStmts [let_stmt, print_it] }
 996           ]}
 997
 998 mkPlan stmt@(L loc (BindStmt {}))
 999   | [L _ v] <- collectLStmtBinders stmt         -- One binder, for a bind stmt
1000   = do  { let print_v  = L loc $ ExprStmt (nlHsApp (nlHsVar printName) (nlHsVar v))
1001                                            (HsVar thenIOName) placeHolderType
1002
1003         ; print_bind_result <- doptM Opt_PrintBindResult
1004         ; let print_plan = do
1005                   { stuff@([v_id], _) <- tcGhciStmts [stmt, print_v]
1006                   ; v_ty <- zonkTcType (idType v_id)
1007                   ; ifM (isUnitTy v_ty || not (isTauTy v_ty)) failM
1008                   ; return stuff }
1009
1010         -- The plans are:
1011         --      [stmt; print v]         but not if v::()
1012         --      [stmt]
1013         ; runPlans ((if print_bind_result then [print_plan] else []) ++
1014                     [tcGhciStmts [stmt]])
1015         }
1016
1017 mkPlan stmt
1018   = tcGhciStmts [stmt]
1019
1020 ---------------------------
1021 tcGhciStmts :: [LStmt Name] -> TcM PlanResult
1022 tcGhciStmts stmts
1023  = do { ioTyCon <- tcLookupTyCon ioTyConName ;
1024         ret_id  <- tcLookupId returnIOName ;            -- return @ IO
1025         let {
1026             io_ty     = mkTyConApp ioTyCon [] ;
1027             ret_ty    = mkListTy unitTy ;
1028             io_ret_ty = mkTyConApp ioTyCon [ret_ty] ;
1029             tc_io_stmts stmts = tcStmts DoExpr (tcDoStmt io_ty) stmts
1030                                         (emptyRefinement, io_ret_ty) ;
1031
1032             names = map unLoc (collectLStmtsBinders stmts) ;
1033
1034                 -- mk_return builds the expression
1035                 --      returnIO @ [()] [coerce () x, ..,  coerce () z]
1036                 --
1037                 -- Despite the inconvenience of building the type applications etc,
1038                 -- this *has* to be done in type-annotated post-typecheck form
1039                 -- because we are going to return a list of *polymorphic* values
1040                 -- coerced to type (). If we built a *source* stmt
1041                 --      return [coerce x, ..., coerce z]
1042                 -- then the type checker would instantiate x..z, and we wouldn't
1043                 -- get their *polymorphic* values.  (And we'd get ambiguity errs
1044                 -- if they were overloaded, since they aren't applied to anything.)
1045             mk_return ids = nlHsApp (nlHsTyApp ret_id [ret_ty])
1046                                     (noLoc $ ExplicitList unitTy (map mk_item ids)) ;
1047             mk_item id = nlHsApp (nlHsTyApp unsafeCoerceId [idType id, unitTy])
1048                                  (nlHsVar id)
1049          } ;
1050
1051         -- OK, we're ready to typecheck the stmts
1052         traceTc (text "tcs 2") ;
1053         ((tc_stmts, ids), lie) <- getLIE $ tc_io_stmts stmts $ \ _ ->
1054                                            mappM tcLookupId names ;
1055                                         -- Look up the names right in the middle,
1056                                         -- where they will all be in scope
1057
1058         -- Simplify the context
1059         const_binds <- checkNoErrs (tcSimplifyInteractive lie) ;
1060                 -- checkNoErrs ensures that the plan fails if context redn fails
1061
1062         return (ids, mkHsDictLet const_binds $
1063                      noLoc (HsDo DoExpr tc_stmts (mk_return ids) io_ret_ty))
1064     }
1065 \end{code}
1066
1067
1068 tcRnExpr just finds the type of an expression
1069
1070 \begin{code}
1071 tcRnExpr :: HscEnv
1072          -> InteractiveContext
1073          -> LHsExpr RdrName
1074          -> IO (Maybe Type)
1075 tcRnExpr hsc_env ictxt rdr_expr
1076   = initTcPrintErrors hsc_env iNTERACTIVE $
1077     setInteractiveContext hsc_env ictxt $ do {
1078
1079     (rn_expr, fvs) <- rnLExpr rdr_expr ;
1080     failIfErrsM ;
1081
1082         -- Now typecheck the expression;
1083         -- it might have a rank-2 type (e.g. :t runST)
1084     ((tc_expr, res_ty), lie)       <- getLIE (tcInferRho rn_expr) ;
1085     ((qtvs, dict_insts, _), lie_top) <- getLIE (tcSimplifyInfer smpl_doc (tyVarsOfType res_ty) lie)  ;
1086     tcSimplifyInteractive lie_top ;
1087
1088     let { all_expr_ty = mkForAllTys qtvs $
1089                         mkFunTys (map (idType . instToId) dict_insts)   $
1090                         res_ty } ;
1091     zonkTcType all_expr_ty
1092     }
1093   where
1094     smpl_doc = ptext SLIT("main expression")
1095 \end{code}
1096
1097 tcRnType just finds the kind of a type
1098
1099 \begin{code}
1100 tcRnType :: HscEnv
1101          -> InteractiveContext
1102          -> LHsType RdrName
1103          -> IO (Maybe Kind)
1104 tcRnType hsc_env ictxt rdr_type
1105   = initTcPrintErrors hsc_env iNTERACTIVE $
1106     setInteractiveContext hsc_env ictxt $ do {
1107
1108     rn_type <- rnLHsType doc rdr_type ;
1109     failIfErrsM ;
1110
1111         -- Now kind-check the type
1112     (ty', kind) <- kcHsType rn_type ;
1113     return kind
1114     }
1115   where
1116     doc = ptext SLIT("In GHCi input")
1117
1118 #endif /* GHCi */
1119 \end{code}
1120
1121
1122 %************************************************************************
1123 %*                                                                      *
1124         More GHCi stuff, to do with browsing and getting info
1125 %*                                                                      *
1126 %************************************************************************
1127
1128 \begin{code}
1129 #ifdef GHCI
1130 -- ASSUMES that the module is either in the HomePackageTable or is
1131 -- a package module with an interface on disk.  If neither of these is
1132 -- true, then the result will be an error indicating the interface
1133 -- could not be found.
1134 getModuleExports :: HscEnv -> Module -> IO (Messages, Maybe [AvailInfo])
1135 getModuleExports hsc_env mod
1136   = let
1137       ic        = hsc_IC hsc_env
1138       checkMods = ic_toplev_scope ic ++ ic_exports ic
1139     in
1140     initTc hsc_env HsSrcFile False iNTERACTIVE (tcGetModuleExports mod checkMods)
1141
1142 -- Get the export avail info and also load all orphan and family-instance
1143 -- modules.  Finally, check that the family instances of all modules in the
1144 -- interactive context are consistent (these modules are in the second
1145 -- argument).
1146 tcGetModuleExports :: Module -> [Module] -> TcM [AvailInfo]
1147 tcGetModuleExports mod directlyImpMods
1148   = do { let doc = ptext SLIT("context for compiling statements")
1149        ; iface <- initIfaceTcRn $ loadSysInterface doc mod
1150
1151                 -- Load any orphan-module and family instance-module
1152                 -- interfaces, so their instances are visible.
1153        ; loadOrphanModules (dep_orphs (mi_deps iface)) False
1154        ; loadOrphanModules (dep_finsts (mi_deps iface)) True
1155
1156                 -- Check that the family instances of all directly loaded
1157                 -- modules are consistent.
1158        ; checkFamInstConsistency (dep_finsts (mi_deps iface)) directlyImpMods
1159
1160        ; ifaceExportNames (mi_exports iface)
1161        }
1162
1163 tcRnLookupRdrName :: HscEnv -> RdrName -> IO (Maybe [Name])
1164 tcRnLookupRdrName hsc_env rdr_name
1165   = initTcPrintErrors hsc_env iNTERACTIVE $
1166     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1167     lookup_rdr_name rdr_name
1168
1169 lookup_rdr_name rdr_name = do {
1170         -- If the identifier is a constructor (begins with an
1171         -- upper-case letter), then we need to consider both
1172         -- constructor and type class identifiers.
1173     let { rdr_names = dataTcOccs rdr_name } ;
1174
1175         -- results :: [Either Messages Name]
1176     results <- mapM (tryTcErrs . lookupOccRn) rdr_names ;
1177
1178     traceRn (text "xx" <+> vcat [ppr rdr_names, ppr (map snd results)]);
1179         -- The successful lookups will be (Just name)
1180     let { (warns_s, good_names) = unzip [ (msgs, name)
1181                                         | (msgs, Just name) <- results] ;
1182           errs_s = [msgs | (msgs, Nothing) <- results] } ;
1183
1184         -- Fail if nothing good happened, else add warnings
1185     if null good_names then
1186                 -- No lookup succeeded, so
1187                 -- pick the first error message and report it
1188                 -- ToDo: If one of the errors is "could be Foo.X or Baz.X",
1189                 --       while the other is "X is not in scope",
1190                 --       we definitely want the former; but we might pick the latter
1191         do { addMessages (head errs_s) ; failM }
1192       else                      -- Add deprecation warnings
1193         mapM_ addMessages warns_s ;
1194
1195     return good_names
1196  }
1197
1198 tcRnRecoverDataCon :: HscEnv -> Ptr () -> IO (Maybe DataCon)
1199 tcRnRecoverDataCon hsc_env ptr
1200   = initTcPrintErrors hsc_env iNTERACTIVE $
1201     setInteractiveContext hsc_env (hsc_IC hsc_env) $ do
1202         name <- dataConInfoPtrToName ptr
1203         tcLookupDataCon name
1204
1205 tcRnLookupName :: HscEnv -> Name -> IO (Maybe TyThing)
1206 tcRnLookupName hsc_env name
1207   = initTcPrintErrors hsc_env iNTERACTIVE $
1208     setInteractiveContext hsc_env (hsc_IC hsc_env) $
1209     tcLookupGlobal name
1210
1211
1212 tcRnGetInfo :: HscEnv
1213             -> Name
1214             -> IO (Maybe (TyThing, Fixity, [Instance]))
1215
1216 -- Used to implemnent :info in GHCi
1217 --
1218 -- Look up a RdrName and return all the TyThings it might be
1219 -- A capitalised RdrName is given to us in the DataName namespace,
1220 -- but we want to treat it as *both* a data constructor
1221 --  *and* as a type or class constructor;
1222 -- hence the call to dataTcOccs, and we return up to two results
1223 tcRnGetInfo hsc_env name
1224   = initTcPrintErrors hsc_env iNTERACTIVE $
1225     let ictxt = hsc_IC hsc_env in
1226     setInteractiveContext hsc_env ictxt $ do
1227
1228         -- Load the interface for all unqualified types and classes
1229         -- That way we will find all the instance declarations
1230         -- (Packages have not orphan modules, and we assume that
1231         --  in the home package all relevant modules are loaded.)
1232     loadUnqualIfaces ictxt
1233
1234     thing  <- tcLookupGlobal name
1235     fixity <- lookupFixityRn name
1236     ispecs <- lookupInsts (icPrintUnqual ictxt) thing
1237     return (thing, fixity, ispecs)
1238
1239 lookupInsts :: PrintUnqualified -> TyThing -> TcM [Instance]
1240 -- Filter the instances by the ones whose tycons (or clases resp)
1241 -- are in scope unqualified.  Otherwise we list a whole lot too many!
1242 lookupInsts print_unqual (AClass cls)
1243   = do  { inst_envs <- tcGetInstEnvs
1244         ; return [ ispec
1245                  | ispec <- classInstances inst_envs cls
1246                  , plausibleDFun print_unqual (instanceDFunId ispec) ] }
1247
1248 lookupInsts print_unqual (ATyCon tc)
1249   = do  { eps <- getEps -- Load all instances for all classes that are
1250                         -- in the type environment (which are all the ones
1251                         -- we've seen in any interface file so far)
1252         ; (pkg_ie, home_ie) <- tcGetInstEnvs    -- Search all
1253         ; return [ ispec
1254                  | ispec <- instEnvElts home_ie ++ instEnvElts pkg_ie
1255                  , let dfun = instanceDFunId ispec
1256                  , relevant dfun
1257                  , plausibleDFun print_unqual dfun ] }
1258   where
1259     relevant df = tc_name `elemNameSet` tyClsNamesOfDFunHead (idType df)
1260     tc_name     = tyConName tc
1261
1262 lookupInsts print_unqual other = return []
1263
1264 plausibleDFun print_unqual dfun -- Dfun involving only names that print unqualified
1265   = all ok (nameSetToList (tyClsNamesOfType (idType dfun)))
1266   where
1267     ok name | isBuiltInSyntax name = True
1268             | isExternalName name  =
1269                 isNothing $ fst print_unqual (nameModule name)
1270                                              (nameOccName name)
1271             | otherwise            = True
1272
1273 loadUnqualIfaces :: InteractiveContext -> TcM ()
1274 -- Load the home module for everything that is in scope unqualified
1275 -- This is so that we can accurately report the instances for
1276 -- something
1277 loadUnqualIfaces ictxt
1278   = initIfaceTcRn $
1279     mapM_ (loadSysInterface doc) (moduleSetElts (mkModuleSet unqual_mods))
1280   where
1281     unqual_mods = [ nameModule name
1282                   | gre <- globalRdrEnvElts (ic_rn_gbl_env ictxt),
1283                     let name = gre_name gre,
1284                     not (isInternalName name),
1285                     isTcOcc (nameOccName name),  -- Types and classes only
1286                     unQualOK gre ]               -- In scope unqualified
1287     doc = ptext SLIT("Need interface for module whose export(s) are in scope unqualified")
1288 #endif /* GHCI */
1289 \end{code}
1290
1291 %************************************************************************
1292 %*                                                                      *
1293                 Degugging output
1294 %*                                                                      *
1295 %************************************************************************
1296
1297 \begin{code}
1298 rnDump :: SDoc -> TcRn ()
1299 -- Dump, with a banner, if -ddump-rn
1300 rnDump doc = do { dumpOptTcRn Opt_D_dump_rn (mkDumpDoc "Renamer" doc) }
1301
1302 tcDump :: TcGblEnv -> TcRn ()
1303 tcDump env
1304  = do { dflags <- getDOpts ;
1305
1306         -- Dump short output if -ddump-types or -ddump-tc
1307         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1308             (dumpTcRn short_dump) ;
1309
1310         -- Dump bindings if -ddump-tc
1311         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump)
1312    }
1313   where
1314     short_dump = pprTcGblEnv env
1315     full_dump  = pprLHsBinds (tcg_binds env)
1316         -- NB: foreign x-d's have undefined's in their types;
1317         --     hence can't show the tc_fords
1318
1319 tcCoreDump mod_guts
1320  = do { dflags <- getDOpts ;
1321         ifM (dopt Opt_D_dump_types dflags || dopt Opt_D_dump_tc dflags)
1322             (dumpTcRn (pprModGuts mod_guts)) ;
1323
1324         -- Dump bindings if -ddump-tc
1325         dumpOptTcRn Opt_D_dump_tc (mkDumpDoc "Typechecker" full_dump) }
1326   where
1327     full_dump = pprCoreBindings (mg_binds mod_guts)
1328
1329 -- It's unpleasant having both pprModGuts and pprModDetails here
1330 pprTcGblEnv :: TcGblEnv -> SDoc
1331 pprTcGblEnv (TcGblEnv { tcg_type_env  = type_env,
1332                         tcg_insts     = insts,
1333                         tcg_fam_insts = fam_insts,
1334                         tcg_rules     = rules,
1335                         tcg_imports   = imports })
1336   = vcat [ ppr_types insts type_env
1337          , ppr_tycons fam_insts type_env
1338          , ppr_insts insts
1339          , ppr_fam_insts fam_insts
1340          , vcat (map ppr rules)
1341          , ppr_gen_tycons (typeEnvTyCons type_env)
1342          , ptext SLIT("Dependent modules:") <+> ppr (eltsUFM (imp_dep_mods imports))
1343          , ptext SLIT("Dependent packages:") <+> ppr (imp_dep_pkgs imports)]
1344
1345 pprModGuts :: ModGuts -> SDoc
1346 pprModGuts (ModGuts { mg_types = type_env,
1347                       mg_rules = rules })
1348   = vcat [ ppr_types [] type_env,
1349            ppr_rules rules ]
1350
1351 ppr_types :: [Instance] -> TypeEnv -> SDoc
1352 ppr_types insts type_env
1353   = text "TYPE SIGNATURES" $$ nest 4 (ppr_sigs ids)
1354   where
1355     dfun_ids = map instanceDFunId insts
1356     ids = [id | id <- typeEnvIds type_env, want_sig id]
1357     want_sig id | opt_PprStyle_Debug = True
1358                 | otherwise          = isLocalId id &&
1359                                        isExternalName (idName id) &&
1360                                        not (id `elem` dfun_ids)
1361         -- isLocalId ignores data constructors, records selectors etc.
1362         -- The isExternalName ignores local dictionary and method bindings
1363         -- that the type checker has invented.  Top-level user-defined things
1364         -- have External names.
1365
1366 ppr_tycons :: [FamInst] -> TypeEnv -> SDoc
1367 ppr_tycons fam_insts type_env
1368   = text "TYPE CONSTRUCTORS" $$ nest 4 (ppr_tydecls tycons)
1369   where
1370     fi_tycons = map famInstTyCon fam_insts
1371     tycons = [tycon | tycon <- typeEnvTyCons type_env, want_tycon tycon]
1372     want_tycon tycon | opt_PprStyle_Debug = True
1373                      | otherwise          = not (isImplicitTyCon tycon) &&
1374                                             isExternalName (tyConName tycon) &&
1375                                             not (tycon `elem` fi_tycons)
1376
1377 ppr_insts :: [Instance] -> SDoc
1378 ppr_insts []     = empty
1379 ppr_insts ispecs = text "INSTANCES" $$ nest 2 (pprInstances ispecs)
1380
1381 ppr_fam_insts :: [FamInst] -> SDoc
1382 ppr_fam_insts []        = empty
1383 ppr_fam_insts fam_insts =
1384   text "FAMILY INSTANCES" $$ nest 2 (pprFamInsts fam_insts)
1385
1386 ppr_sigs :: [Var] -> SDoc
1387 ppr_sigs ids
1388         -- Print type signatures; sort by OccName
1389   = vcat (map ppr_sig (sortLe le_sig ids))
1390   where
1391     le_sig id1 id2 = getOccName id1 <= getOccName id2
1392     ppr_sig id = ppr id <+> dcolon <+> ppr (tidyTopType (idType id))
1393
1394 ppr_tydecls :: [TyCon] -> SDoc
1395 ppr_tydecls tycons
1396         -- Print type constructor info; sort by OccName
1397   = vcat (map ppr_tycon (sortLe le_sig tycons))
1398   where
1399     le_sig tycon1 tycon2 = getOccName tycon1 <= getOccName tycon2
1400     ppr_tycon tycon
1401       | isCoercionTyCon tycon = ptext SLIT("coercion") <+> ppr tycon
1402       | otherwise             = ppr (tyThingToIfaceDecl (ATyCon tycon))
1403
1404 ppr_rules :: [CoreRule] -> SDoc
1405 ppr_rules [] = empty
1406 ppr_rules rs = vcat [ptext SLIT("{-# RULES"),
1407                       nest 4 (pprRules rs),
1408                       ptext SLIT("#-}")]
1409
1410 ppr_gen_tycons []  = empty
1411 ppr_gen_tycons tcs = vcat [ptext SLIT("Tycons with generics:"),
1412                            nest 2 (fsep (map ppr (filter tyConHasGenerics tcs)))]
1413 \end{code}