compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The AQUA Project, Glasgow University, 1996-1998
   3 %
   4 \section[TcTyClsDecls]{Typecheck type and class declarations}
   5
   6 \begin{code}
   7 module TcTyClsDecls (
   8         tcTyAndClassDecls
   9     ) where
  10
  11 #include "HsVersions.h"
  12
  13 import HsSyn            ( TyClDecl(..),  HsConDetails(..), HsTyVarBndr(..),
  14                           ConDecl(..),   Sig(..), NewOrData(..), ResType(..),
  15                           tyClDeclTyVars, isSynDecl, isClassDecl, hsConArgs,
  16                           LTyClDecl, tcdName, hsTyVarName, LHsTyVarBndr
  17                         )
  18 import HsTypes          ( HsBang(..), getBangStrictness )
  19 import BasicTypes       ( RecFlag(..), StrictnessMark(..) )
  20 import HscTypes         ( implicitTyThings, ModDetails )
  21 import BuildTyCl        ( buildClass, buildAlgTyCon, buildSynTyCon, buildDataCon,
  22                           mkDataTyConRhs, mkNewTyConRhs )
  23 import TcRnMonad
  24 import TcEnv            ( TyThing(..),
  25                           tcLookupLocated, tcLookupLocatedGlobal,
  26                           tcExtendGlobalEnv, tcExtendKindEnv, tcExtendKindEnvTvs,
  27                           tcExtendRecEnv, tcLookupTyVar )
  28 import TcTyDecls        ( calcTyConArgVrcs, calcRecFlags, calcClassCycles, calcSynCycles )
  29 import TcClassDcl       ( tcClassSigs, tcAddDeclCtxt )
  30 import TcHsType         ( kcHsTyVars, kcHsLiftedSigType, kcHsType,
  31                           kcHsContext, tcTyVarBndrs, tcHsKindedType, tcHsKindedContext,
  32                           kcHsSigType, tcHsBangType, tcLHsConResTy, tcDataKindSig )
  33 import TcMType          ( newKindVar, checkValidTheta, checkValidType,
  34                           -- checkFreeness,
  35                           UserTypeCtxt(..), SourceTyCtxt(..) )
  36 import TcType           ( TcKind, TcType, tyVarsOfType, mkPhiTy,
  37                           mkArrowKind, liftedTypeKind, mkTyVarTys,
  38                           tcSplitSigmaTy, tcEqTypes, tcGetTyVar_maybe )
  39 import Type             ( splitTyConApp_maybe,
  40                           -- pprParendType, pprThetaArrow
  41                         )
  42 import Kind             ( mkArrowKinds, splitKindFunTys )
  43 import Generics         ( validGenericMethodType, canDoGenerics )
  44 import Class            ( Class, className, classTyCon, DefMeth(..), classBigSig, classTyVars )
  45 import TyCon            ( TyCon, ArgVrcs, AlgTyConRhs( AbstractTyCon ),
  46                           tyConDataCons, mkForeignTyCon, isProductTyCon, isRecursiveTyCon,
  47                           tyConStupidTheta, synTyConRhs, isSynTyCon, tyConName )
  48 import DataCon          ( DataCon, dataConWrapId, dataConName,
  49                           dataConFieldLabels, dataConTyCon,
  50                           dataConTyVars, dataConFieldType, dataConResTys )
  51 import Var              ( TyVar, idType, idName )
  52 import VarSet           ( elemVarSet, mkVarSet )
  53 import Name             ( Name, getSrcLoc )
  54 import Outputable
  55 import Maybe            ( isJust )
  56 import Maybes           ( expectJust )
  57 import Unify            ( tcMatchTys, tcMatchTyX )
  58 import Util             ( zipLazy, isSingleton, notNull, sortLe )
  59 import List             ( partition )
  60 import SrcLoc           ( Located(..), unLoc, getLoc, srcLocSpan )
  61 import ListSetOps       ( equivClasses )
  62 import List             ( delete )
  63 import Digraph          ( SCC(..) )
  64 import DynFlags         ( DynFlag( Opt_GlasgowExts, Opt_Generics,
  65                                         Opt_UnboxStrictFields ) )
  66 \end{code}
  67
  68
  69 %************************************************************************
  70 %*                                                                      *
  71 \subsection{Type checking for type and class declarations}
  72 %*                                                                      *
  73 %************************************************************************
  74
  75 Dealing with a group
  76 ~~~~~~~~~~~~~~~~~~~~
  77 Consider a mutually-recursive group, binding
  78 a type constructor T and a class C.
  79
  80 Step 1:         getInitialKind
  81         Construct a KindEnv by binding T and C to a kind variable
  82
  83 Step 2:         kcTyClDecl
  84         In that environment, do a kind check
  85
  86 Step 3: Zonk the kinds
  87
  88 Step 4:         buildTyConOrClass
  89         Construct an environment binding T to a TyCon and C to a Class.
  90         a) Their kinds comes from zonking the relevant kind variable
  91         b) Their arity (for synonyms) comes direct from the decl
  92         c) The funcional dependencies come from the decl
  93         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  94         e) The variances of the tycons in the group is calculated from
  95                 the knot-tied stuff
  96
  97 Step 5:         tcTyClDecl1
  98         In this environment, walk over the decls, constructing the TyCons and Classes.
  99         This uses in a strict way items (a)-(c) above, which is why they must
 100         be constructed in Step 4. Feed the results back to Step 4.
 101         For this step, pass the is-recursive flag as the wimp-out flag
 102         to tcTyClDecl1.
 103
 104
 105 Step 6:         Extend environment
 106         We extend the type environment with bindings not only for the TyCons and Classes,
 107         but also for their "implicit Ids" like data constructors and class selectors
 108
 109 Step 7:         checkValidTyCl
 110         For a recursive group only, check all the decls again, just
 111         to check all the side conditions on validity.  We could not
 112         do this before because we were in a mutually recursive knot.
 113
 114
 115 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 116 @TyThing@s.  @rec_vrcs@ is a finite map from @Name@s to @ArgVrcs@s.
 117
 118 \begin{code}
 119 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 120                    -> TcM TcGblEnv      -- Input env extended by types and classes
 121                                         -- and their implicit Ids,DataCons
 122 tcTyAndClassDecls boot_details decls
 123   = do  {       -- First check for cyclic type synonysm or classes
 124                 -- See notes with checkCycleErrs
 125           checkCycleErrs decls
 126         ; mod <- getModule
 127         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 128         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(rec_syn_tycons, rec_alg_tyclss) ->
 129           do    { let { -- Calculate variances and rec-flag
 130                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 131                                                    decls }
 132                         -- Extend the global env with the knot-tied results
 133                         -- for data types and classes
 134                         --
 135                         -- We must populate the environment with the loop-tied T's right
 136                         -- away, because the kind checker may "fault in" some type
 137                         -- constructors that recursively mention T
 138                 ; let { gbl_things = mkGlobalThings alg_decls rec_alg_tyclss }
 139                 ; tcExtendRecEnv gbl_things $ do
 140
 141                         -- Kind-check the declarations
 142                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 143
 144                 ; let { calc_vrcs = calcTyConArgVrcs (rec_syn_tycons ++ rec_alg_tyclss)
 145                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 146                       ; tc_decl   = addLocM (tcTyClDecl calc_vrcs calc_rec) }
 147                         -- Type-check the type synonyms, and extend the envt
 148                 ; syn_tycons <- tcSynDecls calc_vrcs kc_syn_decls
 149                 ; tcExtendGlobalEnv syn_tycons $ do
 150
 151                         -- Type-check the data types and classes
 152                 { alg_tyclss <- mappM tc_decl kc_alg_decls
 153                 ; return (syn_tycons, alg_tyclss)
 154             }}})
 155         -- Finished with knot-tying now
 156         -- Extend the environment with the finished things
 157         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 158
 159         -- Perform the validity check
 160         { traceTc (text "ready for validity check")
 161         ; mappM_ (addLocM checkValidTyCl) decls
 162         ; traceTc (text "done")
 163
 164         -- Add the implicit things;
 165         -- we want them in the environment because
 166         -- they may be mentioned in interface files
 167         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 168         ; traceTc ((text "Adding" <+> ppr alg_tyclss) $$ (text "and" <+> ppr implicit_things))
 169         ; tcExtendGlobalEnv implicit_things getGblEnv
 170     }}
 171
 172 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 173                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 174                -> [(Name,TyThing)]
 175 -- Driven by the Decls, and treating the TyThings lazily
 176 -- make a TypeEnv for the new things
 177 mkGlobalThings decls things
 178   = map mk_thing (decls `zipLazy` things)
 179   where
 180     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 181          = (name, AClass cl)
 182     mk_thing (L _ decl, ~(ATyCon tc))
 183          = (tcdName decl, ATyCon tc)
 184 \end{code}
 185
 186
 187 %************************************************************************
 188 %*                                                                      *
 189                 Kind checking
 190 %*                                                                      *
 191 %************************************************************************
 192
 193 We need to kind check all types in the mutually recursive group
 194 before we know the kind of the type variables.  For example:
 195
 196 class C a where
 197    op :: D b => a -> b -> b
 198
 199 class D c where
 200    bop :: (Monad c) => ...
 201
 202 Here, the kind of the locally-polymorphic type variable "b"
 203 depends on *all the uses of class D*.  For example, the use of
 204 Monad c in bop's type signature means that D must have kind Type->Type.
 205
 206 However type synonyms work differently.  They can have kinds which don't
 207 just involve (->) and *:
 208         type R = Int#           -- Kind #
 209         type S a = Array# a     -- Kind * -> #
 210         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 211 So we must infer their kinds from their right-hand sides *first* and then
 212 use them, whereas for the mutually recursive data types D we bring into
 213 scope kind bindings D -> k, where k is a kind variable, and do inference.
 214
 215 \begin{code}
 216 kcTyClDecls syn_decls alg_decls
 217   = do  {       -- First extend the kind env with each data
 218                 -- type and class, mapping them to a type variable
 219           alg_kinds <- mappM getInitialKind alg_decls
 220         ; tcExtendKindEnv alg_kinds $ do
 221
 222                 -- Now kind-check the type synonyms, in dependency order
 223                 -- We do these differently to data type and classes,
 224                 -- because a type synonym can be an unboxed type
 225                 --      type Foo = Int#
 226                 -- and a kind variable can't unify with UnboxedTypeKind
 227                 -- So we infer their kinds in dependency order
 228         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 229         ; tcExtendKindEnv syn_kinds $  do
 230
 231                 -- Now kind-check the data type and class declarations,
 232                 -- returning kind-annotated decls
 233         { kc_alg_decls <- mappM (wrapLocM kcTyClDecl) alg_decls
 234
 235         ; return (kc_syn_decls, kc_alg_decls) }}}
 236
 237 ------------------------------------------------------------------------
 238 getInitialKind :: LTyClDecl Name -> TcM (Name, TcKind)
 239 -- Only for data type and class declarations
 240 -- Get as much info as possible from the data or class decl,
 241 -- so as to maximise usefulness of error messages
 242 getInitialKind (L _ decl)
 243   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 244         ; res_kind  <- mk_res_kind decl
 245         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 246   where
 247     mk_arg_kind (UserTyVar _)        = newKindVar
 248     mk_arg_kind (KindedTyVar _ kind) = return kind
 249
 250     mk_res_kind (TyData { tcdKindSig = Just kind }) = return kind
 251         -- On GADT-style declarations we allow a kind signature
 252         --      data T :: *->* where { ... }
 253     mk_res_kind other = return liftedTypeKind
 254
 255
 256 ----------------
 257 kcSynDecls :: [SCC (LTyClDecl Name)]
 258            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 259                    [(Name,TcKind)])     -- Kind bindings
 260 kcSynDecls []
 261   = return ([], [])
 262 kcSynDecls (group : groups)
 263   = do  { (decl,  nk)  <- kcSynDecl group
 264         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 265         ; return (decl:decls, nk:nks) }
 266
 267 ----------------
 268 kcSynDecl :: SCC (LTyClDecl Name)
 269            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 270                    (Name,TcKind))       -- Kind bindings
 271 kcSynDecl (AcyclicSCC ldecl@(L loc decl))
 272   = tcAddDeclCtxt decl  $
 273     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 274     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 275                         <+> brackets (ppr k_tvs))
 276        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 277        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 278        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 279        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 280                  (unLoc (tcdLName decl), tc_kind)) })
 281
 282 kcSynDecl (CyclicSCC decls)
 283   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 284                                         -- of out-of-scope tycons
 285
 286 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 287
 288 ------------------------------------------------------------------------
 289 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 290         -- Not used for type synonyms (see kcSynDecl)
 291
 292 kcTyClDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 293   = kcTyClDeclBody decl $ \ tvs' ->
 294     do  { ctxt' <- kcHsContext ctxt
 295         ; cons' <- mappM (wrapLocM kc_con_decl) cons
 296         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdCons = cons'}) }
 297   where
 298     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res) = do
 299       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 300         ex_ctxt' <- kcHsContext ex_ctxt
 301         details' <- kc_con_details details
 302         res'     <- case res of
 303           ResTyH98 -> return ResTyH98
 304           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 305         return (ConDecl name expl ex_tvs' ex_ctxt' details' res')
 306
 307     kc_con_details (PrefixCon btys)
 308         = do { btys' <- mappM kc_larg_ty btys ; return (PrefixCon btys') }
 309     kc_con_details (InfixCon bty1 bty2)
 310         = do { bty1' <- kc_larg_ty bty1; bty2' <- kc_larg_ty bty2; return (InfixCon bty1' bty2') }
 311     kc_con_details (RecCon fields)
 312         = do { fields' <- mappM kc_field fields; return (RecCon fields') }
 313
 314     kc_field (fld, bty) = do { bty' <- kc_larg_ty bty ; return (fld, bty') }
 315
 316     kc_larg_ty bty = case new_or_data of
 317                         DataType -> kcHsSigType bty
 318                         NewType  -> kcHsLiftedSigType bty
 319         -- Can't allow an unlifted type for newtypes, because we're effectively
 320         -- going to remove the constructor while coercing it to a lifted type.
 321         -- And newtypes can't be bang'd
 322
 323 -- !!!TODO -=chak
 324 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt,  tcdSigs = sigs})
 325   = kcTyClDeclBody decl $ \ tvs' ->
 326     do  { is_boot <- tcIsHsBoot
 327         ; ctxt' <- kcHsContext ctxt
 328         ; sigs' <- mappM (wrapLocM kc_sig) sigs
 329         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs'}) }
 330   where
 331     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 332                                    ; return (TypeSig nm op_ty') }
 333     kc_sig other_sig          = return other_sig
 334
 335 kcTyClDecl decl@(ForeignType {})
 336   = return decl
 337
 338 kcTyClDeclBody :: TyClDecl Name
 339                -> ([LHsTyVarBndr Name] -> TcM a)
 340                -> TcM a
 341 -- getInitialKind has made a suitably-shaped kind for the type or class
 342 -- Unpack it, and attribute those kinds to the type variables
 343 -- Extend the env with bindings for the tyvars, taken from
 344 -- the kind of the tycon/class.  Give it to the thing inside, and
 345  -- check the result kind matches
 346 kcTyClDeclBody decl thing_inside
 347   = tcAddDeclCtxt decl          $
 348     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 349         ; let tc_kind    = case tc_ty_thing of { AThing k -> k }
 350               (kinds, _) = splitKindFunTys tc_kind
 351               hs_tvs     = tcdTyVars decl
 352               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 353                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 354                            | (L loc tv, k) <- zip hs_tvs kinds]
 355         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 356 \end{code}
 357
 358
 359 %************************************************************************
 360 %*                                                                      *
 361 \subsection{Type checking}
 362 %*                                                                      *
 363 %************************************************************************
 364
 365 \begin{code}
 366 tcSynDecls :: (Name -> ArgVrcs) -> [LTyClDecl Name] -> TcM [TyThing]
 367 tcSynDecls calc_vrcs [] = return []
 368 tcSynDecls calc_vrcs (decl : decls)
 369   = do { syn_tc <- addLocM (tcSynDecl calc_vrcs) decl
 370        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls calc_vrcs decls)
 371        ; return (syn_tc : syn_tcs) }
 372
 373 tcSynDecl calc_vrcs
 374   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 375   = tcTyVarBndrs tvs            $ \ tvs' -> do
 376     { traceTc (text "tcd1" <+> ppr tc_name)
 377     ; rhs_ty' <- tcHsKindedType rhs_ty
 378     ; return (ATyCon (buildSynTyCon tc_name tvs' rhs_ty' (calc_vrcs tc_name))) }
 379
 380 --------------------
 381 tcTyClDecl :: (Name -> ArgVrcs) -> (Name -> RecFlag)
 382            -> TyClDecl Name -> TcM TyThing
 383
 384 tcTyClDecl calc_vrcs calc_isrec decl
 385   = tcAddDeclCtxt decl (tcTyClDecl1 calc_vrcs calc_isrec decl)
 386
 387 tcTyClDecl1 calc_vrcs calc_isrec
 388   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 389            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 390   = tcTyVarBndrs tvs    $ \ tvs' -> do
 391   { extra_tvs <- tcDataKindSig mb_ksig
 392   ; let final_tvs = tvs' ++ extra_tvs
 393   ; stupid_theta <- tcHsKindedContext ctxt
 394   ; want_generic <- doptM Opt_Generics
 395   ; unbox_strict <- doptM Opt_UnboxStrictFields
 396   ; gla_exts     <- doptM Opt_GlasgowExts
 397   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 398
 399         -- Check that we don't use GADT syntax in H98 world
 400   ; checkTc (gla_exts || h98_syntax) (badGadtDecl tc_name)
 401
 402         -- Check that there's at least one condecl,
 403         -- or else we're reading an interface file, or -fglasgow-exts
 404   ; checkTc (not (null cons) || gla_exts || is_boot)
 405             (emptyConDeclsErr tc_name)
 406
 407         -- Check that a newtype has exactly one constructor
 408   ; checkTc (new_or_data == DataType || isSingleton cons)
 409             (newtypeConError tc_name (length cons))
 410
 411   ; tycon <- fixM (\ tycon -> do
 412         { data_cons <- mappM (addLocM (tcConDecl unbox_strict new_or_data
 413                                                  tycon final_tvs))
 414                              cons
 415         ; let tc_rhs
 416                 | null cons && is_boot  -- In a hs-boot file, empty cons means
 417                 = AbstractTyCon         -- "don't know"; hence Abstract
 418                 | otherwise
 419                 = case new_or_data of
 420                         DataType -> mkDataTyConRhs data_cons
 421                         NewType  -> ASSERT( isSingleton data_cons )
 422                                     mkNewTyConRhs tycon (head data_cons)
 423         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs arg_vrcs is_rec
 424                         (want_generic && canDoGenerics data_cons)
 425         })
 426   ; return (ATyCon tycon)
 427   }
 428   where
 429     arg_vrcs = calc_vrcs tc_name
 430     is_rec   = calc_isrec tc_name
 431     h98_syntax = case cons of   -- All constructors have same shape
 432                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 433                         other -> True
 434
 435 tcTyClDecl1 calc_vrcs calc_isrec
 436   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 437               tcdCtxt = ctxt, tcdMeths = meths,
 438               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 439   = tcTyVarBndrs tvs            $ \ tvs' -> do
 440   { ctxt' <- tcHsKindedContext ctxt
 441   ; fds' <- mappM (addLocM tc_fundep) fundeps
 442   -- !!!TODO: process `ats`; what do we want to store in the `Class'? -=chak
 443   ; sig_stuff <- tcClassSigs class_name sigs meths
 444   ; clas <- fixM (\ clas ->
 445                 let     -- This little knot is just so we can get
 446                         -- hold of the name of the class TyCon, which we
 447                         -- need to look up its recursiveness and variance
 448                     tycon_name = tyConName (classTyCon clas)
 449                     tc_isrec = calc_isrec tycon_name
 450                     tc_vrcs  = calc_vrcs  tycon_name
 451                 in
 452                 buildClass class_name tvs' ctxt' fds'
 453                            sig_stuff tc_isrec tc_vrcs)
 454   ; return (AClass clas) }
 455   where
 456     tc_fundep (tvs1, tvs2) = do { tvs1' <- mappM tcLookupTyVar tvs1 ;
 457                                 ; tvs2' <- mappM tcLookupTyVar tvs2 ;
 458                                 ; return (tvs1', tvs2') }
 459
 460
 461 tcTyClDecl1 calc_vrcs calc_isrec
 462   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 463   = returnM (ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0 []))
 464
 465 -----------------------------------
 466 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 467           -> NewOrData -> TyCon -> [TyVar]
 468           -> ConDecl Name -> TcM DataCon
 469
 470 tcConDecl unbox_strict NewType tycon tc_tvs     -- Newtypes
 471           (ConDecl name _ ex_tvs ex_ctxt details ResTyH98)
 472   = do  { let tc_datacon field_lbls arg_ty
 473                 = do { arg_ty' <- tcHsKindedType arg_ty -- No bang on newtype
 474                      ; buildDataCon (unLoc name) False {- Prefix -}
 475                                     True {- Vanilla -} [NotMarkedStrict]
 476                                     (map unLoc field_lbls)
 477                                     tc_tvs [] [arg_ty']
 478                                     tycon (mkTyVarTys tc_tvs) }
 479
 480                 -- Check that a newtype has no existential stuff
 481         ; checkTc (null ex_tvs && null (unLoc ex_ctxt)) (newtypeExError name)
 482
 483         ; case details of
 484             PrefixCon [arg_ty] -> tc_datacon [] arg_ty
 485             RecCon [(field_lbl, arg_ty)] -> tc_datacon [field_lbl] arg_ty
 486             other -> failWithTc (newtypeFieldErr name (length (hsConArgs details)))
 487                         -- Check that the constructor has exactly one field
 488         }
 489
 490 tcConDecl unbox_strict DataType tycon tc_tvs    -- Data types
 491           (ConDecl name _ tvs ctxt details res_ty)
 492   = tcTyVarBndrs tvs            $ \ tvs' -> do
 493     { ctxt' <- tcHsKindedContext ctxt
 494     ; (data_tc, res_ty_args) <- tcResultType tycon tc_tvs res_ty
 495     ; let
 496         con_tvs = case res_ty of
 497                     ResTyH98    -> tc_tvs ++ tvs'
 498                     ResTyGADT _ -> tryVanilla tvs' res_ty_args
 499
 500         -- Vanilla iff result type matches the quantified vars exactly,
 501         -- and there is no existential context
 502         -- Must check the context too because of implicit params; e.g.
 503         --      data T = (?x::Int) => MkT Int
 504         is_vanilla = res_ty_args `tcEqTypes` mkTyVarTys con_tvs
 505                      && null (unLoc ctxt)
 506
 507         tc_datacon is_infix field_lbls btys
 508           = do { let bangs = map getBangStrictness btys
 509                ; arg_tys <- mappM tcHsBangType btys
 510                ; buildDataCon (unLoc name) is_infix is_vanilla
 511                     (argStrictness unbox_strict tycon bangs arg_tys)
 512                     (map unLoc field_lbls)
 513                     con_tvs ctxt' arg_tys
 514                     data_tc res_ty_args }
 515                 -- NB:  we put data_tc, the type constructor gotten from the constructor
 516                 --      type signature into the data constructor; that way
 517                 --      checkValidDataCon can complain if it's wrong.
 518
 519     ; case details of
 520         PrefixCon btys     -> tc_datacon False [] btys
 521         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 522         RecCon fields      -> tc_datacon False field_names btys
 523                            where
 524                               (field_names, btys) = unzip fields
 525
 526     }
 527
 528 tcResultType :: TyCon -> [TyVar] -> ResType Name -> TcM (TyCon, [TcType])
 529 tcResultType tycon tvs ResTyH98           = return (tycon, mkTyVarTys tvs)
 530 tcResultType _     _   (ResTyGADT res_ty) = tcLHsConResTy res_ty
 531
 532 tryVanilla :: [TyVar] -> [TcType] -> [TyVar]
 533 -- (tryVanilla tvs tys) returns a permutation of tvs.
 534 -- It tries to re-order the tvs so that it exactly
 535 -- matches the [Type], if that is possible
 536 tryVanilla tvs (ty:tys) | Just tv <- tcGetTyVar_maybe ty        -- The type is a tyvar
 537                         , tv `elem` tvs                         -- That tyvar is in the list
 538                         = tv : tryVanilla (delete tv tvs) tys
 539 tryVanilla tvs tys = tvs        -- Fall through case
 540
 541
 542 -------------------
 543 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 544               -> TyCon -> [HsBang]
 545               -> [TcType] -> [StrictnessMark]
 546 argStrictness unbox_strict tycon bangs arg_tys
 547  = ASSERT( length bangs == length arg_tys )
 548    zipWith (chooseBoxingStrategy unbox_strict tycon) arg_tys bangs
 549
 550 -- We attempt to unbox/unpack a strict field when either:
 551 --   (i)  The field is marked '!!', or
 552 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 553
 554 chooseBoxingStrategy :: Bool -> TyCon -> TcType -> HsBang -> StrictnessMark
 555 chooseBoxingStrategy unbox_strict_fields tycon arg_ty bang
 556   = case bang of
 557         HsNoBang                                    -> NotMarkedStrict
 558         HsStrict | unbox_strict_fields && can_unbox -> MarkedUnboxed
 559         HsUnbox  | can_unbox                        -> MarkedUnboxed
 560         other                                       -> MarkedStrict
 561   where
 562     can_unbox = case splitTyConApp_maybe arg_ty of
 563                    Nothing             -> False
 564                    Just (arg_tycon, _) -> not (isRecursiveTyCon tycon) &&
 565                                           isProductTyCon arg_tycon
 566 \end{code}
 567
 568 %************************************************************************
 569 %*                                                                      *
 570 \subsection{Dependency analysis}
 571 %*                                                                      *
 572 %************************************************************************
 573
 574 Validity checking is done once the mutually-recursive knot has been
 575 tied, so we can look at things freely.
 576
 577 \begin{code}
 578 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 579 checkCycleErrs tyclss
 580   | null cls_cycles
 581   = return ()
 582   | otherwise
 583   = do  { mappM_ recClsErr cls_cycles
 584         ; failM }       -- Give up now, because later checkValidTyCl
 585                         -- will loop if the synonym is recursive
 586   where
 587     cls_cycles = calcClassCycles tyclss
 588
 589 checkValidTyCl :: TyClDecl Name -> TcM ()
 590 -- We do the validity check over declarations, rather than TyThings
 591 -- only so that we can add a nice context with tcAddDeclCtxt
 592 checkValidTyCl decl
 593   = tcAddDeclCtxt decl $
 594     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 595         ; traceTc (text "Validity of" <+> ppr thing)
 596         ; case thing of
 597             ATyCon tc -> checkValidTyCon tc
 598             AClass cl -> checkValidClass cl
 599         ; traceTc (text "Done validity of" <+> ppr thing)
 600         }
 601
 602 -------------------------
 603 -- For data types declared with record syntax, we require
 604 -- that each constructor that has a field 'f'
 605 --      (a) has the same result type
 606 --      (b) has the same type for 'f'
 607 -- module alpha conversion of the quantified type variables
 608 -- of the constructor.
 609
 610 checkValidTyCon :: TyCon -> TcM ()
 611 checkValidTyCon tc
 612   | isSynTyCon tc
 613   = checkValidType syn_ctxt syn_rhs
 614   | otherwise
 615   =     -- Check the context on the data decl
 616     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)     `thenM_`
 617
 618         -- Check arg types of data constructors
 619     mappM_ (checkValidDataCon tc) data_cons                     `thenM_`
 620
 621         -- Check that fields with the same name share a type
 622     mappM_ check_fields groups
 623
 624   where
 625     syn_ctxt  = TySynCtxt name
 626     name      = tyConName tc
 627     syn_rhs   = synTyConRhs tc
 628     data_cons = tyConDataCons tc
 629
 630     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
 631     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
 632     get_fields con = dataConFieldLabels con `zip` repeat con
 633         -- dataConFieldLabels may return the empty list, which is fine
 634
 635     -- Note: The complicated checkOne logic below is there to accomodate
 636     --       for different return types.  Add res_ty to the mix,
 637     --       comparing them in two steps, all for good error messages.
 638     --       Plan: Use Unify.tcMatchTys to compare the first candidate's
 639     --             result type against other candidates' types (check bothways).
 640     --             If they magically agrees, take the substitution and
 641     --             apply them to the latter ones, and see if they match perfectly.
 642     -- check_fields fields@((first_field_label, field_ty) : other_fields)
 643     check_fields fields@((label, con1) : other_fields)
 644         -- These fields all have the same name, but are from
 645         -- different constructors in the data type
 646         = recoverM (return ()) $ mapM_ checkOne other_fields
 647                 -- Check that all the fields in the group have the same type
 648                 -- NB: this check assumes that all the constructors of a given
 649                 -- data type use the same type variables
 650         where
 651         tvs1 = mkVarSet (dataConTyVars con1)
 652         res1 = dataConResTys con1
 653         fty1 = dataConFieldType con1 label
 654
 655         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
 656             = do { checkFieldCompat label con1 con2 tvs1 res1 res2 fty1 fty2
 657                  ; checkFieldCompat label con2 con1 tvs2 res2 res1 fty2 fty1 }
 658             where
 659                 tvs2 = mkVarSet (dataConTyVars con2)
 660                 res2 = dataConResTys con2
 661                 fty2 = dataConFieldType con2 label
 662
 663 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
 664   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
 665         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
 666   where
 667     mb_subst1 = tcMatchTys tvs1 res1 res2
 668     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
 669
 670 -------------------------------
 671 checkValidDataCon :: TyCon -> DataCon -> TcM ()
 672 checkValidDataCon tc con
 673   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
 674     addErrCtxt (dataConCtxt con)                $
 675     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
 676         ; checkValidType ctxt (idType (dataConWrapId con)) }
 677
 678                 -- This checks the argument types and
 679                 -- ambiguity of the existential context (if any)
 680                 --
 681                 -- Note [Sept 04] Now that tvs is all the tvs, this
 682                 -- test doesn't actually check anything
 683 --      ; checkFreeness tvs ex_theta }
 684   where
 685     ctxt = ConArgCtxt (dataConName con)
 686 --    (tvs, ex_theta, _, _, _) = dataConSig con
 687
 688
 689 -------------------------------
 690 checkValidClass :: Class -> TcM ()
 691 checkValidClass cls
 692   = do  {       -- CHECK ARITY 1 FOR HASKELL 1.4
 693           gla_exts <- doptM Opt_GlasgowExts
 694
 695         -- Check that the class is unary, unless GlaExs
 696         ; checkTc (notNull tyvars) (nullaryClassErr cls)
 697         ; checkTc (gla_exts || unary) (classArityErr cls)
 698
 699         -- Check the super-classes
 700         ; checkValidTheta (ClassSCCtxt (className cls)) theta
 701
 702         -- Check the class operations
 703         ; mappM_ (check_op gla_exts) op_stuff
 704
 705         -- Check that if the class has generic methods, then the
 706         -- class has only one parameter.  We can't do generic
 707         -- multi-parameter type classes!
 708         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
 709
 710         -- Check that the class has no associated types, unless GlaExs
 711         ; checkTc (gla_exts || no_ats) (badATDecl cls)
 712         }
 713   where
 714     (tyvars, theta, _, op_stuff) = classBigSig cls
 715     unary       = isSingleton tyvars
 716     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
 717     no_ats      = True -- !!!TODO: determine whether the class has ATs -=chak
 718
 719     check_op gla_exts (sel_id, dm)
 720       = addErrCtxt (classOpCtxt sel_id tau) $ do
 721         { checkValidTheta SigmaCtxt (tail theta)
 722                 -- The 'tail' removes the initial (C a) from the
 723                 -- class itself, leaving just the method type
 724
 725         ; checkValidType (FunSigCtxt op_name) tau
 726
 727                 -- Check that the type mentions at least one of
 728                 -- the class type variables
 729         ; checkTc (any (`elemVarSet` tyVarsOfType tau) tyvars)
 730                   (noClassTyVarErr cls sel_id)
 731
 732                 -- Check that for a generic method, the type of
 733                 -- the method is sufficiently simple
 734         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
 735                   (badGenericMethodType op_name op_ty)
 736         }
 737         where
 738           op_name = idName sel_id
 739           op_ty   = idType sel_id
 740           (_,theta1,tau1) = tcSplitSigmaTy op_ty
 741           (_,theta2,tau2)  = tcSplitSigmaTy tau1
 742           (theta,tau) | gla_exts  = (theta1 ++ theta2, tau2)
 743                       | otherwise = (theta1,           mkPhiTy (tail theta1) tau1)
 744                 -- Ugh!  The function might have a type like
 745                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
 746                 -- With -fglasgow-exts, we want to allow this, even though the inner
 747                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
 748                 -- in the context of a for-all must mention at least one quantified
 749                 -- type variable.  What a mess!
 750
 751
 752 ---------------------------------------------------------------------
 753 resultTypeMisMatch field_name con1 con2
 754   = vcat [sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
 755                 ptext SLIT("have a common field") <+> quotes (ppr field_name) <> comma],
 756           nest 2 $ ptext SLIT("but have different result types")]
 757 fieldTypeMisMatch field_name con1 con2
 758   = sep [ptext SLIT("Constructors") <+> ppr con1 <+> ptext SLIT("and") <+> ppr con2,
 759          ptext SLIT("give different types for field"), quotes (ppr field_name)]
 760
 761 dataConCtxt con = ptext SLIT("In the definition of data constructor") <+> quotes (ppr con)
 762
 763 classOpCtxt sel_id tau = sep [ptext SLIT("When checking the class method:"),
 764                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
 765
 766 nullaryClassErr cls
 767   = ptext SLIT("No parameters for class")  <+> quotes (ppr cls)
 768
 769 classArityErr cls
 770   = vcat [ptext SLIT("Too many parameters for class") <+> quotes (ppr cls),
 771           parens (ptext SLIT("Use -fglasgow-exts to allow multi-parameter classes"))]
 772
 773 noClassTyVarErr clas op
 774   = sep [ptext SLIT("The class method") <+> quotes (ppr op),
 775          ptext SLIT("mentions none of the type variables of the class") <+>
 776                 ppr clas <+> hsep (map ppr (classTyVars clas))]
 777
 778 genericMultiParamErr clas
 779   = ptext SLIT("The multi-parameter class") <+> quotes (ppr clas) <+>
 780     ptext SLIT("cannot have generic methods")
 781
 782 badGenericMethodType op op_ty
 783   = hang (ptext SLIT("Generic method type is too complex"))
 784        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
 785                 ptext SLIT("You can only use type variables, arrows, lists, and tuples")])
 786
 787 recSynErr syn_decls
 788   = setSrcSpan (getLoc (head sorted_decls)) $
 789     addErr (sep [ptext SLIT("Cycle in type synonym declarations:"),
 790                  nest 2 (vcat (map ppr_decl sorted_decls))])
 791   where
 792     sorted_decls = sortLocated syn_decls
 793     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
 794
 795 recClsErr cls_decls
 796   = setSrcSpan (getLoc (head sorted_decls)) $
 797     addErr (sep [ptext SLIT("Cycle in class declarations (via superclasses):"),
 798                  nest 2 (vcat (map ppr_decl sorted_decls))])
 799   where
 800     sorted_decls = sortLocated cls_decls
 801     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
 802
 803 sortLocated :: [Located a] -> [Located a]
 804 sortLocated things = sortLe le things
 805   where
 806     le (L l1 _) (L l2 _) = l1 <= l2
 807
 808 badDataConTyCon data_con
 809   = hang (ptext SLIT("Data constructor") <+> quotes (ppr data_con) <+>
 810                 ptext SLIT("returns type") <+> quotes (ppr (dataConTyCon data_con)))
 811        2 (ptext SLIT("instead of its parent type"))
 812
 813 badGadtDecl tc_name
 814   = vcat [ ptext SLIT("Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
 815          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow GADTs")) ]
 816
 817 newtypeConError tycon n
 818   = sep [ptext SLIT("A newtype must have exactly one constructor,"),
 819          nest 2 $ ptext SLIT("but") <+> quotes (ppr tycon) <+> ptext SLIT("has") <+> speakN n ]
 820
 821 newtypeExError con
 822   = sep [ptext SLIT("A newtype constructor cannot have an existential context,"),
 823          nest 2 $ ptext SLIT("but") <+> quotes (ppr con) <+> ptext SLIT("does")]
 824
 825 newtypeFieldErr con_name n_flds
 826   = sep [ptext SLIT("The constructor of a newtype must have exactly one field"),
 827          nest 2 $ ptext SLIT("but") <+> quotes (ppr con_name) <+> ptext SLIT("has") <+> speakN n_flds]
 828
 829 badATDecl cl_name
 830   = vcat [ ptext SLIT("Illegal associated type declaration in") <+> quotes (ppr cl_name)
 831          , nest 2 (parens $ ptext SLIT("Use -fglasgow-exts to allow ATs")) ]
 832
 833 emptyConDeclsErr tycon
 834   = sep [quotes (ppr tycon) <+> ptext SLIT("has no constructors"),
 835          nest 2 $ ptext SLIT("(-fglasgow-exts permits this)")]
 836 \end{code}