configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot,
  95 [AC_HELP_STRING([--enable-hc-boot],
  96 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
  97  (This option is mostly of interest to porters.) [default=no]])],
  98 [ if test x"$enableval" = x"yes"; then
  99         BootingFromHc=YES
 100   else
 101         BootingFromHc=NO
 102   fi
 103 ],
 104 [BootingFromHc=NO]
 105 )
 106 AC_SUBST(BootingFromHc)
 107
 108 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 109 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 110                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 111         EnableBootstrapWithDevelSnaphost=YES,
 112         EnableBootstrapWithDevelSnaphost=NO
 113 )
 114
 115 if test "$WithGhc" != ""; then
 116   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 117
 118   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 119      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 120   fi
 121
 122   AC_SUBST(GhcVersion)dnl
 123   AC_SUBST(GhcMajVersion)dnl
 124   AC_SUBST(GhcMinVersion)dnl
 125   AC_SUBST(GhcPatchLevel)dnl
 126   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 127   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 128   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 129   AC_SUBST(ghc_ge_613)dnl
 130 fi
 131
 132 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 133 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 134   if test "$WithGhc" = ""; then
 135      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 136   fi
 137   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 138     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 139
 140   if test `expr $GhcMinVersion % 2` = "1"; then
 141      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 142         AC_MSG_ERROR([
 143      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 144      Bootstrapping using this version of GHC is not supported, and may not
 145      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 146      or --with-ghc to specify a different GHC to use.])
 147      fi
 148   fi
 149 fi;
 150
 151 # GHC is passed to Cabal, so we need a native path
 152 if test "${WithGhc}" != ""
 153 then
 154     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 155
 156     if test "$ghc_host" = "i386-unknown-mingw32"
 157     then
 158         if test "${OSTYPE}" = "msys"
 159         then
 160             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 161         else
 162             # Canonicalise to <drive>:/path/to/ghc
 163             WithGhc=`cygpath -m "${WithGhc}"`
 164         fi
 165         echo "GHC path canonicalised to: ${WithGhc}"
 166     fi
 167 fi
 168 AC_SUBST([WithGhc])
 169
 170 dnl ** Without optimization some INLINE trickery fails for GHCi
 171 SRC_CC_OPTS="-O"
 172
 173 FP_ICONV
 174 FP_GMP
 175
 176 dnl--------------------------------------------------------------------
 177 dnl * Choose host(/target/build) platform
 178 dnl--------------------------------------------------------------------
 179 dnl If we aren't explicitly told what values to use with configure flags,
 180 dnl we ask the bootstrapping compiler what platform it is for
 181
 182 if test "${WithGhc}" != ""
 183 then
 184         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 185         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 186         if test "$bootstrap_host" != "$bootstrap_target"
 187         then
 188                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 189         fi
 190 fi
 191
 192 # We have to run these unconditionally, but we may discard their
 193 # results in the following code
 194 AC_CANONICAL_BUILD
 195 AC_CANONICAL_HOST
 196 AC_CANONICAL_TARGET
 197
 198 # If no argument was given for a configuration variable, then discard
 199 # the guessed canonical system and use the configuration of the
 200 # bootstrapping ghc. If an argument was given, map it from gnu format
 201 # to ghc format.
 202 #
 203 # For why we do it this way, see: #3637, #1717, #2951
 204
 205 if test "$build_alias" = ""
 206 then
 207     if test "${WithGhc}" != ""
 208     then
 209         build=$bootstrap_target
 210         echo "Build platform inferred as: $build"
 211     else
 212         echo "Can't work out build platform"
 213         exit 1
 214     fi
 215
 216     BuildArch=`echo "$build" | sed 's/-.*//'`
 217     BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 218     BuildOS=`echo "$build" | sed 's/.*-//'`
 219 else
 220     GHC_CONVERT_CPU([$build_cpu], [BuildArch])
 221     GHC_CONVERT_VENDOR([$build_vendor], [BuildVendor])
 222     GHC_CONVERT_OS([$build_os], [BuildOS])
 223 fi
 224
 225 if test "$host_alias" = ""
 226 then
 227     if test "${WithGhc}" != ""
 228     then
 229         host=$bootstrap_target
 230         echo "Host platform inferred as: $host"
 231     else
 232         echo "Can't work out host platform"
 233         exit 1
 234     fi
 235
 236     HostArch=`echo "$host" | sed 's/-.*//'`
 237     HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 238     HostOS=`echo "$host" | sed 's/.*-//'`
 239 else
 240     GHC_CONVERT_CPU([$host_cpu], [HostArch])
 241     GHC_CONVERT_VENDOR([$host_vendor], [HostVendor])
 242     GHC_CONVERT_OS([$host_os], [HostOS])
 243 fi
 244
 245 if test "$target_alias" = ""
 246 then
 247     if test "${WithGhc}" != ""
 248     then
 249         target=$bootstrap_target
 250         echo "Target platform inferred as: $target"
 251     else
 252         echo "Can't work out target platform"
 253         exit 1
 254     fi
 255
 256     TargetArch=`echo "$target" | sed 's/-.*//'`
 257     TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 258     TargetOS=`echo "$target" | sed 's/.*-//'`
 259 else
 260     GHC_CONVERT_CPU([$target_cpu], [TargetArch])
 261     GHC_CONVERT_VENDOR([$target_vendor], [TargetVendor])
 262     GHC_CONVERT_OS([$target_os], [TargetOS])
 263 fi
 264
 265 exeext=''
 266 soext='.so'
 267 case $host in
 268 *-unknown-cygwin32)
 269     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 270     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 271     exit 1
 272     ;;
 273 *-unknown-mingw32)
 274     exeext='.exe'
 275     soext='.dll'
 276     ;;
 277 i386-apple-darwin|powerpc-apple-darwin)
 278     soext='.dylib'
 279     ;;
 280 x86_64-apple-darwin)
 281     soext='.dylib'
 282     ;;
 283 esac
 284
 285 # Sync this with cTargetArch in compiler/ghc.mk
 286 checkArch() {
 287     case $1 in
 288     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 289         ;;
 290     *)
 291         echo "Unknown arch $1"
 292         exit 1
 293         ;;
 294     esac
 295 }
 296
 297 checkVendor() {
 298     case $1 in
 299     dec|unknown|hp|apple|next|sun|sgi|ibm)
 300         ;;
 301     *)
 302         echo "Unknown vendor $1"
 303         exit 1
 304         ;;
 305     esac
 306 }
 307
 308 checkOS() {
 309     case $1 in
 310     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 311         ;;
 312     *)
 313         echo "Unknown OS '$1'"
 314         exit 1
 315         ;;
 316     esac
 317 }
 318
 319 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 320 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 321 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 322 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 323 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 324
 325 checkArch "$BuildArch"
 326 checkVendor "$BuildVendor"
 327 checkOS "$BuildOS"
 328
 329 HostPlatform="$HostArch-$HostVendor-$HostOS"
 330 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 331 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 332 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 333 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 334
 335 checkArch "$HostArch"
 336 checkVendor "$HostVendor"
 337 checkOS "$HostOS"
 338
 339 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 340 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 341 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 342 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 343 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 344
 345 checkArch "$TargetArch"
 346 checkVendor "$TargetVendor"
 347 checkOS "$TargetOS"
 348
 349 AC_SUBST(BuildPlatform)
 350 AC_SUBST(HostPlatform)
 351 AC_SUBST(TargetPlatform)
 352 AC_SUBST(HostPlatform_CPP)
 353 AC_SUBST(BuildPlatform_CPP)
 354 AC_SUBST(TargetPlatform_CPP)
 355
 356 AC_SUBST(HostArch_CPP)
 357 AC_SUBST(BuildArch_CPP)
 358 AC_SUBST(TargetArch_CPP)
 359
 360 AC_SUBST(HostOS_CPP)
 361 AC_SUBST(BuildOS_CPP)
 362 AC_SUBST(TargetOS_CPP)
 363
 364 AC_SUBST(HostVendor_CPP)
 365 AC_SUBST(BuildVendor_CPP)
 366 AC_SUBST(TargetVendor_CPP)
 367
 368 AC_SUBST(exeext)
 369 AC_SUBST(soext)
 370
 371 AC_ARG_WITH(hc,
 372 [AC_HELP_STRING([--with-hc=ARG],
 373         [Use ARG as the path to the compiler for compiling ordinary
 374          Haskell code  (default= value of --with-ghc)])],
 375 [WithHc="$withval"],
 376 [WithHc=$WithGhc]
 377 )
 378 AC_SUBST(WithHc)
 379
 380 # This uses GHC, so put it after the "GHC is required" check above:
 381 FP_INTREE_GHC_PWD
 382 FP_FIND_ROOT
 383
 384 if test "$HostOS" = "mingw32"
 385 then
 386     test -d inplace || mkdir inplace
 387
 388     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 389     LD="$hardtop/inplace/mingw/bin/ld.exe"
 390     NM="$hardtop/inplace/mingw/bin/nm.exe"
 391     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 392
 393     # NB. If you update the tarbballs to a new version of gcc, don't
 394     # forget to tweak the paths in driver/gcc/gcc.c.
 395     if ! test -d inplace/mingw ||
 396          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 397          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 398          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 399          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 400          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 401          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 402          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 403          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 404          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 405          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 406     then
 407         AC_MSG_NOTICE([Making in-tree mingw tree])
 408         rm -rf inplace/mingw
 409         mkdir inplace/mingw
 410         (
 411             cd inplace/mingw &&
 412             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 413             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 414             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 415             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 416             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 417             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 418             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 419             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 420             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 421             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 422             mv bin/gcc.exe bin/realgcc.exe
 423         )
 424         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 425         if ! test -e inplace/mingw/bin/gcc.exe
 426         then
 427             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 428         fi
 429         AC_MSG_NOTICE([In-tree mingw tree created])
 430     fi
 431     if ! test -d inplace/perl ||
 432          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 433     then
 434         AC_MSG_NOTICE([Making in-tree perl tree])
 435         rm -rf inplace/perl
 436         mkdir inplace
 437         mkdir inplace/perl
 438         (
 439             cd inplace/perl &&
 440             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 441         )
 442         AC_MSG_NOTICE([In-tree perl tree created])
 443     fi
 444 fi
 445
 446 dnl ** Which gcc to use?
 447 dnl --------------------------------------------------------------
 448 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 449 export CC
 450 WhatGccIsCalled="$CC"
 451 AC_SUBST(WhatGccIsCalled)
 452
 453 dnl ** Which ld to use?
 454 dnl --------------------------------------------------------------
 455 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 456 LdCmd="$LD"
 457 AC_SUBST([LdCmd])
 458
 459 dnl ** Which nm to use?
 460 dnl --------------------------------------------------------------
 461 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 462 NmCmd="$NM"
 463 AC_SUBST([NmCmd])
 464
 465 dnl ** Mac OS X: explicit deployment target
 466 dnl --------------------------------------------------------------
 467 AC_ARG_WITH([macosx-deployment-target],
 468 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 469         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 470 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 471  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 472    # ignore everywhere, but on Mac OS
 473    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 474    FP_MACOSX_DEPLOYMENT_TARGET=none
 475  fi],
 476 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 477 )
 478 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 479 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 480 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 481
 482 dnl --------------------------------------------------------------
 483 dnl End of configure script option section
 484 dnl --------------------------------------------------------------
 485
 486
 487 dnl --------------------------------------------------------------
 488 dnl * General configuration checks
 489 dnl --------------------------------------------------------------
 490
 491 dnl ** Can the unix package be built?
 492 dnl --------------------------------------------------------------
 493
 494 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 495    GhcLibsWithUnix=NO
 496 else
 497    GhcLibsWithUnix=YES
 498 fi
 499 AC_SUBST([GhcLibsWithUnix])
 500
 501 dnl ** does #! work?
 502 AC_SYS_INTERPRETER()
 503
 504 dnl ** look for `perl'
 505 case $HostOS_CPP in
 506 cygwin32|mingw32)
 507     PerlCmd=$hardtop/inplace/perl/perl
 508     ;;
 509 *)
 510     AC_PATH_PROG(PerlCmd,perl)
 511     if test -z "$PerlCmd"
 512     then
 513         echo "You must install perl before you can continue"
 514         echo "Perhaps it is already installed, but not in your PATH?"
 515         exit 1
 516     else
 517         FPTOOLS_CHECK_PERL_VERSION
 518     fi
 519     ;;
 520 esac
 521
 522 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 523 FPTOOLS_SHEBANG_PERL
 524
 525 dnl ** check for Python
 526 AC_PATH_PROG(PythonCmd,python)
 527
 528 dnl ** look for GCC and find out which version
 529 dnl     Figure out which C compiler to use.  Gcc is preferred.
 530 dnl     If gcc, make sure it's at least 2.1
 531 dnl
 532 FP_HAVE_GCC
 533
 534 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[CPPFLAGS])
 535 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_LD_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 536 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_LD_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 537 # Stage 3 won't be supported by cross-compilation
 538 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_LD_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 539
 540 FP_GCC_EXTRA_FLAGS
 541
 542 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 543 AC_PROG_CPP
 544
 545 AC_SUBST(CONF_CC_OPTS_STAGE0)
 546 AC_SUBST(CONF_CC_OPTS_STAGE1)
 547 AC_SUBST(CONF_CC_OPTS_STAGE2)
 548 AC_SUBST(CONF_LD_OPTS_STAGE0)
 549 AC_SUBST(CONF_LD_OPTS_STAGE1)
 550 AC_SUBST(CONF_LD_OPTS_STAGE2)
 551 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 552 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 553 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 554
 555 dnl ** figure out how to do context diffs
 556 FP_PROG_CONTEXT_DIFF
 557
 558 dnl Let's make sure install-sh is executable here.  If we got it from
 559 dnl a darcs repo, it might not be (see bug #978).
 560 chmod +x install-sh
 561 dnl ** figure out how to do a BSD-ish install
 562 AC_PROG_INSTALL
 563
 564 dnl If you can run configure, you certainly have /bin/sh
 565 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 566
 567 dnl ** how to invoke `ar' and `ranlib'
 568 FP_PROG_AR_SUPPORTS_ATFILE
 569 FP_PROG_AR_NEEDS_RANLIB
 570 FP_PROG_AR_SUPPORTS_INPUT
 571
 572 dnl ** Check to see whether ln -s works
 573 AC_PROG_LN_S
 574
 575
 576 dnl ** Find the path to sed
 577 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 578
 579
 580 dnl ** check for time command
 581 AC_PATH_PROG(TimeCmd,time)
 582
 583 dnl ** check for tar
 584 dnl   if GNU tar is named gtar, look for it first.
 585 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 586
 587 dnl ** check for patch
 588 dnl if GNU patch is named gpatch, look for it first
 589 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 590
 591 dnl ** check for dtrace (currently only implemented for Mac OS X)
 592 HaveDtrace=NO
 593 AC_PATH_PROG(DtraceCmd,dtrace)
 594 if test -n "$DtraceCmd"; then
 595   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple"; then
 596     HaveDtrace=YES
 597   fi
 598 fi
 599 AC_SUBST(HaveDtrace)
 600
 601 AC_PATH_PROG(HSCOLOUR,HsColour)
 602 # HsColour is passed to Cabal, so we need a native path
 603 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 604    test "${OSTYPE}"      != "msys"                  && \
 605    test "${HSCOLOUR}"    != ""
 606 then
 607     # Canonicalise to <drive>:/path/to/gcc
 608     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 609 fi
 610
 611 dnl ** check for DocBook toolchain
 612 FP_CHECK_DOCBOOK_DTD
 613 FP_DOCBOOK_XSL
 614 FP_PROG_DBLATEX
 615
 616 FP_PROG_HSTAGS
 617
 618 dnl ** check for ghc-pkg command
 619 FP_PROG_GHC_PKG
 620
 621 dnl ** check for installed happy binary + version
 622 dnl    (don't do it if we're booting from .hc files though.)
 623 if test "$BootingFromHc" = "NO"; then
 624 FPTOOLS_HAPPY
 625 fi;
 626
 627 dnl ** check for installed alex binary + version
 628 dnl    (don't do it if we're booting from .hc files though.)
 629 if test "$BootingFromHc" = "NO"; then
 630 FPTOOLS_ALEX
 631 fi;
 632
 633 dnl --------------------------------------------------
 634 dnl ### program checking section ends here ###
 635 dnl --------------------------------------------------
 636
 637 dnl --------------------------------------------------
 638 dnl * Platform header file and syscall feature tests
 639 dnl ### checking the state of the local header files and syscalls ###
 640
 641 dnl ** check for full ANSI header (.h) files
 642 AC_HEADER_STDC
 643
 644 dnl ** Enable large file support.  NB. do this before testing the type of
 645 dnl    off_t, because it will affect the result of that test.
 646 AC_SYS_LARGEFILE
 647
 648 dnl ** check for specific header (.h) files that we are interested in
 649 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 650
 651 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 652 AC_HEADER_TIME
 653
 654 dnl ** do we have long longs?
 655 AC_CHECK_TYPES([long long])
 656
 657 dnl ** what are the sizes of various types
 658 AC_CHECK_SIZEOF(char,               1)
 659 AC_CHECK_SIZEOF(double,             8)
 660 AC_CHECK_SIZEOF(float,              4)
 661 AC_CHECK_SIZEOF(int,                4)
 662 AC_CHECK_SIZEOF(long,               4)
 663 if test "$ac_cv_type_long_long" = yes; then
 664 AC_CHECK_SIZEOF(long long,          8)
 665 fi
 666 AC_CHECK_SIZEOF(short,              2)
 667 AC_CHECK_SIZEOF(unsigned char,      1)
 668 AC_CHECK_SIZEOF(unsigned int,       4)
 669 AC_CHECK_SIZEOF(unsigned long,      4)
 670 if test "$ac_cv_type_long_long" = yes; then
 671 AC_CHECK_SIZEOF(unsigned long long, 8)
 672 fi
 673 AC_CHECK_SIZEOF(unsigned short,     2)
 674 AC_CHECK_SIZEOF(void *,             4)
 675
 676 dnl ** what are alignment constraints on various types
 677 FP_CHECK_ALIGNMENT(char)
 678 FP_CHECK_ALIGNMENT(double)
 679 FP_CHECK_ALIGNMENT(float)
 680 FP_CHECK_ALIGNMENT(int)
 681 FP_CHECK_ALIGNMENT(long)
 682 if test "$ac_cv_type_long_long" = yes; then
 683 FP_CHECK_ALIGNMENT(long long)
 684 fi
 685 FP_CHECK_ALIGNMENT(short)
 686 FP_CHECK_ALIGNMENT(unsigned char)
 687 FP_CHECK_ALIGNMENT(unsigned int)
 688 FP_CHECK_ALIGNMENT(unsigned long)
 689 if test "$ac_cv_type_long_long" = yes; then
 690 FP_CHECK_ALIGNMENT(unsigned long long)
 691 fi
 692 FP_CHECK_ALIGNMENT(unsigned short)
 693 FP_CHECK_ALIGNMENT(void *)
 694
 695 FP_CHECK_FUNC([WinExec],
 696   [@%:@include <windows.h>], [WinExec("",0)])
 697
 698 FP_CHECK_FUNC([GetModuleFileName],
 699   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 700
 701 dnl ** check return type of signal handlers
 702 dnl Foo: assumes we can use prototypes.
 703 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 704 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 705 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 706 dnl #include <signal.h>
 707 dnl #ifdef signal
 708 dnl #undef signal
 709 dnl #endif
 710 dnl void (*signal (int, void (*)(int)))(int);
 711 dnl ]],
 712 dnl [[int i;]])],
 713 dnl [ac_cv_type_signal_handler=void_int],
 714 dnl [ac_cv_type_signal_handler=int_void])])
 715 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 716 dnl AC_DEFINE(VOID_INT_SIGNALS)
 717 dnl fi
 718
 719 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 720 AC_TYPE_SIGNAL
 721 if test "$ac_cv_type_signal" = void; then
 722   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 723 fi
 724
 725 dnl ** check for more functions
 726 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 727 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 728
 729 AC_TRY_RUN([
 730 #include <sys/types.h>
 731 #include <sys/time.h>
 732 int main(void) {
 733   struct itimerval tval;
 734   tval.it_value.tv_sec = 1;
 735   tval.it_value.tv_usec = 0;
 736   tval.it_interval = tval.it_value;
 737   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 738 }
 739 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 740
 741 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 742 dnl ** _POSIX_C_SOURCE is defined
 743 AC_CHECK_DECLS([ctime_r], , ,
 744 [#define _POSIX_SOURCE 1
 745 #define _POSIX_C_SOURCE 199506L
 746 #include <time.h>])
 747
 748 dnl ** check for mingwex library
 749 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 750 AC_SUBST(HaveLibMingwEx)
 751
 752 if test $HaveLibMingwEx = YES ; then
 753   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 754 fi
 755
 756 dnl ** check for math library
 757 dnl    Keep that check as early as possible.
 758 dnl    as we need to know whether we need libm
 759 dnl    for math functions or not
 760 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 761 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 762 if test $HaveLibM = YES
 763 then
 764   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 765 fi
 766
 767 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 768 dnl    the order of these tests matters: bfd needs liberty
 769 AC_CHECK_LIB(iberty, xmalloc)
 770 AC_CHECK_LIB(bfd,    bfd_init)
 771
 772 dnl ################################################################
 773 dnl Check for libraries
 774 dnl ################################################################
 775
 776 dnl ** check whether we need -ldl to get dlopen()
 777
 778 AC_CHECK_LIB(dl, dlopen,
 779     [HaveLibDL=YES
 780      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 781      LIBS="$LIBS -ldl"],
 782     [HaveLibDL=NO])
 783 AC_SUBST(HaveLibDL)
 784
 785 dnl --------------------------------------------------
 786 dnl * Miscellaneous feature tests
 787 dnl --------------------------------------------------
 788
 789 dnl ** can we get alloca?
 790 AC_FUNC_ALLOCA
 791
 792 dnl ** Working vfork?
 793 AC_FUNC_FORK
 794
 795 dnl ** determine whether or not const works
 796 AC_C_CONST
 797
 798 dnl ** are we big endian?
 799 AC_C_BIGENDIAN
 800 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 801
 802 dnl ** check for leading underscores in symbol names
 803 FP_LEADING_UNDERSCORE
 804
 805 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 806 FP_PROG_LD_X
 807 FP_PROG_LD_IS_GNU
 808
 809 dnl ** check for Apple-style dead-stripping support
 810 dnl    (.subsections-via-symbols assembler directive)
 811
 812
 813 AC_MSG_CHECKING(for .subsections_via_symbols)
 814 AC_COMPILE_IFELSE(
 815     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 816     [AC_MSG_RESULT(yes)
 817      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 818                [Define to 1 if Apple-style dead-stripping is supported.])
 819     ],
 820     [AC_MSG_RESULT(no)])
 821
 822 dnl *** check for GNU non-executable stack note support (ELF only)
 823 dnl     (.section .note.GNU-stack,"",@progbits)
 824
 825 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 826 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 827 dnl so we empty CFLAGS while running this test
 828 CFLAGS2="$CFLAGS"
 829 CFLAGS=
 830 AC_MSG_CHECKING(for GNU non-executable stack support)
 831 AC_COMPILE_IFELSE(
 832     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 833     [AC_MSG_RESULT(yes)
 834      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 835                [Define to 1 if GNU non-executable stack notes are supported.])
 836     ],
 837     [AC_MSG_RESULT(no)])
 838 CFLAGS="$CFLAGS2"
 839
 840 FP_VISIBILITY_HIDDEN
 841
 842 dnl ** check for librt
 843 AC_CHECK_LIB(rt, clock_gettime)
 844 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 845 FP_CHECK_TIMER_CREATE
 846
 847 dnl ** check for Apple's "interesting" long double compatibility scheme
 848 AC_MSG_CHECKING(for printf\$LDBLStub)
 849 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 850     [
 851         AC_MSG_RESULT(yes)
 852         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 853             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 854     ],
 855     [
 856         AC_MSG_RESULT(no)
 857         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 858             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 859     ])
 860
 861 dnl ** check for eventfd which is needed by the I/O manager
 862 AC_CHECK_HEADERS([sys/eventfd.h])
 863 AC_CHECK_FUNCS([eventfd])
 864
 865 # test for GTK+
 866 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 867 if test -n "$GTK_CONFIG"; then
 868   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 869     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 870   else
 871     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 872     GTK_CONFIG=
 873   fi
 874 fi
 875 AC_SUBST([GTK_CONFIG])
 876
 877 #Checking for PAPI
 878 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 879 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 880 AC_SUBST(HavePapiLib)
 881 AC_SUBST(HavePapiHeader)
 882
 883 AC_CHECK_FUNCS(__mingw_vfprintf)
 884
 885 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 886    HavePapi=YES
 887 else
 888    HavePapi=NO
 889 fi
 890 AC_SUBST(HavePapi)
 891
 892 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 893    test "$XsltprocCmd" = ""
 894 then
 895     BUILD_DOCBOOK_HTML=NO
 896 else
 897     BUILD_DOCBOOK_HTML=YES
 898 fi
 899 AC_SUBST(BUILD_DOCBOOK_HTML)
 900
 901 if test "$DblatexCmd" = ""
 902 then
 903     BUILD_DOCBOOK_PS=NO
 904     BUILD_DOCBOOK_PDF=NO
 905 else
 906     BUILD_DOCBOOK_PS=YES
 907     BUILD_DOCBOOK_PDF=YES
 908 fi
 909 AC_SUBST(BUILD_DOCBOOK_PS)
 910 AC_SUBST(BUILD_DOCBOOK_PDF)
 911
 912 LIBRARY_VERSION(base)
 913 LIBRARY_VERSION(Cabal)
 914 LIBRARY_VERSION(ghc-prim)
 915 LIBRARY_ghc_VERSION="$ProjectVersion"
 916 AC_SUBST(LIBRARY_ghc_VERSION)
 917
 918 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 919    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 920 fi
 921
 922 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac distrib/MacOS/installer-scripts/create-links distrib/MacOS/installer-scripts/Uninstaller distrib/MacOS/GHC-system.pmdoc/index.xml])
 923 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 924 AC_OUTPUT
 925
 926 # We get caught by
 927 #     http://savannah.gnu.org/bugs/index.php?1516
 928 #     $(eval ...) inside conditionals causes errors
 929 # with make 3.80, so warn the user if it looks like they're about to
 930 # try to use it.
 931 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 932 checkMake380() {
 933     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 934     then
 935         echo
 936         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 937         echo "This version cannot be used to build GHC."
 938         echo "Please use GNU make >= 3.81."
 939     fi
 940 }
 941
 942 checkMake380 make
 943 checkMake380 gmake
 944
 945 echo ["
 946 ----------------------------------------------------------------------
 947 Configure completed successfully.
 948
 949    Building GHC version  : $ProjectVersion
 950
 951    Build platform        : $BuildPlatform
 952    Host platform         : $HostPlatform
 953    Target platform       : $TargetPlatform
 954 "]
 955
 956 if test "$BootingFromHc" = "YES"; then
 957 echo ["\
 958    Bootstrapping from HC files.
 959 "]
 960 else
 961 echo ["\
 962    Bootstrapping using   : $WithGhc
 963       which is version   : $GhcVersion
 964 "]
 965 fi
 966
 967 echo ["\
 968    Using GCC             : $WhatGccIsCalled
 969       which is version   : $GccVersion
 970
 971    ld       : $LdCmd
 972    Happy    : $HappyCmd ($HappyVersion)
 973    Alex     : $AlexCmd ($AlexVersion)
 974    Python   : $PythonCmd
 975    Perl     : $PerlCmd
 976    dblatex  : $DblatexCmd
 977    xsltproc : $XsltprocCmd"]
 978
 979 if test "$HSCOLOUR" = ""; then
 980 echo ["
 981    HsColour was not found; documentation will not contain source links
 982 "]
 983 else
 984 echo ["\
 985    HsColour : $HSCOLOUR
 986 "]
 987 fi
 988
 989 echo ["\
 990    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 991    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 992    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 993
 994 echo ["----------------------------------------------------------------------
 995 "]
 996
 997 echo "\
 998 For a standard build of GHC (fully optimised with profiling), type (g)make.
 999
1000 To make changes to the default build configuration, copy the file
1001 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
1002
1003 For more information on how to configure your GHC build, see
1004    http://hackage.haskell.org/trac/ghc/wiki/Building
1005 "