compiler/typecheck/TcUnify.lhs

   1 %
   2 % (c) The GRASP/AQUA Project, Glasgow University, 1992-1998
   3 %
   4 \section{Type subsumption and unification}
   5
   6 \begin{code}
   7 module TcUnify (
   8         -- Full-blown subsumption
   9   tcSubExp, tcFunResTy, tcGen,
  10   checkSigTyVars, checkSigTyVarsWrt, bleatEscapedTvs, sigCtxt,
  11
  12         -- Various unifications
  13   unifyType, unifyTypeList, unifyTheta,
  14   unifyKind, unifyKinds, unifyFunKind,
  15   checkExpectedKind,
  16   preSubType, boxyMatchTypes,
  17
  18   --------------------------------
  19   -- Holes
  20   tcInfer, subFunTys, unBox, stripBoxyType, withBox,
  21   boxyUnify, boxyUnifyList, zapToMonotype,
  22   boxySplitListTy, boxySplitTyConApp, boxySplitAppTy,
  23   wrapFunResCoercion
  24   ) where
  25
  26 #include "HsVersions.h"
  27
  28 import HsSyn            ( ExprCoFn(..), idCoercion, isIdCoercion, (<.>) )
  29 import TypeRep          ( Type(..), PredType(..) )
  30
  31 import TcMType          ( lookupTcTyVar, LookupTyVarResult(..),
  32                           tcInstSkolType, tcInstBoxyTyVar, newKindVar, newMetaTyVar,
  33                           newBoxyTyVar, newBoxyTyVarTys, readFilledBox,
  34                           readMetaTyVar, writeMetaTyVar, newFlexiTyVarTy,
  35                           tcInstSkolTyVars, tcInstTyVar,
  36                           zonkTcKind, zonkType, zonkTcType,  zonkTcTyVarsAndFV,
  37                           readKindVar, writeKindVar )
  38 import TcSimplify       ( tcSimplifyCheck )
  39 import TcEnv            ( tcGetGlobalTyVars, findGlobals )
  40 import TcIface          ( checkWiredInTyCon )
  41 import TcRnMonad         -- TcType, amongst others
  42 import TcType           ( TcKind, TcType, TcTyVar, BoxyTyVar, TcTauType,
  43                           BoxySigmaType, BoxyRhoType, BoxyType,
  44                           TcTyVarSet, TcThetaType, TcTyVarDetails(..), BoxInfo(..),
  45                           SkolemInfo( GenSkol, UnkSkol ), MetaDetails(..), isImmutableTyVar,
  46                           pprSkolTvBinding, isTauTy, isTauTyCon, isSigmaTy,
  47                           mkFunTy, mkFunTys, mkTyConApp, isMetaTyVar,
  48                           tcSplitForAllTys, tcSplitAppTy_maybe, tcSplitFunTys, mkTyVarTys,
  49                           tcSplitSigmaTy, tyVarsOfType, mkPhiTy, mkTyVarTy, mkPredTy,
  50                           typeKind, mkForAllTys, mkAppTy, isBoxyTyVar,
  51                           tcView, exactTyVarsOfType,
  52                           tidyOpenType, tidyOpenTyVar, tidyOpenTyVars,
  53                           pprType, tidyKind, tidySkolemTyVar, isSkolemTyVar, isSigTyVar,
  54                           TvSubst, mkTvSubst, zipTyEnv, zipOpenTvSubst, emptyTvSubst,
  55                           substTy, substTheta,
  56                           lookupTyVar, extendTvSubst )
  57 import Kind             ( Kind(..), SimpleKind, KindVar, isArgTypeKind,
  58                           openTypeKind, liftedTypeKind, unliftedTypeKind,
  59                           mkArrowKind, defaultKind,
  60                           isOpenTypeKind, argTypeKind, isLiftedTypeKind, isUnliftedTypeKind,
  61                           isSubKind, pprKind, splitKindFunTys )
  62 import TysPrim          ( alphaTy, betaTy )
  63 import Inst             ( newDicts, instToId )
  64 import TyCon            ( TyCon, tyConArity, tyConTyVars, isSynTyCon )
  65 import TysWiredIn       ( listTyCon )
  66 import Id               ( Id, mkSysLocal )
  67 import Var              ( Var, varName, tyVarKind, isTcTyVar, tcTyVarDetails )
  68 import VarSet
  69 import VarEnv
  70 import Name             ( Name, isSystemName )
  71 import ErrUtils         ( Message )
  72 import Maybes           ( expectJust, isNothing )
  73 import BasicTypes       ( Arity )
  74 import UniqSupply       ( uniqsFromSupply )
  75 import Util             ( notNull, equalLength )
  76 import Outputable
  77
  78 -- Assertion imports
  79 #ifdef DEBUG
  80 import TcType           ( isBoxyTy, isFlexi )
  81 #endif
  82 \end{code}
  83
  84 %************************************************************************
  85 %*                                                                      *
  86 \subsection{'hole' type variables}
  87 %*                                                                      *
  88 %************************************************************************
  89
  90 \begin{code}
  91 tcInfer :: (BoxyType -> TcM a) -> TcM (a, TcType)
  92 tcInfer tc_infer
  93   = do  { box <- newBoxyTyVar openTypeKind
  94         ; res <- tc_infer (mkTyVarTy box)
  95         ; res_ty <- readFilledBox box   -- Guaranteed filled-in by now
  96         ; return (res, res_ty) }
  97 \end{code}
  98
  99
 100 %************************************************************************
 101 %*                                                                      *
 102         subFunTys
 103 %*                                                                      *
 104 %************************************************************************
 105
 106 \begin{code}
 107 subFunTys :: SDoc  -- Somthing like "The function f has 3 arguments"
 108                    -- or "The abstraction (\x.e) takes 1 argument"
 109           -> Arity              -- Expected # of args
 110           -> BoxyRhoType        -- res_ty
 111           -> ([BoxySigmaType] -> BoxyRhoType -> TcM a)
 112           -> TcM (ExprCoFn, a)
 113 -- Attempt to decompse res_ty to have enough top-level arrows to
 114 -- match the number of patterns in the match group
 115 --
 116 -- If (subFunTys n_args res_ty thing_inside) = (co_fn, res)
 117 -- and the inner call to thing_inside passes args: [a1,...,an], b
 118 -- then co_fn :: (a1 -> ... -> an -> b) -> res_ty
 119 --
 120 -- Note that it takes a BoxyRho type, and guarantees to return a BoxyRhoType
 121
 122
 123 {-      Error messages from subFunTys
 124
 125    The abstraction `\Just 1 -> ...' has two arguments
 126    but its type `Maybe a -> a' has only one
 127
 128    The equation(s) for `f' have two arguments
 129    but its type `Maybe a -> a' has only one
 130
 131    The section `(f 3)' requires 'f' to take two arguments
 132    but its type `Int -> Int' has only one
 133
 134    The function 'f' is applied to two arguments
 135    but its type `Int -> Int' has only one
 136 -}
 137
 138
 139 subFunTys error_herald n_pats res_ty thing_inside
 140   = loop n_pats [] res_ty
 141   where
 142         -- In 'loop', the parameter 'arg_tys' accumulates
 143         -- the arg types so far, in *reverse order*
 144     loop n args_so_far res_ty
 145         | Just res_ty' <- tcView res_ty  = loop n args_so_far res_ty'
 146
 147     loop n args_so_far res_ty
 148         | isSigmaTy res_ty      -- Do this before checking n==0, because we
 149                                 -- guarantee to return a BoxyRhoType, not a BoxySigmaType
 150         = do { (gen_fn, (co_fn, res)) <- tcGen res_ty emptyVarSet $ \ res_ty' ->
 151                                          loop n args_so_far res_ty'
 152              ; return (gen_fn <.> co_fn, res) }
 153
 154     loop 0 args_so_far res_ty
 155         = do { res <- thing_inside (reverse args_so_far) res_ty
 156              ; return (idCoercion, res) }
 157
 158     loop n args_so_far (FunTy arg_ty res_ty)
 159         = do { (co_fn, res) <- loop (n-1) (arg_ty:args_so_far) res_ty
 160              ; co_fn' <- wrapFunResCoercion [arg_ty] co_fn
 161              ; return (co_fn', res) }
 162
 163         -- res_ty might have a type variable at the head, such as (a b c),
 164         -- in which case we must fill in with (->).  Simplest thing to do
 165         -- is to use boxyUnify, but we catch failure and generate our own
 166         -- error message on failure
 167     loop n args_so_far res_ty@(AppTy _ _)
 168         = do { [arg_ty',res_ty'] <- newBoxyTyVarTys [argTypeKind, openTypeKind]
 169              ; (_, mb_unit) <- tryTcErrs $ boxyUnify res_ty (FunTy arg_ty' res_ty')
 170              ; if isNothing mb_unit then bale_out args_so_far
 171                else loop n args_so_far (FunTy arg_ty' res_ty') }
 172
 173     loop n args_so_far (TyVarTy tv)
 174         | not (isImmutableTyVar tv)
 175         = do { cts <- readMetaTyVar tv
 176              ; case cts of
 177                  Indirect ty -> loop n args_so_far ty
 178                  Flexi -> do { (res_ty:arg_tys) <- withMetaTvs tv kinds mk_res_ty
 179                              ; res <- thing_inside (reverse args_so_far ++ arg_tys) res_ty
 180                              ; return (idCoercion, res) } }
 181         where
 182           mk_res_ty (res_ty' : arg_tys') = mkFunTys arg_tys' res_ty'
 183           mk_res_ty [] = panic "TcUnify.mk_res_ty1"
 184           kinds = openTypeKind : take n (repeat argTypeKind)
 185                 -- Note argTypeKind: the args can have an unboxed type,
 186                 -- but not an unboxed tuple.
 187
 188     loop n args_so_far res_ty = bale_out args_so_far
 189
 190     bale_out args_so_far
 191         = do { env0 <- tcInitTidyEnv
 192              ; res_ty' <- zonkTcType res_ty
 193              ; let (env1, res_ty'') = tidyOpenType env0 res_ty'
 194              ; failWithTcM (env1, mk_msg res_ty'' (length args_so_far)) }
 195
 196     mk_msg res_ty n_actual
 197       = error_herald <> comma $$
 198         sep [ptext SLIT("but its type") <+> quotes (pprType res_ty),
 199              if n_actual == 0 then ptext SLIT("has none")
 200              else ptext SLIT("has only") <+> speakN n_actual]
 201 \end{code}
 202
 203 \begin{code}
 204 ----------------------
 205 boxySplitTyConApp :: TyCon                      -- T :: k1 -> ... -> kn -> *
 206                   -> BoxyRhoType                -- Expected type (T a b c)
 207                   -> TcM [BoxySigmaType]        -- Element types, a b c
 208   -- It's used for wired-in tycons, so we call checkWiredInTyCOn
 209   -- Precondition: never called with FunTyCon
 210   -- Precondition: input type :: *
 211
 212 boxySplitTyConApp tc orig_ty
 213   = do  { checkWiredInTyCon tc
 214         ; loop (tyConArity tc) [] orig_ty }
 215   where
 216     loop n_req args_so_far ty
 217       | Just ty' <- tcView ty = loop n_req args_so_far ty'
 218
 219     loop n_req args_so_far (TyConApp tycon args)
 220       | tc == tycon
 221       = ASSERT( n_req == length args)   -- ty::*
 222         return (args ++ args_so_far)
 223
 224     loop n_req args_so_far (AppTy fun arg)
 225       = loop (n_req - 1) (arg:args_so_far) fun
 226
 227     loop n_req args_so_far (TyVarTy tv)
 228       | not (isImmutableTyVar tv)
 229       = do { cts <- readMetaTyVar tv
 230            ; case cts of
 231                Indirect ty -> loop n_req args_so_far ty
 232                Flexi       -> do { arg_tys <- withMetaTvs tv arg_kinds mk_res_ty
 233                                  ; return (arg_tys ++ args_so_far) }
 234         }
 235       where
 236         mk_res_ty arg_tys' = mkTyConApp tc arg_tys'
 237         arg_kinds = map tyVarKind (take n_req (tyConTyVars tc))
 238
 239     loop _ _ _ = boxySplitFailure (mkTyConApp tc (mkTyVarTys (tyConTyVars tc))) orig_ty
 240
 241 ----------------------
 242 boxySplitListTy :: BoxyRhoType -> TcM BoxySigmaType     -- Special case for lists
 243 boxySplitListTy exp_ty = do { [elt_ty] <- boxySplitTyConApp listTyCon exp_ty
 244                             ; return elt_ty }
 245
 246
 247 ----------------------
 248 boxySplitAppTy :: BoxyRhoType                           -- Type to split: m a
 249                -> TcM (BoxySigmaType, BoxySigmaType)    -- Returns m, a
 250 -- Assumes (m: * -> k), where k is the kind of the incoming type
 251 -- If the incoming type is boxy, then so are the result types; and vice versa
 252
 253 boxySplitAppTy orig_ty
 254   = loop orig_ty
 255   where
 256     loop ty
 257       | Just ty' <- tcView ty = loop ty'
 258
 259     loop ty
 260       | Just (fun_ty, arg_ty) <- tcSplitAppTy_maybe ty
 261       = return (fun_ty, arg_ty)
 262
 263     loop (TyVarTy tv)
 264       | not (isImmutableTyVar tv)
 265       = do { cts <- readMetaTyVar tv
 266            ; case cts of
 267                Indirect ty -> loop ty
 268                Flexi       -> do { [fun_ty,arg_ty] <- withMetaTvs tv kinds mk_res_ty
 269                                  ; return (fun_ty, arg_ty) } }
 270       where
 271         mk_res_ty [fun_ty', arg_ty'] = mkAppTy fun_ty' arg_ty'
 272         mk_res_ty other = panic "TcUnify.mk_res_ty2"
 273         tv_kind = tyVarKind tv
 274         kinds = [mkArrowKind liftedTypeKind (defaultKind tv_kind),
 275                                                 -- m :: * -> k
 276                  liftedTypeKind]                -- arg type :: *
 277         -- The defaultKind is a bit smelly.  If you remove it,
 278         -- try compiling        f x = do { x }
 279         -- and you'll get a kind mis-match.  It smells, but
 280         -- not enough to lose sleep over.
 281
 282     loop _ = boxySplitFailure (mkAppTy alphaTy betaTy) orig_ty
 283
 284 ------------------
 285 boxySplitFailure actual_ty expected_ty
 286   = unifyMisMatch False False actual_ty expected_ty
 287         -- "outer" is False, so we don't pop the context
 288         -- which is what we want since we have not pushed one!
 289 \end{code}
 290
 291
 292 --------------------------------
 293 -- withBoxes: the key utility function
 294 --------------------------------
 295
 296 \begin{code}
 297 withMetaTvs :: TcTyVar  -- An unfilled-in, non-skolem, meta type variable
 298             -> [Kind]   -- Make fresh boxes (with the same BoxTv/TauTv setting as tv)
 299             -> ([BoxySigmaType] -> BoxySigmaType)
 300                                         -- Constructs the type to assign
 301                                         -- to the original var
 302             -> TcM [BoxySigmaType]      -- Return the fresh boxes
 303
 304 -- It's entirely possible for the [kind] to be empty.
 305 -- For example, when pattern-matching on True,
 306 -- we call boxySplitTyConApp passing a boolTyCon
 307
 308 -- Invariant: tv is still Flexi
 309
 310 withMetaTvs tv kinds mk_res_ty
 311   | isBoxyTyVar tv
 312   = do  { box_tvs <- mapM (newMetaTyVar BoxTv) kinds
 313         ; let box_tys = mkTyVarTys box_tvs
 314         ; writeMetaTyVar tv (mk_res_ty box_tys)
 315         ; return box_tys }
 316
 317   | otherwise                   -- Non-boxy meta type variable
 318   = do  { tau_tys <- mapM newFlexiTyVarTy kinds
 319         ; writeMetaTyVar tv (mk_res_ty tau_tys) -- Write it *first*
 320                                                 -- Sure to be a tau-type
 321         ; return tau_tys }
 322
 323 withBox :: Kind -> (BoxySigmaType -> TcM a) -> TcM (a, TcType)
 324 -- Allocate a *boxy* tyvar
 325 withBox kind thing_inside
 326   = do  { box_tv <- newMetaTyVar BoxTv kind
 327         ; res <- thing_inside (mkTyVarTy box_tv)
 328         ; ty  <- readFilledBox box_tv
 329         ; return (res, ty) }
 330 \end{code}
 331
 332
 333 %************************************************************************
 334 %*                                                                      *
 335                 Approximate boxy matching
 336 %*                                                                      *
 337 %************************************************************************
 338
 339 \begin{code}
 340 preSubType :: [TcTyVar]         -- Quantified type variables
 341            -> TcTyVarSet        -- Subset of quantified type variables
 342                                 -- that can be instantiated with boxy types
 343             -> TcType           -- The rho-type part; quantified tyvars scopes over this
 344             -> BoxySigmaType    -- Matching type from the context
 345             -> TcM [TcType]     -- Types to instantiate the tyvars
 346 -- Perform pre-subsumption, and return suitable types
 347 -- to instantiate the quantified type varibles:
 348 --      info from the pre-subsumption, if there is any
 349 --      a boxy type variable otherwise
 350 --
 351 -- The 'btvs' are a subset of 'qtvs'.  They are the ones we can
 352 -- instantiate to a boxy type variable, because they'll definitely be
 353 -- filled in later.  This isn't always the case; sometimes we have type
 354 -- variables mentioned in the context of the type, but not the body;
 355 --              f :: forall a b. C a b => a -> a
 356 -- Then we may land up with an unconstrained 'b', so we want to
 357 -- instantiate it to a monotype (non-boxy) type variable
 358
 359 preSubType qtvs btvs qty expected_ty
 360   = do { tys <- mapM inst_tv qtvs
 361         ; traceTc (text "preSubType" <+> (ppr qtvs $$ ppr btvs $$ ppr qty $$ ppr expected_ty $$ ppr pre_subst $$ ppr tys))
 362         ; return tys }
 363   where
 364     pre_subst = boxySubMatchType (mkVarSet qtvs) qty expected_ty
 365     inst_tv tv
 366         | Just boxy_ty <- lookupTyVar pre_subst tv = return boxy_ty
 367         | tv `elemVarSet` btvs = do { tv' <- tcInstBoxyTyVar tv
 368                                     ; return (mkTyVarTy tv') }
 369         | otherwise            = do { tv' <- tcInstTyVar tv
 370                                     ; return (mkTyVarTy tv') }
 371
 372 boxySubMatchType
 373         :: TcTyVarSet -> TcType -- The "template"; the tyvars are skolems
 374         -> BoxyRhoType          -- Type to match (note a *Rho* type)
 375         -> TvSubst              -- Substitution of the [TcTyVar] to BoxySigmaTypes
 376
 377 -- boxySubMatchType implements the Pre-subsumption judgement, in Fig 5 of the paper
 378 -- "Boxy types: inference for higher rank types and impredicativity"
 379
 380 boxySubMatchType tmpl_tvs tmpl_ty boxy_ty
 381   = go tmpl_tvs tmpl_ty emptyVarSet boxy_ty
 382   where
 383     go t_tvs t_ty b_tvs b_ty
 384         | Just t_ty' <- tcView t_ty = go t_tvs t_ty' b_tvs b_ty
 385         | Just b_ty' <- tcView b_ty = go t_tvs t_ty b_tvs b_ty'
 386
 387     go t_tvs (TyVarTy _) b_tvs b_ty = emptyTvSubst      -- Rule S-ANY; no bindings
 388         -- Rule S-ANY covers (a) type variables and (b) boxy types
 389         -- in the template.  Both look like a TyVarTy.
 390         -- See Note [Sub-match] below
 391
 392     go t_tvs t_ty b_tvs b_ty
 393         | isSigmaTy t_ty, (tvs, _, t_tau) <- tcSplitSigmaTy t_ty
 394         = go (t_tvs `delVarSetList` tvs) t_tau b_tvs b_ty       -- Rule S-SPEC
 395                 -- Under a forall on the left, if there is shadowing,
 396                 -- do not bind! Hence the delVarSetList.
 397         | isSigmaTy b_ty, (tvs, _, b_tau) <- tcSplitSigmaTy b_ty
 398         = go t_tvs t_ty (extendVarSetList b_tvs tvs) b_tau      -- Rule S-SKOL
 399                 -- Add to the variables we must not bind to
 400         -- NB: it's *important* to discard the theta part. Otherwise
 401         -- consider (forall a. Eq a => a -> b) ~<~ (Int -> Int -> Bool)
 402         -- and end up with a completely bogus binding (b |-> Bool), by lining
 403         -- up the (Eq a) with the Int, whereas it should be (b |-> (Int->Bool)).
 404         -- This pre-subsumption stuff can return too few bindings, but it
 405         -- must *never* return bogus info.
 406
 407     go t_tvs (FunTy arg1 res1) b_tvs (FunTy arg2 res2)  -- Rule S-FUN
 408         = boxy_match t_tvs arg1 b_tvs arg2 (go t_tvs res1 b_tvs res2)
 409         -- Match the args, and sub-match the results
 410
 411     go t_tvs t_ty b_tvs b_ty = boxy_match t_tvs t_ty b_tvs b_ty emptyTvSubst
 412         -- Otherwise defer to boxy matching
 413         -- This covers TyConApp, AppTy, PredTy
 414 \end{code}
 415
 416 Note [Sub-match]
 417 ~~~~~~~~~~~~~~~~
 418 Consider this
 419         head :: [a] -> a
 420         |- head xs : <rhobox>
 421 We will do a boxySubMatchType between   a ~ <rhobox>
 422 But we *don't* want to match [a |-> <rhobox>] because
 423     (a) The box should be filled in with a rho-type, but
 424            but the returned substitution maps TyVars to boxy
 425            *sigma* types
 426     (b) In any case, the right final answer might be *either*
 427            instantiate 'a' with a rho-type or a sigma type
 428            head xs : Int   vs   head xs : forall b. b->b
 429 So the matcher MUST NOT make a choice here.   In general, we only
 430 bind a template type variable in boxyMatchType, not in boxySubMatchType.
 431
 432
 433 \begin{code}
 434 boxyMatchTypes
 435         :: TcTyVarSet -> [TcType] -- The "template"; the tyvars are skolems
 436         -> [BoxySigmaType]        -- Type to match
 437         -> TvSubst                -- Substitution of the [TcTyVar] to BoxySigmaTypes
 438
 439 -- boxyMatchTypes implements the Pre-matching judgement, in Fig 5 of the paper
 440 -- "Boxy types: inference for higher rank types and impredicativity"
 441
 442 -- Find a *boxy* substitution that makes the template look as much
 443 --      like the BoxySigmaType as possible.
 444 -- It's always ok to return an empty substitution;
 445 --      anything more is jam on the pudding
 446 --
 447 -- NB1: This is a pure, non-monadic function.
 448 --      It does no unification, and cannot fail
 449 --
 450 -- Precondition: the arg lengths are equal
 451 -- Precondition: none of the template type variables appear anywhere in the [BoxySigmaType]
 452 --
 453
 454 ------------
 455 boxyMatchTypes tmpl_tvs tmpl_tys boxy_tys
 456   = ASSERT( length tmpl_tys == length boxy_tys )
 457     boxy_match_s tmpl_tvs tmpl_tys emptyVarSet boxy_tys emptyTvSubst
 458         -- ToDo: add error context?
 459
 460 boxy_match_s tmpl_tvs [] boxy_tvs [] subst
 461   = subst
 462 boxy_match_s tmpl_tvs (t_ty:t_tys) boxy_tvs (b_ty:b_tys) subst
 463   = boxy_match tmpl_tvs t_ty boxy_tvs b_ty $
 464     boxy_match_s tmpl_tvs t_tys boxy_tvs b_tys subst
 465 boxy_match_s tmpl_tvs _ boxy_tvs _ subst
 466   = panic "boxy_match_s"        -- Lengths do not match
 467
 468
 469 ------------
 470 boxy_match :: TcTyVarSet -> TcType      -- Template
 471            -> TcTyVarSet                -- boxy_tvs: do not bind template tyvars to any of these
 472            -> BoxySigmaType             -- Match against this type
 473            -> TvSubst
 474            -> TvSubst
 475
 476 -- The boxy_tvs argument prevents this match:
 477 --      [a]  forall b. a  ~  forall b. b
 478 -- We don't want to bind the template variable 'a'
 479 -- to the quantified type variable 'b'!
 480
 481 boxy_match tmpl_tvs orig_tmpl_ty boxy_tvs orig_boxy_ty subst
 482   = go orig_tmpl_ty orig_boxy_ty
 483   where
 484     go t_ty b_ty
 485         | Just t_ty' <- tcView t_ty = go t_ty' b_ty
 486         | Just b_ty' <- tcView b_ty = go t_ty b_ty'
 487
 488     go ty1 ty2          -- C.f. the isSigmaTy case for boxySubMatchType
 489         | isSigmaTy ty1
 490         , (tvs1, _, tau1) <- tcSplitSigmaTy ty1
 491         , (tvs2, _, tau2) <- tcSplitSigmaTy ty2
 492         , equalLength tvs1 tvs2
 493         = boxy_match (tmpl_tvs `delVarSetList` tvs1)    tau1
 494                      (boxy_tvs `extendVarSetList` tvs2) tau2 subst
 495
 496     go (TyConApp tc1 tys1) (TyConApp tc2 tys2)
 497         | tc1 == tc2 = go_s tys1 tys2
 498
 499     go (FunTy arg1 res1) (FunTy arg2 res2)
 500         = go_s [arg1,res1] [arg2,res2]
 501
 502     go t_ty b_ty
 503         | Just (s1,t1) <- tcSplitAppTy_maybe t_ty,
 504           Just (s2,t2) <- tcSplitAppTy_maybe b_ty,
 505           typeKind t2 `isSubKind` typeKind t1   -- Maintain invariant
 506         = go_s [s1,t1] [s2,t2]
 507
 508     go (TyVarTy tv) b_ty
 509         | tv `elemVarSet` tmpl_tvs      -- Template type variable in the template
 510         , not (intersectsVarSet boxy_tvs (tyVarsOfType orig_boxy_ty))
 511         , typeKind b_ty `isSubKind` tyVarKind tv  -- See Note [Matching kinds]
 512         = extendTvSubst subst tv boxy_ty'
 513         | otherwise
 514         = subst                         -- Ignore others
 515         where
 516           boxy_ty' = case lookupTyVar subst tv of
 517                         Nothing -> orig_boxy_ty
 518                         Just ty -> ty `boxyLub` orig_boxy_ty
 519
 520     go _ _ = emptyTvSubst       -- It's important to *fail* by returning the empty substitution
 521         -- Example:  Tree a ~ Maybe Int
 522         -- We do not want to bind (a |-> Int) in pre-matching, because that can give very
 523         -- misleading error messages.  An even more confusing case is
 524         --           a -> b ~ Maybe Int
 525         -- Then we do not want to bind (b |-> Int)!  It's always safe to discard bindings
 526         -- from this pre-matching phase.
 527
 528     --------
 529     go_s tys1 tys2 = boxy_match_s tmpl_tvs tys1 boxy_tvs tys2 subst
 530
 531
 532 boxyLub :: BoxySigmaType -> BoxySigmaType -> BoxySigmaType
 533 -- Combine boxy information from the two types
 534 -- If there is a conflict, return the first
 535 boxyLub orig_ty1 orig_ty2
 536   = go orig_ty1 orig_ty2
 537   where
 538     go (AppTy f1 a1) (AppTy f2 a2) = AppTy (boxyLub f1 f2) (boxyLub a1 a2)
 539     go (FunTy f1 a1) (FunTy f2 a2) = FunTy (boxyLub f1 f2) (boxyLub a1 a2)
 540     go (TyConApp tc1 ts1) (TyConApp tc2 ts2)
 541       | tc1 == tc2, length ts1 == length ts2
 542       = TyConApp tc1 (zipWith boxyLub ts1 ts2)
 543
 544     go (TyVarTy tv1) ty2                -- This is the whole point;
 545       | isTcTyVar tv1, isBoxyTyVar tv1  -- choose ty2 if ty2 is a box
 546       = orig_ty2
 547
 548         -- Look inside type synonyms, but only if the naive version fails
 549     go ty1 ty2 | Just ty1' <- tcView ty1 = go ty1' ty2
 550                | Just ty2' <- tcView ty1 = go ty1 ty2'
 551
 552     -- For now, we don't look inside ForAlls, PredTys
 553     go ty1 ty2 = orig_ty1       -- Default
 554 \end{code}
 555
 556 Note [Matching kinds]
 557 ~~~~~~~~~~~~~~~~~~~~~
 558 The target type might legitimately not be a sub-kind of template.
 559 For example, suppose the target is simply a box with an OpenTypeKind,
 560 and the template is a type variable with LiftedTypeKind.
 561 Then it's ok (because the target type will later be refined).
 562 We simply don't bind the template type variable.
 563
 564 It might also be that the kind mis-match is an error. For example,
 565 suppose we match the template (a -> Int) against (Int# -> Int),
 566 where the template type variable 'a' has LiftedTypeKind.  This
 567 matching function does not fail; it simply doesn't bind the template.
 568 Later stuff will fail.
 569
 570 %************************************************************************
 571 %*                                                                      *
 572                 Subsumption checking
 573 %*                                                                      *
 574 %************************************************************************
 575
 576 All the tcSub calls have the form
 577
 578                 tcSub expected_ty offered_ty
 579 which checks
 580                 offered_ty <= expected_ty
 581
 582 That is, that a value of type offered_ty is acceptable in
 583 a place expecting a value of type expected_ty.
 584
 585 It returns a coercion function
 586         co_fn :: offered_ty -> expected_ty
 587 which takes an HsExpr of type offered_ty into one of type
 588 expected_ty.
 589
 590 \begin{code}
 591 -----------------
 592 tcSubExp :: BoxySigmaType -> BoxySigmaType -> TcM ExprCoFn      -- Locally used only
 593         -- (tcSub act exp) checks that
 594         --      act <= exp
 595 tcSubExp actual_ty expected_ty
 596   = addErrCtxtM (unifyCtxt actual_ty expected_ty)
 597                 (tc_sub True actual_ty actual_ty expected_ty expected_ty)
 598
 599 tcFunResTy :: Name -> BoxySigmaType -> BoxySigmaType -> TcM ExprCoFn    -- Locally used only
 600 tcFunResTy fun actual_ty expected_ty
 601   = addErrCtxtM (checkFunResCtxt fun actual_ty expected_ty) $
 602                 (tc_sub True actual_ty actual_ty expected_ty expected_ty)
 603
 604 -----------------
 605 tc_sub :: Outer                 -- See comments with uTys
 606        -> BoxySigmaType         -- actual_ty, before expanding synonyms
 607        -> BoxySigmaType         --              ..and after
 608        -> BoxySigmaType         -- expected_ty, before
 609        -> BoxySigmaType         --              ..and after
 610        -> TcM ExprCoFn
 611
 612 tc_sub outer act_sty act_ty exp_sty exp_ty
 613   | Just exp_ty' <- tcView exp_ty = tc_sub False act_sty act_ty exp_sty exp_ty'
 614 tc_sub outer act_sty act_ty exp_sty exp_ty
 615   | Just act_ty' <- tcView act_ty = tc_sub False act_sty act_ty' exp_sty exp_ty
 616
 617 -----------------------------------
 618 -- Rule SBOXY, plus other cases when act_ty is a type variable
 619 -- Just defer to boxy matching
 620 -- This rule takes precedence over SKOL!
 621 tc_sub outer act_sty (TyVarTy tv) exp_sty exp_ty
 622   = do  { uVar outer False tv False exp_sty exp_ty
 623         ; return idCoercion }
 624
 625 -----------------------------------
 626 -- Skolemisation case (rule SKOL)
 627 --      actual_ty:   d:Eq b => b->b
 628 --      expected_ty: forall a. Ord a => a->a
 629 --      co_fn e      /\a. \d2:Ord a. let d = eqFromOrd d2 in e
 630
 631 -- It is essential to do this *before* the specialisation case
 632 -- Example:  f :: (Eq a => a->a) -> ...
 633 --           g :: Ord b => b->b
 634 -- Consider  f g !
 635
 636 tc_sub outer act_sty act_ty exp_sty exp_ty
 637   | isSigmaTy exp_ty
 638   = do  { (gen_fn, co_fn) <- tcGen exp_ty act_tvs $ \ body_exp_ty ->
 639                              tc_sub False act_sty act_ty body_exp_ty body_exp_ty
 640         ; return (gen_fn <.> co_fn) }
 641   where
 642     act_tvs = tyVarsOfType act_ty
 643                 -- It's really important to check for escape wrt
 644                 -- the free vars of both expected_ty *and* actual_ty
 645
 646 -----------------------------------
 647 -- Specialisation case (rule ASPEC):
 648 --      actual_ty:   forall a. Ord a => a->a
 649 --      expected_ty: Int -> Int
 650 --      co_fn e =    e Int dOrdInt
 651
 652 tc_sub outer act_sty actual_ty exp_sty expected_ty
 653 -- Implements the new SPEC rule in the Appendix of the paper
 654 -- "Boxy types: inference for higher rank types and impredicativity"
 655 -- (This appendix isn't in the published version.)
 656 -- The idea is to *first* do pre-subsumption, and then full subsumption
 657 -- Example:     forall a. a->a  <=  Int -> (forall b. Int)
 658 --   Pre-subsumpion finds a|->Int, and that works fine, whereas
 659 --   just running full subsumption would fail.
 660   | isSigmaTy actual_ty
 661   = do  {       -- Perform pre-subsumption, and instantiate
 662                 -- the type with info from the pre-subsumption;
 663                 -- boxy tyvars if pre-subsumption gives no info
 664           let (tyvars, theta, tau) = tcSplitSigmaTy actual_ty
 665               tau_tvs = exactTyVarsOfType tau
 666         ; inst_tys <- preSubType tyvars tau_tvs tau expected_ty
 667         ; let subst' = zipOpenTvSubst tyvars inst_tys
 668               tau'   = substTy subst' tau
 669
 670                 -- Perform a full subsumption check
 671         ; co_fn <- tc_sub False tau' tau' exp_sty expected_ty
 672
 673                 -- Deal with the dictionaries
 674         ; dicts <- newDicts InstSigOrigin (substTheta subst' theta)
 675         ; extendLIEs dicts
 676         ; let inst_fn = CoApps (CoTyApps CoHole inst_tys)
 677                                (map instToId dicts)
 678         ; return (co_fn <.> inst_fn) }
 679
 680 -----------------------------------
 681 -- Function case (rule F1)
 682 tc_sub _ _ (FunTy act_arg act_res) _ (FunTy exp_arg exp_res)
 683   = tc_sub_funs act_arg act_res exp_arg exp_res
 684
 685 -- Function case (rule F2)
 686 tc_sub outer act_sty act_ty@(FunTy act_arg act_res) exp_sty (TyVarTy exp_tv)
 687   | isBoxyTyVar exp_tv
 688   = do  { cts <- readMetaTyVar exp_tv
 689         ; case cts of
 690             Indirect ty -> do { u_tys outer False act_sty act_ty True exp_sty ty
 691                               ; return idCoercion }
 692             Flexi       -> do { [arg_ty,res_ty] <- withMetaTvs exp_tv fun_kinds mk_res_ty
 693                               ; tc_sub_funs act_arg act_res arg_ty res_ty } }
 694  where
 695     mk_res_ty [arg_ty', res_ty'] = mkFunTy arg_ty' res_ty'
 696     mk_res_ty other = panic "TcUnify.mk_res_ty3"
 697     fun_kinds = [argTypeKind, openTypeKind]
 698
 699 -- Everything else: defer to boxy matching
 700 tc_sub outer act_sty actual_ty exp_sty expected_ty
 701   = do  { u_tys outer False act_sty actual_ty False exp_sty expected_ty
 702         ; return idCoercion }
 703
 704
 705 -----------------------------------
 706 tc_sub_funs act_arg act_res exp_arg exp_res
 707   = do  { uTys False act_arg False exp_arg
 708         ; co_fn_res <- tc_sub False act_res act_res exp_res exp_res
 709         ; wrapFunResCoercion [exp_arg] co_fn_res }
 710
 711 -----------------------------------
 712 wrapFunResCoercion
 713         :: [TcType]     -- Type of args
 714         -> ExprCoFn     -- HsExpr a -> HsExpr b
 715         -> TcM ExprCoFn -- HsExpr (arg_tys -> a) -> HsExpr (arg_tys -> b)
 716 wrapFunResCoercion arg_tys co_fn_res
 717   | isIdCoercion co_fn_res = return idCoercion
 718   | null arg_tys           = return co_fn_res
 719   | otherwise
 720   = do  { us <- newUniqueSupply
 721         ; let arg_ids = zipWith (mkSysLocal FSLIT("sub")) (uniqsFromSupply us) arg_tys
 722         ; return (CoLams arg_ids (co_fn_res <.> (CoApps CoHole arg_ids))) }
 723 \end{code}
 724
 725
 726
 727 %************************************************************************
 728 %*                                                                      *
 729 \subsection{Generalisation}
 730 %*                                                                      *
 731 %************************************************************************
 732
 733 \begin{code}
 734 tcGen :: BoxySigmaType                          -- expected_ty
 735       -> TcTyVarSet                             -- Extra tyvars that the universally
 736                                                 --      quantified tyvars of expected_ty
 737                                                 --      must not be unified
 738       -> (BoxyRhoType -> TcM result)            -- spec_ty
 739       -> TcM (ExprCoFn, result)
 740         -- The expression has type: spec_ty -> expected_ty
 741
 742 tcGen expected_ty extra_tvs thing_inside        -- We expect expected_ty to be a forall-type
 743                                                 -- If not, the call is a no-op
 744   = do  {       -- We want the GenSkol info in the skolemised type variables to
 745                 -- mention the *instantiated* tyvar names, so that we get a
 746                 -- good error message "Rigid variable 'a' is bound by (forall a. a->a)"
 747                 -- Hence the tiresome but innocuous fixM
 748           ((forall_tvs, theta, rho_ty), skol_info) <- fixM (\ ~(_, skol_info) ->
 749                 do { (forall_tvs, theta, rho_ty) <- tcInstSkolType skol_info expected_ty
 750                    ; span <- getSrcSpanM
 751                    ; let skol_info = GenSkol forall_tvs (mkPhiTy theta rho_ty) span
 752                    ; return ((forall_tvs, theta, rho_ty), skol_info) })
 753
 754 #ifdef DEBUG
 755         ; traceTc (text "tcGen" <+> vcat [text "extra_tvs" <+> ppr extra_tvs,
 756                                     text "expected_ty" <+> ppr expected_ty,
 757                                     text "inst ty" <+> ppr forall_tvs <+> ppr theta <+> ppr rho_ty,
 758                                     text "free_tvs" <+> ppr free_tvs,
 759                                     text "forall_tvs" <+> ppr forall_tvs])
 760 #endif
 761
 762         -- Type-check the arg and unify with poly type
 763         ; (result, lie) <- getLIE (thing_inside rho_ty)
 764
 765         -- Check that the "forall_tvs" havn't been constrained
 766         -- The interesting bit here is that we must include the free variables
 767         -- of the expected_ty.  Here's an example:
 768         --       runST (newVar True)
 769         -- Here, if we don't make a check, we'll get a type (ST s (MutVar s Bool))
 770         -- for (newVar True), with s fresh.  Then we unify with the runST's arg type
 771         -- forall s'. ST s' a. That unifies s' with s, and a with MutVar s Bool.
 772         -- So now s' isn't unconstrained because it's linked to a.
 773         -- Conclusion: include the free vars of the expected_ty in the
 774         -- list of "free vars" for the signature check.
 775
 776         ; dicts <- newDicts (SigOrigin skol_info) theta
 777         ; inst_binds <- tcSimplifyCheck sig_msg forall_tvs dicts lie
 778
 779         ; checkSigTyVarsWrt free_tvs forall_tvs
 780         ; traceTc (text "tcGen:done")
 781
 782         ; let
 783             -- This HsLet binds any Insts which came out of the simplification.
 784             -- It's a bit out of place here, but using AbsBind involves inventing
 785             -- a couple of new names which seems worse.
 786                 dict_ids   = map instToId dicts
 787                 co_fn = CoTyLams forall_tvs $ CoLams dict_ids $ CoLet inst_binds CoHole
 788         ; returnM (co_fn, result) }
 789   where
 790     free_tvs = tyVarsOfType expected_ty `unionVarSet` extra_tvs
 791     sig_msg  = ptext SLIT("expected type of an expression")
 792 \end{code}
 793
 794
 795
 796 %************************************************************************
 797 %*                                                                      *
 798                 Boxy unification
 799 %*                                                                      *
 800 %************************************************************************
 801
 802 The exported functions are all defined as versions of some
 803 non-exported generic functions.
 804
 805 \begin{code}
 806 boxyUnify :: BoxyType -> BoxyType -> TcM ()
 807 -- Acutal and expected, respectively
 808 boxyUnify ty1 ty2
 809   = addErrCtxtM (unifyCtxt ty1 ty2) $
 810     uTysOuter False ty1 False ty2
 811
 812 ---------------
 813 boxyUnifyList :: [BoxyType] -> [BoxyType] -> TcM ()
 814 -- Arguments should have equal length
 815 -- Acutal and expected types
 816 boxyUnifyList tys1 tys2 = uList boxyUnify tys1 tys2
 817
 818 ---------------
 819 unifyType :: TcTauType -> TcTauType -> TcM ()
 820 -- No boxes expected inside these types
 821 -- Acutal and expected types
 822 unifyType ty1 ty2       -- ty1 expected, ty2 inferred
 823   = ASSERT2( not (isBoxyTy ty1), ppr ty1 )
 824     ASSERT2( not (isBoxyTy ty2), ppr ty2 )
 825     addErrCtxtM (unifyCtxt ty1 ty2) $
 826     uTysOuter True ty1 True ty2
 827
 828 ---------------
 829 unifyPred :: PredType -> PredType -> TcM ()
 830 -- Acutal and expected types
 831 unifyPred p1 p2 = addErrCtxtM (unifyCtxt (mkPredTy p1) (mkPredTy p2)) $
 832                   uPred True True p1 True p2
 833
 834 unifyTheta :: TcThetaType -> TcThetaType -> TcM ()
 835 -- Acutal and expected types
 836 unifyTheta theta1 theta2
 837   = do  { checkTc (equalLength theta1 theta2)
 838                   (ptext SLIT("Contexts differ in length"))
 839         ; uList unifyPred theta1 theta2 }
 840
 841 ---------------
 842 uList :: (a -> a -> TcM ())
 843        -> [a] -> [a] -> TcM ()
 844 -- Unify corresponding elements of two lists of types, which
 845 -- should be f equal length.  We charge down the list explicitly so that
 846 -- we can complain if their lengths differ.
 847 uList unify []         []         = return ()
 848 uList unify (ty1:tys1) (ty2:tys2) = do { unify ty1 ty2; uList unify tys1 tys2 }
 849 uList unify ty1s ty2s = panic "Unify.uList: mismatched type lists!"
 850 \end{code}
 851
 852 @unifyTypeList@ takes a single list of @TauType@s and unifies them
 853 all together.  It is used, for example, when typechecking explicit
 854 lists, when all the elts should be of the same type.
 855
 856 \begin{code}
 857 unifyTypeList :: [TcTauType] -> TcM ()
 858 unifyTypeList []                 = returnM ()
 859 unifyTypeList [ty]               = returnM ()
 860 unifyTypeList (ty1:tys@(ty2:_)) = do { unifyType ty1 ty2
 861                                       ; unifyTypeList tys }
 862 \end{code}
 863
 864 %************************************************************************
 865 %*                                                                      *
 866 \subsection[Unify-uTys]{@uTys@: getting down to business}
 867 %*                                                                      *
 868 %************************************************************************
 869
 870 @uTys@ is the heart of the unifier.  Each arg happens twice, because
 871 we want to report errors in terms of synomyms if poss.  The first of
 872 the pair is used in error messages only; it is always the same as the
 873 second, except that if the first is a synonym then the second may be a
 874 de-synonym'd version.  This way we get better error messages.
 875
 876 We call the first one \tr{ps_ty1}, \tr{ps_ty2} for ``possible synomym''.
 877
 878 \begin{code}
 879 type NoBoxes = Bool     -- True  <=> definitely no boxes in this type
 880                         -- False <=> there might be boxes (always safe)
 881
 882 type Outer = Bool       -- True <=> this is the outer level of a unification
 883                         --          so that the types being unified are the
 884                         --          very ones we began with, not some sub
 885                         --          component or synonym expansion
 886 -- The idea is that if Outer is true then unifyMisMatch should
 887 -- pop the context to remove the "Expected/Acutal" context
 888
 889 uTysOuter, uTys
 890      :: NoBoxes -> TcType       -- ty1 is the *expected* type
 891      -> NoBoxes -> TcType       -- ty2 is the *actual* type
 892      -> TcM ()
 893 uTysOuter nb1 ty1 nb2 ty2 = u_tys True nb1 ty1 ty1 nb2 ty2 ty2
 894 uTys      nb1 ty1 nb2 ty2 = u_tys False nb1 ty1 ty1 nb2 ty2 ty2
 895
 896
 897 --------------
 898 uTys_s :: NoBoxes -> [TcType]   -- ty1 is the *actual* types
 899        -> NoBoxes -> [TcType]   -- ty2 is the *expected* types
 900        -> TcM ()
 901 uTys_s nb1 []           nb2 []         = returnM ()
 902 uTys_s nb1 (ty1:tys1) nb2 (ty2:tys2) = do { uTys nb1 ty1 nb2 ty2
 903                                           ; uTys_s nb1 tys1 nb2 tys2 }
 904 uTys_s nb1 ty1s nb2 ty2s = panic "Unify.uTys_s: mismatched type lists!"
 905
 906 --------------
 907 u_tys :: Outer
 908       -> NoBoxes -> TcType -> TcType    -- ty1 is the *actual* type
 909       -> NoBoxes -> TcType -> TcType    -- ty2 is the *expected* type
 910       -> TcM ()
 911
 912 u_tys outer nb1 orig_ty1 ty1 nb2 orig_ty2 ty2
 913   = go outer ty1 ty2
 914   where
 915
 916         -- Always expand synonyms (see notes at end)
 917         -- (this also throws away FTVs)
 918     go outer ty1 ty2
 919       | Just ty1' <- tcView ty1 = go False ty1' ty2
 920       | Just ty2' <- tcView ty2 = go False ty1 ty2'
 921
 922         -- Variables; go for uVar
 923     go outer (TyVarTy tyvar1) ty2 = uVar outer False tyvar1 nb2 orig_ty2 ty2
 924     go outer ty1 (TyVarTy tyvar2) = uVar outer True  tyvar2 nb1 orig_ty1 ty1
 925                                 -- "True" means args swapped
 926         -- Predicates
 927     go outer (PredTy p1) (PredTy p2) = uPred outer nb1 p1 nb2 p2
 928
 929         -- Type constructors must match
 930     go _ (TyConApp con1 tys1) (TyConApp con2 tys2)
 931       | con1 == con2 = uTys_s nb1 tys1 nb2 tys2
 932         -- See Note [TyCon app]
 933
 934         -- Functions; just check the two parts
 935     go _ (FunTy fun1 arg1) (FunTy fun2 arg2)
 936       = do { uTys nb1 fun1 nb2 fun2
 937            ; uTys nb1 arg1 nb2 arg2 }
 938
 939         -- Applications need a bit of care!
 940         -- They can match FunTy and TyConApp, so use splitAppTy_maybe
 941         -- NB: we've already dealt with type variables and Notes,
 942         -- so if one type is an App the other one jolly well better be too
 943     go outer (AppTy s1 t1) ty2
 944       | Just (s2,t2) <- tcSplitAppTy_maybe ty2
 945       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 946
 947         -- Now the same, but the other way round
 948         -- Don't swap the types, because the error messages get worse
 949     go outer ty1 (AppTy s2 t2)
 950       | Just (s1,t1) <- tcSplitAppTy_maybe ty1
 951       = do { uTys nb1 s1 nb2 s2; uTys nb1 t1 nb2 t2 }
 952
 953     go _ ty1@(ForAllTy _ _) ty2@(ForAllTy _ _)
 954       | length tvs1 == length tvs2
 955       = do   { tvs <- tcInstSkolTyVars UnkSkol tvs1     -- Not a helpful SkolemInfo
 956              ; let tys      = mkTyVarTys tvs
 957                    in_scope = mkInScopeSet (mkVarSet tvs)
 958                    subst1   = mkTvSubst in_scope (zipTyEnv tvs1 tys)
 959                    subst2   = mkTvSubst in_scope (zipTyEnv tvs2 tys)
 960              ; uTys nb1 (substTy subst1 body1) nb2 (substTy subst2 body2)
 961
 962                 -- If both sides are inside a box, we should not have
 963                 -- a polytype at all.  This check comes last, because
 964                 -- the error message is extremely unhelpful.
 965              ; ifM (nb1 && nb2) (notMonoType ty1)
 966              }
 967       where
 968         (tvs1, body1) = tcSplitForAllTys ty1
 969         (tvs2, body2) = tcSplitForAllTys ty2
 970
 971         -- Anything else fails
 972     go outer _ _ = unifyMisMatch outer False orig_ty1 orig_ty2
 973
 974 ----------
 975 uPred outer nb1 (IParam n1 t1) nb2 (IParam n2 t2)
 976   | n1 == n2 = uTys nb1 t1 nb2 t2
 977 uPred outer nb1 (ClassP c1 tys1) nb2 (ClassP c2 tys2)
 978   | c1 == c2 = uTys_s nb1 tys1 nb2 tys2         -- Guaranteed equal lengths because the kinds check
 979 uPred outer _ p1 _ p2 = unifyMisMatch outer False (mkPredTy p1) (mkPredTy p2)
 980 \end{code}
 981
 982 Note [Tycon app]
 983 ~~~~~~~~~~~~~~~~
 984 When we find two TyConApps, the argument lists are guaranteed equal
 985 length.  Reason: intially the kinds of the two types to be unified is
 986 the same. The only way it can become not the same is when unifying two
 987 AppTys (f1 a1):=:(f2 a2).  In that case there can't be a TyConApp in
 988 the f1,f2 (because it'd absorb the app).  If we unify f1:=:f2 first,
 989 which we do, that ensures that f1,f2 have the same kind; and that
 990 means a1,a2 have the same kind.  And now the argument repeats.
 991
 992
 993 Notes on synonyms
 994 ~~~~~~~~~~~~~~~~~
 995 If you are tempted to make a short cut on synonyms, as in this
 996 pseudocode...
 997
 998 \begin{verbatim}
 999 -- NO   uTys (SynTy con1 args1 ty1) (SynTy con2 args2 ty2)
1000 -- NO     = if (con1 == con2) then
1001 -- NO   -- Good news!  Same synonym constructors, so we can shortcut
1002 -- NO   -- by unifying their arguments and ignoring their expansions.
1003 -- NO   unifyTypepeLists args1 args2
1004 -- NO    else
1005 -- NO   -- Never mind.  Just expand them and try again
1006 -- NO   uTys ty1 ty2
1007 \end{verbatim}
1008
1009 then THINK AGAIN.  Here is the whole story, as detected and reported
1010 by Chris Okasaki \tr{<Chris_Okasaki@loch.mess.cs.cmu.edu>}:
1011 \begin{quotation}
1012 Here's a test program that should detect the problem:
1013
1014 \begin{verbatim}
1015         type Bogus a = Int
1016         x = (1 :: Bogus Char) :: Bogus Bool
1017 \end{verbatim}
1018
1019 The problem with [the attempted shortcut code] is that
1020 \begin{verbatim}
1021         con1 == con2
1022 \end{verbatim}
1023 is not a sufficient condition to be able to use the shortcut!
1024 You also need to know that the type synonym actually USES all
1025 its arguments.  For example, consider the following type synonym
1026 which does not use all its arguments.
1027 \begin{verbatim}
1028         type Bogus a = Int
1029 \end{verbatim}
1030
1031 If you ever tried unifying, say, \tr{Bogus Char} with \tr{Bogus Bool},
1032 the unifier would blithely try to unify \tr{Char} with \tr{Bool} and
1033 would fail, even though the expanded forms (both \tr{Int}) should
1034 match.
1035
1036 Similarly, unifying \tr{Bogus Char} with \tr{Bogus t} would
1037 unnecessarily bind \tr{t} to \tr{Char}.
1038
1039 ... You could explicitly test for the problem synonyms and mark them
1040 somehow as needing expansion, perhaps also issuing a warning to the
1041 user.
1042 \end{quotation}
1043
1044
1045 %************************************************************************
1046 %*                                                                      *
1047 \subsection[Unify-uVar]{@uVar@: unifying with a type variable}
1048 %*                                                                      *
1049 %************************************************************************
1050
1051 @uVar@ is called when at least one of the types being unified is a
1052 variable.  It does {\em not} assume that the variable is a fixed point
1053 of the substitution; rather, notice that @uVar@ (defined below) nips
1054 back into @uTys@ if it turns out that the variable is already bound.
1055
1056 \begin{code}
1057 uVar :: Outer
1058      -> Bool            -- False => tyvar is the "expected"
1059                         -- True  => ty    is the "expected" thing
1060      -> TcTyVar
1061      -> NoBoxes         -- True <=> definitely no boxes in t2
1062      -> TcTauType -> TcTauType  -- printing and real versions
1063      -> TcM ()
1064
1065 uVar outer swapped tv1 nb2 ps_ty2 ty2
1066   = do  { let expansion | showSDoc (ppr ty2) == showSDoc (ppr ps_ty2) = empty
1067                         | otherwise = brackets (equals <+> ppr ty2)
1068         ; traceTc (text "uVar" <+> ppr swapped <+>
1069                         sep [ppr tv1 <+> dcolon <+> ppr (tyVarKind tv1 ),
1070                                 nest 2 (ptext SLIT(" :=: ")),
1071                              ppr ps_ty2 <+> dcolon <+> ppr (typeKind ty2) <+> expansion])
1072         ; details <- lookupTcTyVar tv1
1073         ; case details of
1074             IndirectTv ty1
1075                 | swapped   -> u_tys outer nb2  ps_ty2 ty2 True ty1    ty1      -- Swap back
1076                 | otherwise -> u_tys outer True ty1    ty1 nb2  ps_ty2 ty2      -- Same order
1077                         -- The 'True' here says that ty1
1078                         -- is definitely box-free
1079             DoneTv details1 -> uUnfilledVar outer swapped tv1 details1 nb2 ps_ty2 ty2
1080         }
1081
1082 ----------------
1083 uUnfilledVar :: Outer
1084              -> Bool                            -- Args are swapped
1085              -> TcTyVar -> TcTyVarDetails               -- Tyvar 1
1086              -> NoBoxes -> TcTauType -> TcTauType       -- Type 2
1087              -> TcM ()
1088 -- Invariant: tyvar 1 is not unified with anything
1089
1090 uUnfilledVar outer swapped tv1 details1 nb2 ps_ty2 ty2
1091   | Just ty2' <- tcView ty2
1092   =     -- Expand synonyms; ignore FTVs
1093     uUnfilledVar False swapped tv1 details1 nb2 ps_ty2 ty2'
1094
1095 uUnfilledVar outer swapped tv1 details1 nb2 ps_ty2 (TyVarTy tv2)
1096   | tv1 == tv2  -- Same type variable => no-op (but watch out for the boxy case)
1097   = case details1 of
1098         MetaTv BoxTv ref1  -- A boxy type variable meets itself;
1099                            -- this is box-meets-box, so fill in with a tau-type
1100               -> do { tau_tv <- tcInstTyVar tv1
1101                     ; updateMeta tv1 ref1 (mkTyVarTy tau_tv) }
1102         other -> returnM ()     -- No-op
1103
1104         -- Distinct type variables
1105   | otherwise
1106   = do  { lookup2 <- lookupTcTyVar tv2
1107         ; case lookup2 of
1108             IndirectTv ty2' -> uUnfilledVar  outer swapped tv1 details1 True ty2' ty2'
1109             DoneTv details2 -> uUnfilledVars outer swapped tv1 details1 tv2 details2
1110         }
1111
1112 uUnfilledVar outer swapped tv1 details1 nb2 ps_ty2 non_var_ty2  -- ty2 is not a type variable
1113   = case details1 of
1114         MetaTv (SigTv _) ref1 -> mis_match      -- Can't update a skolem with a non-type-variable
1115         MetaTv info ref1      -> uMetaVar swapped tv1 info ref1 nb2 ps_ty2 non_var_ty2
1116         skolem_details        -> mis_match
1117   where
1118     mis_match = unifyMisMatch outer swapped (TyVarTy tv1) ps_ty2
1119
1120 ----------------
1121 uMetaVar :: Bool
1122          -> TcTyVar -> BoxInfo -> IORef MetaDetails
1123          -> NoBoxes -> TcType -> TcType
1124          -> TcM ()
1125 -- tv1 is an un-filled-in meta type variable (maybe boxy, maybe tau)
1126 -- ty2 is not a type variable
1127
1128 uMetaVar swapped tv1 BoxTv ref1 nb2 ps_ty2 non_var_ty2
1129   =     -- tv1 is a BoxTv.  So we must unbox ty2, to ensure
1130         -- that any boxes in ty2 are filled with monotypes
1131         --
1132         -- It should not be the case that tv1 occurs in ty2
1133         -- (i.e. no occurs check should be needed), but if perchance
1134         -- it does, the unbox operation will fill it, and the DEBUG
1135         -- checks for that.
1136     do  { final_ty <- unBox ps_ty2
1137 #ifdef DEBUG
1138         ; meta_details <- readMutVar ref1
1139         ; case meta_details of
1140             Indirect ty -> WARN( True, ppr tv1 <+> ppr ty )
1141                            return ()    -- This really should *not* happen
1142             Flexi       -> return ()
1143 #endif
1144         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1145
1146 uMetaVar swapped tv1 info1 ref1 nb2 ps_ty2 non_var_ty2
1147   = do  { final_ty <- checkTauTvUpdate tv1 ps_ty2       -- Occurs check + monotype check
1148         ; checkUpdateMeta swapped tv1 ref1 final_ty }
1149
1150 ----------------
1151 uUnfilledVars :: Outer
1152               -> Bool                   -- Args are swapped
1153               -> TcTyVar -> TcTyVarDetails      -- Tyvar 1
1154               -> TcTyVar -> TcTyVarDetails      -- Tyvar 2
1155               -> TcM ()
1156 -- Invarant: The type variables are distinct,
1157 --           Neither is filled in yet
1158 --           They might be boxy or not
1159
1160 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (SkolemTv _)
1161   = unifyMisMatch outer swapped (mkTyVarTy tv1) (mkTyVarTy tv2)
1162
1163 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (SkolemTv _)
1164   = checkUpdateMeta swapped tv1 ref1 (mkTyVarTy tv2)
1165 uUnfilledVars outer swapped tv1 (SkolemTv _) tv2 (MetaTv info2 ref2)
1166   = checkUpdateMeta (not swapped) tv2 ref2 (mkTyVarTy tv1)
1167
1168 -- ToDo: this function seems too long for what it acutally does!
1169 uUnfilledVars outer swapped tv1 (MetaTv info1 ref1) tv2 (MetaTv info2 ref2)
1170   = case (info1, info2) of
1171         (BoxTv,   BoxTv)   -> box_meets_box
1172
1173         -- If a box meets a TauTv, but the fomer has the smaller kind
1174         -- then we must create a fresh TauTv with the smaller kind
1175         (_,       BoxTv)   | k1_sub_k2 -> update_tv2
1176                            | otherwise -> box_meets_box
1177         (BoxTv,   _    )   | k2_sub_k1 -> update_tv1
1178                            | otherwise -> box_meets_box
1179
1180         -- Avoid SigTvs if poss
1181         (SigTv _, _      ) | k1_sub_k2 -> update_tv2
1182         (_,       SigTv _) | k2_sub_k1 -> update_tv1
1183
1184         (_,   _) | k1_sub_k2 -> if k2_sub_k1 && nicer_to_update_tv1
1185                                 then update_tv1         -- Same kinds
1186                                 else update_tv2
1187                  | k2_sub_k1 -> update_tv1
1188                  | otherwise -> kind_err
1189
1190         -- Update the variable with least kind info
1191         -- See notes on type inference in Kind.lhs
1192         -- The "nicer to" part only applies if the two kinds are the same,
1193         -- so we can choose which to do.
1194   where
1195         -- Kinds should be guaranteed ok at this point
1196     update_tv1 = updateMeta tv1 ref1 (mkTyVarTy tv2)
1197     update_tv2 = updateMeta tv2 ref2 (mkTyVarTy tv1)
1198
1199     box_meets_box | k1_sub_k2 = if k2_sub_k1 && nicer_to_update_tv1
1200                                 then fill_from tv2
1201                                 else fill_from tv1
1202                   | k2_sub_k1 = fill_from tv2
1203                   | otherwise = kind_err
1204
1205         -- Update *both* tyvars with a TauTv whose name and kind
1206         -- are gotten from tv (avoid losing nice names is poss)
1207     fill_from tv = do { tv' <- tcInstTyVar tv
1208                       ; let tau_ty = mkTyVarTy tv'
1209                       ; updateMeta tv1 ref1 tau_ty
1210                       ; updateMeta tv2 ref2 tau_ty }
1211
1212     kind_err = addErrCtxtM (unifyKindCtxt swapped tv1 (mkTyVarTy tv2))  $
1213                unifyKindMisMatch k1 k2
1214
1215     k1 = tyVarKind tv1
1216     k2 = tyVarKind tv2
1217     k1_sub_k2 = k1 `isSubKind` k2
1218     k2_sub_k1 = k2 `isSubKind` k1
1219
1220     nicer_to_update_tv1 = isSystemName (varName tv1)
1221         -- Try to update sys-y type variables in preference to ones
1222         -- gotten (say) by instantiating a polymorphic function with
1223         -- a user-written type sig
1224
1225 ----------------
1226 checkUpdateMeta :: Bool -> TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1227 -- Update tv1, which is flexi; occurs check is alrady done
1228 -- The 'check' version does a kind check too
1229 -- We do a sub-kind check here: we might unify (a b) with (c d)
1230 --      where b::*->* and d::*; this should fail
1231
1232 checkUpdateMeta swapped tv1 ref1 ty2
1233   = do  { checkKinds swapped tv1 ty2
1234         ; updateMeta tv1 ref1 ty2 }
1235
1236 updateMeta :: TcTyVar -> IORef MetaDetails -> TcType -> TcM ()
1237 updateMeta tv1 ref1 ty2
1238   = ASSERT( isMetaTyVar tv1 )
1239     ASSERT( isBoxyTyVar tv1 || isTauTy ty2 )
1240     do  { ASSERTM2( do { details <- readMetaTyVar tv1; return (isFlexi details) }, ppr tv1 )
1241         ; traceTc (text "updateMeta" <+> ppr tv1 <+> text ":=" <+> ppr ty2)
1242         ; writeMutVar ref1 (Indirect ty2) }
1243
1244 ----------------
1245 checkKinds swapped tv1 ty2
1246 -- We're about to unify a type variable tv1 with a non-tyvar-type ty2.
1247 -- ty2 has been zonked at this stage, which ensures that
1248 -- its kind has as much boxity information visible as possible.
1249   | tk2 `isSubKind` tk1 = returnM ()
1250
1251   | otherwise
1252         -- Either the kinds aren't compatible
1253         --      (can happen if we unify (a b) with (c d))
1254         -- or we are unifying a lifted type variable with an
1255         --      unlifted type: e.g.  (id 3#) is illegal
1256   = addErrCtxtM (unifyKindCtxt swapped tv1 ty2) $
1257     unifyKindMisMatch k1 k2
1258   where
1259     (k1,k2) | swapped   = (tk2,tk1)
1260             | otherwise = (tk1,tk2)
1261     tk1 = tyVarKind tv1
1262     tk2 = typeKind ty2
1263
1264 ----------------
1265 checkTauTvUpdate :: TcTyVar -> TcType -> TcM TcType
1266 --    (checkTauTvUpdate tv ty)
1267 -- We are about to update the TauTv tv with ty.
1268 -- Check (a) that tv doesn't occur in ty (occurs check)
1269 --       (b) that ty is a monotype
1270 -- Furthermore, in the interest of (b), if you find an
1271 -- empty box (BoxTv that is Flexi), fill it in with a TauTv
1272 --
1273 -- Returns the (non-boxy) type to update the type variable with, or fails
1274
1275 checkTauTvUpdate orig_tv orig_ty
1276   = go orig_ty
1277   where
1278     go (TyConApp tc tys)
1279         | isSynTyCon tc  = go_syn tc tys
1280         | otherwise      = do { tys' <- mappM go tys; return (TyConApp tc tys') }
1281     go (NoteTy _ ty2)    = go ty2       -- Discard free-tyvar annotations
1282     go (PredTy p)        = do { p' <- go_pred p; return (PredTy p') }
1283     go (FunTy arg res)   = do { arg' <- go arg; res' <- go res; return (FunTy arg' res') }
1284     go (AppTy fun arg)   = do { fun' <- go fun; arg' <- go arg; return (mkAppTy fun' arg') }
1285                 -- NB the mkAppTy; we might have instantiated a
1286                 -- type variable to a type constructor, so we need
1287                 -- to pull the TyConApp to the top.
1288     go (ForAllTy tv ty) = notMonoType orig_ty           -- (b)
1289
1290     go (TyVarTy tv)
1291         | orig_tv == tv = occurCheck tv orig_ty         -- (a)
1292         | isTcTyVar tv  = go_tyvar tv (tcTyVarDetails tv)
1293         | otherwise     = return (TyVarTy tv)
1294                  -- Ordinary (non Tc) tyvars
1295                  -- occur inside quantified types
1296
1297     go_pred (ClassP c tys) = do { tys' <- mapM go tys; return (ClassP c tys') }
1298     go_pred (IParam n ty)  = do { ty' <- go ty;        return (IParam n ty') }
1299
1300     go_tyvar tv (SkolemTv _) = return (TyVarTy tv)
1301     go_tyvar tv (MetaTv box ref)
1302         = do { cts <- readMutVar ref
1303              ; case cts of
1304                   Indirect ty -> go ty
1305                   Flexi -> case box of
1306                                 BoxTv -> fillBoxWithTau tv ref
1307                                 other -> return (TyVarTy tv)
1308              }
1309
1310         -- go_syn is called for synonyms only
1311         -- See Note [Type synonyms and the occur check]
1312     go_syn tc tys
1313         | not (isTauTyCon tc)
1314         = notMonoType orig_ty   -- (b) again
1315         | otherwise
1316         = do { (msgs, mb_tys') <- tryTc (mapM go tys)
1317              ; case mb_tys' of
1318                 Just tys' -> return (TyConApp tc tys')
1319                                 -- Retain the synonym (the common case)
1320                 Nothing   -> go (expectJust "checkTauTvUpdate"
1321                                         (tcView (TyConApp tc tys)))
1322                                 -- Try again, expanding the synonym
1323              }
1324
1325 fillBoxWithTau :: BoxyTyVar -> IORef MetaDetails -> TcM TcType
1326 -- (fillBoxWithTau tv ref) fills ref with a freshly allocated
1327 --  tau-type meta-variable, whose print-name is the same as tv
1328 -- Choosing the same name is good: when we instantiate a function
1329 -- we allocate boxy tyvars with the same print-name as the quantified
1330 -- tyvar; and then we often fill the box with a tau-tyvar, and again
1331 -- we want to choose the same name.
1332 fillBoxWithTau tv ref
1333   = do  { tv' <- tcInstTyVar tv         -- Do not gratuitously forget
1334         ; let tau = mkTyVarTy tv'       -- name of the type variable
1335         ; writeMutVar ref (Indirect tau)
1336         ; return tau }
1337 \end{code}
1338
1339 Note [Type synonyms and the occur check]
1340 ~~~~~~~~~~~~~~~~~~~~
1341 Basically we want to update     tv1 := ps_ty2
1342 because ps_ty2 has type-synonym info, which improves later error messages
1343
1344 But consider
1345         type A a = ()
1346
1347         f :: (A a -> a -> ()) -> ()
1348         f = \ _ -> ()
1349
1350         x :: ()
1351         x = f (\ x p -> p x)
1352
1353 In the application (p x), we try to match "t" with "A t".  If we go
1354 ahead and bind t to A t (= ps_ty2), we'll lead the type checker into
1355 an infinite loop later.
1356 But we should not reject the program, because A t = ().
1357 Rather, we should bind t to () (= non_var_ty2).
1358
1359 \begin{code}
1360 stripBoxyType :: BoxyType -> TcM TcType
1361 -- Strip all boxes from the input type, returning a non-boxy type.
1362 -- It's fine for there to be a polytype inside a box (c.f. unBox)
1363 -- All of the boxes should have been filled in by now;
1364 -- hence we return a TcType
1365 stripBoxyType ty = zonkType strip_tv ty
1366   where
1367     strip_tv tv = ASSERT( not (isBoxyTyVar tv) ) return (TyVarTy tv)
1368         -- strip_tv will be called for *Flexi* meta-tyvars
1369         -- There should not be any Boxy ones; hence the ASSERT
1370
1371 zapToMonotype :: BoxySigmaType -> TcM TcTauType
1372 -- Subtle... we must zap the boxy res_ty
1373 -- to kind * before using it to instantiate a LitInst
1374 -- Calling unBox instead doesn't do the job, because the box
1375 -- often has an openTypeKind, and we don't want to instantiate
1376 -- with that type.
1377 zapToMonotype res_ty
1378   = do  { res_tau <- newFlexiTyVarTy liftedTypeKind
1379         ; boxyUnify res_tau res_ty
1380         ; return res_tau }
1381
1382 unBox :: BoxyType -> TcM TcType
1383 -- unBox implements the judgement
1384 --      |- s' ~ box(s)
1385 -- with input s', and result s
1386 --
1387 -- It removes all boxes from the input type, returning a non-boxy type.
1388 -- A filled box in the type can only contain a monotype; unBox fails if not
1389 -- The type can have empty boxes, which unBox fills with a monotype
1390 --
1391 -- Compare this wth checkTauTvUpdate
1392 --
1393 -- For once, it's safe to treat synonyms as opaque!
1394
1395 unBox (NoteTy n ty)     = do { ty' <- unBox ty; return (NoteTy n ty') }
1396 unBox (TyConApp tc tys) = do { tys' <- mapM unBox tys; return (TyConApp tc tys') }
1397 unBox (AppTy f a)       = do { f' <- unBox f; a' <- unBox a; return (mkAppTy f' a') }
1398 unBox (FunTy f a)       = do { f' <- unBox f; a' <- unBox a; return (FunTy f' a') }
1399 unBox (PredTy p)        = do { p' <- unBoxPred p; return (PredTy p') }
1400 unBox (ForAllTy tv ty)  = ASSERT( isImmutableTyVar tv )
1401                           do { ty' <- unBox ty; return (ForAllTy tv ty') }
1402 unBox (TyVarTy tv)
1403   | isTcTyVar tv                                -- It's a boxy type variable
1404   , MetaTv BoxTv ref <- tcTyVarDetails tv       -- NB: non-TcTyVars are possible
1405   = do  { cts <- readMutVar ref                 --     under nested quantifiers
1406         ; case cts of
1407             Flexi       -> fillBoxWithTau tv ref
1408             Indirect ty -> do { non_boxy_ty <- unBox ty
1409                               ; if isTauTy non_boxy_ty
1410                                 then return non_boxy_ty
1411                                 else notMonoType non_boxy_ty }
1412         }
1413   | otherwise   -- Skolems, and meta-tau-variables
1414   = return (TyVarTy tv)
1415
1416 unBoxPred (ClassP cls tys) = do { tys' <- mapM unBox tys; return (ClassP cls tys') }
1417 unBoxPred (IParam ip ty)   = do { ty' <- unBox ty; return (IParam ip ty') }
1418 \end{code}
1419
1420
1421
1422 %************************************************************************
1423 %*                                                                      *
1424 \subsection[Unify-context]{Errors and contexts}
1425 %*                                                                      *
1426 %************************************************************************
1427
1428 Errors
1429 ~~~~~~
1430
1431 \begin{code}
1432 unifyCtxt act_ty exp_ty tidy_env
1433   = do  { act_ty' <- zonkTcType act_ty
1434         ; exp_ty' <- zonkTcType exp_ty
1435         ; let (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1436               (env2, act_ty'') = tidyOpenType env1     act_ty'
1437         ; return (env2, mkExpectedActualMsg act_ty'' exp_ty'') }
1438
1439 ----------------
1440 mkExpectedActualMsg act_ty exp_ty
1441   = nest 2 (vcat [ text "Expected type" <> colon <+> ppr exp_ty,
1442                    text "Inferred type" <> colon <+> ppr act_ty ])
1443
1444 ----------------
1445 -- If an error happens we try to figure out whether the function
1446 -- function has been given too many or too few arguments, and say so.
1447 checkFunResCtxt fun actual_res_ty expected_res_ty tidy_env
1448   = do  { exp_ty' <- zonkTcType expected_res_ty
1449         ; act_ty' <- zonkTcType actual_res_ty
1450         ; let
1451               (env1, exp_ty'') = tidyOpenType tidy_env exp_ty'
1452               (env2, act_ty'') = tidyOpenType env1     act_ty'
1453               (exp_args, _)    = tcSplitFunTys exp_ty''
1454               (act_args, _)    = tcSplitFunTys act_ty''
1455
1456               len_act_args     = length act_args
1457               len_exp_args     = length exp_args
1458
1459               message | len_exp_args < len_act_args = wrongArgsCtxt "too few"  fun
1460                       | len_exp_args > len_act_args = wrongArgsCtxt "too many" fun
1461                       | otherwise                   = mkExpectedActualMsg act_ty'' exp_ty''
1462         ; return (env2, message) }
1463
1464   where
1465     wrongArgsCtxt too_many_or_few fun
1466       = ptext SLIT("Probable cause:") <+> quotes (ppr fun)
1467         <+> ptext SLIT("is applied to") <+> text too_many_or_few
1468         <+> ptext SLIT("arguments")
1469
1470 ------------------
1471 unifyKindCtxt swapped tv1 ty2 tidy_env  -- not swapped => tv1 expected, ty2 inferred
1472         -- tv1 and ty2 are zonked already
1473   = returnM msg
1474   where
1475     msg = (env2, ptext SLIT("When matching the kinds of") <+>
1476                  sep [quotes pp_expected <+> ptext SLIT("and"), quotes pp_actual])
1477
1478     (pp_expected, pp_actual) | swapped   = (pp2, pp1)
1479                              | otherwise = (pp1, pp2)
1480     (env1, tv1') = tidyOpenTyVar tidy_env tv1
1481     (env2, ty2') = tidyOpenType  env1 ty2
1482     pp1 = ppr tv1' <+> dcolon <+> ppr (tyVarKind tv1)
1483     pp2 = ppr ty2' <+> dcolon <+> ppr (typeKind ty2)
1484
1485 unifyMisMatch outer swapped ty1 ty2
1486   = do  { (env, msg) <- if swapped then misMatchMsg ty1 ty2
1487                                    else misMatchMsg ty2 ty1
1488
1489         -- This is the whole point of the 'outer' stuff
1490         ; if outer then popErrCtxt (failWithTcM (env, msg))
1491                    else failWithTcM (env, msg)
1492         }
1493
1494 misMatchMsg ty1 ty2
1495   = do  { env0 <- tcInitTidyEnv
1496         ; (env1, pp1, extra1) <- ppr_ty env0 ty1
1497         ; (env2, pp2, extra2) <- ppr_ty env1 ty2
1498         ; return (env2, sep [sep [ptext SLIT("Couldn't match expected type") <+> pp1,
1499                                   nest 7 (ptext SLIT("against inferred type") <+> pp2)],
1500                              nest 2 extra1, nest 2 extra2]) }
1501
1502 ppr_ty :: TidyEnv -> TcType -> TcM (TidyEnv, SDoc, SDoc)
1503 ppr_ty env ty
1504   = do { ty' <- zonkTcType ty
1505        ; let (env1,tidy_ty) = tidyOpenType env ty'
1506              simple_result  = (env1, quotes (ppr tidy_ty), empty)
1507        ; case tidy_ty of
1508            TyVarTy tv
1509                 | isSkolemTyVar tv || isSigTyVar tv
1510                 -> return (env2, pp_rigid tv', pprSkolTvBinding tv')
1511                 | otherwise -> return simple_result
1512                 where
1513                   (env2, tv') = tidySkolemTyVar env1 tv
1514            other -> return simple_result }
1515   where
1516     pp_rigid tv = quotes (ppr tv) <+> parens (ptext SLIT("a rigid variable"))
1517
1518
1519 notMonoType ty
1520   = do  { ty' <- zonkTcType ty
1521         ; env0 <- tcInitTidyEnv
1522         ; let (env1, tidy_ty) = tidyOpenType env0 ty'
1523               msg = ptext SLIT("Cannot match a monotype with") <+> quotes (ppr tidy_ty)
1524         ; failWithTcM (env1, msg) }
1525
1526 occurCheck tyvar ty
1527   = do  { env0 <- tcInitTidyEnv
1528         ; ty'  <- zonkTcType ty
1529         ; let (env1, tidy_tyvar) = tidyOpenTyVar env0 tyvar
1530               (env2, tidy_ty)    = tidyOpenType  env1 ty'
1531               extra = sep [ppr tidy_tyvar, char '=', ppr tidy_ty]
1532         ; failWithTcM (env2, hang msg 2 extra) }
1533   where
1534     msg = ptext SLIT("Occurs check: cannot construct the infinite type:")
1535 \end{code}
1536
1537
1538 %************************************************************************
1539 %*                                                                      *
1540                 Kind unification
1541 %*                                                                      *
1542 %************************************************************************
1543
1544 Unifying kinds is much, much simpler than unifying types.
1545
1546 \begin{code}
1547 unifyKind :: TcKind                 -- Expected
1548           -> TcKind                 -- Actual
1549           -> TcM ()
1550 unifyKind LiftedTypeKind   LiftedTypeKind   = returnM ()
1551 unifyKind UnliftedTypeKind UnliftedTypeKind = returnM ()
1552
1553 unifyKind OpenTypeKind k2 | isOpenTypeKind k2 = returnM ()
1554 unifyKind ArgTypeKind  k2 | isArgTypeKind k2    = returnM ()
1555   -- Respect sub-kinding
1556
1557 unifyKind (FunKind a1 r1) (FunKind a2 r2)
1558  = do { unifyKind a2 a1; unifyKind r1 r2 }
1559                 -- Notice the flip in the argument,
1560                 -- so that the sub-kinding works right
1561
1562 unifyKind (KindVar kv1) k2 = uKVar False kv1 k2
1563 unifyKind k1 (KindVar kv2) = uKVar True kv2 k1
1564 unifyKind k1 k2 = unifyKindMisMatch k1 k2
1565
1566 unifyKinds :: [TcKind] -> [TcKind] -> TcM ()
1567 unifyKinds []       []       = returnM ()
1568 unifyKinds (k1:ks1) (k2:ks2) = unifyKind k1 k2  `thenM_`
1569                                unifyKinds ks1 ks2
1570 unifyKinds _ _               = panic "unifyKinds: length mis-match"
1571
1572 ----------------
1573 uKVar :: Bool -> KindVar -> TcKind -> TcM ()
1574 uKVar swapped kv1 k2
1575   = do  { mb_k1 <- readKindVar kv1
1576         ; case mb_k1 of
1577             Nothing -> uUnboundKVar swapped kv1 k2
1578             Just k1 | swapped   -> unifyKind k2 k1
1579                     | otherwise -> unifyKind k1 k2 }
1580
1581 ----------------
1582 uUnboundKVar :: Bool -> KindVar -> TcKind -> TcM ()
1583 uUnboundKVar swapped kv1 k2@(KindVar kv2)
1584   | kv1 == kv2 = returnM ()
1585   | otherwise   -- Distinct kind variables
1586   = do  { mb_k2 <- readKindVar kv2
1587         ; case mb_k2 of
1588             Just k2 -> uUnboundKVar swapped kv1 k2
1589             Nothing -> writeKindVar kv1 k2 }
1590
1591 uUnboundKVar swapped kv1 non_var_k2
1592   = do  { k2' <- zonkTcKind non_var_k2
1593         ; kindOccurCheck kv1 k2'
1594         ; k2'' <- kindSimpleKind swapped k2'
1595                 -- KindVars must be bound only to simple kinds
1596                 -- Polarities: (kindSimpleKind True ?) succeeds
1597                 -- returning *, corresponding to unifying
1598                 --      expected: ?
1599                 --      actual:   kind-ver
1600         ; writeKindVar kv1 k2'' }
1601
1602 ----------------
1603 kindOccurCheck kv1 k2   -- k2 is zonked
1604   = checkTc (not_in k2) (kindOccurCheckErr kv1 k2)
1605   where
1606     not_in (KindVar kv2)   = kv1 /= kv2
1607     not_in (FunKind a2 r2) = not_in a2 && not_in r2
1608     not_in other           = True
1609
1610 kindSimpleKind :: Bool -> Kind -> TcM SimpleKind
1611 -- (kindSimpleKind True k) returns a simple kind sk such that sk <: k
1612 -- If the flag is False, it requires k <: sk
1613 -- E.g.         kindSimpleKind False ?? = *
1614 -- What about (kv -> *) :=: ?? -> *
1615 kindSimpleKind orig_swapped orig_kind
1616   = go orig_swapped orig_kind
1617   where
1618     go sw (FunKind k1 k2) = do { k1' <- go (not sw) k1
1619                                ; k2' <- go sw k2
1620                                ; return (FunKind k1' k2') }
1621     go True OpenTypeKind = return liftedTypeKind
1622     go True ArgTypeKind  = return liftedTypeKind
1623     go sw LiftedTypeKind  = return liftedTypeKind
1624     go sw UnliftedTypeKind = return unliftedTypeKind
1625     go sw k@(KindVar _)   = return k    -- KindVars are always simple
1626     go swapped kind = failWithTc (ptext SLIT("Unexpected kind unification failure:")
1627                                   <+> ppr orig_swapped <+> ppr orig_kind)
1628         -- I think this can't actually happen
1629
1630 -- T v = MkT v           v must be a type
1631 -- T v w = MkT (v -> w)  v must not be an umboxed tuple
1632
1633 ----------------
1634 kindOccurCheckErr tyvar ty
1635   = hang (ptext SLIT("Occurs check: cannot construct the infinite kind:"))
1636        2 (sep [ppr tyvar, char '=', ppr ty])
1637
1638 unifyKindMisMatch ty1 ty2
1639   = zonkTcKind ty1      `thenM` \ ty1' ->
1640     zonkTcKind ty2      `thenM` \ ty2' ->
1641     let
1642         msg = hang (ptext SLIT("Couldn't match kind"))
1643                    2 (sep [quotes (ppr ty1'),
1644                            ptext SLIT("against"),
1645                            quotes (ppr ty2')])
1646     in
1647     failWithTc msg
1648 \end{code}
1649
1650 \begin{code}
1651 unifyFunKind :: TcKind -> TcM (Maybe (TcKind, TcKind))
1652 -- Like unifyFunTy, but does not fail; instead just returns Nothing
1653
1654 unifyFunKind (KindVar kvar)
1655   = readKindVar kvar    `thenM` \ maybe_kind ->
1656     case maybe_kind of
1657         Just fun_kind -> unifyFunKind fun_kind
1658         Nothing       -> do { arg_kind <- newKindVar
1659                             ; res_kind <- newKindVar
1660                             ; writeKindVar kvar (mkArrowKind arg_kind res_kind)
1661                             ; returnM (Just (arg_kind,res_kind)) }
1662
1663 unifyFunKind (FunKind arg_kind res_kind) = returnM (Just (arg_kind,res_kind))
1664 unifyFunKind other                       = returnM Nothing
1665 \end{code}
1666
1667 %************************************************************************
1668 %*                                                                      *
1669         Checking kinds
1670 %*                                                                      *
1671 %************************************************************************
1672
1673 ---------------------------
1674 -- We would like to get a decent error message from
1675 --   (a) Under-applied type constructors
1676 --              f :: (Maybe, Maybe)
1677 --   (b) Over-applied type constructors
1678 --              f :: Int x -> Int x
1679 --
1680
1681 \begin{code}
1682 checkExpectedKind :: Outputable a => a -> TcKind -> TcKind -> TcM ()
1683 -- A fancy wrapper for 'unifyKind', which tries
1684 -- to give decent error messages.
1685 checkExpectedKind ty act_kind exp_kind
1686   | act_kind `isSubKind` exp_kind -- Short cut for a very common case
1687   = returnM ()
1688   | otherwise
1689   = tryTc (unifyKind exp_kind act_kind) `thenM` \ (_errs, mb_r) ->
1690     case mb_r of {
1691         Just r  -> returnM () ; -- Unification succeeded
1692         Nothing ->
1693
1694         -- So there's definitely an error
1695         -- Now to find out what sort
1696     zonkTcKind exp_kind         `thenM` \ exp_kind ->
1697     zonkTcKind act_kind         `thenM` \ act_kind ->
1698
1699     tcInitTidyEnv               `thenM` \ env0 ->
1700     let (exp_as, _) = splitKindFunTys exp_kind
1701         (act_as, _) = splitKindFunTys act_kind
1702         n_exp_as = length exp_as
1703         n_act_as = length act_as
1704
1705         (env1, tidy_exp_kind) = tidyKind env0 exp_kind
1706         (env2, tidy_act_kind) = tidyKind env1 act_kind
1707
1708         err | n_exp_as < n_act_as       -- E.g. [Maybe]
1709             = quotes (ppr ty) <+> ptext SLIT("is not applied to enough type arguments")
1710
1711                 -- Now n_exp_as >= n_act_as. In the next two cases,
1712                 -- n_exp_as == 0, and hence so is n_act_as
1713             | isLiftedTypeKind exp_kind && isUnliftedTypeKind act_kind
1714             = ptext SLIT("Expecting a lifted type, but") <+> quotes (ppr ty)
1715                 <+> ptext SLIT("is unlifted")
1716
1717             | isUnliftedTypeKind exp_kind && isLiftedTypeKind act_kind
1718             = ptext SLIT("Expecting an unlifted type, but") <+> quotes (ppr ty)
1719                 <+> ptext SLIT("is lifted")
1720
1721             | otherwise                 -- E.g. Monad [Int]
1722             = ptext SLIT("Kind mis-match")
1723
1724         more_info = sep [ ptext SLIT("Expected kind") <+>
1725                                 quotes (pprKind tidy_exp_kind) <> comma,
1726                           ptext SLIT("but") <+> quotes (ppr ty) <+>
1727                                 ptext SLIT("has kind") <+> quotes (pprKind tidy_act_kind)]
1728    in
1729    failWithTcM (env2, err $$ more_info)
1730    }
1731 \end{code}
1732
1733 %************************************************************************
1734 %*                                                                      *
1735 \subsection{Checking signature type variables}
1736 %*                                                                      *
1737 %************************************************************************
1738
1739 @checkSigTyVars@ checks that a set of universally quantified type varaibles
1740 are not mentioned in the environment.  In particular:
1741
1742         (a) Not mentioned in the type of a variable in the envt
1743                 eg the signature for f in this:
1744
1745                         g x = ... where
1746                                         f :: a->[a]
1747                                         f y = [x,y]
1748
1749                 Here, f is forced to be monorphic by the free occurence of x.
1750
1751         (d) Not (unified with another type variable that is) in scope.
1752                 eg f x :: (r->r) = (\y->y) :: forall a. a->r
1753             when checking the expression type signature, we find that
1754             even though there is nothing in scope whose type mentions r,
1755             nevertheless the type signature for the expression isn't right.
1756
1757             Another example is in a class or instance declaration:
1758                 class C a where
1759                    op :: forall b. a -> b
1760                    op x = x
1761             Here, b gets unified with a
1762
1763 Before doing this, the substitution is applied to the signature type variable.
1764
1765 \begin{code}
1766 checkSigTyVars :: [TcTyVar] -> TcM ()
1767 checkSigTyVars sig_tvs = check_sig_tyvars emptyVarSet sig_tvs
1768
1769 checkSigTyVarsWrt :: TcTyVarSet -> [TcTyVar] -> TcM ()
1770 -- The extra_tvs can include boxy type variables;
1771 --      e.g. TcMatches.tcCheckExistentialPat
1772 checkSigTyVarsWrt extra_tvs sig_tvs
1773   = do  { extra_tvs' <- zonkTcTyVarsAndFV (varSetElems extra_tvs)
1774         ; check_sig_tyvars extra_tvs' sig_tvs }
1775
1776 check_sig_tyvars
1777         :: TcTyVarSet   -- Global type variables. The universally quantified
1778                         --      tyvars should not mention any of these
1779                         --      Guaranteed already zonked.
1780         -> [TcTyVar]    -- Universally-quantified type variables in the signature
1781                         --      Guaranteed to be skolems
1782         -> TcM ()
1783 check_sig_tyvars extra_tvs []
1784   = returnM ()
1785 check_sig_tyvars extra_tvs sig_tvs
1786   = ASSERT( all isSkolemTyVar sig_tvs )
1787     do  { gbl_tvs <- tcGetGlobalTyVars
1788         ; traceTc (text "check_sig_tyvars" <+> (vcat [text "sig_tys" <+> ppr sig_tvs,
1789                                       text "gbl_tvs" <+> ppr gbl_tvs,
1790                                       text "extra_tvs" <+> ppr extra_tvs]))
1791
1792         ; let env_tvs = gbl_tvs `unionVarSet` extra_tvs
1793         ; ifM (any (`elemVarSet` env_tvs) sig_tvs)
1794               (bleatEscapedTvs env_tvs sig_tvs sig_tvs)
1795         }
1796
1797 bleatEscapedTvs :: TcTyVarSet   -- The global tvs
1798                 -> [TcTyVar]    -- The possibly-escaping type variables
1799                 -> [TcTyVar]    -- The zonked versions thereof
1800                 -> TcM ()
1801 -- Complain about escaping type variables
1802 -- We pass a list of type variables, at least one of which
1803 -- escapes.  The first list contains the original signature type variable,
1804 -- while the second  contains the type variable it is unified to (usually itself)
1805 bleatEscapedTvs globals sig_tvs zonked_tvs
1806   = do  { env0 <- tcInitTidyEnv
1807         ; let (env1, tidy_tvs)        = tidyOpenTyVars env0 sig_tvs
1808               (env2, tidy_zonked_tvs) = tidyOpenTyVars env1 zonked_tvs
1809
1810         ; (env3, msgs) <- foldlM check (env2, []) (tidy_tvs `zip` tidy_zonked_tvs)
1811         ; failWithTcM (env3, main_msg $$ nest 2 (vcat msgs)) }
1812   where
1813     main_msg = ptext SLIT("Inferred type is less polymorphic than expected")
1814
1815     check (tidy_env, msgs) (sig_tv, zonked_tv)
1816       | not (zonked_tv `elemVarSet` globals) = return (tidy_env, msgs)
1817       | otherwise
1818       = do { (tidy_env1, globs) <- findGlobals (unitVarSet zonked_tv) tidy_env
1819            ; returnM (tidy_env1, escape_msg sig_tv zonked_tv globs : msgs) }
1820
1821 -----------------------
1822 escape_msg sig_tv zonked_tv globs
1823   | notNull globs
1824   = vcat [sep [msg, ptext SLIT("is mentioned in the environment:")],
1825           nest 2 (vcat globs)]
1826   | otherwise
1827   = msg <+> ptext SLIT("escapes")
1828         -- Sigh.  It's really hard to give a good error message
1829         -- all the time.   One bad case is an existential pattern match.
1830         -- We rely on the "When..." context to help.
1831   where
1832     msg = ptext SLIT("Quantified type variable") <+> quotes (ppr sig_tv) <+> is_bound_to
1833     is_bound_to
1834         | sig_tv == zonked_tv = empty
1835         | otherwise = ptext SLIT("is unified with") <+> quotes (ppr zonked_tv) <+> ptext SLIT("which")
1836 \end{code}
1837
1838 These two context are used with checkSigTyVars
1839
1840 \begin{code}
1841 sigCtxt :: Id -> [TcTyVar] -> TcThetaType -> TcTauType
1842         -> TidyEnv -> TcM (TidyEnv, Message)
1843 sigCtxt id sig_tvs sig_theta sig_tau tidy_env
1844   = zonkTcType sig_tau          `thenM` \ actual_tau ->
1845     let
1846         (env1, tidy_sig_tvs)    = tidyOpenTyVars tidy_env sig_tvs
1847         (env2, tidy_sig_rho)    = tidyOpenType env1 (mkPhiTy sig_theta sig_tau)
1848         (env3, tidy_actual_tau) = tidyOpenType env2 actual_tau
1849         sub_msg = vcat [ptext SLIT("Signature type:    ") <+> pprType (mkForAllTys tidy_sig_tvs tidy_sig_rho),
1850                         ptext SLIT("Type to generalise:") <+> pprType tidy_actual_tau
1851                    ]
1852         msg = vcat [ptext SLIT("When trying to generalise the type inferred for") <+> quotes (ppr id),
1853                     nest 2 sub_msg]
1854     in
1855     returnM (env3, msg)
1856 \end{code}