compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8
   9 import DynFlags
  10 import HscTypes
  11
  12 import CoreLint             ( showPass, endPass )
  13 import CoreSyn
  14 import CoreUtils
  15 import CoreFVs
  16 import TyCon
  17 import Type
  18 import TypeRep
  19 import Var
  20 import VarEnv
  21 import Name                 ( mkSysTvName )
  22 import NameEnv
  23 import Id
  24
  25 import DsMonad hiding (mapAndUnzipM)
  26
  27 import PrelNames
  28
  29 import Outputable
  30 import FastString
  31 import Control.Monad        ( liftM, liftM2, mapAndUnzipM, zipWithM_ )
  32 import Data.Maybe           ( maybeToList )
  33
  34 vectorise :: HscEnv -> ModGuts -> IO ModGuts
  35 vectorise hsc_env guts
  36   | not (Opt_Vectorise `dopt` dflags) = return guts
  37   | otherwise
  38   = do
  39       showPass dflags "Vectorisation"
  40       eps <- hscEPS hsc_env
  41       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  42       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  43       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  44       return $ guts' { mg_vect_info = info' }
  45   where
  46     dflags = hsc_dflags hsc_env
  47
  48 vectModule :: ModGuts -> VM ModGuts
  49 vectModule guts = return guts
  50
  51 -- ----------------------------------------------------------------------------
  52 -- Bindings
  53
  54 vectBndr :: Var -> VM (Var, Var)
  55 vectBndr v
  56   = do
  57       vty <- vectType (idType v)
  58       lty <- mkPArrayType vty
  59       let vv = v `Id.setIdType` vty
  60           lv = v `Id.setIdType` lty
  61       updLEnv (mapTo vv lv)
  62       return (vv, lv)
  63   where
  64     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
  65
  66 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
  67 vectBndrIn v p
  68   = localV
  69   $ do
  70       (vv, lv) <- vectBndr v
  71       x <- p
  72       return (vv, lv, x)
  73
  74 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
  75 vectBndrsIn vs p
  76   = localV
  77   $ do
  78       (vvs, lvs) <- mapAndUnzipM vectBndr vs
  79       x <- p
  80       return (vvs, lvs, x)
  81
  82 -- ----------------------------------------------------------------------------
  83 -- Expressions
  84
  85 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
  86 replicateP expr len
  87   = do
  88       dict <- paDictOfType ty
  89       rep  <- builtin replicatePAVar
  90       return $ mkApps (Var rep) [Type ty, dict, expr, len]
  91   where
  92     ty = exprType expr
  93
  94 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
  95 capply (vfn, lfn) (varg, larg)
  96   = do
  97       apply  <- builtin applyClosureVar
  98       applyP <- builtin applyClosurePVar
  99       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 100               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 101   where
 102     fn_ty            = exprType vfn
 103     (arg_ty, res_ty) = splitClosureTy fn_ty
 104
 105 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 106 vectVar lc v = local v `orElseV` global v
 107   where
 108     local  v = maybeV (readLEnv $ \env -> lookupVarEnv (local_vars env) v)
 109     global v = do
 110                  vexpr <- maybeV (readGEnv $ \env -> lookupVarEnv (global_vars env) v)
 111                  lexpr <- replicateP vexpr lc
 112                  return (vexpr, lexpr)
 113
 114 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 115 vectPolyVar lc v tys
 116   = do
 117       r <- readLEnv $ \env -> lookupVarEnv (local_vars env) v
 118       case r of
 119         Just (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 120         Nothing ->
 121           do
 122             poly  <- maybeV (readGEnv $ \env -> lookupVarEnv (global_vars env) v)
 123             vexpr <- mk_app poly
 124             lexpr <- replicateP vexpr lc
 125             return (vexpr, lexpr)
 126   where
 127     mk_app e = do
 128                  vtys  <- mapM vectType tys
 129                  dicts <- mapM paDictOfType vtys
 130                  return $ mkApps e [arg | (vty, dict) <- zip vtys dicts
 131                                         , arg <- [Type vty, dict]]
 132
 133 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 134 vectPolyExpr lc expr
 135   = do
 136       mdicts <- mapM mk_dict_var tvs
 137
 138       -- FIXME: shadowing (tvs in lc)
 139       (vmono, lmono) <- localV
 140                       $ do
 141                           zipWithM_ (\tv -> maybe (deleteTyVarPA tv) (extendTyVarPA tv . Var))
 142                                     tvs mdicts
 143                           vectExpr lc mono
 144       return (mk_lams tvs mdicts vmono, mk_lams tvs mdicts lmono)
 145   where
 146     (tvs, mono) = collectAnnTypeBinders expr
 147
 148     mk_dict_var tv = do
 149                        r <- paDictArgType tv
 150                        case r of
 151                          Just ty -> liftM Just (newLocalVar FSLIT("dPA") ty)
 152                          Nothing -> return Nothing
 153
 154     mk_lams tvs mdicts = mkLams [arg | (tv, mdict) <- zip tvs mdicts
 155                                      , arg <- tv : maybeToList mdict]
 156
 157 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 158 vectExpr lc (_, AnnType ty)
 159   = do
 160       vty <- vectType ty
 161       return (Type vty, Type vty)
 162
 163 vectExpr lc (_, AnnVar v)   = vectVar lc v
 164
 165 vectExpr lc (_, AnnLit lit)
 166   = do
 167       let vexpr = Lit lit
 168       lexpr <- replicateP vexpr lc
 169       return (vexpr, lexpr)
 170
 171 vectExpr lc (_, AnnNote note expr)
 172   = do
 173       (vexpr, lexpr) <- vectExpr lc expr
 174       return (Note note vexpr, Note note lexpr)
 175
 176 vectExpr lc e@(_, AnnApp _ arg)
 177   | isAnnTypeArg arg
 178   = vectTyAppExpr lc fn tys
 179   where
 180     (fn, tys) = collectAnnTypeArgs e
 181
 182 vectExpr lc (_, AnnApp fn arg)
 183   = do
 184       fn'  <- vectExpr lc fn
 185       arg' <- vectExpr lc arg
 186       capply fn' arg'
 187
 188 vectExpr lc (_, AnnCase expr bndr ty alts)
 189   = panic "vectExpr: case"
 190
 191 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 192   = do
 193       (vrhs, lrhs) <- vectPolyExpr lc rhs
 194       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 195       return (Let (NonRec vbndr vrhs) vbody,
 196               Let (NonRec lbndr lrhs) lbody)
 197
 198 vectExpr lc (_, AnnLet (AnnRec prs) body)
 199   = do
 200       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 201       return (Let (Rec (zip vbndrs vrhss)) vbody,
 202               Let (Rec (zip lbndrs lrhss)) lbody)
 203   where
 204     (bndrs, rhss) = unzip prs
 205
 206     vect = do
 207              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 208              (vbody, lbody) <- vectPolyExpr lc body
 209              return (vrhss, vbody, lrhss, lbody)
 210
 211 vectExpr lc e@(_, AnnLam bndr body)
 212   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 213
 214 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 215 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 216 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 217
 218 -- ----------------------------------------------------------------------------
 219 -- Types
 220
 221 vectTyCon :: TyCon -> VM TyCon
 222 vectTyCon tc
 223   | isFunTyCon tc        = builtin closureTyCon
 224   | isBoxedTupleTyCon tc = return tc
 225   | isUnLiftedTyCon tc   = return tc
 226   | otherwise = do
 227                   r <- lookupTyCon tc
 228                   case r of
 229                     Just tc' -> return tc'
 230
 231                     -- FIXME: just for now
 232                     Nothing  -> pprTrace "ccTyCon:" (ppr tc) $ return tc
 233
 234 vectType :: Type -> VM Type
 235 vectType ty | Just ty' <- coreView ty = vectType ty
 236 vectType (TyVarTy tv) = return $ TyVarTy tv
 237 vectType (AppTy ty1 ty2) = liftM2 AppTy (vectType ty1) (vectType ty2)
 238 vectType (TyConApp tc tys) = liftM2 TyConApp (vectTyCon tc) (mapM vectType tys)
 239 vectType (FunTy ty1 ty2)   = liftM2 TyConApp (builtin closureTyCon)
 240                                              (mapM vectType [ty1,ty2])
 241 vectType (ForAllTy tv ty)
 242   = do
 243       r   <- paDictArgType tv
 244       ty' <- vectType ty
 245       return $ ForAllTy tv (wrap r ty')
 246   where
 247     wrap Nothing      = id
 248     wrap (Just pa_ty) = FunTy pa_ty
 249
 250 vectType ty = pprPanic "vectType:" (ppr ty)
 251