compiler/typecheck/TcTyClsDecls.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The AQUA Project, Glasgow University, 1996-1998
   4 %
   5
   6 TcTyClsDecls: Typecheck type and class declarations
   7
   8 \begin{code}
   9 module TcTyClsDecls (
  10         tcTyAndClassDecls, tcFamInstDecl
  11     ) where
  12
  13 #include "HsVersions.h"
  14
  15 import HsSyn
  16 import HsTypes
  17 import BasicTypes
  18 import HscTypes
  19 import BuildTyCl
  20 import TcUnify
  21 import TcRnMonad
  22 import TcEnv
  23 import TcTyDecls
  24 import TcClassDcl
  25 import TcHsType
  26 import TcMType
  27 import TcType
  28 import FunDeps
  29 import Type
  30 import Generics
  31 import Class
  32 import TyCon
  33 import DataCon
  34 import Id
  35 import Var
  36 import VarSet
  37 import Name
  38 import OccName
  39 import Outputable
  40 import Maybes
  41 import Monad
  42 import Unify
  43 import Util
  44 import SrcLoc
  45 import ListSetOps
  46 import Digraph
  47 import DynFlags
  48 import FastString
  49
  50 import Data.List
  51 import Control.Monad    ( mplus )
  52 \end{code}
  53
  54
  55 %************************************************************************
  56 %*                                                                      *
  57 \subsection{Type checking for type and class declarations}
  58 %*                                                                      *
  59 %************************************************************************
  60
  61 Dealing with a group
  62 ~~~~~~~~~~~~~~~~~~~~
  63 Consider a mutually-recursive group, binding
  64 a type constructor T and a class C.
  65
  66 Step 1:         getInitialKind
  67         Construct a KindEnv by binding T and C to a kind variable
  68
  69 Step 2:         kcTyClDecl
  70         In that environment, do a kind check
  71
  72 Step 3: Zonk the kinds
  73
  74 Step 4:         buildTyConOrClass
  75         Construct an environment binding T to a TyCon and C to a Class.
  76         a) Their kinds comes from zonking the relevant kind variable
  77         b) Their arity (for synonyms) comes direct from the decl
  78         c) The funcional dependencies come from the decl
  79         d) The rest comes a knot-tied binding of T and C, returned from Step 4
  80         e) The variances of the tycons in the group is calculated from
  81                 the knot-tied stuff
  82
  83 Step 5:         tcTyClDecl1
  84         In this environment, walk over the decls, constructing the TyCons and Classes.
  85         This uses in a strict way items (a)-(c) above, which is why they must
  86         be constructed in Step 4. Feed the results back to Step 4.
  87         For this step, pass the is-recursive flag as the wimp-out flag
  88         to tcTyClDecl1.
  89
  90
  91 Step 6:         Extend environment
  92         We extend the type environment with bindings not only for the TyCons and Classes,
  93         but also for their "implicit Ids" like data constructors and class selectors
  94
  95 Step 7:         checkValidTyCl
  96         For a recursive group only, check all the decls again, just
  97         to check all the side conditions on validity.  We could not
  98         do this before because we were in a mutually recursive knot.
  99
 100 Identification of recursive TyCons
 101 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~
 102 The knot-tying parameters: @rec_details_list@ is an alist mapping @Name@s to
 103 @TyThing@s.
 104
 105 Identifying a TyCon as recursive serves two purposes
 106
 107 1.  Avoid infinite types.  Non-recursive newtypes are treated as
 108 "transparent", like type synonyms, after the type checker.  If we did
 109 this for all newtypes, we'd get infinite types.  So we figure out for
 110 each newtype whether it is "recursive", and add a coercion if so.  In
 111 effect, we are trying to "cut the loops" by identifying a loop-breaker.
 112
 113 2.  Avoid infinite unboxing.  This is nothing to do with newtypes.
 114 Suppose we have
 115         data T = MkT Int T
 116         f (MkT x t) = f t
 117 Well, this function diverges, but we don't want the strictness analyser
 118 to diverge.  But the strictness analyser will diverge because it looks
 119 deeper and deeper into the structure of T.   (I believe there are
 120 examples where the function does something sane, and the strictness
 121 analyser still diverges, but I can't see one now.)
 122
 123 Now, concerning (1), the FC2 branch currently adds a coercion for ALL
 124 newtypes.  I did this as an experiment, to try to expose cases in which
 125 the coercions got in the way of optimisations.  If it turns out that we
 126 can indeed always use a coercion, then we don't risk recursive types,
 127 and don't need to figure out what the loop breakers are.
 128
 129 For newtype *families* though, we will always have a coercion, so they
 130 are always loop breakers!  So you can easily adjust the current
 131 algorithm by simply treating all newtype families as loop breakers (and
 132 indeed type families).  I think.
 133
 134 \begin{code}
 135 tcTyAndClassDecls :: ModDetails -> [LTyClDecl Name]
 136                    -> TcM TcGblEnv      -- Input env extended by types and classes
 137                                         -- and their implicit Ids,DataCons
 138 -- Fails if there are any errors
 139
 140 tcTyAndClassDecls boot_details allDecls
 141   = checkNoErrs $       -- The code recovers internally, but if anything gave rise to
 142                         -- an error we'd better stop now, to avoid a cascade
 143     do  {       -- Omit instances of type families; they are handled together
 144                 -- with the *heads* of class instances
 145         ; let decls = filter (not . isFamInstDecl . unLoc) allDecls
 146
 147                 -- First check for cyclic type synonysm or classes
 148                 -- See notes with checkCycleErrs
 149         ; checkCycleErrs decls
 150         ; mod <- getModule
 151         ; traceTc (text "tcTyAndCl" <+> ppr mod)
 152         ; (syn_tycons, alg_tyclss) <- fixM (\ ~(_rec_syn_tycons, rec_alg_tyclss) ->
 153           do    { let { -- Seperate ordinary synonyms from all other type and
 154                         -- class declarations and add all associated type
 155                         -- declarations from type classes.  The latter is
 156                         -- required so that the temporary environment for the
 157                         -- knot includes all associated family declarations.
 158                       ; (syn_decls, alg_decls) = partition (isSynDecl . unLoc)
 159                                                    decls
 160                       ; alg_at_decls           = concatMap addATs alg_decls
 161                       }
 162                         -- Extend the global env with the knot-tied results
 163                         -- for data types and classes
 164                         --
 165                         -- We must populate the environment with the loop-tied
 166                         -- T's right away, because the kind checker may "fault
 167                         -- in" some type  constructors that recursively
 168                         -- mention T
 169                 ; let gbl_things = mkGlobalThings alg_at_decls rec_alg_tyclss
 170                 ; tcExtendRecEnv gbl_things $ do
 171
 172                         -- Kind-check the declarations
 173                 { (kc_syn_decls, kc_alg_decls) <- kcTyClDecls syn_decls alg_decls
 174
 175                 ; let { -- Calculate rec-flag
 176                       ; calc_rec  = calcRecFlags boot_details rec_alg_tyclss
 177                       ; tc_decl   = addLocM (tcTyClDecl calc_rec) }
 178
 179                         -- Type-check the type synonyms, and extend the envt
 180                 ; syn_tycons <- tcSynDecls kc_syn_decls
 181                 ; tcExtendGlobalEnv syn_tycons $ do
 182
 183                         -- Type-check the data types and classes
 184                 { alg_tyclss <- mapM tc_decl kc_alg_decls
 185                 ; return (syn_tycons, concat alg_tyclss)
 186             }}})
 187         -- Finished with knot-tying now
 188         -- Extend the environment with the finished things
 189         ; tcExtendGlobalEnv (syn_tycons ++ alg_tyclss) $ do
 190
 191         -- Perform the validity check
 192         { traceTc (text "ready for validity check")
 193         ; mapM_ (addLocM checkValidTyCl) decls
 194         ; traceTc (text "done")
 195
 196         -- Add the implicit things;
 197         -- we want them in the environment because
 198         -- they may be mentioned in interface files
 199         -- NB: All associated types and their implicit things will be added a
 200         --     second time here.  This doesn't matter as the definitions are
 201         --     the same.
 202         ; let { implicit_things = concatMap implicitTyThings alg_tyclss }
 203         ; traceTc ((text "Adding" <+> ppr alg_tyclss)
 204                    $$ (text "and" <+> ppr implicit_things))
 205         ; tcExtendGlobalEnv implicit_things getGblEnv
 206     }}
 207   where
 208     -- Pull associated types out of class declarations, to tie them into the
 209     -- knot above.
 210     -- NB: We put them in the same place in the list as `tcTyClDecl' will
 211     --     eventually put the matching `TyThing's.  That's crucial; otherwise,
 212     --     the two argument lists of `mkGlobalThings' don't match up.
 213     addATs decl@(L _ (ClassDecl {tcdATs = ats})) = decl : ats
 214     addATs decl                                  = [decl]
 215
 216 mkGlobalThings :: [LTyClDecl Name]      -- The decls
 217                -> [TyThing]             -- Knot-tied, in 1-1 correspondence with the decls
 218                -> [(Name,TyThing)]
 219 -- Driven by the Decls, and treating the TyThings lazily
 220 -- make a TypeEnv for the new things
 221 mkGlobalThings decls things
 222   = map mk_thing (decls `zipLazy` things)
 223   where
 224     mk_thing (L _ (ClassDecl {tcdLName = L _ name}), ~(AClass cl))
 225          = (name, AClass cl)
 226     mk_thing (L _ decl, ~(ATyCon tc))
 227          = (tcdName decl, ATyCon tc)
 228 #if __GLASGOW_HASKELL__ < 605
 229 -- Old GHCs don't understand that ~... matches anything
 230     mk_thing _ = panic "mkGlobalThings: Can't happen"
 231 #endif
 232 \end{code}
 233
 234
 235 %************************************************************************
 236 %*                                                                      *
 237 \subsection{Type checking family instances}
 238 %*                                                                      *
 239 %************************************************************************
 240
 241 Family instances are somewhat of a hybrid.  They are processed together with
 242 class instance heads, but can contain data constructors and hence they share a
 243 lot of kinding and type checking code with ordinary algebraic data types (and
 244 GADTs).
 245
 246 \begin{code}
 247 tcFamInstDecl :: LTyClDecl Name -> TcM TyThing
 248 tcFamInstDecl (L loc decl)
 249   =     -- Prime error recovery, set source location
 250     setSrcSpan loc                              $
 251     tcAddDeclCtxt decl                          $
 252     do { -- type families require -XTypeFamilies and can't be in an
 253          -- hs-boot file
 254        ; type_families <- doptM Opt_TypeFamilies
 255        ; is_boot  <- tcIsHsBoot   -- Are we compiling an hs-boot file?
 256        ; checkTc type_families $ badFamInstDecl (tcdLName decl)
 257        ; checkTc (not is_boot) $ badBootFamInstDeclErr
 258
 259          -- Perform kind and type checking
 260        ; tc <- tcFamInstDecl1 decl
 261        ; checkValidTyCon tc     -- Remember to check validity;
 262                                 -- no recursion to worry about here
 263        ; return (ATyCon tc) }
 264
 265 tcFamInstDecl1 :: TyClDecl Name -> TcM TyCon
 266
 267   -- "type instance"
 268 tcFamInstDecl1 (decl@TySynonym {tcdLName = L loc tc_name})
 269   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 270     do { -- check that the family declaration is for a synonym
 271          unless (isSynTyCon family) $
 272            addErr (wrongKindOfFamily family)
 273
 274        ; -- (1) kind check the right-hand side of the type equation
 275        ; k_rhs <- kcCheckHsType (tcdSynRhs decl) resKind
 276
 277          -- we need the exact same number of type parameters as the family
 278          -- declaration
 279        ; let famArity = tyConArity family
 280        ; checkTc (length k_typats == famArity) $
 281            wrongNumberOfParmsErr famArity
 282
 283          -- (2) type check type equation
 284        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 285        ; t_typats <- mapM tcHsKindedType k_typats
 286        ; t_rhs    <- tcHsKindedType k_rhs
 287
 288          -- (3) check the well-formedness of the instance
 289        ; checkValidTypeInst t_typats t_rhs
 290
 291          -- (4) construct representation tycon
 292        ; rep_tc_name <- newFamInstTyConName tc_name loc
 293        ; buildSynTyCon rep_tc_name t_tvs (SynonymTyCon t_rhs)
 294                        (typeKind t_rhs) (Just (family, t_typats))
 295        }}
 296
 297   -- "newtype instance" and "data instance"
 298 tcFamInstDecl1 (decl@TyData {tcdND = new_or_data, tcdLName = L loc tc_name,
 299                              tcdCons = cons})
 300   = kcIdxTyPats decl $ \k_tvs k_typats resKind family ->
 301     do { -- check that the family declaration is for the right kind
 302          unless (isAlgTyCon family) $
 303            addErr (wrongKindOfFamily family)
 304
 305        ; -- (1) kind check the data declaration as usual
 306        ; k_decl <- kcDataDecl decl k_tvs
 307        ; let k_ctxt = tcdCtxt k_decl
 308              k_cons = tcdCons k_decl
 309
 310          -- result kind must be '*' (otherwise, we have too few patterns)
 311        ; checkTc (isLiftedTypeKind resKind) $ tooFewParmsErr (tyConArity family)
 312
 313          -- (2) type check indexed data type declaration
 314        ; tcTyVarBndrs k_tvs $ \t_tvs -> do {  -- turn kinded into proper tyvars
 315        ; unbox_strict <- doptM Opt_UnboxStrictFields
 316
 317          -- kind check the type indexes and the context
 318        ; t_typats     <- mapM tcHsKindedType k_typats
 319        ; stupid_theta <- tcHsKindedContext k_ctxt
 320
 321          -- (3) Check that
 322          --     - left-hand side contains no type family applications
 323          --       (vanilla synonyms are fine, though, and we checked for
 324          --       foralls earlier)
 325        ; mapM_ checkTyFamFreeness t_typats
 326
 327          --     - we don't use GADT syntax for indexed types
 328        ; checkTc h98_syntax (badGadtIdxTyDecl tc_name)
 329
 330          --     - a newtype has exactly one constructor
 331        ; checkTc (new_or_data == DataType || isSingleton k_cons) $
 332            newtypeConError tc_name (length k_cons)
 333
 334          -- (4) construct representation tycon
 335        ; rep_tc_name <- newFamInstTyConName tc_name loc
 336        ; let ex_ok = True       -- Existentials ok for type families!
 337        ; fixM (\ tycon -> do
 338              { data_cons <- mapM (addLocM (tcConDecl unbox_strict ex_ok tycon t_tvs))
 339                                   k_cons
 340              ; tc_rhs <-
 341                  case new_or_data of
 342                    DataType -> return (mkDataTyConRhs data_cons)
 343                    NewType  -> ASSERT( not (null data_cons) )
 344                                mkNewTyConRhs rep_tc_name tycon (head data_cons)
 345              ; buildAlgTyCon rep_tc_name t_tvs stupid_theta tc_rhs Recursive
 346                              False h98_syntax (Just (family, t_typats))
 347                  -- We always assume that indexed types are recursive.  Why?
 348                  -- (1) Due to their open nature, we can never be sure that a
 349                  -- further instance might not introduce a new recursive
 350                  -- dependency.  (2) They are always valid loop breakers as
 351                  -- they involve a coercion.
 352              })
 353        }}
 354        where
 355          h98_syntax = case cons of      -- All constructors have same shape
 356                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 357                         _ -> True
 358
 359 tcFamInstDecl1 d = pprPanic "tcFamInstDecl1" (ppr d)
 360
 361 -- Kind checking of indexed types
 362 -- -
 363
 364 -- Kind check type patterns and kind annotate the embedded type variables.
 365 --
 366 -- * Here we check that a type instance matches its kind signature, but we do
 367 --   not check whether there is a pattern for each type index; the latter
 368 --   check is only required for type synonym instances.
 369 --
 370 kcIdxTyPats :: TyClDecl Name
 371             -> ([LHsTyVarBndr Name] -> [LHsType Name] -> Kind -> TyCon -> TcM a)
 372                -- ^^kinded tvs         ^^kinded ty pats  ^^res kind
 373             -> TcM a
 374 kcIdxTyPats decl thing_inside
 375   = kcHsTyVars (tcdTyVars decl) $ \tvs ->
 376     do { family <- tcLookupLocatedTyCon (tcdLName decl)
 377        ; let { (kinds, resKind) = splitKindFunTys (tyConKind family)
 378              ; hs_typats        = fromJust $ tcdTyPats decl }
 379
 380          -- we may not have more parameters than the kind indicates
 381        ; checkTc (length kinds >= length hs_typats) $
 382            tooManyParmsErr (tcdLName decl)
 383
 384          -- type functions can have a higher-kinded result
 385        ; let resultKind = mkArrowKinds (drop (length hs_typats) kinds) resKind
 386        ; typats <- zipWithM kcCheckHsType hs_typats kinds
 387        ; thing_inside tvs typats resultKind family
 388        }
 389   where
 390 \end{code}
 391
 392
 393 %************************************************************************
 394 %*                                                                      *
 395                 Kind checking
 396 %*                                                                      *
 397 %************************************************************************
 398
 399 We need to kind check all types in the mutually recursive group
 400 before we know the kind of the type variables.  For example:
 401
 402 class C a where
 403    op :: D b => a -> b -> b
 404
 405 class D c where
 406    bop :: (Monad c) => ...
 407
 408 Here, the kind of the locally-polymorphic type variable "b"
 409 depends on *all the uses of class D*.  For example, the use of
 410 Monad c in bop's type signature means that D must have kind Type->Type.
 411
 412 However type synonyms work differently.  They can have kinds which don't
 413 just involve (->) and *:
 414         type R = Int#           -- Kind #
 415         type S a = Array# a     -- Kind * -> #
 416         type T a b = (# a,b #)  -- Kind * -> * -> (# a,b #)
 417 So we must infer their kinds from their right-hand sides *first* and then
 418 use them, whereas for the mutually recursive data types D we bring into
 419 scope kind bindings D -> k, where k is a kind variable, and do inference.
 420
 421 Type families
 422 ~~~~~~~~~~~~~
 423 This treatment of type synonyms only applies to Haskell 98-style synonyms.
 424 General type functions can be recursive, and hence, appear in `alg_decls'.
 425
 426 The kind of a type family is solely determinded by its kind signature;
 427 hence, only kind signatures participate in the construction of the initial
 428 kind environment (as constructed by `getInitialKind').  In fact, we ignore
 429 instances of families altogether in the following.  However, we need to
 430 include the kinds of associated families into the construction of the
 431 initial kind environment.  (This is handled by `allDecls').
 432
 433 \begin{code}
 434 kcTyClDecls :: [LTyClDecl Name] -> [Located (TyClDecl Name)]
 435             -> TcM ([LTyClDecl Name], [Located (TyClDecl Name)])
 436 kcTyClDecls syn_decls alg_decls
 437   = do  {       -- First extend the kind env with each data type, class, and
 438                 -- indexed type, mapping them to a type variable
 439           let initialKindDecls = concat [allDecls decl | L _ decl <- alg_decls]
 440         ; alg_kinds <- mapM getInitialKind initialKindDecls
 441         ; tcExtendKindEnv alg_kinds $ do
 442
 443                 -- Now kind-check the type synonyms, in dependency order
 444                 -- We do these differently to data type and classes,
 445                 -- because a type synonym can be an unboxed type
 446                 --      type Foo = Int#
 447                 -- and a kind variable can't unify with UnboxedTypeKind
 448                 -- So we infer their kinds in dependency order
 449         { (kc_syn_decls, syn_kinds) <- kcSynDecls (calcSynCycles syn_decls)
 450         ; tcExtendKindEnv syn_kinds $  do
 451
 452                 -- Now kind-check the data type, class, and kind signatures,
 453                 -- returning kind-annotated decls; we don't kind-check
 454                 -- instances of indexed types yet, but leave this to
 455                 -- `tcInstDecls1'
 456         { kc_alg_decls <- mapM (wrapLocM kcTyClDecl)
 457                             (filter (not . isFamInstDecl . unLoc) alg_decls)
 458
 459         ; return (kc_syn_decls, kc_alg_decls) }}}
 460   where
 461     -- get all declarations relevant for determining the initial kind
 462     -- environment
 463     allDecls (decl@ClassDecl {tcdATs = ats}) = decl : [ at
 464                                                       | L _ at <- ats
 465                                                       , isFamilyDecl at]
 466     allDecls decl | isFamInstDecl decl = []
 467                   | otherwise          = [decl]
 468
 469 ------------------------------------------------------------------------
 470 getInitialKind :: TyClDecl Name -> TcM (Name, TcKind)
 471 -- Only for data type, class, and indexed type declarations
 472 -- Get as much info as possible from the data, class, or indexed type decl,
 473 -- so as to maximise usefulness of error messages
 474 getInitialKind decl
 475   = do  { arg_kinds <- mapM (mk_arg_kind . unLoc) (tyClDeclTyVars decl)
 476         ; res_kind  <- mk_res_kind decl
 477         ; return (tcdName decl, mkArrowKinds arg_kinds res_kind) }
 478   where
 479     mk_arg_kind (UserTyVar _)        = newKindVar
 480     mk_arg_kind (KindedTyVar _ kind) = return kind
 481
 482     mk_res_kind (TyFamily { tcdKind    = Just kind }) = return kind
 483     mk_res_kind (TyData   { tcdKindSig = Just kind }) = return kind
 484         -- On GADT-style declarations we allow a kind signature
 485         --      data T :: *->* where { ... }
 486     mk_res_kind _ = return liftedTypeKind
 487
 488
 489 ----------------
 490 kcSynDecls :: [SCC (LTyClDecl Name)]
 491            -> TcM ([LTyClDecl Name],    -- Kind-annotated decls
 492                    [(Name,TcKind)])     -- Kind bindings
 493 kcSynDecls []
 494   = return ([], [])
 495 kcSynDecls (group : groups)
 496   = do  { (decl,  nk)  <- kcSynDecl group
 497         ; (decls, nks) <- tcExtendKindEnv [nk] (kcSynDecls groups)
 498         ; return (decl:decls, nk:nks) }
 499
 500 ----------------
 501 kcSynDecl :: SCC (LTyClDecl Name)
 502            -> TcM (LTyClDecl Name,      -- Kind-annotated decls
 503                    (Name,TcKind))       -- Kind bindings
 504 kcSynDecl (AcyclicSCC (L loc decl))
 505   = tcAddDeclCtxt decl  $
 506     kcHsTyVars (tcdTyVars decl) (\ k_tvs ->
 507     do { traceTc (text "kcd1" <+> ppr (unLoc (tcdLName decl)) <+> brackets (ppr (tcdTyVars decl))
 508                         <+> brackets (ppr k_tvs))
 509        ; (k_rhs, rhs_kind) <- kcHsType (tcdSynRhs decl)
 510        ; traceTc (text "kcd2" <+> ppr (unLoc (tcdLName decl)))
 511        ; let tc_kind = foldr (mkArrowKind . kindedTyVarKind) rhs_kind k_tvs
 512        ; return (L loc (decl { tcdTyVars = k_tvs, tcdSynRhs = k_rhs }),
 513                  (unLoc (tcdLName decl), tc_kind)) })
 514
 515 kcSynDecl (CyclicSCC decls)
 516   = do { recSynErr decls; failM }       -- Fail here to avoid error cascade
 517                                         -- of out-of-scope tycons
 518
 519 kindedTyVarKind :: LHsTyVarBndr Name -> Kind
 520 kindedTyVarKind (L _ (KindedTyVar _ k)) = k
 521 kindedTyVarKind x = pprPanic "kindedTyVarKind" (ppr x)
 522
 523 ------------------------------------------------------------------------
 524 kcTyClDecl :: TyClDecl Name -> TcM (TyClDecl Name)
 525         -- Not used for type synonyms (see kcSynDecl)
 526
 527 kcTyClDecl decl@(TyData {})
 528   = ASSERT( not . isFamInstDecl $ decl )   -- must not be a family instance
 529     kcTyClDeclBody decl $
 530       kcDataDecl decl
 531
 532 kcTyClDecl decl@(TyFamily {})
 533   = kcFamilyDecl [] decl      -- the empty list signals a toplevel decl
 534
 535 kcTyClDecl decl@(ClassDecl {tcdCtxt = ctxt, tcdSigs = sigs, tcdATs = ats})
 536   = kcTyClDeclBody decl $ \ tvs' ->
 537     do  { ctxt' <- kcHsContext ctxt
 538         ; ats'  <- mapM (wrapLocM (kcFamilyDecl tvs')) ats
 539         ; sigs' <- mapM (wrapLocM kc_sig) sigs
 540         ; return (decl {tcdTyVars = tvs', tcdCtxt = ctxt', tcdSigs = sigs',
 541                         tcdATs = ats'}) }
 542   where
 543     kc_sig (TypeSig nm op_ty) = do { op_ty' <- kcHsLiftedSigType op_ty
 544                                    ; return (TypeSig nm op_ty') }
 545     kc_sig other_sig          = return other_sig
 546
 547 kcTyClDecl decl@(ForeignType {})
 548   = return decl
 549
 550 kcTyClDecl (TySynonym {}) = panic "kcTyClDecl TySynonym"
 551
 552 kcTyClDeclBody :: TyClDecl Name
 553                -> ([LHsTyVarBndr Name] -> TcM a)
 554                -> TcM a
 555 -- getInitialKind has made a suitably-shaped kind for the type or class
 556 -- Unpack it, and attribute those kinds to the type variables
 557 -- Extend the env with bindings for the tyvars, taken from
 558 -- the kind of the tycon/class.  Give it to the thing inside, and
 559 -- check the result kind matches
 560 kcTyClDeclBody decl thing_inside
 561   = tcAddDeclCtxt decl          $
 562     do  { tc_ty_thing <- tcLookupLocated (tcdLName decl)
 563         ; let tc_kind    = case tc_ty_thing of
 564                            AThing k -> k
 565                            _ -> pprPanic "kcTyClDeclBody" (ppr tc_ty_thing)
 566               (kinds, _) = splitKindFunTys tc_kind
 567               hs_tvs     = tcdTyVars decl
 568               kinded_tvs = ASSERT( length kinds >= length hs_tvs )
 569                            [ L loc (KindedTyVar (hsTyVarName tv) k)
 570                            | (L loc tv, k) <- zip hs_tvs kinds]
 571         ; tcExtendKindEnvTvs kinded_tvs (thing_inside kinded_tvs) }
 572
 573 -- Kind check a data declaration, assuming that we already extended the
 574 -- kind environment with the type variables of the left-hand side (these
 575 -- kinded type variables are also passed as the second parameter).
 576 --
 577 kcDataDecl :: TyClDecl Name -> [LHsTyVarBndr Name] -> TcM (TyClDecl Name)
 578 kcDataDecl decl@(TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdCons = cons})
 579            tvs
 580   = do  { ctxt' <- kcHsContext ctxt
 581         ; cons' <- mapM (wrapLocM kc_con_decl) cons
 582         ; return (decl {tcdTyVars = tvs, tcdCtxt = ctxt', tcdCons = cons'}) }
 583   where
 584     -- doc comments are typechecked to Nothing here
 585     kc_con_decl (ConDecl name expl ex_tvs ex_ctxt details res _) = do
 586       kcHsTyVars ex_tvs $ \ex_tvs' -> do
 587         ex_ctxt' <- kcHsContext ex_ctxt
 588         details' <- kc_con_details details
 589         res'     <- case res of
 590           ResTyH98 -> return ResTyH98
 591           ResTyGADT ty -> do { ty' <- kcHsSigType ty; return (ResTyGADT ty') }
 592         return (ConDecl name expl ex_tvs' ex_ctxt' details' res' Nothing)
 593
 594     kc_con_details (PrefixCon btys)
 595         = do { btys' <- mapM kc_larg_ty btys
 596              ; return (PrefixCon btys') }
 597     kc_con_details (InfixCon bty1 bty2)
 598         = do { bty1' <- kc_larg_ty bty1
 599              ; bty2' <- kc_larg_ty bty2
 600              ; return (InfixCon bty1' bty2') }
 601     kc_con_details (RecCon fields)
 602         = do { fields' <- mapM kc_field fields
 603              ; return (RecCon fields') }
 604
 605     kc_field (ConDeclField fld bty d) = do { bty' <- kc_larg_ty bty
 606                                            ; return (ConDeclField fld bty' d) }
 607
 608     kc_larg_ty bty = case new_or_data of
 609                         DataType -> kcHsSigType bty
 610                         NewType  -> kcHsLiftedSigType bty
 611         -- Can't allow an unlifted type for newtypes, because we're effectively
 612         -- going to remove the constructor while coercing it to a lifted type.
 613         -- And newtypes can't be bang'd
 614 kcDataDecl d _ = pprPanic "kcDataDecl" (ppr d)
 615
 616 -- Kind check a family declaration or type family default declaration.
 617 --
 618 kcFamilyDecl :: [LHsTyVarBndr Name]  -- tyvars of enclosing class decl if any
 619              -> TyClDecl Name -> TcM (TyClDecl Name)
 620 kcFamilyDecl classTvs decl@(TyFamily {tcdKind = kind})
 621   = kcTyClDeclBody decl $ \tvs' ->
 622     do { mapM_ unifyClassParmKinds tvs'
 623        ; return (decl {tcdTyVars = tvs',
 624                        tcdKind = kind `mplus` Just liftedTypeKind})
 625                        -- default result kind is '*'
 626        }
 627   where
 628     unifyClassParmKinds (L _ (KindedTyVar n k))
 629       | Just classParmKind <- lookup n classTyKinds = unifyKind k classParmKind
 630       | otherwise                                   = return ()
 631     unifyClassParmKinds x = pprPanic "kcFamilyDecl/unifyClassParmKinds" (ppr x)
 632     classTyKinds = [(n, k) | L _ (KindedTyVar n k) <- classTvs]
 633 kcFamilyDecl _ (TySynonym {})              -- type family defaults
 634   = panic "TcTyClsDecls.kcFamilyDecl: not implemented yet"
 635 kcFamilyDecl _ d = pprPanic "kcFamilyDecl" (ppr d)
 636 \end{code}
 637
 638
 639 %************************************************************************
 640 %*                                                                      *
 641 \subsection{Type checking}
 642 %*                                                                      *
 643 %************************************************************************
 644
 645 \begin{code}
 646 tcSynDecls :: [LTyClDecl Name] -> TcM [TyThing]
 647 tcSynDecls [] = return []
 648 tcSynDecls (decl : decls)
 649   = do { syn_tc <- addLocM tcSynDecl decl
 650        ; syn_tcs <- tcExtendGlobalEnv [syn_tc] (tcSynDecls decls)
 651        ; return (syn_tc : syn_tcs) }
 652
 653   -- "type"
 654 tcSynDecl :: TyClDecl Name -> TcM TyThing
 655 tcSynDecl
 656   (TySynonym {tcdLName = L _ tc_name, tcdTyVars = tvs, tcdSynRhs = rhs_ty})
 657   = tcTyVarBndrs tvs            $ \ tvs' -> do
 658     { traceTc (text "tcd1" <+> ppr tc_name)
 659     ; rhs_ty' <- tcHsKindedType rhs_ty
 660     ; tycon <- buildSynTyCon tc_name tvs' (SynonymTyCon rhs_ty')
 661                              (typeKind rhs_ty') Nothing
 662     ; return (ATyCon tycon)
 663     }
 664 tcSynDecl d = pprPanic "tcSynDecl" (ppr d)
 665
 666 --------------------
 667 tcTyClDecl :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 668
 669 tcTyClDecl calc_isrec decl
 670   = tcAddDeclCtxt decl (tcTyClDecl1 calc_isrec decl)
 671
 672   -- "type family" declarations
 673 tcTyClDecl1 :: (Name -> RecFlag) -> TyClDecl Name -> TcM [TyThing]
 674 tcTyClDecl1 _calc_isrec
 675   (TyFamily {tcdFlavour = TypeFamily,
 676              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = Just kind})
 677                                                       -- NB: kind at latest
 678                                                       --     added during
 679                                                       --     kind checking
 680   = tcTyVarBndrs tvs  $ \ tvs' -> do
 681   { traceTc (text "type family: " <+> ppr tc_name)
 682   ; idx_tys <- doptM Opt_TypeFamilies
 683
 684         -- Check that we don't use families without -XTypeFamilies
 685   ; checkTc idx_tys $ badFamInstDecl tc_name
 686
 687   ; tycon <- buildSynTyCon tc_name tvs' (OpenSynTyCon kind Nothing) kind Nothing
 688   ; return [ATyCon tycon]
 689   }
 690
 691   -- "data family" declaration
 692 tcTyClDecl1 _calc_isrec
 693   (TyFamily {tcdFlavour = DataFamily,
 694              tcdLName = L _ tc_name, tcdTyVars = tvs, tcdKind = mb_kind})
 695   = tcTyVarBndrs tvs  $ \ tvs' -> do
 696   { traceTc (text "data family: " <+> ppr tc_name)
 697   ; extra_tvs <- tcDataKindSig mb_kind
 698   ; let final_tvs = tvs' ++ extra_tvs    -- we may not need these
 699
 700   ; idx_tys <- doptM Opt_TypeFamilies
 701
 702         -- Check that we don't use families without -XTypeFamilies
 703   ; checkTc idx_tys $ badFamInstDecl tc_name
 704
 705   ; tycon <- buildAlgTyCon tc_name final_tvs []
 706                mkOpenDataTyConRhs Recursive False True Nothing
 707   ; return [ATyCon tycon]
 708   }
 709
 710   -- "newtype" and "data"
 711   -- NB: not used for newtype/data instances (whether associated or not)
 712 tcTyClDecl1 calc_isrec
 713   (TyData {tcdND = new_or_data, tcdCtxt = ctxt, tcdTyVars = tvs,
 714            tcdLName = L _ tc_name, tcdKindSig = mb_ksig, tcdCons = cons})
 715   = tcTyVarBndrs tvs    $ \ tvs' -> do
 716   { extra_tvs <- tcDataKindSig mb_ksig
 717   ; let final_tvs = tvs' ++ extra_tvs
 718   ; stupid_theta <- tcHsKindedContext ctxt
 719   ; want_generic <- doptM Opt_Generics
 720   ; unbox_strict <- doptM Opt_UnboxStrictFields
 721   ; empty_data_decls <- doptM Opt_EmptyDataDecls
 722   ; kind_signatures <- doptM Opt_KindSignatures
 723   ; existential_ok <- doptM Opt_ExistentialQuantification
 724   ; gadt_ok      <- doptM Opt_GADTs
 725   ; is_boot      <- tcIsHsBoot  -- Are we compiling an hs-boot file?
 726   ; let ex_ok = existential_ok || gadt_ok       -- Data cons can have existential context
 727
 728         -- Check that we don't use GADT syntax in H98 world
 729   ; checkTc (gadt_ok || h98_syntax) (badGadtDecl tc_name)
 730
 731         -- Check that we don't use kind signatures without Glasgow extensions
 732   ; checkTc (kind_signatures || isNothing mb_ksig) (badSigTyDecl tc_name)
 733
 734         -- Check that the stupid theta is empty for a GADT-style declaration
 735   ; checkTc (null stupid_theta || h98_syntax) (badStupidTheta tc_name)
 736
 737         -- Check that a newtype has exactly one constructor
 738         -- Do this before checking for empty data decls, so that
 739         -- we don't suggest -XEmptyDataDecls for newtypes
 740   ; checkTc (new_or_data == DataType || isSingleton cons)
 741             (newtypeConError tc_name (length cons))
 742
 743         -- Check that there's at least one condecl,
 744         -- or else we're reading an hs-boot file, or -XEmptyDataDecls
 745   ; checkTc (not (null cons) || empty_data_decls || is_boot)
 746             (emptyConDeclsErr tc_name)
 747
 748   ; tycon <- fixM (\ tycon -> do
 749         { data_cons <- mapM (addLocM (tcConDecl unbox_strict ex_ok tycon final_tvs))
 750                              cons
 751         ; tc_rhs <-
 752             if null cons && is_boot     -- In a hs-boot file, empty cons means
 753             then return AbstractTyCon   -- "don't know"; hence Abstract
 754             else case new_or_data of
 755                    DataType -> return (mkDataTyConRhs data_cons)
 756                    NewType  ->
 757                        ASSERT( not (null data_cons) )
 758                        mkNewTyConRhs tc_name tycon (head data_cons)
 759         ; buildAlgTyCon tc_name final_tvs stupid_theta tc_rhs is_rec
 760             (want_generic && canDoGenerics data_cons) h98_syntax Nothing
 761         })
 762   ; return [ATyCon tycon]
 763   }
 764   where
 765     is_rec   = calc_isrec tc_name
 766     h98_syntax = case cons of   -- All constructors have same shape
 767                         L _ (ConDecl { con_res = ResTyGADT _ }) : _ -> False
 768                         _ -> True
 769
 770 tcTyClDecl1 calc_isrec
 771   (ClassDecl {tcdLName = L _ class_name, tcdTyVars = tvs,
 772               tcdCtxt = ctxt, tcdMeths = meths,
 773               tcdFDs = fundeps, tcdSigs = sigs, tcdATs = ats} )
 774   = tcTyVarBndrs tvs            $ \ tvs' -> do
 775   { ctxt' <- tcHsKindedContext ctxt
 776   ; fds' <- mapM (addLocM tc_fundep) fundeps
 777   ; atss <- mapM (addLocM (tcTyClDecl1 (const Recursive))) ats
 778             -- NB: 'ats' only contains "type family" and "data family"
 779             --     declarations as well as type family defaults
 780   ; let ats' = zipWith setTyThingPoss atss (map (tcdTyVars . unLoc) ats)
 781   ; sig_stuff <- tcClassSigs class_name sigs meths
 782   ; clas <- fixM (\ clas ->
 783                 let     -- This little knot is just so we can get
 784                         -- hold of the name of the class TyCon, which we
 785                         -- need to look up its recursiveness
 786                     tycon_name = tyConName (classTyCon clas)
 787                     tc_isrec = calc_isrec tycon_name
 788                 in
 789                 buildClass False {- Must include unfoldings for selectors -}
 790                            class_name tvs' ctxt' fds' ats'
 791                            sig_stuff tc_isrec)
 792   ; return (AClass clas : ats')
 793       -- NB: Order is important due to the call to `mkGlobalThings' when
 794       --     tying the the type and class declaration type checking knot.
 795   }
 796   where
 797     tc_fundep (tvs1, tvs2) = do { tvs1' <- mapM tcLookupTyVar tvs1 ;
 798                                 ; tvs2' <- mapM tcLookupTyVar tvs2 ;
 799                                 ; return (tvs1', tvs2') }
 800
 801     -- For each AT argument compute the position of the corresponding class
 802     -- parameter in the class head.  This will later serve as a permutation
 803     -- vector when checking the validity of instance declarations.
 804     setTyThingPoss [ATyCon tycon] atTyVars =
 805       let classTyVars = hsLTyVarNames tvs
 806           poss        =   catMaybes
 807                         . map (`elemIndex` classTyVars)
 808                         . hsLTyVarNames
 809                         $ atTyVars
 810                      -- There will be no Nothing, as we already passed renaming
 811       in
 812       ATyCon (setTyConArgPoss tycon poss)
 813     setTyThingPoss _              _ = panic "TcTyClsDecls.setTyThingPoss"
 814
 815 tcTyClDecl1 _
 816   (ForeignType {tcdLName = L _ tc_name, tcdExtName = tc_ext_name})
 817   = return [ATyCon (mkForeignTyCon tc_name tc_ext_name liftedTypeKind 0)]
 818
 819 tcTyClDecl1 _ d = pprPanic "tcTyClDecl1" (ppr d)
 820
 821 -----------------------------------
 822 tcConDecl :: Bool               -- True <=> -funbox-strict_fields
 823           -> Bool               -- True <=> -XExistentialQuantificaton or -XGADTs
 824           -> TyCon -> [TyVar]
 825           -> ConDecl Name
 826           -> TcM DataCon
 827
 828 tcConDecl unbox_strict existential_ok tycon tc_tvs      -- Data types
 829           (ConDecl name _ tvs ctxt details res_ty _)
 830   = addErrCtxt (dataConCtxt name)       $
 831     tcTyVarBndrs tvs                    $ \ tvs' -> do
 832     { ctxt' <- tcHsKindedContext ctxt
 833     ; checkTc (existential_ok || (null tvs && null (unLoc ctxt)))
 834               (badExistential name)
 835     ; (univ_tvs, ex_tvs, eq_preds, data_tc) <- tcResultType tycon tc_tvs tvs' res_ty
 836     ; let
 837         -- Tiresome: tidy the tyvar binders, since tc_tvs and tvs' may have the same OccNames
 838         tc_datacon is_infix field_lbls btys
 839           = do { let bangs = map getBangStrictness btys
 840                ; arg_tys <- mapM tcHsBangType btys
 841                ; buildDataCon (unLoc name) is_infix
 842                     (argStrictness unbox_strict bangs arg_tys)
 843                     (map unLoc field_lbls)
 844                     univ_tvs ex_tvs eq_preds ctxt' arg_tys
 845                     data_tc }
 846                 -- NB:  we put data_tc, the type constructor gotten from the
 847                 --      constructor type signature into the data constructor;
 848                 --      that way checkValidDataCon can complain if it's wrong.
 849
 850     ; case details of
 851         PrefixCon btys     -> tc_datacon False [] btys
 852         InfixCon bty1 bty2 -> tc_datacon True  [] [bty1,bty2]
 853         RecCon fields      -> tc_datacon False field_names btys
 854                            where
 855                               field_names = map cd_fld_name fields
 856                               btys        = map cd_fld_type fields
 857     }
 858
 859 tcResultType :: TyCon
 860              -> [TyVar]         -- data T a b c = ...
 861              -> [TyVar]         -- where MkT :: forall a b c. ...
 862              -> ResType Name
 863              -> TcM ([TyVar],           -- Universal
 864                      [TyVar],           -- Existential (distinct OccNames from univs)
 865                      [(TyVar,Type)],    -- Equality predicates
 866                      TyCon)             -- TyCon given in the ResTy
 867         -- We don't check that the TyCon given in the ResTy is
 868         -- the same as the parent tycon, becuase we are in the middle
 869         -- of a recursive knot; so it's postponed until checkValidDataCon
 870
 871 tcResultType decl_tycon tc_tvs dc_tvs ResTyH98
 872   = return (tc_tvs, dc_tvs, [], decl_tycon)
 873         -- In H98 syntax the dc_tvs are the existential ones
 874         --      data T a b c = forall d e. MkT ...
 875         -- The {a,b,c} are tc_tvs, and {d,e} are dc_tvs
 876
 877 tcResultType _ tc_tvs dc_tvs (ResTyGADT res_ty)
 878         -- E.g.  data T a b c where
 879         --         MkT :: forall x y z. T (x,y) z z
 880         -- Then we generate
 881         --      ([a,z,c], [x,y], [a:=:(x,y), c:=:z], T)
 882
 883   = do  { (dc_tycon, res_tys) <- tcLHsConResTy res_ty
 884
 885         ; let univ_tvs = choose_univs [] tidy_tc_tvs res_tys
 886                 -- Each univ_tv is either a dc_tv or a tc_tv
 887               ex_tvs = dc_tvs `minusList` univ_tvs
 888               eq_spec = [ (tv, ty) | (tv,ty) <- univ_tvs `zip` res_tys,
 889                                       tv `elem` tc_tvs]
 890         ; return (univ_tvs, ex_tvs, eq_spec, dc_tycon) }
 891   where
 892         -- choose_univs uses the res_ty itself if it's a type variable
 893         -- and hasn't already been used; otherwise it uses one of the tc_tvs
 894     choose_univs _ tc_tvs []
 895         = ASSERT( null tc_tvs ) []
 896     choose_univs used (tc_tv:tc_tvs) (res_ty:res_tys)
 897         | Just tv <- tcGetTyVar_maybe res_ty, not (tv `elem` used)
 898         = tv    : choose_univs (tv:used) tc_tvs res_tys
 899         | otherwise
 900         = tc_tv : choose_univs used tc_tvs res_tys
 901
 902         -- NB: tc_tvs and dc_tvs are distinct, but
 903         -- we want them to be *visibly* distinct, both for
 904         -- interface files and general confusion.  So rename
 905         -- the tc_tvs, since they are not used yet (no
 906         -- consequential renaming needed)
 907     choose_univs _ _ _ = panic "tcResultType/choose_univs"
 908     init_occ_env     = initTidyOccEnv (map getOccName dc_tvs)
 909     (_, tidy_tc_tvs) = mapAccumL tidy_one init_occ_env tc_tvs
 910     tidy_one env tv  = (env', setTyVarName tv (tidyNameOcc name occ'))
 911               where
 912                  name = tyVarName tv
 913                  (env', occ') = tidyOccName env (getOccName name)
 914
 915               -------------------
 916 argStrictness :: Bool           -- True <=> -funbox-strict_fields
 917               -> [HsBang]
 918               -> [TcType] -> [StrictnessMark]
 919 argStrictness unbox_strict bangs arg_tys
 920  = ASSERT( length bangs == length arg_tys )
 921    zipWith (chooseBoxingStrategy unbox_strict) arg_tys bangs
 922
 923 -- We attempt to unbox/unpack a strict field when either:
 924 --   (i)  The field is marked '!!', or
 925 --   (ii) The field is marked '!', and the -funbox-strict-fields flag is on.
 926 --
 927 -- We have turned off unboxing of newtypes because coercions make unboxing
 928 -- and reboxing more complicated
 929 chooseBoxingStrategy :: Bool -> TcType -> HsBang -> StrictnessMark
 930 chooseBoxingStrategy unbox_strict_fields arg_ty bang
 931   = case bang of
 932         HsNoBang                                    -> NotMarkedStrict
 933         HsStrict | unbox_strict_fields
 934                    && can_unbox arg_ty              -> MarkedUnboxed
 935         HsUnbox  | can_unbox arg_ty                 -> MarkedUnboxed
 936         _                                           -> MarkedStrict
 937   where
 938     -- we can unbox if the type is a chain of newtypes with a product tycon
 939     -- at the end
 940     can_unbox arg_ty = case splitTyConApp_maybe arg_ty of
 941                    Nothing                      -> False
 942                    Just (arg_tycon, tycon_args) ->
 943                        not (isRecursiveTyCon arg_tycon) &&      -- Note [Recusive unboxing]
 944                        isProductTyCon arg_tycon &&
 945                        (if isNewTyCon arg_tycon then
 946                             can_unbox (newTyConInstRhs arg_tycon tycon_args)
 947                         else True)
 948 \end{code}
 949
 950 Note [Recursive unboxing]
 951 ~~~~~~~~~~~~~~~~~~~~~~~~~
 952 Be careful not to try to unbox this!
 953         data T = MkT !T Int
 954 But it's the *argument* type that matters. This is fine:
 955         data S = MkS S !Int
 956 because Int is non-recursive.
 957
 958 %************************************************************************
 959 %*                                                                      *
 960 \subsection{Dependency analysis}
 961 %*                                                                      *
 962 %************************************************************************
 963
 964 Validity checking is done once the mutually-recursive knot has been
 965 tied, so we can look at things freely.
 966
 967 \begin{code}
 968 checkCycleErrs :: [LTyClDecl Name] -> TcM ()
 969 checkCycleErrs tyclss
 970   | null cls_cycles
 971   = return ()
 972   | otherwise
 973   = do  { mapM_ recClsErr cls_cycles
 974         ; failM }       -- Give up now, because later checkValidTyCl
 975                         -- will loop if the synonym is recursive
 976   where
 977     cls_cycles = calcClassCycles tyclss
 978
 979 checkValidTyCl :: TyClDecl Name -> TcM ()
 980 -- We do the validity check over declarations, rather than TyThings
 981 -- only so that we can add a nice context with tcAddDeclCtxt
 982 checkValidTyCl decl
 983   = tcAddDeclCtxt decl $
 984     do  { thing <- tcLookupLocatedGlobal (tcdLName decl)
 985         ; traceTc (text "Validity of" <+> ppr thing)
 986         ; case thing of
 987             ATyCon tc -> checkValidTyCon tc
 988             AClass cl -> checkValidClass cl
 989             _ -> panic "checkValidTyCl"
 990         ; traceTc (text "Done validity of" <+> ppr thing)
 991         }
 992
 993 -------------------------
 994 -- For data types declared with record syntax, we require
 995 -- that each constructor that has a field 'f'
 996 --      (a) has the same result type
 997 --      (b) has the same type for 'f'
 998 -- module alpha conversion of the quantified type variables
 999 -- of the constructor.
1000
1001 checkValidTyCon :: TyCon -> TcM ()
1002 checkValidTyCon tc
1003   | isSynTyCon tc
1004   = case synTyConRhs tc of
1005       OpenSynTyCon _ _ -> return ()
1006       SynonymTyCon ty  -> checkValidType syn_ctxt ty
1007   | otherwise
1008   = do  -- Check the context on the data decl
1009     checkValidTheta (DataTyCtxt name) (tyConStupidTheta tc)
1010
1011         -- Check arg types of data constructors
1012     mapM_ (checkValidDataCon tc) data_cons
1013
1014         -- Check that fields with the same name share a type
1015     mapM_ check_fields groups
1016
1017   where
1018     syn_ctxt  = TySynCtxt name
1019     name      = tyConName tc
1020     data_cons = tyConDataCons tc
1021
1022     groups = equivClasses cmp_fld (concatMap get_fields data_cons)
1023     cmp_fld (f1,_) (f2,_) = f1 `compare` f2
1024     get_fields con = dataConFieldLabels con `zip` repeat con
1025         -- dataConFieldLabels may return the empty list, which is fine
1026
1027     -- See Note [GADT record selectors] in MkId.lhs
1028     -- We must check (a) that the named field has the same
1029     --                   type in each constructor
1030     --               (b) that those constructors have the same result type
1031     --
1032     -- However, the constructors may have differently named type variable
1033     -- and (worse) we don't know how the correspond to each other.  E.g.
1034     --     C1 :: forall a b. { f :: a, g :: b } -> T a b
1035     --     C2 :: forall d c. { f :: c, g :: c } -> T c d
1036     --
1037     -- So what we do is to ust Unify.tcMatchTys to compare the first candidate's
1038     -- result type against other candidates' types BOTH WAYS ROUND.
1039     -- If they magically agrees, take the substitution and
1040     -- apply them to the latter ones, and see if they match perfectly.
1041     check_fields ((label, con1) : other_fields)
1042         -- These fields all have the same name, but are from
1043         -- different constructors in the data type
1044         = recoverM (return ()) $ mapM_ checkOne other_fields
1045                 -- Check that all the fields in the group have the same type
1046                 -- NB: this check assumes that all the constructors of a given
1047                 -- data type use the same type variables
1048         where
1049         (tvs1, _, _, res1) = dataConSig con1
1050         ts1 = mkVarSet tvs1
1051         fty1 = dataConFieldType con1 label
1052
1053         checkOne (_, con2)    -- Do it bothways to ensure they are structurally identical
1054             = do { checkFieldCompat label con1 con2 ts1 res1 res2 fty1 fty2
1055                  ; checkFieldCompat label con2 con1 ts2 res2 res1 fty2 fty1 }
1056             where
1057                 (tvs2, _, _, res2) = dataConSig con2
1058                 ts2 = mkVarSet tvs2
1059                 fty2 = dataConFieldType con2 label
1060     check_fields [] = panic "checkValidTyCon/check_fields []"
1061
1062 checkFieldCompat :: Name -> DataCon -> DataCon -> TyVarSet
1063                  -> Type -> Type -> Type -> Type -> TcM ()
1064 checkFieldCompat fld con1 con2 tvs1 res1 res2 fty1 fty2
1065   = do  { checkTc (isJust mb_subst1) (resultTypeMisMatch fld con1 con2)
1066         ; checkTc (isJust mb_subst2) (fieldTypeMisMatch fld con1 con2) }
1067   where
1068     mb_subst1 = tcMatchTy tvs1 res1 res2
1069     mb_subst2 = tcMatchTyX tvs1 (expectJust "checkFieldCompat" mb_subst1) fty1 fty2
1070
1071 -------------------------------
1072 checkValidDataCon :: TyCon -> DataCon -> TcM ()
1073 checkValidDataCon tc con
1074   = setSrcSpan (srcLocSpan (getSrcLoc con))     $
1075     addErrCtxt (dataConCtxt con)                $
1076     do  { checkTc (dataConTyCon con == tc) (badDataConTyCon con)
1077         ; checkValidMonoType (dataConOrigResTy con)
1078                 -- Disallow MkT :: T (forall a. a->a)
1079                 -- Reason: it's really the argument of an equality constraint
1080         ; checkValidType ctxt (dataConUserType con)
1081         ; when (isNewTyCon tc) (checkNewDataCon con)
1082     }
1083   where
1084     ctxt = ConArgCtxt (dataConName con)
1085
1086 -------------------------------
1087 checkNewDataCon :: DataCon -> TcM ()
1088 -- Checks for the data constructor of a newtype
1089 checkNewDataCon con
1090   = do  { checkTc (isSingleton arg_tys) (newtypeFieldErr con (length arg_tys))
1091                 -- One argument
1092         ; checkTc (null eq_spec) (newtypePredError con)
1093                 -- Return type is (T a b c)
1094         ; checkTc (null ex_tvs && null eq_theta && null dict_theta) (newtypeExError con)
1095                 -- No existentials
1096         ; checkTc (not (any isMarkedStrict (dataConStrictMarks con)))
1097                   (newtypeStrictError con)
1098                 -- No strictness
1099     }
1100   where
1101     (_univ_tvs, ex_tvs, eq_spec, eq_theta, dict_theta, arg_tys, _res_ty) = dataConFullSig con
1102
1103 -------------------------------
1104 checkValidClass :: Class -> TcM ()
1105 checkValidClass cls
1106   = do  { constrained_class_methods <- doptM Opt_ConstrainedClassMethods
1107         ; multi_param_type_classes <- doptM Opt_MultiParamTypeClasses
1108         ; fundep_classes <- doptM Opt_FunctionalDependencies
1109
1110         -- Check that the class is unary, unless GlaExs
1111         ; checkTc (notNull tyvars) (nullaryClassErr cls)
1112         ; checkTc (multi_param_type_classes || unary) (classArityErr cls)
1113         ; checkTc (fundep_classes || null fundeps) (classFunDepsErr cls)
1114
1115         -- Check the super-classes
1116         ; checkValidTheta (ClassSCCtxt (className cls)) theta
1117
1118         -- Check the class operations
1119         ; mapM_ (check_op constrained_class_methods) op_stuff
1120
1121         -- Check that if the class has generic methods, then the
1122         -- class has only one parameter.  We can't do generic
1123         -- multi-parameter type classes!
1124         ; checkTc (unary || no_generics) (genericMultiParamErr cls)
1125         }
1126   where
1127     (tyvars, fundeps, theta, _, _, op_stuff) = classExtraBigSig cls
1128     unary       = isSingleton tyvars
1129     no_generics = null [() | (_, GenDefMeth) <- op_stuff]
1130
1131     check_op constrained_class_methods (sel_id, dm)
1132       = addErrCtxt (classOpCtxt sel_id tau) $ do
1133         { checkValidTheta SigmaCtxt (tail theta)
1134                 -- The 'tail' removes the initial (C a) from the
1135                 -- class itself, leaving just the method type
1136
1137         ; traceTc (text "class op type" <+> ppr op_ty <+> ppr tau)
1138         ; checkValidType (FunSigCtxt op_name) tau
1139
1140                 -- Check that the type mentions at least one of
1141                 -- the class type variables...or at least one reachable
1142                 -- from one of the class variables.  Example: tc223
1143                 --   class Error e => Game b mv e | b -> mv e where
1144                 --      newBoard :: MonadState b m => m ()
1145                 -- Here, MonadState has a fundep m->b, so newBoard is fine
1146         ; let grown_tyvars = grow theta (mkVarSet tyvars)
1147         ; checkTc (tyVarsOfType tau `intersectsVarSet` grown_tyvars)
1148                   (noClassTyVarErr cls sel_id)
1149
1150                 -- Check that for a generic method, the type of
1151                 -- the method is sufficiently simple
1152         ; checkTc (dm /= GenDefMeth || validGenericMethodType tau)
1153                   (badGenericMethodType op_name op_ty)
1154         }
1155         where
1156           op_name = idName sel_id
1157           op_ty   = idType sel_id
1158           (_,theta1,tau1) = tcSplitSigmaTy op_ty
1159           (_,theta2,tau2)  = tcSplitSigmaTy tau1
1160           (theta,tau) | constrained_class_methods = (theta1 ++ theta2, tau2)
1161                       | otherwise = (theta1, mkPhiTy (tail theta1) tau1)
1162                 -- Ugh!  The function might have a type like
1163                 --      op :: forall a. C a => forall b. (Eq b, Eq a) => tau2
1164                 -- With -XConstrainedClassMethods, we want to allow this, even though the inner
1165                 -- forall has an (Eq a) constraint.  Whereas in general, each constraint
1166                 -- in the context of a for-all must mention at least one quantified
1167                 -- type variable.  What a mess!
1168
1169
1170 ---------------------------------------------------------------------
1171 resultTypeMisMatch :: Name -> DataCon -> DataCon -> SDoc
1172 resultTypeMisMatch field_name con1 con2
1173   = vcat [sep [ptext (sLit "Constructors") <+> ppr con1 <+> ptext (sLit "and") <+> ppr con2,
1174                 ptext (sLit "have a common field") <+> quotes (ppr field_name) <> comma],
1175           nest 2 $ ptext (sLit "but have different result types")]
1176
1177 fieldTypeMisMatch :: Name -> DataCon -> DataCon -> SDoc
1178 fieldTypeMisMatch field_name con1 con2
1179   = sep [ptext (sLit "Constructors") <+> ppr con1 <+> ptext (sLit "and") <+> ppr con2,
1180          ptext (sLit "give different types for field"), quotes (ppr field_name)]
1181
1182 dataConCtxt :: Outputable a => a -> SDoc
1183 dataConCtxt con = ptext (sLit "In the definition of data constructor") <+> quotes (ppr con)
1184
1185 classOpCtxt :: Var -> Type -> SDoc
1186 classOpCtxt sel_id tau = sep [ptext (sLit "When checking the class method:"),
1187                               nest 2 (ppr sel_id <+> dcolon <+> ppr tau)]
1188
1189 nullaryClassErr :: Class -> SDoc
1190 nullaryClassErr cls
1191   = ptext (sLit "No parameters for class")  <+> quotes (ppr cls)
1192
1193 classArityErr :: Class -> SDoc
1194 classArityErr cls
1195   = vcat [ptext (sLit "Too many parameters for class") <+> quotes (ppr cls),
1196           parens (ptext (sLit "Use -XMultiParamTypeClasses to allow multi-parameter classes"))]
1197
1198 classFunDepsErr :: Class -> SDoc
1199 classFunDepsErr cls
1200   = vcat [ptext (sLit "Fundeps in class") <+> quotes (ppr cls),
1201           parens (ptext (sLit "Use -XFunctionalDependencies to allow fundeps"))]
1202
1203 noClassTyVarErr :: Class -> Var -> SDoc
1204 noClassTyVarErr clas op
1205   = sep [ptext (sLit "The class method") <+> quotes (ppr op),
1206          ptext (sLit "mentions none of the type variables of the class") <+>
1207                 ppr clas <+> hsep (map ppr (classTyVars clas))]
1208
1209 genericMultiParamErr :: Class -> SDoc
1210 genericMultiParamErr clas
1211   = ptext (sLit "The multi-parameter class") <+> quotes (ppr clas) <+>
1212     ptext (sLit "cannot have generic methods")
1213
1214 badGenericMethodType :: Name -> Kind -> SDoc
1215 badGenericMethodType op op_ty
1216   = hang (ptext (sLit "Generic method type is too complex"))
1217        4 (vcat [ppr op <+> dcolon <+> ppr op_ty,
1218                 ptext (sLit "You can only use type variables, arrows, lists, and tuples")])
1219
1220 recSynErr :: [LTyClDecl Name] -> TcRn ()
1221 recSynErr syn_decls
1222   = setSrcSpan (getLoc (head sorted_decls)) $
1223     addErr (sep [ptext (sLit "Cycle in type synonym declarations:"),
1224                  nest 2 (vcat (map ppr_decl sorted_decls))])
1225   where
1226     sorted_decls = sortLocated syn_decls
1227     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr decl
1228
1229 recClsErr :: [Located (TyClDecl Name)] -> TcRn ()
1230 recClsErr cls_decls
1231   = setSrcSpan (getLoc (head sorted_decls)) $
1232     addErr (sep [ptext (sLit "Cycle in class declarations (via superclasses):"),
1233                  nest 2 (vcat (map ppr_decl sorted_decls))])
1234   where
1235     sorted_decls = sortLocated cls_decls
1236     ppr_decl (L loc decl) = ppr loc <> colon <+> ppr (decl { tcdSigs = [] })
1237
1238 sortLocated :: [Located a] -> [Located a]
1239 sortLocated things = sortLe le things
1240   where
1241     le (L l1 _) (L l2 _) = l1 <= l2
1242
1243 badDataConTyCon :: DataCon -> SDoc
1244 badDataConTyCon data_con
1245   = hang (ptext (sLit "Data constructor") <+> quotes (ppr data_con) <+>
1246                 ptext (sLit "returns type") <+> quotes (ppr (dataConTyCon data_con)))
1247        2 (ptext (sLit "instead of its parent type"))
1248
1249 badGadtDecl :: Name -> SDoc
1250 badGadtDecl tc_name
1251   = vcat [ ptext (sLit "Illegal generalised algebraic data declaration for") <+> quotes (ppr tc_name)
1252          , nest 2 (parens $ ptext (sLit "Use -XGADTs to allow GADTs")) ]
1253
1254 badExistential :: Located Name -> SDoc
1255 badExistential con_name
1256   = hang (ptext (sLit "Data constructor") <+> quotes (ppr con_name) <+>
1257                 ptext (sLit "has existential type variables, or a context"))
1258        2 (parens $ ptext (sLit "Use -XExistentialQuantification or -XGADTs to allow this"))
1259
1260 badStupidTheta :: Name -> SDoc
1261 badStupidTheta tc_name
1262   = ptext (sLit "A data type declared in GADT style cannot have a context:") <+> quotes (ppr tc_name)
1263
1264 newtypeConError :: Name -> Int -> SDoc
1265 newtypeConError tycon n
1266   = sep [ptext (sLit "A newtype must have exactly one constructor,"),
1267          nest 2 $ ptext (sLit "but") <+> quotes (ppr tycon) <+> ptext (sLit "has") <+> speakN n ]
1268
1269 newtypeExError :: DataCon -> SDoc
1270 newtypeExError con
1271   = sep [ptext (sLit "A newtype constructor cannot have an existential context,"),
1272          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does")]
1273
1274 newtypeStrictError :: DataCon -> SDoc
1275 newtypeStrictError con
1276   = sep [ptext (sLit "A newtype constructor cannot have a strictness annotation,"),
1277          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does")]
1278
1279 newtypePredError :: DataCon -> SDoc
1280 newtypePredError con
1281   = sep [ptext (sLit "A newtype constructor must have a return type of form T a1 ... an"),
1282          nest 2 $ ptext (sLit "but") <+> quotes (ppr con) <+> ptext (sLit "does not")]
1283
1284 newtypeFieldErr :: DataCon -> Int -> SDoc
1285 newtypeFieldErr con_name n_flds
1286   = sep [ptext (sLit "The constructor of a newtype must have exactly one field"),
1287          nest 2 $ ptext (sLit "but") <+> quotes (ppr con_name) <+> ptext (sLit "has") <+> speakN n_flds]
1288
1289 badSigTyDecl :: Name -> SDoc
1290 badSigTyDecl tc_name
1291   = vcat [ ptext (sLit "Illegal kind signature") <+>
1292            quotes (ppr tc_name)
1293          , nest 2 (parens $ ptext (sLit "Use -XKindSignatures to allow kind signatures")) ]
1294
1295 badFamInstDecl :: Outputable a => a -> SDoc
1296 badFamInstDecl tc_name
1297   = vcat [ ptext (sLit "Illegal family instance for") <+>
1298            quotes (ppr tc_name)
1299          , nest 2 (parens $ ptext (sLit "Use -XTypeFamilies to allow indexed type families")) ]
1300
1301 badGadtIdxTyDecl :: Name -> SDoc
1302 badGadtIdxTyDecl tc_name
1303   = vcat [ ptext (sLit "Illegal generalised algebraic data declaration for") <+>
1304            quotes (ppr tc_name)
1305          , nest 2 (parens $ ptext (sLit "Family instances can not yet use GADT declarations")) ]
1306
1307 tooManyParmsErr :: Located Name -> SDoc
1308 tooManyParmsErr tc_name
1309   = ptext (sLit "Family instance has too many parameters:") <+>
1310     quotes (ppr tc_name)
1311
1312 tooFewParmsErr :: Arity -> SDoc
1313 tooFewParmsErr arity
1314   = ptext (sLit "Family instance has too few parameters; expected") <+>
1315     ppr arity
1316
1317 wrongNumberOfParmsErr :: Arity -> SDoc
1318 wrongNumberOfParmsErr exp_arity
1319   = ptext (sLit "Number of parameters must match family declaration; expected")
1320     <+> ppr exp_arity
1321
1322 badBootFamInstDeclErr :: SDoc
1323 badBootFamInstDeclErr =
1324   ptext (sLit "Illegal family instance in hs-boot file")
1325
1326 wrongKindOfFamily :: TyCon -> SDoc
1327 wrongKindOfFamily family =
1328   ptext (sLit "Wrong category of family instance; declaration was for a") <+>
1329   kindOfFamily
1330   where
1331     kindOfFamily | isSynTyCon family = ptext (sLit "type synonym")
1332                  | isAlgTyCon family = ptext (sLit "data type")
1333                  | otherwise = pprPanic "wrongKindOfFamily" (ppr family)
1334
1335 emptyConDeclsErr :: Name -> SDoc
1336 emptyConDeclsErr tycon
1337   = sep [quotes (ppr tycon) <+> ptext (sLit "has no constructors"),
1338          nest 2 $ ptext (sLit "(-XEmptyDataDecls permits this)")]
1339 \end{code}