compiler/vectorise/Vectorise.hs

   1 module Vectorise( vectorise )
   2 where
   3
   4 #include "HsVersions.h"
   5
   6 import VectMonad
   7 import VectUtils
   8
   9 import DynFlags
  10 import HscTypes
  11
  12 import CoreLint             ( showPass, endPass )
  13 import CoreSyn
  14 import CoreUtils
  15 import CoreFVs
  16 import SimplMonad           ( SimplCount, zeroSimplCount )
  17 import Rules                ( RuleBase )
  18 import DataCon
  19 import TyCon
  20 import Type
  21 import TypeRep
  22 import Var
  23 import VarEnv
  24 import VarSet
  25 import Name                 ( mkSysTvName, getName )
  26 import NameEnv
  27 import Id
  28 import MkId                 ( unwrapFamInstScrut )
  29 import OccName
  30
  31 import DsMonad hiding (mapAndUnzipM)
  32 import DsUtils              ( mkCoreTup, mkCoreTupTy )
  33
  34 import PrelNames
  35 import TysWiredIn
  36 import BasicTypes           ( Boxity(..) )
  37
  38 import Outputable
  39 import FastString
  40 import Control.Monad        ( liftM, liftM2, mapAndUnzipM, zipWithM_ )
  41 import Data.Maybe           ( maybeToList )
  42
  43 vectorise :: HscEnv -> UniqSupply -> RuleBase -> ModGuts
  44           -> IO (SimplCount, ModGuts)
  45 vectorise hsc_env _ _ guts
  46   = do
  47       showPass dflags "Vectorisation"
  48       eps <- hscEPS hsc_env
  49       let info = hptVectInfo hsc_env `plusVectInfo` eps_vect_info eps
  50       Just (info', guts') <- initV hsc_env guts info (vectModule guts)
  51       endPass dflags "Vectorisation" Opt_D_dump_vect (mg_binds guts')
  52       return (zeroSimplCount dflags, guts' { mg_vect_info = info' })
  53   where
  54     dflags = hsc_dflags hsc_env
  55
  56 vectModule :: ModGuts -> VM ModGuts
  57 vectModule guts
  58   = do
  59       binds' <- mapM vectTopBind (mg_binds guts)
  60       return $ guts { mg_binds = binds' }
  61
  62 vectTopBind :: CoreBind -> VM CoreBind
  63 vectTopBind b@(NonRec var expr)
  64   = do
  65       var'  <- vectTopBinder var
  66       expr' <- vectTopRhs expr
  67       hs    <- takeHoisted
  68       return . Rec $ (var, expr) : (var', expr') : hs
  69   `orElseV`
  70     return b
  71
  72 vectTopBind b@(Rec bs)
  73   = do
  74       vars'  <- mapM vectTopBinder vars
  75       exprs' <- mapM vectTopRhs exprs
  76       hs     <- takeHoisted
  77       return . Rec $ bs ++ zip vars' exprs' ++ hs
  78   `orElseV`
  79     return b
  80   where
  81     (vars, exprs) = unzip bs
  82
  83 vectTopBinder :: Var -> VM Var
  84 vectTopBinder var
  85   = do
  86       vty <- vectType (idType var)
  87       name <- cloneName mkVectOcc (getName var)
  88       let var' | isExportedId var = Id.mkExportedLocalId name vty
  89                | otherwise        = Id.mkLocalId         name vty
  90       defGlobalVar var var'
  91       return var'
  92
  93 vectTopRhs :: CoreExpr -> VM CoreExpr
  94 vectTopRhs = liftM fst . closedV . vectPolyExpr (panic "Empty lifting context") . freeVars
  95
  96 -- ----------------------------------------------------------------------------
  97 -- Bindings
  98
  99 vectBndr :: Var -> VM (Var, Var)
 100 vectBndr v
 101   = do
 102       vty <- vectType (idType v)
 103       lty <- mkPArrayType vty
 104       let vv = v `Id.setIdType` vty
 105           lv = v `Id.setIdType` lty
 106       updLEnv (mapTo vv lv)
 107       return (vv, lv)
 108   where
 109     mapTo vv lv env = env { local_vars = extendVarEnv (local_vars env) v (Var vv, Var lv) }
 110
 111 vectBndrIn :: Var -> VM a -> VM (Var, Var, a)
 112 vectBndrIn v p
 113   = localV
 114   $ do
 115       (vv, lv) <- vectBndr v
 116       x <- p
 117       return (vv, lv, x)
 118
 119 vectBndrsIn :: [Var] -> VM a -> VM ([Var], [Var], a)
 120 vectBndrsIn vs p
 121   = localV
 122   $ do
 123       (vvs, lvs) <- mapAndUnzipM vectBndr vs
 124       x <- p
 125       return (vvs, lvs, x)
 126
 127 -- ----------------------------------------------------------------------------
 128 -- Expressions
 129
 130 replicateP :: CoreExpr -> CoreExpr -> VM CoreExpr
 131 replicateP expr len
 132   = do
 133       dict <- paDictOfType ty
 134       rep  <- builtin replicatePAVar
 135       return $ mkApps (Var rep) [Type ty, dict, expr, len]
 136   where
 137     ty = exprType expr
 138
 139 capply :: (CoreExpr, CoreExpr) -> (CoreExpr, CoreExpr) -> VM (CoreExpr, CoreExpr)
 140 capply (vfn, lfn) (varg, larg)
 141   = do
 142       apply  <- builtin applyClosureVar
 143       applyP <- builtin applyClosurePVar
 144       return (mkApps (Var apply)  [Type arg_ty, Type res_ty, vfn, varg],
 145               mkApps (Var applyP) [Type arg_ty, Type res_ty, lfn, larg])
 146   where
 147     fn_ty            = exprType vfn
 148     (arg_ty, res_ty) = splitClosureTy fn_ty
 149
 150 vectVar :: CoreExpr -> Var -> VM (CoreExpr, CoreExpr)
 151 vectVar lc v
 152   = do
 153       r <- lookupVar v
 154       case r of
 155         Local es     -> return es
 156         Global vexpr -> do
 157                           lexpr <- replicateP vexpr lc
 158                           return (vexpr, lexpr)
 159
 160 vectPolyVar :: CoreExpr -> Var -> [Type] -> VM (CoreExpr, CoreExpr)
 161 vectPolyVar lc v tys
 162   = do
 163       r <- lookupVar v
 164       case r of
 165         Local (vexpr, lexpr) -> liftM2 (,) (mk_app vexpr) (mk_app lexpr)
 166         Global poly          -> do
 167                                   vexpr <- mk_app poly
 168                                   lexpr <- replicateP vexpr lc
 169                                   return (vexpr, lexpr)
 170   where
 171     mk_app e = applyToTypes e =<< mapM vectType tys
 172
 173 abstractOverTyVars :: [TyVar] -> ((CoreExpr -> CoreExpr) -> VM a) -> VM a
 174 abstractOverTyVars tvs p
 175   = do
 176       mdicts <- mapM mk_dict_var tvs
 177       zipWithM_ (\tv -> maybe (deleteTyVarPA tv) (extendTyVarPA tv . Var)) tvs mdicts
 178       p (mk_lams mdicts)
 179   where
 180     mk_dict_var tv = do
 181                        r <- paDictArgType tv
 182                        case r of
 183                          Just ty -> liftM Just (newLocalVar FSLIT("dPA") ty)
 184                          Nothing -> return Nothing
 185
 186     mk_lams mdicts = mkLams [arg | (tv, mdict) <- zip tvs mdicts
 187                                  , arg <- tv : maybeToList mdict]
 188
 189 applyToTypes :: CoreExpr -> [Type] -> VM CoreExpr
 190 applyToTypes expr tys
 191   = do
 192       dicts <- mapM paDictOfType tys
 193       return $ mkApps expr [arg | (ty, dict) <- zip tys dicts
 194                                 , arg <- [Type ty, dict]]
 195
 196
 197 vectPolyExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 198 vectPolyExpr lc expr
 199   = localV
 200   . abstractOverTyVars tvs $ \mk_lams ->
 201     -- FIXME: shadowing (tvs in lc)
 202     do
 203       (vmono, lmono) <- vectExpr lc mono
 204       return $ (mk_lams vmono, mk_lams lmono)
 205   where
 206     (tvs, mono) = collectAnnTypeBinders expr
 207
 208 vectExpr :: CoreExpr -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 209 vectExpr lc (_, AnnType ty)
 210   = do
 211       vty <- vectType ty
 212       return (Type vty, Type vty)
 213
 214 vectExpr lc (_, AnnVar v)   = vectVar lc v
 215
 216 vectExpr lc (_, AnnLit lit)
 217   = do
 218       let vexpr = Lit lit
 219       lexpr <- replicateP vexpr lc
 220       return (vexpr, lexpr)
 221
 222 vectExpr lc (_, AnnNote note expr)
 223   = do
 224       (vexpr, lexpr) <- vectExpr lc expr
 225       return (Note note vexpr, Note note lexpr)
 226
 227 vectExpr lc e@(_, AnnApp _ arg)
 228   | isAnnTypeArg arg
 229   = vectTyAppExpr lc fn tys
 230   where
 231     (fn, tys) = collectAnnTypeArgs e
 232
 233 vectExpr lc (_, AnnApp fn arg)
 234   = do
 235       fn'  <- vectExpr lc fn
 236       arg' <- vectExpr lc arg
 237       capply fn' arg'
 238
 239 vectExpr lc (_, AnnCase expr bndr ty alts)
 240   = panic "vectExpr: case"
 241
 242 vectExpr lc (_, AnnLet (AnnNonRec bndr rhs) body)
 243   = do
 244       (vrhs, lrhs) <- vectPolyExpr lc rhs
 245       (vbndr, lbndr, (vbody, lbody)) <- vectBndrIn bndr (vectExpr lc body)
 246       return (Let (NonRec vbndr vrhs) vbody,
 247               Let (NonRec lbndr lrhs) lbody)
 248
 249 vectExpr lc (_, AnnLet (AnnRec prs) body)
 250   = do
 251       (vbndrs, lbndrs, (vrhss, vbody, lrhss, lbody)) <- vectBndrsIn bndrs vect
 252       return (Let (Rec (zip vbndrs vrhss)) vbody,
 253               Let (Rec (zip lbndrs lrhss)) lbody)
 254   where
 255     (bndrs, rhss) = unzip prs
 256
 257     vect = do
 258              (vrhss, lrhss) <- mapAndUnzipM (vectExpr lc) rhss
 259              (vbody, lbody) <- vectPolyExpr lc body
 260              return (vrhss, vbody, lrhss, lbody)
 261
 262 vectExpr lc e@(_, AnnLam bndr body)
 263   | isTyVar bndr = pprPanic "vectExpr" (ppr $ deAnnotate e)
 264
 265 vectExpr lc (fvs, AnnLam bndr body)
 266   = do
 267       let tyvars = filter isTyVar (varSetElems fvs)
 268       info <- mkCEnvInfo fvs bndr body
 269       (poly_vfn, poly_lfn) <- mkClosureFns info tyvars bndr body
 270
 271       vfn_var <- hoistExpr FSLIT("vfn") poly_vfn
 272       lfn_var <- hoistExpr FSLIT("lfn") poly_lfn
 273
 274       let (venv, lenv) = mkClosureEnvs info lc
 275
 276       let env_ty = cenv_vty info
 277
 278       pa_dict <- paDictOfType env_ty
 279
 280       arg_ty <- vectType (varType bndr)
 281       res_ty <- vectType (exprType $ deAnnotate body)
 282
 283       -- FIXME: move the functions to the top level
 284       mono_vfn <- applyToTypes (Var vfn_var) (map TyVarTy tyvars)
 285       mono_lfn <- applyToTypes (Var lfn_var) (map TyVarTy tyvars)
 286
 287       mk_clo <- builtin mkClosureVar
 288       mk_cloP <- builtin mkClosurePVar
 289
 290       let vclo = Var mk_clo  `mkTyApps` [arg_ty, res_ty, env_ty]
 291                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, venv]
 292
 293           lclo = Var mk_cloP `mkTyApps` [arg_ty, res_ty, env_ty]
 294                              `mkApps`   [pa_dict, mono_vfn, mono_lfn, lenv]
 295
 296       return (vclo, lclo)
 297
 298
 299 data CEnvInfo = CEnvInfo {
 300                cenv_vars         :: [Var]
 301              , cenv_values       :: [(CoreExpr, CoreExpr)]
 302              , cenv_vty          :: Type
 303              , cenv_lty          :: Type
 304              , cenv_repr_tycon   :: TyCon
 305              , cenv_repr_tyargs  :: [Type]
 306              , cenv_repr_datacon :: DataCon
 307              }
 308
 309 mkCEnvInfo :: VarSet -> Var -> CoreExprWithFVs -> VM CEnvInfo
 310 mkCEnvInfo fvs arg body
 311   = do
 312       locals <- readLEnv local_vars
 313       let
 314           (vars, vals) = unzip
 315                  [(var, val) | var      <- varSetElems fvs
 316                              , Just val <- [lookupVarEnv locals var]]
 317       vtys <- mapM (vectType . varType) vars
 318
 319       (vty, repr_tycon, repr_tyargs, repr_datacon) <- mk_env_ty vtys
 320       lty <- mkPArrayType vty
 321
 322       return $ CEnvInfo {
 323                  cenv_vars         = vars
 324                , cenv_values       = vals
 325                , cenv_vty          = vty
 326                , cenv_lty          = lty
 327                , cenv_repr_tycon   = repr_tycon
 328                , cenv_repr_tyargs  = repr_tyargs
 329                , cenv_repr_datacon = repr_datacon
 330                }
 331   where
 332     mk_env_ty [vty]
 333       = return (vty, error "absent cinfo_repr_tycon"
 334                    , error "absent cinfo_repr_tyargs"
 335                    , error "absent cinfo_repr_datacon")
 336
 337     mk_env_ty vtys
 338       = do
 339           let ty = mkCoreTupTy vtys
 340           (repr_tc, repr_tyargs) <- lookupPArrayFamInst ty
 341           let [repr_con] = tyConDataCons repr_tc
 342           return (ty, repr_tc, repr_tyargs, repr_con)
 343
 344
 345
 346 mkClosureEnvs :: CEnvInfo -> CoreExpr -> (CoreExpr, CoreExpr)
 347 mkClosureEnvs info lc
 348   | [] <- vals
 349   = (Var unitDataConId, mkApps (Var $ dataConWrapId (cenv_repr_datacon info))
 350                                [lc, Var unitDataConId])
 351
 352   | [(vval, lval)] <- vals
 353   = (vval, lval)
 354
 355   | otherwise
 356   = (mkCoreTup vvals, Var (dataConWrapId $ cenv_repr_datacon info)
 357                       `mkTyApps` cenv_repr_tyargs info
 358                       `mkApps`   (lc : lvals))
 359
 360   where
 361     vals = cenv_values info
 362     (vvals, lvals) = unzip vals
 363
 364 mkClosureFns :: CEnvInfo -> [TyVar] -> Var -> CoreExprWithFVs
 365              -> VM (CoreExpr, CoreExpr)
 366 mkClosureFns info tyvars arg body
 367   = closedV
 368   . abstractOverTyVars tyvars
 369   $ \mk_tlams ->
 370   do
 371     (vfn, lfn) <- mkClosureMonoFns info arg body
 372     return (mk_tlams vfn, mk_tlams lfn)
 373
 374 mkClosureMonoFns :: CEnvInfo -> Var -> CoreExprWithFVs -> VM (CoreExpr, CoreExpr)
 375 mkClosureMonoFns info arg body
 376   = do
 377       lc_bndr <- newLocalVar FSLIT("lc") intTy
 378       (varg : vbndrs, larg : lbndrs, (vbody, lbody))
 379         <- vectBndrsIn (arg : cenv_vars info)
 380                        (vectExpr (Var lc_bndr) body)
 381
 382       venv_bndr <- newLocalVar FSLIT("env") vty
 383       lenv_bndr <- newLocalVar FSLIT("env") lty
 384
 385       let vcase = bind_venv (Var venv_bndr) vbody vbndrs
 386       lcase <- bind_lenv (Var lenv_bndr) lbody lc_bndr lbndrs
 387       return (mkLams [venv_bndr, varg] vcase, mkLams [lenv_bndr, larg] lcase)
 388   where
 389     vty = cenv_vty info
 390     lty = cenv_lty info
 391
 392     arity = length (cenv_vars info)
 393
 394     bind_venv venv vbody []      = vbody
 395     bind_venv venv vbody [vbndr] = Let (NonRec vbndr venv) vbody
 396     bind_venv venv vbody vbndrs
 397       = Case venv (mkWildId vty) (exprType vbody)
 398              [(DataAlt (tupleCon Boxed arity), vbndrs, vbody)]
 399
 400     bind_lenv lenv lbody lc_bndr [lbndr]
 401       = do
 402           lengthPA <- builtin lengthPAVar
 403           return . Let (NonRec lbndr lenv)
 404                  $ Case (mkApps (Var lengthPA) [Type vty, (Var lbndr)])
 405                         lc_bndr
 406                         intTy
 407                         [(DEFAULT, [], lbody)]
 408
 409     bind_lenv lenv lbody lc_bndr lbndrs
 410       = return
 411       $ Case (unwrapFamInstScrut (cenv_repr_tycon info)
 412                                  (cenv_repr_tyargs info)
 413                                  lenv)
 414              (mkWildId lty)
 415              (exprType lbody)
 416              [(DataAlt (cenv_repr_datacon info), lc_bndr : lbndrs, lbody)]
 417
 418 vectTyAppExpr :: CoreExpr -> CoreExprWithFVs -> [Type] -> VM (CoreExpr, CoreExpr)
 419 vectTyAppExpr lc (_, AnnVar v) tys = vectPolyVar lc v tys
 420 vectTyAppExpr lc e tys = pprPanic "vectTyAppExpr" (ppr $ deAnnotate e)
 421
 422 -- ----------------------------------------------------------------------------
 423 -- Types
 424
 425 vectTyCon :: TyCon -> VM TyCon
 426 vectTyCon tc
 427   | isFunTyCon tc        = builtin closureTyCon
 428   | isBoxedTupleTyCon tc = return tc
 429   | isUnLiftedTyCon tc   = return tc
 430   | otherwise = do
 431                   r <- lookupTyCon tc
 432                   case r of
 433                     Just tc' -> return tc'
 434
 435                     -- FIXME: just for now
 436                     Nothing  -> pprTrace "ccTyCon:" (ppr tc) $ return tc
 437
 438 vectType :: Type -> VM Type
 439 vectType ty | Just ty' <- coreView ty = vectType ty'
 440 vectType (TyVarTy tv) = return $ TyVarTy tv
 441 vectType (AppTy ty1 ty2) = liftM2 AppTy (vectType ty1) (vectType ty2)
 442 vectType (TyConApp tc tys) = liftM2 TyConApp (vectTyCon tc) (mapM vectType tys)
 443 vectType (FunTy ty1 ty2)   = liftM2 TyConApp (builtin closureTyCon)
 444                                              (mapM vectType [ty1,ty2])
 445 vectType (ForAllTy tv ty)
 446   = do
 447       r   <- paDictArgType tv
 448       ty' <- vectType ty
 449       return $ ForAllTy tv (wrap r ty')
 450   where
 451     wrap Nothing      = id
 452     wrap (Just pa_ty) = FunTy pa_ty
 453
 454 vectType ty = pprPanic "vectType:" (ppr ty)
 455