configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * We require autoconf version 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE
  20 AC_PREREQ(2.50)
  21
  22 dnl * Declare subdirectories that have a private configure script
  23 dnl
  24 dnl After the toplevel configuration is complete, the script will recurse into
  25 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  26 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  27 AC_CONFIG_SUBDIRS(ghc)
  28
  29 # -------------------------------------------------------------------------
  30 # Prepare to generate the following header files
  31 #
  32 #
  33 AC_CONFIG_HEADER(mk/config.h)
  34
  35 # No, semi-sadly, we don't do `--srcdir'...
  36 if test x"$srcdir" != 'x.' ; then
  37     echo "This configuration does not support the \`--srcdir' option.."
  38     exit 1
  39 fi
  40
  41 dnl--------------------------------------------------------------------
  42 dnl * Choose host(/target/build) platform
  43 dnl--------------------------------------------------------------------
  44
  45 dnl Guess host/target/build platform(s) if necessary.
  46 AC_CANONICAL_SYSTEM
  47
  48 # "$host" defaults to "$target"
  49 if test "x$host" = xNONE ; then
  50     host=$target
  51 fi
  52
  53 dnl ** canonicalize platform names
  54 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  55 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  56 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  57
  58 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  59     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  60     exit 1
  61 fi
  62
  63 exeext=''
  64 #
  65 # The following will be more difficult when we *are* cross-compiling.
  66 # Suitable names to slam in *_CPP are in platform.h.in.
  67 # We also record the architecture, vendor, and operating system (OS)
  68 # separately.
  69 case $HostPlatform in
  70 alpha*-dec-osf[[12]]*)
  71         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  72         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  73         BuildPlatform=alpha-dec-osf1  # hack
  74         HostPlatform_CPP='alpha_dec_osf1'
  75         HostArch_CPP='alpha'
  76         HostVendor_CPP='dec'
  77         HostOS_CPP='osf1'
  78         ;;
  79 alpha*-dec-osf[[345]]*)
  80         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  81         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  82         BuildPlatform=alpha-dec-osf3  # hack
  83         HostPlatform_CPP='alpha_dec_osf3'
  84         HostArch_CPP='alpha'
  85         HostVendor_CPP='dec'
  86         HostOS_CPP='osf3'
  87         ;;
  88 alpha*-unknown-linux*)
  89         HostPlatform=alpha-unknown-linux
  90         TargetPlatform=alpha-unknown-linux
  91         BuildPlatform=alpha-unknown-linux
  92         HostPlatform_CPP='alpha_unknown_linux'
  93         HostArch_CPP='alpha'
  94         HostVendor_CPP='unknown'
  95         HostOS_CPP='linux'
  96         ;;
  97 alpha*-unknown-freebsd*)
  98         HostPlatform=alpha-unknown-freebsd
  99         TargetPlatform=alpha-unknown-freebsd
 100         BuildPlatform=alpha-unknown-freebsd
 101         HostPlatform_CPP='alpha_unknown_freebsd'
 102         HostArch_CPP='alpha'
 103         HostVendor_CPP='unknown'
 104         HostOS_CPP='freebsd'
 105         ;;
 106 hppa1.1-hp-hpux*)
 107         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 108         TargetPlatform=hppa1.1-hp-hpux
 109         BuildPlatform=hppa1.1-hp-hpux
 110         HostPlatform_CPP='hppa1_1_hp_hpux'
 111         HostArch_CPP='hppa1_1'
 112         HostVendor_CPP='hp'
 113         HostOS_CPP='hpux'
 114         ;;
 115 i[[3456]]86-*-linuxaout*)
 116         HostPlatform=i386-unknown-linuxaout   # hack again
 117         TargetPlatform=i386-unknown-linuxaout
 118         BuildPlatform=i386-unknown-linuxaout
 119         HostPlatform_CPP='i386_unknown_linuxaout'
 120         HostArch_CPP='i386'
 121         HostVendor_CPP='unknown'
 122         HostOS_CPP='linuxaout'
 123         ;;
 124 i[[3456]]86-*-linux*)
 125         HostPlatform=i386-unknown-linux # hack again
 126         TargetPlatform=i386-unknown-linux
 127         BuildPlatform=i386-unknown-linux
 128         HostPlatform_CPP='i386_unknown_linux'
 129         HostArch_CPP='i386'
 130         HostVendor_CPP='unknown'
 131         HostOS_CPP='linux'
 132         ;;
 133 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 134         HostPlatform=i386-unknown-freebsd # hack again
 135         TargetPlatform=i386-unknown-freebsd
 136         BuildPlatform=i386-unknown-freebsd
 137         HostPlatform_CPP='i386_unknown_freebsd'
 138         HostArch_CPP='i386'
 139         HostVendor_CPP='unknown'
 140         HostOS_CPP='freebsd'
 141         ;;
 142 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 143         HostPlatform=i386-unknown-freebsd2 # hack again
 144         TargetPlatform=i386-unknown-freebsd2
 145         BuildPlatform=i386-unknown-freebsd2
 146         HostPlatform_CPP='i386_unknown_freebsd2'
 147         HostArch_CPP='i386'
 148         HostVendor_CPP='unknown'
 149         HostOS_CPP='freebsd2'
 150         ;;
 151 i[[3456]]86-*-netbsd*)
 152         HostPlatform=i386-unknown-netbsd # hack again
 153         TargetPlatform=i386-unknown-netbsd
 154         BuildPlatform=i386-unknown-netbsd
 155         HostPlatform_CPP='i386_unknown_netbsd'
 156         HostArch_CPP='i386'
 157         HostVendor_CPP='unknown'
 158         HostOS_CPP='netbsd'
 159         ;;
 160 i[[3456]]86-*-openbsd*)
 161         HostPlatform=i386-unknown-openbsd # hack again
 162         TargetPlatform=i386-unknown-openbsd
 163         BuildPlatform=i386-unknown-openbsd
 164         HostPlatform_CPP='i386_unknown_openbsd'
 165         HostArch_CPP='i386'
 166         HostVendor_CPP='unknown'
 167         HostOS_CPP='openbsd'
 168         ;;
 169 i[[3456]]86-*-solaris2*)
 170         HostPlatform=i386-unknown-solaris2 # hack again
 171         TargetPlatform=i386-unknown-solaris2
 172         BuildPlatform=i386-unknown-solaris2
 173         HostPlatform_CPP='i386_unknown_solaris2'
 174         HostArch_CPP='i386'
 175         HostVendor_CPP='unknown'
 176         HostOS_CPP='solaris2'
 177         ;;
 178 i[[3456]]86-*-cygwin*)
 179         HostPlatform=i386-unknown-cygwin32 # hack again
 180         TargetPlatform=i386-unknown-cygwin32
 181         BuildPlatform=i386-unknown-cygwin32
 182         HostPlatform_CPP='i386_unknown_cygwin32'
 183         HostArch_CPP='i386'
 184         HostVendor_CPP='unknown'
 185         HostOS_CPP='cygwin32'
 186         exeext='.exe'
 187         ;;
 188 i[[3456]]86-*-mingw32*)
 189         HostPlatform=i386-unknown-mingw32 # hack again
 190         TargetPlatform=i386-unknown-mingw32
 191         BuildPlatform=i386-unknown-mingw32
 192         HostPlatform_CPP='i386_unknown_mingw32'
 193         HostArch_CPP='i386'
 194         HostVendor_CPP='unknown'
 195         HostOS_CPP='mingw32'
 196         exeext='.exe'
 197         ;;
 198 ia64-*-linux*)
 199         HostPlatform=ia64-unknown-linux # hack again
 200         TargetPlatform=ia64-unknown-linux
 201         BuildPlatform=ia64-unknown-linux
 202         HostPlatform_CPP='ia64_unknown_linux'
 203         HostArch_CPP='ia64'
 204         HostVendor_CPP='unknown'
 205         HostOS_CPP='linux'
 206         ;;
 207 m68k-next-nextstep2)
 208         HostPlatform_CPP='m68k_next_nextstep2'
 209         HostArch_CPP='m68k'
 210         HostVendor_CPP='next'
 211         HostOS_CPP='nextstep2'
 212         ;;
 213 m68k-next-nextstep3)
 214         HostPlatform_CPP='m68k_next_nextstep3'
 215         HostArch_CPP='m68k'
 216         HostVendor_CPP='next'
 217         HostOS_CPP='nextstep3'
 218         ;;
 219 i[[3456]]86-next-nextstep3)
 220         HostPlatform=i386-next-nextstep3 # hack again
 221         TargetPlatform=i386-next-nextstep3
 222         BuildPlatform=i386-next-nextstep3
 223         HostPlatform_CPP='i386_next_nextstep3'
 224         HostArch_CPP='i386'
 225         HostVendor_CPP='next'
 226         HostOS_CPP='nextstep3'
 227         ;;
 228 m68k-*-openbsd*)
 229         HostPlatform=m68k-unknown-openbsd
 230         TargetPlatform=m68k-unknown-openbsd
 231         BuildPlatform=m68k-unknown-openbsd
 232         HostPlatform_CPP='m68k_unknown_openbsd'
 233         HostArch_CPP='m68k'
 234         HostVendor_CPP='unknown'
 235         HostOS_CPP='openbsd'
 236         ;;
 237 m68k-apple-netbsd*)
 238         HostPlatform=m68k-apple-netbsd
 239         TargetPlatform=m68k-apple-netbsd
 240         BuildPlatform=m68k-apple-netbsd
 241         HostPlatform_CPP='m68k_apple_netbsd'
 242         HostArch_CPP='m68k'
 243         HostVendor_CPP='apple'
 244         HostOS_CPP='netbsd'
 245         ;;
 246 m68k-sun-sunos4*)
 247         HostPlatform=m68k-sun-sunos4
 248         TargetPlatform=m68k-sun-sunos4 #hack
 249         BuildPlatform=m68k-sun-sunos4 #hack
 250         HostPlatform_CPP='m68k_sun_sunos4'
 251         HostArch_CPP='m68k'
 252         HostVendor_CPP='sun'
 253         HostOS_CPP='sunos4'
 254         ;;
 255 mips-dec-ultrix*)
 256         HostPlatform_CPP='mips_dec_ultrix'
 257         HostArch_CPP='mipsel'   # NB a little different
 258         HostVendor_CPP='dec'
 259         HostOS_CPP='ultrix'
 260         ;;
 261 mips-sgi-irix*)
 262         HostPlatform=mips-sgi-irix
 263         TargetPlatform=mips-sgi-irix #hack
 264         BuildPlatform=mips-sgi-irix #hack
 265         HostPlatform_CPP='mips_sgi_irix'
 266         HostArch_CPP='mipseb'   # NB a little different
 267         HostVendor_CPP='sgi'
 268         HostOS_CPP='irix'
 269         ;;
 270 rs6000-ibm-aix*)
 271         HostPlatform=rs6000-ibm-aix
 272         TargetPlatform=rs6000-ibm-aix #hack
 273         BuildPlatform=rs6000-ibm-aix #hack
 274         HostPlatform_CPP='rs6000_ibm_aix'
 275         HostArch_CPP='rs6000'
 276         HostVendor_CPP='ibm'
 277         HostOS_CPP='aix'
 278         ;;
 279 powerpc-ibm-aix*)
 280         HostPlatform=powerpc-ibm-aix
 281         TargetPlatform=powerpc-ibm-aix #hack
 282         BuildPlatform=powerpc-ibm-aix #hack
 283         HostPlatform_CPP='powerpc_ibm_aix'
 284         HostArch_CPP='powerpc'
 285         HostVendor_CPP='ibm'
 286         HostOS_CPP='aix'
 287         ;;
 288 powerpc-apple-darwin*)
 289         HostPlatform=powerpc-apple-darwin
 290         TargetPlatform=powerpc-apple-darwin #hack
 291         BuildPlatform=powerpc-apple-darwin #hack
 292         HostPlatform_CPP='powerpc_apple_darwin'
 293         HostArch_CPP='powerpc'
 294         HostVendor_CPP='apple'
 295         HostOS_CPP='darwin'
 296         ;;
 297 sparc-sun-sunos4*)
 298         HostPlatform=sparc-sun-sunos4
 299         TargetPlatform=sparc-sun-sunos4 #hack
 300         BuildPlatform=sparc-sun-sunos4 #hack
 301         HostPlatform_CPP='sparc_sun_sunos4'
 302         HostArch_CPP='sparc'
 303         HostVendor_CPP='sun'
 304         HostOS_CPP='sunos4'
 305         ;;
 306 sparc-sun-solaris2*)
 307         HostPlatform=sparc-sun-solaris2
 308         TargetPlatform=sparc-sun-solaris2 #hack
 309         BuildPlatform=sparc-sun-solaris2 #hack
 310         HostPlatform_CPP='sparc_sun_solaris2'
 311         HostArch_CPP='sparc'
 312         HostVendor_CPP='sun'
 313         HostOS_CPP='solaris2'
 314         ;;
 315 sparc*-linux*)
 316         HostPlatform=sparc-unknown-linux
 317         TargetPlatform=sparc-unknown-linux
 318         BuildPlatform=sparc-unknown-linux
 319         HostPlatform_CPP='sparc_unknown_linux'
 320         HostArch_CPP='sparc'
 321         HostVendor_CPP='unknown'
 322         HostOS_CPP='linux'
 323         ;;
 324 sparc-*-openbsd*)
 325         HostPlatform=sparc-unknown-openbsd
 326         TargetPlatform=sparc-unknown-openbsd
 327         BuildPlatform=sparc-unknown-openbsd
 328         HostPlatform_CPP='sparc_unknown_openbsd'
 329         HostArch_CPP='sparc'
 330         HostVendor_CPP='unknown'
 331         HostOS_CPP='openbsd'
 332         ;;
 333 *)
 334         echo "Unrecognised platform: $HostPlatform"
 335         exit 1
 336         ;;
 337 esac
 338 echo "Canonicalised to: $HostPlatform"
 339 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 340 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 341
 342 BuildPlatform_CPP=$HostPlatform_CPP
 343 TargetPlatform_CPP=$HostPlatform_CPP
 344 BuildArch_CPP=$HostArch_CPP
 345 TargetArch_CPP=$HostArch_CPP
 346 BuildOS_CPP=$HostOS_CPP
 347 HostOS_Full=$host_os
 348 TargetOS_CPP=$HostOS_CPP
 349 BuildVendor_CPP=$HostVendor_CPP
 350 TargetVendor_CPP=$HostVendor_CPP
 351
 352 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 353 dnl AC_SUBST(BuildPlatform)
 354
 355 AC_SUBST(HostPlatform)
 356 AC_SUBST(TargetPlatform)
 357 AC_SUBST(HostPlatform_CPP)
 358 dnl AC_SUBST(BuildPlatform_CPP)
 359 dnl AC_SUBST(TargetPlatform_CPP)
 360
 361 AC_SUBST(HostArch_CPP)
 362 dnl AC_SUBST(BuildArch_CPP)
 363 dnl AC_SUBST(TargetArch_CPP)
 364
 365 AC_SUBST(HostOS_CPP)
 366 AC_SUBST(HostOS_Full)
 367 dnl AC_SUBST(BuildOS_CPP)
 368 dnl AC_SUBST(TargetOS_CPP)
 369
 370 AC_SUBST(HostVendor_CPP)
 371 dnl AC_SUBST(BuildVendor_CPP)
 372 dnl AC_SUBST(TargetVendor_CPP)
 373
 374 AC_SUBST(exeext)
 375
 376 dnl --------------------------------------------------------------
 377 dnl * Calculate absolute path to build tree
 378 dnl --------------------------------------------------------------
 379
 380 AC_MSG_CHECKING(for path to top of build tree)
 381
 382 hardtop=`pwd`
 383
 384 dnl Remove common automounter nonsense
 385 dnl
 386 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^//\(.\)/|\1:/|' `
 387
 388 dnl Find 'hardtop_plat', the native format for 'hardtop' (i.e., right kind of \dnl slashes on a Win32 box, but with b-slashes being escaped).
 389 dnl
 390 case $HostPlatform in
 391   i386-unknown-mingw32 | i386-unknown-cygwin32)
 392         # convert $hardtop to a path that mingw will understand too
 393         cyghardtop=${hardtop}
 394         hardtop=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@/@g'`
 395         hardtop_plat=`cygpath -w ${cyghardtop} | sed -e 's@\\\\@\\\\\\\\@g'`
 396         ;;
 397   *)
 398         hardtop_plat=${hardtop}
 399         ;;
 400 esac
 401 AC_SUBST(hardtop)
 402 AC_SUBST(hardtop_plat)
 403
 404 AC_MSG_RESULT(${hardtop})
 405
 406 dnl --------------------------------------------------------------
 407 dnl * Project specific configuration options
 408 dnl --------------------------------------------------------------
 409 dnl What follows is a bunch of options that can either be configured
 410 dnl through command line options to the configure script or by
 411 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 412 dnl use either is considered a Feature.
 413
 414 dnl ** What command to use to compile compiler sources ?
 415 dnl --------------------------------------------------------------
 416
 417 AC_ARG_WITH(ghc,
 418 [  --with-ghc=<haskell compiler>
 419         Use a command different from 'ghc' to compile GHC-specific Haskell code
 420             (including GHC itself).
 421 ],
 422 [ WithGhc="$withval" ],
 423 [
 424   if test "$GHC" = ""; then
 425     AC_PATH_PROG(GHC,ghc)
 426   fi
 427   WithGhc=$GHC
 428 ]
 429 )
 430 AC_SUBST(WithGhc)
 431
 432 AC_ARG_WITH(hc,
 433 [  --with-hc=<haskell compiler>
 434         Use a command different from 'ghc' to compile generic Haskell code.
 435 ],
 436 [WithHc="$withval"],
 437 [WithHc=$WithGhc]
 438 )
 439 AC_SUBST(WithHc)
 440
 441 if test "$WithGhc" != ""; then
 442   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 443   AC_SUBST(GhcVersion)dnl
 444   AC_SUBST(GhcMajVersion)dnl
 445   AC_SUBST(GhcMinVersion)dnl
 446   AC_SUBST(GhcPatchLevel)dnl
 447 fi
 448
 449 AC_PATH_PROGS(NHC,nhc nhc98)
 450 AC_PATH_PROG(HBC,hbc)
 451
 452 dnl ** Which gcc to use?
 453 dnl --------------------------------------------------------------
 454 AC_ARG_WITH(gcc,
 455 [  --with-gcc=<gcc command>
 456         Use a different command instead of 'gcc' for the GNU C compiler.
 457 ],
 458 [WhatGccIsCalled="$withval"
 459  if test "x$HostPlatform" = "xi386-unknown-mingw32"; then
 460     # Canonicalise to <drive>:/path/to/gcc
 461     withval=`cygpath -w ${withval} | sed -e 's@\\\\@/@g' `
 462  fi;
 463  CC="$withval"],
 464 [WhatGccIsCalled="gcc"]
 465 )
 466 AC_SUBST(WhatGccIsCalled)
 467
 468 dnl ** Booting from .hc files?
 469 dnl --------------------------------------------------------------
 470 AC_ARG_ENABLE(hc-boot,
 471 [  --enable-hc-boot
 472         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 473         (This option is mostly of interest to porters.)
 474 ],
 475 [BootingFromHc=YES],
 476 [BootingFromHc=NO]
 477 )
 478 AC_SUBST(BootingFromHc)
 479
 480 dnl ** Booting from unregisterised .hc files?
 481 dnl --------------------------------------------------------------
 482 AC_ARG_ENABLE(hc-boot-unregisterised,
 483 [  --enable-hc-boot-unregisterised
 484         With --enable-hc-boot, treat the intermediate .hc files as
 485         unregisterised rather than registerised code.
 486         (This option is mostly of interest to porters.)
 487 ],
 488 [BootingFromUnregisterisedHc=YES],
 489 [BootingFromUnregisterisedHc=NO]
 490 )
 491 AC_SUBST(BootingFromUnregisterisedHc)
 492
 493 if test "$BootingFromHc" = "NO"; then
 494 if test "$BootingFromUnregisterisedHc" = "YES"; then
 495 AC_MSG_ERROR([--enable-hc-boot-unregisterised requires --enable-hc-boot.])
 496 fi;
 497 fi;
 498
 499 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 500 if test "$BootingFromHc" = "NO" -a "$WithGhc" = "" -a -d "$srcdir/ghc"; then
 501 AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 502 fi;
 503
 504 dnl ** Enable multi-thread friendly RTS?
 505 dnl --------------------------------------------------------------
 506 AC_ARG_ENABLE(threaded-rts,
 507 [  --enable-threaded-rts
 508         Support better interop with OS threads.
 509 ],
 510 [ThreadedRts=YES],
 511 [ThreadedRts=NO]
 512 )
 513 AC_SUBST(ThreadedRts)
 514
 515 dnl ** Enable the construction of Win32 DLLs?
 516 dnl --------------------------------------------------------------
 517 dnl
 518 dnl [ The ability to build the RTS and libraries as separate DLLs used
 519 dnl   to be supported, but isn't currently (updates to the RTS, compiler
 520 dnl   and build system would be required to bring it back again.)
 521 dnl   Hence, exposing it as an option is false advertisement, so better
 522 dnl   disable it to avoid confusion (but leave it commented-out rather
 523 dnl   than removed in order to remind ourselves to bring back the
 524 dnl   feature at some stage.) ]
 525 dnl
 526 dnl AC_ARG_ENABLE(win32-dlls,
 527 dnl [  --enable-win32-dlls
 528 dnl         If on a Win32 platform running mingw32/cygwin, enable the
 529 dnl     construction of DLLs containing ghc-compiled code.
 530 dnl ],
 531 dnl [
 532 dnl case $HostOS_CPP in
 533 dnl cygwin32) ;;
 534 dnl mingw32)  ;;
 535 dnl *)    echo "Unrecognised win32 platform: $HostPlatform"
 536 dnl       exit 1
 537 dnl       ;;
 538 dnl esac
 539 dnl EnableWin32DLLs=YES
 540 dnl ],
 541 dnl [EnableWin32DLLs=NO]
 542 dnl )
 543 dnl AC_SUBST(EnableWin32DLLs)
 544 dnl if test x"$EnableWin32DLLs" = "xYES" ; then
 545 dnl  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 546 dnl fi
 547
 548 dnl ** Enable the building of the ObjectIO?
 549 dnl --------------------------------------------------------------
 550 AC_ARG_ENABLE(objectio,
 551 [  --enable-objectio
 552         Build ObjectIO, a portable GUI library for Haskell.
 553 ],
 554 [GhcLibsWithObjectIO=YES],
 555 [GhcLibsWithObjectIO=NO]
 556 )
 557 AC_SUBST(GhcLibsWithObjectIO)
 558
 559 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 560 dnl --------------------------------------------------------------
 561 AC_ARG_ENABLE(hopengl,
 562 [  --enable-hopengl
 563         Build HOpenGL, a Haskell binding for OpenGL/GLUT.
 564         On Mac OS X, use --enable-hopengl=x11 to use X11 instead
 565         of the "native" libraries.
 566 ],
 567 [GhcLibsWithHOpenGL=YES],
 568 [GhcLibsWithHOpenGL=NO]
 569 )
 570 UseQuartzOpenGL=NO
 571 if test x"$TargetOS_CPP" = x"darwin"; then
 572   if test x"$enable_hopengl" != x"x11"; then
 573     AC_DEFINE([USE_QUARTZ_OPENGL], [1],
 574               [Define to 1 if native OpenGL should be used on Mac OS X])
 575     UseQuartzOpenGL=YES
 576   fi
 577 fi
 578
 579 AC_SUBST(GhcLibsWithHOpenGL)
 580
 581 dnl ** .NET interop support?
 582 dnl --------------------------------------------------------------
 583 AC_ARG_ENABLE(dotnet,
 584 [  --enable-dotnet
 585         Build .NET interop layer.
 586 ],
 587 [DotnetSupport=YES; AC_DEFINE(WANT_DOTNET_SUPPORT)],
 588 [DotnetSupport=NO]
 589 )
 590 AC_SUBST(DotnetSupport)
 591
 592 dnl --------------------------------------------------------------
 593 dnl End of configure script option section
 594 dnl --------------------------------------------------------------
 595
 596
 597 dnl --------------------------------------------------------------
 598 dnl * General configuration checks
 599 dnl --------------------------------------------------------------
 600
 601 dnl ** does #! work?
 602 AC_SYS_INTERPRETER()
 603
 604 dnl ** look for `perl', but only in /bin on Windows
 605 case $HostOS_CPP in
 606 cygwin32|mingw32)
 607       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 608       if test -z "$PerlCmd"; then
 609          echo "You must install the version of Perl shipped with GHC"
 610          echo "(or a compatible one) in /bin."
 611          exit 1
 612       fi
 613    ;;
 614 *)
 615    AC_PATH_PROG(PerlCmd,perl)
 616    if test -z "$PerlCmd"; then
 617       echo "You must install perl before you can continue"
 618       echo "Perhaps it is already installed, but not in your PATH?"
 619       exit 1
 620    else
 621    FPTOOLS_CHECK_PERL_VERSION
 622    fi
 623    ;;
 624 esac
 625
 626 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 627 FPTOOLS_SHEBANG_PERL
 628
 629 dnl ** check for Python
 630 AC_PATH_PROG(PythonCmd,python)
 631
 632 dnl ** look for GCC and find out which version
 633 dnl     Figure out which C compiler to use.  Gcc is preferred.
 634 dnl     If gcc, make sure it's at least 2.1
 635 dnl
 636 AC_PROG_CC
 637 FPTOOLS_HAVE_GCC
 638 FPTOOLS_GCC_NEEDS_NO_OMIT_LFPTR
 639
 640 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 641 AC_PROG_CPP
 642
 643 dnl ** Without optimization some INLINE trickery fails for GHCi
 644 SRC_CC_OPTS="-O"
 645
 646 dnl ** Try to add -mno-cygwin to the C compiler options for mingw32 targets
 647 if test x"$TargetOS_CPP" = x"mingw32"; then
 648   FPTOOLS_CC_FLAG(-mno-cygwin,CC_SUPPORTS_MNO_CYGWIN)
 649   SRC_CC_OPTS="$CC_SUPPORTS_MNO_CYGWIN $SRC_CC_OPTS"
 650   CPPFLAGS="$CC_SUPPORTS_MNO_CYGWIN $CPPFLAGS"
 651 fi
 652 AC_SUBST(SRC_CC_OPTS)
 653
 654 dnl ** figure out how to do context diffs
 655 FP_PROG_CONTEXT_DIFF
 656
 657 dnl ** Find find command (for Win32's benefit)
 658 FPTOOLS_FIND_FIND
 659
 660 dnl ** figure out how to do a BSD-ish install
 661 AC_PROG_INSTALL
 662
 663 dnl If you can run configure, you certainly have /bin/sh
 664 AC_DEFINE(HAVE_BIN_SH)
 665
 666 dnl ** how to invoke `ar' and `ranlib'
 667 FPTOOLS_PROG_AR_AND_RANLIB
 668
 669 dnl ** Check to see whether ln -s works
 670 AC_PROG_LN_S
 671
 672
 673 dnl ** Find the path to sed
 674 AC_PATH_PROG(SedCmd,sed)
 675
 676
 677 dnl ** check for time command
 678 AC_PATH_PROG(TimeCmd,time)
 679
 680 dnl ** check for tar
 681 dnl   if GNU tar is named gtar, look for it first.
 682 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 683
 684 dnl ** check for gzip/compress
 685 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 686
 687 dnl ** check for jade/openjade & determine a working catalog
 688 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 689 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 690                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl /usr/local/share/sgml/catalog glafp-utils/docbook/CATALOG*)
 691 if test -z "$Catalog"; then
 692   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 693 fi
 694 case $Catalog in
 695    yes) # assume it is provided by other means (e.g., SGML_CATALOG_FILES env var).
 696         Catalog=
 697         ;;
 698    glafp*)
 699         case $HostOS_CPP in
 700            mingw32)
 701               Catalog=`cygpath -w $hardtop/$Catalog`
 702               ;;
 703            *) Catalog=$hardtop/$Catalog
 704               ;;
 705         esac
 706    ;;
 707 esac
 708 AC_SUBST(Catalog)
 709
 710 compress_nm=`basename $CompressCmd`
 711 if test x"$compress_nm" = xgzip; then
 712   CompressCmd="$CompressCmd -d"
 713   CompressSuffix="gz"
 714 else
 715   CompressSuffix="Z"
 716 fi
 717 AC_SUBST(CompressCmd)
 718 AC_SUBST(CompressSuffix)
 719
 720 dnl ** check for ghc-pkg command
 721 changequote(, )dnl
 722 ghc_pkg_guess=`echo $WithGhc | sed 's@ghc\([^/\\]*\)$@ghc-pkg\1@'`
 723 changequote([, ])dnl
 724 if $ghc_pkg_guess -l >/dev/null 2>/dev/null; then
 725    GhcPkgCmd=$ghc_pkg_guess
 726    AC_MSG_NOTICE([using $ghc_pkg_guess for ghc-pkg])
 727 else
 728    AC_PATH_PROG(GhcPkgCmd,ghc-pkg)
 729 fi
 730
 731 AC_ARG_WITH(greencard,
 732 [  --with-greencard=<greencard compiler>
 733         Use a command different from 'green-card' to compile GreenCard files
 734 ],
 735 [
 736 GreencardCmd=$withval;
 737 FPTOOLS_GREENCARD(3.00)
 738 ]
 739 )
 740
 741 AC_ARG_ENABLE(src-tree-happy,
 742 [  --enable-src-tree-happy
 743         Build and use source tree (fptools/happy) version of Happy.
 744 ],
 745 [UseSrcTreeHappy=YES],
 746 [UseSrcTreeHappy=NO]
 747 )
 748 dnl ** check for installed happy binary + version
 749 dnl    (don't do it if we're booting from .hc files though.)
 750 if test "$BootingFromHc" = "NO"; then
 751 FPTOOLS_HAPPY
 752 fi;
 753
 754 AC_ARG_ENABLE(src-tree-haddock,
 755 [  --enable-src-tree-haddock
 756         Build and use source tree (fptools/haddock) version of Haddock.
 757 ],
 758 [UseSrcTreeHaddock=YES],
 759 [UseSrcTreeHaddock=NO]
 760 )
 761 dnl ** check for installed haddock
 762 FPTOOLS_HADDOCK
 763
 764 AC_ARG_ENABLE(src-tree-alex,
 765 [  --enable-src-tree-alex
 766         Build and use source tree (fptools/alex) version of Alex.
 767 ],
 768 [UseSrcTreeAlex=YES],
 769 [UseSrcTreeAlex=NO]
 770 )
 771 dnl ** check for installed alex binary + version
 772 dnl    (don't do it if we're booting from .hc files though.)
 773 if test "$BootingFromHc" = "NO"; then
 774 FPTOOLS_ALEX
 775 fi;
 776
 777 dnl --------------------------------------------------
 778 dnl ### program checking section ends here ###
 779 dnl --------------------------------------------------
 780
 781 dnl --------------------------------------------------
 782 dnl * Platform header file and syscall feature tests
 783 dnl ### checking the state of the local header files and syscalls ###
 784
 785 dnl ** check for full ANSI header (.h) files
 786 AC_HEADER_STDC
 787
 788 dnl ** Enable large file support.  NB. do this before testing the type of
 789 dnl    off_t, because it will affect the result of that test.
 790 AC_SYS_LARGEFILE
 791
 792 dnl ** check for specific header (.h) files that we are interested in
 793 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h limits.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stddef.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h bfd.h winsock.h pthread.h sys/uio.h)
 794 AC_CHECK_HEADER(unistd.h,[AC_CHECK_FUNCS(lchown)])
 795
 796 AC_CHECK_HEADER(readline/readline.h, [HaveReadlineReadlineH=YES], [HaveReadlineReadlineH=NO])
 797 AC_CHECK_HEADER(readline/history.h, [HaveReadlineHistoryH=YES], [HaveReadlineHistoryH=NO])
 798
 799 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 800   HaveReadlineHeaders=YES
 801   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 802 else
 803   HaveReadlineHeaders=NO
 804   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 805 fi
 806 AC_SUBST(HaveReadlineHeaders)
 807
 808 dnl ** check for DOS include files
 809 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 810
 811 dnl ** check for Windows include files
 812 AC_CHECK_HEADERS(windows.h)
 813
 814 dnl ** check for OpenGL include files
 815 if test $UseQuartzOpenGL = YES ; then
 816   AC_CHECK_HEADERS(OpenGL/gl.h)
 817 else
 818   AC_CHECK_HEADERS(GL/gl.h)
 819 fi
 820
 821 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 822 AC_HEADER_TIME
 823
 824 dnl dynamic loading include files
 825 AC_CHECK_HEADERS(dlfcn.h dl.h)
 826
 827 dnl ** check for farcalloc (in bcc)
 828 AC_CHECK_HEADER(alloc.h,[AC_CHECK_FUNCS(farcalloc)])
 829
 830 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 831 AC_CHECK_HEADER(malloc.h,[AC_CHECK_FUNCS(valloc)])
 832
 833 dnl ** check for POSIX regex
 834 HavePosixRegex=NO
 835 AC_CHECK_HEADER(regex.h,[AC_CHECK_FUNC(regcomp, [HavePosixRegex=YES])])
 836 AC_SUBST(HavePosixRegex)
 837
 838 dnl ** how do we get a timezone name, and UTC offset ?
 839 AC_STRUCT_TIMEZONE
 840
 841 dnl ** do we have altzone?
 842 FP_DECL_ALTZONE
 843
 844 dnl ** does struct stat contain st_blksize?
 845 AC_STRUCT_ST_BLKSIZE
 846
 847 dnl ** do we have long longs?
 848 AC_CHECK_TYPES([long long])
 849
 850 dnl ** check what fields struct msghdr contains
 851 FPTOOLS_MSGHDR_MSG_ACCRIGHTS
 852 FPTOOLS_MSGHDR_MSG_CONTROL
 853
 854 dnl ** what are the sizes of various types
 855 AC_CHECK_SIZEOF(char,               1)
 856 AC_CHECK_SIZEOF(double,             8)
 857 AC_CHECK_SIZEOF(float,              4)
 858 AC_CHECK_SIZEOF(int,                4)
 859 AC_CHECK_SIZEOF(long,               4)
 860 if test "$ac_cv_type_long_long" = yes; then
 861 AC_CHECK_SIZEOF(long long,          8)
 862 fi
 863 AC_CHECK_SIZEOF(short,              2)
 864 AC_CHECK_SIZEOF(unsigned char,      1)
 865 AC_CHECK_SIZEOF(unsigned int,       4)
 866 AC_CHECK_SIZEOF(unsigned long,      4)
 867 if test "$ac_cv_type_long_long" = yes; then
 868 AC_CHECK_SIZEOF(unsigned long long, 8)
 869 fi
 870 AC_CHECK_SIZEOF(unsigned short,     2)
 871 AC_CHECK_SIZEOF(void *,             4)
 872
 873 dnl ** what are alignment constraints on various types
 874 FP_CHECK_ALIGNMENT(char)
 875 FP_CHECK_ALIGNMENT(double)
 876 FP_CHECK_ALIGNMENT(float)
 877 FP_CHECK_ALIGNMENT(int)
 878 FP_CHECK_ALIGNMENT(long)
 879 if test "$ac_cv_type_long_long" = yes; then
 880 FP_CHECK_ALIGNMENT(long long)
 881 fi
 882 FP_CHECK_ALIGNMENT(short)
 883 FP_CHECK_ALIGNMENT(unsigned char)
 884 FP_CHECK_ALIGNMENT(unsigned int)
 885 FP_CHECK_ALIGNMENT(unsigned long)
 886 if test "$ac_cv_type_long_long" = yes; then
 887 FP_CHECK_ALIGNMENT(unsigned long long)
 888 fi
 889 FP_CHECK_ALIGNMENT(unsigned short)
 890 FP_CHECK_ALIGNMENT(void *)
 891
 892 dnl ** map standard C types and ISO types to Haskell types
 893 FPTOOLS_CHECK_HTYPE(char)
 894 FPTOOLS_CHECK_HTYPE(signed char)
 895 FPTOOLS_CHECK_HTYPE(unsigned char)
 896 FPTOOLS_CHECK_HTYPE(short)
 897 FPTOOLS_CHECK_HTYPE(unsigned short)
 898 FPTOOLS_CHECK_HTYPE(int)
 899 FPTOOLS_CHECK_HTYPE(unsigned int)
 900 FPTOOLS_CHECK_HTYPE(long)
 901 FPTOOLS_CHECK_HTYPE(unsigned long)
 902 if test "$ac_cv_type_long_long" = yes; then
 903 FPTOOLS_CHECK_HTYPE(long long)
 904 FPTOOLS_CHECK_HTYPE(unsigned long long)
 905 fi
 906 FPTOOLS_CHECK_HTYPE(float)
 907 FPTOOLS_CHECK_HTYPE(double)
 908 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 909 FPTOOLS_CHECK_HTYPE(size_t)
 910 FPTOOLS_CHECK_HTYPE(wchar_t)
 911 dnl Int32 is a HACK for non-ISO C compilers
 912 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 913 FPTOOLS_CHECK_HTYPE(clock_t)
 914 FPTOOLS_CHECK_HTYPE(time_t)
 915 FPTOOLS_CHECK_HTYPE(dev_t, Word32)
 916 FPTOOLS_CHECK_HTYPE(ino_t)
 917 FPTOOLS_CHECK_HTYPE(mode_t)
 918 FPTOOLS_CHECK_HTYPE(off_t)
 919 FPTOOLS_CHECK_HTYPE(pid_t)
 920 FPTOOLS_CHECK_HTYPE(gid_t)
 921 FPTOOLS_CHECK_HTYPE(uid_t)
 922 FPTOOLS_CHECK_HTYPE(cc_t)
 923 FPTOOLS_CHECK_HTYPE(speed_t)
 924 FPTOOLS_CHECK_HTYPE(tcflag_t)
 925 FPTOOLS_CHECK_HTYPE(blkcnt_t)
 926 FPTOOLS_CHECK_HTYPE(nlink_t)
 927 FPTOOLS_CHECK_HTYPE(ssize_t)
 928 FPTOOLS_CHECK_HTYPE(rlim_t)
 929
 930 dnl ** Map OpenGL data types to Haskell types
 931 if test $GhcLibsWithHOpenGL = YES ; then
 932 FPTOOLS_CHECK_HTYPE(GLboolean)
 933 FPTOOLS_CHECK_HTYPE(GLbyte)
 934 FPTOOLS_CHECK_HTYPE(GLubyte)
 935 FPTOOLS_CHECK_HTYPE(GLshort)
 936 FPTOOLS_CHECK_HTYPE(GLushort)
 937 FPTOOLS_CHECK_HTYPE(GLint)
 938 FPTOOLS_CHECK_HTYPE(GLuint)
 939 FPTOOLS_CHECK_HTYPE(GLsizei)
 940 FPTOOLS_CHECK_HTYPE(GLenum)
 941 FPTOOLS_CHECK_HTYPE(GLbitfield)
 942 FPTOOLS_CHECK_HTYPE(GLfloat)
 943 FPTOOLS_CHECK_HTYPE(GLclampf)
 944 FPTOOLS_CHECK_HTYPE(GLdouble)
 945 FPTOOLS_CHECK_HTYPE(GLclampd)
 946 fi
 947
 948 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 949
 950 dnl ** can we open files in binary mode?
 951 FPTOOLS_O_BINARY
 952
 953 dnl ** check for GetModuleFileName and WinExec (windows only)
 954 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 955 dnl Doesn't work because the linker can't see the functions if
 956 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 957
 958 FPTOOLS_TRY_LINK_NOWARN(,[
 959 #if HAVE_WINDOWS_H
 960 #include <windows.h>
 961 #endif
 962 main() {
 963   WinExec("",0);
 964   exit(0);
 965 }
 966 ],
 967 [have_winexec=1],
 968 [have_winexec=0])
 969 if test "$have_winexec" = "1"; then
 970 AC_DEFINE(HAVE_WINEXEC)
 971 fi
 972
 973 FPTOOLS_TRY_LINK_NOWARN(,[
 974 #if HAVE_WINDOWS_H
 975 #include <windows.h>
 976 #endif
 977 main() {
 978   char* dir;
 979   GetModuleFileName((HMODULE)0,dir,0);
 980   exit(0);
 981 }
 982 ],
 983 [have_getmodulefilename=1],
 984 [have_getmodulefilename=0])
 985 if test "$have_getmodulefilename" = "1"; then
 986 AC_DEFINE(HAVE_GETMODULEFILENAME)
 987 fi
 988
 989 dnl ** check return type of signal handlers
 990 dnl Foo: assumes we can use prototypes.
 991 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 992 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 993 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 994 dnl #include <signal.h>
 995 dnl #ifdef signal
 996 dnl #undef signal
 997 dnl #endif
 998 dnl void (*signal (int, void (*)(int)))(int);
 999 dnl ],
1000 dnl [int i;],
1001 dnl ac_cv_type_signal_handler=void_int,
1002 dnl ac_cv_type_signal_handler=int_void)])
1003 dnl if test "$ac_cv_type_signal_handler" = void_int; then
1004 dnl AC_DEFINE(VOID_INT_SIGNALS)
1005 dnl fi
1006
1007 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
1008 AC_TYPE_SIGNAL
1009 if test "$ac_cv_type_signal" = void; then
1010 AC_DEFINE(VOID_INT_SIGNALS)
1011 fi
1012
1013 dnl ** check for more functions
1014 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
1015 AC_CHECK_FUNCS(strcmp)
1016 AC_CHECK_FUNCS(realpath _fullpath)
1017 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
1018 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
1019 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
1020 AC_CHECK_FUNCS(snprintf  _snprintf )
1021 AC_CHECK_FUNCS(popen     _popen )
1022 AC_CHECK_FUNCS(pclose    _pclose )
1023 AC_CHECK_FUNCS(setenv unsetenv)
1024
1025
1026 dnl ** check for specific library functions that we are interested in
1027 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat lstat symlink sysconf timelocal times vadvise localtime_r gmtime_r readdir_r getgrgid_r getgrnam_r getpwuid_r getpwnam_r)
1028
1029 dnl ** Solaris2 needs additionl flag for getpw*_r()
1030 case "$TargetPlatform" in
1031   *-solaris2*)
1032     unix_SRC_HSC2HS_OPTS="-D_POSIX_PTHREAD_SEMANTICS"
1033     AC_SUBST(unix_SRC_HSC2HS_OPTS)
1034   ;;
1035 esac
1036
1037 dnl ** check whether this machine has gmp3 installed
1038 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
1039   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
1040     HaveLibGmp=NO; LibGmp=not-installed))
1041 AC_SUBST(HaveLibGmp)
1042 AC_SUBST(LibGmp)
1043
1044 dnl ** (Mac OS X only: check for HaskellSupport.framework)
1045 HaveFrameworkHaskellSupport=NO
1046 if test $HostPlatform = "powerpc-apple-darwin"; then
1047  AC_MSG_CHECKING([for HaskellSupport.framework])
1048  save_libs="$LIBS"
1049  LIBS="-framework HaskellSupport"
1050  AC_TRY_LINK_FUNC(__gmpz_fdiv_qr, HaveFrameworkHaskellSupport=YES,)
1051  if test $HaveFrameworkHaskellSupport = YES; then
1052   AC_DEFINE(HAVE_FRAMEWORK_HASKELLSUPPORT)
1053  fi;
1054  LIBS="$save_libs"
1055  AC_MSG_RESULT([$HaveFrameworkHaskellSupport])
1056 fi;
1057 AC_SUBST(HaveFrameworkHaskellSupport)
1058
1059 dnl ** check for mingwex library
1060 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
1061 AC_SUBST(HaveLibMingwEx)
1062
1063 if test $HaveLibMingwEx = YES ; then
1064   AC_DEFINE(HAVE_MINGWEX)
1065 fi
1066
1067 if test "$HaveLibGmp" = "NO"; then
1068 if test "$HostArch_CPP" = "ia64"; then
1069 AC_MSG_ERROR([You need to install libgmp (the in-tree version does not work on IA64).])
1070 fi;
1071 fi;
1072
1073 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
1074 dnl    the order of these tests matters: bfd needs liberty
1075 AC_CHECK_LIB(iberty, xmalloc)
1076 AC_CHECK_LIB(bfd,    bfd_init)
1077
1078 dnl ** check for readline, for Hugs and hslibs' Readline
1079 dnl ncurses supersedes termcap and curses, but for compatibility,
1080 dnl we have to check for all...
1081 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
1082   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
1083     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
1084       HaveLibTermcap=NO; LibTermcap=not-installed)))
1085
1086 if test $HaveLibTermcap = YES ; then
1087   LIBS="-l$LibTermcap $LIBS"
1088   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
1089 fi
1090
1091 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
1092   AC_DEFINE(HAVE_READLINE_LIBS,1)
1093   LibsReadline="readline $LibTermcap"
1094 else
1095   AC_DEFINE(HAVE_READLINE_LIBS,0)
1096   LibsReadline=
1097 fi
1098 AC_SUBST(LibsReadline)
1099
1100 if test "$HaveLibReadline"; then
1101   AC_CHECK_LIB(readline, rl_erase_empty_line,
1102     [AC_DEFINE(HAVE_READLINE_4, 1)],
1103     [AC_DEFINE(HAVE_READLINE_4, 0)])
1104   AC_CHECK_LIB(readline, rl_free_undo_list,
1105     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
1106     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
1107 else
1108   AC_DEFINE(HAVE_READLINE_4, 0)
1109   AC_DEFINE(HAVE_READLINE_4_2, 0)
1110 fi
1111
1112 dnl ** check for math library
1113 FPTOOLS_CHECK_LIBM()
1114 AC_SUBST(LIBM)
1115
1116 dnl ** check for X Window System
1117 AC_PATH_XTRA()
1118
1119 dnl ** check for OpenGL/GLUT/GLX include paths and libraries
1120 if test $GhcLibsWithHOpenGL = YES ; then
1121   if test $UseQuartzOpenGL = YES ; then
1122     dnl Take a shortcut for Mac OS X native OpenGL:
1123     dnl It's in a non-standard location, but it's always there
1124     GL_CFLAGS=
1125         GL_LIBS=
1126         GLUT_LIBS=
1127         AC_SUBST(GL_CFLAGS)
1128         AC_SUBST(GL_LIBS)
1129         AC_SUBST(GLUT_LIBS)
1130   else
1131     FPTOOLS_HAVE_OPENGL
1132   fi
1133 fi
1134
1135 dnl ################################################################
1136 dnl Check for libraries
1137 dnl ################################################################
1138
1139 dnl ** check for libdl & RTLD_NEXT
1140
1141 dnl (Mac OS X only) ... but don't check if we already have the
1142 dnl HaskellSupport.framework
1143
1144 if test $HaveFrameworkHaskellSupport = YES; then
1145     HaveLibDL=NO
1146     HaveRtldNext=NO
1147     HaveRtldLocal=YES
1148     AC_DEFINE(HAVE_RTLDLOCAL)
1149     HaveRtldGlobal=YES
1150     AC_DEFINE(HAVE_RTLDGLOBAL)
1151     HaveRtldNow=YES
1152     AC_DEFINE(HAVE_RTLDNOW)
1153     AC_SUBST(HaveLibDL)
1154     AC_SUBST(HaveRtldNext)
1155     AC_SUBST(HaveRtldLocal)
1156     AC_SUBST(HaveRtldGlobal)
1157     AC_SUBST(HaveRtldNow)
1158 else
1159     AC_CHECK_LIB(dl, dlopen,
1160         [HaveLibDL=YES
1161          AC_DEFINE(HAVE_LIBDL)
1162          LIBS="$LIBS -ldl"],
1163         [HaveLibDL=NO])
1164     AC_CHECK_FUNCS(dlopen)
1165     AC_SUBST(HaveLibDL)
1166
1167     dnl ** sometimes RTLD_NEXT is hidden in #ifdefs we really don't wan to set
1168     AC_MSG_CHECKING(for RTLD_NEXT from dlfcn.h)
1169     AC_EGREP_CPP(yes,
1170     [
1171      #include <dlfcn.h>
1172      #ifdef RTLD_NEXT
1173             yes
1174      #endif
1175     ], [
1176       AC_MSG_RESULT(yes)
1177       AC_DEFINE(HAVE_RTLDNEXT)
1178       HaveRtldNext=YES
1179     ], [
1180       AC_MSG_RESULT(no)
1181       HaveRtldNext=NO
1182       ])
1183     AC_SUBST(HaveRtldNext)
1184
1185     dnl ** RTLD_LOCAL isn't available on cygwin or openbsd
1186     AC_MSG_CHECKING(for RTLD_LOCAL from dlfcn.h)
1187     AC_EGREP_CPP(yes,
1188     [
1189      #include <dlfcn.h>
1190      #ifdef RTLD_LOCAL
1191             yes
1192      #endif
1193     ], [
1194       AC_MSG_RESULT(yes)
1195       AC_DEFINE(HAVE_RTLDLOCAL)
1196       HaveRtldLocal=YES
1197     ], [
1198       AC_MSG_RESULT(no)
1199       HaveRtldLocal=NO
1200       ])
1201     AC_SUBST(HaveRtldLocal)
1202
1203     dnl ** RTLD_GLOBAL isn't available on openbsd
1204     AC_MSG_CHECKING(for RTLD_GLOBAL from dlfcn.h)
1205     AC_EGREP_CPP(yes,
1206     [
1207      #include <dlfcn.h>
1208      #ifdef RTLD_GLOBAL
1209             yes
1210      #endif
1211     ], [
1212       AC_MSG_RESULT(yes)
1213       AC_DEFINE(HAVE_RTLDGLOBAL)
1214       HaveRtldGlobal=YES
1215     ], [
1216       AC_MSG_RESULT(no)
1217       HaveRtldGlobal=NO
1218       ])
1219     AC_SUBST(HaveRtldGlobal)
1220
1221     dnl ** RTLD_NOW isn't available on openbsd
1222     AC_MSG_CHECKING(for RTLD_NOW from dlfcn.h)
1223     AC_EGREP_CPP(yes,
1224     [
1225      #include <dlfcn.h>
1226      #ifdef RTLD_NOW
1227             yes
1228      #endif
1229     ], [
1230       AC_MSG_RESULT(yes)
1231       AC_DEFINE(HAVE_RTLDNOW)
1232       HaveRtldNow=YES
1233     ], [
1234       AC_MSG_RESULT(no)
1235       HaveRtldNow=NO
1236       ])
1237     AC_SUBST(HaveRtldNow)
1238 fi
1239
1240 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
1241
1242 dnl ---------- usleep ----------
1243 dnl --- stolen from guile configure ---
1244 dnl --- FIXME: /usr/include/unistd.h can't be right?
1245
1246 ### On some systems usleep has no return value.  If it does have one,
1247 ### we'd like to return it; otherwise, we'll fake it.
1248 AC_CACHE_CHECK([return type of usleep], cv_func_usleep_return_type,
1249   [AC_EGREP_HEADER(changequote(<, >)<void[      ]+usleep>changequote([, ]),
1250                    /usr/include/unistd.h,
1251                    [cv_func_usleep_return_type=void],
1252                    [cv_func_usleep_return_type=int])])
1253 case "$cv_func_usleep_return_type" in
1254   "void" )
1255     AC_DEFINE(USLEEP_RETURNS_VOID, 1,
1256       [Define if the system headers declare usleep to return void.])
1257   ;;
1258 esac
1259
1260 dnl --------------------------------------------------
1261 dnl * test for in_addr_t
1262 dnl --------------------------------------------------
1263 AC_MSG_CHECKING(for in_addr_t in netinet/in.h)
1264 AC_EGREP_HEADER(in_addr_t, netinet/in.h,
1265  [ AC_DEFINE(HAVE_IN_ADDR_T) AC_MSG_RESULT(yes) ],
1266  AC_MSG_RESULT(no))
1267
1268 dnl --------------------------------------------------
1269 dnl * test for Linux sendfile(2)
1270 dnl --------------------------------------------------
1271 AC_MSG_CHECKING(for sendfile in sys/sendfile.h)
1272 AC_EGREP_HEADER(sendfile, sys/sendfile.h,
1273  [ AC_DEFINE(HAVE_LINUX_SENDFILE) AC_MSG_RESULT(yes) ],
1274  AC_MSG_RESULT(no))
1275
1276 dnl --------------------------------------------------
1277 dnl * test for BSD sendfile(2)
1278 dnl --------------------------------------------------
1279 AC_MSG_CHECKING(for sendfile in sys/socket.h)
1280 AC_EGREP_HEADER(sendfile, sys/socket.h,
1281  [ AC_DEFINE(HAVE_BSD_SENDFILE) AC_MSG_RESULT(yes) ],
1282  AC_MSG_RESULT(no))
1283
1284 dnl --------------------------------------------------
1285 dnl * test for GTK+
1286 dnl --------------------------------------------------
1287
1288 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
1289 if test "$GTK_CONFIG" != ""; then
1290    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
1291         fptools_cv_gtk_version=`$GTK_CONFIG --version`
1292     ])
1293     GTK_VERSION=$fptools_cv_gtk_version
1294 else
1295     GTK_VERSION=
1296 fi
1297
1298 case $fptools_cv_gtk_version in
1299   1.[[23]].*) ;;
1300   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
1301      GTK_CONFIG=
1302      ;;
1303 esac
1304
1305 AC_SUBST(GTK_CONFIG)
1306 AC_SUBST(GTK_VERSION)
1307
1308 dnl --------------------------------------------------
1309 dnl * Miscellaneous feature tests
1310 dnl --------------------------------------------------
1311
1312 dnl ** can we get alloca?
1313 AC_FUNC_ALLOCA
1314
1315 dnl ** Working vfork?
1316 AC_FUNC_VFORK
1317
1318 dnl ** determine whether or not const works
1319 AC_C_CONST
1320
1321 dnl ** are we big endian?
1322 AC_C_BIGENDIAN
1323
1324 dnl ** check for leading underscores in symbol names
1325 FPTOOLS_UNDERSCORE
1326
1327 dnl ** check for ld, and whether ld has -x option
1328 AC_PATH_PROG(LdCmdRaw, ld)
1329 case $HostOS_CPP in
1330  mingw32) LdCmd=`cygpath -w ${LdCmdRaw} | sed -e 's@\\\\@/@g' `
1331            ;;
1332  *) LdCmd=${LdCmdRaw}
1333     ;;
1334 esac
1335 AC_SUBST(LdCmd)
1336 FPTOOLS_LD_X
1337
1338 AC_MSG_CHECKING([for SIGPOLL])
1339 AC_EGREP_CPP(we_have_sigpoll,
1340 [#include <signal.h>
1341 #ifdef SIGPOLL
1342 we_have_sigpoll
1343 #endif
1344 ], AC_DEFINE(HAVE_SIGPOLL) haveSIGPOLL=yes, haveSIGPOLL=no)
1345 AC_MSG_RESULT([$haveSIGPOLL])
1346
1347 AC_MSG_CHECKING([for _SC_GETGR_R_SIZE_MAX])
1348 AC_EGREP_CPP(we_have_that_sysconf_thing,
1349 [
1350 #include <unistd.h>
1351 #ifdef _SC_GETGR_R_SIZE_MAX
1352 we_have_that_sysconf_thing
1353 #endif
1354 ],
1355 [AC_MSG_RESULT([yes])
1356 AC_DEFINE(HAVE_SC_GETGR_R_SIZE_MAX)],
1357 [AC_MSG_RESULT([no])])
1358
1359 AC_MSG_CHECKING([for _SC_GETPW_R_SIZE_MAX])
1360 AC_EGREP_CPP(we_have_that_sysconf_thing,
1361 [
1362 #include <unistd.h>
1363 #ifdef _SC_GETPW_R_SIZE_MAX
1364 we_have_that_sysconf_thing
1365 #endif
1366 ],
1367 [AC_MSG_RESULT([yes])
1368 AC_DEFINE(HAVE_SC_GETPW_R_SIZE_MAX)],
1369 [AC_MSG_RESULT([no])])
1370
1371 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )