configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * We require autoconf version 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE
  20 AC_PREREQ(2.50)
  21
  22 dnl * Declare subdirectories that have a private configure script
  23 dnl
  24 dnl After the toplevel configuration is complete, the script will recurse into
  25 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  26 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  27 AC_CONFIG_SUBDIRS(ghc)
  28
  29 # -------------------------------------------------------------------------
  30 # Prepare to generate the following header files
  31 #
  32 #
  33 AC_CONFIG_HEADER(mk/config.h)
  34
  35 # No, semi-sadly, we don't do `--srcdir'...
  36 if test x"$srcdir" != 'x.' ; then
  37     echo "This configuration does not support the \`--srcdir' option.."
  38     exit 1
  39 fi
  40
  41 dnl--------------------------------------------------------------------
  42 dnl * Choose host(/target/build) platform
  43 dnl--------------------------------------------------------------------
  44
  45 dnl Guess host/target/build platform(s) if necessary.
  46 AC_CANONICAL_SYSTEM
  47
  48 # "$host" defaults to "$target"
  49 if test "x$host" = xNONE ; then
  50     host=$target
  51 fi
  52
  53 dnl ** canonicalize platform names
  54 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  55 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  56 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  57
  58 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  59     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  60     exit 1
  61 fi
  62
  63 exeext=''
  64 #
  65 # The following will be more difficult when we *are* cross-compiling.
  66 # Suitable names to slam in *_CPP are in platform.h.in.
  67 # We also record the architecture, vendor, and operating system (OS)
  68 # separately.
  69 case $HostPlatform in
  70 alpha*-dec-osf[[12]]*)
  71         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  72         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  73         BuildPlatform=alpha-dec-osf1  # hack
  74         HostPlatform_CPP='alpha_dec_osf1'
  75         HostArch_CPP='alpha'
  76         HostVendor_CPP='dec'
  77         HostOS_CPP='osf1'
  78         ;;
  79 alpha*-dec-osf[[345]]*)
  80         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  81         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  82         BuildPlatform=alpha-dec-osf3  # hack
  83         HostPlatform_CPP='alpha_dec_osf3'
  84         HostArch_CPP='alpha'
  85         HostVendor_CPP='dec'
  86         HostOS_CPP='osf3'
  87         ;;
  88 alpha*-unknown-linux*)
  89         HostPlatform=alpha-unknown-linux
  90         TargetPlatform=alpha-unknown-linux
  91         BuildPlatform=alpha-unknown-linux
  92         HostPlatform_CPP='alpha_unknown_linux'
  93         HostArch_CPP='alpha'
  94         HostVendor_CPP='unknown'
  95         HostOS_CPP='linux'
  96         ;;
  97 alpha*-unknown-freebsd*)
  98         HostPlatform=alpha-unknown-freebsd
  99         TargetPlatform=alpha-unknown-freebsd
 100         BuildPlatform=alpha-unknown-freebsd
 101         HostPlatform_CPP='alpha_unknown_freebsd'
 102         HostArch_CPP='alpha'
 103         HostVendor_CPP='unknown'
 104         HostOS_CPP='freebsd'
 105         ;;
 106 hppa1.1-hp-hpux*)
 107         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 108         TargetPlatform=hppa1.1-hp-hpux
 109         BuildPlatform=hppa1.1-hp-hpux
 110         HostPlatform_CPP='hppa1_1_hp_hpux'
 111         HostArch_CPP='hppa1_1'
 112         HostVendor_CPP='hp'
 113         HostOS_CPP='hpux'
 114         ;;
 115 i[[3456]]86-*-linuxaout*)
 116         HostPlatform=i386-unknown-linuxaout   # hack again
 117         TargetPlatform=i386-unknown-linuxaout
 118         BuildPlatform=i386-unknown-linuxaout
 119         HostPlatform_CPP='i386_unknown_linuxaout'
 120         HostArch_CPP='i386'
 121         HostVendor_CPP='unknown'
 122         HostOS_CPP='linuxaout'
 123         ;;
 124 i[[3456]]86-*-linux*)
 125         HostPlatform=i386-unknown-linux # hack again
 126         TargetPlatform=i386-unknown-linux
 127         BuildPlatform=i386-unknown-linux
 128         HostPlatform_CPP='i386_unknown_linux'
 129         HostArch_CPP='i386'
 130         HostVendor_CPP='unknown'
 131         HostOS_CPP='linux'
 132         ;;
 133 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 134         HostPlatform=i386-unknown-freebsd # hack again
 135         TargetPlatform=i386-unknown-freebsd
 136         BuildPlatform=i386-unknown-freebsd
 137         HostPlatform_CPP='i386_unknown_freebsd'
 138         HostArch_CPP='i386'
 139         HostVendor_CPP='unknown'
 140         HostOS_CPP='freebsd'
 141         ;;
 142 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 143         HostPlatform=i386-unknown-freebsd2 # hack again
 144         TargetPlatform=i386-unknown-freebsd2
 145         BuildPlatform=i386-unknown-freebsd2
 146         HostPlatform_CPP='i386_unknown_freebsd2'
 147         HostArch_CPP='i386'
 148         HostVendor_CPP='unknown'
 149         HostOS_CPP='freebsd2'
 150         ;;
 151 i[[3456]]86-*-netbsd*)
 152         HostPlatform=i386-unknown-netbsd # hack again
 153         TargetPlatform=i386-unknown-netbsd
 154         BuildPlatform=i386-unknown-netbsd
 155         HostPlatform_CPP='i386_unknown_netbsd'
 156         HostArch_CPP='i386'
 157         HostVendor_CPP='unknown'
 158         HostOS_CPP='netbsd'
 159         ;;
 160 i[[3456]]86-*-openbsd*)
 161         HostPlatform=i386-unknown-openbsd # hack again
 162         TargetPlatform=i386-unknown-openbsd
 163         BuildPlatform=i386-unknown-openbsd
 164         HostPlatform_CPP='i386_unknown_openbsd'
 165         HostArch_CPP='i386'
 166         HostVendor_CPP='unknown'
 167         HostOS_CPP='openbsd'
 168         ;;
 169 i[[3456]]86-*-solaris2*)
 170         HostPlatform=i386-unknown-solaris2 # hack again
 171         TargetPlatform=i386-unknown-solaris2
 172         BuildPlatform=i386-unknown-solaris2
 173         HostPlatform_CPP='i386_unknown_solaris2'
 174         HostArch_CPP='i386'
 175         HostVendor_CPP='unknown'
 176         HostOS_CPP='solaris2'
 177         ;;
 178 i[[3456]]86-*-cygwin*)
 179         HostPlatform=i386-unknown-cygwin32 # hack again
 180         TargetPlatform=i386-unknown-cygwin32
 181         BuildPlatform=i386-unknown-cygwin32
 182         HostPlatform_CPP='i386_unknown_cygwin32'
 183         HostArch_CPP='i386'
 184         HostVendor_CPP='unknown'
 185         HostOS_CPP='cygwin32'
 186         exeext='.exe'
 187         ;;
 188 i[[3456]]86-*-mingw32*)
 189         HostPlatform=i386-unknown-mingw32 # hack again
 190         TargetPlatform=i386-unknown-mingw32
 191         BuildPlatform=i386-unknown-mingw32
 192         HostPlatform_CPP='i386_unknown_mingw32'
 193         HostArch_CPP='i386'
 194         HostVendor_CPP='unknown'
 195         HostOS_CPP='mingw32'
 196         exeext='.exe'
 197         ;;
 198 ia64-*-linux*)
 199         HostPlatform=ia64-unknown-linux # hack again
 200         TargetPlatform=ia64-unknown-linux
 201         BuildPlatform=ia64-unknown-linux
 202         HostPlatform_CPP='ia64_unknown_linux'
 203         HostArch_CPP='ia64'
 204         HostVendor_CPP='unknown'
 205         HostOS_CPP='linux'
 206         ;;
 207 m68k-next-nextstep2)
 208         HostPlatform_CPP='m68k_next_nextstep2'
 209         HostArch_CPP='m68k'
 210         HostVendor_CPP='next'
 211         HostOS_CPP='nextstep2'
 212         ;;
 213 m68k-next-nextstep3)
 214         HostPlatform_CPP='m68k_next_nextstep3'
 215         HostArch_CPP='m68k'
 216         HostVendor_CPP='next'
 217         HostOS_CPP='nextstep3'
 218         ;;
 219 i[[3456]]86-next-nextstep3)
 220         HostPlatform=i386-next-nextstep3 # hack again
 221         TargetPlatform=i386-next-nextstep3
 222         BuildPlatform=i386-next-nextstep3
 223         HostPlatform_CPP='i386_next_nextstep3'
 224         HostArch_CPP='i386'
 225         HostVendor_CPP='next'
 226         HostOS_CPP='nextstep3'
 227         ;;
 228 m68k-*-openbsd*)
 229         HostPlatform=m68k-unknown-openbsd
 230         TargetPlatform=m68k-unknown-openbsd
 231         BuildPlatform=m68k-unknown-openbsd
 232         HostPlatform_CPP='m68k_unknown_openbsd'
 233         HostArch_CPP='m68k'
 234         HostVendor_CPP='unknown'
 235         HostOS_CPP='openbsd'
 236         ;;
 237 m68k-apple-netbsd*)
 238         HostPlatform=m68k-apple-netbsd
 239         TargetPlatform=m68k-apple-netbsd
 240         BuildPlatform=m68k-apple-netbsd
 241         HostPlatform_CPP='m68k_apple_netbsd'
 242         HostArch_CPP='m68k'
 243         HostVendor_CPP='apple'
 244         HostOS_CPP='netbsd'
 245         ;;
 246 m68k-sun-sunos4*)
 247         HostPlatform=m68k-sun-sunos4
 248         TargetPlatform=m68k-sun-sunos4 #hack
 249         BuildPlatform=m68k-sun-sunos4 #hack
 250         HostPlatform_CPP='m68k_sun_sunos4'
 251         HostArch_CPP='m68k'
 252         HostVendor_CPP='sun'
 253         HostOS_CPP='sunos4'
 254         ;;
 255 mips-dec-ultrix*)
 256         HostPlatform_CPP='mips_dec_ultrix'
 257         HostArch_CPP='mipsel'   # NB a little different
 258         HostVendor_CPP='dec'
 259         HostOS_CPP='ultrix'
 260         ;;
 261 mips-sgi-irix*)
 262         HostPlatform=mips-sgi-irix
 263         TargetPlatform=mips-sgi-irix #hack
 264         BuildPlatform=mips-sgi-irix #hack
 265         HostPlatform_CPP='mips_sgi_irix'
 266         HostArch_CPP='mipseb'   # NB a little different
 267         HostVendor_CPP='sgi'
 268         HostOS_CPP='irix'
 269         ;;
 270 rs6000-ibm-aix*)
 271         HostPlatform=rs6000-ibm-aix
 272         TargetPlatform=rs6000-ibm-aix #hack
 273         BuildPlatform=rs6000-ibm-aix #hack
 274         HostPlatform_CPP='rs6000_ibm_aix'
 275         HostArch_CPP='rs6000'
 276         HostVendor_CPP='ibm'
 277         HostOS_CPP='aix'
 278         ;;
 279 powerpc-ibm-aix*)
 280         HostPlatform=powerpc-ibm-aix
 281         TargetPlatform=powerpc-ibm-aix #hack
 282         BuildPlatform=powerpc-ibm-aix #hack
 283         HostPlatform_CPP='powerpc_ibm_aix'
 284         HostArch_CPP='powerpc'
 285         HostVendor_CPP='ibm'
 286         HostOS_CPP='aix'
 287         ;;
 288 powerpc-apple-darwin*)
 289         HostPlatform=powerpc-apple-darwin
 290         TargetPlatform=powerpc-apple-darwin #hack
 291         BuildPlatform=powerpc-apple-darwin #hack
 292         HostPlatform_CPP='powerpc_apple_darwin'
 293         HostArch_CPP='powerpc'
 294         HostVendor_CPP='apple'
 295         HostOS_CPP='darwin'
 296         ;;
 297 sparc-sun-sunos4*)
 298         HostPlatform=sparc-sun-sunos4
 299         TargetPlatform=sparc-sun-sunos4 #hack
 300         BuildPlatform=sparc-sun-sunos4 #hack
 301         HostPlatform_CPP='sparc_sun_sunos4'
 302         HostArch_CPP='sparc'
 303         HostVendor_CPP='sun'
 304         HostOS_CPP='sunos4'
 305         ;;
 306 sparc-sun-solaris2*)
 307         HostPlatform=sparc-sun-solaris2
 308         TargetPlatform=sparc-sun-solaris2 #hack
 309         BuildPlatform=sparc-sun-solaris2 #hack
 310         HostPlatform_CPP='sparc_sun_solaris2'
 311         HostArch_CPP='sparc'
 312         HostVendor_CPP='sun'
 313         HostOS_CPP='solaris2'
 314         ;;
 315 sparc*-linux*)
 316         HostPlatform=sparc-unknown-linux
 317         TargetPlatform=sparc-unknown-linux
 318         BuildPlatform=sparc-unknown-linux
 319         HostPlatform_CPP='sparc_unknown_linux'
 320         HostArch_CPP='sparc'
 321         HostVendor_CPP='unknown'
 322         HostOS_CPP='linux'
 323         ;;
 324 sparc-*-openbsd*)
 325         HostPlatform=sparc-unknown-openbsd
 326         TargetPlatform=sparc-unknown-openbsd
 327         BuildPlatform=sparc-unknown-openbsd
 328         HostPlatform_CPP='sparc_unknown_openbsd'
 329         HostArch_CPP='sparc'
 330         HostVendor_CPP='unknown'
 331         HostOS_CPP='openbsd'
 332         ;;
 333 *)
 334         echo "Unrecognised platform: $HostPlatform"
 335         exit 1
 336         ;;
 337 esac
 338 echo "Canonicalised to: $HostPlatform"
 339 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 340 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 341
 342 BuildPlatform_CPP=$HostPlatform_CPP
 343 TargetPlatform_CPP=$HostPlatform_CPP
 344 BuildArch_CPP=$HostArch_CPP
 345 TargetArch_CPP=$HostArch_CPP
 346 BuildOS_CPP=$HostOS_CPP
 347 HostOS_Full=$host_os
 348 TargetOS_CPP=$HostOS_CPP
 349 BuildVendor_CPP=$HostVendor_CPP
 350 TargetVendor_CPP=$HostVendor_CPP
 351
 352 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 353 dnl AC_SUBST(BuildPlatform)
 354
 355 AC_SUBST(HostPlatform)
 356 AC_SUBST(TargetPlatform)
 357 AC_SUBST(HostPlatform_CPP)
 358 dnl AC_SUBST(BuildPlatform_CPP)
 359 dnl AC_SUBST(TargetPlatform_CPP)
 360
 361 AC_SUBST(HostArch_CPP)
 362 dnl AC_SUBST(BuildArch_CPP)
 363 dnl AC_SUBST(TargetArch_CPP)
 364
 365 AC_SUBST(HostOS_CPP)
 366 AC_SUBST(HostOS_Full)
 367 dnl AC_SUBST(BuildOS_CPP)
 368 dnl AC_SUBST(TargetOS_CPP)
 369
 370 AC_SUBST(HostVendor_CPP)
 371 dnl AC_SUBST(BuildVendor_CPP)
 372 dnl AC_SUBST(TargetVendor_CPP)
 373
 374 AC_SUBST(exeext)
 375
 376 dnl --------------------------------------------------------------
 377 dnl * Calculate absolute path to build tree
 378 dnl --------------------------------------------------------------
 379
 380 AC_MSG_CHECKING(for path to top of build tree)
 381
 382 hardtop=`pwd`
 383
 384 dnl Remove common automounter nonsense
 385 dnl
 386 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^//\(.\)/|\1:/|' `
 387
 388 dnl Find 'hardtop_plat', the native format for 'hardtop' (i.e., right kind of \dnl slashes on a Win32 box, but with b-slashes being escaped).
 389 dnl
 390 case $HostPlatform in
 391   i386-unknown-mingw32 | i386-unknown-cygwin32)
 392         # convert $hardtop to a path that mingw will understand too
 393         cyghardtop=${hardtop}
 394         hardtop=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@/@g'`
 395         hardtop_plat=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@\\\\\\\\@g'`
 396         ;;
 397   *)
 398         hardtop_plat=${hardtop}
 399         ;;
 400 esac
 401 AC_SUBST(hardtop)
 402 AC_SUBST(hardtop_plat)
 403
 404 AC_MSG_RESULT(${hardtop})
 405
 406 dnl --------------------------------------------------------------
 407 dnl * Project specific configuration options
 408 dnl --------------------------------------------------------------
 409 dnl What follows is a bunch of options that can either be configured
 410 dnl through command line options to the configure script or by
 411 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 412 dnl use either is considered a Feature.
 413
 414 dnl ** What command to use to compile compiler sources ?
 415 dnl --------------------------------------------------------------
 416
 417 AC_ARG_WITH(ghc,
 418 [  --with-ghc=<haskell compiler>
 419         Use a command different from 'ghc' to compile GHC-specific Haskell code
 420             (including GHC itself).
 421 ],
 422 [ WithGhc="$withval" ],
 423 [
 424   if test "$GHC" = ""; then
 425     AC_PATH_PROG(GHC,ghc)
 426   fi
 427   WithGhc=$GHC
 428 ]
 429 )
 430 AC_SUBST(WithGhc)
 431
 432 AC_ARG_WITH(hc,
 433 [  --with-hc=<haskell compiler>
 434         Use a command different from 'ghc' to compile generic Haskell code.
 435 ],
 436 [WithHc="$withval"],
 437 [WithHc=$WithGhc]
 438 )
 439 AC_SUBST(WithHc)
 440
 441 if test "$WithGhc" != ""; then
 442   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 443   AC_SUBST(GhcVersion)dnl
 444   AC_SUBST(GhcMajVersion)dnl
 445   AC_SUBST(GhcMinVersion)dnl
 446   AC_SUBST(GhcPatchLevel)dnl
 447 fi
 448
 449 AC_PATH_PROGS(NHC,nhc nhc98)
 450 AC_PATH_PROG(HBC,hbc)
 451
 452 dnl ** Which gcc to use?
 453 dnl --------------------------------------------------------------
 454 AC_ARG_WITH(gcc,
 455 [  --with-gcc=<gcc command>
 456         Use a different command instead of 'gcc' for the GNU C compiler.
 457 ],
 458 [WhatGccIsCalled="$withval"
 459  if test "x$HostPlatform" = "xi386-unknown-mingw32"; then
 460     # Canonicalise to <drive>:/path/to/gcc
 461     withval=`cygpath -w ${withval} | sed -e 's@\\\\@/@g' `
 462  fi;
 463  CC="$withval"],
 464 [WhatGccIsCalled="gcc"]
 465 )
 466 AC_SUBST(WhatGccIsCalled)
 467
 468 dnl ** Booting from .hc files?
 469 dnl --------------------------------------------------------------
 470 AC_ARG_ENABLE(hc-boot,
 471 [  --enable-hc-boot
 472         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 473         (This option is mostly of interest to porters.)
 474 ],
 475 [BootingFromHc=YES],
 476 [BootingFromHc=NO]
 477 )
 478 AC_SUBST(BootingFromHc)
 479
 480 dnl ** Booting from unregisterised .hc files?
 481 dnl --------------------------------------------------------------
 482 AC_ARG_ENABLE(hc-boot-unregisterised,
 483 [  --enable-hc-boot-unregisterised
 484         With --enable-hc-boot, treat the intermediate .hc files as
 485         unregisterised rather than registerised code.
 486         (This option is mostly of interest to porters.)
 487 ],
 488 [BootingFromUnregisterisedHc=YES],
 489 [BootingFromUnregisterisedHc=NO]
 490 )
 491 AC_SUBST(BootingFromUnregisterisedHc)
 492
 493 if test "$BootingFromHc" = "NO"; then
 494 if test "$BootingFromUnregisterisedHc" = "YES"; then
 495 AC_MSG_ERROR([--enable-hc-boot-unregisterised requires --enable-hc-boot.])
 496 fi;
 497 fi;
 498
 499 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 500 if test "$BootingFromHc" = "NO" -a "$WithGhc" = "" -a -d "$srcdir/ghc"; then
 501 AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 502 fi;
 503
 504 dnl ** Enable multi-thread friendly RTS?
 505 dnl --------------------------------------------------------------
 506 AC_ARG_ENABLE(threaded-rts,
 507 [  --enable-threaded-rts
 508         Support better interop with OS threads.
 509 ],
 510 [ThreadedRts=YES],
 511 [ThreadedRts=NO]
 512 )
 513 AC_SUBST(ThreadedRts)
 514
 515 dnl ** Enable the construction of Win32 DLLs?
 516 dnl --------------------------------------------------------------
 517 dnl
 518 dnl [ The ability to build the RTS and libraries as separate DLLs used
 519 dnl   to be supported, but isn't currently (updates to the RTS, compiler
 520 dnl   and build system would be required to bring it back again.)
 521 dnl   Hence, exposing it as an option is false advertisement, so better
 522 dnl   disable it to avoid confusion (but leave it commented-out rather
 523 dnl   than removed in order to remind ourselves to bring back the
 524 dnl   feature at some stage.) ]
 525 dnl
 526 dnl AC_ARG_ENABLE(win32-dlls,
 527 dnl [  --enable-win32-dlls
 528 dnl         If on a Win32 platform running mingw32/cygwin, enable the
 529 dnl     construction of DLLs containing ghc-compiled code.
 530 dnl ],
 531 dnl [
 532 dnl case $HostOS_CPP in
 533 dnl cygwin32) ;;
 534 dnl mingw32)  ;;
 535 dnl *)    echo "Unrecognised win32 platform: $HostPlatform"
 536 dnl       exit 1
 537 dnl       ;;
 538 dnl esac
 539 dnl EnableWin32DLLs=YES
 540 dnl ],
 541 dnl [EnableWin32DLLs=NO]
 542 dnl )
 543 dnl AC_SUBST(EnableWin32DLLs)
 544 dnl if test x"$EnableWin32DLLs" = "xYES" ; then
 545 dnl  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 546 dnl fi
 547
 548 dnl ** Enable the building of the ObjectIO?
 549 dnl --------------------------------------------------------------
 550 AC_ARG_ENABLE(objectio,
 551 [  --enable-objectio
 552         Build ObjectIO, a portable GUI library for Haskell.
 553 ],
 554 [GhcLibsWithObjectIO=YES],
 555 [GhcLibsWithObjectIO=NO]
 556 )
 557 AC_SUBST(GhcLibsWithObjectIO)
 558
 559 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 560 dnl --------------------------------------------------------------
 561 AC_ARG_ENABLE(hopengl,
 562 [  --enable-hopengl
 563         Build HOpenGL, a Haskell binding for OpenGL/GLUT.
 564         On Mac OS X, use --enable-hopengl=x11 to use X11 instead
 565         of the "native" libraries.
 566 ],
 567 [GhcLibsWithHOpenGL=YES],
 568 [GhcLibsWithHOpenGL=NO]
 569 )
 570 UseQuartzOpenGL=NO
 571 if test x"$TargetOS_CPP" = x"darwin"; then
 572   if test x"$enable_hopengl" != x"x11"; then
 573     AC_DEFINE(USE_QUARTZ_OPENGL)
 574     UseQuartzOpenGL=YES
 575   fi
 576 fi
 577
 578 AC_SUBST(GhcLibsWithHOpenGL)
 579
 580 dnl ** .NET interop support?
 581 dnl --------------------------------------------------------------
 582 AC_ARG_ENABLE(dotnet,
 583 [  --enable-dotnet
 584         Build .NET interop layer.
 585 ],
 586 [DotnetSupport=YES; AC_DEFINE(WANT_DOTNET_SUPPORT)],
 587 [DotnetSupport=NO]
 588 )
 589 AC_SUBST(DotnetSupport)
 590
 591 dnl --------------------------------------------------------------
 592 dnl End of configure script option section
 593 dnl --------------------------------------------------------------
 594
 595
 596 dnl --------------------------------------------------------------
 597 dnl * General configuration checks
 598 dnl --------------------------------------------------------------
 599
 600 dnl ** does #! work?
 601 AC_SYS_INTERPRETER()
 602
 603 dnl ** look for `perl', but only in /bin on Windows
 604 case $HostOS_CPP in
 605 cygwin32|mingw32)
 606       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 607       if test -z "$PerlCmd"; then
 608          echo "You must install the version of Perl shipped with GHC"
 609          echo "(or a compatible one) in /bin."
 610          exit 1
 611       fi
 612    ;;
 613 *)
 614    AC_PATH_PROG(PerlCmd,perl)
 615    if test -z "$PerlCmd"; then
 616       echo "You must install perl before you can continue"
 617       echo "Perhaps it is already installed, but not in your PATH?"
 618       exit 1
 619    else
 620    FPTOOLS_CHECK_PERL_VERSION
 621    fi
 622    ;;
 623 esac
 624
 625 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 626 FPTOOLS_SHEBANG_PERL
 627
 628 dnl ** check for Python
 629 AC_PATH_PROG(PythonCmd,python)
 630
 631 dnl ** look for GCC and find out which version
 632 dnl     Figure out which C compiler to use.  Gcc is preferred.
 633 dnl     If gcc, make sure it's at least 2.1
 634 dnl
 635 AC_PROG_CC
 636 FPTOOLS_HAVE_GCC
 637 FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
 638
 639 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 640 AC_PROG_CPP
 641
 642 dnl ** Without optimization some INLINE trickery fails for GHCi
 643 SRC_CC_OPTS="-O"
 644
 645 dnl ** Try to add -mno-cygwin to the C compiler options for mingw32 targets
 646 if test x"$TargetOS_CPP" = x"mingw32"; then
 647   FPTOOLS_CC_FLAG(-mno-cygwin,CC_SUPPORTS_MNO_CYGWIN)
 648   SRC_CC_OPTS="$CC_SUPPORTS_MNO_CYGWIN $SRC_CC_OPTS"
 649   CPPFLAGS="$CC_SUPPORTS_MNO_CYGWIN $CPPFLAGS"
 650 fi
 651 AC_SUBST(SRC_CC_OPTS)
 652
 653 dnl ** figure out how to do context diffs
 654 FPTOOLS_PROG_DIFF
 655
 656 dnl ** Find find command (for Win32's benefit)
 657 FPTOOLS_FIND_FIND
 658
 659 dnl ** Find lex command (flex or lex)
 660 AC_PROG_LEX
 661 test -z "$LEX" && AC_MSG_WARN(['flex' or 'lex' not found])
 662
 663 dnl ** figure out how to do a BSD-ish install
 664 AC_PROG_INSTALL
 665
 666 dnl If you can run configure, you certainly have /bin/sh
 667 AC_DEFINE(HAVE_BIN_SH)
 668
 669 dnl ** how to invoke `ar' and `ranlib'
 670 FPTOOLS_PROG_AR_AND_RANLIB
 671
 672 dnl ** Check to see whether ln -s works
 673 AC_PROG_LN_S
 674
 675
 676 dnl ** Find the path to sed
 677 AC_PATH_PROG(SedCmd,sed)
 678
 679
 680 dnl ** check for time command
 681 AC_PATH_PROG(TimeCmd,time)
 682
 683 dnl ** check for tar
 684 dnl   if GNU tar is named gtar, look for it first.
 685 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 686
 687 dnl ** check for gzip/compress
 688 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 689
 690 dnl ** check for jade/openjade & determine a working catalog
 691 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 692 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 693                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl /usr/local/share/sgml/catalog glafp-utils/docbook/CATALOG*)
 694 if test -z "$Catalog"; then
 695   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 696 fi
 697 case $Catalog in
 698    yes) # assume it is provided by other means (e.g., SGML_CATALOG_FILES env var).
 699         Catalog=
 700         ;;
 701    glafp*)
 702         case $HostOS_CPP in
 703            mingw32)
 704               Catalog=`cygpath -w $hardtop/$Catalog`
 705               ;;
 706            *) Catalog=$hardtop/$Catalog
 707               ;;
 708         esac
 709    ;;
 710 esac
 711 AC_SUBST(Catalog)
 712
 713 compress_nm=`basename $CompressCmd`
 714 if test x"$compress_nm" = xgzip; then
 715   CompressCmd="$CompressCmd -d"
 716   CompressSuffix="gz"
 717 else
 718   CompressSuffix="Z"
 719 fi
 720 AC_SUBST(CompressCmd)
 721 AC_SUBST(CompressSuffix)
 722
 723 dnl ** check for ghc-pkg command
 724 changequote(, )dnl
 725 ghc_pkg_guess=`echo $WithGhc | sed 's@ghc\([^/\\]*\)$@ghc-pkg\1@'`
 726 changequote([, ])dnl
 727 if $ghc_pkg_guess -l >/dev/null 2>/dev/null; then
 728    GhcPkgCmd=$ghc_pkg_guess
 729    AC_MSG_NOTICE([using $ghc_pkg_guess for ghc-pkg])
 730 else
 731    AC_PATH_PROG(GhcPkgCmd,ghc-pkg)
 732 fi
 733
 734 AC_ARG_WITH(greencard,
 735 [  --with-greencard=<greencard compiler>
 736         Use a command different from 'green-card' to compile GreenCard files
 737 ],
 738 [
 739 GreencardCmd=$withval;
 740 FPTOOLS_GREENCARD(3.00)
 741 ]
 742 )
 743
 744 AC_ARG_ENABLE(src-tree-happy,
 745 [  --enable-src-tree-happy
 746         Build and use source tree (fptools/happy) version of Happy.
 747 ],
 748 [UseSrcTreeHappy=YES],
 749 [UseSrcTreeHappy=NO]
 750 )
 751 dnl ** check for installed happy binary + version
 752 dnl    (don't do it if we're booting from .hc files though.)
 753 if test "$BootingFromHc" = "NO"; then
 754 FPTOOLS_HAPPY
 755 fi;
 756
 757 AC_ARG_ENABLE(src-tree-haddock,
 758 [  --enable-src-tree-haddock
 759         Build and use source tree (fptools/haddock) version of Haddock.
 760 ],
 761 [UseSrcTreeHaddock=YES],
 762 [UseSrcTreeHaddock=NO]
 763 )
 764 dnl ** check for installed haddock
 765 FPTOOLS_HADDOCK
 766
 767 AC_ARG_ENABLE(src-tree-alex,
 768 [  --enable-src-tree-alex
 769         Build and use source tree (fptools/alex) version of Alex.
 770 ],
 771 [UseSrcTreeAlex=YES],
 772 [UseSrcTreeAlex=NO]
 773 )
 774 dnl ** check for installed alex binary + version
 775 dnl    (don't do it if we're booting from .hc files though.)
 776 if test "$BootingFromHc" = "NO"; then
 777 FPTOOLS_ALEX
 778 fi;
 779
 780 dnl --------------------------------------------------
 781 dnl ### program checking section ends here ###
 782 dnl --------------------------------------------------
 783
 784 dnl --------------------------------------------------
 785 dnl * Platform header file and syscall feature tests
 786 dnl ### checking the state of the local header files and syscalls ###
 787
 788 dnl ** check for full ANSI header (.h) files
 789 AC_HEADER_STDC
 790
 791 dnl ** Enable large file support.  NB. do this before testing the type of
 792 dnl    off_t, because it will affect the result of that test.
 793 AC_SYS_LARGEFILE
 794
 795 dnl ** check for specific header (.h) files that we are interested in
 796 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h limits.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stddef.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h bfd.h winsock.h pthread.h sys/uio.h)
 797 AC_CHECK_HEADER(unistd.h,[AC_CHECK_FUNCS(lchown)])
 798
 799 AC_CHECK_HEADER(readline/readline.h, [HaveReadlineReadlineH=YES], [HaveReadlineReadlineH=NO])
 800 AC_CHECK_HEADER(readline/history.h, [HaveReadlineHistoryH=YES], [HaveReadlineHistoryH=NO])
 801
 802 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 803   HaveReadlineHeaders=YES
 804   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 805 else
 806   HaveReadlineHeaders=NO
 807   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 808 fi
 809 AC_SUBST(HaveReadlineHeaders)
 810
 811 dnl ** check for DOS include files
 812 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 813
 814 dnl ** check for Windows include files
 815 AC_CHECK_HEADERS(windows.h)
 816
 817 dnl ** check for OpenGL include files
 818 if test $UseQuartzOpenGL = YES ; then
 819   AC_CHECK_HEADERS(OpenGL/gl.h)
 820 else
 821   AC_CHECK_HEADERS(GL/gl.h)
 822 fi
 823
 824 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 825 AC_HEADER_TIME
 826
 827 dnl dynamic loading include files
 828 AC_CHECK_HEADERS(dlfcn.h dl.h)
 829
 830 dnl ** check for farcalloc (in bcc)
 831 AC_CHECK_HEADER(alloc.h,[AC_CHECK_FUNCS(farcalloc)])
 832
 833 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 834 AC_CHECK_HEADER(malloc.h,[AC_CHECK_FUNCS(valloc)])
 835
 836 dnl ** check for POSIX regex
 837 HavePosixRegex=NO
 838 AC_CHECK_HEADER(regex.h,[AC_CHECK_FUNC(regcomp, [HavePosixRegex=YES])])
 839 AC_SUBST(HavePosixRegex)
 840
 841 dnl ** how do we get a timezone name, and UTC offset ?
 842 AC_STRUCT_TIMEZONE
 843
 844 dnl ** do we have altzone?
 845 FP_ALTZONE
 846
 847 dnl ** does struct stat contain st_blksize?
 848 AC_STRUCT_ST_BLKSIZE
 849
 850 dnl ** do we have long longs?
 851 FPTOOLS_C_LONG_LONG
 852
 853 dnl ** check what fields struct msghdr contains
 854 FPTOOLS_MSGHDR_MSG_ACCRIGHTS
 855 FPTOOLS_MSGHDR_MSG_CONTROL
 856
 857 dnl ** what are the sizes of various types
 858 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 859 AC_CHECK_SIZEOF(char,               1)
 860 AC_CHECK_SIZEOF(double,             8)
 861 AC_CHECK_SIZEOF(float,              4)
 862 AC_CHECK_SIZEOF(int,                4)
 863 AC_CHECK_SIZEOF(long,               4)
 864 if test "$fptools_cv_have_long_long" = yes; then
 865 AC_CHECK_SIZEOF(long long,          8)
 866 fi
 867 AC_CHECK_SIZEOF(short,              2)
 868 AC_CHECK_SIZEOF(unsigned char,      1)
 869 AC_CHECK_SIZEOF(unsigned int,       4)
 870 AC_CHECK_SIZEOF(unsigned long,      4)
 871 if test "$fptools_cv_have_long_long" = yes; then
 872 AC_CHECK_SIZEOF(unsigned long long, 8)
 873 fi
 874 AC_CHECK_SIZEOF(unsigned short,     2)
 875 AC_CHECK_SIZEOF(void *,             4)
 876
 877 dnl ** what are alignment constraints on various types
 878 FPTOOLS_CHECK_ALIGNMENT(char)
 879 FPTOOLS_CHECK_ALIGNMENT(double)
 880 FPTOOLS_CHECK_ALIGNMENT(float)
 881 FPTOOLS_CHECK_ALIGNMENT(int)
 882 FPTOOLS_CHECK_ALIGNMENT(long)
 883 if test "$fptools_cv_have_long_long" = yes; then
 884 FPTOOLS_CHECK_ALIGNMENT(long long)
 885 fi
 886 FPTOOLS_CHECK_ALIGNMENT(short)
 887 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 888 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 889 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 890 if test "$fptools_cv_have_long_long" = yes; then
 891 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 892 fi
 893 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 894 FPTOOLS_CHECK_ALIGNMENT(void *)
 895
 896 dnl ** map standard C types and ISO types to Haskell types
 897 FPTOOLS_CHECK_HTYPE(char)
 898 FPTOOLS_CHECK_HTYPE(signed char)
 899 FPTOOLS_CHECK_HTYPE(unsigned char)
 900 FPTOOLS_CHECK_HTYPE(short)
 901 FPTOOLS_CHECK_HTYPE(unsigned short)
 902 FPTOOLS_CHECK_HTYPE(int)
 903 FPTOOLS_CHECK_HTYPE(unsigned int)
 904 FPTOOLS_CHECK_HTYPE(long)
 905 FPTOOLS_CHECK_HTYPE(unsigned long)
 906 if test "$fptools_cv_have_long_long" = yes; then
 907 FPTOOLS_CHECK_HTYPE(long long)
 908 FPTOOLS_CHECK_HTYPE(unsigned long long)
 909 fi
 910 FPTOOLS_CHECK_HTYPE(float)
 911 FPTOOLS_CHECK_HTYPE(double)
 912 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 913 FPTOOLS_CHECK_HTYPE(size_t)
 914 FPTOOLS_CHECK_HTYPE(wchar_t)
 915 dnl Int32 is a HACK for non-ISO C compilers
 916 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 917 FPTOOLS_CHECK_HTYPE(clock_t)
 918 FPTOOLS_CHECK_HTYPE(time_t)
 919 FPTOOLS_CHECK_HTYPE(dev_t, Word32)
 920 FPTOOLS_CHECK_HTYPE(ino_t)
 921 FPTOOLS_CHECK_HTYPE(mode_t)
 922 FPTOOLS_CHECK_HTYPE(off_t)
 923 FPTOOLS_CHECK_HTYPE(pid_t)
 924 FPTOOLS_CHECK_HTYPE(gid_t)
 925 FPTOOLS_CHECK_HTYPE(uid_t)
 926 FPTOOLS_CHECK_HTYPE(cc_t)
 927 FPTOOLS_CHECK_HTYPE(speed_t)
 928 FPTOOLS_CHECK_HTYPE(tcflag_t)
 929 FPTOOLS_CHECK_HTYPE(blkcnt_t)
 930 FPTOOLS_CHECK_HTYPE(nlink_t)
 931 FPTOOLS_CHECK_HTYPE(ssize_t)
 932 FPTOOLS_CHECK_HTYPE(rlim_t)
 933
 934 dnl ** Map OpenGL data types to Haskell types
 935 if test $GhcLibsWithHOpenGL = YES ; then
 936 FPTOOLS_CHECK_HTYPE(GLboolean)
 937 FPTOOLS_CHECK_HTYPE(GLbyte)
 938 FPTOOLS_CHECK_HTYPE(GLubyte)
 939 FPTOOLS_CHECK_HTYPE(GLshort)
 940 FPTOOLS_CHECK_HTYPE(GLushort)
 941 FPTOOLS_CHECK_HTYPE(GLint)
 942 FPTOOLS_CHECK_HTYPE(GLuint)
 943 FPTOOLS_CHECK_HTYPE(GLsizei)
 944 FPTOOLS_CHECK_HTYPE(GLenum)
 945 FPTOOLS_CHECK_HTYPE(GLbitfield)
 946 FPTOOLS_CHECK_HTYPE(GLfloat)
 947 FPTOOLS_CHECK_HTYPE(GLclampf)
 948 FPTOOLS_CHECK_HTYPE(GLdouble)
 949 FPTOOLS_CHECK_HTYPE(GLclampd)
 950 fi
 951
 952 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 953
 954 dnl ** can we open files in binary mode?
 955 FPTOOLS_O_BINARY
 956
 957 dnl ** check for GetModuleFileName and WinExec (windows only)
 958 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 959 dnl Doesn't work because the linker can't see the functions if
 960 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 961
 962 FPTOOLS_TRY_LINK_NOWARN(,[
 963 #if HAVE_WINDOWS_H
 964 #include <windows.h>
 965 #endif
 966 main() {
 967   WinExec("",0);
 968   exit(0);
 969 }
 970 ],
 971 [have_winexec=1],
 972 [have_winexec=0])
 973 if test "$have_winexec" = "1"; then
 974 AC_DEFINE(HAVE_WINEXEC)
 975 fi
 976
 977 FPTOOLS_TRY_LINK_NOWARN(,[
 978 #if HAVE_WINDOWS_H
 979 #include <windows.h>
 980 #endif
 981 main() {
 982   char* dir;
 983   GetModuleFileName((HMODULE)0,dir,0);
 984   exit(0);
 985 }
 986 ],
 987 [have_getmodulefilename=1],
 988 [have_getmodulefilename=0])
 989 if test "$have_getmodulefilename" = "1"; then
 990 AC_DEFINE(HAVE_GETMODULEFILENAME)
 991 fi
 992
 993 dnl ** check return type of signal handlers
 994 dnl Foo: assumes we can use prototypes.
 995 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 996 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 997 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 998 dnl #include <signal.h>
 999 dnl #ifdef signal
1000 dnl #undef signal
1001 dnl #endif
1002 dnl void (*signal (int, void (*)(int)))(int);
1003 dnl ],
1004 dnl [int i;],
1005 dnl ac_cv_type_signal_handler=void_int,
1006 dnl ac_cv_type_signal_handler=int_void)])
1007 dnl if test "$ac_cv_type_signal_handler" = void_int; then
1008 dnl AC_DEFINE(VOID_INT_SIGNALS)
1009 dnl fi
1010
1011 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
1012 AC_TYPE_SIGNAL
1013 if test "$ac_cv_type_signal" = void; then
1014 AC_DEFINE(VOID_INT_SIGNALS)
1015 fi
1016
1017 dnl ** check for more functions
1018 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
1019 AC_CHECK_FUNCS(strcmp)
1020 AC_CHECK_FUNCS(realpath _fullpath)
1021 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
1022 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
1023 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
1024 AC_CHECK_FUNCS(snprintf  _snprintf )
1025 AC_CHECK_FUNCS(popen     _popen )
1026 AC_CHECK_FUNCS(pclose    _pclose )
1027 AC_CHECK_FUNCS(setenv unsetenv)
1028
1029
1030 dnl ** check for specific library functions that we are interested in
1031 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat lstat symlink sysconf timelocal times vadvise localtime_r gmtime_r readdir_r getgrgid_r getgrnam_r getpwuid_r getpwnam_r)
1032
1033 dnl ** Solaris2 needs additionl flag for getpw*_r()
1034 case "$TargetPlatform" in
1035   *-solaris2*)
1036     unix_SRC_HSC2HS_OPTS="-D_POSIX_PTHREAD_SEMANTICS"
1037     AC_SUBST(unix_SRC_HSC2HS_OPTS)
1038   ;;
1039 esac
1040
1041 dnl ** check whether this machine has gmp3 installed
1042 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
1043   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
1044     HaveLibGmp=NO; LibGmp=not-installed))
1045 AC_SUBST(HaveLibGmp)
1046 AC_SUBST(LibGmp)
1047
1048 dnl ** (Mac OS X only: check for HaskellSupport.framework)
1049 HaveFrameworkHaskellSupport=NO
1050 if test $HostPlatform = "powerpc-apple-darwin"; then
1051  AC_MSG_CHECKING([for HaskellSupport.framework])
1052  save_libs="$LIBS"
1053  LIBS="-framework HaskellSupport"
1054  AC_TRY_LINK_FUNC(__gmpz_fdiv_qr, HaveFrameworkHaskellSupport=YES,)
1055  if test $HaveFrameworkHaskellSupport = YES; then
1056   AC_DEFINE(HAVE_FRAMEWORK_HASKELLSUPPORT)
1057  fi;
1058  LIBS="$save_libs"
1059  AC_MSG_RESULT([$HaveFrameworkHaskellSupport])
1060 fi;
1061 AC_SUBST(HaveFrameworkHaskellSupport)
1062
1063 dnl ** check for mingwex library
1064 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
1065 AC_SUBST(HaveLibMingwEx)
1066
1067 if test $HaveLibMingwEx = YES ; then
1068   AC_DEFINE(HAVE_MINGWEX)
1069 fi
1070
1071 if test "$HaveLibGmp" = "NO"; then
1072 if test "$HostArch_CPP" = "ia64"; then
1073 AC_MSG_ERROR([You need to install libgmp (the in-tree version does not work on IA64).])
1074 fi;
1075 fi;
1076
1077 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
1078 dnl    the order of these tests matters: bfd needs liberty
1079 AC_CHECK_LIB(iberty, xmalloc)
1080 AC_CHECK_LIB(bfd,    bfd_init)
1081
1082 dnl ** check for readline, for Hugs and hslibs' Readline
1083 dnl ncurses supersedes termcap and curses, but for compatibility,
1084 dnl we have to check for all...
1085 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
1086   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
1087     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
1088       HaveLibTermcap=NO; LibTermcap=not-installed)))
1089
1090 if test $HaveLibTermcap = YES ; then
1091   LIBS="-l$LibTermcap $LIBS"
1092   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
1093 fi
1094
1095 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
1096   AC_DEFINE(HAVE_READLINE_LIBS,1)
1097   LibsReadline="readline $LibTermcap"
1098 else
1099   AC_DEFINE(HAVE_READLINE_LIBS,0)
1100   LibsReadline=
1101 fi
1102 AC_SUBST(LibsReadline)
1103
1104 if test "$HaveLibReadline"; then
1105   AC_CHECK_LIB(readline, rl_erase_empty_line,
1106     [AC_DEFINE(HAVE_READLINE_4, 1)],
1107     [AC_DEFINE(HAVE_READLINE_4, 0)])
1108   AC_CHECK_LIB(readline, rl_free_undo_list,
1109     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
1110     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
1111 else
1112   AC_DEFINE(HAVE_READLINE_4, 0)
1113   AC_DEFINE(HAVE_READLINE_4_2, 0)
1114 fi
1115
1116 dnl ** check for math library
1117 FPTOOLS_CHECK_LIBM()
1118 AC_SUBST(LIBM)
1119
1120 dnl ** check for X Window System
1121 AC_PATH_XTRA()
1122
1123 dnl ** check for OpenGL/GLUT/GLX include paths and libraries
1124 if test $GhcLibsWithHOpenGL = YES ; then
1125   if test $UseQuartzOpenGL = YES ; then
1126     dnl Take a shortcut for Mac OS X native OpenGL:
1127     dnl It's in a non-standard location, but it's always there
1128     GL_CFLAGS=
1129         GL_LIBS=
1130         GLUT_LIBS=
1131         AC_SUBST(GL_CFLAGS)
1132         AC_SUBST(GL_LIBS)
1133         AC_SUBST(GLUT_LIBS)
1134   else
1135     FPTOOLS_HAVE_OPENGL
1136   fi
1137 fi
1138
1139 dnl ################################################################
1140 dnl Check for libraries
1141 dnl ################################################################
1142
1143 dnl ** check for libdl & RTLD_NEXT
1144
1145 dnl (Mac OS X only) ... but don't check if we already have the
1146 dnl HaskellSupport.framework
1147
1148 if test $HaveFrameworkHaskellSupport = YES; then
1149     HaveLibDL=NO
1150     HaveRtldNext=NO
1151     HaveRtldLocal=YES
1152     AC_DEFINE(HAVE_RTLDLOCAL)
1153     HaveRtldGlobal=YES
1154     AC_DEFINE(HAVE_RTLDGLOBAL)
1155     HaveRtldNow=YES
1156     AC_DEFINE(HAVE_RTLDNOW)
1157     AC_SUBST(HaveLibDL)
1158     AC_SUBST(HaveRtldNext)
1159     AC_SUBST(HaveRtldLocal)
1160     AC_SUBST(HaveRtldGlobal)
1161     AC_SUBST(HaveRtldNow)
1162 else
1163     AC_CHECK_LIB(dl, dlopen,
1164         [HaveLibDL=YES
1165          AC_DEFINE(HAVE_LIBDL)
1166          LIBS="$LIBS -ldl"],
1167         [HaveLibDL=NO])
1168     AC_CHECK_FUNCS(dlopen)
1169     AC_SUBST(HaveLibDL)
1170
1171     dnl ** sometimes RTLD_NEXT is hidden in #ifdefs we really don't wan to set
1172     AC_MSG_CHECKING(for RTLD_NEXT from dlfcn.h)
1173     AC_EGREP_CPP(yes,
1174     [
1175      #include <dlfcn.h>
1176      #ifdef RTLD_NEXT
1177             yes
1178      #endif
1179     ], [
1180       AC_MSG_RESULT(yes)
1181       AC_DEFINE(HAVE_RTLDNEXT)
1182       HaveRtldNext=YES
1183     ], [
1184       AC_MSG_RESULT(no)
1185       HaveRtldNext=NO
1186       ])
1187     AC_SUBST(HaveRtldNext)
1188
1189     dnl ** RTLD_LOCAL isn't available on cygwin or openbsd
1190     AC_MSG_CHECKING(for RTLD_LOCAL from dlfcn.h)
1191     AC_EGREP_CPP(yes,
1192     [
1193      #include <dlfcn.h>
1194      #ifdef RTLD_LOCAL
1195             yes
1196      #endif
1197     ], [
1198       AC_MSG_RESULT(yes)
1199       AC_DEFINE(HAVE_RTLDLOCAL)
1200       HaveRtldLocal=YES
1201     ], [
1202       AC_MSG_RESULT(no)
1203       HaveRtldLocal=NO
1204       ])
1205     AC_SUBST(HaveRtldLocal)
1206
1207     dnl ** RTLD_GLOBAL isn't available on openbsd
1208     AC_MSG_CHECKING(for RTLD_GLOBAL from dlfcn.h)
1209     AC_EGREP_CPP(yes,
1210     [
1211      #include <dlfcn.h>
1212      #ifdef RTLD_GLOBAL
1213             yes
1214      #endif
1215     ], [
1216       AC_MSG_RESULT(yes)
1217       AC_DEFINE(HAVE_RTLDGLOBAL)
1218       HaveRtldGlobal=YES
1219     ], [
1220       AC_MSG_RESULT(no)
1221       HaveRtldGlobal=NO
1222       ])
1223     AC_SUBST(HaveRtldGlobal)
1224
1225     dnl ** RTLD_NOW isn't available on openbsd
1226     AC_MSG_CHECKING(for RTLD_NOW from dlfcn.h)
1227     AC_EGREP_CPP(yes,
1228     [
1229      #include <dlfcn.h>
1230      #ifdef RTLD_NOW
1231             yes
1232      #endif
1233     ], [
1234       AC_MSG_RESULT(yes)
1235       AC_DEFINE(HAVE_RTLDNOW)
1236       HaveRtldNow=YES
1237     ], [
1238       AC_MSG_RESULT(no)
1239       HaveRtldNow=NO
1240       ])
1241     AC_SUBST(HaveRtldNow)
1242 fi
1243
1244 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
1245
1246 dnl ---------- usleep ----------
1247 dnl --- stolen from guile configure ---
1248 dnl --- FIXME: /usr/include/unistd.h can't be right?
1249
1250 ### On some systems usleep has no return value.  If it does have one,
1251 ### we'd like to return it; otherwise, we'll fake it.
1252 AC_CACHE_CHECK([return type of usleep], cv_func_usleep_return_type,
1253   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
1254                    /usr/include/unistd.h,
1255                    [cv_func_usleep_return_type=void],
1256                    [cv_func_usleep_return_type=int])])
1257 case "$cv_func_usleep_return_type" in
1258   "void" )
1259     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
1260       [Define if the system headers declare usleep to return void.])
1261   ;;
1262 esac
1263
1264 dnl --------------------------------------------------
1265 dnl * test for in_addr_t
1266 dnl --------------------------------------------------
1267 AC_MSG_CHECKING(for in_addr_t in netinet/in.h)
1268 AC_EGREP_HEADER(in_addr_t, netinet/in.h,
1269  [ AC_DEFINE(HAVE_IN_ADDR_T) AC_MSG_RESULT(yes) ],
1270  AC_MSG_RESULT(no))
1271
1272 dnl --------------------------------------------------
1273 dnl * test for Linux sendfile(2)
1274 dnl --------------------------------------------------
1275 AC_MSG_CHECKING(for sendfile in sys/sendfile.h)
1276 AC_EGREP_HEADER(sendfile, sys/sendfile.h,
1277  [ AC_DEFINE(HAVE_LINUX_SENDFILE) AC_MSG_RESULT(yes) ],
1278  AC_MSG_RESULT(no))
1279
1280 dnl --------------------------------------------------
1281 dnl * test for BSD sendfile(2)
1282 dnl --------------------------------------------------
1283 AC_MSG_CHECKING(for sendfile in sys/socket.h)
1284 AC_EGREP_HEADER(sendfile, sys/socket.h,
1285  [ AC_DEFINE(HAVE_BSD_SENDFILE) AC_MSG_RESULT(yes) ],
1286  AC_MSG_RESULT(no))
1287
1288 dnl --------------------------------------------------
1289 dnl * test for GTK+
1290 dnl --------------------------------------------------
1291
1292 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
1293 if test "$GTK_CONFIG" != ""; then
1294    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
1295         fptools_cv_gtk_version=`$GTK_CONFIG --version`
1296     ])
1297     GTK_VERSION=$fptools_cv_gtk_version
1298 else
1299     GTK_VERSION=
1300 fi
1301
1302 case $fptools_cv_gtk_version in
1303   1.[[23]].*) ;;
1304   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
1305      GTK_CONFIG=
1306      ;;
1307 esac
1308
1309 AC_SUBST(GTK_CONFIG)
1310 AC_SUBST(GTK_VERSION)
1311
1312 dnl --------------------------------------------------
1313 dnl * Miscellaneous feature tests
1314 dnl --------------------------------------------------
1315
1316 dnl ** can we get alloca?
1317 AC_FUNC_ALLOCA
1318
1319 dnl ** Working vfork?
1320 AC_FUNC_VFORK
1321
1322 dnl ** determine whether or not const works
1323 AC_C_CONST
1324
1325 dnl ** determine whether ANSI-function prototypes work?
1326 AC_C_PROTOTYPES
1327
1328 dnl ** are we big endian?
1329 AC_C_BIGENDIAN
1330
1331 dnl ** check for leading underscores in symbol names
1332 FPTOOLS_UNDERSCORE
1333
1334 dnl ** check for ld, and whether ld has -x option
1335 AC_PATH_PROG(LdCmdRaw, ld)
1336 case $HostOS_CPP in
1337  mingw32) LdCmd=`cygpath -w ${LdCmdRaw} | sed -e 's@\\\\@/@g' `
1338            ;;
1339  *) LdCmd=${LdCmdRaw}
1340     ;;
1341 esac
1342 AC_SUBST(LdCmd)
1343 FPTOOLS_LD_X
1344
1345 AC_MSG_CHECKING([for SIGPOLL])
1346 AC_EGREP_CPP(we_have_sigpoll,
1347 [#include <signal.h>
1348 #ifdef SIGPOLL
1349 we_have_sigpoll
1350 #endif
1351 ], AC_DEFINE(HAVE_SIGPOLL) haveSIGPOLL=yes, haveSIGPOLL=no)
1352 AC_MSG_RESULT([$haveSIGPOLL])
1353
1354 AC_MSG_CHECKING([for _SC_GETGR_R_SIZE_MAX])
1355 AC_EGREP_CPP(we_have_that_sysconf_thing,
1356 [
1357 #include <unistd.h>
1358 #ifdef _SC_GETGR_R_SIZE_MAX
1359 we_have_that_sysconf_thing
1360 #endif
1361 ],
1362 [AC_MSG_RESULT([yes])
1363 AC_DEFINE(HAVE_SC_GETGR_R_SIZE_MAX)],
1364 [AC_MSG_RESULT([no])])
1365
1366 AC_MSG_CHECKING([for _SC_GETPW_R_SIZE_MAX])
1367 AC_EGREP_CPP(we_have_that_sysconf_thing,
1368 [
1369 #include <unistd.h>
1370 #ifdef _SC_GETPW_R_SIZE_MAX
1371 we_have_that_sysconf_thing
1372 #endif
1373 ],
1374 [AC_MSG_RESULT([yes])
1375 AC_DEFINE(HAVE_SC_GETPW_R_SIZE_MAX)],
1376 [AC_MSG_RESULT([no])])
1377
1378 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )