compiler/vectorise/Vectorise/Exp.hs

   1
   2 -- | Vectorisation of expressions.
   3 module Vectorise.Exp
   4         (vectPolyExpr)
   5 where
   6 import Vectorise.Utils
   7 import Vectorise.Type.Type
   8 import Vectorise.Var
   9 import Vectorise.Vect
  10 import Vectorise.Env
  11 import Vectorise.Monad
  12 import Vectorise.Builtins
  13
  14 import CoreSyn
  15 import CoreUtils
  16 import MkCore
  17 import CoreFVs
  18 import DataCon
  19 import TyCon
  20 import Type
  21 import Var
  22 import VarEnv
  23 import VarSet
  24 import Id
  25 import BasicTypes( isLoopBreaker )
  26 import Literal
  27 import TysWiredIn
  28 import TysPrim
  29 import Outputable
  30 import FastString
  31 import Control.Monad
  32 import Data.List
  33
  34
  35 -- | Vectorise a polymorphic expression.
  36 vectPolyExpr
  37         :: Bool                 -- ^ When vectorising the RHS of a binding, whether that
  38                                 --   binding is a loop breaker.
  39         -> CoreExprWithFVs
  40         -> VM (Inline, VExpr)
  41
  42 vectPolyExpr loop_breaker (_, AnnNote note expr)
  43  = do (inline, expr') <- vectPolyExpr loop_breaker expr
  44       return (inline, vNote note expr')
  45
  46 vectPolyExpr loop_breaker expr
  47  = do
  48       arity <- polyArity tvs
  49       polyAbstract tvs $ \args ->
  50         do
  51           (inline, mono') <- vectFnExpr False loop_breaker mono
  52           return (addInlineArity inline arity,
  53                   mapVect (mkLams $ tvs ++ args) mono')
  54   where
  55     (tvs, mono) = collectAnnTypeBinders expr
  56
  57
  58 -- | Vectorise an expression.
  59 vectExpr :: CoreExprWithFVs -> VM VExpr
  60 vectExpr (_, AnnType ty)
  61   = liftM vType (vectType ty)
  62
  63 vectExpr (_, AnnVar v)
  64   = vectVar v
  65
  66 vectExpr (_, AnnLit lit)
  67   = vectLiteral lit
  68
  69 vectExpr (_, AnnNote note expr)
  70   = liftM (vNote note) (vectExpr expr)
  71
  72 vectExpr e@(_, AnnApp _ arg)
  73   | isAnnTypeArg arg
  74   = vectTyAppExpr fn tys
  75   where
  76     (fn, tys) = collectAnnTypeArgs e
  77
  78 vectExpr (_, AnnApp (_, AnnVar v) (_, AnnLit lit))
  79   | Just con <- isDataConId_maybe v
  80   , is_special_con con
  81   = do
  82       let vexpr = App (Var v) (Lit lit)
  83       lexpr <- liftPD vexpr
  84       return (vexpr, lexpr)
  85   where
  86     is_special_con con = con `elem` [intDataCon, floatDataCon, doubleDataCon]
  87
  88
  89 -- TODO: Avoid using closure application for dictionaries.
  90 -- vectExpr (_, AnnApp fn arg)
  91 --  | if is application of dictionary
  92 --    just use regular app instead of closure app.
  93
  94 -- for lifted version.
  95 --      do liftPD (sub a dNumber)
  96 --      lift the result of the selection, not sub and dNumber seprately.
  97
  98 vectExpr (_, AnnApp fn arg)
  99  = do
 100       arg_ty' <- vectType arg_ty
 101       res_ty' <- vectType res_ty
 102
 103       fn'     <- vectExpr fn
 104       arg'    <- vectExpr arg
 105
 106       mkClosureApp arg_ty' res_ty' fn' arg'
 107   where
 108     (arg_ty, res_ty) = splitFunTy . exprType $ deAnnotate fn
 109
 110 vectExpr (_, AnnCase scrut bndr ty alts)
 111   | Just (tycon, ty_args) <- splitTyConApp_maybe scrut_ty
 112   , isAlgTyCon tycon
 113   = vectAlgCase tycon ty_args scrut bndr ty alts
 114   where
 115     scrut_ty = exprType (deAnnotate scrut)
 116
 117 vectExpr (_, AnnLet (AnnNonRec bndr rhs) body)
 118   = do
 119       vrhs <- localV . inBind bndr . liftM snd $ vectPolyExpr False rhs
 120       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 121       return $ vLet (vNonRec vbndr vrhs) vbody
 122
 123 vectExpr (_, AnnLet (AnnRec bs) body)
 124   = do
 125       (vbndrs, (vrhss, vbody)) <- vectBndrsIn bndrs
 126                                 $ liftM2 (,)
 127                                   (zipWithM vect_rhs bndrs rhss)
 128                                   (vectExpr body)
 129       return $ vLet (vRec vbndrs vrhss) vbody
 130   where
 131     (bndrs, rhss) = unzip bs
 132
 133     vect_rhs bndr rhs = localV
 134                       . inBind bndr
 135                       . liftM snd
 136                       $ vectPolyExpr (isLoopBreaker $ idOccInfo bndr) rhs
 137
 138 vectExpr e@(_, AnnLam bndr _)
 139   | isId bndr = liftM snd $ vectFnExpr True False e
 140 {-
 141 onlyIfV (isEmptyVarSet fvs) (vectScalarLam bs $ deAnnotate body)
 142                 `orElseV` vectLam True fvs bs body
 143   where
 144     (bs,body) = collectAnnValBinders e
 145 -}
 146
 147 vectExpr e = cantVectorise "Can't vectorise expression" (ppr $ deAnnotate e)
 148
 149
 150 -- | Vectorise an expression with an outer lambda abstraction.
 151 vectFnExpr
 152         :: Bool                 -- ^ When the RHS of a binding, whether that binding should be inlined.
 153         -> Bool                 -- ^ Whether the binding is a loop breaker.
 154         -> CoreExprWithFVs      -- ^ Expression to vectorise. Must have an outer `AnnLam`.
 155         -> VM (Inline, VExpr)
 156
 157 vectFnExpr inline loop_breaker e@(fvs, AnnLam bndr _)
 158   | isId bndr = onlyIfV (isEmptyVarSet fvs)
 159                         (mark DontInline . vectScalarLam bs $ deAnnotate body)
 160                 `orElseV` mark inlineMe (vectLam inline loop_breaker fvs bs body)
 161   where
 162     (bs,body) = collectAnnValBinders e
 163
 164 vectFnExpr _ _ e = mark DontInline $ vectExpr e
 165
 166 mark :: Inline -> VM a -> VM (Inline, a)
 167 mark b p = do { x <- p; return (b,x) }
 168
 169
 170 -- | Vectorise a function where are the args have scalar type,
 171 --   that is Int, Float, Double etc.
 172 vectScalarLam
 173         :: [Var]        -- ^ Bound variables of function.
 174         -> CoreExpr     -- ^ Function body.
 175         -> VM VExpr
 176
 177 vectScalarLam args body
 178  = do scalars <- globalScalars
 179       onlyIfV (all is_scalar_ty arg_tys
 180                && is_scalar_ty res_ty
 181                && is_scalar (extendVarSetList scalars args) body
 182                && uses scalars body)
 183         $ do
 184             fn_var  <- hoistExpr (fsLit "fn") (mkLams args body) DontInline
 185             zipf    <- zipScalars arg_tys res_ty
 186             clo     <- scalarClosure arg_tys res_ty (Var fn_var)
 187                                                 (zipf `App` Var fn_var)
 188             clo_var <- hoistExpr (fsLit "clo") clo DontInline
 189             lclo    <- liftPD (Var clo_var)
 190             return (Var clo_var, lclo)
 191   where
 192     arg_tys = map idType args
 193     res_ty  = exprType body
 194
 195     is_scalar_ty ty
 196         | Just (tycon, [])   <- splitTyConApp_maybe ty
 197         =    tycon == intTyCon
 198           || tycon == floatTyCon
 199           || tycon == doubleTyCon
 200           || tycon == boolTyCon
 201
 202         | otherwise = False
 203
 204     is_scalar vs (Var v)     = v `elemVarSet` vs
 205     is_scalar _ e@(Lit _)    = is_scalar_ty $ exprType e
 206     is_scalar vs (App e1 e2) = is_scalar vs e1 && is_scalar vs e2
 207     is_scalar vs (Let (NonRec b letExpr) body)
 208                              = is_scalar vs letExpr && is_scalar (extendVarSet vs b) body
 209     is_scalar vs (Let (Rec bnds) body)
 210                              =  let vs' = extendVarSetList vs (map fst bnds)
 211                                 in all (is_scalar vs') (map snd bnds) && is_scalar vs' body
 212     is_scalar vs (Case e eId ty alts)
 213                              = let vs' = extendVarSet vs eId
 214                                    in is_scalar_ty ty &&
 215                                   is_scalar vs' e   &&
 216                                   (all (is_scalar_alt vs') alts)
 217
 218     is_scalar _ e            = False
 219
 220     is_scalar_alt vs (_, bs, e)
 221                              = is_scalar (extendVarSetList vs bs) e
 222
 223     -- A scalar function has to actually compute something. Without the check,
 224     -- we would treat (\(x :: Int) -> x) as a scalar function and lift it to
 225     -- (map (\x -> x)) which is very bad. Normal lifting transforms it to
 226     -- (\n# x -> x) which is what we want.
 227     uses funs (Var v)     = v `elemVarSet` funs
 228     uses funs (App e1 e2) = uses funs e1 || uses funs e2
 229     uses funs (Let (NonRec b letExpr) body)
 230                           = uses funs letExpr || uses funs  body
 231     uses funs (Case e eId ty alts)
 232                           = uses funs e || any (uses_alt funs) alts
 233     uses _ _              = False
 234
 235     uses_alt funs (_, bs, e)
 236                           = uses funs e
 237
 238 -- | Vectorise a lambda abstraction.
 239 vectLam
 240         :: Bool                 -- ^ When the RHS of a binding, whether that binding should be inlined.
 241         -> Bool                 -- ^ Whether the binding is a loop breaker.
 242         -> VarSet               -- ^ The free variables in the body.
 243         -> [Var]                -- ^ Binding variables.
 244         -> CoreExprWithFVs      -- ^ Body of abstraction.
 245         -> VM VExpr
 246
 247 vectLam inline loop_breaker fvs bs body
 248  = do tyvars    <- localTyVars
 249       (vs, vvs) <- readLEnv $ \env ->
 250                    unzip [(var, vv) | var <- varSetElems fvs
 251                                     , Just vv <- [lookupVarEnv (local_vars env) var]]
 252
 253       arg_tys   <- mapM (vectType . idType) bs
 254       res_ty    <- vectType (exprType $ deAnnotate body)
 255
 256       buildClosures tyvars vvs arg_tys res_ty
 257         . hoistPolyVExpr tyvars (maybe_inline (length vs + length bs))
 258         $ do
 259             lc              <- builtin liftingContext
 260             (vbndrs, vbody) <- vectBndrsIn (vs ++ bs) (vectExpr body)
 261
 262             vbody' <- break_loop lc res_ty vbody
 263             return $ vLams lc vbndrs vbody'
 264   where
 265     maybe_inline n | inline    = Inline n
 266                    | otherwise = DontInline
 267
 268     break_loop lc ty (ve, le)
 269       | loop_breaker
 270       = do
 271           empty <- emptyPD ty
 272           lty <- mkPDataType ty
 273           return (ve, mkWildCase (Var lc) intPrimTy lty
 274                         [(DEFAULT, [], le),
 275                          (LitAlt (mkMachInt 0), [], empty)])
 276
 277       | otherwise = return (ve, le)
 278
 279
 280 vectTyAppExpr :: CoreExprWithFVs -> [Type] -> VM VExpr
 281 vectTyAppExpr (_, AnnVar v) tys = vectPolyVar v tys
 282 vectTyAppExpr e tys = cantVectorise "Can't vectorise expression"
 283                         (ppr $ deAnnotate e `mkTyApps` tys)
 284
 285
 286 -- | Vectorise an algebraic case expression.
 287 --   We convert
 288 --
 289 --   case e :: t of v { ... }
 290 --
 291 -- to
 292 --
 293 --   V:    let v' = e in case v' of _ { ... }
 294 --   L:    let v' = e in case v' `cast` ... of _ { ... }
 295 --
 296 --   When lifting, we have to do it this way because v must have the type
 297 --   [:V(T):] but the scrutinee must be cast to the representation type. We also
 298 --   have to handle the case where v is a wild var correctly.
 299 --
 300
 301 -- FIXME: this is too lazy
 302 vectAlgCase :: TyCon -> [Type] -> CoreExprWithFVs -> Var -> Type
 303             -> [(AltCon, [Var], CoreExprWithFVs)]
 304             -> VM VExpr
 305 vectAlgCase _tycon _ty_args scrut bndr ty [(DEFAULT, [], body)]
 306   = do
 307       vscrut         <- vectExpr scrut
 308       (vty, lty)     <- vectAndLiftType ty
 309       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 310       return $ vCaseDEFAULT vscrut vbndr vty lty vbody
 311
 312 vectAlgCase _tycon _ty_args scrut bndr ty [(DataAlt _, [], body)]
 313   = do
 314       vscrut         <- vectExpr scrut
 315       (vty, lty)     <- vectAndLiftType ty
 316       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 317       return $ vCaseDEFAULT vscrut vbndr vty lty vbody
 318
 319 vectAlgCase _tycon _ty_args scrut bndr ty [(DataAlt dc, bndrs, body)]
 320   = do
 321       (vty, lty) <- vectAndLiftType ty
 322       vexpr      <- vectExpr scrut
 323       (vbndr, (vbndrs, (vect_body, lift_body)))
 324          <- vect_scrut_bndr
 325           . vectBndrsIn bndrs
 326           $ vectExpr body
 327       let (vect_bndrs, lift_bndrs) = unzip vbndrs
 328       (vscrut, lscrut, pdata_tc, _arg_tys) <- mkVScrut (vVar vbndr)
 329       vect_dc <- maybeV (lookupDataCon dc)
 330       let [pdata_dc] = tyConDataCons pdata_tc
 331
 332       let vcase = mk_wild_case vscrut vty vect_dc  vect_bndrs vect_body
 333           lcase = mk_wild_case lscrut lty pdata_dc lift_bndrs lift_body
 334
 335       return $ vLet (vNonRec vbndr vexpr) (vcase, lcase)
 336   where
 337     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr (fsLit "scrut")
 338                     | otherwise         = vectBndrIn bndr
 339
 340     mk_wild_case expr ty dc bndrs body
 341       = mkWildCase expr (exprType expr) ty [(DataAlt dc, bndrs, body)]
 342
 343 vectAlgCase tycon _ty_args scrut bndr ty alts
 344   = do
 345       vect_tc     <- maybeV (lookupTyCon tycon)
 346       (vty, lty)  <- vectAndLiftType ty
 347
 348       let arity = length (tyConDataCons vect_tc)
 349       sel_ty <- builtin (selTy arity)
 350       sel_bndr <- newLocalVar (fsLit "sel") sel_ty
 351       let sel = Var sel_bndr
 352
 353       (vbndr, valts) <- vect_scrut_bndr
 354                       $ mapM (proc_alt arity sel vty lty) alts'
 355       let (vect_dcs, vect_bndrss, lift_bndrss, vbodies) = unzip4 valts
 356
 357       vexpr <- vectExpr scrut
 358       (vect_scrut, lift_scrut, pdata_tc, _arg_tys) <- mkVScrut (vVar vbndr)
 359       let [pdata_dc] = tyConDataCons pdata_tc
 360
 361       let (vect_bodies, lift_bodies) = unzip vbodies
 362
 363       vdummy <- newDummyVar (exprType vect_scrut)
 364       ldummy <- newDummyVar (exprType lift_scrut)
 365       let vect_case = Case vect_scrut vdummy vty
 366                            (zipWith3 mk_vect_alt vect_dcs vect_bndrss vect_bodies)
 367
 368       lc <- builtin liftingContext
 369       lbody <- combinePD vty (Var lc) sel lift_bodies
 370       let lift_case = Case lift_scrut ldummy lty
 371                            [(DataAlt pdata_dc, sel_bndr : concat lift_bndrss,
 372                              lbody)]
 373
 374       return . vLet (vNonRec vbndr vexpr)
 375              $ (vect_case, lift_case)
 376   where
 377     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr (fsLit "scrut")
 378                     | otherwise         = vectBndrIn bndr
 379
 380     alts' = sortBy (\(alt1, _, _) (alt2, _, _) -> cmp alt1 alt2) alts
 381
 382     cmp (DataAlt dc1) (DataAlt dc2) = dataConTag dc1 `compare` dataConTag dc2
 383     cmp DEFAULT       DEFAULT       = EQ
 384     cmp DEFAULT       _             = LT
 385     cmp _             DEFAULT       = GT
 386     cmp _             _             = panic "vectAlgCase/cmp"
 387
 388     proc_alt arity sel _ lty (DataAlt dc, bndrs, body)
 389       = do
 390           vect_dc <- maybeV (lookupDataCon dc)
 391           let ntag = dataConTagZ vect_dc
 392               tag  = mkDataConTag vect_dc
 393               fvs  = freeVarsOf body `delVarSetList` bndrs
 394
 395           sel_tags  <- liftM (`App` sel) (builtin (selTags arity))
 396           lc        <- builtin liftingContext
 397           elems     <- builtin (selElements arity ntag)
 398
 399           (vbndrs, vbody)
 400             <- vectBndrsIn bndrs
 401              . localV
 402              $ do
 403                  binds    <- mapM (pack_var (Var lc) sel_tags tag)
 404                            . filter isLocalId
 405                            $ varSetElems fvs
 406                  (ve, le) <- vectExpr body
 407                  return (ve, Case (elems `App` sel) lc lty
 408                              [(DEFAULT, [], (mkLets (concat binds) le))])
 409                  -- empty    <- emptyPD vty
 410                  -- return (ve, Case (elems `App` sel) lc lty
 411                  --             [(DEFAULT, [], Let (NonRec flags_var flags_expr)
 412                  --                             $ mkLets (concat binds) le),
 413                  --               (LitAlt (mkMachInt 0), [], empty)])
 414           let (vect_bndrs, lift_bndrs) = unzip vbndrs
 415           return (vect_dc, vect_bndrs, lift_bndrs, vbody)
 416
 417     proc_alt _ _ _ _ _ = panic "vectAlgCase/proc_alt"
 418
 419     mk_vect_alt vect_dc bndrs body = (DataAlt vect_dc, bndrs, body)
 420
 421     pack_var len tags t v
 422       = do
 423           r <- lookupVar v
 424           case r of
 425             Local (vv, lv) ->
 426               do
 427                 lv'  <- cloneVar lv
 428                 expr <- packByTagPD (idType vv) (Var lv) len tags t
 429                 updLEnv (\env -> env { local_vars = extendVarEnv
 430                                                 (local_vars env) v (vv, lv') })
 431                 return [(NonRec lv' expr)]
 432
 433             _ -> return []
 434