compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8 import VectType
   9 import VectCore
  10
  11 import DynFlags
  12 import HscTypes
  13
  14 import CoreLint             ( showPass, endPass )
  15 import CoreSyn
  16 import CoreUtils
  17 import CoreFVs
  18 import SimplMonad           ( SimplCount, zeroSimplCount )
  19 import Rules                ( RuleBase )
  20 import DataCon
  21 import TyCon
  22 import Type
  23 import FamInstEnv           ( extendFamInstEnvList )
  24 import InstEnv              ( extendInstEnvList )
  25 import Var
  26 import VarEnv
  27 import VarSet
  28 import Name                 ( mkSysTvName, getName )
  29 import NameEnv
  30 import Id
  31 import MkId                 ( unwrapFamInstScrut )
  32 import OccName
  33
  34 import DsMonad hiding (mapAndUnzipM)
  35 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  36
  37 import Literal              ( Literal )
  38 import PrelNames
  39 import TysWiredIn
  40 import TysPrim              ( intPrimTy )
  41 import BasicTypes           ( Boxity(..) )
  42
  43 import Outputable
  44 import FastString
  45 import Control.Monad        ( liftM, liftM2, zipWithM, mapAndUnzipM )
  46
  47 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  48           -> IO (SimplCount, ModGuts)
  49 vectorise hsc_env _ _ guts
  50   = do
  51       showPass dflags "Vectorisation"
  52       eps <- hscEPS hsc_env
  53       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  54       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  55       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  56       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  57   where
  58     dflags = hsc_dflags hsc_env
  59
  60 vectModule :: ModGuts -> VM ModGuts
  61 vectModule guts
  62   = do
  63       (types', fam_insts, pa_insts) <- vectTypeEnv (mg_types guts)
  64
  65       let insts         = map painstInstance pa_insts
  66           fam_inst_env' = extendFamInstEnvList (mg_fam_inst_env guts) fam_insts
  67           inst_env'     = extendInstEnvList (mg_inst_env guts) insts
  68       updGEnv (setInstEnvs inst_env' fam_inst_env')
  69
  70       dicts  <- mapM buildPADict pa_insts
  71       binds' <- mapM vectTopBind (mg_binds guts)
  72       return $ guts { mg_types        = types'
  73                     , mg_binds        = Rec (concat dicts) : binds'
  74                     , mg_inst_env     = inst_env'
  75                     , mg_fam_inst_env = fam_inst_env'
  76                     , mg_insts        = mg_insts guts ++ insts
  77                     , mg_fam_insts    = mg_fam_insts guts ++ fam_insts
  78                     }
  79
  80 vectTopBind :: CoreBind -> VM CoreBind
  81 vectTopBind b@(NonRec var expr)
  82   = do
  83       var'  <- vectTopBinder var
  84       expr' <- vectTopRhs var expr
  85       hs    <- takeHoisted
  86       return . Rec $ (var, expr) : (var', expr') : hs
  87   `orElseV`
  88     return b
  89
  90 vectTopBind b@(Rec bs)
  91   = do
  92       vars'  <- mapM vectTopBinder vars
  93       exprs' <- zipWithM vectTopRhs vars exprs
  94       hs     <- takeHoisted
  95       return . Rec $ bs ++ zip vars' exprs' ++ hs
  96   `orElseV`
  97     return b
  98   where
  99     (vars, exprs) = unzip bs
 100
 101 vectTopBinder :: Var -> VM Var
 102 vectTopBinder var
 103   = do
 104       vty  <- vectType (idType var)
 105       var' <- cloneId mkVectOcc var vty
 106       defGlobalVar var var'
 107       return var'
 108
 109 vectTopRhs :: Var -> CoreExpr -> VM CoreExpr
 110 vectTopRhs var expr
 111   = do
 112       closedV . liftM vectorised
 113               . inBind var
 114               $ vectPolyExpr (freeVars expr)
 115
 116 -- ----------------------------------------------------------------------------
 117 -- Bindings
 118
 119 vectBndr :: Var -> VM VVar
 120 vectBndr v
 121   = do
 122       vty <- vectType (idType v)
 123       lty <- mkPArrayType vty
 124       let vv = v `Id.setIdType` vty
 125           lv = v `Id.setIdType` lty
 126       updLEnv (mapTo vv lv)
 127       return (vv, lv)
 128   where
 129     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (vv, lv) }
 130
 131 vectBndrIn :: Var -> VM a -> VM (VVar, a)
 132 vectBndrIn v p
 133   = localV
 134   $ do
 135       vv <- vectBndr v
 136       x <- p
 137       return (vv, x)
 138
 139 vectBndrsIn :: [Var] -> VM a -> VM ([VVar], a)
 140 vectBndrsIn vs p
 141   = localV
 142   $ do
 143       vvs <- mapM vectBndr vs
 144       x <- p
 145       return (vvs, x)
 146
 147 -- ----------------------------------------------------------------------------
 148 -- Expressions
 149
 150 vectVar :: Var -> VM VExpr
 151 vectVar v
 152   = do
 153       r <- lookupVar v
 154       case r of
 155         Local (vv,lv) -> return (Var vv, Var lv)
 156         Global vv     -> do
 157                            let vexpr = Var vv
 158                            lexpr <- liftPA vexpr
 159                            return (vexpr, lexpr)
 160
 161 vectPolyVar :: Var -> [Type] -> VM VExpr
 162 vectPolyVar v tys
 163   = do
 164       vtys <- mapM vectType tys
 165       r <- lookupVar v
 166       case r of
 167         Local (vv, lv) -> liftM2 (,) (polyApply (Var vv) vtys)
 168                                      (polyApply (Var lv) vtys)
 169         Global poly    -> do
 170                             vexpr <- polyApply (Var poly) vtys
 171                             lexpr <- liftPA vexpr
 172                             return (vexpr, lexpr)
 173
 174 vectLiteral :: Literal -> VM VExpr
 175 vectLiteral lit
 176   = do
 177       lexpr <- liftPA (Lit lit)
 178       return (Lit lit, lexpr)
 179
 180 vectPolyExpr :: CoreExprWithFVs -> VM VExpr
 181 vectPolyExpr expr
 182   = polyAbstract tvs $ \abstract ->
 183     do
 184       mono' <- vectExpr mono
 185       return $ mapVect abstract mono'
 186   where
 187     (tvs, mono) = collectAnnTypeBinders expr
 188
 189 vectExpr :: CoreExprWithFVs -> VM VExpr
 190 vectExpr (_, AnnType ty)
 191   = liftM vType (vectType ty)
 192
 193 vectExpr (_, AnnVar v) = vectVar v
 194
 195 vectExpr (_, AnnLit lit) = vectLiteral lit
 196
 197 vectExpr (_, AnnNote note expr)
 198   = liftM (vNote note) (vectExpr expr)
 199
 200 vectExpr e@(_, AnnApp _ arg)
 201   | isAnnTypeArg arg
 202   = vectTyAppExpr fn tys
 203   where
 204     (fn, tys) = collectAnnTypeArgs e
 205
 206 vectExpr (_, AnnApp fn arg)
 207   = do
 208       fn'  <- vectExpr fn
 209       arg' <- vectExpr arg
 210       mkClosureApp fn' arg'
 211
 212 vectExpr (_, AnnCase expr bndr ty alts)
 213   = panic "vectExpr: case"
 214
 215 vectExpr (_, AnnLet (AnnNonRec bndr rhs) body)
 216   = do
 217       vrhs <- localV . inBind bndr $ vectPolyExpr rhs
 218       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 219       return $ vLet (vNonRec vbndr vrhs) vbody
 220
 221 vectExpr (_, AnnLet (AnnRec bs) body)
 222   = do
 223       (vbndrs, (vrhss, vbody)) <- vectBndrsIn bndrs
 224                                 $ liftM2 (,)
 225                                   (zipWithM vect_rhs bndrs rhss)
 226                                   (vectPolyExpr body)
 227       return $ vLet (vRec vbndrs vrhss) vbody
 228   where
 229     (bndrs, rhss) = unzip bs
 230
 231     vect_rhs bndr rhs = localV
 232                       . inBind bndr
 233                       $ vectExpr rhs
 234
 235 vectExpr e@(fvs, AnnLam bndr _)
 236   | not (isId bndr) = pprPanic "vectExpr" (ppr $ deAnnotate e)
 237   | otherwise = vectLam fvs bs body
 238   where
 239     (bs,body) = collectAnnValBinders e
 240
 241 vectLam :: VarSet -> [Var] -> CoreExprWithFVs -> VM VExpr
 242 vectLam fvs bs body
 243   = do
 244       tyvars <- localTyVars
 245       (vs, vvs) <- readLEnv $ \env ->
 246                    unzip [(var, vv) | var <- varSetElems fvs
 247                                     , Just vv <- [lookupVarEnv (local_vars env) var]]
 248
 249       arg_tys <- mapM (vectType . idType) bs
 250       res_ty  <- vectType (exprType $ deAnnotate body)
 251
 252       buildClosures tyvars vvs arg_tys res_ty
 253         . hoistPolyVExpr tyvars
 254         $ do
 255             lc <- builtin liftingContext
 256             (vbndrs, vbody) <- vectBndrsIn (vs ++ bs)
 257                                            (vectExpr body)
 258             return $ vLams lc vbndrs vbody
 259
 260 vectTyAppExpr :: CoreExprWithFVs -> [Type] -> VM VExpr
 261 vectTyAppExpr (_, AnnVar v) tys = vectPolyVar v tys
 262 vectTyAppExpr e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 263