compiler/typecheck/TcType.lhs

   1 %
   2 % (c) The University of Glasgow 2006
   3 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   4 %
   5 \section[TcType]{Types used in the typechecker}
   6
   7 This module provides the Type interface for front-end parts of the
   8 compiler.  These parts
   9
  10         * treat "source types" as opaque:
  11                 newtypes, and predicates are meaningful.
  12         * look through usage types
  13
  14 The "tc" prefix is for "TypeChecker", because the type checker
  15 is the principal client.
  16
  17 \begin{code}
  18 module TcType (
  19   --------------------------------
  20   -- Types
  21   TcType, TcSigmaType, TcRhoType, TcTauType, TcPredType, TcThetaType,
  22   TcTyVar, TcTyVarSet, TcKind, TcCoVar,
  23
  24   --------------------------------
  25   -- MetaDetails
  26   UserTypeCtxt(..), pprUserTypeCtxt,
  27   TcTyVarDetails(..), pprTcTyVarDetails,
  28   MetaDetails(Flexi, Indirect), MetaInfo(..),
  29   SkolemInfo(..), pprSkolTvBinding, pprSkolInfo,
  30   isImmutableTyVar, isSkolemTyVar, isMetaTyVar,  isMetaTyVarTy,
  31   isSigTyVar, isOverlappableTyVar,  isTyConableTyVar,
  32   metaTvRef,
  33   isFlexi, isIndirect, isUnkSkol, isRuntimeUnkSkol,
  34
  35   --------------------------------
  36   -- Builders
  37   mkPhiTy, mkSigmaTy,
  38
  39   --------------------------------
  40   -- Splitters
  41   -- These are important because they do not look through newtypes
  42   tcView,
  43   tcSplitForAllTys, tcSplitPhiTy, tcSplitPredFunTy_maybe,
  44   tcSplitFunTy_maybe, tcSplitFunTys, tcFunArgTy, tcFunResultTy, tcSplitFunTysN,
  45   tcSplitTyConApp, tcSplitTyConApp_maybe, tcTyConAppTyCon, tcTyConAppArgs,
  46   tcSplitAppTy_maybe, tcSplitAppTy, tcSplitAppTys, repSplitAppTy_maybe,
  47   tcInstHeadTyNotSynonym, tcInstHeadTyAppAllTyVars,
  48   tcGetTyVar_maybe, tcGetTyVar,
  49   tcSplitSigmaTy, tcDeepSplitSigmaTy_maybe,
  50
  51   ---------------------------------
  52   -- Predicates.
  53   -- Again, newtypes are opaque
  54   tcEqType, tcEqTypes, tcEqPred, tcCmpType, tcCmpTypes, tcCmpPred, tcEqTypeX,
  55   eqKind,
  56   isSigmaTy, isOverloadedTy, isRigidTy,
  57   isDoubleTy, isFloatTy, isIntTy, isWordTy, isStringTy,
  58   isIntegerTy, isBoolTy, isUnitTy, isCharTy,
  59   isTauTy, isTauTyCon, tcIsTyVarTy, tcIsForAllTy,
  60   isSynFamilyTyConApp,
  61
  62   ---------------------------------
  63   -- Misc type manipulators
  64   deNoteType,
  65   tyClsNamesOfType, tyClsNamesOfDFunHead,
  66   getDFunTyKey,
  67
  68   ---------------------------------
  69   -- Predicate types
  70   getClassPredTys_maybe, getClassPredTys,
  71   isClassPred, isTyVarClassPred, isEqPred,
  72   mkClassPred, mkIPPred, tcSplitPredTy_maybe,
  73   mkDictTy, evVarPred,
  74   isPredTy, isDictTy, isDictLikeTy,
  75   tcSplitDFunTy, tcSplitDFunHead, predTyUnique,
  76   isIPPred,
  77   isRefineableTy, isRefineablePred,
  78
  79   -- * Tidying type related things up for printing
  80   tidyType,      tidyTypes,
  81   tidyOpenType,  tidyOpenTypes,
  82   tidyTyVarBndr, tidyFreeTyVars,
  83   tidyOpenTyVar, tidyOpenTyVars,
  84   tidyTopType,   tidyPred,
  85   tidyKind, tidySkolemTyVar,
  86
  87   ---------------------------------
  88   -- Foreign import and export
  89   isFFIArgumentTy,     -- :: DynFlags -> Safety -> Type -> Bool
  90   isFFIImportResultTy, -- :: DynFlags -> Type -> Bool
  91   isFFIExportResultTy, -- :: Type -> Bool
  92   isFFIExternalTy,     -- :: Type -> Bool
  93   isFFIDynArgumentTy,  -- :: Type -> Bool
  94   isFFIDynResultTy,    -- :: Type -> Bool
  95   isFFIPrimArgumentTy, -- :: DynFlags -> Type -> Bool
  96   isFFIPrimResultTy,   -- :: DynFlags -> Type -> Bool
  97   isFFILabelTy,        -- :: Type -> Bool
  98   isFFIDotnetTy,       -- :: DynFlags -> Type -> Bool
  99   isFFIDotnetObjTy,    -- :: Type -> Bool
 100   isFFITy,             -- :: Type -> Bool
 101   isFunPtrTy,          -- :: Type -> Bool
 102   tcSplitIOType_maybe, -- :: Type -> Maybe Type
 103
 104   --------------------------------
 105   -- Rexported from Coercion
 106   typeKind,
 107
 108   --------------------------------
 109   -- Rexported from Type
 110   Kind,         -- Stuff to do with kinds is insensitive to pre/post Tc
 111   unliftedTypeKind, liftedTypeKind, argTypeKind,
 112   openTypeKind, mkArrowKind, mkArrowKinds,
 113   isLiftedTypeKind, isUnliftedTypeKind, isSubOpenTypeKind,
 114   isSubArgTypeKind, isSubKind, splitKindFunTys, defaultKind,
 115   kindVarRef, mkKindVar,
 116
 117   Type, PredType(..), ThetaType,
 118   mkForAllTy, mkForAllTys,
 119   mkFunTy, mkFunTys, zipFunTys,
 120   mkTyConApp, mkAppTy, mkAppTys, applyTy, applyTys,
 121   mkTyVarTy, mkTyVarTys, mkTyConTy, mkPredTy, mkPredTys,
 122
 123   -- Type substitutions
 124   TvSubst(..),  -- Representation visible to a few friends
 125   TvSubstEnv, emptyTvSubst, substEqSpec,
 126   mkOpenTvSubst, zipOpenTvSubst, zipTopTvSubst,
 127   mkTopTvSubst, notElemTvSubst, unionTvSubst,
 128   getTvSubstEnv, setTvSubstEnv, getTvInScope, extendTvInScope, lookupTyVar,
 129   extendTvSubst, extendTvSubstList, isInScope, mkTvSubst, zipTyEnv,
 130   substTy, substTys, substTyWith, substTheta, substTyVar, substTyVars, substTyVarBndr,
 131
 132   isUnLiftedType,       -- Source types are always lifted
 133   isUnboxedTupleType,   -- Ditto
 134   isPrimitiveType,
 135
 136   tyVarsOfType, tyVarsOfTypes, tyVarsOfPred, tyVarsOfTheta,
 137   tcTyVarsOfType, tcTyVarsOfTypes, tcTyVarsOfPred, exactTyVarsOfType,
 138   exactTyVarsOfTypes,
 139
 140   pprKind, pprParendKind,
 141   pprType, pprParendType, pprTypeApp, pprTyThingCategory,
 142   pprPred, pprTheta, pprThetaArrow, pprClassPred
 143
 144   ) where
 145
 146 #include "HsVersions.h"
 147
 148 -- friends:
 149 import TypeRep
 150 import DataCon
 151 import Class
 152 import Var
 153 import ForeignCall
 154 import VarSet
 155 import Type
 156 import Coercion
 157 import TyCon
 158 import HsExpr( HsMatchContext )
 159
 160 -- others:
 161 import DynFlags
 162 import Name
 163 import NameSet
 164 import VarEnv
 165 import PrelNames
 166 import TysWiredIn
 167 import BasicTypes
 168 import Util
 169 import Maybes
 170 import ListSetOps
 171 import Outputable
 172 import FastString
 173
 174 import Data.List( mapAccumL )
 175 import Data.IORef
 176 \end{code}
 177
 178 %************************************************************************
 179 %*                                                                      *
 180 \subsection{Types}
 181 %*                                                                      *
 182 %************************************************************************
 183
 184 The type checker divides the generic Type world into the
 185 following more structured beasts:
 186
 187 sigma ::= forall tyvars. phi
 188         -- A sigma type is a qualified type
 189         --
 190         -- Note that even if 'tyvars' is empty, theta
 191         -- may not be: e.g.   (?x::Int) => Int
 192
 193         -- Note that 'sigma' is in prenex form:
 194         -- all the foralls are at the front.
 195         -- A 'phi' type has no foralls to the right of
 196         -- an arrow
 197
 198 phi :: theta => rho
 199
 200 rho ::= sigma -> rho
 201      |  tau
 202
 203 -- A 'tau' type has no quantification anywhere
 204 -- Note that the args of a type constructor must be taus
 205 tau ::= tyvar
 206      |  tycon tau_1 .. tau_n
 207      |  tau_1 tau_2
 208      |  tau_1 -> tau_2
 209
 210 -- In all cases, a (saturated) type synonym application is legal,
 211 -- provided it expands to the required form.
 212
 213 \begin{code}
 214 type TcTyVar = TyVar    -- Used only during type inference
 215 type TcCoVar = CoVar    -- Used only during type inference; mutable
 216 type TcType = Type      -- A TcType can have mutable type variables
 217         -- Invariant on ForAllTy in TcTypes:
 218         --      forall a. T
 219         -- a cannot occur inside a MutTyVar in T; that is,
 220         -- T is "flattened" before quantifying over a
 221
 222 -- These types do not have boxy type variables in them
 223 type TcPredType     = PredType
 224 type TcThetaType    = ThetaType
 225 type TcSigmaType    = TcType
 226 type TcRhoType      = TcType
 227 type TcTauType      = TcType
 228 type TcKind         = Kind
 229 type TcTyVarSet     = TyVarSet
 230 \end{code}
 231
 232
 233 %************************************************************************
 234 %*                                                                      *
 235 \subsection{TyVarDetails}
 236 %*                                                                      *
 237 %************************************************************************
 238
 239 TyVarDetails gives extra info about type variables, used during type
 240 checking.  It's attached to mutable type variables only.
 241 It's knot-tied back to Var.lhs.  There is no reason in principle
 242 why Var.lhs shouldn't actually have the definition, but it "belongs" here.
 243
 244
 245 Note [Signature skolems]
 246 ~~~~~~~~~~~~~~~~~~~~~~~~
 247 Consider this
 248
 249   x :: [a]
 250   y :: b
 251   (x,y,z) = ([y,z], z, head x)
 252
 253 Here, x and y have type sigs, which go into the environment.  We used to
 254 instantiate their types with skolem constants, and push those types into
 255 the RHS, so we'd typecheck the RHS with type
 256         ( [a*], b*, c )
 257 where a*, b* are skolem constants, and c is an ordinary meta type varible.
 258
 259 The trouble is that the occurrences of z in the RHS force a* and b* to
 260 be the *same*, so we can't make them into skolem constants that don't unify
 261 with each other.  Alas.
 262
 263 One solution would be insist that in the above defn the programmer uses
 264 the same type variable in both type signatures.  But that takes explanation.
 265
 266 The alternative (currently implemented) is to have a special kind of skolem
 267 constant, SigTv, which can unify with other SigTvs.  These are *not* treated
 268 as righd for the purposes of GADTs.  And they are used *only* for pattern
 269 bindings and mutually recursive function bindings.  See the function
 270 TcBinds.tcInstSig, and its use_skols parameter.
 271
 272
 273 \begin{code}
 274 -- A TyVarDetails is inside a TyVar
 275 data TcTyVarDetails
 276   = SkolemTv SkolemInfo   -- A skolem constant
 277
 278   | FlatSkol TcType
 279            -- The "skolem" obtained by flattening during
 280            -- constraint simplification
 281
 282            -- In comments we will use the notation alpha[flat = ty]
 283            -- to represent a flattening skolem variable alpha
 284            -- identified with type ty.
 285
 286   | MetaTv MetaInfo (IORef MetaDetails)
 287
 288 data MetaDetails
 289   = Flexi  -- Flexi type variables unify to become Indirects
 290   | Indirect TcType
 291
 292 data MetaInfo
 293    = TauTv         -- This MetaTv is an ordinary unification variable
 294                    -- A TauTv is always filled in with a tau-type, which
 295                    -- never contains any ForAlls
 296
 297    | SigTv Name    -- A variant of TauTv, except that it should not be
 298                    -- unified with a type, only with a type variable
 299                    -- SigTvs are only distinguished to improve error messages
 300                    --      see Note [Signature skolems]
 301                    --      The MetaDetails, if filled in, will
 302                    --      always be another SigTv or a SkolemTv
 303                    -- The Name is the name of the function from whose
 304                    -- type signature we got this skolem
 305
 306    | TcsTv         -- A MetaTv allocated by the constraint solver
 307                    -- Its particular property is that it is always "touchable"
 308                    -- Nevertheless, the constraint solver has to try to guess
 309                    -- what type to instantiate it to
 310
 311 ----------------------------------
 312 -- SkolemInfo describes a site where
 313 --   a) type variables are skolemised
 314 --   b) an implication constraint is generated
 315 data SkolemInfo
 316   = SigSkol UserTypeCtxt        -- A skolem that is created by instantiating
 317                                 -- a programmer-supplied type signature
 318                                 -- Location of the binding site is on the TyVar
 319
 320         -- The rest are for non-scoped skolems
 321   | ClsSkol Class       -- Bound at a class decl
 322   | InstSkol            -- Bound at an instance decl
 323   | FamInstSkol         -- Bound at a family instance decl
 324   | PatSkol             -- An existential type variable bound by a pattern for
 325       DataCon           -- a data constructor with an existential type.
 326       (HsMatchContext Name)
 327              -- e.g.   data T = forall a. Eq a => MkT a
 328              --        f (MkT x) = ...
 329              -- The pattern MkT x will allocate an existential type
 330              -- variable for 'a'.
 331
 332   | ArrowSkol           -- An arrow form (see TcArrows)
 333
 334   | IPSkol [IPName Name]  -- Binding site of an implicit parameter
 335
 336   | RuleSkol RuleName   -- The LHS of a RULE
 337   | GenSkol TcType      -- Bound when doing a subsumption check for ty
 338
 339   | RuntimeUnkSkol      -- a type variable used to represent an unknown
 340                         -- runtime type (used in the GHCi debugger)
 341
 342   | UnkSkol             -- Unhelpful info (until I improve it)
 343
 344 -------------------------------------
 345 -- UserTypeCtxt describes the places where a
 346 -- programmer-written type signature can occur
 347 -- Like SkolemInfo, no location info
 348 data UserTypeCtxt
 349   = FunSigCtxt Name     -- Function type signature
 350                         -- Also used for types in SPECIALISE pragmas
 351   | ExprSigCtxt         -- Expression type signature
 352   | ConArgCtxt Name     -- Data constructor argument
 353   | TySynCtxt Name      -- RHS of a type synonym decl
 354   | GenPatCtxt          -- Pattern in generic decl
 355                         --      f{| a+b |} (Inl x) = ...
 356   | LamPatSigCtxt               -- Type sig in lambda pattern
 357                         --      f (x::t) = ...
 358   | BindPatSigCtxt      -- Type sig in pattern binding pattern
 359                         --      (x::t, y) = e
 360   | ResSigCtxt          -- Result type sig
 361                         --      f x :: t = ....
 362   | ForSigCtxt Name     -- Foreign inport or export signature
 363   | DefaultDeclCtxt     -- Types in a default declaration
 364   | SpecInstCtxt        -- SPECIALISE instance pragma
 365   | ThBrackCtxt         -- Template Haskell type brackets [t| ... |]
 366
 367 -- Notes re TySynCtxt
 368 -- We allow type synonyms that aren't types; e.g.  type List = []
 369 --
 370 -- If the RHS mentions tyvars that aren't in scope, we'll
 371 -- quantify over them:
 372 --      e.g.    type T = a->a
 373 -- will become  type T = forall a. a->a
 374 --
 375 -- With gla-exts that's right, but for H98 we should complain.
 376
 377 ---------------------------------
 378 -- Kind variables:
 379
 380 mkKindName :: Unique -> Name
 381 mkKindName unique = mkSystemName unique kind_var_occ
 382
 383 kindVarRef :: KindVar -> IORef MetaDetails
 384 kindVarRef tc =
 385   ASSERT ( isTcTyVar tc )
 386   case tcTyVarDetails tc of
 387     MetaTv TauTv ref -> ref
 388     _                -> pprPanic "kindVarRef" (ppr tc)
 389
 390 mkKindVar :: Unique -> IORef MetaDetails -> KindVar
 391 mkKindVar u r
 392   = mkTcTyVar (mkKindName u)
 393               tySuperKind  -- not sure this is right,
 394                             -- do we need kind vars for
 395                             -- coercions?
 396               (MetaTv TauTv r)
 397
 398 kind_var_occ :: OccName -- Just one for all KindVars
 399                         -- They may be jiggled by tidying
 400 kind_var_occ = mkOccName tvName "k"
 401 \end{code}
 402
 403 %************************************************************************
 404 %*                                                                      *
 405                 Pretty-printing
 406 %*                                                                      *
 407 %************************************************************************
 408
 409 \begin{code}
 410 pprTcTyVarDetails :: TcTyVarDetails -> SDoc
 411 -- For debugging
 412 pprTcTyVarDetails (SkolemTv _)         = ptext (sLit "sk")
 413 pprTcTyVarDetails (FlatSkol {})        = ptext (sLit "fsk")
 414 pprTcTyVarDetails (MetaTv TauTv _)     = ptext (sLit "tau")
 415 pprTcTyVarDetails (MetaTv TcsTv _)     = ptext (sLit "tcs")
 416 pprTcTyVarDetails (MetaTv (SigTv _) _) = ptext (sLit "sig")
 417
 418 pprUserTypeCtxt :: UserTypeCtxt -> SDoc
 419 pprUserTypeCtxt (FunSigCtxt n)  = ptext (sLit "the type signature for") <+> quotes (ppr n)
 420 pprUserTypeCtxt ExprSigCtxt     = ptext (sLit "an expression type signature")
 421 pprUserTypeCtxt (ConArgCtxt c)  = ptext (sLit "the type of the constructor") <+> quotes (ppr c)
 422 pprUserTypeCtxt (TySynCtxt c)   = ptext (sLit "the RHS of the type synonym") <+> quotes (ppr c)
 423 pprUserTypeCtxt GenPatCtxt      = ptext (sLit "the type pattern of a generic definition")
 424 pprUserTypeCtxt ThBrackCtxt     = ptext (sLit "a Template Haskell quotation [t|...|]")
 425 pprUserTypeCtxt LamPatSigCtxt   = ptext (sLit "a pattern type signature")
 426 pprUserTypeCtxt BindPatSigCtxt  = ptext (sLit "a pattern type signature")
 427 pprUserTypeCtxt ResSigCtxt      = ptext (sLit "a result type signature")
 428 pprUserTypeCtxt (ForSigCtxt n)  = ptext (sLit "the foreign declaration for") <+> quotes (ppr n)
 429 pprUserTypeCtxt DefaultDeclCtxt = ptext (sLit "a type in a `default' declaration")
 430 pprUserTypeCtxt SpecInstCtxt    = ptext (sLit "a SPECIALISE instance pragma")
 431
 432 pprSkolTvBinding :: TcTyVar -> SDoc
 433 -- Print info about the binding of a skolem tyvar,
 434 -- or nothing if we don't have anything useful to say
 435 pprSkolTvBinding tv
 436   = ASSERT ( isTcTyVar tv )
 437     quotes (ppr tv) <+> ppr_details (tcTyVarDetails tv)
 438   where
 439     ppr_details (SkolemTv info)      = ppr_skol info
 440     ppr_details (FlatSkol {})        = ptext (sLit "is a flattening type variable")
 441     ppr_details (MetaTv (SigTv n) _) = ptext (sLit "is bound by the type signature for")
 442                                        <+> quotes (ppr n)
 443     ppr_details (MetaTv _ _)         = ptext (sLit "is a meta type variable")
 444
 445     ppr_skol UnkSkol        = ptext (sLit "is an unknown type variable")        -- Unhelpful
 446     ppr_skol RuntimeUnkSkol = ptext (sLit "is an unknown runtime type")
 447     ppr_skol info           = sep [ptext (sLit "is a rigid type variable bound by"),
 448                                    sep [pprSkolInfo info,
 449                                         nest 2 (ptext (sLit "at") <+> ppr (getSrcLoc tv))]]
 450
 451 instance Outputable SkolemInfo where
 452   ppr = pprSkolInfo
 453
 454 pprSkolInfo :: SkolemInfo -> SDoc
 455 -- Complete the sentence "is a rigid type variable bound by..."
 456 pprSkolInfo (SigSkol ctxt)  = pprUserTypeCtxt ctxt
 457 pprSkolInfo (IPSkol ips)    = ptext (sLit "the implicit-parameter bindings for")
 458                               <+> pprWithCommas ppr ips
 459 pprSkolInfo (ClsSkol cls)   = ptext (sLit "the class declaration for") <+> quotes (ppr cls)
 460 pprSkolInfo InstSkol        = ptext (sLit "the instance declaration")
 461 pprSkolInfo FamInstSkol     = ptext (sLit "the family instance declaration")
 462 pprSkolInfo (RuleSkol name) = ptext (sLit "the RULE") <+> doubleQuotes (ftext name)
 463 pprSkolInfo ArrowSkol       = ptext (sLit "the arrow form")
 464 pprSkolInfo (PatSkol dc _)  = sep [ ptext (sLit "a pattern with constructor")
 465                                     , ppr dc <+> dcolon <+> ppr (dataConUserType dc) ]
 466 pprSkolInfo (GenSkol ty)    = sep [ ptext (sLit "the polymorphic type")
 467                                   , quotes (ppr ty) ]
 468
 469 -- UnkSkol
 470 -- For type variables the others are dealt with by pprSkolTvBinding.
 471 -- For Insts, these cases should not happen
 472 pprSkolInfo UnkSkol        = WARN( True, text "pprSkolInfo: UnkSkol" ) ptext (sLit "UnkSkol")
 473 pprSkolInfo RuntimeUnkSkol = WARN( True, text "pprSkolInfo: RuntimeUnkSkol" ) ptext (sLit "RuntimeUnkSkol")
 474
 475 instance Outputable MetaDetails where
 476   ppr Flexi         = ptext (sLit "Flexi")
 477   ppr (Indirect ty) = ptext (sLit "Indirect") <+> ppr ty
 478 \end{code}
 479
 480
 481 %************************************************************************
 482 %*                                                                      *
 483 \subsection{TidyType}
 484 %*                                                                      *
 485 %************************************************************************
 486
 487 \begin{code}
 488 -- | This tidies up a type for printing in an error message, or in
 489 -- an interface file.
 490 --
 491 -- It doesn't change the uniques at all, just the print names.
 492 tidyTyVarBndr :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 493 tidyTyVarBndr env@(tidy_env, subst) tyvar
 494   = case tidyOccName tidy_env (getOccName name) of
 495       (tidy', occ') -> ((tidy', subst'), tyvar'')
 496         where
 497           subst' = extendVarEnv subst tyvar tyvar''
 498           tyvar' = setTyVarName tyvar name'
 499           name'  = tidyNameOcc name occ'
 500                 -- Don't forget to tidy the kind for coercions!
 501           tyvar'' | isCoVar tyvar = setTyVarKind tyvar' kind'
 502                   | otherwise     = tyvar'
 503           kind'  = tidyType env (tyVarKind tyvar)
 504   where
 505     name = tyVarName tyvar
 506
 507 ---------------
 508 tidyFreeTyVars :: TidyEnv -> TyVarSet -> TidyEnv
 509 -- ^ Add the free 'TyVar's to the env in tidy form,
 510 -- so that we can tidy the type they are free in
 511 tidyFreeTyVars env tyvars = fst (tidyOpenTyVars env (varSetElems tyvars))
 512
 513 ---------------
 514 tidyOpenTyVars :: TidyEnv -> [TyVar] -> (TidyEnv, [TyVar])
 515 tidyOpenTyVars env tyvars = mapAccumL tidyOpenTyVar env tyvars
 516
 517 ---------------
 518 tidyOpenTyVar :: TidyEnv -> TyVar -> (TidyEnv, TyVar)
 519 -- ^ Treat a new 'TyVar' as a binder, and give it a fresh tidy name
 520 -- using the environment if one has not already been allocated. See
 521 -- also 'tidyTyVarBndr'
 522 tidyOpenTyVar env@(_, subst) tyvar
 523   = case lookupVarEnv subst tyvar of
 524         Just tyvar' -> (env, tyvar')            -- Already substituted
 525         Nothing     -> tidyTyVarBndr env tyvar  -- Treat it as a binder
 526
 527 ---------------
 528 tidyType :: TidyEnv -> Type -> Type
 529 tidyType env@(_, subst) ty
 530   = go ty
 531   where
 532     go (TyVarTy tv)         = case lookupVarEnv subst tv of
 533                                 Nothing  -> expand tv
 534                                 Just tv' -> expand tv'
 535     go (TyConApp tycon tys) = let args = map go tys
 536                               in args `seqList` TyConApp tycon args
 537     go (PredTy sty)         = PredTy (tidyPred env sty)
 538     go (AppTy fun arg)      = (AppTy $! (go fun)) $! (go arg)
 539     go (FunTy fun arg)      = (FunTy $! (go fun)) $! (go arg)
 540     go (ForAllTy tv ty)     = ForAllTy tvp $! (tidyType envp ty)
 541                               where
 542                                 (envp, tvp) = tidyTyVarBndr env tv
 543
 544     -- Expand FlatSkols, the skolems introduced by flattening process
 545     -- We don't want to show them in type error messages
 546     expand tv | isTcTyVar tv
 547               , FlatSkol ty <- tcTyVarDetails tv
 548               = go ty
 549               | otherwise
 550               = TyVarTy tv
 551
 552 ---------------
 553 tidyTypes :: TidyEnv -> [Type] -> [Type]
 554 tidyTypes env tys = map (tidyType env) tys
 555
 556 ---------------
 557 tidyPred :: TidyEnv -> PredType -> PredType
 558 tidyPred env (IParam n ty)     = IParam n (tidyType env ty)
 559 tidyPred env (ClassP clas tys) = ClassP clas (tidyTypes env tys)
 560 tidyPred env (EqPred ty1 ty2)  = EqPred (tidyType env ty1) (tidyType env ty2)
 561
 562 ---------------
 563 -- | Grabs the free type variables, tidies them
 564 -- and then uses 'tidyType' to work over the type itself
 565 tidyOpenType :: TidyEnv -> Type -> (TidyEnv, Type)
 566 tidyOpenType env ty
 567   = (env', tidyType env' ty)
 568   where
 569     env' = tidyFreeTyVars env (tyVarsOfType ty)
 570
 571 ---------------
 572 tidyOpenTypes :: TidyEnv -> [Type] -> (TidyEnv, [Type])
 573 tidyOpenTypes env tys = mapAccumL tidyOpenType env tys
 574
 575 ---------------
 576 -- | Calls 'tidyType' on a top-level type (i.e. with an empty tidying environment)
 577 tidyTopType :: Type -> Type
 578 tidyTopType ty = tidyType emptyTidyEnv ty
 579
 580 ---------------
 581 tidySkolemTyVar :: TidyEnv -> TcTyVar -> (TidyEnv, TcTyVar)
 582 -- Tidy the type inside a GenSkol, preparatory to printing it
 583 tidySkolemTyVar env tv
 584   = ASSERT( isTcTyVar tv && (isSkolemTyVar tv || isSigTyVar tv ) )
 585     (env1, mkTcTyVar (tyVarName tv) (tyVarKind tv) info1)
 586   where
 587     (env1, info1) = case tcTyVarDetails tv of
 588                         SkolemTv info -> (env1, SkolemTv info')
 589                                 where
 590                                   (env1, info') = tidy_skol_info env info
 591                         info -> (env, info)
 592
 593     tidy_skol_info env (GenSkol ty) = (env1, GenSkol ty1)
 594                             where
 595                               (env1, ty1)  = tidyOpenType env ty
 596     tidy_skol_info env info = (env, info)
 597
 598 ---------------
 599 tidyKind :: TidyEnv -> Kind -> (TidyEnv, Kind)
 600 tidyKind env k = tidyOpenType env k
 601 \end{code}
 602
 603
 604 %************************************************************************
 605 %*                                                                      *
 606                 Predicates
 607 %*                                                                      *
 608 %************************************************************************
 609
 610 \begin{code}
 611 isImmutableTyVar :: TyVar -> Bool
 612
 613 isImmutableTyVar tv
 614   | isTcTyVar tv = isSkolemTyVar tv
 615   | otherwise    = True
 616
 617 isTyConableTyVar, isSkolemTyVar, isOverlappableTyVar,
 618   isMetaTyVar :: TcTyVar -> Bool
 619
 620 isTyConableTyVar tv
 621         -- True of a meta-type variable that can be filled in
 622         -- with a type constructor application; in particular,
 623         -- not a SigTv
 624   = ASSERT( isTcTyVar tv)
 625     case tcTyVarDetails tv of
 626         MetaTv (SigTv _) _ -> False
 627         _                  -> True
 628
 629 isSkolemTyVar tv
 630   = ASSERT2( isTcTyVar tv, ppr tv )
 631     case tcTyVarDetails tv of
 632         SkolemTv {} -> True
 633         FlatSkol {} -> True
 634         MetaTv {}   -> False
 635
 636 -- isOverlappableTyVar has a unique purpose.
 637 -- See Note [Binding when looking up instances] in InstEnv.
 638 isOverlappableTyVar tv
 639   = ASSERT( isTcTyVar tv )
 640     case tcTyVarDetails tv of
 641         SkolemTv (PatSkol {})  -> True
 642         SkolemTv (InstSkol {}) -> True
 643         _                      -> False
 644
 645 isMetaTyVar tv
 646   = ASSERT2( isTcTyVar tv, ppr tv )
 647     case tcTyVarDetails tv of
 648         MetaTv _ _ -> True
 649         _          -> False
 650
 651 isMetaTyVarTy :: TcType -> Bool
 652 isMetaTyVarTy (TyVarTy tv) = isMetaTyVar tv
 653 isMetaTyVarTy _            = False
 654
 655 isSigTyVar :: Var -> Bool
 656 isSigTyVar tv
 657   = ASSERT( isTcTyVar tv )
 658     case tcTyVarDetails tv of
 659         MetaTv (SigTv _) _ -> True
 660         _                  -> False
 661
 662 metaTvRef :: TyVar -> IORef MetaDetails
 663 metaTvRef tv
 664   = ASSERT2( isTcTyVar tv, ppr tv )
 665     case tcTyVarDetails tv of
 666         MetaTv _ ref -> ref
 667         _          -> pprPanic "metaTvRef" (ppr tv)
 668
 669 isFlexi, isIndirect :: MetaDetails -> Bool
 670 isFlexi Flexi = True
 671 isFlexi _     = False
 672
 673 isIndirect (Indirect _) = True
 674 isIndirect _            = False
 675
 676 isRuntimeUnkSkol :: TyVar -> Bool
 677 -- Called only in TcErrors; see Note [Runtime skolems] there
 678 isRuntimeUnkSkol x | isTcTyVar x
 679                    , SkolemTv RuntimeUnkSkol <- tcTyVarDetails x
 680                    = True
 681                    | otherwise = False
 682
 683 isUnkSkol :: TyVar -> Bool
 684 isUnkSkol x | isTcTyVar x
 685             , SkolemTv UnkSkol <- tcTyVarDetails x = True
 686             | otherwise = False
 687 \end{code}
 688
 689
 690 %************************************************************************
 691 %*                                                                      *
 692 \subsection{Tau, sigma and rho}
 693 %*                                                                      *
 694 %************************************************************************
 695
 696 \begin{code}
 697 mkSigmaTy :: [TyVar] -> [PredType] -> Type -> Type
 698 mkSigmaTy tyvars theta tau = mkForAllTys tyvars (mkPhiTy theta tau)
 699
 700 mkPhiTy :: [PredType] -> Type -> Type
 701 mkPhiTy theta ty = foldr (\p r -> mkFunTy (mkPredTy p) r) ty theta
 702 \end{code}
 703
 704 @isTauTy@ tests for nested for-alls.  It should not be called on a boxy type.
 705
 706 \begin{code}
 707 isTauTy :: Type -> Bool
 708 isTauTy ty | Just ty' <- tcView ty = isTauTy ty'
 709 isTauTy (TyVarTy _)       = True
 710 isTauTy (TyConApp tc tys) = all isTauTy tys && isTauTyCon tc
 711 isTauTy (AppTy a b)       = isTauTy a && isTauTy b
 712 isTauTy (FunTy a b)       = isTauTy a && isTauTy b
 713 isTauTy (PredTy _)        = True                -- Don't look through source types
 714 isTauTy _                 = False
 715
 716
 717 isTauTyCon :: TyCon -> Bool
 718 -- Returns False for type synonyms whose expansion is a polytype
 719 isTauTyCon tc
 720   | isClosedSynTyCon tc = isTauTy (snd (synTyConDefn tc))
 721   | otherwise           = True
 722
 723 ---------------
 724 isRigidTy :: TcType -> Bool
 725 -- A type is rigid if it has no meta type variables in it
 726 isRigidTy ty = all isImmutableTyVar (varSetElems (tcTyVarsOfType ty))
 727
 728 isRefineableTy :: TcType -> (Bool,Bool)
 729 -- A type should have type refinements applied to it if it has
 730 -- free type variables, and they are all rigid
 731 isRefineableTy ty = (null tc_tvs,  all isImmutableTyVar tc_tvs)
 732                     where
 733                       tc_tvs = varSetElems (tcTyVarsOfType ty)
 734
 735 isRefineablePred :: TcPredType -> Bool
 736 isRefineablePred pred = not (null tc_tvs) && all isImmutableTyVar tc_tvs
 737                       where
 738                         tc_tvs = varSetElems (tcTyVarsOfPred pred)
 739
 740 ---------------
 741 getDFunTyKey :: Type -> OccName -- Get some string from a type, to be used to
 742                                 -- construct a dictionary function name
 743 getDFunTyKey ty | Just ty' <- tcView ty = getDFunTyKey ty'
 744 getDFunTyKey (TyVarTy tv)    = getOccName tv
 745 getDFunTyKey (TyConApp tc _) = getOccName tc
 746 getDFunTyKey (AppTy fun _)   = getDFunTyKey fun
 747 getDFunTyKey (FunTy _ _)     = getOccName funTyCon
 748 getDFunTyKey (ForAllTy _ t)  = getDFunTyKey t
 749 getDFunTyKey ty              = pprPanic "getDFunTyKey" (pprType ty)
 750 -- PredTy shouldn't happen
 751 \end{code}
 752
 753
 754 %************************************************************************
 755 %*                                                                      *
 756 \subsection{Expanding and splitting}
 757 %*                                                                      *
 758 %************************************************************************
 759
 760 These tcSplit functions are like their non-Tc analogues, but
 761         a) they do not look through newtypes
 762         b) they do not look through PredTys
 763
 764 However, they are non-monadic and do not follow through mutable type
 765 variables.  It's up to you to make sure this doesn't matter.
 766
 767 \begin{code}
 768 tcSplitForAllTys :: Type -> ([TyVar], Type)
 769 tcSplitForAllTys ty = split ty ty []
 770    where
 771      split orig_ty ty tvs | Just ty' <- tcView ty = split orig_ty ty' tvs
 772      split _ (ForAllTy tv ty) tvs
 773        | not (isCoVar tv) = split ty ty (tv:tvs)
 774      split orig_ty _ tvs = (reverse tvs, orig_ty)
 775
 776 tcIsForAllTy :: Type -> Bool
 777 tcIsForAllTy ty | Just ty' <- tcView ty = tcIsForAllTy ty'
 778 tcIsForAllTy (ForAllTy tv _) = not (isCoVar tv)
 779 tcIsForAllTy _               = False
 780
 781 tcSplitPredFunTy_maybe :: Type -> Maybe (PredType, Type)
 782 -- Split off the first predicate argument from a type
 783 tcSplitPredFunTy_maybe ty | Just ty' <- tcView ty = tcSplitPredFunTy_maybe ty'
 784 tcSplitPredFunTy_maybe (ForAllTy tv ty)
 785   | isCoVar tv = Just (coVarPred tv, ty)
 786 tcSplitPredFunTy_maybe (FunTy arg res)
 787   | Just p <- tcSplitPredTy_maybe arg = Just (p, res)
 788 tcSplitPredFunTy_maybe _
 789   = Nothing
 790
 791 tcSplitPhiTy :: Type -> (ThetaType, Type)
 792 tcSplitPhiTy ty
 793   = split ty []
 794   where
 795     split ty ts
 796       = case tcSplitPredFunTy_maybe ty of
 797           Just (pred, ty) -> split ty (pred:ts)
 798           Nothing         -> (reverse ts, ty)
 799
 800 tcSplitSigmaTy :: Type -> ([TyVar], ThetaType, Type)
 801 tcSplitSigmaTy ty = case tcSplitForAllTys ty of
 802                         (tvs, rho) -> case tcSplitPhiTy rho of
 803                                         (theta, tau) -> (tvs, theta, tau)
 804
 805 -----------------------
 806 tcDeepSplitSigmaTy_maybe
 807   :: TcSigmaType -> Maybe ([TcType], [TyVar], ThetaType, TcSigmaType)
 808 -- Looks for a *non-trivial* quantified type, under zero or more function arrows
 809 -- By "non-trivial" we mean either tyvars or constraints are non-empty
 810
 811 tcDeepSplitSigmaTy_maybe ty
 812   | Just (arg_ty, res_ty)           <- tcSplitFunTy_maybe ty
 813   , Just (arg_tys, tvs, theta, rho) <- tcDeepSplitSigmaTy_maybe res_ty
 814   = Just (arg_ty:arg_tys, tvs, theta, rho)
 815
 816   | (tvs, theta, rho) <- tcSplitSigmaTy ty
 817   , not (null tvs && null theta)
 818   = Just ([], tvs, theta, rho)
 819
 820   | otherwise = Nothing
 821
 822 -----------------------
 823 tcTyConAppTyCon :: Type -> TyCon
 824 tcTyConAppTyCon ty = case tcSplitTyConApp_maybe ty of
 825                         Just (tc, _) -> tc
 826                         Nothing      -> pprPanic "tcTyConAppTyCon" (pprType ty)
 827
 828 tcTyConAppArgs :: Type -> [Type]
 829 tcTyConAppArgs ty = case tcSplitTyConApp_maybe ty of
 830                         Just (_, args) -> args
 831                         Nothing        -> pprPanic "tcTyConAppArgs" (pprType ty)
 832
 833 tcSplitTyConApp :: Type -> (TyCon, [Type])
 834 tcSplitTyConApp ty = case tcSplitTyConApp_maybe ty of
 835                         Just stuff -> stuff
 836                         Nothing    -> pprPanic "tcSplitTyConApp" (pprType ty)
 837
 838 tcSplitTyConApp_maybe :: Type -> Maybe (TyCon, [Type])
 839 tcSplitTyConApp_maybe ty | Just ty' <- tcView ty = tcSplitTyConApp_maybe ty'
 840 tcSplitTyConApp_maybe (TyConApp tc tys) = Just (tc, tys)
 841 tcSplitTyConApp_maybe (FunTy arg res)   = Just (funTyCon, [arg,res])
 842         -- Newtypes are opaque, so they may be split
 843         -- However, predicates are not treated
 844         -- as tycon applications by the type checker
 845 tcSplitTyConApp_maybe _                 = Nothing
 846
 847 -----------------------
 848 tcSplitFunTys :: Type -> ([Type], Type)
 849 tcSplitFunTys ty = case tcSplitFunTy_maybe ty of
 850                         Nothing        -> ([], ty)
 851                         Just (arg,res) -> (arg:args, res')
 852                                        where
 853                                           (args,res') = tcSplitFunTys res
 854
 855 tcSplitFunTy_maybe :: Type -> Maybe (Type, Type)
 856 tcSplitFunTy_maybe ty | Just ty' <- tcView ty           = tcSplitFunTy_maybe ty'
 857 tcSplitFunTy_maybe (FunTy arg res) | not (isPredTy arg) = Just (arg, res)
 858 tcSplitFunTy_maybe _                                    = Nothing
 859         -- Note the (not (isPredTy arg)) guard
 860         -- Consider     (?x::Int) => Bool
 861         -- We don't want to treat this as a function type!
 862         -- A concrete example is test tc230:
 863         --      f :: () -> (?p :: ()) => () -> ()
 864         --
 865         --      g = f () ()
 866
 867 tcSplitFunTysN
 868         :: TcRhoType
 869         -> Arity                -- N: Number of desired args
 870         -> ([TcSigmaType],      -- Arg types (N or fewer)
 871             TcSigmaType)        -- The rest of the type
 872
 873 tcSplitFunTysN ty n_args
 874   | n_args == 0
 875   = ([], ty)
 876   | Just (arg,res) <- tcSplitFunTy_maybe ty
 877   = case tcSplitFunTysN res (n_args - 1) of
 878         (args, res) -> (arg:args, res)
 879   | otherwise
 880   = ([], ty)
 881
 882 tcSplitFunTy :: Type -> (Type, Type)
 883 tcSplitFunTy  ty = expectJust "tcSplitFunTy" (tcSplitFunTy_maybe ty)
 884
 885 tcFunArgTy :: Type -> Type
 886 tcFunArgTy    ty = fst (tcSplitFunTy ty)
 887
 888 tcFunResultTy :: Type -> Type
 889 tcFunResultTy ty = snd (tcSplitFunTy ty)
 890
 891 -----------------------
 892 tcSplitAppTy_maybe :: Type -> Maybe (Type, Type)
 893 tcSplitAppTy_maybe ty | Just ty' <- tcView ty = tcSplitAppTy_maybe ty'
 894 tcSplitAppTy_maybe ty = repSplitAppTy_maybe ty
 895
 896 tcSplitAppTy :: Type -> (Type, Type)
 897 tcSplitAppTy ty = case tcSplitAppTy_maybe ty of
 898                     Just stuff -> stuff
 899                     Nothing    -> pprPanic "tcSplitAppTy" (pprType ty)
 900
 901 tcSplitAppTys :: Type -> (Type, [Type])
 902 tcSplitAppTys ty
 903   = go ty []
 904   where
 905     go ty args = case tcSplitAppTy_maybe ty of
 906                    Just (ty', arg) -> go ty' (arg:args)
 907                    Nothing         -> (ty,args)
 908
 909 -----------------------
 910 tcGetTyVar_maybe :: Type -> Maybe TyVar
 911 tcGetTyVar_maybe ty | Just ty' <- tcView ty = tcGetTyVar_maybe ty'
 912 tcGetTyVar_maybe (TyVarTy tv)   = Just tv
 913 tcGetTyVar_maybe _              = Nothing
 914
 915 tcGetTyVar :: String -> Type -> TyVar
 916 tcGetTyVar msg ty = expectJust msg (tcGetTyVar_maybe ty)
 917
 918 tcIsTyVarTy :: Type -> Bool
 919 tcIsTyVarTy ty = maybeToBool (tcGetTyVar_maybe ty)
 920
 921 -----------------------
 922 tcSplitDFunTy :: Type -> ([TyVar], Class, [Type])
 923 -- Split the type of a dictionary function
 924 -- We don't use tcSplitSigmaTy,  because a DFun may (with NDP)
 925 -- have non-Pred arguments, such as
 926 --     df :: forall m. (forall b. Eq b => Eq (m b)) -> C m
 927 tcSplitDFunTy ty
 928   = case tcSplitForAllTys ty                 of { (tvs, rho)  ->
 929     case tcSplitDFunHead (drop_pred_tys rho) of { (clas, tys) ->
 930     (tvs, clas, tys) }}
 931   where
 932     -- Discard the context of the dfun.  This can be a mix of
 933     -- coercion and class constraints; or (in the general NDP case)
 934     -- some other function argument
 935     drop_pred_tys ty | Just ty' <- tcView ty = drop_pred_tys ty'
 936     drop_pred_tys (ForAllTy tv ty) = ASSERT( isCoVar tv ) drop_pred_tys ty
 937     drop_pred_tys (FunTy _ ty)     = drop_pred_tys ty
 938     drop_pred_tys ty               = ty
 939
 940 tcSplitDFunHead :: Type -> (Class, [Type])
 941 tcSplitDFunHead tau
 942   = case tcSplitPredTy_maybe tau of
 943         Just (ClassP clas tys) -> (clas, tys)
 944         _ -> pprPanic "tcSplitDFunHead" (ppr tau)
 945
 946 tcInstHeadTyNotSynonym :: Type -> Bool
 947 -- Used in Haskell-98 mode, for the argument types of an instance head
 948 -- These must not be type synonyms, but everywhere else type synonyms
 949 -- are transparent, so we need a special function here
 950 tcInstHeadTyNotSynonym ty
 951   = case ty of
 952         TyConApp tc _ -> not (isSynTyCon tc)
 953         _ -> True
 954
 955 tcInstHeadTyAppAllTyVars :: Type -> Bool
 956 -- Used in Haskell-98 mode, for the argument types of an instance head
 957 -- These must be a constructor applied to type variable arguments
 958 tcInstHeadTyAppAllTyVars ty
 959   | Just ty' <- tcView ty       -- Look through synonyms
 960   = tcInstHeadTyAppAllTyVars ty'
 961   | otherwise
 962   = case ty of
 963         TyConApp _ tys  -> ok tys
 964         FunTy arg res   -> ok [arg, res]
 965         _               -> False
 966   where
 967         -- Check that all the types are type variables,
 968         -- and that each is distinct
 969     ok tys = equalLength tvs tys && hasNoDups tvs
 970            where
 971              tvs = mapCatMaybes get_tv tys
 972
 973     get_tv (TyVarTy tv)  = Just tv      -- through synonyms
 974     get_tv _             = Nothing
 975 \end{code}
 976
 977
 978
 979 %************************************************************************
 980 %*                                                                      *
 981 \subsection{Predicate types}
 982 %*                                                                      *
 983 %************************************************************************
 984
 985 \begin{code}
 986 evVarPred :: EvVar -> PredType
 987 evVarPred var
 988   = case tcSplitPredTy_maybe (varType var) of
 989       Just pred -> pred
 990       Nothing   -> pprPanic "evVarPred" (ppr var <+> ppr (varType var))
 991
 992 tcSplitPredTy_maybe :: Type -> Maybe PredType
 993    -- Returns Just for predicates only
 994 tcSplitPredTy_maybe ty | Just ty' <- tcView ty = tcSplitPredTy_maybe ty'
 995 tcSplitPredTy_maybe (PredTy p)    = Just p
 996 tcSplitPredTy_maybe _             = Nothing
 997
 998 predTyUnique :: PredType -> Unique
 999 predTyUnique (IParam n _)    = getUnique (ipNameName n)
1000 predTyUnique (ClassP clas _) = getUnique clas
1001 predTyUnique (EqPred a b)    = pprPanic "predTyUnique" (ppr (EqPred a b))
1002 \end{code}
1003
1004
1005 --------------------- Dictionary types ---------------------------------
1006
1007 \begin{code}
1008 mkClassPred :: Class -> [Type] -> PredType
1009 mkClassPred clas tys = ClassP clas tys
1010
1011 isClassPred :: PredType -> Bool
1012 isClassPred (ClassP _ _) = True
1013 isClassPred _            = False
1014
1015 isTyVarClassPred :: PredType -> Bool
1016 isTyVarClassPred (ClassP _ tys) = all tcIsTyVarTy tys
1017 isTyVarClassPred _              = False
1018
1019 getClassPredTys_maybe :: PredType -> Maybe (Class, [Type])
1020 getClassPredTys_maybe (ClassP clas tys) = Just (clas, tys)
1021 getClassPredTys_maybe _                 = Nothing
1022
1023 getClassPredTys :: PredType -> (Class, [Type])
1024 getClassPredTys (ClassP clas tys) = (clas, tys)
1025 getClassPredTys _ = panic "getClassPredTys"
1026
1027 mkDictTy :: Class -> [Type] -> Type
1028 mkDictTy clas tys = mkPredTy (ClassP clas tys)
1029
1030 isDictLikeTy :: Type -> Bool
1031 -- Note [Dictionary-like types]
1032 isDictLikeTy ty | Just ty' <- tcView ty = isDictTy ty'
1033 isDictLikeTy (PredTy p) = isClassPred p
1034 isDictLikeTy (TyConApp tc tys)
1035   | isTupleTyCon tc     = all isDictLikeTy tys
1036 isDictLikeTy _          = False
1037 \end{code}
1038
1039 Note [Dictionary-like types]
1040 ~~~~~~~~~~~~~~~~~~~~~~~~~~~~
1041 Being "dictionary-like" means either a dictionary type or a tuple thereof.
1042 In GHC 6.10 we build implication constraints which construct such tuples,
1043 and if we land up with a binding
1044     t :: (C [a], Eq [a])
1045     t = blah
1046 then we want to treat t as cheap under "-fdicts-cheap" for example.
1047 (Implication constraints are normally inlined, but sadly not if the
1048 occurrence is itself inside an INLINE function!  Until we revise the
1049 handling of implication constraints, that is.)  This turned out to
1050 be important in getting good arities in DPH code.  Example:
1051
1052     class C a
1053     class D a where { foo :: a -> a }
1054     instance C a => D (Maybe a) where { foo x = x }
1055
1056     bar :: (C a, C b) => a -> b -> (Maybe a, Maybe b)
1057     {-# INLINE bar #-}
1058     bar x y = (foo (Just x), foo (Just y))
1059
1060 Then 'bar' should jolly well have arity 4 (two dicts, two args), but
1061 we ended up with something like
1062    bar = __inline_me__ (\d1,d2. let t :: (D (Maybe a), D (Maybe b)) = ...
1063                                 in \x,y. <blah>)
1064
1065 This is all a bit ad-hoc; eg it relies on knowing that implication
1066 constraints build tuples.
1067
1068 --------------------- Implicit parameters ---------------------------------
1069
1070 \begin{code}
1071 mkIPPred :: IPName Name -> Type -> PredType
1072 mkIPPred ip ty = IParam ip ty
1073
1074 isIPPred :: PredType -> Bool
1075 isIPPred (IParam _ _) = True
1076 isIPPred _            = False
1077 \end{code}
1078
1079 --------------------- Equality predicates ---------------------------------
1080 \begin{code}
1081 substEqSpec :: TvSubst -> [(TyVar,Type)] -> [(TcType,TcType)]
1082 substEqSpec subst eq_spec = [ (substTyVar subst tv, substTy subst ty)
1083                             | (tv,ty) <- eq_spec]
1084 \end{code}
1085
1086
1087 %************************************************************************
1088 %*                                                                      *
1089 \subsection{Predicates}
1090 %*                                                                      *
1091 %************************************************************************
1092
1093 isSigmaTy returns true of any qualified type.  It doesn't *necessarily* have
1094 any foralls.  E.g.
1095         f :: (?x::Int) => Int -> Int
1096
1097 \begin{code}
1098 isSigmaTy :: Type -> Bool
1099 isSigmaTy ty | Just ty' <- tcView ty = isSigmaTy ty'
1100 isSigmaTy (ForAllTy _ _) = True
1101 isSigmaTy (FunTy a _)    = isPredTy a
1102 isSigmaTy _              = False
1103
1104 isOverloadedTy :: Type -> Bool
1105 -- Yes for a type of a function that might require evidence-passing
1106 -- Used only by bindLocalMethods
1107 -- NB: be sure to check for type with an equality predicate; hence isCoVar
1108 isOverloadedTy ty | Just ty' <- tcView ty = isOverloadedTy ty'
1109 isOverloadedTy (ForAllTy tv ty) = isCoVar tv || isOverloadedTy ty
1110 isOverloadedTy (FunTy a _)      = isPredTy a
1111 isOverloadedTy _                = False
1112
1113 isPredTy :: Type -> Bool        -- Belongs in TcType because it does
1114                                 -- not look through newtypes, or predtypes (of course)
1115 isPredTy ty | Just ty' <- tcView ty = isPredTy ty'
1116 isPredTy (PredTy _) = True
1117 isPredTy _          = False
1118 \end{code}
1119
1120 \begin{code}
1121 isFloatTy, isDoubleTy, isIntegerTy, isIntTy, isWordTy, isBoolTy,
1122     isUnitTy, isCharTy :: Type -> Bool
1123 isFloatTy      = is_tc floatTyConKey
1124 isDoubleTy     = is_tc doubleTyConKey
1125 isIntegerTy    = is_tc integerTyConKey
1126 isIntTy        = is_tc intTyConKey
1127 isWordTy       = is_tc wordTyConKey
1128 isBoolTy       = is_tc boolTyConKey
1129 isUnitTy       = is_tc unitTyConKey
1130 isCharTy       = is_tc charTyConKey
1131
1132 isStringTy :: Type -> Bool
1133 isStringTy ty
1134   = case tcSplitTyConApp_maybe ty of
1135       Just (tc, [arg_ty]) -> tc == listTyCon && isCharTy arg_ty
1136       _                   -> False
1137
1138 is_tc :: Unique -> Type -> Bool
1139 -- Newtypes are opaque to this
1140 is_tc uniq ty = case tcSplitTyConApp_maybe ty of
1141                         Just (tc, _) -> uniq == getUnique tc
1142                         Nothing      -> False
1143 \end{code}
1144
1145 \begin{code}
1146 -- NB: Currently used in places where we have already expanded type synonyms;
1147 --     hence no 'coreView'.  This could, however, be changed without breaking
1148 --     any code.
1149 isSynFamilyTyConApp :: TcTauType -> Bool
1150 isSynFamilyTyConApp (TyConApp tc tys) = isSynFamilyTyCon tc &&
1151                                       length tys == tyConArity tc
1152 isSynFamilyTyConApp _other            = False
1153 \end{code}
1154
1155
1156 %************************************************************************
1157 %*                                                                      *
1158 \subsection{Misc}
1159 %*                                                                      *
1160 %************************************************************************
1161
1162 \begin{code}
1163 deNoteType :: Type -> Type
1164 -- Remove all *outermost* type synonyms and other notes
1165 deNoteType ty | Just ty' <- tcView ty = deNoteType ty'
1166 deNoteType ty = ty
1167 \end{code}
1168
1169 \begin{code}
1170 tcTyVarsOfType :: Type -> TcTyVarSet
1171 -- Just the *TcTyVars* free in the type
1172 -- (Types.tyVarsOfTypes finds all free TyVars)
1173 tcTyVarsOfType (TyVarTy tv)         = if isTcTyVar tv then unitVarSet tv
1174                                                       else emptyVarSet
1175 tcTyVarsOfType (TyConApp _ tys)     = tcTyVarsOfTypes tys
1176 tcTyVarsOfType (PredTy sty)         = tcTyVarsOfPred sty
1177 tcTyVarsOfType (FunTy arg res)      = tcTyVarsOfType arg `unionVarSet` tcTyVarsOfType res
1178 tcTyVarsOfType (AppTy fun arg)      = tcTyVarsOfType fun `unionVarSet` tcTyVarsOfType arg
1179 tcTyVarsOfType (ForAllTy tyvar ty)  = (tcTyVarsOfType ty `delVarSet` tyvar)
1180                                       `unionVarSet` tcTyVarsOfTyVar tyvar
1181         -- We do sometimes quantify over skolem TcTyVars
1182
1183 tcTyVarsOfTyVar :: TcTyVar -> TyVarSet
1184 tcTyVarsOfTyVar tv | isCoVar tv = tcTyVarsOfType (tyVarKind tv)
1185                    | otherwise  = emptyVarSet
1186
1187 tcTyVarsOfTypes :: [Type] -> TyVarSet
1188 tcTyVarsOfTypes tys = foldr (unionVarSet.tcTyVarsOfType) emptyVarSet tys
1189
1190 tcTyVarsOfPred :: PredType -> TyVarSet
1191 tcTyVarsOfPred (IParam _ ty)    = tcTyVarsOfType ty
1192 tcTyVarsOfPred (ClassP _ tys)   = tcTyVarsOfTypes tys
1193 tcTyVarsOfPred (EqPred ty1 ty2) = tcTyVarsOfType ty1 `unionVarSet` tcTyVarsOfType ty2
1194 \end{code}
1195
1196 Note [Silly type synonym]
1197 ~~~~~~~~~~~~~~~~~~~~~~~~~
1198 Consider
1199         type T a = Int
1200 What are the free tyvars of (T x)?  Empty, of course!
1201 Here's the example that Ralf Laemmel showed me:
1202         foo :: (forall a. C u a -> C u a) -> u
1203         mappend :: Monoid u => u -> u -> u
1204
1205         bar :: Monoid u => u
1206         bar = foo (\t -> t `mappend` t)
1207 We have to generalise at the arg to f, and we don't
1208 want to capture the constraint (Monad (C u a)) because
1209 it appears to mention a.  Pretty silly, but it was useful to him.
1210
1211 exactTyVarsOfType is used by the type checker to figure out exactly
1212 which type variables are mentioned in a type.  It's also used in the
1213 smart-app checking code --- see TcExpr.tcIdApp
1214
1215 On the other hand, consider a *top-level* definition
1216         f = (\x -> x) :: T a -> T a
1217 If we don't abstract over 'a' it'll get fixed to GHC.Prim.Any, and then
1218 if we have an application like (f "x") we get a confusing error message
1219 involving Any.  So the conclusion is this: when generalising
1220   - at top level use tyVarsOfType
1221   - in nested bindings use exactTyVarsOfType
1222 See Trac #1813 for example.
1223
1224 \begin{code}
1225 exactTyVarsOfType :: TcType -> TyVarSet
1226 -- Find the free type variables (of any kind)
1227 -- but *expand* type synonyms.  See Note [Silly type synonym] above.
1228 exactTyVarsOfType ty
1229   = go ty
1230   where
1231     go ty | Just ty' <- tcView ty = go ty'      -- This is the key line
1232     go (TyVarTy tv)               = unitVarSet tv
1233     go (TyConApp _ tys)           = exactTyVarsOfTypes tys
1234     go (PredTy ty)                = go_pred ty
1235     go (FunTy arg res)            = go arg `unionVarSet` go res
1236     go (AppTy fun arg)            = go fun `unionVarSet` go arg
1237     go (ForAllTy tyvar ty)        = delVarSet (go ty) tyvar
1238                                     `unionVarSet` go_tv tyvar
1239
1240     go_pred (IParam _ ty)    = go ty
1241     go_pred (ClassP _ tys)   = exactTyVarsOfTypes tys
1242     go_pred (EqPred ty1 ty2) = go ty1 `unionVarSet` go ty2
1243
1244     go_tv tyvar | isCoVar tyvar = go (tyVarKind tyvar)
1245                 | otherwise     = emptyVarSet
1246
1247 exactTyVarsOfTypes :: [TcType] -> TyVarSet
1248 exactTyVarsOfTypes tys = foldr (unionVarSet . exactTyVarsOfType) emptyVarSet tys
1249 \end{code}
1250
1251 Find the free tycons and classes of a type.  This is used in the front
1252 end of the compiler.
1253
1254 \begin{code}
1255 tyClsNamesOfType :: Type -> NameSet
1256 tyClsNamesOfType (TyVarTy _)                = emptyNameSet
1257 tyClsNamesOfType (TyConApp tycon tys)       = unitNameSet (getName tycon) `unionNameSets` tyClsNamesOfTypes tys
1258 tyClsNamesOfType (PredTy (IParam _ ty))     = tyClsNamesOfType ty
1259 tyClsNamesOfType (PredTy (ClassP cl tys))   = unitNameSet (getName cl) `unionNameSets` tyClsNamesOfTypes tys
1260 tyClsNamesOfType (PredTy (EqPred ty1 ty2))  = tyClsNamesOfType ty1 `unionNameSets` tyClsNamesOfType ty2
1261 tyClsNamesOfType (FunTy arg res)            = tyClsNamesOfType arg `unionNameSets` tyClsNamesOfType res
1262 tyClsNamesOfType (AppTy fun arg)            = tyClsNamesOfType fun `unionNameSets` tyClsNamesOfType arg
1263 tyClsNamesOfType (ForAllTy _ ty)            = tyClsNamesOfType ty
1264
1265 tyClsNamesOfTypes :: [Type] -> NameSet
1266 tyClsNamesOfTypes tys = foldr (unionNameSets . tyClsNamesOfType) emptyNameSet tys
1267
1268 tyClsNamesOfDFunHead :: Type -> NameSet
1269 -- Find the free type constructors and classes
1270 -- of the head of the dfun instance type
1271 -- The 'dfun_head_type' is because of
1272 --      instance Foo a => Baz T where ...
1273 -- The decl is an orphan if Baz and T are both not locally defined,
1274 --      even if Foo *is* locally defined
1275 tyClsNamesOfDFunHead dfun_ty
1276   = case tcSplitSigmaTy dfun_ty of
1277         (_, _, head_ty) -> tyClsNamesOfType head_ty
1278 \end{code}
1279
1280
1281 %************************************************************************
1282 %*                                                                      *
1283 \subsection[TysWiredIn-ext-type]{External types}
1284 %*                                                                      *
1285 %************************************************************************
1286
1287 The compiler's foreign function interface supports the passing of a
1288 restricted set of types as arguments and results (the restricting factor
1289 being the )
1290
1291 \begin{code}
1292 tcSplitIOType_maybe :: Type -> Maybe (TyCon, Type, CoercionI)
1293 -- (isIOType t) returns Just (IO,t',co)
1294 --                              if co : t ~ IO t'
1295 --              returns Nothing otherwise
1296 tcSplitIOType_maybe ty
1297   = case tcSplitTyConApp_maybe ty of
1298         -- This split absolutely has to be a tcSplit, because we must
1299         -- see the IO type; and it's a newtype which is transparent to splitTyConApp.
1300
1301         Just (io_tycon, [io_res_ty])
1302            |  io_tycon `hasKey` ioTyConKey
1303            -> Just (io_tycon, io_res_ty, IdCo ty)
1304
1305         Just (tc, tys)
1306            | not (isRecursiveTyCon tc)
1307            , Just (ty, co1) <- instNewTyCon_maybe tc tys
1308                   -- Newtypes that require a coercion are ok
1309            -> case tcSplitIOType_maybe ty of
1310                 Nothing             -> Nothing
1311                 Just (tc, ty', co2) -> Just (tc, ty', co1 `mkTransCoI` co2)
1312
1313         _ -> Nothing
1314
1315 isFFITy :: Type -> Bool
1316 -- True for any TyCon that can possibly be an arg or result of an FFI call
1317 isFFITy ty = checkRepTyCon legalFFITyCon ty
1318
1319 isFFIArgumentTy :: DynFlags -> Safety -> Type -> Bool
1320 -- Checks for valid argument type for a 'foreign import'
1321 isFFIArgumentTy dflags safety ty
1322    = checkRepTyCon (legalOutgoingTyCon dflags safety) ty
1323
1324 isFFIExternalTy :: Type -> Bool
1325 -- Types that are allowed as arguments of a 'foreign export'
1326 isFFIExternalTy ty = checkRepTyCon legalFEArgTyCon ty
1327
1328 isFFIImportResultTy :: DynFlags -> Type -> Bool
1329 isFFIImportResultTy dflags ty
1330   = checkRepTyCon (legalFIResultTyCon dflags) ty
1331
1332 isFFIExportResultTy :: Type -> Bool
1333 isFFIExportResultTy ty = checkRepTyCon legalFEResultTyCon ty
1334
1335 isFFIDynArgumentTy :: Type -> Bool
1336 -- The argument type of a foreign import dynamic must be Ptr, FunPtr, Addr,
1337 -- or a newtype of either.
1338 isFFIDynArgumentTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1339
1340 isFFIDynResultTy :: Type -> Bool
1341 -- The result type of a foreign export dynamic must be Ptr, FunPtr, Addr,
1342 -- or a newtype of either.
1343 isFFIDynResultTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1344
1345 isFFILabelTy :: Type -> Bool
1346 -- The type of a foreign label must be Ptr, FunPtr, Addr,
1347 -- or a newtype of either.
1348 isFFILabelTy = checkRepTyConKey [ptrTyConKey, funPtrTyConKey]
1349
1350 isFFIPrimArgumentTy :: DynFlags -> Type -> Bool
1351 -- Checks for valid argument type for a 'foreign import prim'
1352 -- Currently they must all be simple unlifted types.
1353 isFFIPrimArgumentTy dflags ty
1354    = checkRepTyCon (legalFIPrimArgTyCon dflags) ty
1355
1356 isFFIPrimResultTy :: DynFlags -> Type -> Bool
1357 -- Checks for valid result type for a 'foreign import prim'
1358 -- Currently it must be an unlifted type, including unboxed tuples.
1359 isFFIPrimResultTy dflags ty
1360    = checkRepTyCon (legalFIPrimResultTyCon dflags) ty
1361
1362 isFFIDotnetTy :: DynFlags -> Type -> Bool
1363 isFFIDotnetTy dflags ty
1364   = checkRepTyCon (\ tc -> (legalFIResultTyCon dflags tc ||
1365                            isFFIDotnetObjTy ty || isStringTy ty)) ty
1366         -- NB: isStringTy used to look through newtypes, but
1367         --     it no longer does so.  May need to adjust isFFIDotNetTy
1368         --     if we do want to look through newtypes.
1369
1370 isFFIDotnetObjTy :: Type -> Bool
1371 isFFIDotnetObjTy ty
1372   = checkRepTyCon check_tc t_ty
1373   where
1374    (_, t_ty) = tcSplitForAllTys ty
1375    check_tc tc = getName tc == objectTyConName
1376
1377 isFunPtrTy :: Type -> Bool
1378 isFunPtrTy = checkRepTyConKey [funPtrTyConKey]
1379
1380 checkRepTyCon :: (TyCon -> Bool) -> Type -> Bool
1381 -- Look through newtypes, but *not* foralls
1382 -- Should work even for recursive newtypes
1383 -- eg Manuel had:       newtype T = MkT (Ptr T)
1384 checkRepTyCon check_tc ty
1385   = go [] ty
1386   where
1387     go rec_nts ty
1388       | Just (tc,tys) <- splitTyConApp_maybe ty
1389       = case carefullySplitNewType_maybe rec_nts tc tys of
1390            Just (rec_nts', ty') -> go rec_nts' ty'
1391            Nothing              -> check_tc tc
1392       | otherwise
1393       = False
1394
1395 checkRepTyConKey :: [Unique] -> Type -> Bool
1396 -- Like checkRepTyCon, but just looks at the TyCon key
1397 checkRepTyConKey keys
1398   = checkRepTyCon (\tc -> tyConUnique tc `elem` keys)
1399 \end{code}
1400
1401 ----------------------------------------------
1402 These chaps do the work; they are not exported
1403 ----------------------------------------------
1404
1405 \begin{code}
1406 legalFEArgTyCon :: TyCon -> Bool
1407 legalFEArgTyCon tc
1408   -- It's illegal to make foreign exports that take unboxed
1409   -- arguments.  The RTS API currently can't invoke such things.  --SDM 7/2000
1410   = boxedMarshalableTyCon tc
1411
1412 legalFIResultTyCon :: DynFlags -> TyCon -> Bool
1413 legalFIResultTyCon dflags tc
1414   | tc == unitTyCon         = True
1415   | otherwise               = marshalableTyCon dflags tc
1416
1417 legalFEResultTyCon :: TyCon -> Bool
1418 legalFEResultTyCon tc
1419   | tc == unitTyCon         = True
1420   | otherwise               = boxedMarshalableTyCon tc
1421
1422 legalOutgoingTyCon :: DynFlags -> Safety -> TyCon -> Bool
1423 -- Checks validity of types going from Haskell -> external world
1424 legalOutgoingTyCon dflags _ tc
1425   = marshalableTyCon dflags tc
1426
1427 legalFFITyCon :: TyCon -> Bool
1428 -- True for any TyCon that can possibly be an arg or result of an FFI call
1429 legalFFITyCon tc
1430   = isUnLiftedTyCon tc || boxedMarshalableTyCon tc || tc == unitTyCon
1431
1432 marshalableTyCon :: DynFlags -> TyCon -> Bool
1433 marshalableTyCon dflags tc
1434   =  (xopt Opt_UnliftedFFITypes dflags
1435       && isUnLiftedTyCon tc
1436       && not (isUnboxedTupleTyCon tc)
1437       && case tyConPrimRep tc of        -- Note [Marshalling VoidRep]
1438            VoidRep -> False
1439            _       -> True)
1440   || boxedMarshalableTyCon tc
1441
1442 boxedMarshalableTyCon :: TyCon -> Bool
1443 boxedMarshalableTyCon tc
1444    = getUnique tc `elem` [ intTyConKey, int8TyConKey, int16TyConKey
1445                          , int32TyConKey, int64TyConKey
1446                          , wordTyConKey, word8TyConKey, word16TyConKey
1447                          , word32TyConKey, word64TyConKey
1448                          , floatTyConKey, doubleTyConKey
1449                          , ptrTyConKey, funPtrTyConKey
1450                          , charTyConKey
1451                          , stablePtrTyConKey
1452                          , boolTyConKey
1453                          ]
1454
1455 legalFIPrimArgTyCon :: DynFlags -> TyCon -> Bool
1456 -- Check args of 'foreign import prim', only allow simple unlifted types.
1457 -- Strictly speaking it is unnecessary to ban unboxed tuples here since
1458 -- currently they're of the wrong kind to use in function args anyway.
1459 legalFIPrimArgTyCon dflags tc
1460   = xopt Opt_UnliftedFFITypes dflags
1461     && isUnLiftedTyCon tc
1462     && not (isUnboxedTupleTyCon tc)
1463
1464 legalFIPrimResultTyCon :: DynFlags -> TyCon -> Bool
1465 -- Check result type of 'foreign import prim'. Allow simple unlifted
1466 -- types and also unboxed tuple result types '... -> (# , , #)'
1467 legalFIPrimResultTyCon dflags tc
1468   = xopt Opt_UnliftedFFITypes dflags
1469     && isUnLiftedTyCon tc
1470     && (isUnboxedTupleTyCon tc
1471         || case tyConPrimRep tc of      -- Note [Marshalling VoidRep]
1472            VoidRep -> False
1473            _       -> True)
1474 \end{code}
1475
1476 Note [Marshalling VoidRep]
1477 ~~~~~~~~~~~~~~~~~~~~~~~~~~
1478 We don't treat State# (whose PrimRep is VoidRep) as marshalable.
1479 In turn that means you can't write
1480         foreign import foo :: Int -> State# RealWorld
1481
1482 Reason: the back end falls over with panic "primRepHint:VoidRep";
1483         and there is no compelling reason to permit it