compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls, tcIdxTyInstDecl
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), NewOrData(..), ResType(..),
  15                           tyClDeclTyVars, isSynDecl, isClassDecl, isIdxTyDecl,
  16                           isKindSigDecl, hsConArgs, LTyClDecl, tcdName,
  17                           hsTyVarName, LHsTyVarBndr, LHsType, HsType(..),
  18                           mkHsAppTy
  19                         )
  20 import HsTypes          ( HsBang(..), getBangStrictness, hsLTyVarNames )
  21 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  22 import HscTypes         ( implicitTyThings, ModDetails )
  23 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  24                           mkDataTyConRhs, mkNewTyConRhs )
  25 import TcRnMonad
  26 import TcEnv            ( TyThing(..),
  27                           tcLookupLocated, tcLookupLocatedGlobal,
  28                           tcExtendGlobalEnv, tcExtendKindEnv,
  29                           tcExtendKindEnvTvs, newFamInstTyConName,
  30                           tcExtendRecEnv, tcLookupTyVar, tcLookupLocatedTyCon )
  31 import TcTyDecls        ( calcRecFlags, calcClassCycles, calcSynCycles )
  32 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  33 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  34                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  35                           kcHsSigType, tcHsBangType, tcLHsConResTy,
  36                           tcDataKindSig, kcCheckHsType )
  37 import TcMType          ( newKindVar, checkValidTheta, checkValidType,
  38                           -- checkFreeness,
  39                           UserTypeCtxt(..), SourceTyCtxt(..) )
  40 import TcType           ( TcKind, TcType, Type, tyVarsOfType, mkPhiTy,
  41                           mkArrowKind, liftedTypeKind, mkTyVarTys,
  42                           tcSplitSigmaTy, tcEqTypes, tcGetTyVar_maybe )
  43 import Type             ( PredType(..), splitTyConApp_maybe, mkTyVarTy,
  44                           newTyConInstRhs, isLiftedTypeKind, Kind,
  45                           splitKindFunTys, mkArrowKinds
  46                           -- pprParendType, pprThetaArrow
  47                         )
  48 import Generics         ( validGenericMethodType, canDoGenerics )
  49 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  50 import TyCon            ( TyCon, AlgTyConRhs( AbstractTyCon, OpenDataTyCon,
  51                                               OpenNewTyCon ),
  52                           SynTyConRhs( OpenSynTyCon, SynonymTyCon ),
  53                           tyConDataCons, mkForeignTyCon, isProductTyCon,
  54                           isRecursiveTyCon, isOpenTyCon,
  55                           tyConStupidTheta, synTyConRhs, isSynTyCon, tyConName,
  56                           isNewTyCon, isDataTyCon, tyConKind,
  57                           setTyConArgPoss )
  58 import DataCon          ( DataCon, dataConUserType, dataConName,
  59                           dataConFieldLabels, dataConTyCon, dataConAllTyVars,
  60                           dataConFieldType, dataConResTys )
  61 import Var              ( TyVar, idType, idName )
  62 import VarSet           ( elemVarSet, mkVarSet )
  63 import Name             ( Name, getSrcLoc )
  64 import Outputable
  65 import Maybe            ( isJust, fromJust, isNothing, catMaybes )
  66 import Maybes           ( expectJust )
  67 import Monad            ( unless )
  68 import Unify            ( tcMatchTys, tcMatchTyX )
  69 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  70 import List             ( partition, elemIndex )
  71 import SrcLoc           ( Located(..), unLoc, getLoc, srcLocSpan,
  72                           srcSpanStart )
  73 import ListSetOps       ( equivClasses, minusList )
  74 import Digraph          ( SCC(..) )
  75 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics,
  76                                    Opt_UnboxStrictFields, Opt_IndexedTypes ) )
  77 \end{code}
  78
  79
  80 %************************************************************************
  81 %*                                                                      *
  82 \subsection{Type checking for type and class declarations}
  83 %*                                                                      *
  84 %************************************************************************
  85
  86 Dealing with a group
  87 ~~~~~~~~~~~~~~~~~~~~
  88 Consider a mutually-recursive group, binding
  89 a type constructor T and a class C.
  90
  91 Step 1:         getInitialKind
  92         Construct a KindEnv by binding T and C to a kind variable
  93
  94 Step 2:         kcTyClDecl
  95         In that environment, do a kind check
  96
  97 Step 3: Zonk the kinds
  98
  99 Step 4:         buildTyConOrClass
 100         Construct an environment binding T to a TyCon and C to a Class.
 101         a) Their kinds comes from zonking the relevant kind variable
 102         b) Their arity (for synonyms) comes direct from the decl
 103         c) The funcional dependencies come from the decl
 104         d) The rest comes a knot-tied binding of T and C, returned from Step 4
 105         e) The variances of the tycons in the group is calculated from
 106                 the knot-tied stuff
 107
 108 Step 5:         tcTyClDecl1
 109         In this environment, walk over the decls, constructing the TyCons and Classes.
 110         This uses in a strict way items (a)-(c) above, which is why they must
 111         be constructed in Step 4. Feed the results back to Step 4.
 112         For this step, pass the is-recursive flag as the wimp-out flag
 113         to tcTyClDecl1.
 114
 115
 116 Step 6:         Extend environment
 117         We extend the type environment with bindings not only for the TyCons and Classes,
 118         but also for their "implicit Ids" like data constructors and class selectors
 119
 120 Step 7:         checkValidTyCl
 121         For a recursive group only, check all the decls again, just
 122         to check all the side conditions on validity.  We could not
 123         do this before because we were in a mutually recursive knot.
 124
 125 Identification of recursive TyCons
 126 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 127 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 128 @TyThing@s.
 129
 130 Identifying a TyCon as recursive serves two purposes
 131
 132 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 133 "transparent", like type synonyms, after the type checker.  If we did
 134 this for all newtypes, we'd get infinite types.  So we figure out for
 135 each newtype whether it is "recursive", and add a coercion if so.  In
 136 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 137
 138 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 139 Suppose we have
 140         data T = MkT Int T
 141         f (MkT x t) = f t
 142 Well, this function diverges, but we don't want the strictness analyser
 143 to diverge.  But the strictness analyser will diverge because it looks
 144 deeper and deeper into the structure of T.   (I believe there are
 145 examples where the function does something sane, and the strictness
 146 analyser still diverges, but I can't see one now.)
 147
 148 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 149 newtypes.  I did this as an experiment, to try to expose cases in which
 150 the coercions got in the way of optimisations.  If it turns out that we
 151 can indeed always use a coercion, then we don't risk recursive types,
 152 and don't need to figure out what the loop breakers are.
 153
 154 For newtype *families* though, we will always have a coercion, so they
 155 are always loop breakers!  So you can easily adjust the current
 156 algorithm by simply treating all newtype families as loop breakers (and
 157 indeed type families).  I think.
 158
 159 \begin{code}
 160 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 161                    -> TcM TcGblEnv      -- Input env extended by types and classes
 162                                         -- and their implicit Ids,DataCons
 163 tcTyAndClassDecls boot_details allDecls
 164   = do  {       -- Omit instances of indexed types; they are handled together
 165                 -- with the *heads* of class instances
 166         ; let decls = filter (not . isIdxTyDecl . unLoc) allDecls
 167
 168                 -- First check for cyclic type synonysm or classes
 169                 -- See notes with checkCycleErrs
 170         ; checkCycleErrs decls
 171         ; mod <- getModule
 172         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 173         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 174           do    { let { -- Seperate ordinary synonyms from all other type and
 175                         -- class declarations and add all associated type
 176                         -- declarations from type classes.  The latter is
 177                         -- required so that the temporary environment for the
 178                         -- knot includes all associated family declarations.
 179                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 180                                                    decls
 181                       ; alg_at_decls           = concatMap addATs alg_decls
 182                       }
 183                         -- Extend the global env with the knot-tied results
 184                         -- for data types and classes
 185                         --
 186                         -- We must populate the environment with the loop-tied
 187                         -- T's right away, because the kind checker may "fault
 188                         -- in" some type  constructors that recursively
 189                         -- mention T
 190                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 191                 ; tcExtendRecEnv gbl_things $ do
 192
 193                         -- Kind-check the declarations
 194                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 195
 196                 ; let { -- Calculate rec-flag
 197                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 198                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 199                         -- Type-check the type synonyms, and extend the envt
 200                 ; syn_tycons <- tcSynDecls kc_syn_decls
 201                 ; tcExtendGlobalEnv syn_tycons $ do
 202
 203                         -- Type-check the data types and classes
 204                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 205                 ; return (syn_tycons, concat alg_tyclss)
 206             }}})
 207         -- Finished with knot-tying now
 208         -- Extend the environment with the finished things
 209         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 210
 211         -- Perform the validity check
 212         { traceTc (text "ready for validity check")
 213         ; mappM_ (addLocM checkValidTyCl) decls
 214         ; traceTc (text "done")
 215
 216         -- Add the implicit things;
 217         -- we want them in the environment because
 218         -- they may be mentioned in interface files
 219         -- NB: All associated types and their implicit things will be added a
 220         --     second time here.  This doesn't matter as the definitions are
 221         --     the same.
 222         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 223         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 224                    $$ (text "and" <+> ppr implicit_things))
 225         ; tcExtendGlobalEnv implicit_things getGblEnv
 226     }}
 227   where
 228     -- Pull associated types out of class declarations, to tie them into the
 229     -- knot above.
 230     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 231     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 232     --     the two argument lists of `mkGlobalThings' don't match up.
 233     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 234     addATs decl                                  = [decl]
 235
 236 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 237                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 238                -> [(Name,TyThing)]
 239 -- Driven by the Decls, and treating the TyThings lazily
 240 -- make a TypeEnv for the new things
 241 mkGlobalThings decls things
 242   = map mk_thing (decls `zipLazy` things)
 243   where
 244     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 245          = (name, AClass cl)
 246     mk_thing (L _ decl, ~(ATyCon tc))
 247          = (tcdName decl, ATyCon tc)
 248 \end{code}
 249
 250
 251 %************************************************************************
 252 %*                                                                      *
 253 \subsection{Type checking instances of indexed types}
 254 %*                                                                      *
 255 %************************************************************************
 256
 257 Instances of indexed types are somewhat of a hybrid.  They are processed
 258 together with class instance heads, but can contain data constructors and hence
 259 they share a lot of kinding and type checking code with ordinary algebraic
 260 data types (and GADTs).
 261
 262 \begin{code}
 263 tcIdxTyInstDecl :: LTyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 264 tcIdxTyInstDecl (L loc decl)
 265   =     -- Prime error recovery, set source location
 266     recoverM (returnM Nothing)                  $
 267     setSrcSpan loc                              $
 268     tcAddDeclCtxt decl                          $
 269     do { -- indexed data types require -findexed-types and can't be in an
 270          -- hs-boot file
 271        ; gla_exts <- doptM Opt_IndexedTypes
 272        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 273        ; checkTc gla_exts      $ badIdxTyDecl (tcdLName decl)
 274        ; checkTc (not is_boot) $ badBootTyIdxDeclErr
 275
 276          -- perform kind and type checking
 277        ; tcIdxTyInstDecl1 decl
 278        }
 279
 280 tcIdxTyInstDecl1 :: TyClDecl Name -> TcM (Maybe TyThing)   -- Nothing if error
 281
 282 tcIdxTyInstDecl1 (decl@TySynonym {})
 283   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 284     do { -- check that the family declaration is for a synonym
 285          unless (isSynTyCon family) $
 286            addErr (wrongKindOfFamily family)
 287
 288        ; -- (1) kind check the right hand side of the type equation
 289        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 290
 291          -- (2) type check type equation
 292        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 293        ; t_typats <- mappM tcHsKindedType k_typats
 294        ; t_rhs    <- tcHsKindedType k_rhs
 295
 296          -- !!!of the form: forall t_tvs. (tcdLName decl) t_typats = t_rhs
 297        ; return Nothing     -- !!!TODO: need TyThing for indexed synonym
 298        }}
 299
 300 tcIdxTyInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 301                                tcdCons = cons})
 302   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 303     do { -- check that the family declaration is for the right kind
 304          unless (new_or_data == NewType  && isNewTyCon  family ||
 305                  new_or_data == DataType && isDataTyCon family) $
 306            addErr (wrongKindOfFamily family)
 307
 308        ; -- (1) kind check the data declaration as usual
 309        ; k_decl <- kcDataDecl decl k_tvs
 310        ; let k_ctxt = tcdCtxt k_decl
 311              k_cons = tcdCons k_decl
 312
 313          -- result kind must be '*' (otherwise, we have too few patterns)
 314        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr tc_name
 315
 316          -- (2) type check indexed data type declaration
 317        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 318        ; unbox_strict <- doptM Opt_UnboxStrictFields
 319
 320          -- Check that we don't use GADT syntax for indexed types
 321        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 322
 323          -- Check that a newtype has exactly one constructor
 324        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 325            newtypeConError tc_name (length k_cons)
 326
 327        ; t_typats     <- mappM tcHsKindedType k_typats
 328        ; stupid_theta <- tcHsKindedContext k_ctxt
 329
 330        ; rep_tc_name <- newFamInstTyConName tc_name (srcSpanStart loc)
 331        ; tycon <- fixM (\ tycon -> do
 332              { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 333                                               tycon t_tvs))
 334                                   k_cons
 335              ; tc_rhs <-
 336                  case new_or_data of
 337                    DataType -> return (mkDataTyConRhs data_cons)
 338                    NewType  -> ASSERT( isSingleton data_cons )
 339                                mkNewTyConRhs tc_name tycon (head data_cons)
 340              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 341                              False h98_syntax (Just (family, t_typats))
 342                  -- We always assume that indexed types are recursive.  Why?
 343                  -- (1) Due to their open nature, we can never be sure that a
 344                  -- further instance might not introduce a new recursive
 345                  -- dependency.  (2) They are always valid loop breakers as
 346                  -- they involve a coercion.
 347              })
 348
 349          -- construct result
 350        ; return $ Just (ATyCon tycon)
 351        }}
 352        where
 353          h98_syntax = case cons of      -- All constructors have same shape
 354                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 355                         other -> True
 356
 357 -- Kind checking of indexed types
 358 -- -
 359
 360 -- Kind check type patterns and kind annotate the embedded type variables.
 361 --
 362 -- * Here we check that a type instance matches its kind signature, but we do
 363 --   not check whether there is a pattern for each type index; the latter
 364 --   check is only required for type functions.
 365 --
 366 kcIdxTyPats :: TyClDecl Name
 367             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 368                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 369             -> TcM a
 370 kcIdxTyPats decl thing_inside
 371   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 372     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 373        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 374              ; hs_typats        = fromJust $ tcdTyPats decl }
 375
 376          -- we may not have more parameters than the kind indicates
 377        ; checkTc (length kinds >= length hs_typats) $
 378            tooManyParmsErr (tcdLName decl)
 379
 380          -- type functions can have a higher-kinded result
 381        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 382        ; typats <- zipWithM kcCheckHsType hs_typats kinds
 383        ; thing_inside tvs typats resultKind family
 384        }
 385   where
 386 \end{code}
 387
 388
 389 %************************************************************************
 390 %*                                                                      *
 391                 Kind checking
 392 %*                                                                      *
 393 %************************************************************************
 394
 395 We need to kind check all types in the mutually recursive group
 396 before we know the kind of the type variables.  For example:
 397
 398 class C a where
 399    op :: D b => a -> b -> b
 400
 401 class D c where
 402    bop :: (Monad c) => ...
 403
 404 Here, the kind of the locally-polymorphic type variable "b"
 405 depends on *all the uses of class D*.  For example, the use of
 406 Monad c in bop's type signature means that D must have kind Type->Type.
 407
 408 However type synonyms work differently.  They can have kinds which don't
 409 just involve (->) and *:
 410         type R = Int#           -- Kind #
 411         type S a = Array# a     -- Kind * -> #
 412         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 413 So we must infer their kinds from their right-hand sides *first* and then
 414 use them, whereas for the mutually recursive data types D we bring into
 415 scope kind bindings D -> k, where k is a kind variable, and do inference.
 416
 417 Indexed Types
 418 ~~~~~~~~~~~~~
 419 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 420 General type functions can be recursive, and hence, appear in `alg_decls'.
 421
 422 The kind of an indexed type is solely determinded by its kind signature;
 423 hence, only kind signatures participate in the construction of the initial
 424 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 425 instances of indexed types altogether in the following.  However, we need to
 426 include the kind signatures of associated types into the construction of the
 427 initial kind environment.  (This is handled by `allDecls').
 428
 429 \begin{code}
 430 kcTyClDecls syn_decls alg_decls
 431   = do  {       -- First extend the kind env with each data type, class, and
 432                 -- indexed type, mapping them to a type variable
 433           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 434         ; alg_kinds <- mappM getInitialKind initialKindDecls
 435         ; tcExtendKindEnv alg_kinds $ do
 436
 437                 -- Now kind-check the type synonyms, in dependency order
 438                 -- We do these differently to data type and classes,
 439                 -- because a type synonym can be an unboxed type
 440                 --      type Foo = Int#
 441                 -- and a kind variable can't unify with UnboxedTypeKind
 442                 -- So we infer their kinds in dependency order
 443         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 444         ; tcExtendKindEnv syn_kinds $  do
 445
 446                 -- Now kind-check the data type, class, and kind signatures,
 447                 -- returning kind-annotated decls; we don't kind-check
 448                 -- instances of indexed types yet, but leave this to
 449                 -- `tcInstDecls1'
 450         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl)
 451                             (filter (not . isIdxTyDecl . unLoc) alg_decls)
 452
 453         ; return (kc_syn_decls, kc_alg_decls) }}}
 454   where
 455     -- get all declarations relevant for determining the initial kind
 456     -- environment
 457     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 458                                                       | L _ at <- ats
 459                                                       , isKindSigDecl at]
 460     allDecls decl | isIdxTyDecl decl         = []
 461                   | otherwise                = [decl]
 462
 463 ------------------------------------------------------------------------
 464 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 465 -- Only for data type, class, and indexed type declarations
 466 -- Get as much info as possible from the data, class, or indexed type decl,
 467 -- so as to maximise usefulness of error messages
 468 getInitialKind decl
 469   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 470         ; res_kind  <- mk_res_kind decl
 471         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 472   where
 473     mk_arg_kind (UserTyVar _)        = newKindVar
 474     mk_arg_kind (KindedTyVar _ kind) = return kind
 475
 476     mk_res_kind (TyFunction { tcdKind    = kind      }) = return kind
 477     mk_res_kind (TyData     { tcdKindSig = Just kind }) = return kind
 478         -- On GADT-style and data signature declarations we allow a kind
 479         -- signature
 480         --      data T :: *->* where { ... }
 481     mk_res_kind other = return liftedTypeKind
 482
 483
 484 ----------------
 485 kcSynDecls :: [SCC (LTyClDecl Name)]
 486            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 487                    [(Name,TcKind)])     -- Kind bindings
 488 kcSynDecls []
 489   = return ([], [])
 490 kcSynDecls (group : groups)
 491   = do  { (decl,  nk)  <- kcSynDecl group
 492         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 493         ; return (decl:decls, nk:nks) }
 494
 495 ----------------
 496 kcSynDecl :: SCC (LTyClDecl Name)
 497            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 498                    (Name,TcKind))       -- Kind bindings
 499 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 500   = tcAddDeclCtxt decl  $
 501     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 502     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 503                         <+> brackets (ppr k_tvs))
 504        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 505        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 506        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 507        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 508                  (unLoc (tcdLName decl), tc_kind)) })
 509
 510 kcSynDecl (CyclicSCC decls)
 511   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 512                                         -- of out-of-scope tycons
 513
 514 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 515
 516 ------------------------------------------------------------------------
 517 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 518         -- Not used for type synonyms (see kcSynDecl)
 519
 520 kcTyClDecl decl@(TyData {})
 521   = ASSERT( not . isJust $ tcdTyPats decl )   -- must not be instance of idx ty
 522     kcTyClDeclBody decl $
 523       kcDataDecl decl
 524
 525 kcTyClDecl decl@(TyFunction {})
 526   = kcTyClDeclBody decl $ \ tvs' ->
 527       return (decl {tcdTyVars = tvs'})
 528
 529 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 530   = kcTyClDeclBody decl $ \ tvs' ->
 531     do  { is_boot <- tcIsHsBoot
 532         ; ctxt' <- kcHsContext ctxt
 533         ; ats'  <- mappM (wrapLocM kcTyClDecl) ats
 534         ; sigs' <- mappM (wrapLocM kc_sig    ) sigs
 535         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 536                         tcdATs = ats'}) }
 537   where
 538     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 539                                    ; return (TypeSig nm op_ty') }
 540     kc_sig other_sig          = return other_sig
 541
 542 kcTyClDecl decl@(ForeignType {})
 543   = return decl
 544
 545 kcTyClDeclBody :: TyClDecl Name
 546                -> ([LHsTyVarBndr Name] -> TcM a)
 547                -> TcM a
 548 -- getInitialKind has made a suitably-shaped kind for the type or class
 549 -- Unpack it, and attribute those kinds to the type variables
 550 -- Extend the env with bindings for the tyvars, taken from
 551 -- the kind of the tycon/class.  Give it to the thing inside, and
 552 -- check the result kind matches
 553 kcTyClDeclBody decl thing_inside
 554   = tcAddDeclCtxt decl          $
 555     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 556         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 557               (kinds, _) = splitKindFunTys tc_kind
 558               hs_tvs     = tcdTyVars decl
 559               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 560                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 561                            | (L loc tv, k) <- zip hs_tvs kinds]
 562         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 563
 564 -- Kind check a data declaration, assuming that we already extended the
 565 -- kind environment with the type variables of the left-hand side (these
 566 -- kinded type variables are also passed as the second parameter).
 567 --
 568 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 569 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 570            tvs
 571   = do  { ctxt' <- kcHsContext ctxt
 572         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 573         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 574   where
 575     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res) = do
 576       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 577         ex_ctxt' <- kcHsContext ex_ctxt
 578         details' <- kc_con_details details
 579         res'     <- case res of
 580           ResTyH98 -> return ResTyH98
 581           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 582         return (ConDecl name expl ex_tvs' ex_ctxt' details' res')
 583
 584     kc_con_details (PrefixCon btys)
 585         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 586     kc_con_details (InfixCon bty1 bty2)
 587         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 588     kc_con_details (RecCon fields)
 589         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 590
 591     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 592
 593     kc_larg_ty bty = case new_or_data of
 594                         DataType -> kcHsSigType bty
 595                         NewType  -> kcHsLiftedSigType bty
 596         -- Can't allow an unlifted type for newtypes, because we're effectively
 597         -- going to remove the constructor while coercing it to a lifted type.
 598         -- And newtypes can't be bang'd
 599 \end{code}
 600
 601
 602 %************************************************************************
 603 %*                                                                      *
 604 \subsection{Type checking}
 605 %*                                                                      *
 606 %************************************************************************
 607
 608 \begin{code}
 609 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 610 tcSynDecls [] = return []
 611 tcSynDecls (decl : decls)
 612   = do { syn_tc <- addLocM tcSynDecl decl
 613        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 614        ; return (syn_tc : syn_tcs) }
 615
 616 tcSynDecl
 617   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 618   = tcTyVarBndrs tvs            $ \ tvs' -> do
 619     { traceTc (text "tcd1" <+> ppr tc_name)
 620     ; rhs_ty' <- tcHsKindedType rhs_ty
 621     ; return (ATyCon (buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty'))) }
 622
 623 --------------------
 624 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 625
 626 tcTyClDecl calc_isrec decl
 627   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 628
 629   -- kind signature for a type function
 630 tcTyClDecl1 _calc_isrec
 631   (TyFunction {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = kind})
 632   = tcTyVarBndrs tvs  $ \ tvs' -> do
 633   { traceTc (text "type family: " <+> ppr tc_name)
 634   ; gla_exts <- doptM Opt_IndexedTypes
 635
 636         -- Check that we don't use kind signatures without Glasgow extensions
 637   ; checkTc gla_exts $ badSigTyDecl tc_name
 638
 639   ; return [ATyCon $ buildSynTyCon tc_name tvs' (OpenSynTyCon kind)]
 640   }
 641
 642   -- kind signature for an indexed data type
 643 tcTyClDecl1 _calc_isrec
 644   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 645            tcdLName = L _ tc_name, tcdKindSig = Just ksig, tcdCons = []})
 646   = tcTyVarBndrs tvs  $ \ tvs' -> do
 647   { traceTc (text "data/newtype family: " <+> ppr tc_name)
 648   ; extra_tvs <- tcDataKindSig (Just ksig)
 649   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 650
 651   ; checkTc (null . unLoc $ ctxt) $ badKindSigCtxt tc_name
 652   ; gla_exts <- doptM Opt_IndexedTypes
 653
 654         -- Check that we don't use kind signatures without Glasgow extensions
 655   ; checkTc gla_exts $ badSigTyDecl tc_name
 656
 657   ; tycon <- buildAlgTyCon tc_name final_tvs []
 658                (case new_or_data of
 659                   DataType -> OpenDataTyCon
 660                   NewType  -> OpenNewTyCon)
 661                Recursive False True Nothing
 662   ; return [ATyCon tycon]
 663   }
 664
 665 tcTyClDecl1 calc_isrec
 666   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 667            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 668   = tcTyVarBndrs tvs    $ \ tvs' -> do
 669   { extra_tvs <- tcDataKindSig mb_ksig
 670   ; let final_tvs = tvs' ++ extra_tvs
 671   ; stupid_theta <- tcHsKindedContext ctxt
 672   ; want_generic <- doptM Opt_Generics
 673   ; unbox_strict <- doptM Opt_UnboxStrictFields
 674   ; gla_exts     <- doptM Opt_GlasgowExts
 675   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 676
 677         -- Check that we don't use GADT syntax in H98 world
 678   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 679
 680         -- Check that we don't use kind signatures without Glasgow extensions
 681   ; checkTc (gla_exts || isNothing mb_ksig) (badSigTyDecl tc_name)
 682
 683         -- Check that the stupid theta is empty for a GADT-style declaration
 684   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 685
 686         -- Check that there's at least one condecl,
 687         -- or else we're reading an hs-boot file, or -fglasgow-exts
 688   ; checkTc (not (null cons) || gla_exts || is_boot)
 689             (emptyConDeclsErr tc_name)
 690
 691         -- Check that a newtype has exactly one constructor
 692   ; checkTc (new_or_data == DataType || isSingleton cons)
 693             (newtypeConError tc_name (length cons))
 694
 695   ; tycon <- fixM (\ tycon -> do
 696         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 697                                                  tycon final_tvs))
 698                              cons
 699         ; tc_rhs <-
 700             if null cons && is_boot     -- In a hs-boot file, empty cons means
 701             then return AbstractTyCon   -- "don't know"; hence Abstract
 702             else case new_or_data of
 703                    DataType -> return (mkDataTyConRhs data_cons)
 704                    NewType  ->
 705                        ASSERT( isSingleton data_cons )
 706                        mkNewTyConRhs tc_name tycon (head data_cons)
 707         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 708             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 709         })
 710   ; return [ATyCon tycon]
 711   }
 712   where
 713     is_rec   = calc_isrec tc_name
 714     h98_syntax = case cons of   -- All constructors have same shape
 715                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 716                         other -> True
 717
 718 tcTyClDecl1 calc_isrec
 719   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 720               tcdCtxt = ctxt, tcdMeths = meths,
 721               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 722   = tcTyVarBndrs tvs            $ \ tvs' -> do
 723   { ctxt' <- tcHsKindedContext ctxt
 724   ; fds' <- mappM (addLocM tc_fundep) fundeps
 725   ; atss <- mappM (addLocM (tcTyClDecl1 (const Recursive))) ats
 726   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 727   ; sig_stuff <- tcClassSigs class_name sigs meths
 728   ; clas <- fixM (\ clas ->
 729                 let     -- This little knot is just so we can get
 730                         -- hold of the name of the class TyCon, which we
 731                         -- need to look up its recursiveness
 732                     tycon_name = tyConName (classTyCon clas)
 733                     tc_isrec = calc_isrec tycon_name
 734                 in
 735                 buildClass class_name tvs' ctxt' fds' ats'
 736                            sig_stuff tc_isrec)
 737   ; return (AClass clas : ats')
 738       -- NB: Order is important due to the call to `mkGlobalThings' when
 739       --     tying the the type and class declaration type checking knot.
 740   }
 741   where
 742     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 743                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 744                                 ; return (tvs1', tvs2') }
 745
 746     -- For each AT argument compute the position of the corresponding class
 747     -- parameter in the class head.  This will later serve as a permutation
 748     -- vector when checking the validity of instance declarations.
 749     setTyThingPoss [ATyCon tycon] atTyVars =
 750       let classTyVars = hsLTyVarNames tvs
 751           poss        =   catMaybes
 752                         . map (`elemIndex` classTyVars)
 753                         . hsLTyVarNames
 754                         $ atTyVars
 755                      -- There will be no Nothing, as we already passed renaming
 756       in
 757       ATyCon (setTyConArgPoss tycon poss)
 758     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 759
 760 tcTyClDecl1 calc_isrec
 761   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 762   = returnM [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 763
 764 -----------------------------------
 765 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 766           -> NewOrData
 767           -> TyCon -> [TyVar]
 768           -> ConDecl Name
 769           -> TcM DataCon
 770
 771 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 772           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98)
 773   = do  { let tc_datacon field_lbls arg_ty
 774                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 775                      ; buildDataCon (unLoc name) False {- Prefix -}
 776                                     [NotMarkedStrict]
 777                                     (map unLoc field_lbls)
 778                                     tc_tvs []  -- No existentials
 779                                     [] []      -- No equalities, predicates
 780                                     [arg_ty']
 781                                     tycon }
 782
 783                 -- Check that a newtype has no existential stuff
 784         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
 785
 786         ; case details of
 787             PrefixCon [arg_ty]           -> tc_datacon [] arg_ty
 788             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty
 789             other                        ->
 790               failWithTc (newtypeFieldErr name (length (hsConArgs details)))
 791                         -- Check that the constructor has exactly one field
 792         }
 793
 794 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
 795           (ConDecl name _ tvs ctxt details res_ty)
 796   = tcTyVarBndrs tvs            $ \ tvs' -> do
 797     { ctxt' <- tcHsKindedContext ctxt
 798     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 799     ; let
 800         tc_datacon is_infix field_lbls btys
 801           = do { let bangs = map getBangStrictness btys
 802                ; arg_tys <- mappM tcHsBangType btys
 803                ; buildDataCon (unLoc name) is_infix
 804                     (argStrictness unbox_strict tycon bangs arg_tys)
 805                     (map unLoc field_lbls)
 806                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 807                     data_tc }
 808                 -- NB:  we put data_tc, the type constructor gotten from the
 809                 --      constructor type signature into the data constructor;
 810                 --      that way checkValidDataCon can complain if it's wrong.
 811
 812     ; case details of
 813         PrefixCon btys     -> tc_datacon False [] btys
 814         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 815         RecCon fields      -> tc_datacon False field_names btys
 816                            where
 817                               (field_names, btys) = unzip fields
 818
 819     }
 820
 821 tcResultType :: TyCon
 822              -> [TyVar]         -- data T a b c = ...
 823              -> [TyVar]         -- where MkT :: forall a b c. ...
 824              -> ResType Name
 825              -> TcM ([TyVar],           -- Universal
 826                      [TyVar],           -- Existential
 827                      [(TyVar,Type)],    -- Equality predicates
 828                      TyCon)             -- TyCon given in the ResTy
 829         -- We don't check that the TyCon given in the ResTy is
 830         -- the same as the parent tycon, becuase we are in the middle
 831         -- of a recursive knot; so it's postponed until checkValidDataCon
 832
 833 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 834   = return (tc_tvs, dc_tvs, [], decl_tycon)
 835         -- In H98 syntax the dc_tvs are the existential ones
 836         --      data T a b c = forall d e. MkT ...
 837         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 838
 839 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 840         -- E.g.  data T a b c where
 841         --         MkT :: forall x y z. T (x,y) z z
 842         -- Then we generate
 843         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 844
 845   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 846                 -- NB: tc_tvs and dc_tvs are distinct
 847         ; let univ_tvs = choose_univs [] tc_tvs res_tys
 848                 -- Each univ_tv is either a dc_tv or a tc_tv
 849               ex_tvs = dc_tvs `minusList` univ_tvs
 850               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 851                                       tv `elem` tc_tvs]
 852         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 853   where
 854         -- choose_univs uses the res_ty itself if it's a type variable
 855         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 856     choose_univs used tc_tvs []
 857         = ASSERT( null tc_tvs ) []
 858     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 859         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 860         = tv    : choose_univs (tv:used) tc_tvs res_tys
 861         | otherwise
 862         = tc_tv : choose_univs used tc_tvs res_tys
 863
 864 -------------------
 865 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 866               -> TyCon -> [HsBang]
 867               -> [TcType] -> [StrictnessMark]
 868 argStrictness unbox_strict tycon bangs arg_tys
 869  = ASSERT( length bangs == length arg_tys )
 870    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 871
 872 -- We attempt to unbox/unpack a strict field when either:
 873 --   (i)  The field is marked '!!', or
 874 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 875 --
 876 -- We have turned off unboxing of newtypes because coercions make unboxing
 877 -- and reboxing more complicated
 878 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 879 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 880   = case bang of
 881         HsNoBang                                    -> NotMarkedStrict
 882         HsStrict | unbox_strict_fields
 883                    && can_unbox arg_ty              -> MarkedUnboxed
 884         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 885         other                                       -> MarkedStrict
 886   where
 887     -- we can unbox if the type is a chain of newtypes with a product tycon
 888     -- at the end
 889     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 890                    Nothing                      -> False
 891                    Just (arg_tycon, tycon_args) ->
 892                        not (isRecursiveTyCon tycon) &&
 893                        isProductTyCon arg_tycon &&
 894                        (if isNewTyCon arg_tycon then
 895                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 896                         else True)
 897 \end{code}
 898
 899 %************************************************************************
 900 %*                                                                      *
 901 \subsection{Dependency analysis}
 902 %*                                                                      *
 903 %************************************************************************
 904
 905 Validity checking is done once the mutually-recursive knot has been
 906 tied, so we can look at things freely.
 907
 908 \begin{code}
 909 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 910 checkCycleErrs tyclss
 911   | null cls_cycles
 912   = return ()
 913   | otherwise
 914   = do  { mappM_ recClsErr cls_cycles
 915         ; failM }       -- Give up now, because later checkValidTyCl
 916                         -- will loop if the synonym is recursive
 917   where
 918     cls_cycles = calcClassCycles tyclss
 919
 920 checkValidTyCl :: TyClDecl Name -> TcM ()
 921 -- We do the validity check over declarations, rather than TyThings
 922 -- only so that we can add a nice context with tcAddDeclCtxt
 923 checkValidTyCl decl
 924   = tcAddDeclCtxt decl $
 925     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 926         ; traceTc (text "Validity of" <+> ppr thing)
 927         ; case thing of
 928             ATyCon tc -> checkValidTyCon tc
 929             AClass cl -> checkValidClass cl
 930         ; traceTc (text "Done validity of" <+> ppr thing)
 931         }
 932
 933 -------------------------
 934 -- For data types declared with record syntax, we require
 935 -- that each constructor that has a field 'f'
 936 --      (a) has the same result type
 937 --      (b) has the same type for 'f'
 938 -- module alpha conversion of the quantified type variables
 939 -- of the constructor.
 940
 941 checkValidTyCon :: TyCon -> TcM ()
 942 checkValidTyCon tc
 943   | isSynTyCon tc
 944   = case synTyConRhs tc of
 945       OpenSynTyCon _  -> return ()
 946       SynonymTyCon ty -> checkValidType syn_ctxt ty
 947   | otherwise
 948   =     -- Check the context on the data decl
 949     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 950
 951         -- Check arg types of data constructors
 952     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 953
 954         -- Check that fields with the same name share a type
 955     mappM_ check_fields groups
 956
 957   where
 958     syn_ctxt  = TySynCtxt name
 959     name      = tyConName tc
 960     data_cons = tyConDataCons tc
 961
 962     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 963     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 964     get_fields con = dataConFieldLabels con `zip` repeat con
 965         -- dataConFieldLabels may return the empty list, which is fine
 966
 967     -- See Note [GADT record selectors] in MkId.lhs
 968     -- We must check (a) that the named field has the same
 969     --                   type in each constructor
 970     --               (b) that those constructors have the same result type
 971     --
 972     -- However, the constructors may have differently named type variable
 973     -- and (worse) we don't know how the correspond to each other.  E.g.
 974     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
 975     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
 976     --
 977     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
 978     -- result type against other candidates' types BOTH WAYS ROUND.
 979     -- If they magically agrees, take the substitution and
 980     -- apply them to the latter ones, and see if they match perfectly.
 981     check_fields fields@((label, con1) : other_fields)
 982         -- These fields all have the same name, but are from
 983         -- different constructors in the data type
 984         = recoverM (return ()) $ mapM_ checkOne other_fields
 985                 -- Check that all the fields in the group have the same type
 986                 -- NB: this check assumes that all the constructors of a given
 987                 -- data type use the same type variables
 988         where
 989         tvs1 = mkVarSet (dataConAllTyVars con1)
 990         res1 = dataConResTys con1
 991         fty1 = dataConFieldType con1 label
 992
 993         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 994             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
 995                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
 996             where
 997                 tvs2 = mkVarSet (dataConAllTyVars con2)
 998                 res2 = dataConResTys con2
 999                 fty2 = dataConFieldType con2 label
1000
1001 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1002   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1003         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1004   where
1005     mb_subst1 = tcMatchTys tvs1 res1 res2
1006     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1007
1008 -------------------------------
1009 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1010 checkValidDataCon tc con
1011   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1012     addErrCtxt (dataConCtxt con)                $
1013     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1014         ; checkValidType ctxt (dataConUserType con) }
1015   where
1016     ctxt = ConArgCtxt (dataConName con)
1017
1018 -------------------------------
1019 checkValidClass :: Class -> TcM ()
1020 checkValidClass cls
1021   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
1022           gla_exts <- doptM Opt_GlasgowExts
1023
1024         -- Check that the class is unary, unless GlaExs
1025         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1026         ; checkTc (gla_exts || unary) (classArityErr cls)
1027
1028         -- Check the super-classes
1029         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1030
1031         -- Check the class operations
1032         ; mappM_ (check_op gla_exts) op_stuff
1033
1034         -- Check that if the class has generic methods, then the
1035         -- class has only one parameter.  We can't do generic
1036         -- multi-parameter type classes!
1037         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1038         }
1039   where
1040     (tyvars, theta, _, op_stuff) = classBigSig cls
1041     unary       = isSingleton tyvars
1042     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1043
1044     check_op gla_exts (sel_id, dm)
1045       = addErrCtxt (classOpCtxt sel_id tau) $ do
1046         { checkValidTheta SigmaCtxt (tail theta)
1047                 -- The 'tail' removes the initial (C a) from the
1048                 -- class itself, leaving just the method type
1049
1050         ; checkValidType (FunSigCtxt op_name) tau
1051
1052                 -- Check that the type mentions at least one of
1053                 -- the class type variables
1054         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
1055                   (noClassTyVarErr cls sel_id)
1056
1057                 -- Check that for a generic method, the type of
1058                 -- the method is sufficiently simple
1059         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1060                   (badGenericMethodType op_name op_ty)
1061         }
1062         where
1063           op_name = idName sel_id
1064           op_ty   = idType sel_id
1065           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1066           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1067           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
1068                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
1069                 -- Ugh!  The function might have a type like
1070                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1071                 -- With -fglasgow-exts, we want to allow this, even though the inner
1072                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1073                 -- in the context of a for-all must mention at least one quantified
1074                 -- type variable.  What a mess!
1075
1076
1077 ---------------------------------------------------------------------
1078 resultTypeMisMatch field_name con1 con2
1079   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1080                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
1081           nest 2 $ ptext SLIT("but have different result types")]
1082 fieldTypeMisMatch field_name con1 con2
1083   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
1084          ptext SLIT("give different types for field"), quotes (ppr field_name)]
1085
1086 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
1087
1088 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
1089                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1090
1091 nullaryClassErr cls
1092   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
1093
1094 classArityErr cls
1095   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
1096           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
1097
1098 noClassTyVarErr clas op
1099   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
1100          ptext SLIT("mentions none of the type variables of the class") <+>
1101                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1102
1103 genericMultiParamErr clas
1104   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
1105     ptext SLIT("cannot have generic methods")
1106
1107 badGenericMethodType op op_ty
1108   = hang (ptext SLIT("Generic method type is too complex"))
1109        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1110                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
1111
1112 recSynErr syn_decls
1113   = setSrcSpan (getLoc (head sorted_decls)) $
1114     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
1115                  nest 2 (vcat (map ppr_decl sorted_decls))])
1116   where
1117     sorted_decls = sortLocated syn_decls
1118     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1119
1120 recClsErr cls_decls
1121   = setSrcSpan (getLoc (head sorted_decls)) $
1122     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
1123                  nest 2 (vcat (map ppr_decl sorted_decls))])
1124   where
1125     sorted_decls = sortLocated cls_decls
1126     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1127
1128 sortLocated :: [Located a] -> [Located a]
1129 sortLocated things = sortLe le things
1130   where
1131     le (L l1 _) (L l2 _) = l1 <= l2
1132
1133 badDataConTyCon data_con
1134   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
1135                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
1136        2 (ptext SLIT("instead of its parent type"))
1137
1138 badGadtDecl tc_name
1139   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1140          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
1141
1142 badStupidTheta tc_name
1143   = ptext SLIT("A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1144
1145 newtypeConError tycon n
1146   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
1147          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
1148
1149 newtypeExError con
1150   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
1151          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
1152
1153 newtypeFieldErr con_name n_flds
1154   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
1155          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
1156
1157 badSigTyDecl tc_name
1158   = vcat [ ptext SLIT("Illegal kind signature") <+>
1159            quotes (ppr tc_name)
1160          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1161
1162 badKindSigCtxt tc_name
1163   = vcat [ ptext SLIT("Illegal context in kind signature") <+>
1164            quotes (ppr tc_name)
1165          , nest 2 (parens $ ptext SLIT("Currently, kind signatures cannot have a context")) ]
1166
1167 badIdxTyDecl tc_name
1168   = vcat [ ptext SLIT("Illegal indexed type instance for") <+>
1169            quotes (ppr tc_name)
1170          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow indexed types")) ]
1171
1172 badGadtIdxTyDecl tc_name
1173   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+>
1174            quotes (ppr tc_name)
1175          , nest 2 (parens $ ptext SLIT("Indexed types cannot use GADT declarations")) ]
1176
1177 tooManyParmsErr tc_name
1178   = ptext SLIT("Indexed type instance has too many parameters:") <+>
1179     quotes (ppr tc_name)
1180
1181 tooFewParmsErr tc_name
1182   = ptext SLIT("Indexed type instance has too few parameters:") <+>
1183     quotes (ppr tc_name)
1184
1185 badBootTyIdxDeclErr =
1186   ptext SLIT("Illegal indexed type instance in hs-boot file")
1187
1188 wrongKindOfFamily family =
1189   ptext SLIT("Wrong category of type instance; declaration was for a") <+>
1190   kindOfFamily
1191   where
1192     kindOfFamily | isSynTyCon  family = ptext SLIT("type synonym")
1193                  | isDataTyCon family = ptext SLIT("data type")
1194                  | isNewTyCon  family = ptext SLIT("newtype")
1195
1196 emptyConDeclsErr tycon
1197   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
1198          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
1199 \end{code}