compiler/vectorise/Vectorise.hs

   1 {-# OPTIONS -w #-}
   2 -- The above warning supression flag is a temporary kludge.
   3 -- While working on this module you are encouraged to remove it and fix
   4 -- any warnings in the module. See
   5 --     http://hackage.haskell.org/trac/ghc/wiki/Commentary/CodingStyle#Warnings
   6 -- for details
   7
   8 module Vectorise( vectorise )
   9 where
  10
  11 #include "HsVersions.h"
  12
  13 import VectMonad
  14 import VectUtils
  15 import VectType
  16 import VectCore
  17
  18 import DynFlags
  19 import HscTypes
  20
  21 import CoreLint             ( showPass, endPass )
  22 import CoreSyn
  23 import CoreUtils
  24 import CoreFVs
  25 import SimplMonad           ( SimplCount, zeroSimplCount )
  26 import Rules                ( RuleBase )
  27 import DataCon
  28 import TyCon
  29 import Type
  30 import FamInstEnv           ( extendFamInstEnvList )
  31 import InstEnv              ( extendInstEnvList )
  32 import Var
  33 import VarEnv
  34 import VarSet
  35 import Name                 ( Name, mkSysTvName, getName )
  36 import NameEnv
  37 import Id
  38 import MkId                 ( unwrapFamInstScrut )
  39 import OccName
  40 import Module               ( Module )
  41
  42 import DsMonad hiding (mapAndUnzipM)
  43 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  44
  45 import Literal              ( Literal )
  46 import PrelNames
  47 import TysWiredIn
  48 import TysPrim              ( intPrimTy )
  49 import BasicTypes           ( Boxity(..) )
  50
  51 import Outputable
  52 import FastString
  53 import Control.Monad        ( liftM, liftM2, zipWithM, mapAndUnzipM )
  54 import Data.List            ( sortBy, unzip4 )
  55
  56 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  57           -> IO (SimplCount, ModGuts)
  58 vectorise hsc_env _ _ guts
  59   = do
  60       showPass dflags "Vectorisation"
  61       eps <- hscEPS hsc_env
  62       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  63       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  64       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  65       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  66   where
  67     dflags = hsc_dflags hsc_env
  68
  69 vectModule :: ModGuts -> VM ModGuts
  70 vectModule guts
  71   = do
  72       (types', fam_insts, tc_binds) <- vectTypeEnv (mg_types guts)
  73
  74       let fam_inst_env' = extendFamInstEnvList (mg_fam_inst_env guts) fam_insts
  75       updGEnv (setFamInstEnv fam_inst_env')
  76
  77       -- dicts   <- mapM buildPADict pa_insts
  78       -- workers <- mapM vectDataConWorkers pa_insts
  79       binds'  <- mapM vectTopBind (mg_binds guts)
  80       return $ guts { mg_types        = types'
  81                     , mg_binds        = Rec tc_binds : binds'
  82                     , mg_fam_inst_env = fam_inst_env'
  83                     , mg_fam_insts    = mg_fam_insts guts ++ fam_insts
  84                     }
  85
  86 vectTopBind :: CoreBind -> VM CoreBind
  87 vectTopBind b@(NonRec var expr)
  88   = do
  89       var'  <- vectTopBinder var
  90       expr' <- vectTopRhs var expr
  91       hs    <- takeHoisted
  92       return . Rec $ (var, expr) : (var', expr') : hs
  93   `orElseV`
  94     return b
  95
  96 vectTopBind b@(Rec bs)
  97   = do
  98       vars'  <- mapM vectTopBinder vars
  99       exprs' <- zipWithM vectTopRhs vars exprs
 100       hs     <- takeHoisted
 101       return . Rec $ bs ++ zip vars' exprs' ++ hs
 102   `orElseV`
 103     return b
 104   where
 105     (vars, exprs) = unzip bs
 106
 107 vectTopBinder :: Var -> VM Var
 108 vectTopBinder var
 109   = do
 110       vty  <- vectType (idType var)
 111       var' <- cloneId mkVectOcc var vty
 112       defGlobalVar var var'
 113       return var'
 114
 115 vectTopRhs :: Var -> CoreExpr -> VM CoreExpr
 116 vectTopRhs var expr
 117   = do
 118       closedV . liftM vectorised
 119               . inBind var
 120               $ vectPolyExpr (freeVars expr)
 121
 122 -- ----------------------------------------------------------------------------
 123 -- Bindings
 124
 125 vectBndr :: Var -> VM VVar
 126 vectBndr v
 127   = do
 128       vty <- vectType (idType v)
 129       lty <- mkPArrayType vty
 130       let vv = v `Id.setIdType` vty
 131           lv = v `Id.setIdType` lty
 132       updLEnv (mapTo vv lv)
 133       return (vv, lv)
 134   where
 135     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (vv, lv) }
 136
 137 vectBndrNew :: Var -> FastString -> VM VVar
 138 vectBndrNew v fs
 139   = do
 140       vty <- vectType (idType v)
 141       vv  <- newLocalVVar fs vty
 142       updLEnv (upd vv)
 143       return vv
 144   where
 145     upd vv env = env { local_vars = extendVarEnv (local_vars env) v vv }
 146
 147 vectBndrIn :: Var -> VM a -> VM (VVar, a)
 148 vectBndrIn v p
 149   = localV
 150   $ do
 151       vv <- vectBndr v
 152       x <- p
 153       return (vv, x)
 154
 155 vectBndrNewIn :: Var -> FastString -> VM a -> VM (VVar, a)
 156 vectBndrNewIn v fs p
 157   = localV
 158   $ do
 159       vv <- vectBndrNew v fs
 160       x  <- p
 161       return (vv, x)
 162
 163 vectBndrIn' :: Var -> (VVar -> VM a) -> VM (VVar, a)
 164 vectBndrIn' v p
 165   = localV
 166   $ do
 167       vv <- vectBndr v
 168       x  <- p vv
 169       return (vv, x)
 170
 171 vectBndrsIn :: [Var] -> VM a -> VM ([VVar], a)
 172 vectBndrsIn vs p
 173   = localV
 174   $ do
 175       vvs <- mapM vectBndr vs
 176       x <- p
 177       return (vvs, x)
 178
 179 -- ----------------------------------------------------------------------------
 180 -- Expressions
 181
 182 vectVar :: Var -> VM VExpr
 183 vectVar v
 184   = do
 185       r <- lookupVar v
 186       case r of
 187         Local (vv,lv) -> return (Var vv, Var lv)
 188         Global vv     -> do
 189                            let vexpr = Var vv
 190                            lexpr <- liftPA vexpr
 191                            return (vexpr, lexpr)
 192
 193 vectPolyVar :: Var -> [Type] -> VM VExpr
 194 vectPolyVar v tys
 195   = do
 196       vtys <- mapM vectType tys
 197       r <- lookupVar v
 198       case r of
 199         Local (vv, lv) -> liftM2 (,) (polyApply (Var vv) vtys)
 200                                      (polyApply (Var lv) vtys)
 201         Global poly    -> do
 202                             vexpr <- polyApply (Var poly) vtys
 203                             lexpr <- liftPA vexpr
 204                             return (vexpr, lexpr)
 205
 206 vectLiteral :: Literal -> VM VExpr
 207 vectLiteral lit
 208   = do
 209       lexpr <- liftPA (Lit lit)
 210       return (Lit lit, lexpr)
 211
 212 vectPolyExpr :: CoreExprWithFVs -> VM VExpr
 213 vectPolyExpr expr
 214   = polyAbstract tvs $ \abstract ->
 215     do
 216       mono' <- vectExpr mono
 217       return $ mapVect abstract mono'
 218   where
 219     (tvs, mono) = collectAnnTypeBinders expr
 220
 221 vectExpr :: CoreExprWithFVs -> VM VExpr
 222 vectExpr (_, AnnType ty)
 223   = liftM vType (vectType ty)
 224
 225 vectExpr (_, AnnVar v) = vectVar v
 226
 227 vectExpr (_, AnnLit lit) = vectLiteral lit
 228
 229 vectExpr (_, AnnNote note expr)
 230   = liftM (vNote note) (vectExpr expr)
 231
 232 vectExpr e@(_, AnnApp _ arg)
 233   | isAnnTypeArg arg
 234   = vectTyAppExpr fn tys
 235   where
 236     (fn, tys) = collectAnnTypeArgs e
 237
 238 vectExpr (_, AnnApp fn arg)
 239   = do
 240       arg_ty' <- vectType arg_ty
 241       res_ty' <- vectType res_ty
 242       fn'     <- vectExpr fn
 243       arg'    <- vectExpr arg
 244       mkClosureApp arg_ty' res_ty' fn' arg'
 245   where
 246     (arg_ty, res_ty) = splitFunTy . exprType $ deAnnotate fn
 247
 248 vectExpr (_, AnnCase scrut bndr ty alts)
 249   | Just (tycon, ty_args) <- splitTyConApp_maybe scrut_ty
 250   , isAlgTyCon tycon
 251   = vectAlgCase tycon ty_args scrut bndr ty alts
 252   where
 253     scrut_ty = exprType (deAnnotate scrut)
 254
 255 vectExpr (_, AnnCase expr bndr ty alts)
 256   = panic "vectExpr: case"
 257
 258 vectExpr (_, AnnLet (AnnNonRec bndr rhs) body)
 259   = do
 260       vrhs <- localV . inBind bndr $ vectPolyExpr rhs
 261       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 262       return $ vLet (vNonRec vbndr vrhs) vbody
 263
 264 vectExpr (_, AnnLet (AnnRec bs) body)
 265   = do
 266       (vbndrs, (vrhss, vbody)) <- vectBndrsIn bndrs
 267                                 $ liftM2 (,)
 268                                   (zipWithM vect_rhs bndrs rhss)
 269                                   (vectPolyExpr body)
 270       return $ vLet (vRec vbndrs vrhss) vbody
 271   where
 272     (bndrs, rhss) = unzip bs
 273
 274     vect_rhs bndr rhs = localV
 275                       . inBind bndr
 276                       $ vectExpr rhs
 277
 278 vectExpr e@(fvs, AnnLam bndr _)
 279   | not (isId bndr) = pprPanic "vectExpr" (ppr $ deAnnotate e)
 280   | otherwise = vectLam fvs bs body
 281   where
 282     (bs,body) = collectAnnValBinders e
 283
 284 vectLam :: VarSet -> [Var] -> CoreExprWithFVs -> VM VExpr
 285 vectLam fvs bs body
 286   = do
 287       tyvars <- localTyVars
 288       (vs, vvs) <- readLEnv $ \env ->
 289                    unzip [(var, vv) | var <- varSetElems fvs
 290                                     , Just vv <- [lookupVarEnv (local_vars env) var]]
 291
 292       arg_tys <- mapM (vectType . idType) bs
 293       res_ty  <- vectType (exprType $ deAnnotate body)
 294
 295       buildClosures tyvars vvs arg_tys res_ty
 296         . hoistPolyVExpr tyvars
 297         $ do
 298             lc <- builtin liftingContext
 299             (vbndrs, vbody) <- vectBndrsIn (vs ++ bs)
 300                                            (vectExpr body)
 301             return $ vLams lc vbndrs vbody
 302
 303 vectTyAppExpr :: CoreExprWithFVs -> [Type] -> VM VExpr
 304 vectTyAppExpr (_, AnnVar v) tys = vectPolyVar v tys
 305 vectTyAppExpr e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 306
 307 type CoreAltWithFVs = AnnAlt Id VarSet
 308
 309 -- We convert
 310 --
 311 --   case e :: t of v { ... }
 312 --
 313 -- to
 314 --
 315 --   V:    let v' = e in case v' of _ { ... }
 316 --   L:    let v' = e in case v' `cast` ... of _ { ... }
 317 --
 318 -- When lifting, we have to do it this way because v must have the type
 319 -- [:V(T):] but the scrutinee must be cast to the representation type. We also
 320 -- have to handle the case where v is a wild var correctly.
 321 --
 322
 323 -- FIXME: this is too lazy
 324 vectAlgCase tycon ty_args scrut bndr ty [(DEFAULT, [], body)]
 325   = do
 326       vscrut <- vectExpr scrut
 327       vty    <- vectType ty
 328       lty    <- mkPArrayType vty
 329       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 330       return $ vCaseDEFAULT vscrut vbndr vty lty vbody
 331
 332 vectAlgCase tycon ty_args scrut bndr ty [(DataAlt dc, bndrs, body)]
 333   = do
 334       vect_tc <- maybeV (lookupTyCon tycon)
 335       vty <- vectType ty
 336       lty <- mkPArrayType vty
 337       vexpr <- vectExpr scrut
 338       (vbndr, (vbndrs, vbody)) <- vect_scrut_bndr
 339                                 . vectBndrsIn bndrs
 340                                 $ vectExpr body
 341
 342       (vscrut, arr_tc, arg_tys) <- mkVScrut (vVar vbndr)
 343       vect_dc <- maybeV (lookupDataCon dc)
 344       let [arr_dc] = tyConDataCons arr_tc
 345       repr <- mkRepr vect_tc
 346       shape_bndrs <- arrShapeVars repr
 347       return . vLet (vNonRec vbndr vexpr)
 348              $ vCaseProd vscrut vty lty vect_dc arr_dc shape_bndrs vbndrs vbody
 349   where
 350     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr FSLIT("scrut")
 351                     | otherwise         = vectBndrIn bndr
 352
 353 vectAlgCase tycon ty_args scrut bndr ty alts
 354   = do
 355       vect_tc <- maybeV (lookupTyCon tycon)
 356       vty               <- vectType ty
 357       lty               <- mkPArrayType vty
 358
 359       repr        <- mkRepr vect_tc
 360       shape_bndrs <- arrShapeVars repr
 361       (len, sel, indices) <- arrSelector repr (map Var shape_bndrs)
 362
 363       (vbndr, valts) <- vect_scrut_bndr $ mapM (proc_alt sel lty) alts'
 364       let (vect_dcs, vect_bndrss, lift_bndrss, vbodies) = unzip4 valts
 365
 366       vexpr <- vectExpr scrut
 367       (vscrut, arr_tc, arg_tys) <- mkVScrut (vVar vbndr)
 368       let [arr_dc] = tyConDataCons arr_tc
 369
 370       let (vect_scrut,  lift_scrut)  = vscrut
 371           (vect_bodies, lift_bodies) = unzip vbodies
 372
 373       let vect_case = Case vect_scrut (mkWildId (exprType vect_scrut)) vty
 374                            (zipWith3 mk_vect_alt vect_dcs vect_bndrss vect_bodies)
 375
 376       lbody <- combinePA vty len sel indices lift_bodies
 377       let lift_case = Case lift_scrut (mkWildId (exprType lift_scrut)) lty
 378                            [(DataAlt arr_dc, shape_bndrs ++ concat lift_bndrss,
 379                              lbody)]
 380
 381       return . vLet (vNonRec vbndr vexpr)
 382              $ (vect_case, lift_case)
 383   where
 384     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr FSLIT("scrut")
 385                     | otherwise         = vectBndrIn bndr
 386
 387     alts' = sortBy (\(alt1, _, _) (alt2, _, _) -> cmp alt1 alt2) alts
 388
 389     cmp (DataAlt dc1) (DataAlt dc2) = dataConTag dc1 `compare` dataConTag dc2
 390     cmp DEFAULT       DEFAULT       = EQ
 391     cmp DEFAULT       _             = LT
 392     cmp _             DEFAULT       = GT
 393
 394     proc_alt sel lty (DataAlt dc, bndrs, body)
 395       = do
 396           vect_dc <- maybeV (lookupDataCon dc)
 397           let tag = mkDataConTag vect_dc
 398               fvs = freeVarsOf body `delVarSetList` bndrs
 399           (vect_bndrs, lift_bndrs, vbody)
 400             <- vect_alt_bndrs bndrs
 401              $ \len -> packLiftingContext len sel tag fvs lty
 402              $ vectExpr body
 403
 404           return (vect_dc, vect_bndrs, lift_bndrs, vbody)
 405
 406     vect_alt_bndrs [] p
 407       = do
 408           void_tc <- builtin voidTyCon
 409           let void_ty = mkTyConApp void_tc []
 410           arr_ty <- mkPArrayType void_ty
 411           bndr   <- newLocalVar FSLIT("voids") arr_ty
 412           len    <- lengthPA void_ty (Var bndr)
 413           e      <- p len
 414           return ([], [bndr], e)
 415
 416     vect_alt_bndrs bndrs p
 417        = localV
 418        $ do
 419            vbndrs <- mapM vectBndr bndrs
 420            let (vect_bndrs, lift_bndrs) = unzip vbndrs
 421                vv : _ = vect_bndrs
 422                lv : _ = lift_bndrs
 423            len <- lengthPA (idType vv) (Var lv)
 424            e   <- p len
 425            return (vect_bndrs, lift_bndrs, e)
 426
 427     mk_vect_alt vect_dc bndrs body = (DataAlt vect_dc, bndrs, body)
 428
 429 packLiftingContext :: CoreExpr -> CoreExpr -> CoreExpr -> VarSet -> Type -> VM VExpr -> VM VExpr
 430 packLiftingContext len shape tag fvs res_ty p
 431   = do
 432       select <- builtin selectPAIntPrimVar
 433       let sel_expr = mkApps (Var select) [shape, tag]
 434       sel_var <- newLocalVar FSLIT("sel#") (exprType sel_expr)
 435       lc_var <- builtin liftingContext
 436       localV $
 437         do
 438           bnds <- mapM (packFreeVar (Var lc_var) (Var sel_var)) (varSetElems fvs)
 439           (vexpr, lexpr) <- p
 440           return (vexpr, Let (NonRec sel_var sel_expr)
 441                          $ Case len lc_var res_ty [(DEFAULT, [], lexpr)])
 442
 443 packFreeVar :: CoreExpr -> CoreExpr -> Var -> VM [CoreBind]
 444 packFreeVar len sel v
 445   = do
 446       r <- lookupVar v
 447       case r of
 448         Local (vv,lv) ->
 449           do
 450             lv' <- cloneVar lv
 451             expr <- packPA (idType vv) (Var lv) len sel
 452             updLEnv (upd vv lv')
 453             return [(NonRec lv' expr)]
 454
 455         _  -> return []
 456   where
 457     upd vv lv' env = env { local_vars = extendVarEnv (local_vars env) v (vv, lv') }
 458