configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 143     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 FPTOOLS_SET_PLATFORM_VARS
 204
 205 exeext=''
 206 soext='.so'
 207 case $host in
 208 *-unknown-cygwin32)
 209     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 210     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 211     exit 1
 212     ;;
 213 *-unknown-mingw32)
 214     exeext='.exe'
 215     soext='.dll'
 216     ;;
 217 i386-apple-darwin|powerpc-apple-darwin)
 218     soext='.dylib'
 219     ;;
 220 x86_64-apple-darwin)
 221     soext='.dylib'
 222     ;;
 223 esac
 224
 225 # Sync this with cTargetArch in compiler/ghc.mk
 226 checkArch() {
 227     case $1 in
 228     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 229         ;;
 230     *)
 231         echo "Unknown arch $1"
 232         exit 1
 233         ;;
 234     esac
 235 }
 236
 237 checkVendor() {
 238     case $1 in
 239     dec|unknown|hp|apple|next|sun|sgi|ibm)
 240         ;;
 241     *)
 242         echo "Unknown vendor $1"
 243         exit 1
 244         ;;
 245     esac
 246 }
 247
 248 checkOS() {
 249     case $1 in
 250     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 251         ;;
 252     *)
 253         echo "Unknown OS '$1'"
 254         exit 1
 255         ;;
 256     esac
 257 }
 258
 259 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 260 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 261 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 262 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 263 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 264
 265 checkArch "$BuildArch"
 266 checkVendor "$BuildVendor"
 267 checkOS "$BuildOS"
 268
 269 HostPlatform="$HostArch-$HostVendor-$HostOS"
 270 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 271 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 272 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 273 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 274
 275 checkArch "$HostArch"
 276 checkVendor "$HostVendor"
 277 checkOS "$HostOS"
 278
 279 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 280 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 281 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 282 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 283 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 284
 285 checkArch "$TargetArch"
 286 checkVendor "$TargetVendor"
 287 checkOS "$TargetOS"
 288
 289 # Verify that the installed (bootstrap) GHC is capable of generating
 290 # code for the requested build platform.
 291 if test "$build" != "$bootstrap_target"
 292 then
 293     echo "This GHC (${WithGhc}) does not generate code for the build platform"
 294     echo "   GHC target platform    : $bootstrap_target"
 295     echo "   Desired build platform : $BuildPlatform"
 296     exit 1
 297 fi
 298
 299 AC_SUBST(BuildPlatform)
 300 AC_SUBST(HostPlatform)
 301 AC_SUBST(TargetPlatform)
 302 AC_SUBST(HostPlatform_CPP)
 303 AC_SUBST(BuildPlatform_CPP)
 304 AC_SUBST(TargetPlatform_CPP)
 305
 306 AC_SUBST(HostArch_CPP)
 307 AC_SUBST(BuildArch_CPP)
 308 AC_SUBST(TargetArch_CPP)
 309
 310 AC_SUBST(HostOS_CPP)
 311 AC_SUBST(BuildOS_CPP)
 312 AC_SUBST(TargetOS_CPP)
 313
 314 AC_SUBST(HostVendor_CPP)
 315 AC_SUBST(BuildVendor_CPP)
 316 AC_SUBST(TargetVendor_CPP)
 317
 318 AC_SUBST(exeext)
 319 AC_SUBST(soext)
 320
 321 AC_ARG_WITH(hc,
 322 [AC_HELP_STRING([--with-hc=ARG],
 323         [Use ARG as the path to the compiler for compiling ordinary
 324          Haskell code  (default= value of --with-ghc)])],
 325 [WithHc="$withval"],
 326 [WithHc=$WithGhc]
 327 )
 328 AC_SUBST(WithHc)
 329
 330 # This uses GHC, so put it after the "GHC is required" check above:
 331 FP_INTREE_GHC_PWD
 332 FP_FIND_ROOT
 333
 334 if test "$HostOS" = "mingw32"
 335 then
 336     test -d inplace || mkdir inplace
 337
 338     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 339     LD="$hardtop/inplace/mingw/bin/ld.exe"
 340     NM="$hardtop/inplace/mingw/bin/nm.exe"
 341     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 342
 343     # NB. If you update the tarbballs to a new version of gcc, don't
 344     # forget to tweak the paths in driver/gcc/gcc.c.
 345     if ! test -d inplace/mingw ||
 346          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 347          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 348          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 349          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 350          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 351          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 352          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 353          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 354          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 355          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 356          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 357     then
 358         AC_MSG_NOTICE([Making in-tree mingw tree])
 359         rm -rf inplace/mingw
 360         mkdir inplace/mingw
 361         (
 362             cd inplace/mingw &&
 363             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 364             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 365             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 366             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 367             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 368             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 369             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 370             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 371             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 372             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 373             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 374             mv bin/gcc.exe bin/realgcc.exe
 375         )
 376         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 377         if ! test -e inplace/mingw/bin/gcc.exe
 378         then
 379             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 380         fi
 381         AC_MSG_NOTICE([In-tree mingw tree created])
 382     fi
 383     if ! test -d inplace/perl ||
 384          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 385     then
 386         AC_MSG_NOTICE([Making in-tree perl tree])
 387         rm -rf inplace/perl
 388         mkdir inplace
 389         mkdir inplace/perl
 390         (
 391             cd inplace/perl &&
 392             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 393         )
 394         AC_MSG_NOTICE([In-tree perl tree created])
 395     fi
 396 fi
 397
 398 dnl ** Which gcc to use?
 399 dnl --------------------------------------------------------------
 400 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 401 export CC
 402 WhatGccIsCalled="$CC"
 403 AC_SUBST(WhatGccIsCalled)
 404
 405 dnl ** Which ld to use?
 406 dnl --------------------------------------------------------------
 407 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 408 LdCmd="$LD"
 409 AC_SUBST([LdCmd])
 410
 411 dnl ** Which nm to use?
 412 dnl --------------------------------------------------------------
 413 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 414 NmCmd="$NM"
 415 AC_SUBST([NmCmd])
 416
 417 dnl ** Mac OS X: explicit deployment target
 418 dnl --------------------------------------------------------------
 419 AC_ARG_WITH([macosx-deployment-target],
 420 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 421         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 422 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 423  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 424    # ignore everywhere, but on Mac OS
 425    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 426    FP_MACOSX_DEPLOYMENT_TARGET=none
 427  fi],
 428 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 429 )
 430 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 431 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 432 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 433
 434 dnl --------------------------------------------------------------
 435 dnl End of configure script option section
 436 dnl --------------------------------------------------------------
 437
 438
 439 dnl --------------------------------------------------------------
 440 dnl * General configuration checks
 441 dnl --------------------------------------------------------------
 442
 443 dnl ** Can the unix package be built?
 444 dnl --------------------------------------------------------------
 445
 446 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 447    GhcLibsWithUnix=NO
 448 else
 449    GhcLibsWithUnix=YES
 450 fi
 451 AC_SUBST([GhcLibsWithUnix])
 452
 453 dnl ** does #! work?
 454 AC_SYS_INTERPRETER()
 455
 456 dnl ** look for `perl'
 457 case $HostOS_CPP in
 458 cygwin32|mingw32)
 459     PerlCmd=$hardtop/inplace/perl/perl
 460     ;;
 461 *)
 462     AC_PATH_PROG(PerlCmd,perl)
 463     if test -z "$PerlCmd"
 464     then
 465         echo "You must install perl before you can continue"
 466         echo "Perhaps it is already installed, but not in your PATH?"
 467         exit 1
 468     else
 469         FPTOOLS_CHECK_PERL_VERSION
 470     fi
 471     ;;
 472 esac
 473
 474 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 475 FPTOOLS_SHEBANG_PERL
 476
 477 dnl ** check for Python
 478 AC_PATH_PROG(PythonCmd,python)
 479
 480 dnl ** look for GCC and find out which version
 481 dnl     Figure out which C compiler to use.  Gcc is preferred.
 482 dnl     If gcc, make sure it's at least 2.1
 483 dnl
 484 FP_HAVE_GCC
 485
 486 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 487 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 488 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 489 # Stage 3 won't be supported by cross-compilation
 490 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 491
 492 FP_GCC_EXTRA_FLAGS
 493
 494 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 495 AC_PROG_CPP
 496
 497 AC_SUBST(CONF_CC_OPTS_STAGE0)
 498 AC_SUBST(CONF_CC_OPTS_STAGE1)
 499 AC_SUBST(CONF_CC_OPTS_STAGE2)
 500 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 501 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 502 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 503 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 504 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 505 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 506 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 507 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 508 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 509
 510 dnl ** figure out how to do context diffs
 511 FP_PROG_CONTEXT_DIFF
 512
 513 dnl Let's make sure install-sh is executable here.  If we got it from
 514 dnl a darcs repo, it might not be (see bug #978).
 515 chmod +x install-sh
 516 dnl ** figure out how to do a BSD-ish install
 517 AC_PROG_INSTALL
 518
 519 dnl If you can run configure, you certainly have /bin/sh
 520 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 521
 522 dnl ** how to invoke `ar' and `ranlib'
 523 FP_PROG_AR_SUPPORTS_ATFILE
 524 FP_PROG_AR_NEEDS_RANLIB
 525 FP_PROG_AR_SUPPORTS_INPUT
 526
 527 dnl ** Check to see whether ln -s works
 528 AC_PROG_LN_S
 529
 530
 531 dnl ** Find the path to sed
 532 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 533
 534
 535 dnl ** check for time command
 536 AC_PATH_PROG(TimeCmd,time)
 537
 538 dnl ** check for tar
 539 dnl   if GNU tar is named gtar, look for it first.
 540 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 541
 542 dnl ** check for patch
 543 dnl if GNU patch is named gpatch, look for it first
 544 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 545
 546 dnl ** check for dtrace (currently only implemented for Mac OS X)
 547 HaveDtrace=NO
 548 AC_PATH_PROG(DtraceCmd,dtrace)
 549 if test -n "$DtraceCmd"; then
 550   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 551     HaveDtrace=YES
 552   fi
 553 fi
 554 AC_SUBST(HaveDtrace)
 555
 556 AC_PATH_PROG(HSCOLOUR,HsColour)
 557 # HsColour is passed to Cabal, so we need a native path
 558 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 559    test "${OSTYPE}"      != "msys"                  && \
 560    test "${HSCOLOUR}"    != ""
 561 then
 562     # Canonicalise to <drive>:/path/to/gcc
 563     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 564 fi
 565
 566 dnl ** check for DocBook toolchain
 567 FP_CHECK_DOCBOOK_DTD
 568 FP_DOCBOOK_XSL
 569 FP_PROG_DBLATEX
 570
 571 FP_PROG_HSTAGS
 572
 573 dnl ** check for ghc-pkg command
 574 FP_PROG_GHC_PKG
 575
 576 dnl ** check for installed happy binary + version
 577 dnl    (don't do it if we're booting from .hc files though.)
 578 if test "$BootingFromHc" = "NO"; then
 579 FPTOOLS_HAPPY
 580 fi;
 581
 582 dnl ** check for installed alex binary + version
 583 dnl    (don't do it if we're booting from .hc files though.)
 584 if test "$BootingFromHc" = "NO"; then
 585 FPTOOLS_ALEX
 586 fi;
 587
 588 dnl --------------------------------------------------
 589 dnl ### program checking section ends here ###
 590 dnl --------------------------------------------------
 591
 592 dnl --------------------------------------------------
 593 dnl * Platform header file and syscall feature tests
 594 dnl ### checking the state of the local header files and syscalls ###
 595
 596 dnl ** check for full ANSI header (.h) files
 597 AC_HEADER_STDC
 598
 599 dnl ** Enable large file support.  NB. do this before testing the type of
 600 dnl    off_t, because it will affect the result of that test.
 601 AC_SYS_LARGEFILE
 602
 603 dnl ** check for specific header (.h) files that we are interested in
 604 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 605
 606 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 607 AC_HEADER_TIME
 608
 609 dnl ** do we have long longs?
 610 AC_CHECK_TYPES([long long])
 611
 612 dnl ** what are the sizes of various types
 613 AC_CHECK_SIZEOF(char,               1)
 614 AC_CHECK_SIZEOF(double,             8)
 615 AC_CHECK_SIZEOF(float,              4)
 616 AC_CHECK_SIZEOF(int,                4)
 617 AC_CHECK_SIZEOF(long,               4)
 618 if test "$ac_cv_type_long_long" = yes; then
 619 AC_CHECK_SIZEOF(long long,          8)
 620 fi
 621 AC_CHECK_SIZEOF(short,              2)
 622 AC_CHECK_SIZEOF(unsigned char,      1)
 623 AC_CHECK_SIZEOF(unsigned int,       4)
 624 AC_CHECK_SIZEOF(unsigned long,      4)
 625 if test "$ac_cv_type_long_long" = yes; then
 626 AC_CHECK_SIZEOF(unsigned long long, 8)
 627 fi
 628 AC_CHECK_SIZEOF(unsigned short,     2)
 629 AC_CHECK_SIZEOF(void *,             4)
 630
 631 dnl ** what are alignment constraints on various types
 632 FP_CHECK_ALIGNMENT(char)
 633 FP_CHECK_ALIGNMENT(double)
 634 FP_CHECK_ALIGNMENT(float)
 635 FP_CHECK_ALIGNMENT(int)
 636 FP_CHECK_ALIGNMENT(long)
 637 if test "$ac_cv_type_long_long" = yes; then
 638 FP_CHECK_ALIGNMENT(long long)
 639 fi
 640 FP_CHECK_ALIGNMENT(short)
 641 FP_CHECK_ALIGNMENT(unsigned char)
 642 FP_CHECK_ALIGNMENT(unsigned int)
 643 FP_CHECK_ALIGNMENT(unsigned long)
 644 if test "$ac_cv_type_long_long" = yes; then
 645 FP_CHECK_ALIGNMENT(unsigned long long)
 646 fi
 647 FP_CHECK_ALIGNMENT(unsigned short)
 648 FP_CHECK_ALIGNMENT(void *)
 649
 650 FP_CHECK_FUNC([WinExec],
 651   [@%:@include <windows.h>], [WinExec("",0)])
 652
 653 FP_CHECK_FUNC([GetModuleFileName],
 654   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 655
 656 dnl ** check return type of signal handlers
 657 dnl Foo: assumes we can use prototypes.
 658 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 659 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 660 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 661 dnl #include <signal.h>
 662 dnl #ifdef signal
 663 dnl #undef signal
 664 dnl #endif
 665 dnl void (*signal (int, void (*)(int)))(int);
 666 dnl ]],
 667 dnl [[int i;]])],
 668 dnl [ac_cv_type_signal_handler=void_int],
 669 dnl [ac_cv_type_signal_handler=int_void])])
 670 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 671 dnl AC_DEFINE(VOID_INT_SIGNALS)
 672 dnl fi
 673
 674 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 675 AC_TYPE_SIGNAL
 676 if test "$ac_cv_type_signal" = void; then
 677   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 678 fi
 679
 680 dnl ** check for more functions
 681 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 682 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 683
 684 AC_TRY_RUN([
 685 #include <sys/types.h>
 686 #include <sys/time.h>
 687 int main(void) {
 688   struct itimerval tval;
 689   tval.it_value.tv_sec = 1;
 690   tval.it_value.tv_usec = 0;
 691   tval.it_interval = tval.it_value;
 692   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 693 }
 694 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 695
 696 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 697 dnl ** _POSIX_C_SOURCE is defined
 698 AC_CHECK_DECLS([ctime_r], , ,
 699 [#define _POSIX_SOURCE 1
 700 #define _POSIX_C_SOURCE 199506L
 701 #include <time.h>])
 702
 703 dnl ** check for mingwex library
 704 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 705 AC_SUBST(HaveLibMingwEx)
 706
 707 if test $HaveLibMingwEx = YES ; then
 708   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 709 fi
 710
 711 dnl ** check for math library
 712 dnl    Keep that check as early as possible.
 713 dnl    as we need to know whether we need libm
 714 dnl    for math functions or not
 715 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 716 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 717 if test $HaveLibM = YES
 718 then
 719   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 720 fi
 721
 722 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 723 dnl    the order of these tests matters: bfd needs liberty
 724 AC_CHECK_LIB(iberty, xmalloc)
 725 AC_CHECK_LIB(bfd,    bfd_init)
 726
 727 dnl ################################################################
 728 dnl Check for libraries
 729 dnl ################################################################
 730
 731 dnl ** check whether we need -ldl to get dlopen()
 732
 733 AC_CHECK_LIB(dl, dlopen,
 734     [HaveLibDL=YES
 735      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 736      LIBS="$LIBS -ldl"],
 737     [HaveLibDL=NO])
 738 AC_SUBST(HaveLibDL)
 739
 740 dnl --------------------------------------------------
 741 dnl * Miscellaneous feature tests
 742 dnl --------------------------------------------------
 743
 744 dnl ** can we get alloca?
 745 AC_FUNC_ALLOCA
 746
 747 dnl ** Working vfork?
 748 AC_FUNC_FORK
 749
 750 dnl ** determine whether or not const works
 751 AC_C_CONST
 752
 753 dnl ** are we big endian?
 754 AC_C_BIGENDIAN
 755 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 756
 757 dnl ** check for leading underscores in symbol names
 758 FP_LEADING_UNDERSCORE
 759
 760 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 761 FP_PROG_LD_X
 762 FP_PROG_LD_IS_GNU
 763
 764 dnl ** check for Apple-style dead-stripping support
 765 dnl    (.subsections-via-symbols assembler directive)
 766
 767
 768 AC_MSG_CHECKING(for .subsections_via_symbols)
 769 AC_COMPILE_IFELSE(
 770     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 771     [AC_MSG_RESULT(yes)
 772      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 773                [Define to 1 if Apple-style dead-stripping is supported.])
 774     ],
 775     [AC_MSG_RESULT(no)])
 776
 777 dnl *** check for GNU non-executable stack note support (ELF only)
 778 dnl     (.section .note.GNU-stack,"",@progbits)
 779
 780 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 781 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 782 dnl so we empty CFLAGS while running this test
 783 CFLAGS2="$CFLAGS"
 784 CFLAGS=
 785 AC_MSG_CHECKING(for GNU non-executable stack support)
 786 AC_COMPILE_IFELSE(
 787     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 788     [AC_MSG_RESULT(yes)
 789      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 790                [Define to 1 if GNU non-executable stack notes are supported.])
 791     ],
 792     [AC_MSG_RESULT(no)])
 793 CFLAGS="$CFLAGS2"
 794
 795 FP_VISIBILITY_HIDDEN
 796
 797 dnl ** check for librt
 798 AC_CHECK_LIB(rt, clock_gettime)
 799 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 800 FP_CHECK_TIMER_CREATE
 801
 802 dnl ** check for Apple's "interesting" long double compatibility scheme
 803 AC_MSG_CHECKING(for printf\$LDBLStub)
 804 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 805     [
 806         AC_MSG_RESULT(yes)
 807         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 808             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 809     ],
 810     [
 811         AC_MSG_RESULT(no)
 812         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 813             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 814     ])
 815
 816 dnl ** check for eventfd which is needed by the I/O manager
 817 AC_CHECK_HEADERS([sys/eventfd.h])
 818 AC_CHECK_FUNCS([eventfd])
 819
 820 # test for GTK+
 821 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 822 if test -n "$GTK_CONFIG"; then
 823   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 824     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 825   else
 826     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 827     GTK_CONFIG=
 828   fi
 829 fi
 830 AC_SUBST([GTK_CONFIG])
 831
 832 #Checking for PAPI
 833 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 834 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 835 AC_SUBST(HavePapiLib)
 836 AC_SUBST(HavePapiHeader)
 837
 838 AC_CHECK_FUNCS(__mingw_vfprintf)
 839
 840 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 841    HavePapi=YES
 842 else
 843    HavePapi=NO
 844 fi
 845 AC_SUBST(HavePapi)
 846
 847 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 848    test "$XsltprocCmd" = ""
 849 then
 850     BUILD_DOCBOOK_HTML=NO
 851 else
 852     BUILD_DOCBOOK_HTML=YES
 853 fi
 854 AC_SUBST(BUILD_DOCBOOK_HTML)
 855
 856 if test "$DblatexCmd" = ""
 857 then
 858     BUILD_DOCBOOK_PS=NO
 859     BUILD_DOCBOOK_PDF=NO
 860 else
 861     BUILD_DOCBOOK_PS=YES
 862     BUILD_DOCBOOK_PDF=YES
 863 fi
 864 AC_SUBST(BUILD_DOCBOOK_PS)
 865 AC_SUBST(BUILD_DOCBOOK_PDF)
 866
 867 LIBRARY_VERSION(base)
 868 LIBRARY_VERSION(Cabal)
 869 LIBRARY_VERSION(ghc-prim)
 870 LIBRARY_ghc_VERSION="$ProjectVersion"
 871 AC_SUBST(LIBRARY_ghc_VERSION)
 872
 873 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 874    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 875 fi
 876
 877 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 878 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 879 AC_OUTPUT
 880
 881 # We get caught by
 882 #     http://savannah.gnu.org/bugs/index.php?1516
 883 #     $(eval ...) inside conditionals causes errors
 884 # with make 3.80, so warn the user if it looks like they're about to
 885 # try to use it.
 886 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 887 checkMake380() {
 888     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 889     then
 890         echo
 891         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 892         echo "This version cannot be used to build GHC."
 893         echo "Please use GNU make >= 3.81."
 894     fi
 895 }
 896
 897 checkMake380 make
 898 checkMake380 gmake
 899
 900 echo ["
 901 ----------------------------------------------------------------------
 902 Configure completed successfully.
 903
 904    Building GHC version  : $ProjectVersion
 905
 906    Build platform        : $BuildPlatform
 907    Host platform         : $HostPlatform
 908    Target platform       : $TargetPlatform
 909 "]
 910
 911 if test "$BootingFromHc" = "YES"; then
 912 echo ["\
 913    Bootstrapping from HC files.
 914 "]
 915 else
 916 echo ["\
 917    Bootstrapping using   : $WithGhc
 918       which is version   : $GhcVersion
 919 "]
 920 fi
 921
 922 echo ["\
 923    Using GCC             : $WhatGccIsCalled
 924       which is version   : $GccVersion
 925
 926    ld       : $LdCmd
 927    Happy    : $HappyCmd ($HappyVersion)
 928    Alex     : $AlexCmd ($AlexVersion)
 929    Python   : $PythonCmd
 930    Perl     : $PerlCmd
 931    dblatex  : $DblatexCmd
 932    xsltproc : $XsltprocCmd"]
 933
 934 if test "$HSCOLOUR" = ""; then
 935 echo ["
 936    HsColour was not found; documentation will not contain source links
 937 "]
 938 else
 939 echo ["\
 940    HsColour : $HSCOLOUR
 941 "]
 942 fi
 943
 944 echo ["\
 945    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 946    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 947    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 948
 949 echo ["----------------------------------------------------------------------
 950 "]
 951
 952 echo "\
 953 For a standard build of GHC (fully optimised with profiling), type (g)make.
 954
 955 To make changes to the default build configuration, copy the file
 956 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 957
 958 For more information on how to configure your GHC build, see
 959    http://hackage.haskell.org/trac/ghc/wiki/Building
 960 "