configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [6.11], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'sh boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92 dnl ** Booting from unregisterised .hc files?
  93 dnl --------------------------------------------------------------
  94 AC_ARG_ENABLE(hc-boot-unregisterised,
  95 [AC_HELP_STRING([--enable-hc-boot-unregisterised],
  96 [ With --enable-hc-boot, treat the intermediate .hc files as
  97  unregisterised rather than registerised code.
  98  (This option is mostly of interest to porters.) [default=no]])],
  99 [ if test x"$enableval" = x"yes"; then
 100         BootingFromUnregisterisedHc=YES
 101   else
 102         BootingFromUnregisterisedHc=NO
 103   fi
 104 ],
 105 [BootingFromUnregisterisedHc=NO]
 106 )
 107 AC_SUBST(BootingFromUnregisterisedHc)
 108
 109 if test "$BootingFromHc" = "NO"; then
 110 if test "$BootingFromUnregisterisedHc" = "YES"; then
 111 AC_MSG_ERROR([--enable-hc-boot-unregisterised requires --enable-hc-boot.])
 112 fi;
 113 fi;
 114
 115 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 116 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 117   if test "$WithGhc" = ""; then
 118      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 119   fi
 120   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.8],
 121     [AC_MSG_ERROR([GHC version 6.8 or later is required to compile GHC.])])dnl
 122
 123   if test `expr $GhcMinVersion % 2` = "1"; then
 124      echo $EnableBootstrapWithDevelSnaphost
 125      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 126         AC_MSG_ERROR([
 127      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 128      Bootstrapping using this version of GHC is not supported, and may not
 129      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 130      or --with-ghc to specify a different GHC to use.])
 131      fi
 132   fi
 133 fi;
 134
 135 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 136 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 137                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 138         EnableBootstrapWithDevelSnaphost=YES,
 139         EnableBootstrapWithDevelSnaphost=NO
 140 )
 141
 142 if test "$WithGhc" != ""; then
 143   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 144
 145   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 146      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 147   fi
 148
 149   AC_SUBST(GhcVersion)dnl
 150   AC_SUBST(GhcMajVersion)dnl
 151   AC_SUBST(GhcMinVersion)dnl
 152   AC_SUBST(GhcPatchLevel)dnl
 153   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 154   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 155   if test $GhcCanonVersion -ge 609; then ghc_ge_609=YES; else ghc_ge_609=NO; fi
 156   AC_SUBST(ghc_ge_609)dnl
 157 fi
 158
 159 # GHC is passed to Cabal, so we need a native path
 160 if test "${WithGhc}" != ""
 161 then
 162     ghc_host=`${WithGhc} +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 163
 164     if test "$ghc_host" = "i386-unknown-mingw32"
 165     then
 166         if test "${OSTYPE}" = "msys"
 167         then
 168             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 169         else
 170             # Canonicalise to <drive>:/path/to/ghc
 171             WithGhc=`cygpath -m ${WithGhc}`
 172         fi
 173         echo "GHC path canonicalised to: ${WithGhc}"
 174     fi
 175 fi
 176 AC_SUBST([WithGhc])
 177
 178 dnl ** Without optimization some INLINE trickery fails for GHCi
 179 SRC_CC_OPTS="-O"
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl We don't use the standard autoconf macros for this, but instead
 185 dnl ask the bootstrapping compiler what platform it is for
 186
 187 dnl Guess host/target/build platform(s) if necessary.
 188 m4_divert_once([HELP_CANON],
 189 [[
 190 System types:
 191   --build=BUILD     configure for building on BUILD [guessed]
 192   --host=HOST       cross-compile to build programs to run on HOST [guessed]
 193   --target=TARGET   configure for building compilers for TARGET [guessed]]])dnl
 194
 195 if test "$build" = ""
 196 then
 197     if test "${WithGhc}" != ""
 198     then
 199         build=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 200         echo "Build platform inferred as: $build"
 201     else
 202         echo "Can't work out build platform"
 203         exit 1
 204     fi
 205 fi
 206
 207 if test "$host" = ""
 208 then
 209     if test "${WithGhc}" != ""
 210     then
 211         host=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 212         echo "Host platform inferred as: $host"
 213     else
 214         echo "Can't work out host platform"
 215         exit 1
 216     fi
 217 fi
 218
 219 if test "$target" = ""
 220 then
 221     if test "${WithGhc}" != ""
 222     then
 223         target=`${WithGhc} +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 224         echo "Target platform inferred as: $target"
 225     else
 226         echo "Can't work out target platform"
 227         exit 1
 228     fi
 229 fi
 230
 231 exeext=''
 232 soext='.so'
 233 case $host in
 234 *-unknown-cygwin32)
 235     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 236     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 237     exit 1
 238     ;;
 239 *-unknown-mingw32)
 240     exeext='.exe'
 241     soext='.dll'
 242     ;;
 243 i386-apple-darwin|powerpc-apple-darwin)
 244     soext='.dylib'
 245     ;;
 246 x86_64-apple-darwin)
 247     soext='.dylib'
 248     CFLAGS="$CFLAGS -m64"
 249     LDFLAGS="$LDFLAGS -m64"
 250     SRC_CC_OPTS="$SRC_CC_OPTS -m64"
 251     SRC_LD_OPTS="$SRC_LD_OPTS -m64"
 252     ;;
 253 esac
 254
 255 checkArch() {
 256     case $1 in
 257     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 258         ;;
 259     *)
 260         echo "Unknown arch $1"
 261         exit 1
 262         ;;
 263     esac
 264 }
 265
 266 checkVendor() {
 267     case $1 in
 268     dec|unknown|hp|apple|next|sun|sgi|ibm)
 269         ;;
 270     *)
 271         echo "Unknown vendor $1"
 272         exit 1
 273         ;;
 274     esac
 275 }
 276
 277 checkOS() {
 278     case $1 in
 279     linux|freebsd|netbsd|openbsd|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix)
 280         ;;
 281     *)
 282         echo "Unknown OS '$1'"
 283         exit 1
 284         ;;
 285     esac
 286 }
 287
 288 BuildPlatform=$build
 289 BuildArch=`echo "$build" | sed 's/-.*//'`
 290 BuildVendor=`echo "$build" | sed -e 's/.*-\(.*\)-.*/\1/'`
 291 BuildOS=`echo "$build" | sed 's/.*-//'`
 292 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 293 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 294 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 295 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 296
 297 checkArch "$BuildArch"
 298 checkVendor "$BuildVendor"
 299 checkOS "$BuildOS"
 300
 301 HostPlatform=$host
 302 HostArch=`echo "$host" | sed 's/-.*//'`
 303 HostVendor=`echo "$host" | sed -e 's/.*-\(.*\)-.*/\1/'`
 304 HostOS=`echo "$host" | sed 's/.*-//'`
 305 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 306 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 307 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 308 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 309
 310 checkArch "$HostArch"
 311 checkVendor "$HostVendor"
 312 checkOS "$HostOS"
 313
 314 TargetPlatform=$target
 315 TargetArch=`echo "$target" | sed 's/-.*//'`
 316 TargetVendor=`echo "$target" | sed -e 's/.*-\(.*\)-.*/\1/'`
 317 TargetOS=`echo "$target" | sed 's/.*-//'`
 318 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 319 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 320 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 321 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 322
 323 checkArch "$TargetArch"
 324 checkVendor "$TargetVendor"
 325 checkOS "$TargetOS"
 326
 327 AC_SUBST(BuildPlatform)
 328 AC_SUBST(HostPlatform)
 329 AC_SUBST(TargetPlatform)
 330 AC_SUBST(HostPlatform_CPP)
 331 AC_SUBST(BuildPlatform_CPP)
 332 AC_SUBST(TargetPlatform_CPP)
 333
 334 AC_SUBST(HostArch_CPP)
 335 AC_SUBST(BuildArch_CPP)
 336 AC_SUBST(TargetArch_CPP)
 337
 338 AC_SUBST(HostOS_CPP)
 339 AC_SUBST(BuildOS_CPP)
 340 AC_SUBST(TargetOS_CPP)
 341
 342 AC_SUBST(HostVendor_CPP)
 343 AC_SUBST(BuildVendor_CPP)
 344 AC_SUBST(TargetVendor_CPP)
 345
 346 AC_SUBST(exeext)
 347 AC_SUBST(soext)
 348
 349 AC_ARG_WITH(hc,
 350 [AC_HELP_STRING([--with-hc=ARG],
 351         [Use ARG as the path to the compiler for compiling ordinary
 352          Haskell code  (default= value of --with-ghc)])],
 353 [WithHc="$withval"],
 354 [WithHc=$WithGhc]
 355 )
 356 AC_SUBST(WithHc)
 357
 358 AC_PATH_PROGS(NHC,nhc nhc98)
 359 AC_PATH_PROG(HBC,hbc)
 360
 361 dnl ** Which gcc to use?
 362 dnl --------------------------------------------------------------
 363 AC_ARG_WITH(gcc,
 364 [AC_HELP_STRING([--with-gcc=ARG],
 365         [Use ARG as the path to GCC  [default=autodetect]])],
 366 [WhatGccIsCalled="$withval"
 367  if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 368     test "${OSTYPE}"      != "msys"                  && \
 369     test "${withval}"     != ""
 370  then
 371      # Canonicalise to <drive>:/path/to/gcc
 372      withval=`cygpath -m ${withval}`
 373  fi;
 374  CC="$withval"
 375  export CC
 376  ],
 377 [WhatGccIsCalled="gcc"]
 378 )
 379 AC_SUBST(WhatGccIsCalled)
 380
 381 dnl ** Which ld to use?
 382 dnl --------------------------------------------------------------
 383 AC_ARG_WITH(ld,
 384 [AC_HELP_STRING([--with-ld=ARG],
 385         [Use ARG as the path to LD  [default=autodetect]])],
 386 [if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 387     test "${OSTYPE}"      != "msys"                  && \
 388     test "${withval}"     != ""
 389  then
 390      # Canonicalise to <drive>:/path/to/ld
 391      withval=`cygpath -m ${withval}`
 392  fi;
 393  LD=$withval
 394  FP_PROG_LD([$LD])
 395  ],
 396  [FP_PROG_LD()]
 397 )
 398
 399 dnl ** Booting from .hc files?
 400 dnl --------------------------------------------------------------
 401 AC_ARG_ENABLE(hc-boot,
 402 [AC_HELP_STRING([--enable-hc-boot],
 403 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 404  (This option is mostly of interest to porters.) [default=no]])],
 405 [ if test x"$enableval" = x"yes"; then
 406         BootingFromHc=YES
 407   else
 408         BootingFromHc=NO
 409   fi
 410 ],
 411 [BootingFromHc=NO]
 412 )
 413 AC_SUBST(BootingFromHc)
 414
 415 # This uses GHC, so put it after the "GHC is required" check above:
 416 FP_FIND_ROOT
 417
 418 dnl ** Enable the construction of Win32 DLLs?
 419 dnl --------------------------------------------------------------
 420 dnl
 421 dnl [ The ability to build the RTS and libraries as separate DLLs used
 422 dnl   to be supported, but isn't currently (updates to the RTS, compiler
 423 dnl   and build system would be required to bring it back again.)
 424 dnl   Hence, exposing it as an option is false advertisement, so better
 425 dnl   disable it to avoid confusion (but leave it commented-out rather
 426 dnl   than removed in order to remind ourselves to bring back the
 427 dnl   feature at some stage.) ]
 428 dnl
 429 dnl AC_ARG_ENABLE(win32-dlls,
 430 dnl [  --enable-win32-dlls
 431 dnl         If on a Win32 platform running mingw32/cygwin, enable the
 432 dnl         construction of DLLs containing ghc-compiled code.
 433 dnl ],
 434 dnl [
 435 dnl case $HostOS_CPP in
 436 dnl cygwin32) ;;
 437 dnl mingw32)  ;;
 438 dnl *)    echo "Unrecognised win32 platform: $HostPlatform"
 439 dnl       exit 1
 440 dnl       ;;
 441 dnl esac
 442 dnl EnableWin32DLLs=YES
 443 dnl ],
 444 dnl [EnableWin32DLLs=NO]
 445 dnl )
 446 dnl AC_SUBST(EnableWin32DLLs)
 447 dnl if test x"$EnableWin32DLLs" = "xYES" ; then
 448 dnl  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 449 dnl fi
 450
 451 dnl ** Mac OS X: explicit deployment target
 452 dnl --------------------------------------------------------------
 453 AC_ARG_WITH([macosx-deployment-target],
 454 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 455         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 456 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 457  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 458    # ignore everywhere, but on Mac OS
 459    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 460    FP_MACOSX_DEPLOYMENT_TARGET=none
 461  fi],
 462 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 463 )
 464 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 465 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 466 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 467
 468 dnl --------------------------------------------------------------
 469 dnl End of configure script option section
 470 dnl --------------------------------------------------------------
 471
 472
 473 dnl --------------------------------------------------------------
 474 dnl * General configuration checks
 475 dnl --------------------------------------------------------------
 476
 477 dnl ** Can the unix package be built?
 478 dnl --------------------------------------------------------------
 479
 480 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 481    GhcLibsWithUnix=NO
 482 else
 483    GhcLibsWithUnix=YES
 484 fi
 485 AC_SUBST([GhcLibsWithUnix])
 486
 487 dnl ** does #! work?
 488 AC_SYS_INTERPRETER()
 489
 490 dnl ** look for `perl', but only in /bin on Windows
 491 case $HostOS_CPP in
 492 cygwin32|mingw32)
 493       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 494       if test -z "$PerlCmd"; then
 495          echo "You must install the version of Perl shipped with GHC"
 496          echo "(or a compatible one) in /bin."
 497          exit 1
 498       fi
 499    ;;
 500 *)
 501    AC_PATH_PROG(PerlCmd,perl)
 502    if test -z "$PerlCmd"; then
 503       echo "You must install perl before you can continue"
 504       echo "Perhaps it is already installed, but not in your PATH?"
 505       exit 1
 506    else
 507    FPTOOLS_CHECK_PERL_VERSION
 508    fi
 509    ;;
 510 esac
 511
 512 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 513 FPTOOLS_SHEBANG_PERL
 514
 515 dnl ** check for Python
 516 AC_PATH_PROG(PythonCmd,python)
 517
 518 dnl ** look for GCC and find out which version
 519 dnl     Figure out which C compiler to use.  Gcc is preferred.
 520 dnl     If gcc, make sure it's at least 2.1
 521 dnl
 522 FP_HAVE_GCC
 523 FP_MINGW_GCC
 524 FP_GCC_EXTRA_FLAGS
 525
 526 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 527 AC_PROG_CPP
 528
 529 AC_SUBST(SRC_CC_OPTS)
 530 AC_SUBST(SRC_LD_OPTS)
 531
 532 dnl ** figure out how to do context diffs
 533 FP_PROG_CONTEXT_DIFF
 534
 535 dnl Let's make sure install-sh is executable here.  If we got it from
 536 dnl a darcs repo, it might not be (see bug #978).
 537 chmod +x install-sh
 538 dnl ** figure out how to do a BSD-ish install
 539 AC_PROG_INSTALL
 540
 541 dnl If you can run configure, you certainly have /bin/sh
 542 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 543
 544 dnl ** how to invoke `ar' and `ranlib'
 545 FP_PROG_AR_NEEDS_RANLIB
 546 FP_PROG_AR_SUPPORTS_INPUT
 547
 548 dnl ** Check to see whether ln -s works
 549 AC_PROG_LN_S
 550
 551
 552 dnl ** Find the path to sed
 553 AC_PATH_PROG(SedCmd,sed)
 554
 555
 556 dnl ** check for time command
 557 AC_PATH_PROG(TimeCmd,time)
 558
 559 dnl ** check for tar
 560 dnl   if GNU tar is named gtar, look for it first.
 561 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 562
 563 dnl ** check for patch
 564 dnl if GNU patch is named gpatch, look for it first
 565 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 566
 567 AC_PATH_PROG(HSCOLOUR,HsColour)
 568 # HsColour is passed to Cabal, so we need a native path
 569 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 570    test "${OSTYPE}"      != "msys"                  && \
 571    test "${HSCOLOUR}"    != ""
 572 then
 573     # Canonicalise to <drive>:/path/to/gcc
 574     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 575 fi
 576
 577 dnl ** check for DocBook toolchain
 578 FP_CHECK_DOCBOOK_DTD
 579 FP_DOCBOOK_XSL
 580 FP_PROG_DBLATEX
 581
 582 FP_PROG_HSTAGS
 583
 584 dnl ** check for ghc-pkg command
 585 FP_PROG_GHC_PKG
 586
 587 dnl ** check for installed happy binary + version
 588 dnl    (don't do it if we're booting from .hc files though.)
 589 if test "$BootingFromHc" = "NO"; then
 590 FPTOOLS_HAPPY
 591 fi;
 592
 593 dnl ** check for installed alex binary + version
 594 dnl    (don't do it if we're booting from .hc files though.)
 595 if test "$BootingFromHc" = "NO"; then
 596 FPTOOLS_ALEX
 597 fi;
 598
 599 dnl Check we have an acceptable version of windres
 600 FPTOOLS_WINDRES
 601
 602 dnl --------------------------------------------------
 603 dnl ### program checking section ends here ###
 604 dnl --------------------------------------------------
 605
 606 dnl --------------------------------------------------
 607 dnl * Platform header file and syscall feature tests
 608 dnl ### checking the state of the local header files and syscalls ###
 609
 610 dnl ** check for full ANSI header (.h) files
 611 AC_HEADER_STDC
 612
 613 dnl ** Enable large file support.  NB. do this before testing the type of
 614 dnl    off_t, because it will affect the result of that test.
 615 AC_SYS_LARGEFILE
 616
 617 dnl ** check for specific header (.h) files that we are interested in
 618 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/mman.h sys/resource.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 619
 620 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 621 AC_HEADER_TIME
 622
 623 dnl ** do we have long longs?
 624 AC_CHECK_TYPES([long long])
 625
 626 dnl ** what are the sizes of various types
 627 AC_CHECK_SIZEOF(char,               1)
 628 AC_CHECK_SIZEOF(double,             8)
 629 AC_CHECK_SIZEOF(float,              4)
 630 AC_CHECK_SIZEOF(int,                4)
 631 AC_CHECK_SIZEOF(long,               4)
 632 if test "$ac_cv_type_long_long" = yes; then
 633 AC_CHECK_SIZEOF(long long,          8)
 634 fi
 635 AC_CHECK_SIZEOF(short,              2)
 636 AC_CHECK_SIZEOF(unsigned char,      1)
 637 AC_CHECK_SIZEOF(unsigned int,       4)
 638 AC_CHECK_SIZEOF(unsigned long,      4)
 639 if test "$ac_cv_type_long_long" = yes; then
 640 AC_CHECK_SIZEOF(unsigned long long, 8)
 641 fi
 642 AC_CHECK_SIZEOF(unsigned short,     2)
 643 AC_CHECK_SIZEOF(void *,             4)
 644
 645 dnl ** what are alignment constraints on various types
 646 FP_CHECK_ALIGNMENT(char)
 647 FP_CHECK_ALIGNMENT(double)
 648 FP_CHECK_ALIGNMENT(float)
 649 FP_CHECK_ALIGNMENT(int)
 650 FP_CHECK_ALIGNMENT(long)
 651 if test "$ac_cv_type_long_long" = yes; then
 652 FP_CHECK_ALIGNMENT(long long)
 653 fi
 654 FP_CHECK_ALIGNMENT(short)
 655 FP_CHECK_ALIGNMENT(unsigned char)
 656 FP_CHECK_ALIGNMENT(unsigned int)
 657 FP_CHECK_ALIGNMENT(unsigned long)
 658 if test "$ac_cv_type_long_long" = yes; then
 659 FP_CHECK_ALIGNMENT(unsigned long long)
 660 fi
 661 FP_CHECK_ALIGNMENT(unsigned short)
 662 FP_CHECK_ALIGNMENT(void *)
 663
 664 FP_CHECK_FUNC([WinExec],
 665   [@%:@include <windows.h>], [WinExec("",0)])
 666
 667 FP_CHECK_FUNC([GetModuleFileName],
 668   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 669
 670 dnl ** check return type of signal handlers
 671 dnl Foo: assumes we can use prototypes.
 672 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 673 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 674 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 675 dnl #include <signal.h>
 676 dnl #ifdef signal
 677 dnl #undef signal
 678 dnl #endif
 679 dnl void (*signal (int, void (*)(int)))(int);
 680 dnl ]],
 681 dnl [[int i;]])],
 682 dnl [ac_cv_type_signal_handler=void_int],
 683 dnl [ac_cv_type_signal_handler=int_void])])
 684 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 685 dnl AC_DEFINE(VOID_INT_SIGNALS)
 686 dnl fi
 687
 688 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 689 AC_TYPE_SIGNAL
 690 if test "$ac_cv_type_signal" = void; then
 691   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 692 fi
 693
 694 dnl ** check for more functions
 695 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 696 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 697
 698 AC_TRY_RUN([
 699 #include <sys/types.h>
 700 #include <sys/time.h>
 701 int main(void) {
 702   struct itimerval tval;
 703   tval.it_value.tv_sec = 1;
 704   tval.it_value.tv_usec = 0;
 705   tval.it_interval = tval.it_value;
 706   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 707 }
 708 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 709
 710 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 711 dnl ** _POSIX_C_SOURCE is defined
 712 AC_CHECK_DECLS([ctime_r], , ,
 713 [#define _POSIX_SOURCE 1
 714 #define _POSIX_C_SOURCE 199506L
 715 #include <time.h>])
 716
 717 dnl ** check for mingwex library
 718 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 719 AC_SUBST(HaveLibMingwEx)
 720
 721 if test $HaveLibMingwEx = YES ; then
 722   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 723 fi
 724
 725 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 726 dnl    the order of these tests matters: bfd needs liberty
 727 AC_CHECK_LIB(iberty, xmalloc)
 728 AC_CHECK_LIB(bfd,    bfd_init)
 729
 730 dnl ** check for math library
 731 AC_CHECK_FUNC(atan,[fp_libm_not_needed=yes;LIBM=],[fp_libm_not_needed=dunno])
 732 if test x"$fp_libm_not_needed" = xdunno; then
 733    AC_CHECK_LIB([m], [atan], [LIBS="-lm $LIBS"; LIBM="-lm"],[LIBM=])
 734 fi
 735 AC_SUBST([LIBM])
 736
 737 dnl ################################################################
 738 dnl Check for libraries
 739 dnl ################################################################
 740
 741 dnl ** check whether we need -ldl to get dlopen()
 742
 743 AC_CHECK_LIB(dl, dlopen,
 744     [HaveLibDL=YES
 745      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 746      LIBS="$LIBS -ldl"],
 747     [HaveLibDL=NO])
 748 AC_SUBST(HaveLibDL)
 749
 750 dnl --------------------------------------------------
 751 dnl * Miscellaneous feature tests
 752 dnl --------------------------------------------------
 753
 754 dnl ** can we get alloca?
 755 AC_FUNC_ALLOCA
 756
 757 dnl ** Working vfork?
 758 AC_FUNC_FORK
 759
 760 dnl ** determine whether or not const works
 761 AC_C_CONST
 762
 763 dnl ** are we big endian?
 764 AC_C_BIGENDIAN
 765 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 766
 767 dnl ** check for leading underscores in symbol names
 768 FP_LEADING_UNDERSCORE
 769
 770 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 771 FP_PROG_LD_X
 772 FP_PROG_LD_IS_GNU
 773
 774 dnl ** check for Apple-style dead-stripping support
 775 dnl    (.subsections-via-symbols assembler directive)
 776
 777
 778 AC_MSG_CHECKING(for .subsections_via_symbols)
 779 AC_COMPILE_IFELSE(
 780     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 781     [AC_MSG_RESULT(yes)
 782      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 783                [Define to 1 if Apple-style dead-stripping is supported.])
 784     ],
 785     [AC_MSG_RESULT(no)])
 786
 787 dnl *** check for GNU non-executable stack note support (ELF only)
 788 dnl     (.section .note.GNU-stack,"",@progbits)
 789
 790 AC_MSG_CHECKING(for GNU non-executable stack support)
 791 AC_COMPILE_IFELSE(
 792     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 793     [AC_MSG_RESULT(yes)
 794      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 795                [Define to 1 if GNU non-executable stack notes are supported.])
 796     ],
 797     [AC_MSG_RESULT(no)])
 798
 799 dnl ** check for librt
 800 AC_CHECK_LIB(rt, clock_gettime)
 801 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 802 FP_CHECK_TIMER_CREATE
 803
 804 dnl ** check for Apple's "interesting" long double compatibility scheme
 805 AC_MSG_CHECKING(for printf\$LDBLStub)
 806 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 807     [
 808         AC_MSG_RESULT(yes)
 809         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 810             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 811     ],
 812     [
 813         AC_MSG_RESULT(no)
 814         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 815             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 816     ])
 817
 818 # test for GTK+
 819 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 820 if test -n "$GTK_CONFIG"; then
 821   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 822     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 823   else
 824     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 825     GTK_CONFIG=
 826   fi
 827 fi
 828 AC_SUBST([GTK_CONFIG])
 829
 830 #Checking for PAPI
 831 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 832 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 833 AC_SUBST(HavePapiLib)
 834 AC_SUBST(HavePapiHeader)
 835
 836 AC_CHECK_FUNCS(__mingw_vfprintf)
 837
 838 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 839    HavePapi=YES
 840 else
 841    HavePapi=NO
 842 fi
 843 AC_SUBST(HavePapi)
 844
 845 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 846    test "$XsltprocCmd" = ""
 847 then
 848     BUILD_DOCBOOK_HTML=NO
 849 else
 850     BUILD_DOCBOOK_HTML=YES
 851 fi
 852 AC_SUBST(BUILD_DOCBOOK_HTML)
 853
 854 if test "$DblatexCmd" = ""
 855 then
 856     BUILD_DOCBOOK_PS=NO
 857     BUILD_DOCBOOK_PDF=NO
 858 else
 859     BUILD_DOCBOOK_PS=YES
 860     BUILD_DOCBOOK_PDF=YES
 861 fi
 862 AC_SUBST(BUILD_DOCBOOK_PS)
 863 AC_SUBST(BUILD_DOCBOOK_PDF)
 864
 865 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 866    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 867 fi
 868
 869 AC_CONFIG_FILES([mk/config.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml distrib/ghc.iss])
 870 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 871 AC_OUTPUT
 872
 873 # We get caught by
 874 #     http://savannah.gnu.org/bugs/index.php?1516
 875 #     $(eval ...) inside conditionals causes errors
 876 # with make 3.80, so warn the user if it looks like they're about to
 877 # try to use it.
 878 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 879 checkMake380() {
 880     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 881     then
 882         echo
 883         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 884         echo "This version cannot be used to build GHC."
 885         echo "Please use GNU make >= 3.81."
 886     fi
 887 }
 888
 889 checkMake380 make
 890 checkMake380 gmake
 891
 892 echo ["
 893 ----------------------------------------------------------------------
 894 Configure completed successfully.
 895
 896    Building GHC version  : $ProjectVersion
 897
 898    Build platform        : $BuildPlatform
 899    Host platform         : $HostPlatform
 900    Target platform       : $TargetPlatform
 901 "]
 902
 903 if test "$BootingFromHc" = "YES"; then
 904 echo ["\
 905    Bootstrapping from HC files.
 906 "]
 907 else
 908 echo ["\
 909    Bootstrapping using   : $WithGhc
 910       which is version   : $GhcVersion
 911 "]
 912 fi
 913
 914 echo ["\
 915    Using GCC             : $WhatGccIsCalled
 916       which is version   : $GccVersion
 917
 918    ld       : $LdCmd
 919    Happy    : $HappyCmd ($HappyVersion)
 920    Alex     : $AlexCmd ($AlexVersion)
 921    Python   : $PythonCmd
 922    Perl     : $PerlCmd
 923    dblatex  : $DblatexCmd
 924    xsltproc : $XsltprocCmd"]
 925
 926 if test "$HSCOLOUR" = ""; then
 927 echo ["
 928    HsColour was not found; documentation will not contain source links
 929 "]
 930 else
 931 echo ["\
 932    HsColour : $HSCOLOUR
 933 "]
 934 fi
 935
 936 echo ["\
 937    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 938    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 939    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF
 940
 941    Building shared libraries           : $BuildSharedLibs"]
 942
 943 echo ["----------------------------------------------------------------------
 944 "]
 945
 946 echo "\
 947 For a standard build of GHC (fully optimised with profiling), type (g)make.
 948
 949 To make changes to the default build configuration, copy the file
 950 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 951
 952 For more information on how to configure your GHC build, see
 953    http://hackage.haskell.org/trac/ghc/wiki/Building
 954 "