compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8 import VectType
   9
  10 import DynFlags
  11 import HscTypes
  12
  13 import CoreLint             ( showPass, endPass )
  14 import CoreSyn
  15 import CoreUtils
  16 import CoreFVs
  17 import SimplMonad           ( SimplCount, zeroSimplCount )
  18 import Rules                ( RuleBase )
  19 import DataCon
  20 import TyCon
  21 import Type
  22 import FamInstEnv           ( extendFamInstEnvList )
  23 import InstEnv              ( extendInstEnvList )
  24 import Var
  25 import VarEnv
  26 import VarSet
  27 import Name                 ( mkSysTvName, getName )
  28 import NameEnv
  29 import Id
  30 import MkId                 ( unwrapFamInstScrut )
  31 import OccName
  32
  33 import DsMonad hiding (mapAndUnzipM)
  34 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  35
  36 import PrelNames
  37 import TysWiredIn
  38 import TysPrim              ( intPrimTy )
  39 import BasicTypes           ( Boxity(..) )
  40
  41 import Outputable
  42 import FastString
  43 import Control.Monad        ( liftM, liftM2, mapAndUnzipM, zipWithM_ )
  44
  45 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  46           -> IO (SimplCount, ModGuts)
  47 vectorise hsc_env _ _ guts
  48   = do
  49       showPass dflags "Vectorisation"
  50       eps <- hscEPS hsc_env
  51       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  52       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  53       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  54       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  55   where
  56     dflags = hsc_dflags hsc_env
  57
  58 vectModule :: ModGuts -> VM ModGuts
  59 vectModule guts
  60   = do
  61       (types', fam_insts, insts) <- vectTypeEnv (mg_types guts)
  62
  63       let fam_inst_env' = extendFamInstEnvList (mg_fam_inst_env guts) fam_insts
  64           inst_env'     = extendInstEnvList (mg_inst_env guts) insts
  65       updGEnv (setInstEnvs inst_env' fam_inst_env')
  66
  67       binds' <- mapM vectTopBind (mg_binds guts)
  68       return $ guts { mg_types        = types'
  69                     , mg_binds        = binds'
  70                     , mg_inst_env     = inst_env'
  71                     , mg_fam_inst_env = fam_inst_env'
  72                     , mg_insts        = mg_insts guts ++ insts
  73                     , mg_fam_insts    = mg_fam_insts guts ++ fam_insts
  74                     }
  75
  76 vectTopBind :: CoreBind -> VM CoreBind
  77 vectTopBind b@(NonRec var expr)
  78   = do
  79       var'  <- vectTopBinder var
  80       expr' <- vectTopRhs expr
  81       hs    <- takeHoisted
  82       return . Rec $ (var, expr) : (var', expr') : hs
  83   `orElseV`
  84     return b
  85
  86 vectTopBind b@(Rec bs)
  87   = do
  88       vars'  <- mapM vectTopBinder vars
  89       exprs' <- mapM vectTopRhs exprs
  90       hs     <- takeHoisted
  91       return . Rec $ bs ++ zip vars' exprs' ++ hs
  92   `orElseV`
  93     return b
  94   where
  95     (vars, exprs) = unzip bs
  96
  97 vectTopBinder :: Var -> VM Var
  98 vectTopBinder var
  99   = do
 100       vty <- vectType (idType var)
 101       name <- cloneName mkVectOcc (getName var)
 102       let var' | isExportedId var = Id.mkExportedLocalId name vty
 103                | otherwise        = Id.mkLocalId         name vty
 104       defGlobalVar var var'
 105       return var'
 106
 107 vectTopRhs :: CoreExpr -> VM CoreExpr
 108 vectTopRhs = liftM fst . closedV . vectPolyExpr (panic "Empty lifting context") . freeVars
 109
 110 -- ----------------------------------------------------------------------------
 111 -- Bindings
 112
 113 vectBndr :: Var -> VM (Var, Var)
 114 vectBndr v
 115   = do
 116       vty <- vectType (idType v)
 117       lty <- mkPArrayType vty
 118       let vv = v `Id.setIdType` vty
 119           lv = v `Id.setIdType` lty
 120       updLEnv (mapTo vv lv)
 121       return (vv, lv)
 122   where
 123     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 124
 125 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 126 vectBndrIn v p
 127   = localV
 128   $ do
 129       (vv, lv) <- vectBndr v
 130       x <- p
 131       return (vv, lv, x)
 132
 133 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 134 vectBndrsIn vs p
 135   = localV
 136   $ do
 137       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 138       x <- p
 139       return (vvs, lvs, x)
 140
 141 -- ----------------------------------------------------------------------------
 142 -- Expressions
 143
 144 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
 145 replicateP expr len = liftM (`mkApps` [expr, len])
 146                             (paMethod replicatePAVar (exprType expr))
 147
 148 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 149 capply (vfn, lfn) (varg, larg)
 150   = do
 151       apply  <- builtin applyClosureVar
 152       applyP <- builtin applyClosurePVar
 153       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 154               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 155   where
 156     fn_ty            = exprType vfn
 157     (arg_ty, res_ty) = splitClosureTy fn_ty
 158
 159 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 160 vectVar lc v
 161   = do
 162       r <- lookupVar v
 163       case r of
 164         Local es     -> return es
 165         Global vexpr -> do
 166                           lexpr <- replicateP vexpr lc
 167                           return (vexpr, lexpr)
 168
 169 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 170 vectPolyVar lc v tys
 171   = do
 172       r <- lookupVar v
 173       case r of
 174         Local (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 175         Global poly          -> do
 176                                   vexpr <- mk_app poly
 177                                   lexpr <- replicateP vexpr lc
 178                                   return (vexpr, lexpr)
 179   where
 180     mk_app e = applyToTypes e =<< mapM vectType tys
 181
 182 abstractOverTyVars :: [TyVar] -> ((CoreExpr -> CoreExpr) -> VM a) -> VM a
 183 abstractOverTyVars tvs p
 184   = do
 185       mdicts <- mapM mk_dict_var tvs
 186       zipWithM_ (\tv -> maybe (defLocalTyVar tv) (defLocalTyVarWithPA tv . Var)) tvs mdicts
 187       p (mk_lams mdicts)
 188   where
 189     mk_dict_var tv = do
 190                        r <- paDictArgType tv
 191                        case r of
 192                          Just ty -> liftM Just (newLocalVar FSLIT("dPA") ty)
 193                          Nothing -> return Nothing
 194
 195     mk_lams mdicts = mkLams (tvs ++ [dict | Just dict <- mdicts])
 196
 197 applyToTypes :: CoreExpr -> [Type] -> VM CoreExpr
 198 applyToTypes expr tys
 199   = do
 200       dicts <- mapM paDictOfType tys
 201       return $ expr `mkTyApps` tys `mkApps` dicts
 202
 203 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 204 vectPolyExpr lc expr
 205   = localV
 206   . abstractOverTyVars tvs $ \mk_lams ->
 207     -- FIXME: shadowing (tvs in lc)
 208     do
 209       (vmono, lmono) <- vectExpr lc mono
 210       return $ (mk_lams vmono, mk_lams lmono)
 211   where
 212     (tvs, mono) = collectAnnTypeBinders expr
 213
 214 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 215 vectExpr lc (_, AnnType ty)
 216   = do
 217       vty <- vectType ty
 218       return (Type vty, Type vty)
 219
 220 vectExpr lc (_, AnnVar v)   = vectVar lc v
 221
 222 vectExpr lc (_, AnnLit lit)
 223   = do
 224       let vexpr = Lit lit
 225       lexpr <- replicateP vexpr lc
 226       return (vexpr, lexpr)
 227
 228 vectExpr lc (_, AnnNote note expr)
 229   = do
 230       (vexpr, lexpr) <- vectExpr lc expr
 231       return (Note note vexpr, Note note lexpr)
 232
 233 vectExpr lc e@(_, AnnApp _ arg)
 234   | isAnnTypeArg arg
 235   = vectTyAppExpr lc fn tys
 236   where
 237     (fn, tys) = collectAnnTypeArgs e
 238
 239 vectExpr lc (_, AnnApp fn arg)
 240   = do
 241       fn'  <- vectExpr lc fn
 242       arg' <- vectExpr lc arg
 243       capply fn' arg'
 244
 245 vectExpr lc (_, AnnCase expr bndr ty alts)
 246   = panic "vectExpr: case"
 247
 248 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 249   = do
 250       (vrhs, lrhs) <- vectPolyExpr lc rhs
 251       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 252       return (Let (NonRec vbndr vrhs) vbody,
 253               Let (NonRec lbndr lrhs) lbody)
 254
 255 vectExpr lc (_, AnnLet (AnnRec prs) body)
 256   = do
 257       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 258       return (Let (Rec (zip vbndrs vrhss)) vbody,
 259               Let (Rec (zip lbndrs lrhss)) lbody)
 260   where
 261     (bndrs, rhss) = unzip prs
 262
 263     vect = do
 264              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 265              (vbody, lbody) <- vectPolyExpr lc body
 266              return (vrhss, vbody, lrhss, lbody)
 267
 268 vectExpr lc e@(_, AnnLam bndr body)
 269   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 270
 271 vectExpr lc (fvs, AnnLam bndr body)
 272   = do
 273       tyvars <- localTyVars
 274       info <- mkCEnvInfo fvs bndr body
 275       (poly_vfn, poly_lfn) <- mkClosureFns info tyvars bndr body
 276
 277       vfn_var <- hoistExpr FSLIT("vfn") poly_vfn
 278       lfn_var <- hoistExpr FSLIT("lfn") poly_lfn
 279
 280       let (venv, lenv) = mkClosureEnvs info lc
 281
 282       let env_ty = cenv_vty info
 283
 284       pa_dict <- paDictOfType env_ty
 285
 286       arg_ty <- vectType (varType bndr)
 287       res_ty <- vectType (exprType $ deAnnotate body)
 288
 289       -- FIXME: move the functions to the top level
 290       mono_vfn <- applyToTypes (Var vfn_var) (mkTyVarTys tyvars)
 291       mono_lfn <- applyToTypes (Var lfn_var) (mkTyVarTys tyvars)
 292
 293       mk_clo <- builtin mkClosureVar
 294       mk_cloP <- builtin mkClosurePVar
 295
 296       let vclo = Var mk_clo  `mkTyApps` [arg_ty, res_ty, env_ty]
 297                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, venv]
 298
 299           lclo = Var mk_cloP `mkTyApps` [arg_ty, res_ty, env_ty]
 300                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, lenv]
 301
 302       return (vclo, lclo)
 303
 304
 305 data CEnvInfo = CEnvInfo {
 306                cenv_vars         :: [Var]
 307              , cenv_values       :: [(CoreExpr, CoreExpr)]
 308              , cenv_vty          :: Type
 309              , cenv_lty          :: Type
 310              , cenv_repr_tycon   :: TyCon
 311              , cenv_repr_tyargs  :: [Type]
 312              , cenv_repr_datacon :: DataCon
 313              }
 314
 315 mkCEnvInfo :: VarSet -> Var -> CoreExprWithFVs -> VM CEnvInfo
 316 mkCEnvInfo fvs arg body
 317   = do
 318       locals <- readLEnv local_vars
 319       let
 320           (vars, vals) = unzip
 321                  [(var, val) | var      <- varSetElems fvs
 322                              , Just val <- [lookupVarEnv locals var]]
 323       vtys <- mapM (vectType . varType) vars
 324
 325       (vty, repr_tycon, repr_tyargs, repr_datacon) <- mk_env_ty vtys
 326       lty <- mkPArrayType vty
 327
 328       return $ CEnvInfo {
 329                  cenv_vars         = vars
 330                , cenv_values       = vals
 331                , cenv_vty          = vty
 332                , cenv_lty          = lty
 333                , cenv_repr_tycon   = repr_tycon
 334                , cenv_repr_tyargs  = repr_tyargs
 335                , cenv_repr_datacon = repr_datacon
 336                }
 337   where
 338     mk_env_ty [vty]
 339       = return (vty, error "absent cinfo_repr_tycon"
 340                    , error "absent cinfo_repr_tyargs"
 341                    , error "absent cinfo_repr_datacon")
 342
 343     mk_env_ty vtys
 344       = do
 345           let ty = mkCoreTupTy vtys
 346           (repr_tc, repr_tyargs) <- lookupPArrayFamInst ty
 347           let [repr_con] = tyConDataCons repr_tc
 348           return (ty, repr_tc, repr_tyargs, repr_con)
 349
 350
 351
 352 mkClosureEnvs :: CEnvInfo -> CoreExpr -> (CoreExpr, CoreExpr)
 353 mkClosureEnvs info lc
 354   | [] <- vals
 355   = (Var unitDataConId, mkApps (Var $ dataConWrapId (cenv_repr_datacon info))
 356                                [lc, Var unitDataConId])
 357
 358   | [(vval, lval)] <- vals
 359   = (vval, lval)
 360
 361   | otherwise
 362   = (mkCoreTup vvals, Var (dataConWrapId $ cenv_repr_datacon info)
 363                       `mkTyApps` cenv_repr_tyargs info
 364                       `mkApps`   (lc : lvals))
 365
 366   where
 367     vals = cenv_values info
 368     (vvals, lvals) = unzip vals
 369
 370 mkClosureFns :: CEnvInfo -> [TyVar] -> Var -> CoreExprWithFVs
 371              -> VM (CoreExpr, CoreExpr)
 372 mkClosureFns info tyvars arg body
 373   = closedV
 374   . abstractOverTyVars tyvars
 375   $ \mk_tlams ->
 376   do
 377     (vfn, lfn) <- mkClosureMonoFns info arg body
 378     return (mk_tlams vfn, mk_tlams lfn)
 379
 380 mkClosureMonoFns :: CEnvInfo -> Var -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 381 mkClosureMonoFns info arg body
 382   = do
 383       lc_bndr <- newLocalVar FSLIT("lc") intPrimTy
 384       (varg : vbndrs, larg : lbndrs, (vbody, lbody))
 385         <- vectBndrsIn (arg : cenv_vars info)
 386                        (vectExpr (Var lc_bndr) body)
 387
 388       venv_bndr <- newLocalVar FSLIT("env") vty
 389       lenv_bndr <- newLocalVar FSLIT("env") lty
 390
 391       let vcase = bind_venv (Var venv_bndr) vbody vbndrs
 392       lcase <- bind_lenv (Var lenv_bndr) lbody lc_bndr lbndrs
 393       return (mkLams [venv_bndr, varg] vcase, mkLams [lenv_bndr, larg] lcase)
 394   where
 395     vty = cenv_vty info
 396     lty = cenv_lty info
 397
 398     arity = length (cenv_vars info)
 399
 400     bind_venv venv vbody []      = vbody
 401     bind_venv venv vbody [vbndr] = Let (NonRec vbndr venv) vbody
 402     bind_venv venv vbody vbndrs
 403       = Case venv (mkWildId vty) (exprType vbody)
 404              [(DataAlt (tupleCon Boxed arity), vbndrs, vbody)]
 405
 406     bind_lenv lenv lbody lc_bndr [lbndr]
 407       = do
 408           lengthPA <- paMethod lengthPAVar vty
 409           return . Let (NonRec lbndr lenv)
 410                  $ Case (App lengthPA (Var lbndr))
 411                         lc_bndr
 412                         (exprType lbody)
 413                         [(DEFAULT, [], lbody)]
 414
 415     bind_lenv lenv lbody lc_bndr lbndrs
 416       = let scrut = unwrapFamInstScrut (cenv_repr_tycon info)
 417                                        (cenv_repr_tyargs info)
 418                                        lenv
 419             lbndrs' | null lbndrs = [mkWildId unitTy]
 420                     | otherwise   = lbndrs
 421         in
 422         return
 423       $ Case scrut
 424              (mkWildId (exprType scrut))
 425              (exprType lbody)
 426              [(DataAlt (cenv_repr_datacon info), lc_bndr : lbndrs', lbody)]
 427
 428 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 429 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 430 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 431