compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8 import VectType
   9
  10 import DynFlags
  11 import HscTypes
  12
  13 import CoreLint             ( showPass, endPass )
  14 import CoreSyn
  15 import CoreUtils
  16 import CoreFVs
  17 import SimplMonad           ( SimplCount, zeroSimplCount )
  18 import Rules                ( RuleBase )
  19 import DataCon
  20 import TyCon
  21 import Type
  22 import FamInstEnv           ( extendFamInstEnvList )
  23 import InstEnv              ( extendInstEnvList )
  24 import Var
  25 import VarEnv
  26 import VarSet
  27 import Name                 ( mkSysTvName, getName )
  28 import NameEnv
  29 import Id
  30 import MkId                 ( unwrapFamInstScrut )
  31 import OccName
  32
  33 import DsMonad hiding (mapAndUnzipM)
  34 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  35
  36 import PrelNames
  37 import TysWiredIn
  38 import TysPrim              ( intPrimTy )
  39 import BasicTypes           ( Boxity(..) )
  40
  41 import Outputable
  42 import FastString
  43 import Control.Monad        ( liftM, liftM2, mapAndUnzipM )
  44
  45 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  46           -> IO (SimplCount, ModGuts)
  47 vectorise hsc_env _ _ guts
  48   = do
  49       showPass dflags "Vectorisation"
  50       eps <- hscEPS hsc_env
  51       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  52       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  53       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  54       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  55   where
  56     dflags = hsc_dflags hsc_env
  57
  58 vectModule :: ModGuts -> VM ModGuts
  59 vectModule guts
  60   = do
  61       (types', fam_insts, pa_insts) <- vectTypeEnv (mg_types guts)
  62
  63       let insts         = map painstInstance pa_insts
  64           fam_inst_env' = extendFamInstEnvList (mg_fam_inst_env guts) fam_insts
  65           inst_env'     = extendInstEnvList (mg_inst_env guts) insts
  66       updGEnv (setInstEnvs inst_env' fam_inst_env')
  67
  68       dicts  <- mapM buildPADict pa_insts
  69       binds' <- mapM vectTopBind (mg_binds guts)
  70       return $ guts { mg_types        = types'
  71                     , mg_binds        = Rec (concat dicts) : binds'
  72                     , mg_inst_env     = inst_env'
  73                     , mg_fam_inst_env = fam_inst_env'
  74                     , mg_insts        = mg_insts guts ++ insts
  75                     , mg_fam_insts    = mg_fam_insts guts ++ fam_insts
  76                     }
  77
  78 vectTopBind :: CoreBind -> VM CoreBind
  79 vectTopBind b@(NonRec var expr)
  80   = do
  81       var'  <- vectTopBinder var
  82       expr' <- vectTopRhs expr
  83       hs    <- takeHoisted
  84       return . Rec $ (var, expr) : (var', expr') : hs
  85   `orElseV`
  86     return b
  87
  88 vectTopBind b@(Rec bs)
  89   = do
  90       vars'  <- mapM vectTopBinder vars
  91       exprs' <- mapM vectTopRhs exprs
  92       hs     <- takeHoisted
  93       return . Rec $ bs ++ zip vars' exprs' ++ hs
  94   `orElseV`
  95     return b
  96   where
  97     (vars, exprs) = unzip bs
  98
  99 vectTopBinder :: Var -> VM Var
 100 vectTopBinder var
 101   = do
 102       vty <- vectType (idType var)
 103       name <- cloneName mkVectOcc (getName var)
 104       let var' | isExportedId var = Id.mkExportedLocalId name vty
 105                | otherwise        = Id.mkLocalId         name vty
 106       defGlobalVar var var'
 107       return var'
 108
 109 vectTopRhs :: CoreExpr -> VM CoreExpr
 110 vectTopRhs = liftM fst . closedV . vectPolyExpr (panic "Empty lifting context") . freeVars
 111
 112 -- ----------------------------------------------------------------------------
 113 -- Bindings
 114
 115 vectBndr :: Var -> VM (Var, Var)
 116 vectBndr v
 117   = do
 118       vty <- vectType (idType v)
 119       lty <- mkPArrayType vty
 120       let vv = v `Id.setIdType` vty
 121           lv = v `Id.setIdType` lty
 122       updLEnv (mapTo vv lv)
 123       return (vv, lv)
 124   where
 125     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 126
 127 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 128 vectBndrIn v p
 129   = localV
 130   $ do
 131       (vv, lv) <- vectBndr v
 132       x <- p
 133       return (vv, lv, x)
 134
 135 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 136 vectBndrsIn vs p
 137   = localV
 138   $ do
 139       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 140       x <- p
 141       return (vvs, lvs, x)
 142
 143 -- ----------------------------------------------------------------------------
 144 -- Expressions
 145
 146 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 147 capply (vfn, lfn) (varg, larg)
 148   = do
 149       apply  <- builtin applyClosureVar
 150       applyP <- builtin applyClosurePVar
 151       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 152               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 153   where
 154     fn_ty            = exprType vfn
 155     (arg_ty, res_ty) = splitClosureTy fn_ty
 156
 157 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 158 vectVar lc v
 159   = do
 160       r <- lookupVar v
 161       case r of
 162         Local es     -> return es
 163         Global vexpr -> do
 164                           lexpr <- replicatePA vexpr lc
 165                           return (vexpr, lexpr)
 166
 167 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 168 vectPolyVar lc v tys
 169   = do
 170       r <- lookupVar v
 171       case r of
 172         Local (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 173         Global poly          -> do
 174                                   vexpr <- mk_app poly
 175                                   lexpr <- replicatePA vexpr lc
 176                                   return (vexpr, lexpr)
 177   where
 178     mk_app e = polyApply e =<< mapM vectType tys
 179
 180 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 181 vectPolyExpr lc expr
 182   = polyAbstract tvs $ \mk_lams ->
 183     -- FIXME: shadowing (tvs in lc)
 184     do
 185       (vmono, lmono) <- vectExpr lc mono
 186       return $ (mk_lams vmono, mk_lams lmono)
 187   where
 188     (tvs, mono) = collectAnnTypeBinders expr
 189
 190 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 191 vectExpr lc (_, AnnType ty)
 192   = do
 193       vty <- vectType ty
 194       return (Type vty, Type vty)
 195
 196 vectExpr lc (_, AnnVar v)   = vectVar lc v
 197
 198 vectExpr lc (_, AnnLit lit)
 199   = do
 200       let vexpr = Lit lit
 201       lexpr <- replicatePA vexpr lc
 202       return (vexpr, lexpr)
 203
 204 vectExpr lc (_, AnnNote note expr)
 205   = do
 206       (vexpr, lexpr) <- vectExpr lc expr
 207       return (Note note vexpr, Note note lexpr)
 208
 209 vectExpr lc e@(_, AnnApp _ arg)
 210   | isAnnTypeArg arg
 211   = vectTyAppExpr lc fn tys
 212   where
 213     (fn, tys) = collectAnnTypeArgs e
 214
 215 vectExpr lc (_, AnnApp fn arg)
 216   = do
 217       fn'  <- vectExpr lc fn
 218       arg' <- vectExpr lc arg
 219       capply fn' arg'
 220
 221 vectExpr lc (_, AnnCase expr bndr ty alts)
 222   = panic "vectExpr: case"
 223
 224 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 225   = do
 226       (vrhs, lrhs) <- vectPolyExpr lc rhs
 227       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 228       return (Let (NonRec vbndr vrhs) vbody,
 229               Let (NonRec lbndr lrhs) lbody)
 230
 231 vectExpr lc (_, AnnLet (AnnRec prs) body)
 232   = do
 233       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 234       return (Let (Rec (zip vbndrs vrhss)) vbody,
 235               Let (Rec (zip lbndrs lrhss)) lbody)
 236   where
 237     (bndrs, rhss) = unzip prs
 238
 239     vect = do
 240              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 241              (vbody, lbody) <- vectPolyExpr lc body
 242              return (vrhss, vbody, lrhss, lbody)
 243
 244 vectExpr lc e@(_, AnnLam bndr body)
 245   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 246
 247 vectExpr lc (fvs, AnnLam bndr body)
 248   = do
 249       tyvars <- localTyVars
 250       info <- mkCEnvInfo fvs bndr body
 251       (poly_vfn, poly_lfn) <- mkClosureFns info tyvars bndr body
 252
 253       vfn_var <- hoistExpr FSLIT("vfn") poly_vfn
 254       lfn_var <- hoistExpr FSLIT("lfn") poly_lfn
 255
 256       let (venv, lenv) = mkClosureEnvs info lc
 257
 258       let env_ty = cenv_vty info
 259
 260       pa_dict <- paDictOfType env_ty
 261
 262       arg_ty <- vectType (varType bndr)
 263       res_ty <- vectType (exprType $ deAnnotate body)
 264
 265       -- FIXME: move the functions to the top level
 266       mono_vfn <- polyApply (Var vfn_var) (mkTyVarTys tyvars)
 267       mono_lfn <- polyApply (Var lfn_var) (mkTyVarTys tyvars)
 268
 269       mk_clo <- builtin mkClosureVar
 270       mk_cloP <- builtin mkClosurePVar
 271
 272       let vclo = Var mk_clo  `mkTyApps` [arg_ty, res_ty, env_ty]
 273                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, venv]
 274
 275           lclo = Var mk_cloP `mkTyApps` [arg_ty, res_ty, env_ty]
 276                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, lenv]
 277
 278       return (vclo, lclo)
 279
 280
 281 data CEnvInfo = CEnvInfo {
 282                cenv_vars         :: [Var]
 283              , cenv_values       :: [(CoreExpr, CoreExpr)]
 284              , cenv_vty          :: Type
 285              , cenv_lty          :: Type
 286              , cenv_repr_tycon   :: TyCon
 287              , cenv_repr_tyargs  :: [Type]
 288              , cenv_repr_datacon :: DataCon
 289              }
 290
 291 mkCEnvInfo :: VarSet -> Var -> CoreExprWithFVs -> VM CEnvInfo
 292 mkCEnvInfo fvs arg body
 293   = do
 294       locals <- readLEnv local_vars
 295       let
 296           (vars, vals) = unzip
 297                  [(var, val) | var      <- varSetElems fvs
 298                              , Just val <- [lookupVarEnv locals var]]
 299       vtys <- mapM (vectType . varType) vars
 300
 301       (vty, repr_tycon, repr_tyargs, repr_datacon) <- mk_env_ty vtys
 302       lty <- mkPArrayType vty
 303
 304       return $ CEnvInfo {
 305                  cenv_vars         = vars
 306                , cenv_values       = vals
 307                , cenv_vty          = vty
 308                , cenv_lty          = lty
 309                , cenv_repr_tycon   = repr_tycon
 310                , cenv_repr_tyargs  = repr_tyargs
 311                , cenv_repr_datacon = repr_datacon
 312                }
 313   where
 314     mk_env_ty [vty]
 315       = return (vty, error "absent cinfo_repr_tycon"
 316                    , error "absent cinfo_repr_tyargs"
 317                    , error "absent cinfo_repr_datacon")
 318
 319     mk_env_ty vtys
 320       = do
 321           let ty = mkCoreTupTy vtys
 322           (repr_tc, repr_tyargs) <- lookupPArrayFamInst ty
 323           let [repr_con] = tyConDataCons repr_tc
 324           return (ty, repr_tc, repr_tyargs, repr_con)
 325
 326
 327
 328 mkClosureEnvs :: CEnvInfo -> CoreExpr -> (CoreExpr, CoreExpr)
 329 mkClosureEnvs info lc
 330   | [] <- vals
 331   = (Var unitDataConId, mkApps (Var $ dataConWrapId (cenv_repr_datacon info))
 332                                [lc, Var unitDataConId])
 333
 334   | [(vval, lval)] <- vals
 335   = (vval, lval)
 336
 337   | otherwise
 338   = (mkCoreTup vvals, Var (dataConWrapId $ cenv_repr_datacon info)
 339                       `mkTyApps` cenv_repr_tyargs info
 340                       `mkApps`   (lc : lvals))
 341
 342   where
 343     vals = cenv_values info
 344     (vvals, lvals) = unzip vals
 345
 346 mkClosureFns :: CEnvInfo -> [TyVar] -> Var -> CoreExprWithFVs
 347              -> VM (CoreExpr, CoreExpr)
 348 mkClosureFns info tyvars arg body
 349   = closedV
 350   . polyAbstract tyvars
 351   $ \mk_tlams ->
 352   do
 353     (vfn, lfn) <- mkClosureMonoFns info arg body
 354     return (mk_tlams vfn, mk_tlams lfn)
 355
 356 mkClosureMonoFns :: CEnvInfo -> Var -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 357 mkClosureMonoFns info arg body
 358   = do
 359       lc_bndr <- newLocalVar FSLIT("lc") intPrimTy
 360       (varg : vbndrs, larg : lbndrs, (vbody, lbody))
 361         <- vectBndrsIn (arg : cenv_vars info)
 362                        (vectExpr (Var lc_bndr) body)
 363
 364       venv_bndr <- newLocalVar FSLIT("env") vty
 365       lenv_bndr <- newLocalVar FSLIT("env") lty
 366
 367       let vcase = bind_venv (Var venv_bndr) vbody vbndrs
 368       lcase <- bind_lenv (Var lenv_bndr) lbody lc_bndr lbndrs
 369       return (mkLams [venv_bndr, varg] vcase, mkLams [lenv_bndr, larg] lcase)
 370   where
 371     vty = cenv_vty info
 372     lty = cenv_lty info
 373
 374     arity = length (cenv_vars info)
 375
 376     bind_venv venv vbody []      = vbody
 377     bind_venv venv vbody [vbndr] = Let (NonRec vbndr venv) vbody
 378     bind_venv venv vbody vbndrs
 379       = Case venv (mkWildId vty) (exprType vbody)
 380              [(DataAlt (tupleCon Boxed arity), vbndrs, vbody)]
 381
 382     bind_lenv lenv lbody lc_bndr [lbndr]
 383       = do
 384           len <- lengthPA (Var lbndr)
 385           return . Let (NonRec lbndr lenv)
 386                  $ Case len
 387                         lc_bndr
 388                         (exprType lbody)
 389                         [(DEFAULT, [], lbody)]
 390
 391     bind_lenv lenv lbody lc_bndr lbndrs
 392       = let scrut = unwrapFamInstScrut (cenv_repr_tycon info)
 393                                        (cenv_repr_tyargs info)
 394                                        lenv
 395             lbndrs' | null lbndrs = [mkWildId unitTy]
 396                     | otherwise   = lbndrs
 397         in
 398         return
 399       $ Case scrut
 400              (mkWildId (exprType scrut))
 401              (exprType lbody)
 402              [(DataAlt (cenv_repr_datacon info), lc_bndr : lbndrs', lbody)]
 403
 404 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 405 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 406 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 407