compiler/typecheck/TcType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcType]{Types used in the typechecker}
   6
   7 This module provides the Type interface for front-end parts of the
   8 compiler.  These parts
   9
  10         * treat "source types" as opaque:
  11                 newtypes, and predicates are meaningful.
  12         * look through usage types
  13
  14 The "tc" prefix is for "TypeChecker", because the type checker
  15 is the principal client.
  16
  17 \begin{code}
  18 module TcType (
  19   --------------------------------
  20   -- Types
  21   TcType, TcSigmaType, TcRhoType, TcTauType, TcPredType, TcThetaType,
  22   TcTyVar, TcTyVarSet, TcKind,
  23
  24   BoxyTyVar, BoxySigmaType, BoxyRhoType, BoxyThetaType, BoxyType,
  25
  26   --------------------------------
  27   -- MetaDetails
  28   UserTypeCtxt(..), pprUserTypeCtxt,
  29   TcTyVarDetails(..), BoxInfo(..), pprTcTyVarDetails,
  30   MetaDetails(Flexi, Indirect), SkolemInfo(..), pprSkolTvBinding, pprSkolInfo,
  31   isImmutableTyVar, isSkolemTyVar, isMetaTyVar, isBoxyTyVar,
  32   isSigTyVar, isExistentialTyVar,  isTyConableTyVar,
  33   metaTvRef,
  34   isFlexi, isIndirect,
  35
  36   --------------------------------
  37   -- Builders
  38   mkPhiTy, mkSigmaTy,
  39
  40   --------------------------------
  41   -- Splitters
  42   -- These are important because they do not look through newtypes
  43   tcView,
  44   tcSplitForAllTys, tcSplitPhiTy,
  45   tcSplitFunTy_maybe, tcSplitFunTys, tcFunArgTy, tcFunResultTy, tcSplitFunTysN,
  46   tcSplitTyConApp, tcSplitTyConApp_maybe, tcTyConAppTyCon, tcTyConAppArgs,
  47   tcSplitAppTy_maybe, tcSplitAppTy, tcSplitAppTys, repSplitAppTy_maybe,
  48   tcInstHeadTyNotSynonym, tcInstHeadTyAppAllTyVars,
  49   tcGetTyVar_maybe, tcGetTyVar,
  50   tcSplitSigmaTy, tcMultiSplitSigmaTy,
  51
  52   ---------------------------------
  53   -- Predicates.
  54   -- Again, newtypes are opaque
  55   tcEqType, tcEqTypes, tcEqPred, tcCmpType, tcCmpTypes, tcCmpPred, tcEqTypeX,
  56   eqKind,
  57   isSigmaTy, isOverloadedTy, isRigidTy, isBoxyTy,
  58   isDoubleTy, isFloatTy, isIntTy, isStringTy,
  59   isIntegerTy, isBoolTy, isUnitTy, isCharTy,
  60   isTauTy, isTauTyCon, tcIsTyVarTy, tcIsForAllTy,
  61
  62   ---------------------------------
  63   -- Misc type manipulators
  64   deNoteType,
  65   tyClsNamesOfType, tyClsNamesOfDFunHead,
  66   getDFunTyKey,
  67
  68   ---------------------------------
  69   -- Predicate types
  70   getClassPredTys_maybe, getClassPredTys,
  71   isClassPred, isTyVarClassPred, isEqPred,
  72   mkDictTy, tcSplitPredTy_maybe,
  73   isPredTy, isDictTy, tcSplitDFunTy, tcSplitDFunHead, predTyUnique,
  74   mkClassPred, isInheritablePred, isIPPred,
  75   dataConsStupidTheta, isRefineableTy, isRefineablePred,
  76
  77   ---------------------------------
  78   -- Foreign import and export
  79   isFFIArgumentTy,     -- :: DynFlags -> Safety -> Type -> Bool
  80   isFFIImportResultTy, -- :: DynFlags -> Type -> Bool
  81   isFFIExportResultTy, -- :: Type -> Bool
  82   isFFIExternalTy,     -- :: Type -> Bool
  83   isFFIDynArgumentTy,  -- :: Type -> Bool
  84   isFFIDynResultTy,    -- :: Type -> Bool
  85   isFFILabelTy,        -- :: Type -> Bool
  86   isFFIDotnetTy,       -- :: DynFlags -> Type -> Bool
  87   isFFIDotnetObjTy,    -- :: Type -> Bool
  88   isFFITy,             -- :: Type -> Bool
  89   tcSplitIOType_maybe, -- :: Type -> Maybe Type
  90   toDNType,            -- :: Type -> DNType
  91
  92   --------------------------------
  93   -- Rexported from Type
  94   Kind,         -- Stuff to do with kinds is insensitive to pre/post Tc
  95   unliftedTypeKind, liftedTypeKind, argTypeKind,
  96   openTypeKind, mkArrowKind, mkArrowKinds,
  97   isLiftedTypeKind, isUnliftedTypeKind, isSubOpenTypeKind,
  98   isSubArgTypeKind, isSubKind, defaultKind,
  99   kindVarRef, mkKindVar,
 100
 101   Type, PredType(..), ThetaType,
 102   mkForAllTy, mkForAllTys,
 103   mkFunTy, mkFunTys, zipFunTys,
 104   mkTyConApp, mkAppTy, mkAppTys, applyTy, applyTys,
 105   mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
 106
 107   -- Type substitutions
 108   TvSubst(..),  -- Representation visible to a few friends
 109   TvSubstEnv, emptyTvSubst, substEqSpec,
 110   mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst, mkTopTvSubst, notElemTvSubst,
 111   getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope, lookupTyVar,
 112   extendTvSubst, extendTvSubstList, isInScope, mkTvSubst, zipTyEnv,
 113   substTy, substTys, substTyWith, substTheta, substTyVar, substTyVars, substTyVarBndr,
 114
 115   isUnLiftedType,       -- Source types are always lifted
 116   isUnboxedTupleType,   -- Ditto
 117   isPrimitiveType,
 118
 119   tidyTopType, tidyType, tidyPred, tidyTypes, tidyFreeTyVars, tidyOpenType, tidyOpenTypes,
 120   tidyTyVarBndr, tidyOpenTyVar, tidyOpenTyVars, tidySkolemTyVar,
 121   typeKind, tidyKind,
 122
 123   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
 124   tcTyVarsOfType, tcTyVarsOfTypes, exactTyVarsOfType, exactTyVarsOfTypes,
 125
 126   pprKind, pprParendKind,
 127   pprType, pprParendType, pprTypeApp, pprTyThingCategory,
 128   pprPred, pprTheta, pprThetaArrow, pprClassPred
 129
 130   ) where
 131
 132 #include "HsVersions.h"
 133
 134 -- friends:
 135 import TypeRep
 136 import DataCon
 137 import Class
 138 import Var
 139 import ForeignCall
 140 import Unify
 141 import VarSet
 142 import Type
 143 import TyCon
 144
 145 -- others:
 146 import DynFlags
 147 import CoreSyn
 148 import Name
 149 import NameSet
 150 import VarEnv
 151 import OccName
 152 import PrelNames
 153 import TysWiredIn
 154 import BasicTypes
 155 import Util
 156 import Maybes
 157 import ListSetOps
 158 import Outputable
 159
 160 import Data.List
 161 import Data.IORef
 162 \end{code}
 163
 164
 165 %************************************************************************
 166 %*                                                                      *
 167 \subsection{Types}
 168 %*                                                                      *
 169 %************************************************************************
 170
 171 The type checker divides the generic Type world into the
 172 following more structured beasts:
 173
 174 sigma ::= forall tyvars. phi
 175         -- A sigma type is a qualified type
 176         --
 177         -- Note that even if 'tyvars' is empty, theta
 178         -- may not be: e.g.   (?x::Int) => Int
 179
 180         -- Note that 'sigma' is in prenex form:
 181         -- all the foralls are at the front.
 182         -- A 'phi' type has no foralls to the right of
 183         -- an arrow
 184
 185 phi :: theta => rho
 186
 187 rho ::= sigma -> rho
 188      |  tau
 189
 190 -- A 'tau' type has no quantification anywhere
 191 -- Note that the args of a type constructor must be taus
 192 tau ::= tyvar
 193      |  tycon tau_1 .. tau_n
 194      |  tau_1 tau_2
 195      |  tau_1 -> tau_2
 196
 197 -- In all cases, a (saturated) type synonym application is legal,
 198 -- provided it expands to the required form.
 199
 200 \begin{code}
 201 type TcTyVar = TyVar    -- Used only during type inference
 202 type TcType = Type      -- A TcType can have mutable type variables
 203         -- Invariant on ForAllTy in TcTypes:
 204         --      forall a. T
 205         -- a cannot occur inside a MutTyVar in T; that is,
 206         -- T is "flattened" before quantifying over a
 207
 208 -- These types do not have boxy type variables in them
 209 type TcPredType     = PredType
 210 type TcThetaType    = ThetaType
 211 type TcSigmaType    = TcType
 212 type TcRhoType      = TcType
 213 type TcTauType      = TcType
 214 type TcKind         = Kind
 215 type TcTyVarSet     = TyVarSet
 216
 217 -- These types may have boxy type variables in them
 218 type BoxyTyVar      = TcTyVar
 219 type BoxyRhoType    = TcType
 220 type BoxyThetaType  = TcThetaType
 221 type BoxySigmaType  = TcType
 222 type BoxyType       = TcType
 223 \end{code}
 224
 225
 226 %************************************************************************
 227 %*                                                                      *
 228 \subsection{TyVarDetails}
 229 %*                                                                      *
 230 %************************************************************************
 231
 232 TyVarDetails gives extra info about type variables, used during type
 233 checking.  It's attached to mutable type variables only.
 234 It's knot-tied back to Var.lhs.  There is no reason in principle
 235 why Var.lhs shouldn't actually have the definition, but it "belongs" here.
 236
 237
 238 Note [Signature skolems]
 239 ~~~~~~~~~~~~~~~~~~~~~~~~
 240 Consider this
 241
 242   x :: [a]
 243   y :: b
 244   (x,y,z) = ([y,z], z, head x)
 245
 246 Here, x and y have type sigs, which go into the environment.  We used to
 247 instantiate their types with skolem constants, and push those types into
 248 the RHS, so we'd typecheck the RHS with type
 249         ( [a*], b*, c )
 250 where a*, b* are skolem constants, and c is an ordinary meta type varible.
 251
 252 The trouble is that the occurrences of z in the RHS force a* and b* to
 253 be the *same*, so we can't make them into skolem constants that don't unify
 254 with each other.  Alas.
 255
 256 One solution would be insist that in the above defn the programmer uses
 257 the same type variable in both type signatures.  But that takes explanation.
 258
 259 The alternative (currently implemented) is to have a special kind of skolem
 260 constant, SigTv, which can unify with other SigTvs.  These are *not* treated
 261 as righd for the purposes of GADTs.  And they are used *only* for pattern
 262 bindings and mutually recursive function bindings.  See the function
 263 TcBinds.tcInstSig, and its use_skols parameter.
 264
 265
 266 \begin{code}
 267 -- A TyVarDetails is inside a TyVar
 268 data TcTyVarDetails
 269   = SkolemTv SkolemInfo                 -- A skolem constant
 270
 271   | MetaTv BoxInfo (IORef MetaDetails)
 272
 273 data BoxInfo
 274    = BoxTv      -- The contents is a (non-boxy) sigma-type
 275                 -- That is, this MetaTv is a "box"
 276
 277    | TauTv      -- The contents is a (non-boxy) tau-type
 278                 -- That is, this MetaTv is an ordinary unification variable
 279
 280    | SigTv SkolemInfo   -- A variant of TauTv, except that it should not be
 281                         -- unified with a type, only with a type variable
 282                         -- SigTvs are only distinguished to improve error messages
 283                         --      see Note [Signature skolems]
 284                         --      The MetaDetails, if filled in, will
 285                         --      always be another SigTv or a SkolemTv
 286
 287 -- INVARIANTS:
 288 --      A TauTv is always filled in with a tau-type, which
 289 --      never contains any BoxTvs, nor any ForAlls
 290 --
 291 --      However, a BoxTv can contain a type that contains further BoxTvs
 292 --      Notably, when typechecking an explicit list, say [e1,e2], with
 293 --      expected type being a box b1, we fill in b1 with (List b2), where
 294 --      b2 is another (currently empty) box.
 295
 296 data MetaDetails
 297   = Flexi          -- Flexi type variables unify to become
 298                    -- Indirects.
 299
 300   | Indirect TcType  -- INVARIANT:
 301                      --   For a BoxTv, this type must be non-boxy
 302                      --   For a TauTv, this type must be a tau-type
 303
 304 -- Generally speaking, SkolemInfo should not contain location info
 305 -- that is contained in the Name of the tyvar with this SkolemInfo
 306 data SkolemInfo
 307   = SigSkol UserTypeCtxt        -- A skolem that is created by instantiating
 308                                 -- a programmer-supplied type signature
 309                                 -- Location of the binding site is on the TyVar
 310
 311         -- The rest are for non-scoped skolems
 312   | ClsSkol Class       -- Bound at a class decl
 313   | InstSkol            -- Bound at an instance decl
 314   | FamInstSkol         -- Bound at a family instance decl
 315   | PatSkol DataCon     -- An existential type variable bound by a pattern for
 316                         -- a data constructor with an existential type. E.g.
 317                         --      data T = forall a. Eq a => MkT a
 318                         --      f (MkT x) = ...
 319                         -- The pattern MkT x will allocate an existential type
 320                         -- variable for 'a'.
 321   | ArrowSkol           -- An arrow form (see TcArrows)
 322
 323   | RuleSkol RuleName   -- The LHS of a RULE
 324   | GenSkol [TcTyVar]   -- Bound when doing a subsumption check for
 325             TcType      --      (forall tvs. ty)
 326
 327   | RuntimeUnkSkol      -- a type variable used to represent an unknown
 328                         -- runtime type (used in the GHCi debugger)
 329
 330   | UnkSkol             -- Unhelpful info (until I improve it)
 331
 332 -------------------------------------
 333 -- UserTypeCtxt describes the places where a
 334 -- programmer-written type signature can occur
 335 -- Like SkolemInfo, no location info
 336 data UserTypeCtxt
 337   = FunSigCtxt Name     -- Function type signature
 338                         -- Also used for types in SPECIALISE pragmas
 339   | ExprSigCtxt         -- Expression type signature
 340   | ConArgCtxt Name     -- Data constructor argument
 341   | TySynCtxt Name      -- RHS of a type synonym decl
 342   | GenPatCtxt          -- Pattern in generic decl
 343                         --      f{| a+b |} (Inl x) = ...
 344   | LamPatSigCtxt               -- Type sig in lambda pattern
 345                         --      f (x::t) = ...
 346   | BindPatSigCtxt      -- Type sig in pattern binding pattern
 347                         --      (x::t, y) = e
 348   | ResSigCtxt          -- Result type sig
 349                         --      f x :: t = ....
 350   | ForSigCtxt Name     -- Foreign inport or export signature
 351   | DefaultDeclCtxt     -- Types in a default declaration
 352   | SpecInstCtxt        -- SPECIALISE instance pragma
 353
 354 -- Notes re TySynCtxt
 355 -- We allow type synonyms that aren't types; e.g.  type List = []
 356 --
 357 -- If the RHS mentions tyvars that aren't in scope, we'll
 358 -- quantify over them:
 359 --      e.g.    type T = a->a
 360 -- will become  type T = forall a. a->a
 361 --
 362 -- With gla-exts that's right, but for H98 we should complain.
 363
 364 ---------------------------------
 365 -- Kind variables:
 366
 367 mkKindName :: Unique -> Name
 368 mkKindName unique = mkSystemName unique kind_var_occ
 369
 370 kindVarRef :: KindVar -> IORef MetaDetails
 371 kindVarRef tc =
 372   ASSERT ( isTcTyVar tc )
 373   case tcTyVarDetails tc of
 374     MetaTv TauTv ref -> ref
 375     other            -> pprPanic "kindVarRef" (ppr tc)
 376
 377 mkKindVar :: Unique -> IORef MetaDetails -> KindVar
 378 mkKindVar u r
 379   = mkTcTyVar (mkKindName u)
 380               tySuperKind  -- not sure this is right,
 381                             -- do we need kind vars for
 382                             -- coercions?
 383               (MetaTv TauTv r)
 384
 385 kind_var_occ :: OccName -- Just one for all KindVars
 386                         -- They may be jiggled by tidying
 387 kind_var_occ = mkOccName tvName "k"
 388 \end{code}
 389 \end{code}
 390
 391 %************************************************************************
 392 %*                                                                      *
 393                 Pretty-printing
 394 %*                                                                      *
 395 %************************************************************************
 396
 397 \begin{code}
 398 pprTcTyVarDetails :: TcTyVarDetails -> SDoc
 399 -- For debugging
 400 pprTcTyVarDetails (SkolemTv _)         = ptext SLIT("sk")
 401 pprTcTyVarDetails (MetaTv BoxTv _)     = ptext SLIT("box")
 402 pprTcTyVarDetails (MetaTv TauTv _)     = ptext SLIT("tau")
 403 pprTcTyVarDetails (MetaTv (SigTv _) _) = ptext SLIT("sig")
 404
 405 pprUserTypeCtxt :: UserTypeCtxt -> SDoc
 406 pprUserTypeCtxt (FunSigCtxt n)  = ptext SLIT("the type signature for") <+> quotes (ppr n)
 407 pprUserTypeCtxt ExprSigCtxt     = ptext SLIT("an expression type signature")
 408 pprUserTypeCtxt (ConArgCtxt c)  = ptext SLIT("the type of the constructor") <+> quotes (ppr c)
 409 pprUserTypeCtxt (TySynCtxt c)   = ptext SLIT("the RHS of the type synonym") <+> quotes (ppr c)
 410 pprUserTypeCtxt GenPatCtxt      = ptext SLIT("the type pattern of a generic definition")
 411 pprUserTypeCtxt LamPatSigCtxt   = ptext SLIT("a pattern type signature")
 412 pprUserTypeCtxt BindPatSigCtxt  = ptext SLIT("a pattern type signature")
 413 pprUserTypeCtxt ResSigCtxt      = ptext SLIT("a result type signature")
 414 pprUserTypeCtxt (ForSigCtxt n)  = ptext SLIT("the foreign declaration for") <+> quotes (ppr n)
 415 pprUserTypeCtxt DefaultDeclCtxt = ptext SLIT("a type in a `default' declaration")
 416 pprUserTypeCtxt SpecInstCtxt    = ptext SLIT("a SPECIALISE instance pragma")
 417
 418
 419 --------------------------------
 420 tidySkolemTyVar :: TidyEnv -> TcTyVar -> (TidyEnv, TcTyVar)
 421 -- Tidy the type inside a GenSkol, preparatory to printing it
 422 tidySkolemTyVar env tv
 423   = ASSERT( isSkolemTyVar tv || isSigTyVar tv )
 424     (env1, mkTcTyVar (tyVarName tv) (tyVarKind tv) info1)
 425   where
 426     (env1, info1) = case tcTyVarDetails tv of
 427                         SkolemTv info -> (env1, SkolemTv info')
 428                                 where
 429                                   (env1, info') = tidy_skol_info env info
 430                         MetaTv (SigTv info) box -> (env1, MetaTv (SigTv info') box)
 431                                 where
 432                                   (env1, info') = tidy_skol_info env info
 433                         info -> (env, info)
 434
 435     tidy_skol_info env (GenSkol tvs ty) = (env2, GenSkol tvs1 ty1)
 436                             where
 437                               (env1, tvs1) = tidyOpenTyVars env tvs
 438                               (env2, ty1)  = tidyOpenType env1 ty
 439     tidy_skol_info env info = (env, info)
 440
 441 pprSkolTvBinding :: TcTyVar -> SDoc
 442 -- Print info about the binding of a skolem tyvar,
 443 -- or nothing if we don't have anything useful to say
 444 pprSkolTvBinding tv
 445   = ASSERT ( isTcTyVar tv )
 446     quotes (ppr tv) <+> ppr_details (tcTyVarDetails tv)
 447   where
 448     ppr_details (MetaTv TauTv _)        = ptext SLIT("is a meta type variable")
 449     ppr_details (MetaTv BoxTv _)        = ptext SLIT("is a boxy type variable")
 450     ppr_details (MetaTv (SigTv info) _) = ppr_skol info
 451     ppr_details (SkolemTv info)         = ppr_skol info
 452
 453     ppr_skol UnkSkol        = empty     -- Unhelpful; omit
 454     ppr_skol RuntimeUnkSkol = ptext SLIT("is an unknown runtime type")
 455     ppr_skol info           = sep [ptext SLIT("is a rigid type variable bound by"),
 456                                    sep [pprSkolInfo info,
 457                                          nest 2 (ptext SLIT("at") <+> ppr (getSrcLoc tv))]]
 458
 459 pprSkolInfo :: SkolemInfo -> SDoc
 460 pprSkolInfo (SigSkol ctxt)   = pprUserTypeCtxt ctxt
 461 pprSkolInfo (ClsSkol cls)    = ptext SLIT("the class declaration for") <+> quotes (ppr cls)
 462 pprSkolInfo InstSkol         = ptext SLIT("the instance declaration")
 463 pprSkolInfo FamInstSkol      = ptext SLIT("the family instance declaration")
 464 pprSkolInfo (RuleSkol name)  = ptext SLIT("the RULE") <+> doubleQuotes (ftext name)
 465 pprSkolInfo ArrowSkol        = ptext SLIT("the arrow form")
 466 pprSkolInfo (PatSkol dc)     = sep [ptext SLIT("the constructor") <+> quotes (ppr dc)]
 467 pprSkolInfo (GenSkol tvs ty) = sep [ptext SLIT("the polymorphic type"),
 468                                     nest 2 (quotes (ppr (mkForAllTys tvs ty)))]
 469
 470 -- UnkSkol
 471 -- For type variables the others are dealt with by pprSkolTvBinding.
 472 -- For Insts, these cases should not happen
 473 pprSkolInfo UnkSkol = panic "UnkSkol"
 474 pprSkolInfo RuntimeUnkSkol = panic "RuntimeUnkSkol"
 475
 476 instance Outputable MetaDetails where
 477   ppr Flexi         = ptext SLIT("Flexi")
 478   ppr (Indirect ty) = ptext SLIT("Indirect") <+> ppr ty
 479 \end{code}
 480
 481
 482 %************************************************************************
 483 %*                                                                      *
 484                 Predicates
 485 %*                                                                      *
 486 %************************************************************************
 487
 488 \begin{code}
 489 isImmutableTyVar :: TyVar -> Bool
 490
 491 isImmutableTyVar tv
 492   | isTcTyVar tv = isSkolemTyVar tv
 493   | otherwise    = True
 494
 495 isTyConableTyVar, isSkolemTyVar, isExistentialTyVar,
 496   isBoxyTyVar, isMetaTyVar :: TcTyVar -> Bool
 497
 498 isTyConableTyVar tv
 499         -- True of a meta-type variable tha can be filled in
 500         -- with a type constructor application; in particular,
 501         -- not a SigTv
 502   = ASSERT( isTcTyVar tv)
 503     case tcTyVarDetails tv of
 504         MetaTv BoxTv      _ -> True
 505         MetaTv TauTv      _ -> True
 506         MetaTv (SigTv {}) _ -> False
 507         SkolemTv {}         -> False
 508
 509 isSkolemTyVar tv
 510   = ASSERT( isTcTyVar tv )
 511     case tcTyVarDetails tv of
 512         SkolemTv _         -> True
 513         MetaTv _ _         -> False
 514
 515 isExistentialTyVar tv   -- Existential type variable, bound by a pattern
 516   = ASSERT( isTcTyVar tv )
 517     case tcTyVarDetails tv of
 518         SkolemTv (PatSkol {}) -> True
 519         other                 -> False
 520
 521 isMetaTyVar tv
 522   = ASSERT2( isTcTyVar tv, ppr tv )
 523     case tcTyVarDetails tv of
 524         MetaTv _ _ -> True
 525         other      -> False
 526
 527 isBoxyTyVar tv
 528   = ASSERT( isTcTyVar tv )
 529     case tcTyVarDetails tv of
 530         MetaTv BoxTv _ -> True
 531         other          -> False
 532
 533 isSigTyVar tv
 534   = ASSERT( isTcTyVar tv )
 535     case tcTyVarDetails tv of
 536         MetaTv (SigTv _) _ -> True
 537         other              -> False
 538
 539 metaTvRef :: TyVar -> IORef MetaDetails
 540 metaTvRef tv
 541   = ASSERT( isTcTyVar tv )
 542     case tcTyVarDetails tv of
 543         MetaTv _ ref -> ref
 544         other      -> pprPanic "metaTvRef" (ppr tv)
 545
 546 isFlexi, isIndirect :: MetaDetails -> Bool
 547 isFlexi Flexi = True
 548 isFlexi other = False
 549
 550 isIndirect (Indirect _) = True
 551 isIndirect other        = False
 552 \end{code}
 553
 554
 555 %************************************************************************
 556 %*                                                                      *
 557 \subsection{Tau, sigma and rho}
 558 %*                                                                      *
 559 %************************************************************************
 560
 561 \begin{code}
 562 mkSigmaTy :: [TyVar] -> [PredType] -> Type -> Type
 563 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkPhiTy theta tau)
 564
 565 mkPhiTy :: [PredType] -> Type -> Type
 566 mkPhiTy theta ty = foldr (\p r -> mkFunTy (mkPredTy p) r) ty theta
 567 \end{code}
 568
 569 @isTauTy@ tests for nested for-alls.  It should not be called on a boxy type.
 570
 571 \begin{code}
 572 isTauTy :: Type -> Bool
 573 isTauTy ty | Just ty' <- tcView ty = isTauTy ty'
 574 isTauTy (TyVarTy tv)     = ASSERT( not (isTcTyVar tv && isBoxyTyVar tv) )
 575                            True
 576 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
 577 isTauTy (AppTy a b)       = isTauTy a && isTauTy b
 578 isTauTy (FunTy a b)       = isTauTy a && isTauTy b
 579 isTauTy (PredTy p)        = True                -- Don't look through source types
 580 isTauTy other             = False
 581
 582
 583 isTauTyCon :: TyCon -> Bool
 584 -- Returns False for type synonyms whose expansion is a polytype
 585 isTauTyCon tc
 586   | isClosedSynTyCon tc = isTauTy (snd (synTyConDefn tc))
 587   | otherwise           = True
 588
 589 ---------------
 590 isBoxyTy :: TcType -> Bool
 591 isBoxyTy ty = any isBoxyTyVar (varSetElems (tcTyVarsOfType ty))
 592
 593 isRigidTy :: TcType -> Bool
 594 -- A type is rigid if it has no meta type variables in it
 595 isRigidTy ty = all isImmutableTyVar (varSetElems (tcTyVarsOfType ty))
 596
 597 isRefineableTy :: TcType -> Bool
 598 -- A type should have type refinements applied to it if it has
 599 -- free type variables, and they are all rigid
 600 isRefineableTy ty = not (null tc_tvs) && all isImmutableTyVar tc_tvs
 601                     where
 602                       tc_tvs = varSetElems (tcTyVarsOfType ty)
 603
 604 isRefineablePred :: TcPredType -> Bool
 605 isRefineablePred pred = not (null tc_tvs) && all isImmutableTyVar tc_tvs
 606                       where
 607                         tc_tvs = varSetElems (tcTyVarsOfPred pred)
 608
 609 ---------------
 610 getDFunTyKey :: Type -> OccName -- Get some string from a type, to be used to
 611                                 -- construct a dictionary function name
 612 getDFunTyKey ty | Just ty' <- tcView ty = getDFunTyKey ty'
 613 getDFunTyKey (TyVarTy tv)    = getOccName tv
 614 getDFunTyKey (TyConApp tc _) = getOccName tc
 615 getDFunTyKey (AppTy fun _)   = getDFunTyKey fun
 616 getDFunTyKey (FunTy arg _)   = getOccName funTyCon
 617 getDFunTyKey (ForAllTy _ t)  = getDFunTyKey t
 618 getDFunTyKey ty              = pprPanic "getDFunTyKey" (pprType ty)
 619 -- PredTy shouldn't happen
 620 \end{code}
 621
 622
 623 %************************************************************************
 624 %*                                                                      *
 625 \subsection{Expanding and splitting}
 626 %*                                                                      *
 627 %************************************************************************
 628
 629 These tcSplit functions are like their non-Tc analogues, but
 630         a) they do not look through newtypes
 631         b) they do not look through PredTys
 632         c) [future] they ignore usage-type annotations
 633
 634 However, they are non-monadic and do not follow through mutable type
 635 variables.  It's up to you to make sure this doesn't matter.
 636
 637 \begin{code}
 638 tcSplitForAllTys :: Type -> ([TyVar], Type)
 639 tcSplitForAllTys ty = split ty ty []
 640    where
 641      split orig_ty ty tvs | Just ty' <- tcView ty = split orig_ty ty' tvs
 642      split orig_ty (ForAllTy tv ty) tvs
 643        | not (isCoVar tv) = split ty ty (tv:tvs)
 644      split orig_ty t tvs = (reverse tvs, orig_ty)
 645
 646 tcIsForAllTy ty | Just ty' <- tcView ty = tcIsForAllTy ty'
 647 tcIsForAllTy (ForAllTy tv ty) = not (isCoVar tv)
 648 tcIsForAllTy t                = False
 649
 650 tcSplitPhiTy :: Type -> (ThetaType, Type)
 651 tcSplitPhiTy ty = split ty ty []
 652  where
 653   split orig_ty ty tvs | Just ty' <- tcView ty = split orig_ty ty' tvs
 654
 655   split orig_ty (ForAllTy tv ty) ts
 656         | isCoVar tv = split ty ty (eq_pred:ts)
 657         where
 658            PredTy eq_pred = tyVarKind tv
 659   split orig_ty (FunTy arg res) ts
 660         | Just p <- tcSplitPredTy_maybe arg = split res res (p:ts)
 661   split orig_ty ty              ts = (reverse ts, orig_ty)
 662
 663 tcSplitSigmaTy :: Type -> ([TyVar], ThetaType, Type)
 664 tcSplitSigmaTy ty = case tcSplitForAllTys ty of
 665                         (tvs, rho) -> case tcSplitPhiTy rho of
 666                                         (theta, tau) -> (tvs, theta, tau)
 667
 668 -----------------------
 669 tcMultiSplitSigmaTy
 670         :: TcSigmaType
 671         -> ( [([TyVar], ThetaType)],    -- forall as.C => forall bs.D
 672              TcSigmaType)               -- The rest of the type
 673
 674 -- We need a loop here because we are now prepared to entertain
 675 -- types like
 676 --      f:: forall a. Eq a => forall b. Baz b => tau
 677 -- We want to instantiate this to
 678 --      f2::tau         {f2 = f1 b (Baz b), f1 = f a (Eq a)}
 679
 680 tcMultiSplitSigmaTy sigma
 681   = case (tcSplitSigmaTy sigma) of
 682         ([],[],ty) -> ([], sigma)
 683         (tvs, theta, ty) -> case tcMultiSplitSigmaTy ty of
 684                                 (pairs, rest) -> ((tvs,theta):pairs, rest)
 685
 686 -----------------------
 687 tcTyConAppTyCon :: Type -> TyCon
 688 tcTyConAppTyCon ty = case tcSplitTyConApp_maybe ty of
 689                         Just (tc, _) -> tc
 690                         Nothing      -> pprPanic "tcTyConAppTyCon" (pprType ty)
 691
 692 tcTyConAppArgs :: Type -> [Type]
 693 tcTyConAppArgs ty = case tcSplitTyConApp_maybe ty of
 694                         Just (_, args) -> args
 695                         Nothing        -> pprPanic "tcTyConAppArgs" (pprType ty)
 696
 697 tcSplitTyConApp :: Type -> (TyCon, [Type])
 698 tcSplitTyConApp ty = case tcSplitTyConApp_maybe ty of
 699                         Just stuff -> stuff
 700                         Nothing    -> pprPanic "tcSplitTyConApp" (pprType ty)
 701
 702 tcSplitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 703 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
 704 tcSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 705 tcSplitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 706         -- Newtypes are opaque, so they may be split
 707         -- However, predicates are not treated
 708         -- as tycon applications by the type checker
 709 tcSplitTyConApp_maybe other             = Nothing
 710
 711 -----------------------
 712 tcSplitFunTys :: Type -> ([Type], Type)
 713 tcSplitFunTys ty = case tcSplitFunTy_maybe ty of
 714                         Nothing        -> ([], ty)
 715                         Just (arg,res) -> (arg:args, res')
 716                                        where
 717                                           (args,res') = tcSplitFunTys res
 718
 719 tcSplitFunTy_maybe :: Type -> Maybe (Type, Type)
 720 tcSplitFunTy_maybe ty | Just ty' <- tcView ty           = tcSplitFunTy_maybe ty'
 721 tcSplitFunTy_maybe (FunTy arg res) | not (isPredTy arg) = Just (arg, res)
 722 tcSplitFunTy_maybe other                                = Nothing
 723         -- Note the (not (isPredTy arg)) guard
 724         -- Consider     (?x::Int) => Bool
 725         -- We don't want to treat this as a function type!
 726         -- A concrete example is test tc230:
 727         --      f :: () -> (?p :: ()) => () -> ()
 728         --
 729         --      g = f () ()
 730
 731 tcSplitFunTysN
 732         :: TcRhoType
 733         -> Arity                -- N: Number of desired args
 734         -> ([TcSigmaType],      -- Arg types (N or fewer)
 735             TcSigmaType)        -- The rest of the type
 736
 737 tcSplitFunTysN ty n_args
 738   | n_args == 0
 739   = ([], ty)
 740   | Just (arg,res) <- tcSplitFunTy_maybe ty
 741   = case tcSplitFunTysN res (n_args - 1) of
 742         (args, res) -> (arg:args, res)
 743   | otherwise
 744   = ([], ty)
 745
 746 tcSplitFunTy  ty = expectJust "tcSplitFunTy" (tcSplitFunTy_maybe ty)
 747 tcFunArgTy    ty = fst (tcSplitFunTy ty)
 748 tcFunResultTy ty = snd (tcSplitFunTy ty)
 749
 750 -----------------------
 751 tcSplitAppTy_maybe :: Type -> Maybe (Type, Type)
 752 tcSplitAppTy_maybe ty | Just ty' <- tcView ty = tcSplitAppTy_maybe ty'
 753 tcSplitAppTy_maybe ty = repSplitAppTy_maybe ty
 754
 755 tcSplitAppTy :: Type -> (Type, Type)
 756 tcSplitAppTy ty = case tcSplitAppTy_maybe ty of
 757                     Just stuff -> stuff
 758                     Nothing    -> pprPanic "tcSplitAppTy" (pprType ty)
 759
 760 tcSplitAppTys :: Type -> (Type, [Type])
 761 tcSplitAppTys ty
 762   = go ty []
 763   where
 764     go ty args = case tcSplitAppTy_maybe ty of
 765                    Just (ty', arg) -> go ty' (arg:args)
 766                    Nothing         -> (ty,args)
 767
 768 -----------------------
 769 tcGetTyVar_maybe :: Type -> Maybe TyVar
 770 tcGetTyVar_maybe ty | Just ty' <- tcView ty = tcGetTyVar_maybe ty'
 771 tcGetTyVar_maybe (TyVarTy tv)   = Just tv
 772 tcGetTyVar_maybe other          = Nothing
 773
 774 tcGetTyVar :: String -> Type -> TyVar
 775 tcGetTyVar msg ty = expectJust msg (tcGetTyVar_maybe ty)
 776
 777 tcIsTyVarTy :: Type -> Bool
 778 tcIsTyVarTy ty = maybeToBool (tcGetTyVar_maybe ty)
 779
 780 -----------------------
 781 tcSplitDFunTy :: Type -> ([TyVar], [PredType], Class, [Type])
 782 -- Split the type of a dictionary function
 783 tcSplitDFunTy ty
 784   = case tcSplitSigmaTy ty   of { (tvs, theta, tau) ->
 785     case tcSplitDFunHead tau of { (clas, tys) ->
 786     (tvs, theta, clas, tys) }}
 787
 788 tcSplitDFunHead :: Type -> (Class, [Type])
 789 tcSplitDFunHead tau
 790   = case tcSplitPredTy_maybe tau of
 791         Just (ClassP clas tys) -> (clas, tys)
 792         other -> panic "tcSplitDFunHead"
 793
 794 tcInstHeadTyNotSynonym :: Type -> Bool
 795 -- Used in Haskell-98 mode, for the argument types of an instance head
 796 -- These must not be type synonyms, but everywhere else type synonyms
 797 -- are transparent, so we need a special function here
 798 tcInstHeadTyNotSynonym ty
 799   = case ty of
 800         NoteTy _ ty     -> tcInstHeadTyNotSynonym ty
 801         TyConApp tc tys -> not (isSynTyCon tc)
 802         _ -> True
 803
 804 tcInstHeadTyAppAllTyVars :: Type -> Bool
 805 -- Used in Haskell-98 mode, for the argument types of an instance head
 806 -- These must be a constructor applied to type variable arguments
 807 tcInstHeadTyAppAllTyVars ty
 808   = case ty of
 809         NoteTy _ ty     -> tcInstHeadTyAppAllTyVars ty
 810         TyConApp _ tys  -> ok tys
 811         FunTy arg res   -> ok [arg, res]
 812         other           -> False
 813   where
 814         -- Check that all the types are type variables,
 815         -- and that each is distinct
 816     ok tys = equalLength tvs tys && hasNoDups tvs
 817            where
 818              tvs = mapCatMaybes get_tv tys
 819
 820     get_tv (NoteTy _ ty) = get_tv ty    -- Again, do not look
 821     get_tv (TyVarTy tv)  = Just tv      -- through synonyms
 822     get_tv other         = Nothing
 823 \end{code}
 824
 825
 826
 827 %************************************************************************
 828 %*                                                                      *
 829 \subsection{Predicate types}
 830 %*                                                                      *
 831 %************************************************************************
 832
 833 \begin{code}
 834 tcSplitPredTy_maybe :: Type -> Maybe PredType
 835    -- Returns Just for predicates only
 836 tcSplitPredTy_maybe ty | Just ty' <- tcView ty = tcSplitPredTy_maybe ty'
 837 tcSplitPredTy_maybe (PredTy p)    = Just p
 838 tcSplitPredTy_maybe other         = Nothing
 839
 840 predTyUnique :: PredType -> Unique
 841 predTyUnique (IParam n _)      = getUnique (ipNameName n)
 842 predTyUnique (ClassP clas tys) = getUnique clas
 843 \end{code}
 844
 845
 846 --------------------- Dictionary types ---------------------------------
 847
 848 \begin{code}
 849 mkClassPred clas tys = ClassP clas tys
 850
 851 isClassPred :: PredType -> Bool
 852 isClassPred (ClassP clas tys) = True
 853 isClassPred other             = False
 854
 855 isTyVarClassPred (ClassP clas tys) = all tcIsTyVarTy tys
 856 isTyVarClassPred other             = False
 857
 858 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
 859 getClassPredTys_maybe (ClassP clas tys) = Just (clas, tys)
 860 getClassPredTys_maybe _                 = Nothing
 861
 862 getClassPredTys :: PredType -> (Class, [Type])
 863 getClassPredTys (ClassP clas tys) = (clas, tys)
 864 getClassPredTys other = panic "getClassPredTys"
 865
 866 mkDictTy :: Class -> [Type] -> Type
 867 mkDictTy clas tys = mkPredTy (ClassP clas tys)
 868
 869 isDictTy :: Type -> Bool
 870 isDictTy ty | Just ty' <- tcView ty = isDictTy ty'
 871 isDictTy (PredTy p) = isClassPred p
 872 isDictTy other      = False
 873 \end{code}
 874
 875 --------------------- Implicit parameters ---------------------------------
 876
 877 \begin{code}
 878 isIPPred :: PredType -> Bool
 879 isIPPred (IParam _ _) = True
 880 isIPPred other        = False
 881
 882 isInheritablePred :: PredType -> Bool
 883 -- Can be inherited by a context.  For example, consider
 884 --      f x = let g y = (?v, y+x)
 885 --            in (g 3 with ?v = 8,
 886 --                g 4 with ?v = 9)
 887 -- The point is that g's type must be quantifed over ?v:
 888 --      g :: (?v :: a) => a -> a
 889 -- but it doesn't need to be quantified over the Num a dictionary
 890 -- which can be free in g's rhs, and shared by both calls to g
 891 isInheritablePred (ClassP _ _) = True
 892 isInheritablePred (EqPred _ _) = True
 893 isInheritablePred other        = False
 894 \end{code}
 895
 896 --------------------- Equality predicates ---------------------------------
 897 \begin{code}
 898 substEqSpec :: TvSubst -> [(TyVar,Type)] -> [(TcType,TcType)]
 899 substEqSpec subst eq_spec = [ (substTyVar subst tv, substTy subst ty)
 900                             | (tv,ty) <- eq_spec]
 901 \end{code}
 902
 903 --------------------- The stupid theta (sigh) ---------------------------------
 904
 905 \begin{code}
 906 dataConsStupidTheta :: [DataCon] -> ThetaType
 907 -- Union the stupid thetas from all the specified constructors (non-empty)
 908 -- All the constructors should have the same result type, modulo alpha conversion
 909 -- The resulting ThetaType uses type variables from the *first* constructor in the list
 910 --
 911 -- It's here because it's used in MkId.mkRecordSelId, and in TcExpr
 912 dataConsStupidTheta (con1:cons)
 913   = nubBy tcEqPred all_preds
 914   where
 915     all_preds     = dataConStupidTheta con1 ++ other_stupids
 916     res_ty1       = dataConOrigResTy con1
 917     other_stupids = [ substPred subst pred
 918                     | con <- cons
 919                     , let (tvs, _, _, res_ty) = dataConSig con
 920                           Just subst = tcMatchTy (mkVarSet tvs) res_ty res_ty1
 921                     , pred <- dataConStupidTheta con ]
 922 dataConsStupidTheta [] = panic "dataConsStupidTheta"
 923 \end{code}
 924
 925
 926 %************************************************************************
 927 %*                                                                      *
 928 \subsection{Predicates}
 929 %*                                                                      *
 930 %************************************************************************
 931
 932 isSigmaTy returns true of any qualified type.  It doesn't *necessarily* have
 933 any foralls.  E.g.
 934         f :: (?x::Int) => Int -> Int
 935
 936 \begin{code}
 937 isSigmaTy :: Type -> Bool
 938 isSigmaTy ty | Just ty' <- tcView ty = isSigmaTy ty'
 939 isSigmaTy (ForAllTy tyvar ty) = True
 940 isSigmaTy (FunTy a b)         = isPredTy a
 941 isSigmaTy _                   = False
 942
 943 isOverloadedTy :: Type -> Bool
 944 isOverloadedTy ty | Just ty' <- tcView ty = isOverloadedTy ty'
 945 isOverloadedTy (ForAllTy tyvar ty) = isOverloadedTy ty
 946 isOverloadedTy (FunTy a b)         = isPredTy a
 947 isOverloadedTy _                   = False
 948
 949 isPredTy :: Type -> Bool        -- Belongs in TcType because it does
 950                                 -- not look through newtypes, or predtypes (of course)
 951 isPredTy ty | Just ty' <- tcView ty = isPredTy ty'
 952 isPredTy (PredTy sty)  = True
 953 isPredTy _             = False
 954 \end{code}
 955
 956 \begin{code}
 957 isFloatTy      = is_tc floatTyConKey
 958 isDoubleTy     = is_tc doubleTyConKey
 959 isIntegerTy    = is_tc integerTyConKey
 960 isIntTy        = is_tc intTyConKey
 961 isBoolTy       = is_tc boolTyConKey
 962 isUnitTy       = is_tc unitTyConKey
 963 isCharTy       = is_tc charTyConKey
 964
 965 isStringTy ty
 966   = case tcSplitTyConApp_maybe ty of
 967       Just (tc, [arg_ty]) -> tc == listTyCon && isCharTy arg_ty
 968       other               -> False
 969
 970 is_tc :: Unique -> Type -> Bool
 971 -- Newtypes are opaque to this
 972 is_tc uniq ty = case tcSplitTyConApp_maybe ty of
 973                         Just (tc, _) -> uniq == getUnique tc
 974                         Nothing      -> False
 975 \end{code}
 976
 977
 978 %************************************************************************
 979 %*                                                                      *
 980 \subsection{Misc}
 981 %*                                                                      *
 982 %************************************************************************
 983
 984 \begin{code}
 985 deNoteType :: Type -> Type
 986 -- Remove all *outermost* type synonyms and other notes
 987 deNoteType ty | Just ty' <- tcView ty = deNoteType ty'
 988 deNoteType ty = ty
 989 \end{code}
 990
 991 \begin{code}
 992 tcTyVarsOfType :: Type -> TcTyVarSet
 993 -- Just the *TcTyVars* free in the type
 994 -- (Types.tyVarsOfTypes finds all free TyVars)
 995 tcTyVarsOfType (TyVarTy tv)         = if isTcTyVar tv then unitVarSet tv
 996                                                       else emptyVarSet
 997 tcTyVarsOfType (TyConApp tycon tys) = tcTyVarsOfTypes tys
 998 tcTyVarsOfType (NoteTy _ ty)        = tcTyVarsOfType ty
 999 tcTyVarsOfType (PredTy sty)         = tcTyVarsOfPred sty
1000 tcTyVarsOfType (FunTy arg res)      = tcTyVarsOfType arg `unionVarSet` tcTyVarsOfType res
1001 tcTyVarsOfType (AppTy fun arg)      = tcTyVarsOfType fun `unionVarSet` tcTyVarsOfType arg
1002 tcTyVarsOfType (ForAllTy tyvar ty)  = (tcTyVarsOfType ty `delVarSet` tyvar)
1003                                       `unionVarSet` tcTyVarsOfTyVar tyvar
1004         -- We do sometimes quantify over skolem TcTyVars
1005
1006 tcTyVarsOfTyVar :: TcTyVar -> TyVarSet
1007 tcTyVarsOfTyVar tv | isCoVar tv = tcTyVarsOfType (tyVarKind tv)
1008                    | otherwise  = emptyVarSet
1009
1010 tcTyVarsOfTypes :: [Type] -> TyVarSet
1011 tcTyVarsOfTypes tys = foldr (unionVarSet.tcTyVarsOfType) emptyVarSet tys
1012
1013 tcTyVarsOfPred :: PredType -> TyVarSet
1014 tcTyVarsOfPred (IParam _ ty)    = tcTyVarsOfType ty
1015 tcTyVarsOfPred (ClassP _ tys)   = tcTyVarsOfTypes tys
1016 tcTyVarsOfPred (EqPred ty1 ty2) = tcTyVarsOfType ty1 `unionVarSet` tcTyVarsOfType ty2
1017 \end{code}
1018
1019 Note [Silly type synonym]
1020 ~~~~~~~~~~~~~~~~~~~~~~~~~
1021 Consider
1022         type T a = Int
1023 What are the free tyvars of (T x)?  Empty, of course!
1024 Here's the example that Ralf Laemmel showed me:
1025         foo :: (forall a. C u a -> C u a) -> u
1026         mappend :: Monoid u => u -> u -> u
1027
1028         bar :: Monoid u => u
1029         bar = foo (\t -> t `mappend` t)
1030 We have to generalise at the arg to f, and we don't
1031 want to capture the constraint (Monad (C u a)) because
1032 it appears to mention a.  Pretty silly, but it was useful to him.
1033
1034 exactTyVarsOfType is used by the type checker to figure out exactly
1035 which type variables are mentioned in a type.  It's also used in the
1036 smart-app checking code --- see TcExpr.tcIdApp
1037
1038 \begin{code}
1039 exactTyVarsOfType :: TcType -> TyVarSet
1040 -- Find the free type variables (of any kind)
1041 -- but *expand* type synonyms.  See Note [Silly type synonym] above.
1042 exactTyVarsOfType ty
1043   = go ty
1044   where
1045     go ty | Just ty' <- tcView ty = go ty'      -- This is the key line
1046     go (TyVarTy tv)               = unitVarSet tv
1047     go (TyConApp tycon tys)       = exactTyVarsOfTypes tys
1048     go (PredTy ty)                = go_pred ty
1049     go (FunTy arg res)            = go arg `unionVarSet` go res
1050     go (AppTy fun arg)            = go fun `unionVarSet` go arg
1051     go (ForAllTy tyvar ty)        = delVarSet (go ty) tyvar
1052                                     `unionVarSet` go_tv tyvar
1053
1054     go_pred (IParam _ ty)    = go ty
1055     go_pred (ClassP _ tys)   = exactTyVarsOfTypes tys
1056     go_pred (EqPred ty1 ty2) = go ty1 `unionVarSet` go ty2
1057
1058     go_tv tyvar | isCoVar tyvar = go (tyVarKind tyvar)
1059                 | otherwise     = emptyVarSet
1060
1061 exactTyVarsOfTypes :: [TcType] -> TyVarSet
1062 exactTyVarsOfTypes tys = foldr (unionVarSet . exactTyVarsOfType) emptyVarSet tys
1063 \end{code}
1064
1065 Find the free tycons and classes of a type.  This is used in the front
1066 end of the compiler.
1067
1068 \begin{code}
1069 tyClsNamesOfType :: Type -> NameSet
1070 tyClsNamesOfType (TyVarTy tv)               = emptyNameSet
1071 tyClsNamesOfType (TyConApp tycon tys)       = unitNameSet (getName tycon) `unionNameSets` tyClsNamesOfTypes tys
1072 tyClsNamesOfType (NoteTy _ ty2)             = tyClsNamesOfType ty2
1073 tyClsNamesOfType (PredTy (IParam n ty))     = tyClsNamesOfType ty
1074 tyClsNamesOfType (PredTy (ClassP cl tys))   = unitNameSet (getName cl) `unionNameSets` tyClsNamesOfTypes tys
1075 tyClsNamesOfType (PredTy (EqPred ty1 ty2))  = tyClsNamesOfType ty1 `unionNameSets` tyClsNamesOfType ty2
1076 tyClsNamesOfType (FunTy arg res)            = tyClsNamesOfType arg `unionNameSets` tyClsNamesOfType res
1077 tyClsNamesOfType (AppTy fun arg)            = tyClsNamesOfType fun `unionNameSets` tyClsNamesOfType arg
1078 tyClsNamesOfType (ForAllTy tyvar ty)        = tyClsNamesOfType ty
1079
1080 tyClsNamesOfTypes tys = foldr (unionNameSets . tyClsNamesOfType) emptyNameSet tys
1081
1082 tyClsNamesOfDFunHead :: Type -> NameSet
1083 -- Find the free type constructors and classes
1084 -- of the head of the dfun instance type
1085 -- The 'dfun_head_type' is because of
1086 --      instance Foo a => Baz T where ...
1087 -- The decl is an orphan if Baz and T are both not locally defined,
1088 --      even if Foo *is* locally defined
1089 tyClsNamesOfDFunHead dfun_ty
1090   = case tcSplitSigmaTy dfun_ty of
1091         (tvs,_,head_ty) -> tyClsNamesOfType head_ty
1092 \end{code}
1093
1094
1095 %************************************************************************
1096 %*                                                                      *
1097 \subsection[TysWiredIn-ext-type]{External types}
1098 %*                                                                      *
1099 %************************************************************************
1100
1101 The compiler's foreign function interface supports the passing of a
1102 restricted set of types as arguments and results (the restricting factor
1103 being the )
1104
1105 \begin{code}
1106 tcSplitIOType_maybe :: Type -> Maybe (TyCon, Type)
1107 -- (isIOType t) returns (Just (IO,t')) if t is of the form (IO t'), or
1108 --                                     some newtype wrapping thereof
1109 --              returns Nothing otherwise
1110 tcSplitIOType_maybe ty
1111   | Just (io_tycon, [io_res_ty]) <- tcSplitTyConApp_maybe ty,
1112         -- This split absolutely has to be a tcSplit, because we must
1113         -- see the IO type; and it's a newtype which is transparent to splitTyConApp.
1114     io_tycon `hasKey` ioTyConKey
1115   = Just (io_tycon, io_res_ty)
1116
1117   | Just ty' <- coreView ty     -- Look through non-recursive newtypes
1118   = tcSplitIOType_maybe ty'
1119
1120   | otherwise
1121   = Nothing
1122
1123 isFFITy :: Type -> Bool
1124 -- True for any TyCon that can possibly be an arg or result of an FFI call
1125 isFFITy ty = checkRepTyCon legalFFITyCon ty
1126
1127 isFFIArgumentTy :: DynFlags -> Safety -> Type -> Bool
1128 -- Checks for valid argument type for a 'foreign import'
1129 isFFIArgumentTy dflags safety ty
1130    = checkRepTyCon (legalOutgoingTyCon dflags safety) ty
1131
1132 isFFIExternalTy :: Type -> Bool
1133 -- Types that are allowed as arguments of a 'foreign export'
1134 isFFIExternalTy ty = checkRepTyCon legalFEArgTyCon ty
1135
1136 isFFIImportResultTy :: DynFlags -> Type -> Bool
1137 isFFIImportResultTy dflags ty
1138   = checkRepTyCon (legalFIResultTyCon dflags) ty
1139
1140 isFFIExportResultTy :: Type -> Bool
1141 isFFIExportResultTy ty = checkRepTyCon legalFEResultTyCon ty
1142
1143 isFFIDynArgumentTy :: Type -> Bool
1144 -- The argument type of a foreign import dynamic must be Ptr, FunPtr, Addr,
1145 -- or a newtype of either.
1146 isFFIDynArgumentTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1147
1148 isFFIDynResultTy :: Type -> Bool
1149 -- The result type of a foreign export dynamic must be Ptr, FunPtr, Addr,
1150 -- or a newtype of either.
1151 isFFIDynResultTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1152
1153 isFFILabelTy :: Type -> Bool
1154 -- The type of a foreign label must be Ptr, FunPtr, Addr,
1155 -- or a newtype of either.
1156 isFFILabelTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1157
1158 isFFIDotnetTy :: DynFlags -> Type -> Bool
1159 isFFIDotnetTy dflags ty
1160   = checkRepTyCon (\ tc -> (legalFIResultTyCon dflags tc ||
1161                            isFFIDotnetObjTy ty || isStringTy ty)) ty
1162         -- NB: isStringTy used to look through newtypes, but
1163         --     it no longer does so.  May need to adjust isFFIDotNetTy
1164         --     if we do want to look through newtypes.
1165
1166 isFFIDotnetObjTy ty =
1167   let
1168    (_, t_ty) = tcSplitForAllTys ty
1169   in
1170   case tcSplitTyConApp_maybe (repType t_ty) of
1171     Just (tc, [arg_ty]) | getName tc == objectTyConName -> True
1172     _ -> False
1173
1174 toDNType :: Type -> DNType
1175 toDNType ty
1176   | isStringTy ty = DNString
1177   | isFFIDotnetObjTy ty = DNObject
1178   | Just (tc,argTys) <- tcSplitTyConApp_maybe ty
1179   =  case lookup (getUnique tc) dn_assoc of
1180        Just x  -> x
1181        Nothing
1182          | tc `hasKey` ioTyConKey -> toDNType (head argTys)
1183          | otherwise -> pprPanic ("toDNType: unsupported .NET type")
1184                           (pprType ty <+> parens (hcat (map pprType argTys)) <+> ppr tc)
1185   | otherwise = panic "toDNType"        -- Is this right?
1186     where
1187       dn_assoc :: [ (Unique, DNType) ]
1188       dn_assoc = [ (unitTyConKey,   DNUnit)
1189                  , (intTyConKey,    DNInt)
1190                  , (int8TyConKey,   DNInt8)
1191                  , (int16TyConKey,  DNInt16)
1192                  , (int32TyConKey,  DNInt32)
1193                  , (int64TyConKey,  DNInt64)
1194                  , (wordTyConKey,   DNInt)
1195                  , (word8TyConKey,  DNWord8)
1196                  , (word16TyConKey, DNWord16)
1197                  , (word32TyConKey, DNWord32)
1198                  , (word64TyConKey, DNWord64)
1199                  , (floatTyConKey,  DNFloat)
1200                  , (doubleTyConKey, DNDouble)
1201                  , (ptrTyConKey,    DNPtr)
1202                  , (funPtrTyConKey, DNPtr)
1203                  , (charTyConKey,   DNChar)
1204                  , (boolTyConKey,   DNBool)
1205                  ]
1206
1207 checkRepTyCon :: (TyCon -> Bool) -> Type -> Bool
1208         -- Look through newtypes
1209         -- Non-recursive ones are transparent to splitTyConApp,
1210         -- but recursive ones aren't.  Manuel had:
1211         --      newtype T = MkT (Ptr T)
1212         -- and wanted it to work...
1213 checkRepTyCon check_tc ty
1214   | Just (tc,_) <- splitTyConApp_maybe (repType ty) = check_tc tc
1215   | otherwise                                       = False
1216
1217 checkRepTyConKey :: [Unique] -> Type -> Bool
1218 -- Like checkRepTyCon, but just looks at the TyCon key
1219 checkRepTyConKey keys
1220   = checkRepTyCon (\tc -> tyConUnique tc `elem` keys)
1221 \end{code}
1222
1223 ----------------------------------------------
1224 These chaps do the work; they are not exported
1225 ----------------------------------------------
1226
1227 \begin{code}
1228 legalFEArgTyCon :: TyCon -> Bool
1229 legalFEArgTyCon tc
1230   -- It's illegal to make foreign exports that take unboxed
1231   -- arguments.  The RTS API currently can't invoke such things.  --SDM 7/2000
1232   = boxedMarshalableTyCon tc
1233
1234 legalFIResultTyCon :: DynFlags -> TyCon -> Bool
1235 legalFIResultTyCon dflags tc
1236   | tc == unitTyCon         = True
1237   | otherwise               = marshalableTyCon dflags tc
1238
1239 legalFEResultTyCon :: TyCon -> Bool
1240 legalFEResultTyCon tc
1241   | tc == unitTyCon         = True
1242   | otherwise               = boxedMarshalableTyCon tc
1243
1244 legalOutgoingTyCon :: DynFlags -> Safety -> TyCon -> Bool
1245 -- Checks validity of types going from Haskell -> external world
1246 legalOutgoingTyCon dflags safety tc
1247   = marshalableTyCon dflags tc
1248
1249 legalFFITyCon :: TyCon -> Bool
1250 -- True for any TyCon that can possibly be an arg or result of an FFI call
1251 legalFFITyCon tc
1252   = isUnLiftedTyCon tc || boxedMarshalableTyCon tc || tc == unitTyCon
1253
1254 marshalableTyCon dflags tc
1255   =  (dopt Opt_UnliftedFFITypes dflags && isUnLiftedTyCon tc)
1256   || boxedMarshalableTyCon tc
1257
1258 boxedMarshalableTyCon tc
1259    = getUnique tc `elem` [ intTyConKey, int8TyConKey, int16TyConKey
1260                          , int32TyConKey, int64TyConKey
1261                          , wordTyConKey, word8TyConKey, word16TyConKey
1262                          , word32TyConKey, word64TyConKey
1263                          , floatTyConKey, doubleTyConKey
1264                          , ptrTyConKey, funPtrTyConKey
1265                          , charTyConKey
1266                          , stablePtrTyConKey
1267                          , boolTyConKey
1268                          ]
1269 \end{code}