compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import DynFlags
   7 import HscTypes
   8
   9 import CoreLint             ( showPass, endPass )
  10 import CoreSyn
  11 import CoreUtils
  12 import CoreFVs
  13 import TyCon
  14 import Type
  15 import TypeRep
  16 import Var
  17 import VarEnv
  18 import Name                 ( mkSysTvName )
  19 import NameEnv
  20 import Id
  21
  22 import DsMonad hiding (mapAndUnzipM)
  23
  24 import PrelNames
  25
  26 import Outputable
  27 import FastString
  28 import Control.Monad        ( liftM, liftM2, mapAndUnzipM )
  29
  30 vectorise :: HscEnv -> ModGuts -> IO ModGuts
  31 vectorise hsc_env guts
  32   | not (Opt_Vectorise `dopt` dflags) = return guts
  33   | otherwise
  34   = do
  35       showPass dflags "Vectorisation"
  36       eps <- hscEPS hsc_env
  37       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  38       Just guts' <- initDs hsc_env (mg_module guts)
  39                                    (mg_rdr_env guts)
  40                                    (mg_types guts)
  41                                    (vectoriseModule info guts)
  42       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  43       return guts'
  44   where
  45     dflags = hsc_dflags hsc_env
  46
  47 -- ----------------------------------------------------------------------------
  48 -- Vectorisation monad
  49
  50 data Builtins = Builtins {
  51                   parrayTyCon      :: TyCon
  52                 , paTyCon          :: TyCon
  53                 , closureTyCon     :: TyCon
  54                 , mkClosureVar     :: Var
  55                 , applyClosureVar  :: Var
  56                 , mkClosurePVar    :: Var
  57                 , applyClosurePVar :: Var
  58                 , closurePAVar     :: Var
  59                 , lengthPAVar      :: Var
  60                 , replicatePAVar   :: Var
  61                 }
  62
  63 initBuiltins :: DsM Builtins
  64 initBuiltins
  65   = do
  66       parrayTyCon  <- dsLookupTyCon parrayTyConName
  67       paTyCon      <- dsLookupTyCon paTyConName
  68       closureTyCon <- dsLookupTyCon closureTyConName
  69
  70       mkClosureVar     <- dsLookupGlobalId mkClosureName
  71       applyClosureVar  <- dsLookupGlobalId applyClosureName
  72       mkClosurePVar    <- dsLookupGlobalId mkClosurePName
  73       applyClosurePVar <- dsLookupGlobalId applyClosurePName
  74       closurePAVar     <- dsLookupGlobalId closurePAName
  75       lengthPAVar      <- dsLookupGlobalId lengthPAName
  76       replicatePAVar   <- dsLookupGlobalId replicatePAName
  77
  78       return $ Builtins {
  79                  parrayTyCon      = parrayTyCon
  80                , paTyCon          = paTyCon
  81                , closureTyCon     = closureTyCon
  82                , mkClosureVar     = mkClosureVar
  83                , applyClosureVar  = applyClosureVar
  84                , mkClosurePVar    = mkClosurePVar
  85                , applyClosurePVar = applyClosurePVar
  86                , closurePAVar     = closurePAVar
  87                , lengthPAVar      = lengthPAVar
  88                , replicatePAVar   = replicatePAVar
  89                }
  90
  91 data GlobalEnv = GlobalEnv {
  92                   -- Mapping from global variables to their vectorised versions.
  93                   --
  94                   global_vars :: VarEnv CoreExpr
  95
  96                   -- Exported variables which have a vectorised version
  97                   --
  98                 , global_exported_vars :: VarEnv (Var, Var)
  99
 100                   -- Mapping from TyCons to their vectorised versions.
 101                   -- TyCons which do not have to be vectorised are mapped to
 102                   -- themselves.
 103                   --
 104                 , global_tycons :: NameEnv TyCon
 105
 106                   -- Mapping from TyCons to their PA dictionaries
 107                   --
 108                 , global_tycon_pa :: NameEnv CoreExpr
 109                 }
 110
 111 data LocalEnv = LocalEnv {
 112                  -- Mapping from local variables to their vectorised and
 113                  -- lifted versions
 114                  --
 115                  local_vars :: VarEnv (CoreExpr, CoreExpr)
 116
 117                  -- Mapping from tyvars to their PA dictionaries
 118                , local_tyvar_pa :: VarEnv CoreExpr
 119                }
 120
 121
 122 initGlobalEnv :: VectInfo -> GlobalEnv
 123 initGlobalEnv info
 124   = GlobalEnv {
 125       global_vars          = mapVarEnv  (Var . snd) $ vectInfoCCVar   info
 126     , global_exported_vars = emptyVarEnv
 127     , global_tycons        = mapNameEnv snd $ vectInfoCCTyCon info
 128     , global_tycon_pa      = emptyNameEnv
 129     }
 130
 131 emptyLocalEnv = LocalEnv {
 132                    local_vars     = emptyVarEnv
 133                  , local_tyvar_pa = emptyVarEnv
 134                  }
 135
 136 -- FIXME
 137 updVectInfo :: GlobalEnv -> ModGuts -> ModGuts
 138 updVectInfo env guts = guts { mg_vect_info = info' }
 139   where
 140     info' = info {
 141               vectInfoCCVar   = global_exported_vars env
 142             , vectInfoCCTyCon = tc_env
 143             }
 144
 145     info  = mg_vect_info guts
 146     tyenv = mg_types guts
 147
 148     tc_env = mkNameEnv [(tc_name, (tc,tc')) | tc <- typeEnvTyCons tyenv
 149                                             , let tc_name = tyConName tc
 150                                             , Just tc' <- [lookupNameEnv (global_tycons env) tc_name]]
 151
 152 data VResult a = Yes GlobalEnv LocalEnv a | No
 153
 154 newtype VM a = VM { runVM :: Builtins -> GlobalEnv -> LocalEnv -> DsM (VResult a) }
 155
 156 instance Monad VM where
 157   return x   = VM $ \bi genv lenv -> return (Yes genv lenv x)
 158   VM p >>= f = VM $ \bi genv lenv -> do
 159                                       r <- p bi genv lenv
 160                                       case r of
 161                                         Yes genv' lenv' x -> runVM (f x) bi genv' lenv'
 162                                         No                -> return No
 163
 164 noV :: VM a
 165 noV = VM $ \_ _ _ -> return No
 166
 167 tryV :: VM a -> VM (Maybe a)
 168 tryV (VM p) = VM $ \bi genv lenv ->
 169   do
 170     r <- p bi genv lenv
 171     case r of
 172       Yes genv' lenv' x -> return (Yes genv' lenv' (Just x))
 173       No                -> return (Yes genv  lenv  Nothing)
 174
 175 maybeV :: VM (Maybe a) -> VM a
 176 maybeV p = maybe noV return =<< p
 177
 178 orElseV :: VM a -> VM a -> VM a
 179 orElseV p q = maybe q return =<< tryV p
 180
 181 localV :: VM a -> VM a
 182 localV p = do
 183              env <- readLEnv id
 184              x <- p
 185              setLEnv env
 186              return x
 187
 188 liftDs :: DsM a -> VM a
 189 liftDs p = VM $ \bi genv lenv -> do { x <- p; return (Yes genv lenv x) }
 190
 191 builtin :: (Builtins -> a) -> VM a
 192 builtin f = VM $ \bi genv lenv -> return (Yes genv lenv (f bi))
 193
 194 readGEnv :: (GlobalEnv -> a) -> VM a
 195 readGEnv f = VM $ \bi genv lenv -> return (Yes genv lenv (f genv))
 196
 197 setGEnv :: GlobalEnv -> VM ()
 198 setGEnv genv = VM $ \_ _ lenv -> return (Yes genv lenv ())
 199
 200 updGEnv :: (GlobalEnv -> GlobalEnv) -> VM ()
 201 updGEnv f = VM $ \_ genv lenv -> return (Yes (f genv) lenv ())
 202
 203 readLEnv :: (LocalEnv -> a) -> VM a
 204 readLEnv f = VM $ \bi genv lenv -> return (Yes genv lenv (f lenv))
 205
 206 setLEnv :: LocalEnv -> VM ()
 207 setLEnv lenv = VM $ \_ genv _ -> return (Yes genv lenv ())
 208
 209 updLEnv :: (LocalEnv -> LocalEnv) -> VM ()
 210 updLEnv f = VM $ \_ genv lenv -> return (Yes genv (f lenv) ())
 211
 212 newLocalVar :: FastString -> Type -> VM Var
 213 newLocalVar fs ty
 214   = do
 215       u <- liftDs newUnique
 216       return $ mkSysLocal fs u ty
 217
 218 newTyVar :: FastString -> Kind -> VM Var
 219 newTyVar fs k
 220   = do
 221       u <- liftDs newUnique
 222       return $ mkTyVar (mkSysTvName u fs) k
 223
 224 lookupTyCon :: TyCon -> VM (Maybe TyCon)
 225 lookupTyCon tc = readGEnv $ \env -> lookupNameEnv (global_tycons env) (tyConName tc)
 226
 227
 228 extendTyVarPA :: Var -> CoreExpr -> VM ()
 229 extendTyVarPA tv pa = updLEnv $ \env -> env { local_tyvar_pa = extendVarEnv (local_tyvar_pa env) tv pa }
 230
 231 -- ----------------------------------------------------------------------------
 232 -- Bindings
 233
 234 vectoriseModule :: VectInfo -> ModGuts -> DsM ModGuts
 235 vectoriseModule info guts
 236   = do
 237       builtins <- initBuiltins
 238       r <- runVM (vectModule guts) builtins (initGlobalEnv info) emptyLocalEnv
 239       case r of
 240         Yes genv _ guts' -> return $ updVectInfo genv guts'
 241         No               -> return guts
 242
 243 vectModule :: ModGuts -> VM ModGuts
 244 vectModule guts = return guts
 245
 246
 247
 248 vectBndr :: Var -> VM (Var, Var)
 249 vectBndr v
 250   = do
 251       vty <- vectType (idType v)
 252       lty <- mkPArrayTy vty
 253       let vv = v `Id.setIdType` vty
 254           lv = v `Id.setIdType` lty
 255       updLEnv (mapTo vv lv)
 256       return (vv, lv)
 257   where
 258     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 259
 260 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 261 vectBndrIn v p
 262   = localV
 263   $ do
 264       (vv, lv) <- vectBndr v
 265       x <- p
 266       return (vv, lv, x)
 267
 268 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 269 vectBndrsIn vs p
 270   = localV
 271   $ do
 272       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 273       x <- p
 274       return (vvs, lvs, x)
 275
 276 -- ----------------------------------------------------------------------------
 277 -- Expressions
 278
 279 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
 280 replicateP expr len
 281   = do
 282       pa  <- paOfType ty
 283       rep <- builtin replicatePAVar
 284       return $ mkApps (Var rep) [Type ty, pa, expr, len]
 285   where
 286     ty = exprType expr
 287
 288 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 289 capply (vfn, lfn) (varg, larg)
 290   = do
 291       apply  <- builtin applyClosureVar
 292       applyP <- builtin applyClosurePVar
 293       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 294               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 295   where
 296     fn_ty            = exprType vfn
 297     (arg_ty, res_ty) = splitClosureTy fn_ty
 298
 299 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 300 vectVar lc v = local v `orElseV` global v
 301   where
 302     local  v = maybeV (readLEnv $ \env -> lookupVarEnv (local_vars env) v)
 303     global v = do
 304                  vexpr <- maybeV (readGEnv $ \env -> lookupVarEnv (global_vars env) v)
 305                  lexpr <- replicateP vexpr lc
 306                  return (vexpr, lexpr)
 307
 308 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 309 vectExpr lc (_, AnnType ty)
 310   = do
 311       vty <- vectType ty
 312       return (Type vty, Type vty)
 313 vectExpr lc (_, AnnVar v)   = vectVar lc v
 314 vectExpr lc (_, AnnLit lit)
 315   = do
 316       let vexpr = Lit lit
 317       lexpr <- replicateP vexpr lc
 318       return (vexpr, lexpr)
 319 vectExpr lc (_, AnnNote note expr)
 320   = do
 321       (vexpr, lexpr) <- vectExpr lc expr
 322       return (Note note vexpr, Note note lexpr)
 323 vectExpr lc (_, AnnApp fn arg)
 324   = do
 325       fn'  <- vectExpr lc fn
 326       arg' <- vectExpr lc arg
 327       capply fn' arg'
 328 vectExpr lc (_, AnnCase expr bndr ty alts)
 329   = panic "vectExpr: case"
 330 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 331   = do
 332       (vrhs, lrhs) <- vectExpr lc rhs
 333       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 334       return (Let (NonRec vbndr vrhs) vbody,
 335               Let (NonRec lbndr lrhs) lbody)
 336 vectExpr lc (_, AnnLet (AnnRec prs) body)
 337   = do
 338       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 339       return (Let (Rec (zip vbndrs vrhss)) vbody,
 340               Let (Rec (zip lbndrs lrhss)) lbody)
 341   where
 342     (bndrs, rhss) = unzip prs
 343
 344     vect = do
 345              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 346              (vbody, lbody) <- vectExpr lc body
 347              return (vrhss, vbody, lrhss, lbody)
 348 vectExpr lc (_, AnnLam bndr body)
 349   | isTyVar bndr
 350   = do
 351       pa_ty          <- paArgType' (TyVarTy bndr) (tyVarKind bndr)
 352       pa_var         <- newLocalVar FSLIT("dPA") pa_ty
 353       (vbody, lbody) <- localV
 354                       $ do
 355                           extendTyVarPA bndr (Var pa_var)
 356                           -- FIXME: what about shadowing here (bndr in lc)?
 357                           vectExpr lc body
 358       return (mkLams [bndr, pa_var] vbody,
 359               mkLams [bndr, pa_var] lbody)
 360
 361 -- ----------------------------------------------------------------------------
 362 -- PA dictionaries
 363
 364 paArgType :: Type -> Kind -> VM (Maybe Type)
 365 paArgType ty k
 366   | Just k' <- kindView k = paArgType ty k'
 367
 368 -- Here, we assume that for a kind (k1 -> k2) to be valid, k1 and k2 can only
 369 -- be made up of * and (->), i.e., they can't be coercion kinds or #.
 370 paArgType ty (FunTy k1 k2)
 371   = do
 372       tv  <- newTyVar FSLIT("a") k1
 373       ty1 <- paArgType' (TyVarTy tv) k1
 374       ty2 <- paArgType' (AppTy ty (TyVarTy tv)) k2
 375       return . Just $ ForAllTy tv (FunTy ty1 ty2)
 376
 377 paArgType ty k
 378   | isLiftedTypeKind k
 379   = do
 380       tc <- builtin paTyCon
 381       return . Just $ TyConApp tc [ty]
 382
 383   | otherwise
 384   = return Nothing
 385
 386 paArgType' :: Type -> Kind -> VM Type
 387 paArgType' ty k
 388   = do
 389       r <- paArgType ty k
 390       case r of
 391         Just ty' -> return ty'
 392         Nothing  -> pprPanic "paArgType'" (ppr ty)
 393
 394 paOfTyCon :: TyCon -> VM CoreExpr
 395 -- FIXME: just for now
 396 paOfTyCon tc = maybeV (readGEnv $ \env -> lookupNameEnv (global_tycon_pa env) (tyConName tc))
 397
 398 paOfType :: Type -> VM CoreExpr
 399 paOfType ty | Just ty' <- coreView ty = paOfType ty'
 400
 401 paOfType (TyVarTy tv) = maybeV (readLEnv $ \env -> lookupVarEnv (local_tyvar_pa env) tv)
 402 paOfType (AppTy ty1 ty2)
 403   = do
 404       e1 <- paOfType ty1
 405       e2 <- paOfType ty2
 406       return $ mkApps e1 [Type ty2, e2]
 407 paOfType (TyConApp tc tys)
 408   = do
 409       e  <- paOfTyCon tc
 410       es <- mapM paOfType tys
 411       return $ mkApps e [arg | (t,e) <- zip tys es, arg <- [Type t, e]]
 412 paOfType (FunTy ty1 ty2) = paOfType (TyConApp funTyCon [ty1,ty2])
 413 paOfType t@(ForAllTy tv ty) = pprPanic "paOfType:" (ppr t)
 414 paOfType ty = pprPanic "paOfType:" (ppr ty)
 415
 416
 417
 418 -- ----------------------------------------------------------------------------
 419 -- Types
 420
 421 vectTyCon :: TyCon -> VM TyCon
 422 vectTyCon tc
 423   | isFunTyCon tc        = builtin closureTyCon
 424   | isBoxedTupleTyCon tc = return tc
 425   | isUnLiftedTyCon tc   = return tc
 426   | otherwise = do
 427                   r <- lookupTyCon tc
 428                   case r of
 429                     Just tc' -> return tc'
 430
 431                     -- FIXME: just for now
 432                     Nothing  -> pprTrace "ccTyCon:" (ppr tc) $ return tc
 433
 434 vectType :: Type -> VM Type
 435 vectType ty | Just ty' <- coreView ty = vectType ty
 436 vectType (TyVarTy tv) = return $ TyVarTy tv
 437 vectType (AppTy ty1 ty2) = liftM2 AppTy (vectType ty1) (vectType ty2)
 438 vectType (TyConApp tc tys) = liftM2 TyConApp (vectTyCon tc) (mapM vectType tys)
 439 vectType (FunTy ty1 ty2)   = liftM2 TyConApp (builtin closureTyCon)
 440                                              (mapM vectType [ty1,ty2])
 441 vectType (ForAllTy tv ty)
 442   = do
 443       r   <- paArgType (TyVarTy tv) (tyVarKind tv)
 444       ty' <- vectType ty
 445       return . ForAllTy tv $ case r of { Just paty -> FunTy paty ty'; Nothing -> ty' }
 446
 447 vectType ty = pprPanic "vectType:" (ppr ty)
 448
 449 isClosureTyCon :: TyCon -> Bool
 450 isClosureTyCon tc = tyConUnique tc == closureTyConKey
 451
 452 splitClosureTy :: Type -> (Type, Type)
 453 splitClosureTy ty
 454   | Just (tc, [arg_ty, res_ty]) <- splitTyConApp_maybe ty
 455   , isClosureTyCon tc
 456   = (arg_ty, res_ty)
 457
 458   | otherwise = pprPanic "splitClosureTy" (ppr ty)
 459
 460 mkPArrayTy :: Type -> VM Type
 461 mkPArrayTy ty = do
 462                   tc <- builtin parrayTyCon
 463                   return $ TyConApp tc [ty]
 464