compiler/vectorise/Vectorise/Exp.hs

   1
   2 -- | Vectorisation of expressions.
   3 module Vectorise.Exp
   4         (vectPolyExpr)
   5 where
   6 import Vectorise.Utils
   7 import Vectorise.Type.Type
   8 import Vectorise.Var
   9 import Vectorise.Vect
  10 import Vectorise.Env
  11 import Vectorise.Monad
  12 import Vectorise.Builtins
  13
  14 import CoreSyn
  15 import CoreUtils
  16 import MkCore
  17 import CoreFVs
  18 import DataCon
  19 import TyCon
  20 import Type
  21 import Var
  22 import VarEnv
  23 import VarSet
  24 import Id
  25 import BasicTypes( isLoopBreaker )
  26 import Literal
  27 import TysWiredIn
  28 import TysPrim
  29 import Outputable
  30 import FastString
  31 import Control.Monad
  32 import Data.List
  33
  34
  35 -- | Vectorise a polymorphic expression.
  36 vectPolyExpr
  37         :: Bool                 -- ^ When vectorising the RHS of a binding, whether that
  38                                 --   binding is a loop breaker.
  39         -> CoreExprWithFVs
  40         -> VM (Inline, VExpr)
  41
  42 vectPolyExpr loop_breaker (_, AnnNote note expr)
  43  = do (inline, expr') <- vectPolyExpr loop_breaker expr
  44       return (inline, vNote note expr')
  45
  46 vectPolyExpr loop_breaker expr
  47  = do
  48       arity <- polyArity tvs
  49       polyAbstract tvs $ \args ->
  50         do
  51           (inline, mono') <- vectFnExpr False loop_breaker mono
  52           return (addInlineArity inline arity,
  53                   mapVect (mkLams $ tvs ++ args) mono')
  54   where
  55     (tvs, mono) = collectAnnTypeBinders expr
  56
  57
  58 -- | Vectorise an expression.
  59 vectExpr :: CoreExprWithFVs -> VM VExpr
  60 vectExpr (_, AnnType ty)
  61   = liftM vType (vectType ty)
  62
  63 vectExpr (_, AnnVar v)
  64   = vectVar v
  65
  66 vectExpr (_, AnnLit lit)
  67   = vectLiteral lit
  68
  69 vectExpr (_, AnnNote note expr)
  70   = liftM (vNote note) (vectExpr expr)
  71
  72 vectExpr e@(_, AnnApp _ arg)
  73   | isAnnTypeArg arg
  74   = vectTyAppExpr fn tys
  75   where
  76     (fn, tys) = collectAnnTypeArgs e
  77
  78 vectExpr (_, AnnApp (_, AnnVar v) (_, AnnLit lit))
  79   | Just con <- isDataConId_maybe v
  80   , is_special_con con
  81   = do
  82       let vexpr = App (Var v) (Lit lit)
  83       lexpr <- liftPD vexpr
  84       return (vexpr, lexpr)
  85   where
  86     is_special_con con = con `elem` [intDataCon, floatDataCon, doubleDataCon]
  87
  88
  89 -- TODO: Avoid using closure application for dictionaries.
  90 -- vectExpr (_, AnnApp fn arg)
  91 --  | if is application of dictionary
  92 --    just use regular app instead of closure app.
  93
  94 -- for lifted version.
  95 --      do liftPD (sub a dNumber)
  96 --      lift the result of the selection, not sub and dNumber seprately.
  97
  98 vectExpr (_, AnnApp fn arg)
  99  = do
 100       arg_ty' <- vectType arg_ty
 101       res_ty' <- vectType res_ty
 102
 103       fn'     <- vectExpr fn
 104       arg'    <- vectExpr arg
 105
 106       mkClosureApp arg_ty' res_ty' fn' arg'
 107   where
 108     (arg_ty, res_ty) = splitFunTy . exprType $ deAnnotate fn
 109
 110 vectExpr (_, AnnCase scrut bndr ty alts)
 111   | Just (tycon, ty_args) <- splitTyConApp_maybe scrut_ty
 112   , isAlgTyCon tycon
 113   = vectAlgCase tycon ty_args scrut bndr ty alts
 114   where
 115     scrut_ty = exprType (deAnnotate scrut)
 116
 117 vectExpr (_, AnnLet (AnnNonRec bndr rhs) body)
 118   = do
 119       vrhs <- localV . inBind bndr . liftM snd $ vectPolyExpr False rhs
 120       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 121       return $ vLet (vNonRec vbndr vrhs) vbody
 122
 123 vectExpr (_, AnnLet (AnnRec bs) body)
 124   = do
 125       (vbndrs, (vrhss, vbody)) <- vectBndrsIn bndrs
 126                                 $ liftM2 (,)
 127                                   (zipWithM vect_rhs bndrs rhss)
 128                                   (vectExpr body)
 129       return $ vLet (vRec vbndrs vrhss) vbody
 130   where
 131     (bndrs, rhss) = unzip bs
 132
 133     vect_rhs bndr rhs = localV
 134                       . inBind bndr
 135                       . liftM snd
 136                       $ vectPolyExpr (isLoopBreaker $ idOccInfo bndr) rhs
 137
 138 vectExpr e@(_, AnnLam bndr _)
 139   | isId bndr = liftM snd $ vectFnExpr True False e
 140 {-
 141 onlyIfV (isEmptyVarSet fvs) (vectScalarLam bs $ deAnnotate body)
 142                 `orElseV` vectLam True fvs bs body
 143   where
 144     (bs,body) = collectAnnValBinders e
 145 -}
 146
 147 vectExpr e = cantVectorise "Can't vectorise expression" (ppr $ deAnnotate e)
 148
 149
 150 -- | Vectorise an expression with an outer lambda abstraction.
 151 vectFnExpr
 152         :: Bool                 -- ^ When the RHS of a binding, whether that binding should be inlined.
 153         -> Bool                 -- ^ Whether the binding is a loop breaker.
 154         -> CoreExprWithFVs      -- ^ Expression to vectorise. Must have an outer `AnnLam`.
 155         -> VM (Inline, VExpr)
 156
 157 vectFnExpr inline loop_breaker e@(fvs, AnnLam bndr _)
 158   | isId bndr = onlyIfV (isEmptyVarSet fvs)
 159                         (mark DontInline . vectScalarLam bs $ deAnnotate body)
 160                 `orElseV` mark inlineMe (vectLam inline loop_breaker fvs bs body)
 161   where
 162     (bs,body) = collectAnnValBinders e
 163
 164 vectFnExpr _ _ e = mark DontInline $ vectExpr e
 165
 166 mark :: Inline -> VM a -> VM (Inline, a)
 167 mark b p = do { x <- p; return (b,x) }
 168
 169
 170 -- | Vectorise a function where are the args have scalar type,
 171 --   that is Int, Float, Double etc.
 172 vectScalarLam
 173         :: [Var]        -- ^ Bound variables of function.
 174         -> CoreExpr     -- ^ Function body.
 175         -> VM VExpr
 176
 177 vectScalarLam args body
 178  = do scalars <- globalScalars
 179       onlyIfV (all is_scalar_ty arg_tys
 180                && is_scalar_ty res_ty
 181                && is_scalar (extendVarSetList scalars args) body
 182                && uses scalars body)
 183         $ do
 184             fn_var  <- hoistExpr (fsLit "fn") (mkLams args body) DontInline
 185             zipf    <- zipScalars arg_tys res_ty
 186             clo     <- scalarClosure arg_tys res_ty (Var fn_var)
 187                                                 (zipf `App` Var fn_var)
 188             clo_var <- hoistExpr (fsLit "clo") clo DontInline
 189             lclo    <- liftPD (Var clo_var)
 190             return (Var clo_var, lclo)
 191   where
 192     arg_tys = map idType args
 193     res_ty  = exprType body
 194
 195     is_prim_ty ty
 196         | Just (tycon, [])   <- splitTyConApp_maybe ty
 197         =    tycon == intTyCon
 198           || tycon == floatTyCon
 199           || tycon == doubleTyCon
 200
 201         | otherwise = False
 202
 203     cantbe_parr_expr expr = not $ maybe_parr_ty $ exprType expr
 204
 205     maybe_parr_ty ty = maybe_parr_ty' [] ty
 206     maybe_parr_ty' alreadySeen ty
 207        | isPArrTyCon tycon     = True
 208        | isPrimTyCon tycon     = False
 209        | isAbstractTyCon tycon = True
 210        | isFunTyCon tycon || isProductTyCon tycon || isTupleTyCon tycon  = any (maybe_parr_ty' alreadySeen) args
 211        | isDataTyCon tycon = pprTrace "isDataTyCon" (ppr tycon) $
 212                              any (maybe_parr_ty' alreadySeen) args ||
 213                              hasParrDataCon alreadySeen tycon
 214        | otherwise = True
 215        where
 216          Just (tycon, args) = splitTyConApp_maybe ty
 217
 218
 219          hasParrDataCon alreadySeen tycon
 220            | tycon `elem` alreadySeen = False
 221            | otherwise                =
 222                any (maybe_parr_ty' $ tycon : alreadySeen) $ concat $  map dataConOrigArgTys $ tyConDataCons tycon
 223
 224     -- checks to make sure expression can't contain a non-scalar subexpression. Might err on the side of caution whenever
 225     -- an external (non data constructor) variable is used, or anonymous data constructor
 226     is_scalar vs e@(Var v)
 227       | Just _ <- isDataConId_maybe v = cantbe_parr_expr e
 228       | otherwise                     = cantbe_parr_expr e &&  (v `elemVarSet` vs)
 229     is_scalar _ e@(Lit _)    = -- pprTrace "is_scalar  Lit" (ppr e) $
 230                                cantbe_parr_expr e
 231
 232     is_scalar vs e@(App e1 e2) = -- pprTrace "is_scalar  App" (ppr e) $
 233                                cantbe_parr_expr e &&
 234                                is_scalar vs e1 && is_scalar vs e2
 235     is_scalar vs e@(Let (NonRec b letExpr) body)
 236                              = -- pprTrace "is_scalar  Let" (ppr e) $
 237                                cantbe_parr_expr e &&
 238                                is_scalar vs letExpr && is_scalar (extendVarSet vs b) body
 239     is_scalar vs e@(Let (Rec bnds) body)
 240                              =  let vs' = extendVarSetList vs (map fst bnds)
 241                                 in -- pprTrace "is_scalar  Rec" (ppr e) $
 242                                    cantbe_parr_expr e &&
 243                                    all (is_scalar vs') (map snd bnds) && is_scalar vs' body
 244     is_scalar vs e@(Case eC eId ty alts)
 245                              = let vs' = extendVarSet vs eId
 246                                    in -- pprTrace "is_scalar  Case" (ppr e) $
 247                                       cantbe_parr_expr e &&
 248                                   is_prim_ty ty &&
 249                                   is_scalar vs' eC   &&
 250                                   (all (is_scalar_alt vs') alts)
 251
 252     is_scalar _ e            =  -- pprTrace "is_scalar  other" (ppr e) $
 253                                 False
 254
 255     is_scalar_alt vs (_, bs, e)
 256                              = is_scalar (extendVarSetList vs bs) e
 257
 258     -- A scalar function has to actually compute something. Without the check,
 259     -- we would treat (\(x :: Int) -> x) as a scalar function and lift it to
 260     -- (map (\x -> x)) which is very bad. Normal lifting transforms it to
 261     -- (\n# x -> x) which is what we want.
 262     uses funs (Var v)     = v `elemVarSet` funs
 263     uses funs (App e1 e2) = uses funs e1 || uses funs e2
 264     uses funs (Let (NonRec _b letExpr) body)
 265                           = uses funs letExpr || uses funs  body
 266     uses funs (Case e _eId _ty alts)
 267                           = uses funs e || any (uses_alt funs) alts
 268     uses _ _              = False
 269
 270     uses_alt funs (_, _bs, e)
 271                           = uses funs e
 272
 273 -- | Vectorise a lambda abstraction.
 274 vectLam
 275         :: Bool                 -- ^ When the RHS of a binding, whether that binding should be inlined.
 276         -> Bool                 -- ^ Whether the binding is a loop breaker.
 277         -> VarSet               -- ^ The free variables in the body.
 278         -> [Var]                -- ^ Binding variables.
 279         -> CoreExprWithFVs      -- ^ Body of abstraction.
 280         -> VM VExpr
 281
 282 vectLam inline loop_breaker fvs bs body
 283  = do tyvars    <- localTyVars
 284       (vs, vvs) <- readLEnv $ \env ->
 285                    unzip [(var, vv) | var <- varSetElems fvs
 286                                     , Just vv <- [lookupVarEnv (local_vars env) var]]
 287
 288       arg_tys   <- mapM (vectType . idType) bs
 289       res_ty    <- vectType (exprType $ deAnnotate body)
 290
 291       buildClosures tyvars vvs arg_tys res_ty
 292         . hoistPolyVExpr tyvars (maybe_inline (length vs + length bs))
 293         $ do
 294             lc              <- builtin liftingContext
 295             (vbndrs, vbody) <- vectBndrsIn (vs ++ bs) (vectExpr body)
 296
 297             vbody' <- break_loop lc res_ty vbody
 298             return $ vLams lc vbndrs vbody'
 299   where
 300     maybe_inline n | inline    = Inline n
 301                    | otherwise = DontInline
 302
 303     break_loop lc ty (ve, le)
 304       | loop_breaker
 305       = do
 306           empty <- emptyPD ty
 307           lty <- mkPDataType ty
 308           return (ve, mkWildCase (Var lc) intPrimTy lty
 309                         [(DEFAULT, [], le),
 310                          (LitAlt (mkMachInt 0), [], empty)])
 311
 312       | otherwise = return (ve, le)
 313
 314
 315 vectTyAppExpr :: CoreExprWithFVs -> [Type] -> VM VExpr
 316 vectTyAppExpr (_, AnnVar v) tys = vectPolyVar v tys
 317 vectTyAppExpr e tys = cantVectorise "Can't vectorise expression"
 318                         (ppr $ deAnnotate e `mkTyApps` tys)
 319
 320
 321 -- | Vectorise an algebraic case expression.
 322 --   We convert
 323 --
 324 --   case e :: t of v { ... }
 325 --
 326 -- to
 327 --
 328 --   V:    let v' = e in case v' of _ { ... }
 329 --   L:    let v' = e in case v' `cast` ... of _ { ... }
 330 --
 331 --   When lifting, we have to do it this way because v must have the type
 332 --   [:V(T):] but the scrutinee must be cast to the representation type. We also
 333 --   have to handle the case where v is a wild var correctly.
 334 --
 335
 336 -- FIXME: this is too lazy
 337 vectAlgCase :: TyCon -> [Type] -> CoreExprWithFVs -> Var -> Type
 338             -> [(AltCon, [Var], CoreExprWithFVs)]
 339             -> VM VExpr
 340 vectAlgCase _tycon _ty_args scrut bndr ty [(DEFAULT, [], body)]
 341   = do
 342       vscrut         <- vectExpr scrut
 343       (vty, lty)     <- vectAndLiftType ty
 344       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 345       return $ vCaseDEFAULT vscrut vbndr vty lty vbody
 346
 347 vectAlgCase _tycon _ty_args scrut bndr ty [(DataAlt _, [], body)]
 348   = do
 349       vscrut         <- vectExpr scrut
 350       (vty, lty)     <- vectAndLiftType ty
 351       (vbndr, vbody) <- vectBndrIn bndr (vectExpr body)
 352       return $ vCaseDEFAULT vscrut vbndr vty lty vbody
 353
 354 vectAlgCase _tycon _ty_args scrut bndr ty [(DataAlt dc, bndrs, body)]
 355   = do
 356       (vty, lty) <- vectAndLiftType ty
 357       vexpr      <- vectExpr scrut
 358       (vbndr, (vbndrs, (vect_body, lift_body)))
 359          <- vect_scrut_bndr
 360           . vectBndrsIn bndrs
 361           $ vectExpr body
 362       let (vect_bndrs, lift_bndrs) = unzip vbndrs
 363       (vscrut, lscrut, pdata_tc, _arg_tys) <- mkVScrut (vVar vbndr)
 364       vect_dc <- maybeV (lookupDataCon dc)
 365       let [pdata_dc] = tyConDataCons pdata_tc
 366
 367       let vcase = mk_wild_case vscrut vty vect_dc  vect_bndrs vect_body
 368           lcase = mk_wild_case lscrut lty pdata_dc lift_bndrs lift_body
 369
 370       return $ vLet (vNonRec vbndr vexpr) (vcase, lcase)
 371   where
 372     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr (fsLit "scrut")
 373                     | otherwise         = vectBndrIn bndr
 374
 375     mk_wild_case expr ty dc bndrs body
 376       = mkWildCase expr (exprType expr) ty [(DataAlt dc, bndrs, body)]
 377
 378 vectAlgCase tycon _ty_args scrut bndr ty alts
 379   = do
 380       vect_tc     <- maybeV (lookupTyCon tycon)
 381       (vty, lty)  <- vectAndLiftType ty
 382
 383       let arity = length (tyConDataCons vect_tc)
 384       sel_ty <- builtin (selTy arity)
 385       sel_bndr <- newLocalVar (fsLit "sel") sel_ty
 386       let sel = Var sel_bndr
 387
 388       (vbndr, valts) <- vect_scrut_bndr
 389                       $ mapM (proc_alt arity sel vty lty) alts'
 390       let (vect_dcs, vect_bndrss, lift_bndrss, vbodies) = unzip4 valts
 391
 392       vexpr <- vectExpr scrut
 393       (vect_scrut, lift_scrut, pdata_tc, _arg_tys) <- mkVScrut (vVar vbndr)
 394       let [pdata_dc] = tyConDataCons pdata_tc
 395
 396       let (vect_bodies, lift_bodies) = unzip vbodies
 397
 398       vdummy <- newDummyVar (exprType vect_scrut)
 399       ldummy <- newDummyVar (exprType lift_scrut)
 400       let vect_case = Case vect_scrut vdummy vty
 401                            (zipWith3 mk_vect_alt vect_dcs vect_bndrss vect_bodies)
 402
 403       lc <- builtin liftingContext
 404       lbody <- combinePD vty (Var lc) sel lift_bodies
 405       let lift_case = Case lift_scrut ldummy lty
 406                            [(DataAlt pdata_dc, sel_bndr : concat lift_bndrss,
 407                              lbody)]
 408
 409       return . vLet (vNonRec vbndr vexpr)
 410              $ (vect_case, lift_case)
 411   where
 412     vect_scrut_bndr | isDeadBinder bndr = vectBndrNewIn bndr (fsLit "scrut")
 413                     | otherwise         = vectBndrIn bndr
 414
 415     alts' = sortBy (\(alt1, _, _) (alt2, _, _) -> cmp alt1 alt2) alts
 416
 417     cmp (DataAlt dc1) (DataAlt dc2) = dataConTag dc1 `compare` dataConTag dc2
 418     cmp DEFAULT       DEFAULT       = EQ
 419     cmp DEFAULT       _             = LT
 420     cmp _             DEFAULT       = GT
 421     cmp _             _             = panic "vectAlgCase/cmp"
 422
 423     proc_alt arity sel _ lty (DataAlt dc, bndrs, body)
 424       = do
 425           vect_dc <- maybeV (lookupDataCon dc)
 426           let ntag = dataConTagZ vect_dc
 427               tag  = mkDataConTag vect_dc
 428               fvs  = freeVarsOf body `delVarSetList` bndrs
 429
 430           sel_tags  <- liftM (`App` sel) (builtin (selTags arity))
 431           lc        <- builtin liftingContext
 432           elems     <- builtin (selElements arity ntag)
 433
 434           (vbndrs, vbody)
 435             <- vectBndrsIn bndrs
 436              . localV
 437              $ do
 438                  binds    <- mapM (pack_var (Var lc) sel_tags tag)
 439                            . filter isLocalId
 440                            $ varSetElems fvs
 441                  (ve, le) <- vectExpr body
 442                  return (ve, Case (elems `App` sel) lc lty
 443                              [(DEFAULT, [], (mkLets (concat binds) le))])
 444                  -- empty    <- emptyPD vty
 445                  -- return (ve, Case (elems `App` sel) lc lty
 446                  --             [(DEFAULT, [], Let (NonRec flags_var flags_expr)
 447                  --                             $ mkLets (concat binds) le),
 448                  --               (LitAlt (mkMachInt 0), [], empty)])
 449           let (vect_bndrs, lift_bndrs) = unzip vbndrs
 450           return (vect_dc, vect_bndrs, lift_bndrs, vbody)
 451
 452     proc_alt _ _ _ _ _ = panic "vectAlgCase/proc_alt"
 453
 454     mk_vect_alt vect_dc bndrs body = (DataAlt vect_dc, bndrs, body)
 455
 456     pack_var len tags t v
 457       = do
 458           r <- lookupVar v
 459           case r of
 460             Local (vv, lv) ->
 461               do
 462                 lv'  <- cloneVar lv
 463                 expr <- packByTagPD (idType vv) (Var lv) len tags t
 464                 updLEnv (\env -> env { local_vars = extendVarEnv
 465                                                 (local_vars env) v (vv, lv') })
 466                 return [(NonRec lv' expr)]
 467
 468             _ -> return []
 469