compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8 import VectType
   9
  10 import DynFlags
  11 import HscTypes
  12
  13 import CoreLint             ( showPass, endPass )
  14 import CoreSyn
  15 import CoreUtils
  16 import CoreFVs
  17 import SimplMonad           ( SimplCount, zeroSimplCount )
  18 import Rules                ( RuleBase )
  19 import DataCon
  20 import TyCon
  21 import Type
  22 import Var
  23 import VarEnv
  24 import VarSet
  25 import Name                 ( mkSysTvName, getName )
  26 import NameEnv
  27 import Id
  28 import MkId                 ( unwrapFamInstScrut )
  29 import OccName
  30
  31 import DsMonad hiding (mapAndUnzipM)
  32 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  33
  34 import PrelNames
  35 import TysWiredIn
  36 import TysPrim              ( intPrimTy )
  37 import BasicTypes           ( Boxity(..) )
  38
  39 import Outputable
  40 import FastString
  41 import Control.Monad        ( liftM, liftM2, mapAndUnzipM, zipWithM_ )
  42
  43 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  44           -> IO (SimplCount, ModGuts)
  45 vectorise hsc_env _ _ guts
  46   = do
  47       showPass dflags "Vectorisation"
  48       eps <- hscEPS hsc_env
  49       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  50       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  51       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  52       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  53   where
  54     dflags = hsc_dflags hsc_env
  55
  56 vectModule :: ModGuts -> VM ModGuts
  57 vectModule guts
  58   = do
  59       types' <- vectTypeEnv (mg_types guts)
  60       binds' <- mapM vectTopBind (mg_binds guts)
  61       return $ guts { mg_types = types'
  62                     , mg_binds = binds' }
  63
  64 vectTopBind :: CoreBind -> VM CoreBind
  65 vectTopBind b@(NonRec var expr)
  66   = do
  67       var'  <- vectTopBinder var
  68       expr' <- vectTopRhs expr
  69       hs    <- takeHoisted
  70       return . Rec $ (var, expr) : (var', expr') : hs
  71   `orElseV`
  72     return b
  73
  74 vectTopBind b@(Rec bs)
  75   = do
  76       vars'  <- mapM vectTopBinder vars
  77       exprs' <- mapM vectTopRhs exprs
  78       hs     <- takeHoisted
  79       return . Rec $ bs ++ zip vars' exprs' ++ hs
  80   `orElseV`
  81     return b
  82   where
  83     (vars, exprs) = unzip bs
  84
  85 vectTopBinder :: Var -> VM Var
  86 vectTopBinder var
  87   = do
  88       vty <- vectType (idType var)
  89       name <- cloneName mkVectOcc (getName var)
  90       let var' | isExportedId var = Id.mkExportedLocalId name vty
  91                | otherwise        = Id.mkLocalId         name vty
  92       defGlobalVar var var'
  93       return var'
  94
  95 vectTopRhs :: CoreExpr -> VM CoreExpr
  96 vectTopRhs = liftM fst . closedV . vectPolyExpr (panic "Empty lifting context") . freeVars
  97
  98 -- ----------------------------------------------------------------------------
  99 -- Bindings
 100
 101 vectBndr :: Var -> VM (Var, Var)
 102 vectBndr v
 103   = do
 104       vty <- vectType (idType v)
 105       lty <- mkPArrayType vty
 106       let vv = v `Id.setIdType` vty
 107           lv = v `Id.setIdType` lty
 108       updLEnv (mapTo vv lv)
 109       return (vv, lv)
 110   where
 111     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 112
 113 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 114 vectBndrIn v p
 115   = localV
 116   $ do
 117       (vv, lv) <- vectBndr v
 118       x <- p
 119       return (vv, lv, x)
 120
 121 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 122 vectBndrsIn vs p
 123   = localV
 124   $ do
 125       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 126       x <- p
 127       return (vvs, lvs, x)
 128
 129 -- ----------------------------------------------------------------------------
 130 -- Expressions
 131
 132 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
 133 replicateP expr len
 134   = do
 135       dict <- paDictOfType ty
 136       rep  <- builtin replicatePAVar
 137       return $ mkApps (Var rep) [Type ty, dict, expr, len]
 138   where
 139     ty = exprType expr
 140
 141 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 142 capply (vfn, lfn) (varg, larg)
 143   = do
 144       apply  <- builtin applyClosureVar
 145       applyP <- builtin applyClosurePVar
 146       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 147               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 148   where
 149     fn_ty            = exprType vfn
 150     (arg_ty, res_ty) = splitClosureTy fn_ty
 151
 152 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 153 vectVar lc v
 154   = do
 155       r <- lookupVar v
 156       case r of
 157         Local es     -> return es
 158         Global vexpr -> do
 159                           lexpr <- replicateP vexpr lc
 160                           return (vexpr, lexpr)
 161
 162 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 163 vectPolyVar lc v tys
 164   = do
 165       r <- lookupVar v
 166       case r of
 167         Local (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 168         Global poly          -> do
 169                                   vexpr <- mk_app poly
 170                                   lexpr <- replicateP vexpr lc
 171                                   return (vexpr, lexpr)
 172   where
 173     mk_app e = applyToTypes e =<< mapM vectType tys
 174
 175 abstractOverTyVars :: [TyVar] -> ((CoreExpr -> CoreExpr) -> VM a) -> VM a
 176 abstractOverTyVars tvs p
 177   = do
 178       mdicts <- mapM mk_dict_var tvs
 179       zipWithM_ (\tv -> maybe (defLocalTyVar tv) (defLocalTyVarWithPA tv . Var)) tvs mdicts
 180       p (mk_lams mdicts)
 181   where
 182     mk_dict_var tv = do
 183                        r <- paDictArgType tv
 184                        case r of
 185                          Just ty -> liftM Just (newLocalVar FSLIT("dPA") ty)
 186                          Nothing -> return Nothing
 187
 188     mk_lams mdicts = mkLams (tvs ++ [dict | Just dict <- mdicts])
 189
 190 applyToTypes :: CoreExpr -> [Type] -> VM CoreExpr
 191 applyToTypes expr tys
 192   = do
 193       dicts <- mapM paDictOfType tys
 194       return $ expr `mkTyApps` tys `mkApps` dicts
 195
 196 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 197 vectPolyExpr lc expr
 198   = localV
 199   . abstractOverTyVars tvs $ \mk_lams ->
 200     -- FIXME: shadowing (tvs in lc)
 201     do
 202       (vmono, lmono) <- vectExpr lc mono
 203       return $ (mk_lams vmono, mk_lams lmono)
 204   where
 205     (tvs, mono) = collectAnnTypeBinders expr
 206
 207 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 208 vectExpr lc (_, AnnType ty)
 209   = do
 210       vty <- vectType ty
 211       return (Type vty, Type vty)
 212
 213 vectExpr lc (_, AnnVar v)   = vectVar lc v
 214
 215 vectExpr lc (_, AnnLit lit)
 216   = do
 217       let vexpr = Lit lit
 218       lexpr <- replicateP vexpr lc
 219       return (vexpr, lexpr)
 220
 221 vectExpr lc (_, AnnNote note expr)
 222   = do
 223       (vexpr, lexpr) <- vectExpr lc expr
 224       return (Note note vexpr, Note note lexpr)
 225
 226 vectExpr lc e@(_, AnnApp _ arg)
 227   | isAnnTypeArg arg
 228   = vectTyAppExpr lc fn tys
 229   where
 230     (fn, tys) = collectAnnTypeArgs e
 231
 232 vectExpr lc (_, AnnApp fn arg)
 233   = do
 234       fn'  <- vectExpr lc fn
 235       arg' <- vectExpr lc arg
 236       capply fn' arg'
 237
 238 vectExpr lc (_, AnnCase expr bndr ty alts)
 239   = panic "vectExpr: case"
 240
 241 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 242   = do
 243       (vrhs, lrhs) <- vectPolyExpr lc rhs
 244       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 245       return (Let (NonRec vbndr vrhs) vbody,
 246               Let (NonRec lbndr lrhs) lbody)
 247
 248 vectExpr lc (_, AnnLet (AnnRec prs) body)
 249   = do
 250       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 251       return (Let (Rec (zip vbndrs vrhss)) vbody,
 252               Let (Rec (zip lbndrs lrhss)) lbody)
 253   where
 254     (bndrs, rhss) = unzip prs
 255
 256     vect = do
 257              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 258              (vbody, lbody) <- vectPolyExpr lc body
 259              return (vrhss, vbody, lrhss, lbody)
 260
 261 vectExpr lc e@(_, AnnLam bndr body)
 262   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 263
 264 vectExpr lc (fvs, AnnLam bndr body)
 265   = do
 266       tyvars <- localTyVars
 267       info <- mkCEnvInfo fvs bndr body
 268       (poly_vfn, poly_lfn) <- mkClosureFns info tyvars bndr body
 269
 270       vfn_var <- hoistExpr FSLIT("vfn") poly_vfn
 271       lfn_var <- hoistExpr FSLIT("lfn") poly_lfn
 272
 273       let (venv, lenv) = mkClosureEnvs info lc
 274
 275       let env_ty = cenv_vty info
 276
 277       pa_dict <- paDictOfType env_ty
 278
 279       arg_ty <- vectType (varType bndr)
 280       res_ty <- vectType (exprType $ deAnnotate body)
 281
 282       -- FIXME: move the functions to the top level
 283       mono_vfn <- applyToTypes (Var vfn_var) (mkTyVarTys tyvars)
 284       mono_lfn <- applyToTypes (Var lfn_var) (mkTyVarTys tyvars)
 285
 286       mk_clo <- builtin mkClosureVar
 287       mk_cloP <- builtin mkClosurePVar
 288
 289       let vclo = Var mk_clo  `mkTyApps` [arg_ty, res_ty, env_ty]
 290                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, venv]
 291
 292           lclo = Var mk_cloP `mkTyApps` [arg_ty, res_ty, env_ty]
 293                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, lenv]
 294
 295       return (vclo, lclo)
 296
 297
 298 data CEnvInfo = CEnvInfo {
 299                cenv_vars         :: [Var]
 300              , cenv_values       :: [(CoreExpr, CoreExpr)]
 301              , cenv_vty          :: Type
 302              , cenv_lty          :: Type
 303              , cenv_repr_tycon   :: TyCon
 304              , cenv_repr_tyargs  :: [Type]
 305              , cenv_repr_datacon :: DataCon
 306              }
 307
 308 mkCEnvInfo :: VarSet -> Var -> CoreExprWithFVs -> VM CEnvInfo
 309 mkCEnvInfo fvs arg body
 310   = do
 311       locals <- readLEnv local_vars
 312       let
 313           (vars, vals) = unzip
 314                  [(var, val) | var      <- varSetElems fvs
 315                              , Just val <- [lookupVarEnv locals var]]
 316       vtys <- mapM (vectType . varType) vars
 317
 318       (vty, repr_tycon, repr_tyargs, repr_datacon) <- mk_env_ty vtys
 319       lty <- mkPArrayType vty
 320
 321       return $ CEnvInfo {
 322                  cenv_vars         = vars
 323                , cenv_values       = vals
 324                , cenv_vty          = vty
 325                , cenv_lty          = lty
 326                , cenv_repr_tycon   = repr_tycon
 327                , cenv_repr_tyargs  = repr_tyargs
 328                , cenv_repr_datacon = repr_datacon
 329                }
 330   where
 331     mk_env_ty [vty]
 332       = return (vty, error "absent cinfo_repr_tycon"
 333                    , error "absent cinfo_repr_tyargs"
 334                    , error "absent cinfo_repr_datacon")
 335
 336     mk_env_ty vtys
 337       = do
 338           let ty = mkCoreTupTy vtys
 339           (repr_tc, repr_tyargs) <- lookupPArrayFamInst ty
 340           let [repr_con] = tyConDataCons repr_tc
 341           return (ty, repr_tc, repr_tyargs, repr_con)
 342
 343
 344
 345 mkClosureEnvs :: CEnvInfo -> CoreExpr -> (CoreExpr, CoreExpr)
 346 mkClosureEnvs info lc
 347   | [] <- vals
 348   = (Var unitDataConId, mkApps (Var $ dataConWrapId (cenv_repr_datacon info))
 349                                [lc, Var unitDataConId])
 350
 351   | [(vval, lval)] <- vals
 352   = (vval, lval)
 353
 354   | otherwise
 355   = (mkCoreTup vvals, Var (dataConWrapId $ cenv_repr_datacon info)
 356                       `mkTyApps` cenv_repr_tyargs info
 357                       `mkApps`   (lc : lvals))
 358
 359   where
 360     vals = cenv_values info
 361     (vvals, lvals) = unzip vals
 362
 363 mkClosureFns :: CEnvInfo -> [TyVar] -> Var -> CoreExprWithFVs
 364              -> VM (CoreExpr, CoreExpr)
 365 mkClosureFns info tyvars arg body
 366   = closedV
 367   . abstractOverTyVars tyvars
 368   $ \mk_tlams ->
 369   do
 370     (vfn, lfn) <- mkClosureMonoFns info arg body
 371     return (mk_tlams vfn, mk_tlams lfn)
 372
 373 mkClosureMonoFns :: CEnvInfo -> Var -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 374 mkClosureMonoFns info arg body
 375   = do
 376       lc_bndr <- newLocalVar FSLIT("lc") intPrimTy
 377       (varg : vbndrs, larg : lbndrs, (vbody, lbody))
 378         <- vectBndrsIn (arg : cenv_vars info)
 379                        (vectExpr (Var lc_bndr) body)
 380
 381       venv_bndr <- newLocalVar FSLIT("env") vty
 382       lenv_bndr <- newLocalVar FSLIT("env") lty
 383
 384       let vcase = bind_venv (Var venv_bndr) vbody vbndrs
 385       lcase <- bind_lenv (Var lenv_bndr) lbody lc_bndr lbndrs
 386       return (mkLams [venv_bndr, varg] vcase, mkLams [lenv_bndr, larg] lcase)
 387   where
 388     vty = cenv_vty info
 389     lty = cenv_lty info
 390
 391     arity = length (cenv_vars info)
 392
 393     bind_venv venv vbody []      = vbody
 394     bind_venv venv vbody [vbndr] = Let (NonRec vbndr venv) vbody
 395     bind_venv venv vbody vbndrs
 396       = Case venv (mkWildId vty) (exprType vbody)
 397              [(DataAlt (tupleCon Boxed arity), vbndrs, vbody)]
 398
 399     bind_lenv lenv lbody lc_bndr [lbndr]
 400       = do
 401           lengthPA <- builtin lengthPAVar
 402           pa_dict  <- paDictOfType vty
 403           return . Let (NonRec lbndr lenv)
 404                  $ Case (mkApps (Var lengthPA) [Type vty, pa_dict, (Var lbndr)])
 405                         lc_bndr
 406                         (exprType lbody)
 407                         [(DEFAULT, [], lbody)]
 408
 409     bind_lenv lenv lbody lc_bndr lbndrs
 410       = let scrut = unwrapFamInstScrut (cenv_repr_tycon info)
 411                                        (cenv_repr_tyargs info)
 412                                        lenv
 413             lbndrs' | null lbndrs = [mkWildId unitTy]
 414                     | otherwise   = lbndrs
 415         in
 416         return
 417       $ Case scrut
 418              (mkWildId (exprType scrut))
 419              (exprType lbody)
 420              [(DataAlt (cenv_repr_datacon info), lc_bndr : lbndrs', lbody)]
 421
 422 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 423 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 424 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 425