compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8
   9 import DynFlags
  10 import HscTypes
  11
  12 import CoreLint             ( showPass, endPass )
  13 import CoreSyn
  14 import CoreUtils
  15 import CoreFVs
  16 import SimplMonad           ( SimplCount, zeroSimplCount )
  17 import Rules                ( RuleBase )
  18 import DataCon
  19 import TyCon
  20 import Type
  21 import TypeRep
  22 import Var
  23 import VarEnv
  24 import VarSet
  25 import Name                 ( mkSysTvName, getName )
  26 import NameEnv
  27 import Id
  28 import MkId                 ( unwrapFamInstScrut )
  29 import OccName
  30
  31 import DsMonad hiding (mapAndUnzipM)
  32 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  33
  34 import PrelNames
  35 import TysWiredIn
  36 import BasicTypes           ( Boxity(..) )
  37
  38 import Outputable
  39 import FastString
  40 import Control.Monad        ( liftM, liftM2, mapAndUnzipM, zipWithM_ )
  41 import Data.Maybe           ( maybeToList )
  42
  43 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  44           -> IO (SimplCount, ModGuts)
  45 vectorise hsc_env _ _ guts
  46   = do
  47       showPass dflags "Vectorisation"
  48       eps <- hscEPS hsc_env
  49       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  50       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  51       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  52       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  53   where
  54     dflags = hsc_dflags hsc_env
  55
  56 vectModule :: ModGuts -> VM ModGuts
  57 vectModule guts
  58   = do
  59       binds' <- mapM vectTopBind (mg_binds guts)
  60       return $ guts { mg_binds = binds' }
  61
  62 vectTopBind :: CoreBind -> VM CoreBind
  63 vectTopBind b@(NonRec var expr)
  64   = do
  65       var'  <- vectTopBinder var
  66       expr' <- vectTopRhs expr
  67       hs    <- takeHoisted
  68       return . Rec $ (var, expr) : (var', expr') : hs
  69   `orElseV`
  70     return b
  71
  72 vectTopBind b@(Rec bs)
  73   = do
  74       vars'  <- mapM vectTopBinder vars
  75       exprs' <- mapM vectTopRhs exprs
  76       hs     <- takeHoisted
  77       return . Rec $ bs ++ zip vars' exprs' ++ hs
  78   `orElseV`
  79     return b
  80   where
  81     (vars, exprs) = unzip bs
  82
  83 vectTopBinder :: Var -> VM Var
  84 vectTopBinder var
  85   = do
  86       vty <- liftM (mkForAllTys tyvars) $ vectType mono_ty
  87       name <- cloneName mkVectOcc (getName var)
  88       let var' | isExportedId var = Id.mkExportedLocalId name vty
  89                | otherwise        = Id.mkLocalId         name vty
  90       defGlobalVar var var'
  91       return var'
  92   where
  93     (tyvars, mono_ty) = splitForAllTys (idType var)
  94
  95 vectTopRhs :: CoreExpr -> VM CoreExpr
  96 vectTopRhs = liftM fst . closedV . vectPolyExpr (panic "Empty lifting context") . freeVars
  97
  98 -- ----------------------------------------------------------------------------
  99 -- Bindings
 100
 101 vectBndr :: Var -> VM (Var, Var)
 102 vectBndr v
 103   = do
 104       vty <- vectType (idType v)
 105       lty <- mkPArrayType vty
 106       let vv = v `Id.setIdType` vty
 107           lv = v `Id.setIdType` lty
 108       updLEnv (mapTo vv lv)
 109       return (vv, lv)
 110   where
 111     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 112
 113 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 114 vectBndrIn v p
 115   = localV
 116   $ do
 117       (vv, lv) <- vectBndr v
 118       x <- p
 119       return (vv, lv, x)
 120
 121 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 122 vectBndrsIn vs p
 123   = localV
 124   $ do
 125       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 126       x <- p
 127       return (vvs, lvs, x)
 128
 129 -- ----------------------------------------------------------------------------
 130 -- Expressions
 131
 132 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
 133 replicateP expr len
 134   = do
 135       dict <- paDictOfType ty
 136       rep  <- builtin replicatePAVar
 137       return $ mkApps (Var rep) [Type ty, dict, expr, len]
 138   where
 139     ty = exprType expr
 140
 141 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 142 capply (vfn, lfn) (varg, larg)
 143   = do
 144       apply  <- builtin applyClosureVar
 145       applyP <- builtin applyClosurePVar
 146       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 147               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 148   where
 149     fn_ty            = exprType vfn
 150     (arg_ty, res_ty) = splitClosureTy fn_ty
 151
 152 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 153 vectVar lc v
 154   = do
 155       r <- lookupVar v
 156       case r of
 157         Local es     -> return es
 158         Global vexpr -> do
 159                           lexpr <- replicateP vexpr lc
 160                           return (vexpr, lexpr)
 161
 162 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 163 vectPolyVar lc v tys
 164   = do
 165       r <- lookupVar v
 166       case r of
 167         Local (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 168         Global poly          -> do
 169                                   vexpr <- mk_app poly
 170                                   lexpr <- replicateP vexpr lc
 171                                   return (vexpr, lexpr)
 172   where
 173     mk_app e = applyToTypes e =<< mapM vectType tys
 174
 175 abstractOverTyVars :: [TyVar] -> ((CoreExpr -> CoreExpr) -> VM a) -> VM a
 176 abstractOverTyVars tvs p
 177   = do
 178       mdicts <- mapM mk_dict_var tvs
 179       zipWithM_ (\tv -> maybe (deleteTyVarPA tv) (extendTyVarPA tv . Var)) tvs mdicts
 180       p (mk_lams mdicts)
 181   where
 182     mk_dict_var tv = do
 183                        r <- paDictArgType tv
 184                        case r of
 185                          Just ty -> liftM Just (newLocalVar FSLIT("dPA") ty)
 186                          Nothing -> return Nothing
 187
 188     mk_lams mdicts = mkLams [arg | (tv, mdict) <- zip tvs mdicts
 189                                  , arg <- tv : maybeToList mdict]
 190
 191 applyToTypes :: CoreExpr -> [Type] -> VM CoreExpr
 192 applyToTypes expr tys
 193   = do
 194       dicts <- mapM paDictOfType tys
 195       return $ mkApps expr [arg | (ty, dict) <- zip tys dicts
 196                                 , arg <- [Type ty, dict]]
 197
 198
 199 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 200 vectPolyExpr lc expr
 201   = localV
 202   . abstractOverTyVars tvs $ \mk_lams ->
 203     -- FIXME: shadowing (tvs in lc)
 204     do
 205       (vmono, lmono) <- vectExpr lc mono
 206       return $ (mk_lams vmono, mk_lams lmono)
 207   where
 208     (tvs, mono) = collectAnnTypeBinders expr
 209
 210 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 211 vectExpr lc (_, AnnType ty)
 212   = do
 213       vty <- vectType ty
 214       return (Type vty, Type vty)
 215
 216 vectExpr lc (_, AnnVar v)   = vectVar lc v
 217
 218 vectExpr lc (_, AnnLit lit)
 219   = do
 220       let vexpr = Lit lit
 221       lexpr <- replicateP vexpr lc
 222       return (vexpr, lexpr)
 223
 224 vectExpr lc (_, AnnNote note expr)
 225   = do
 226       (vexpr, lexpr) <- vectExpr lc expr
 227       return (Note note vexpr, Note note lexpr)
 228
 229 vectExpr lc e@(_, AnnApp _ arg)
 230   | isAnnTypeArg arg
 231   = vectTyAppExpr lc fn tys
 232   where
 233     (fn, tys) = collectAnnTypeArgs e
 234
 235 vectExpr lc (_, AnnApp fn arg)
 236   = do
 237       fn'  <- vectExpr lc fn
 238       arg' <- vectExpr lc arg
 239       capply fn' arg'
 240
 241 vectExpr lc (_, AnnCase expr bndr ty alts)
 242   = panic "vectExpr: case"
 243
 244 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 245   = do
 246       (vrhs, lrhs) <- vectPolyExpr lc rhs
 247       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 248       return (Let (NonRec vbndr vrhs) vbody,
 249               Let (NonRec lbndr lrhs) lbody)
 250
 251 vectExpr lc (_, AnnLet (AnnRec prs) body)
 252   = do
 253       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 254       return (Let (Rec (zip vbndrs vrhss)) vbody,
 255               Let (Rec (zip lbndrs lrhss)) lbody)
 256   where
 257     (bndrs, rhss) = unzip prs
 258
 259     vect = do
 260              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 261              (vbody, lbody) <- vectPolyExpr lc body
 262              return (vrhss, vbody, lrhss, lbody)
 263
 264 vectExpr lc e@(_, AnnLam bndr body)
 265   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 266
 267 vectExpr lc (fvs, AnnLam bndr body)
 268   = do
 269       let tyvars = filter isTyVar (varSetElems fvs)
 270       info <- mkCEnvInfo fvs bndr body
 271       (poly_vfn, poly_lfn) <- mkClosureFns info tyvars bndr body
 272
 273       vfn_var <- hoistExpr FSLIT("vfn") poly_vfn
 274       lfn_var <- hoistExpr FSLIT("lfn") poly_lfn
 275
 276       let (venv, lenv) = mkClosureEnvs info lc
 277
 278       let env_ty = cenv_vty info
 279
 280       pa_dict <- paDictOfType env_ty
 281
 282       arg_ty <- vectType (varType bndr)
 283       res_ty <- vectType (exprType $ deAnnotate body)
 284
 285       -- FIXME: move the functions to the top level
 286       mono_vfn <- applyToTypes (Var vfn_var) (map TyVarTy tyvars)
 287       mono_lfn <- applyToTypes (Var lfn_var) (map TyVarTy tyvars)
 288
 289       mk_clo <- builtin mkClosureVar
 290       mk_cloP <- builtin mkClosurePVar
 291
 292       let vclo = Var mk_clo  `mkTyApps` [arg_ty, res_ty, env_ty]
 293                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, venv]
 294
 295           lclo = Var mk_cloP `mkTyApps` [arg_ty, res_ty, env_ty]
 296                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, lenv]
 297
 298       return (vclo, lclo)
 299
 300
 301 data CEnvInfo = CEnvInfo {
 302                cenv_vars         :: [Var]
 303              , cenv_values       :: [(CoreExpr, CoreExpr)]
 304              , cenv_vty          :: Type
 305              , cenv_lty          :: Type
 306              , cenv_repr_tycon   :: TyCon
 307              , cenv_repr_tyargs  :: [Type]
 308              , cenv_repr_datacon :: DataCon
 309              }
 310
 311 mkCEnvInfo :: VarSet -> Var -> CoreExprWithFVs -> VM CEnvInfo
 312 mkCEnvInfo fvs arg body
 313   = do
 314       locals <- readLEnv local_vars
 315       let
 316           (vars, vals) = unzip
 317                  [(var, val) | var      <- varSetElems fvs
 318                              , Just val <- [lookupVarEnv locals var]]
 319       vtys <- mapM (vectType . varType) vars
 320
 321       (vty, repr_tycon, repr_tyargs, repr_datacon) <- mk_env_ty vtys
 322       lty <- mkPArrayType vty
 323
 324       return $ CEnvInfo {
 325                  cenv_vars         = vars
 326                , cenv_values       = vals
 327                , cenv_vty          = vty
 328                , cenv_lty          = lty
 329                , cenv_repr_tycon   = repr_tycon
 330                , cenv_repr_tyargs  = repr_tyargs
 331                , cenv_repr_datacon = repr_datacon
 332                }
 333   where
 334     mk_env_ty [vty]
 335       = return (vty, error "absent cinfo_repr_tycon"
 336                    , error "absent cinfo_repr_tyargs"
 337                    , error "absent cinfo_repr_datacon")
 338
 339     mk_env_ty vtys
 340       = do
 341           let ty = mkCoreTupTy vtys
 342           (repr_tc, repr_tyargs) <- lookupPArrayFamInst ty
 343           let [repr_con] = tyConDataCons repr_tc
 344           return (ty, repr_tc, repr_tyargs, repr_con)
 345
 346
 347
 348 mkClosureEnvs :: CEnvInfo -> CoreExpr -> (CoreExpr, CoreExpr)
 349 mkClosureEnvs info lc
 350   | [] <- vals
 351   = (Var unitDataConId, mkApps (Var $ dataConWrapId (cenv_repr_datacon info))
 352                                [lc, Var unitDataConId])
 353
 354   | [(vval, lval)] <- vals
 355   = (vval, lval)
 356
 357   | otherwise
 358   = (mkCoreTup vvals, Var (dataConWrapId $ cenv_repr_datacon info)
 359                       `mkTyApps` cenv_repr_tyargs info
 360                       `mkApps`   (lc : lvals))
 361
 362   where
 363     vals = cenv_values info
 364     (vvals, lvals) = unzip vals
 365
 366 mkClosureFns :: CEnvInfo -> [TyVar] -> Var -> CoreExprWithFVs
 367              -> VM (CoreExpr, CoreExpr)
 368 mkClosureFns info tyvars arg body
 369   = closedV
 370   . abstractOverTyVars tyvars
 371   $ \mk_tlams ->
 372   do
 373     (vfn, lfn) <- mkClosureMonoFns info arg body
 374     return (mk_tlams vfn, mk_tlams lfn)
 375
 376 mkClosureMonoFns :: CEnvInfo -> Var -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 377 mkClosureMonoFns info arg body
 378   = do
 379       lc_bndr <- newLocalVar FSLIT("lc") intTy
 380       (varg : vbndrs, larg : lbndrs, (vbody, lbody))
 381         <- vectBndrsIn (arg : cenv_vars info)
 382                        (vectExpr (Var lc_bndr) body)
 383
 384       venv_bndr <- newLocalVar FSLIT("env") vty
 385       lenv_bndr <- newLocalVar FSLIT("env") lty
 386
 387       let vcase = bind_venv (Var venv_bndr) vbody vbndrs
 388       lcase <- bind_lenv (Var lenv_bndr) lbody lc_bndr lbndrs
 389       return (mkLams [venv_bndr, varg] vcase, mkLams [lenv_bndr, larg] lcase)
 390   where
 391     vty = cenv_vty info
 392     lty = cenv_lty info
 393
 394     arity = length (cenv_vars info)
 395
 396     bind_venv venv vbody []      = vbody
 397     bind_venv venv vbody [vbndr] = Let (NonRec vbndr venv) vbody
 398     bind_venv venv vbody vbndrs
 399       = Case venv (mkWildId vty) (exprType vbody)
 400              [(DataAlt (tupleCon Boxed arity), vbndrs, vbody)]
 401
 402     bind_lenv lenv lbody lc_bndr [lbndr]
 403       = do
 404           lengthPA <- builtin lengthPAVar
 405           return . Let (NonRec lbndr lenv)
 406                  $ Case (mkApps (Var lengthPA) [Type vty, (Var lbndr)])
 407                         lc_bndr
 408                         intTy
 409                         [(DEFAULT, [], lbody)]
 410
 411     bind_lenv lenv lbody lc_bndr lbndrs
 412       = return
 413       $ Case (unwrapFamInstScrut (cenv_repr_tycon info)
 414                                  (cenv_repr_tyargs info)
 415                                  lenv)
 416              (mkWildId lty)
 417              (exprType lbody)
 418              [(DataAlt (cenv_repr_datacon info), lc_bndr : lbndrs, lbody)]
 419
 420 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 421 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 422 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 423
 424 -- ----------------------------------------------------------------------------
 425 -- Types
 426
 427 vectTyCon :: TyCon -> VM TyCon
 428 vectTyCon tc
 429   | isFunTyCon tc        = builtin closureTyCon
 430   | isBoxedTupleTyCon tc = return tc
 431   | isUnLiftedTyCon tc   = return tc
 432   | otherwise = do
 433                   r <- lookupTyCon tc
 434                   case r of
 435                     Just tc' -> return tc'
 436
 437                     -- FIXME: just for now
 438                     Nothing  -> pprTrace "ccTyCon:" (ppr tc) $ return tc
 439
 440 vectType :: Type -> VM Type
 441 vectType ty | Just ty' <- coreView ty = vectType ty'
 442 vectType (TyVarTy tv) = return $ TyVarTy tv
 443 vectType (AppTy ty1 ty2) = liftM2 AppTy (vectType ty1) (vectType ty2)
 444 vectType (TyConApp tc tys) = liftM2 TyConApp (vectTyCon tc) (mapM vectType tys)
 445 vectType (FunTy ty1 ty2)   = liftM2 TyConApp (builtin closureTyCon)
 446                                              (mapM vectType [ty1,ty2])
 447 vectType (ForAllTy tv ty)
 448   = do
 449       r   <- paDictArgType tv
 450       ty' <- vectType ty
 451       return $ ForAllTy tv (wrap r ty')
 452   where
 453     wrap Nothing      = id
 454     wrap (Just pa_ty) = FunTy pa_ty
 455
 456 vectType ty = pprPanic "vectType:" (ppr ty)
 457