compiler/typecheck/TcRnTypes.lhs

   1
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP Project, Glasgow University, 1992-2002
   4 %
   5 \begin{code}
   6 module TcRnTypes(
   7         TcRnIf, TcRn, TcM, RnM, IfM, IfL, IfG, -- The monad is opaque outside this module
   8         TcRef,
   9
  10         -- The environment types
  11         Env(..),
  12         TcGblEnv(..), TcLclEnv(..),
  13         IfGblEnv(..), IfLclEnv(..),
  14
  15         -- Ranamer types
  16         ErrCtxt, RecFieldEnv(..),
  17         ImportAvails(..), emptyImportAvails, plusImportAvails,
  18         WhereFrom(..), mkModDeps,
  19
  20         -- Typechecker types
  21         TcTypeEnv, TcTyThing(..), pprTcTyThingCategory,
  22
  23         -- Template Haskell
  24         ThStage(..), topStage, topAnnStage, topSpliceStage,
  25         ThLevel, impLevel, outerLevel, thLevel,
  26
  27         -- Arrows
  28         ArrowCtxt(NoArrowCtxt), newArrowScope, escapeArrowScope,
  29
  30         -- Constraints
  31         Untouchables,
  32         WantedConstraints, emptyWanteds, andWanteds, extendWanteds,
  33         WantedConstraint(..), WantedEvVar(..), wantedEvVarLoc,
  34         wantedEvVarToVar, wantedEvVarPred, splitWanteds,
  35
  36         evVarsToWanteds,
  37         Implication(..),
  38         CtLoc(..), ctLocSpan, ctLocOrigin, setCtLocOrigin,
  39         CtOrigin(..), EqOrigin(..),
  40         WantedLoc, GivenLoc,
  41
  42         SkolemInfo(..),
  43
  44         -- Pretty printing
  45         pprEvVarTheta, pprWantedsWithLocs, pprWantedWithLoc,
  46         pprEvVars, pprEvVarWithType,
  47         pprArising, pprArisingAt,
  48
  49         -- Misc other types
  50         TcId, TcIdSet, TcTyVarBind(..), TcTyVarBinds
  51
  52   ) where
  53
  54 #include "HsVersions.h"
  55
  56 import HsSyn
  57 import HscTypes
  58 import Type
  59 import TcType
  60 import Annotations
  61 import InstEnv
  62 import FamInstEnv
  63 import IOEnv
  64 import RdrName
  65 import Name
  66 import NameEnv
  67 import NameSet
  68 import Var
  69 import VarEnv
  70 import Module
  71 import UniqFM
  72 import SrcLoc
  73 import VarSet
  74 import ErrUtils
  75 import UniqSupply
  76 import BasicTypes
  77 import Bag
  78 import Outputable
  79 import ListSetOps
  80 import FastString
  81 import StaticFlags( opt_ErrorSpans )
  82
  83 import Data.Set (Set)
  84 \end{code}
  85
  86
  87 %************************************************************************
  88 %*                                                                      *
  89                Standard monad definition for TcRn
  90     All the combinators for the monad can be found in TcRnMonad
  91 %*                                                                      *
  92 %************************************************************************
  93
  94 The monad itself has to be defined here, because it is mentioned by ErrCtxt
  95
  96 \begin{code}
  97 type TcRef a     = IORef a
  98 type TcId        = Id                   -- Type may be a TcType  DV: WHAT??????????
  99 type TcIdSet     = IdSet
 100
 101
 102 type TcRnIf a b c = IOEnv (Env a b) c
 103 type IfM lcl a  = TcRnIf IfGblEnv lcl a         -- Iface stuff
 104
 105 type IfG a  = IfM () a                          -- Top level
 106 type IfL a  = IfM IfLclEnv a                    -- Nested
 107 type TcRn a = TcRnIf TcGblEnv TcLclEnv a
 108 type RnM  a = TcRn a            -- Historical
 109 type TcM  a = TcRn a            -- Historical
 110 \end{code}
 111
 112 Representation of type bindings to uninstantiated meta variables used during
 113 constraint solving.
 114
 115 \begin{code}
 116 data TcTyVarBind = TcTyVarBind TcTyVar TcType
 117
 118 type TcTyVarBinds = Bag TcTyVarBind
 119
 120 instance Outputable TcTyVarBind where
 121   ppr (TcTyVarBind tv ty) = ppr tv <+> text ":=" <+> ppr ty
 122 \end{code}
 123
 124
 125 %************************************************************************
 126 %*                                                                      *
 127                 The main environment types
 128 %*                                                                      *
 129 %************************************************************************
 130
 131 \begin{code}
 132 data Env gbl lcl        -- Changes as we move into an expression
 133   = Env {
 134         env_top  :: HscEnv,     -- Top-level stuff that never changes
 135                                 -- Includes all info about imported things
 136
 137         env_us   :: {-# UNPACK #-} !(IORef UniqSupply),
 138                                 -- Unique supply for local varibles
 139
 140         env_gbl  :: gbl,        -- Info about things defined at the top level
 141                                 -- of the module being compiled
 142
 143         env_lcl  :: lcl         -- Nested stuff; changes as we go into
 144     }
 145
 146 -- TcGblEnv describes the top-level of the module at the
 147 -- point at which the typechecker is finished work.
 148 -- It is this structure that is handed on to the desugarer
 149
 150 data TcGblEnv
 151   = TcGblEnv {
 152         tcg_mod     :: Module,         -- ^ Module being compiled
 153         tcg_src     :: HscSource,
 154           -- ^ What kind of module (regular Haskell, hs-boot, ext-core)
 155
 156         tcg_rdr_env :: GlobalRdrEnv,   -- ^ Top level envt; used during renaming
 157         tcg_default :: Maybe [Type],
 158           -- ^ Types used for defaulting. @Nothing@ => no @default@ decl
 159
 160         tcg_fix_env   :: FixityEnv,     -- ^ Just for things in this module
 161         tcg_field_env :: RecFieldEnv,   -- ^ Just for things in this module
 162
 163         tcg_type_env :: TypeEnv,
 164           -- ^ Global type env for the module we are compiling now.  All
 165           -- TyCons and Classes (for this module) end up in here right away,
 166           -- along with their derived constructors, selectors.
 167           --
 168           -- (Ids defined in this module start in the local envt, though they
 169           --  move to the global envt during zonking)
 170
 171         tcg_type_env_var :: TcRef TypeEnv,
 172                 -- Used only to initialise the interface-file
 173                 -- typechecker in initIfaceTcRn, so that it can see stuff
 174                 -- bound in this module when dealing with hi-boot recursions
 175                 -- Updated at intervals (e.g. after dealing with types and classes)
 176
 177         tcg_inst_env     :: InstEnv,
 178           -- ^ Instance envt for /home-package/ modules; Includes the dfuns in
 179           -- tcg_insts
 180         tcg_fam_inst_env :: FamInstEnv, -- ^ Ditto for family instances
 181
 182                 -- Now a bunch of things about this module that are simply
 183                 -- accumulated, but never consulted until the end.
 184                 -- Nevertheless, it's convenient to accumulate them along
 185                 -- with the rest of the info from this module.
 186         tcg_exports :: [AvailInfo],     -- ^ What is exported
 187         tcg_imports :: ImportAvails,
 188           -- ^ Information about what was imported from where, including
 189           -- things bound in this module.
 190
 191         tcg_dus :: DefUses,
 192           -- ^ What is defined in this module and what is used.
 193           -- The latter is used to generate
 194           --
 195           --  (a) version tracking; no need to recompile if these things have
 196           --      not changed version stamp
 197           --
 198           --  (b) unused-import info
 199
 200         tcg_keep :: TcRef NameSet,
 201           -- ^ Locally-defined top-level names to keep alive.
 202           --
 203           -- "Keep alive" means give them an Exported flag, so that the
 204           -- simplifier does not discard them as dead code, and so that they
 205           -- are exposed in the interface file (but not to export to the
 206           -- user).
 207           --
 208           -- Some things, like dict-fun Ids and default-method Ids are "born"
 209           -- with the Exported flag on, for exactly the above reason, but some
 210           -- we only discover as we go.  Specifically:
 211           --
 212           --   * The to/from functions for generic data types
 213           --
 214           --   * Top-level variables appearing free in the RHS of an orphan
 215           --     rule
 216           --
 217           --   * Top-level variables appearing free in a TH bracket
 218
 219         tcg_inst_uses :: TcRef NameSet,
 220           -- ^ Home-package Dfuns actually used.
 221           --
 222           -- Used to generate version dependencies This records usages, rather
 223           -- like tcg_dus, but it has to be a mutable variable so it can be
 224           -- augmented when we look up an instance.  These uses of dfuns are
 225           -- rather like the free variables of the program, but are implicit
 226           -- instead of explicit.
 227
 228         tcg_th_used :: TcRef Bool,
 229           -- ^ @True@ <=> Template Haskell syntax used.
 230           --
 231           -- We need this so that we can generate a dependency on the Template
 232           -- Haskell package, becuase the desugarer is going to emit loads of
 233           -- references to TH symbols.  It's rather like tcg_inst_uses; the
 234           -- reference is implicit rather than explicit, so we have to zap a
 235           -- mutable variable.
 236
 237         tcg_dfun_n  :: TcRef OccSet,
 238           -- ^ Allows us to choose unique DFun names.
 239
 240         -- The next fields accumulate the payload of the module
 241         -- The binds, rules and foreign-decl fiels are collected
 242         -- initially in un-zonked form and are finally zonked in tcRnSrcDecls
 243
 244         tcg_rn_exports :: Maybe [Located (IE Name)],
 245         tcg_rn_imports :: [LImportDecl Name],
 246                 -- Keep the renamed imports regardless.  They are not
 247                 -- voluminous and are needed if you want to report unused imports
 248
 249         tcg_used_rdrnames :: TcRef (Set RdrName),
 250                 -- The set of used *imported* (not locally-defined) RdrNames
 251                 -- Used only to report unused import declarations
 252
 253         tcg_rn_decls :: Maybe (HsGroup Name),
 254           -- ^ Renamed decls, maybe.  @Nothing@ <=> Don't retain renamed
 255           -- decls.
 256
 257         tcg_ev_binds  :: Bag EvBind,        -- Top-level evidence bindings
 258         tcg_binds     :: LHsBinds Id,       -- Value bindings in this module
 259         tcg_sigs      :: NameSet,           -- ...Top-level names that *lack* a signature
 260         tcg_warns     :: Warnings,          -- ...Warnings and deprecations
 261         tcg_anns      :: [Annotation],      -- ...Annotations
 262         tcg_insts     :: [Instance],        -- ...Instances
 263         tcg_fam_insts :: [FamInst],         -- ...Family instances
 264         tcg_rules     :: [LRuleDecl Id],    -- ...Rules
 265         tcg_fords     :: [LForeignDecl Id], -- ...Foreign import & exports
 266
 267         tcg_doc_hdr   :: Maybe LHsDocString, -- ^ Maybe Haddock header docs
 268         tcg_hpc       :: AnyHpcUsage,        -- ^ @True@ if any part of the
 269                                              --  prog uses hpc instrumentation.
 270
 271         tcg_main      :: Maybe Name          -- ^ The Name of the main
 272                                              -- function, if this module is
 273                                              -- the main module.
 274     }
 275
 276 data RecFieldEnv
 277   = RecFields (NameEnv [Name])  -- Maps a constructor name *in this module*
 278                                 -- to the fields for that constructor
 279               NameSet           -- Set of all fields declared *in this module*;
 280                                 -- used to suppress name-shadowing complaints
 281                                 -- when using record wild cards
 282                                 -- E.g.  let fld = e in C {..}
 283         -- This is used when dealing with ".." notation in record
 284         -- construction and pattern matching.
 285         -- The FieldEnv deals *only* with constructors defined in *this*
 286         -- module.  For imported modules, we get the same info from the
 287         -- TypeEnv
 288 \end{code}
 289
 290 %************************************************************************
 291 %*                                                                      *
 292                 The interface environments
 293               Used when dealing with IfaceDecls
 294 %*                                                                      *
 295 %************************************************************************
 296
 297 \begin{code}
 298 data IfGblEnv
 299   = IfGblEnv {
 300         -- The type environment for the module being compiled,
 301         -- in case the interface refers back to it via a reference that
 302         -- was originally a hi-boot file.
 303         -- We need the module name so we can test when it's appropriate
 304         -- to look in this env.
 305         if_rec_types :: Maybe (Module, IfG TypeEnv)
 306                 -- Allows a read effect, so it can be in a mutable
 307                 -- variable; c.f. handling the external package type env
 308                 -- Nothing => interactive stuff, no loops possible
 309     }
 310
 311 data IfLclEnv
 312   = IfLclEnv {
 313         -- The module for the current IfaceDecl
 314         -- So if we see   f = \x -> x
 315         -- it means M.f = \x -> x, where M is the if_mod
 316         if_mod :: Module,
 317
 318         -- The field is used only for error reporting
 319         -- if (say) there's a Lint error in it
 320         if_loc :: SDoc,
 321                 -- Where the interface came from:
 322                 --      .hi file, or GHCi state, or ext core
 323                 -- plus which bit is currently being examined
 324
 325         if_tv_env  :: UniqFM TyVar,     -- Nested tyvar bindings
 326         if_id_env  :: UniqFM Id         -- Nested id binding
 327     }
 328 \end{code}
 329
 330
 331 %************************************************************************
 332 %*                                                                      *
 333                 The local typechecker environment
 334 %*                                                                      *
 335 %************************************************************************
 336
 337 The Global-Env/Local-Env story
 338 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 339 During type checking, we keep in the tcg_type_env
 340         * All types and classes
 341         * All Ids derived from types and classes (constructors, selectors)
 342
 343 At the end of type checking, we zonk the local bindings,
 344 and as we do so we add to the tcg_type_env
 345         * Locally defined top-level Ids
 346
 347 Why?  Because they are now Ids not TcIds.  This final GlobalEnv is
 348         a) fed back (via the knot) to typechecking the
 349            unfoldings of interface signatures
 350         b) used in the ModDetails of this module
 351
 352 \begin{code}
 353 data TcLclEnv           -- Changes as we move inside an expression
 354                         -- Discarded after typecheck/rename; not passed on to desugarer
 355   = TcLclEnv {
 356         tcl_loc  :: SrcSpan,            -- Source span
 357         tcl_ctxt :: [ErrCtxt],          -- Error context, innermost on top
 358         tcl_errs :: TcRef Messages,     -- Place to accumulate errors
 359
 360         tcl_th_ctxt    :: ThStage,            -- Template Haskell context
 361         tcl_arrow_ctxt :: ArrowCtxt,          -- Arrow-notation context
 362
 363         tcl_rdr :: LocalRdrEnv,         -- Local name envt
 364                 -- Maintained during renaming, of course, but also during
 365                 -- type checking, solely so that when renaming a Template-Haskell
 366                 -- splice we have the right environment for the renamer.
 367                 --
 368                 --   Does *not* include global name envt; may shadow it
 369                 --   Includes both ordinary variables and type variables;
 370                 --   they are kept distinct because tyvar have a different
 371                 --   occurrence contructor (Name.TvOcc)
 372                 -- We still need the unsullied global name env so that
 373                 --   we can look up record field names
 374
 375         tcl_env  :: TcTypeEnv,    -- The local type environment: Ids and
 376                                   -- TyVars defined in this module
 377
 378         tcl_tyvars :: TcRef TcTyVarSet, -- The "global tyvars"
 379                         -- Namely, the in-scope TyVars bound in tcl_env,
 380                         -- plus the tyvars mentioned in the types of Ids bound
 381                         -- in tcl_lenv.
 382                         -- Why mutable? see notes with tcGetGlobalTyVars
 383
 384         tcl_lie   :: TcRef WantedConstraints,    -- Place to accumulate type constraints
 385         tcl_untch :: Untouchables                -- Untouchables
 386     }
 387
 388 type TcTypeEnv = NameEnv TcTyThing
 389
 390
 391 {- Note [Given Insts]
 392    ~~~~~~~~~~~~~~~~~~
 393 Because of GADTs, we have to pass inwards the Insts provided by type signatures
 394 and existential contexts. Consider
 395         data T a where { T1 :: b -> b -> T [b] }
 396         f :: Eq a => T a -> Bool
 397         f (T1 x y) = [x]==[y]
 398
 399 The constructor T1 binds an existential variable 'b', and we need Eq [b].
 400 Well, we have it, because Eq a refines to Eq [b], but we can only spot that if we
 401 pass it inwards.
 402
 403 -}
 404
 405 ---------------------------
 406 -- Template Haskell stages and levels
 407 ---------------------------
 408
 409 data ThStage    -- See Note [Template Haskell state diagram] in TcSplice
 410   = Splice      -- Top-level splicing
 411                 -- This code will be run *at compile time*;
 412                 --   the result replaces the splice
 413                 -- Binding level = 0
 414
 415   | Comp        -- Ordinary Haskell code
 416                 -- Binding level = 1
 417
 418   | Brack                       -- Inside brackets
 419       ThStage                   --   Binding level = level(stage) + 1
 420       (TcRef [PendingSplice])   --   Accumulate pending splices here
 421       (TcRef WantedConstraints) --     and type constraints here
 422
 423 topStage, topAnnStage, topSpliceStage :: ThStage
 424 topStage       = Comp
 425 topAnnStage    = Splice
 426 topSpliceStage = Splice
 427
 428 instance Outputable ThStage where
 429    ppr Splice        = text "Splice"
 430    ppr Comp          = text "Comp"
 431    ppr (Brack s _ _) = text "Brack" <> parens (ppr s)
 432
 433 type ThLevel = Int
 434         -- See Note [Template Haskell levels] in TcSplice
 435         -- Incremented when going inside a bracket,
 436         -- decremented when going inside a splice
 437         -- NB: ThLevel is one greater than the 'n' in Fig 2 of the
 438         --     original "Template meta-programming for Haskell" paper
 439
 440 impLevel, outerLevel :: ThLevel
 441 impLevel = 0    -- Imported things; they can be used inside a top level splice
 442 outerLevel = 1  -- Things defined outside brackets
 443 -- NB: Things at level 0 are not *necessarily* imported.
 444 --      eg  $( \b -> ... )   here b is bound at level 0
 445 --
 446 -- For example:
 447 --      f = ...
 448 --      g1 = $(map ...)         is OK
 449 --      g2 = $(f ...)           is not OK; because we havn't compiled f yet
 450
 451 thLevel :: ThStage -> ThLevel
 452 thLevel Splice        = 0
 453 thLevel Comp          = 1
 454 thLevel (Brack s _ _) = thLevel s + 1
 455
 456 ---------------------------
 457 -- Arrow-notation context
 458 ---------------------------
 459
 460 {-
 461 In arrow notation, a variable bound by a proc (or enclosed let/kappa)
 462 is not in scope to the left of an arrow tail (-<) or the head of (|..|).
 463 For example
 464
 465         proc x -> (e1 -< e2)
 466
 467 Here, x is not in scope in e1, but it is in scope in e2.  This can get
 468 a bit complicated:
 469
 470         let x = 3 in
 471         proc y -> (proc z -> e1) -< e2
 472
 473 Here, x and z are in scope in e1, but y is not.  We implement this by
 474 recording the environment when passing a proc (using newArrowScope),
 475 and returning to that (using escapeArrowScope) on the left of -< and the
 476 head of (|..|).
 477 -}
 478
 479 data ArrowCtxt
 480   = NoArrowCtxt
 481   | ArrowCtxt (Env TcGblEnv TcLclEnv)
 482
 483 -- Record the current environment (outside a proc)
 484 newArrowScope :: TcM a -> TcM a
 485 newArrowScope
 486   = updEnv $ \env ->
 487         env { env_lcl = (env_lcl env) { tcl_arrow_ctxt = ArrowCtxt env } }
 488
 489 -- Return to the stored environment (from the enclosing proc)
 490 escapeArrowScope :: TcM a -> TcM a
 491 escapeArrowScope
 492   = updEnv $ \ env -> case tcl_arrow_ctxt (env_lcl env) of
 493         NoArrowCtxt -> env
 494         ArrowCtxt env' -> env'
 495
 496 ---------------------------
 497 -- TcTyThing
 498 ---------------------------
 499
 500 data TcTyThing
 501   = AGlobal TyThing             -- Used only in the return type of a lookup
 502
 503   | ATcId   {           -- Ids defined in this module; may not be fully zonked
 504         tct_id    :: TcId,
 505         tct_level :: ThLevel }
 506
 507   | ATyVar  Name TcType         -- The type to which the lexically scoped type vaiable
 508                                 -- is currently refined. We only need the Name
 509                                 -- for error-message purposes; it is the corresponding
 510                                 -- Name in the domain of the envt
 511
 512   | AThing  TcKind              -- Used temporarily, during kind checking, for the
 513                                 --      tycons and clases in this recursive group
 514
 515 instance Outputable TcTyThing where     -- Debugging only
 516    ppr (AGlobal g)      = pprTyThing g
 517    ppr elt@(ATcId {})   = text "Identifier" <>
 518                           brackets (ppr (tct_id elt) <> dcolon
 519                                  <> ppr (varType (tct_id elt)) <> comma
 520                                  <+> ppr (tct_level elt))
 521    ppr (ATyVar tv _)    = text "Type variable" <+> quotes (ppr tv)
 522    ppr (AThing k)       = text "AThing" <+> ppr k
 523
 524 pprTcTyThingCategory :: TcTyThing -> SDoc
 525 pprTcTyThingCategory (AGlobal thing) = pprTyThingCategory thing
 526 pprTcTyThingCategory (ATyVar {})     = ptext (sLit "Type variable")
 527 pprTcTyThingCategory (ATcId {})      = ptext (sLit "Local identifier")
 528 pprTcTyThingCategory (AThing {})     = ptext (sLit "Kinded thing")
 529 \end{code}
 530
 531 \begin{code}
 532 type ErrCtxt = (Bool, TidyEnv -> TcM (TidyEnv, Message))
 533         -- Monadic so that we have a chance
 534         -- to deal with bound type variables just before error
 535         -- message construction
 536
 537         -- Bool:  True <=> this is a landmark context; do not
 538         --                 discard it when trimming for display
 539 \end{code}
 540
 541
 542 %************************************************************************
 543 %*                                                                      *
 544         Operations over ImportAvails
 545 %*                                                                      *
 546 %************************************************************************
 547
 548 \begin{code}
 549 -- | 'ImportAvails' summarises what was imported from where, irrespective of
 550 -- whether the imported things are actually used or not.  It is used:
 551 --
 552 --  * when processing the export list,
 553 --
 554 --  * when constructing usage info for the interface file,
 555 --
 556 --  * to identify the list of directly imported modules for initialisation
 557 --    purposes and for optimised overlap checking of family instances,
 558 --
 559 --  * when figuring out what things are really unused
 560 --
 561 data ImportAvails
 562    = ImportAvails {
 563         imp_mods :: ModuleEnv [(ModuleName, Bool, SrcSpan)],
 564           -- ^ Domain is all directly-imported modules
 565           -- The 'ModuleName' is what the module was imported as, e.g. in
 566           -- @
 567           --     import Foo as Bar
 568           -- @
 569           -- it is @Bar@.
 570           --
 571           -- The 'Bool' means:
 572           --
 573           --  - @True@ => import was @import Foo ()@
 574           --
 575           --  - @False@ => import was some other form
 576           --
 577           -- Used
 578           --
 579           --   (a) to help construct the usage information in the interface
 580           --       file; if we import somethign we need to recompile if the
 581           --       export version changes
 582           --
 583           --   (b) to specify what child modules to initialise
 584           --
 585           -- We need a full ModuleEnv rather than a ModuleNameEnv here,
 586           -- because we might be importing modules of the same name from
 587           -- different packages. (currently not the case, but might be in the
 588           -- future).
 589
 590         imp_dep_mods :: ModuleNameEnv (ModuleName, IsBootInterface),
 591           -- ^ Home-package modules needed by the module being compiled
 592           --
 593           -- It doesn't matter whether any of these dependencies
 594           -- are actually /used/ when compiling the module; they
 595           -- are listed if they are below it at all.  For
 596           -- example, suppose M imports A which imports X.  Then
 597           -- compiling M might not need to consult X.hi, but X
 598           -- is still listed in M's dependencies.
 599
 600         imp_dep_pkgs :: [PackageId],
 601           -- ^ Packages needed by the module being compiled, whether directly,
 602           -- or via other modules in this package, or via modules imported
 603           -- from other packages.
 604
 605         imp_orphs :: [Module],
 606           -- ^ Orphan modules below us in the import tree (and maybe including
 607           -- us for imported modules)
 608
 609         imp_finsts :: [Module]
 610           -- ^ Family instance modules below us in the import tree (and maybe
 611           -- including us for imported modules)
 612       }
 613
 614 mkModDeps :: [(ModuleName, IsBootInterface)]
 615           -> ModuleNameEnv (ModuleName, IsBootInterface)
 616 mkModDeps deps = foldl add emptyUFM deps
 617                where
 618                  add env elt@(m,_) = addToUFM env m elt
 619
 620 emptyImportAvails :: ImportAvails
 621 emptyImportAvails = ImportAvails { imp_mods     = emptyModuleEnv,
 622                                    imp_dep_mods = emptyUFM,
 623                                    imp_dep_pkgs = [],
 624                                    imp_orphs    = [],
 625                                    imp_finsts   = [] }
 626
 627 plusImportAvails ::  ImportAvails ->  ImportAvails ->  ImportAvails
 628 plusImportAvails
 629   (ImportAvails { imp_mods = mods1,
 630                   imp_dep_mods = dmods1, imp_dep_pkgs = dpkgs1,
 631                   imp_orphs = orphs1, imp_finsts = finsts1 })
 632   (ImportAvails { imp_mods = mods2,
 633                   imp_dep_mods = dmods2, imp_dep_pkgs = dpkgs2,
 634                   imp_orphs = orphs2, imp_finsts = finsts2 })
 635   = ImportAvails { imp_mods     = plusModuleEnv_C (++) mods1 mods2,
 636                    imp_dep_mods = plusUFM_C plus_mod_dep dmods1 dmods2,
 637                    imp_dep_pkgs = dpkgs1 `unionLists` dpkgs2,
 638                    imp_orphs    = orphs1 `unionLists` orphs2,
 639                    imp_finsts   = finsts1 `unionLists` finsts2 }
 640   where
 641     plus_mod_dep (m1, boot1) (m2, boot2)
 642         = WARN( not (m1 == m2), (ppr m1 <+> ppr m2) $$ (ppr boot1 <+> ppr boot2) )
 643                 -- Check mod-names match
 644           (m1, boot1 && boot2)  -- If either side can "see" a non-hi-boot interface, use that
 645 \end{code}
 646
 647 %************************************************************************
 648 %*                                                                      *
 649 \subsection{Where from}
 650 %*                                                                      *
 651 %************************************************************************
 652
 653 The @WhereFrom@ type controls where the renamer looks for an interface file
 654
 655 \begin{code}
 656 data WhereFrom
 657   = ImportByUser IsBootInterface        -- Ordinary user import (perhaps {-# SOURCE #-})
 658   | ImportBySystem                      -- Non user import.
 659
 660 instance Outputable WhereFrom where
 661   ppr (ImportByUser is_boot) | is_boot     = ptext (sLit "{- SOURCE -}")
 662                              | otherwise   = empty
 663   ppr ImportBySystem                       = ptext (sLit "{- SYSTEM -}")
 664 \end{code}
 665
 666
 667 %************************************************************************
 668 %*                                                                      *
 669                 Wanted constraints
 670
 671      These are forced to be in TcRnTypes because
 672            TcLclEnv mentions WantedConstraints
 673            WantedConstraint mentions CtLoc
 674            CtLoc mentions ErrCtxt
 675            ErrCtxt mentions TcM
 676 %*                                                                      *
 677 v%************************************************************************
 678
 679 \begin{code}
 680 type Untouchables = TcTyVarSet  -- All MetaTyVars
 681
 682 type WantedConstraints = Bag WantedConstraint
 683
 684 data WantedConstraint
 685   = WcEvVar  WantedEvVar
 686   | WcImplic Implication
 687   -- ToDo: add literals, methods
 688
 689 -- EvVar defined in module Var.lhs:
 690 -- Evidence variables include all *quantifiable* constraints
 691 --   dictionaries
 692 --   implicit parameters
 693 --   coercion variables
 694
 695 data WantedEvVar   -- The sort of constraint over which one can lambda-abstract
 696    = WantedEvVar
 697          EvVar       -- The variable itself; make a binding for it please
 698          WantedLoc   -- How the constraint arose in the first place
 699                      -- (used for error messages only)
 700
 701 type WantedLoc = CtLoc CtOrigin
 702 type GivenLoc  = CtLoc SkolemInfo
 703
 704 data Implication
 705   = Implic {
 706       ic_untch :: Untouchables, -- Untouchables: unification variables
 707                                   -- free in the environment
 708       ic_env   :: TcTypeEnv,    -- The type environment
 709                                   -- Used only when generating error messages
 710           -- Generally, ic_untch is a superset of tvsof(ic_env)
 711           -- However, we don't zonk ic_env when zonking the Implication
 712           -- Instead we do that when generating a skolem-escape error message
 713
 714       ic_skols  :: TcTyVarSet,   -- Introduced skolems
 715                                  -- See Note [Skolems in an implication]
 716
 717       ic_scoped :: [TcTyVar],    -- List of scoped variables to be unified
 718                                  -- bijectively to a subset of ic_tyvars
 719                                  -- Note [Scoped pattern variable]
 720
 721       ic_given  :: [EvVar],      -- Given evidence variables
 722                                  --   (order does not matter)
 723
 724       ic_wanted :: WantedConstraints,    -- Wanted constraints
 725
 726       ic_binds  :: EvBindsVar,   -- Points to the place to fill in the
 727                                  -- abstraction and bindings
 728
 729       ic_loc   :: GivenLoc }
 730
 731 evVarsToWanteds :: WantedLoc -> [EvVar] -> WantedConstraints
 732 evVarsToWanteds loc evs = listToBag [WcEvVar (WantedEvVar ev loc) | ev <- evs]
 733
 734 wantedEvVarLoc :: WantedEvVar -> WantedLoc
 735 wantedEvVarLoc (WantedEvVar _ loc) = loc
 736
 737 wantedEvVarToVar :: WantedEvVar -> EvVar
 738 wantedEvVarToVar (WantedEvVar ev _) = ev
 739
 740 wantedEvVarPred :: WantedEvVar -> PredType
 741 wantedEvVarPred (WantedEvVar ev _)  = evVarPred ev
 742
 743 splitWanteds :: WantedConstraints -> (Bag WantedEvVar, Bag Implication)
 744 splitWanteds wanted = partitionBagWith pick wanted
 745   where
 746     pick (WcEvVar v)  = Left v
 747     pick (WcImplic i) = Right i
 748 \end{code}
 749
 750 Note [Skolems in an implication]
 751 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 752 The skolems in an implication are not there to perform a skolem escape
 753 check.  That happens because all the environment variables are in the
 754 untouchables, and therefore cannot be unified with anything at all,
 755 let alone the skolems.
 756
 757 Instead, ic_skols is used only when considering floating a constraint
 758 outside the implication in TcSimplify.floatEqualities or
 759 TcSimplify.approximateImplications
 760
 761 Note [Scoped pattern variables]
 762 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 763    data T where K :: forall a,b. a -> b -> T
 764
 765    ...(case x of K (p::c) (q::d) -> ...)...
 766
 767 We create fresh MetaTvs for c,d, and later check that they are
 768 bound bijectively to the skolems we created for a,b.  So the
 769 implication constraint looks like
 770             ic_skols  = {a',b'}  -- Skolem tvs created from a,b
 771             ic_scoped = {c',d'}  -- Meta tvs created from c,d
 772
 773 \begin{code}
 774 emptyWanteds :: WantedConstraints
 775 emptyWanteds = emptyBag
 776
 777 andWanteds :: WantedConstraints -> WantedConstraints -> WantedConstraints
 778 andWanteds = unionBags
 779
 780 extendWanteds :: WantedConstraints -> WantedConstraint -> WantedConstraints
 781 extendWanteds = snocBag
 782 \end{code}
 783
 784 \begin{code}
 785 pprEvVars :: [EvVar] -> SDoc    -- Print with their types
 786 pprEvVars ev_vars = vcat (map pprEvVarWithType ev_vars)
 787
 788 pprEvVarTheta :: [EvVar] -> SDoc
 789 pprEvVarTheta ev_vars = pprTheta (map evVarPred ev_vars)
 790
 791 pprEvVarWithType :: EvVar -> SDoc
 792 pprEvVarWithType v = ppr v <+> dcolon <+> pprPred (evVarPred v)
 793
 794 pprWantedsWithLocs :: Bag WantedConstraint -> SDoc
 795 pprWantedsWithLocs = foldrBag (($$) . pprWantedWithLoc) empty
 796
 797 pprWantedWithLoc :: WantedConstraint -> SDoc
 798 pprWantedWithLoc (WcImplic i) = ppr i
 799 pprWantedWithLoc (WcEvVar v)  = pprWantedEvVarWithLoc v
 800
 801 instance Outputable WantedConstraint where
 802   ppr (WcEvVar v)  = ppr v
 803   ppr (WcImplic i) = ppr i
 804
 805 -- Adding -ferror-spans makes the output more voluminous
 806 instance Outputable WantedEvVar where
 807   ppr wev | opt_ErrorSpans = pprWantedEvVarWithLoc wev
 808           | otherwise      = pprWantedEvVar wev
 809
 810 pprWantedEvVarWithLoc, pprWantedEvVar :: WantedEvVar -> SDoc
 811 pprWantedEvVarWithLoc (WantedEvVar v loc) = hang (pprEvVarWithType v)
 812                                                2 (pprArisingAt loc)
 813 pprWantedEvVar        (WantedEvVar v _)   = pprEvVarWithType v
 814
 815 instance Outputable Implication where
 816   ppr (Implic { ic_untch = untch, ic_skols = skols, ic_given = given
 817               , ic_wanted = wanted, ic_binds = binds, ic_loc = loc })
 818    = ptext (sLit "Implic") <+> braces
 819      (sep [ ptext (sLit "Untouchables = ") <+> ppr untch
 820           , ptext (sLit "Skolems = ") <+> ppr skols
 821           , ptext (sLit "Given = ") <+> pprEvVars given
 822           , ptext (sLit "Wanted = ") <+> ppr wanted
 823           , ptext (sLit "Binds = ") <+> ppr binds
 824           , pprSkolInfo (ctLocOrigin loc)
 825           , ppr (ctLocSpan loc) ])
 826 \end{code}
 827
 828 %************************************************************************
 829 %*                                                                      *
 830             CtLoc, CtOrigin
 831 %*                                                                      *
 832 %************************************************************************
 833
 834 The 'CtLoc' and 'CtOrigin' types gives information about where a
 835 *wanted constraint* came from.  This is important for decent error
 836 message reporting because dictionaries don't appear in the original
 837 source code.  Doubtless this type will evolve...
 838
 839 \begin{code}
 840 -------------------------------------------
 841 data CtLoc orig = CtLoc orig SrcSpan [ErrCtxt]
 842
 843 ctLocSpan :: CtLoc o -> SrcSpan
 844 ctLocSpan (CtLoc _ s _) = s
 845
 846 ctLocOrigin :: CtLoc o -> o
 847 ctLocOrigin (CtLoc o _ _) = o
 848
 849 setCtLocOrigin :: CtLoc o -> o' -> CtLoc o'
 850 setCtLocOrigin (CtLoc _ s c) o = CtLoc o s c
 851
 852 pprArising :: CtOrigin -> SDoc
 853 pprArising (TypeEqOrigin {}) = empty
 854 pprArising orig              = text "arising from" <+> ppr orig
 855
 856 pprArisingAt :: CtLoc CtOrigin -> SDoc
 857 pprArisingAt (CtLoc o s _) = sep [pprArising o, text "at" <+> ppr s]
 858
 859 -------------------------------------------
 860 -- CtOrigin gives the origin of *wanted* constraints
 861 data CtOrigin
 862   = OccurrenceOf Name           -- Occurrence of an overloaded identifier
 863   | AppOrigin                   -- An application of some kind
 864
 865   | SpecPragOrigin Name         -- Specialisation pragma for identifier
 866
 867   | TypeEqOrigin EqOrigin
 868
 869   | IPOccOrigin  (IPName Name)  -- Occurrence of an implicit parameter
 870
 871   | LiteralOrigin (HsOverLit Name)      -- Occurrence of a literal
 872   | NegateOrigin                        -- Occurrence of syntactic negation
 873
 874   | ArithSeqOrigin (ArithSeqInfo Name) -- [x..], [x..y] etc
 875   | PArrSeqOrigin  (ArithSeqInfo Name) -- [:x..y:] and [:x,y..z:]
 876   | SectionOrigin
 877   | TupleOrigin                        -- (..,..)
 878   | ExprSigOrigin       -- e :: ty
 879   | PatSigOrigin        -- p :: ty
 880   | PatOrigin           -- Instantiating a polytyped pattern at a constructor
 881   | RecordUpdOrigin
 882   | ViewPatOrigin
 883
 884   | ScOrigin            -- Typechecking superclasses of an instance declaration
 885   | DerivOrigin         -- Typechecking deriving
 886   | StandAloneDerivOrigin -- Typechecking stand-alone deriving
 887   | DefaultOrigin       -- Typechecking a default decl
 888   | DoOrigin            -- Arising from a do expression
 889   | ProcOrigin          -- Arising from a proc expression
 890   | AnnOrigin           -- An annotation
 891
 892 data EqOrigin
 893   = UnifyOrigin
 894        { uo_actual   :: TcType
 895        , uo_expected :: TcType }
 896
 897 instance Outputable CtOrigin where
 898   ppr orig = pprO orig
 899
 900 pprO :: CtOrigin -> SDoc
 901 pprO (OccurrenceOf name)   = hsep [ptext (sLit "a use of"), quotes (ppr name)]
 902 pprO AppOrigin             = ptext (sLit "an application")
 903 pprO (SpecPragOrigin name) = hsep [ptext (sLit "a specialisation pragma for"), quotes (ppr name)]
 904 pprO (IPOccOrigin name)    = hsep [ptext (sLit "a use of implicit parameter"), quotes (ppr name)]
 905 pprO RecordUpdOrigin       = ptext (sLit "a record update")
 906 pprO ExprSigOrigin         = ptext (sLit "an expression type signature")
 907 pprO PatSigOrigin          = ptext (sLit "a pattern type signature")
 908 pprO PatOrigin             = ptext (sLit "a pattern")
 909 pprO ViewPatOrigin         = ptext (sLit "a view pattern")
 910 pprO (LiteralOrigin lit)   = hsep [ptext (sLit "the literal"), quotes (ppr lit)]
 911 pprO (ArithSeqOrigin seq)  = hsep [ptext (sLit "the arithmetic sequence"), quotes (ppr seq)]
 912 pprO (PArrSeqOrigin seq)   = hsep [ptext (sLit "the parallel array sequence"), quotes (ppr seq)]
 913 pprO SectionOrigin         = ptext (sLit "an operator section")
 914 pprO TupleOrigin           = ptext (sLit "a tuple")
 915 pprO NegateOrigin          = ptext (sLit "a use of syntactic negation")
 916 pprO ScOrigin              = ptext (sLit "the superclasses of an instance declaration")
 917 pprO DerivOrigin           = ptext (sLit "the 'deriving' clause of a data type declaration")
 918 pprO StandAloneDerivOrigin = ptext (sLit "a 'deriving' declaration")
 919 pprO DefaultOrigin         = ptext (sLit "a 'default' declaration")
 920 pprO DoOrigin              = ptext (sLit "a do statement")
 921 pprO ProcOrigin            = ptext (sLit "a proc expression")
 922 pprO (TypeEqOrigin eq)     = ptext (sLit "an equality") <+> ppr eq
 923 pprO AnnOrigin             = ptext (sLit "an annotation")
 924
 925 instance Outputable EqOrigin where
 926   ppr (UnifyOrigin t1 t2) = ppr t1 <+> char '~' <+> ppr t2
 927 \end{code}