configure.ac

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.ac | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The University of Glasgow 1994-2004
   7 #
   8 # Configure script template for GHC
   9 #
  10 # Process with 'autoreconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 AC_INIT([The Glorious Glasgow Haskell Compilation System], [7.1], [glasgow-haskell-bugs@haskell.org], [ghc])
  17
  18 # Set this to YES for a released version, otherwise NO
  19 : ${RELEASE=NO}
  20
  21 # The primary version (e.g. 6.7, 6.6.1) is set in the AC_INIT line
  22 # above.  If this is not a released version, then we will append the
  23 # date to the version number (e.g. 6.7.20070204).  The date is
  24 # constructed by finding the date of the most recent patch in the
  25 # darcs repository.  If this is a source distribution (not a darcs
  26 # checkout), then we ship a file 'VERSION' containing the full version
  27 # when the source distribution was created.
  28
  29 if test ! -f mk/config.h.in; then
  30    echo "mk/config.h.in doesn't exist: perhaps you haven't run 'perl boot'?"
  31    exit 1
  32 fi
  33
  34 AC_SUBST([CONFIGURE_ARGS], [$ac_configure_args])
  35
  36 dnl ----------------------------------------------------------
  37 dnl ** Find unixy sort and find commands,
  38 dnl ** which are needed by FP_SETUP_PROJECT_VERSION
  39
  40 dnl ** Find find command (for Win32's benefit)
  41 FP_PROG_FIND
  42
  43 dnl ** Find sort command (for the benefit of Win32 environs)
  44 FP_PROG_SORT
  45
  46 dnl ----------------------------------------------------------
  47 FP_SETUP_PROJECT_VERSION
  48
  49 # Hmmm, we fix the RPM release number to 1 here... Is this convenient?
  50 AC_SUBST([release], [1])
  51
  52 # First off, a distrib sanity check..
  53 AC_CONFIG_SRCDIR([mk/config.mk.in])
  54
  55 dnl * We require autoconf version 2.52
  56 dnl We need 2.50 due to the use of AC_SYS_LARGEFILE and AC_MSG_NOTICE.
  57 dnl We need 2.52 due to the use of AS_TR_CPP and AS_TR_SH.
  58 AC_PREREQ([2.52])
  59
  60 # -------------------------------------------------------------------------
  61 # Prepare to generate the following header files
  62 #
  63 #
  64 AC_CONFIG_HEADER(mk/config.h)
  65
  66 # No, semi-sadly, we don't do `--srcdir'...
  67 if test x"$srcdir" != 'x.' ; then
  68     echo "This configuration does not support the \`--srcdir' option.."
  69     exit 1
  70 fi
  71
  72 dnl --------------------------------------------------------------
  73 dnl * Project specific configuration options
  74 dnl --------------------------------------------------------------
  75 dnl What follows is a bunch of options that can either be configured
  76 dnl through command line options to the configure script or by
  77 dnl supplying defns in the build tree's mk/build.mk. Having the option to
  78 dnl use either is considered a Feature.
  79
  80 dnl ** What command to use to compile compiler sources ?
  81 dnl --------------------------------------------------------------
  82
  83 AC_ARG_WITH([ghc],
  84 [AC_HELP_STRING([--with-ghc=ARG],
  85   [Use ARG as the path to GHC  [default=autodetect]])],
  86   [WithGhc="$withval"],
  87   [if test "$GHC" = ""; then
  88     AC_PATH_PROG([GHC], [ghc])
  89   fi
  90   WithGhc="$GHC"])
  91
  92
  93 dnl ** Tell the make system which OS we are using
  94 dnl $OSTYPE is set by the operating system to "msys" or "cygwin" or something
  95 AC_SUBST(OSTYPE)
  96
  97 dnl ** Booting from .hc files?
  98 dnl --------------------------------------------------------------
  99 AC_ARG_ENABLE(hc-boot,
 100 [AC_HELP_STRING([--enable-hc-boot],
 101 [Boot the Glasgow Haskell Compiler from intermediate .hc files.
 102  (This option is mostly of interest to porters.) [default=no]])],
 103 [ if test x"$enableval" = x"yes"; then
 104         BootingFromHc=YES
 105   else
 106         BootingFromHc=NO
 107   fi
 108 ],
 109 [BootingFromHc=NO]
 110 )
 111 AC_SUBST(BootingFromHc)
 112
 113 AC_ARG_ENABLE(bootstrap-with-devel-snapshot,
 114 [AC_HELP_STRING([--enable-bootstrap-with-devel-snapshot],
 115                 [Allow bootstrapping using a development snapshot of GHC.  This is not guaranteed to work.])],
 116         EnableBootstrapWithDevelSnaphost=YES,
 117         EnableBootstrapWithDevelSnaphost=NO
 118 )
 119
 120 if test "$WithGhc" != ""; then
 121   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 122
 123   if test "$GhcMajVersion" = "unknown" -o "$GhcMinVersion" = "unknown"; then
 124      AC_MSG_ERROR([Cannot determine the version of $WithGhc.  Is it really GHC?])
 125   fi
 126
 127   AC_SUBST(GhcVersion)dnl
 128   AC_SUBST(GhcMajVersion)dnl
 129   AC_SUBST(GhcMinVersion)dnl
 130   AC_SUBST(GhcPatchLevel)dnl
 131   GhcMinVersion2=`echo "$GhcMinVersion" | sed 's/^\\(.\\)$/0\\1/'`
 132   GhcCanonVersion="$GhcMajVersion$GhcMinVersion2"
 133   if test $GhcCanonVersion -ge 613; then ghc_ge_613=YES; else ghc_ge_613=NO; fi
 134   AC_SUBST(ghc_ge_613)dnl
 135 fi
 136
 137 dnl ** Must have GHC to build GHC, unless --enable-hc-boot is on
 138 if test "$BootingFromHc" = "NO" -a -d "$srcdir/compiler"; then
 139   if test "$WithGhc" = ""; then
 140      AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 141   fi
 142   FP_COMPARE_VERSIONS([$GhcVersion],[-lt],[6.12],
 143     [AC_MSG_ERROR([GHC version 6.12 or later is required to compile GHC.])])dnl
 144
 145   if test `expr $GhcMinVersion % 2` = "1"; then
 146      if test "$EnableBootstrapWithDevelSnaphost" = "NO"; then
 147         AC_MSG_ERROR([
 148      $WithGhc is a development snapshot of GHC, version $GhcVersion.
 149      Bootstrapping using this version of GHC is not supported, and may not
 150      work.  Use --enable-bootstrap-with-devel-snapshot to try it anyway,
 151      or --with-ghc to specify a different GHC to use.])
 152      fi
 153   fi
 154 fi;
 155
 156 # GHC is passed to Cabal, so we need a native path
 157 if test "${WithGhc}" != ""
 158 then
 159     ghc_host=`"${WithGhc}" +RTS --info | grep 'Host platform' | sed -e 's/.*, "//' -e 's/")//'`
 160
 161     if test "$ghc_host" = "i386-unknown-mingw32"
 162     then
 163         if test "${OSTYPE}" = "msys"
 164         then
 165             WithGhc=`echo "${WithGhc}" | sed "s#^/\([a-zA-Z]\)/#\1:/#"`
 166         else
 167             # Canonicalise to <drive>:/path/to/ghc
 168             WithGhc=`cygpath -m "${WithGhc}"`
 169         fi
 170         echo "GHC path canonicalised to: ${WithGhc}"
 171     fi
 172 fi
 173 AC_SUBST([WithGhc])
 174
 175 dnl ** Without optimization some INLINE trickery fails for GHCi
 176 SRC_CC_OPTS="-O"
 177
 178 FP_ICONV
 179 FP_GMP
 180
 181 dnl--------------------------------------------------------------------
 182 dnl * Choose host(/target/build) platform
 183 dnl--------------------------------------------------------------------
 184 dnl If we aren't explicitly told what values to use with configure flags,
 185 dnl we ask the bootstrapping compiler what platform it is for
 186
 187 if test "${WithGhc}" != ""
 188 then
 189         bootstrap_host=`"${WithGhc}" +RTS --info | grep '^ ,("Host platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 190         bootstrap_target=`"${WithGhc}" +RTS --info | grep '^ ,("Target platform"' | sed -e 's/.*, "//' -e 's/")//' | tr -d '\r'`
 191         if test "$bootstrap_host" != "$bootstrap_target"
 192         then
 193                 echo "Bootstrapping GHC is a cross compiler. This probably isn't going to work"
 194         fi
 195 fi
 196
 197 # We have to run these unconditionally, but we may discard their
 198 # results in the following code
 199 AC_CANONICAL_BUILD
 200 AC_CANONICAL_HOST
 201 AC_CANONICAL_TARGET
 202
 203 FPTOOLS_SET_PLATFORM_VARS
 204
 205 exeext=''
 206 soext='.so'
 207 case $host in
 208 *-unknown-cygwin32)
 209     AC_MSG_WARN([GHC does not support the Cygwin target at the moment])
 210     AC_MSG_WARN([I'm assuming you wanted to build for i386-unknown-mingw32])
 211     exit 1
 212     ;;
 213 *-unknown-mingw32)
 214     exeext='.exe'
 215     soext='.dll'
 216     ;;
 217 i386-apple-darwin|powerpc-apple-darwin)
 218     soext='.dylib'
 219     ;;
 220 x86_64-apple-darwin)
 221     soext='.dylib'
 222     ;;
 223 esac
 224
 225 # Sync this with cTargetArch in compiler/ghc.mk
 226 checkArch() {
 227     case $1 in
 228     alpha|arm|hppa|hppa1_1|i386|ia64|m68k|mips|mipseb|mipsel|powerpc|powerpc64|rs6000|s390|sparc|sparc64|vax|x86_64)
 229         ;;
 230     *)
 231         echo "Unknown arch $1"
 232         exit 1
 233         ;;
 234     esac
 235 }
 236
 237 checkVendor() {
 238     case $1 in
 239     dec|unknown|hp|apple|next|sun|sgi|ibm)
 240         ;;
 241     *)
 242         echo "Unknown vendor $1"
 243         exit 1
 244         ;;
 245     esac
 246 }
 247
 248 checkOS() {
 249     case $1 in
 250     linux|freebsd|netbsd|openbsd|dragonfly|osf1|osf3|hpux|linuxaout|kfreebsdgnu|freebsd2|solaris2|cygwin32|mingw32|darwin|gnu|nextstep2|nextstep3|sunos4|ultrix|irix|aix|haiku)
 251         ;;
 252     *)
 253         echo "Unknown OS '$1'"
 254         exit 1
 255         ;;
 256     esac
 257 }
 258
 259 BuildPlatform="$BuildArch-$BuildVendor-$BuildOS"
 260 BuildPlatform_CPP=`echo "$BuildPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 261 BuildArch_CPP=`    echo "$BuildArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 262 BuildVendor_CPP=`  echo "$BuildVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 263 BuildOS_CPP=`      echo "$BuildOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 264
 265 checkArch "$BuildArch"
 266 checkVendor "$BuildVendor"
 267 checkOS "$BuildOS"
 268
 269 HostPlatform="$HostArch-$HostVendor-$HostOS"
 270 HostPlatform_CPP=`echo "$HostPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 271 HostArch_CPP=`    echo "$HostArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 272 HostVendor_CPP=`  echo "$HostVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 273 HostOS_CPP=`      echo "$HostOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 274
 275 checkArch "$HostArch"
 276 checkVendor "$HostVendor"
 277 checkOS "$HostOS"
 278
 279 TargetPlatform="$TargetArch-$TargetVendor-$TargetOS"
 280 TargetPlatform_CPP=`echo "$TargetPlatform" | sed -e 's/\./_/g' -e 's/-/_/g'`
 281 TargetArch_CPP=`    echo "$TargetArch"     | sed -e 's/\./_/g' -e 's/-/_/g'`
 282 TargetVendor_CPP=`  echo "$TargetVendor"   | sed -e 's/\./_/g' -e 's/-/_/g'`
 283 TargetOS_CPP=`      echo "$TargetOS"       | sed -e 's/\./_/g' -e 's/-/_/g'`
 284
 285 checkArch "$TargetArch"
 286 checkVendor "$TargetVendor"
 287 checkOS "$TargetOS"
 288
 289 # Verify that the installed (bootstrap) GHC is capable of generating
 290 # code for the requested build platform.
 291 if test "$BuildPlatform" != "$bootstrap_target"
 292 then
 293     echo "This GHC (${WithGhc}) does not generate code for the build platform"
 294     echo "   GHC target platform    : $bootstrap_target"
 295     echo "   Desired build platform : $BuildPlatform"
 296     exit 1
 297 fi
 298
 299 echo "GHC build  : $BuildPlatform"
 300 echo "GHC host   : $HostPlatform"
 301 echo "GHC target : $TargetPlatform"
 302
 303 AC_SUBST(BuildPlatform)
 304 AC_SUBST(HostPlatform)
 305 AC_SUBST(TargetPlatform)
 306 AC_SUBST(HostPlatform_CPP)
 307 AC_SUBST(BuildPlatform_CPP)
 308 AC_SUBST(TargetPlatform_CPP)
 309
 310 AC_SUBST(HostArch_CPP)
 311 AC_SUBST(BuildArch_CPP)
 312 AC_SUBST(TargetArch_CPP)
 313
 314 AC_SUBST(HostOS_CPP)
 315 AC_SUBST(BuildOS_CPP)
 316 AC_SUBST(TargetOS_CPP)
 317
 318 AC_SUBST(HostVendor_CPP)
 319 AC_SUBST(BuildVendor_CPP)
 320 AC_SUBST(TargetVendor_CPP)
 321
 322 AC_SUBST(exeext)
 323 AC_SUBST(soext)
 324
 325 AC_ARG_WITH(hc,
 326 [AC_HELP_STRING([--with-hc=ARG],
 327         [Use ARG as the path to the compiler for compiling ordinary
 328          Haskell code  (default= value of --with-ghc)])],
 329 [WithHc="$withval"],
 330 [WithHc=$WithGhc]
 331 )
 332 AC_SUBST(WithHc)
 333
 334 # This uses GHC, so put it after the "GHC is required" check above:
 335 FP_INTREE_GHC_PWD
 336 FP_FIND_ROOT
 337
 338 if test "$HostOS" = "mingw32"
 339 then
 340     test -d inplace || mkdir inplace
 341
 342     CC="$hardtop/inplace/mingw/bin/gcc.exe"
 343     LD="$hardtop/inplace/mingw/bin/ld.exe"
 344     NM="$hardtop/inplace/mingw/bin/nm.exe"
 345     fp_prog_ar_raw="$hardtop/inplace/mingw/bin/ar.exe"
 346
 347     # NB. If you update the tarbballs to a new version of gcc, don't
 348     # forget to tweak the paths in driver/gcc/gcc.c.
 349     if ! test -d inplace/mingw ||
 350          test inplace/mingw -ot ghc-tarballs/mingw/binutils*.tar.lzma  ||
 351          test inplace/mingw -ot ghc-tarballs/mingw/gcc-core*.tar.lzma  ||
 352          test inplace/mingw -ot ghc-tarballs/mingw/gcc-c++*.tar.lzma   ||
 353          test inplace/mingw -ot ghc-tarballs/mingw/libgcc*.tar.gz      ||
 354          test inplace/mingw -ot ghc-tarballs/mingw/libgmp*.tar.gz      ||
 355          test inplace/mingw -ot ghc-tarballs/mingw/libmpc*.tar.gz      ||
 356          test inplace/mingw -ot ghc-tarballs/mingw/libmpfr*.tar.gz     ||
 357          test inplace/mingw -ot ghc-tarballs/mingw/libstdc*.tar.lzma   ||
 358          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dev.tar.gz ||
 359          test inplace/mingw -ot ghc-tarballs/mingw/mingwrt*-dll.tar.gz ||
 360          test inplace/mingw -ot ghc-tarballs/mingw/w32api*.tar.lzma
 361     then
 362         AC_MSG_NOTICE([Making in-tree mingw tree])
 363         rm -rf inplace/mingw
 364         mkdir inplace/mingw
 365         (
 366             cd inplace/mingw &&
 367             tar --lzma -xf ../../ghc-tarballs/mingw/binutils*.tar.lzma  &&
 368             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-core*.tar.lzma  &&
 369             tar --lzma -xf ../../ghc-tarballs/mingw/gcc-c++*.tar.lzma   &&
 370             tar --lzma -xf ../../ghc-tarballs/mingw/libgcc*.tar.lzma    &&
 371             tar --lzma -xf ../../ghc-tarballs/mingw/libgmp*.tar.lzma    &&
 372             tar --lzma -xf ../../ghc-tarballs/mingw/libmpc*.tar.lzma    &&
 373             tar --lzma -xf ../../ghc-tarballs/mingw/libmpfr*.tar.lzma   &&
 374             tar --lzma -xf ../../ghc-tarballs/mingw/libstdc*.tar.lzma   &&
 375             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dev.tar.gz &&
 376             tar -z     -xf ../../ghc-tarballs/mingw/mingwrt*-dll.tar.gz &&
 377             tar --lzma -xf ../../ghc-tarballs/mingw/w32api*.tar.lzma    &&
 378             mv bin/gcc.exe bin/realgcc.exe
 379         )
 380         PATH=`pwd`/inplace/mingw/bin:$PATH inplace/mingw/bin/realgcc.exe driver/gcc/gcc.c driver/utils/cwrapper.c driver/utils/getLocation.c -Idriver/utils -o inplace/mingw/bin/gcc.exe
 381         if ! test -e inplace/mingw/bin/gcc.exe
 382         then
 383             AC_MSG_ERROR([GHC is required unless bootstrapping from .hc files.])
 384         fi
 385         AC_MSG_NOTICE([In-tree mingw tree created])
 386     fi
 387     if ! test -d inplace/perl ||
 388          test inplace/perl -ot ghc-tarballs/perl/ghc-perl*.tar.gz
 389     then
 390         AC_MSG_NOTICE([Making in-tree perl tree])
 391         rm -rf inplace/perl
 392         mkdir inplace
 393         mkdir inplace/perl
 394         (
 395             cd inplace/perl &&
 396             tar -zxf ../../ghc-tarballs/perl/ghc-perl*.tar.gz
 397         )
 398         AC_MSG_NOTICE([In-tree perl tree created])
 399     fi
 400 fi
 401
 402 dnl ** Which gcc to use?
 403 dnl --------------------------------------------------------------
 404 FP_ARG_WITH_PATH_GNU_PROG([CC], [gcc])
 405 export CC
 406 WhatGccIsCalled="$CC"
 407 AC_SUBST(WhatGccIsCalled)
 408
 409 dnl ** Which ld to use?
 410 dnl --------------------------------------------------------------
 411 FP_ARG_WITH_PATH_GNU_PROG([LD], [ld])
 412 LdCmd="$LD"
 413 AC_SUBST([LdCmd])
 414
 415 dnl ** Which nm to use?
 416 dnl --------------------------------------------------------------
 417 FP_ARG_WITH_PATH_GNU_PROG([NM], [nm])
 418 NmCmd="$NM"
 419 AC_SUBST([NmCmd])
 420
 421 SplitObjsBroken=NO
 422 if test "$TargetOS_CPP" = "darwin"
 423 then
 424     AC_MSG_CHECKING(XCode version)
 425     XCodeVersion=`xcodebuild -version | grep Xcode | sed "s/Xcode //"`
 426     # Old XCode versions don't actually give the XCode version
 427     if test "$XCodeVersion" = ""
 428     then
 429         AC_MSG_RESULT(not found (too old?))
 430         SplitObjsBroken=YES
 431     else
 432         AC_MSG_RESULT($XCodeVersion)
 433         XCodeVersion1=`echo "$XCodeVersion" | sed 's/\..*//'`
 434 changequote(, )dnl
 435         XCodeVersion2=`echo "$XCodeVersion" | sed 's/[^.]*\.\([^.]*\).*/\1/'`
 436 changequote([, ])dnl
 437         AC_MSG_NOTICE(XCode version component 1: $XCodeVersion1)
 438         AC_MSG_NOTICE(XCode version component 2: $XCodeVersion2)
 439         # Split objects is broken (#4013) with XCode < 3.2
 440         if test "$XCodeVersion1" -lt 3
 441         then
 442             SplitObjsBroken=YES
 443         else
 444             if test "$XCodeVersion1" -eq 3
 445             then
 446                 if test "$XCodeVersion2" -lt 2
 447                 then
 448                     SplitObjsBroken=YES
 449                 fi
 450             fi
 451         fi
 452     fi
 453 fi
 454 AC_SUBST([SplitObjsBroken])
 455
 456 dnl ** Mac OS X: explicit deployment target
 457 dnl --------------------------------------------------------------
 458 AC_ARG_WITH([macosx-deployment-target],
 459 [AC_HELP_STRING([--with-macosx-deployment-target=VERSION],
 460         [Build for Mac OS VERSION and higher  (default= version of build host)])],
 461 [FP_MACOSX_DEPLOYMENT_TARGET="$withval"
 462  if test "x$TargetOS_CPP-$TargetVendor_CPP" != "xdarwin-apple"; then
 463    # ignore everywhere, but on Mac OS
 464    AC_MSG_WARN([--macosx-deployment-target is only available on Mac OS X])
 465    FP_MACOSX_DEPLOYMENT_TARGET=none
 466  fi],
 467 [FP_MACOSX_DEPLOYMENT_TARGET=none]
 468 )
 469 FP_CHECK_MACOSX_DEPLOYMENT_TARGET
 470 AC_SUBST(MACOSX_DEPLOYMENT_VERSION)
 471 AC_SUBST(MACOSX_DEPLOYMENT_SDK)
 472
 473 dnl --------------------------------------------------------------
 474 dnl End of configure script option section
 475 dnl --------------------------------------------------------------
 476
 477
 478 dnl --------------------------------------------------------------
 479 dnl * General configuration checks
 480 dnl --------------------------------------------------------------
 481
 482 dnl ** Can the unix package be built?
 483 dnl --------------------------------------------------------------
 484
 485 if test x"$TargetPlatform" = x"i386-unknown-mingw32"; then
 486    GhcLibsWithUnix=NO
 487 else
 488    GhcLibsWithUnix=YES
 489 fi
 490 AC_SUBST([GhcLibsWithUnix])
 491
 492 dnl ** does #! work?
 493 AC_SYS_INTERPRETER()
 494
 495 dnl ** look for `perl'
 496 case $HostOS_CPP in
 497 cygwin32|mingw32)
 498     PerlCmd=$hardtop/inplace/perl/perl
 499     ;;
 500 *)
 501     AC_PATH_PROG(PerlCmd,perl)
 502     if test -z "$PerlCmd"
 503     then
 504         echo "You must install perl before you can continue"
 505         echo "Perhaps it is already installed, but not in your PATH?"
 506         exit 1
 507     else
 508         FPTOOLS_CHECK_PERL_VERSION
 509     fi
 510     ;;
 511 esac
 512
 513 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 514 FPTOOLS_SHEBANG_PERL
 515
 516 dnl ** check for Python
 517 AC_PATH_PROG(PythonCmd,python)
 518
 519 dnl ** look for GCC and find out which version
 520 dnl     Figure out which C compiler to use.  Gcc is preferred.
 521 dnl     If gcc, make sure it's at least 2.1
 522 dnl
 523 FP_HAVE_GCC
 524
 525 FPTOOLS_SET_C_LD_FLAGS([target],[CFLAGS],[LDFLAGS],[IGNORE_LINKER_LD_FLAGS],[CPPFLAGS])
 526 FPTOOLS_SET_C_LD_FLAGS([build],[CONF_CC_OPTS_STAGE0],[CONF_GCC_LINKER_OPTS_STAGE0],[CONF_LD_LINKER_OPTS_STAGE0],[CONF_CPP_OPTS_STAGE0])
 527 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE1],[CONF_GCC_LINKER_OPTS_STAGE1],[CONF_LD_LINKER_OPTS_STAGE1],[CONF_CPP_OPTS_STAGE1])
 528 # Stage 3 won't be supported by cross-compilation
 529 FPTOOLS_SET_C_LD_FLAGS([target],[CONF_CC_OPTS_STAGE2],[CONF_GCC_LINKER_OPTS_STAGE2],[CONF_LD_LINKER_OPTS_STAGE2],[CONF_CPP_OPTS_STAGE2])
 530
 531 FP_GCC_EXTRA_FLAGS
 532
 533 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 534 AC_PROG_CPP
 535
 536 AC_SUBST(CONF_CC_OPTS_STAGE0)
 537 AC_SUBST(CONF_CC_OPTS_STAGE1)
 538 AC_SUBST(CONF_CC_OPTS_STAGE2)
 539 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE0)
 540 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE1)
 541 AC_SUBST(CONF_GCC_LINKER_OPTS_STAGE2)
 542 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE0)
 543 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE1)
 544 AC_SUBST(CONF_LD_LINKER_OPTS_STAGE2)
 545 AC_SUBST(CONF_CPP_OPTS_STAGE0)
 546 AC_SUBST(CONF_CPP_OPTS_STAGE1)
 547 AC_SUBST(CONF_CPP_OPTS_STAGE2)
 548
 549 dnl ** figure out how to do context diffs
 550 FP_PROG_CONTEXT_DIFF
 551
 552 dnl Let's make sure install-sh is executable here.  If we got it from
 553 dnl a darcs repo, it might not be (see bug #978).
 554 chmod +x install-sh
 555 dnl ** figure out how to do a BSD-ish install
 556 AC_PROG_INSTALL
 557
 558 dnl If you can run configure, you certainly have /bin/sh
 559 AC_DEFINE([HAVE_BIN_SH], [1], [Define to 1 if you have /bin/sh.])
 560
 561 dnl ** how to invoke `ar' and `ranlib'
 562 FP_PROG_AR_SUPPORTS_ATFILE
 563 FP_PROG_AR_NEEDS_RANLIB
 564 FP_PROG_AR_SUPPORTS_INPUT
 565
 566 dnl ** Check to see whether ln -s works
 567 AC_PROG_LN_S
 568
 569
 570 dnl ** Find the path to sed
 571 AC_PATH_PROGS(SedCmd,gsed sed,sed)
 572
 573
 574 dnl ** check for time command
 575 AC_PATH_PROG(TimeCmd,time)
 576
 577 dnl ** check for tar
 578 dnl   if GNU tar is named gtar, look for it first.
 579 AC_PATH_PROGS(TarCmd,gnutar gtar tar,tar)
 580
 581 dnl ** check for patch
 582 dnl if GNU patch is named gpatch, look for it first
 583 AC_PATH_PROGS(PatchCmd,gpatch patch, patch)
 584
 585 dnl ** check for dtrace (currently only implemented for Mac OS X)
 586 HaveDtrace=NO
 587 AC_PATH_PROG(DtraceCmd,dtrace)
 588 if test -n "$DtraceCmd"; then
 589   if test "x$TargetOS_CPP-$TargetVendor_CPP" == "xdarwin-apple" -o "x$TargetOS_CPP-$TargetVendor_CPP" == "xsolaris2-unknown"; then
 590     HaveDtrace=YES
 591   fi
 592 fi
 593 AC_SUBST(HaveDtrace)
 594
 595 AC_PATH_PROG(HSCOLOUR,HsColour)
 596 # HsColour is passed to Cabal, so we need a native path
 597 if test "x$HostPlatform"  = "xi386-unknown-mingw32" && \
 598    test "${OSTYPE}"      != "msys"                  && \
 599    test "${HSCOLOUR}"    != ""
 600 then
 601     # Canonicalise to <drive>:/path/to/gcc
 602     HSCOLOUR=`cygpath -m ${HSCOLOUR}`
 603 fi
 604
 605 dnl ** check for DocBook toolchain
 606 FP_CHECK_DOCBOOK_DTD
 607 FP_DOCBOOK_XSL
 608 FP_PROG_DBLATEX
 609
 610 FP_PROG_HSTAGS
 611
 612 dnl ** check for ghc-pkg command
 613 FP_PROG_GHC_PKG
 614
 615 dnl ** check for installed happy binary + version
 616 dnl    (don't do it if we're booting from .hc files though.)
 617 if test "$BootingFromHc" = "NO"; then
 618 FPTOOLS_HAPPY
 619 fi;
 620
 621 dnl ** check for installed alex binary + version
 622 dnl    (don't do it if we're booting from .hc files though.)
 623 if test "$BootingFromHc" = "NO"; then
 624 FPTOOLS_ALEX
 625 fi;
 626
 627 dnl --------------------------------------------------
 628 dnl ### program checking section ends here ###
 629 dnl --------------------------------------------------
 630
 631 dnl --------------------------------------------------
 632 dnl * Platform header file and syscall feature tests
 633 dnl ### checking the state of the local header files and syscalls ###
 634
 635 dnl ** check for full ANSI header (.h) files
 636 AC_HEADER_STDC
 637
 638 dnl ** Enable large file support.  NB. do this before testing the type of
 639 dnl    off_t, because it will affect the result of that test.
 640 AC_SYS_LARGEFILE
 641
 642 dnl ** check for specific header (.h) files that we are interested in
 643 AC_CHECK_HEADERS([bfd.h ctype.h dirent.h dlfcn.h errno.h fcntl.h grp.h limits.h locale.h nlist.h pthread.h pwd.h signal.h sys/cpuset.h sys/mman.h sys/resource.h sys/select.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/utsname.h sys/wait.h termios.h time.h utime.h windows.h winsock.h sched.h])
 644
 645 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 646 AC_HEADER_TIME
 647
 648 dnl ** do we have long longs?
 649 AC_CHECK_TYPES([long long])
 650
 651 dnl ** what are the sizes of various types
 652 AC_CHECK_SIZEOF(char,               1)
 653 AC_CHECK_SIZEOF(double,             8)
 654 AC_CHECK_SIZEOF(float,              4)
 655 AC_CHECK_SIZEOF(int,                4)
 656 AC_CHECK_SIZEOF(long,               4)
 657 if test "$ac_cv_type_long_long" = yes; then
 658 AC_CHECK_SIZEOF(long long,          8)
 659 fi
 660 AC_CHECK_SIZEOF(short,              2)
 661 AC_CHECK_SIZEOF(unsigned char,      1)
 662 AC_CHECK_SIZEOF(unsigned int,       4)
 663 AC_CHECK_SIZEOF(unsigned long,      4)
 664 if test "$ac_cv_type_long_long" = yes; then
 665 AC_CHECK_SIZEOF(unsigned long long, 8)
 666 fi
 667 AC_CHECK_SIZEOF(unsigned short,     2)
 668 AC_CHECK_SIZEOF(void *,             4)
 669
 670 dnl ** what are alignment constraints on various types
 671 FP_CHECK_ALIGNMENT(char)
 672 FP_CHECK_ALIGNMENT(double)
 673 FP_CHECK_ALIGNMENT(float)
 674 FP_CHECK_ALIGNMENT(int)
 675 FP_CHECK_ALIGNMENT(long)
 676 if test "$ac_cv_type_long_long" = yes; then
 677 FP_CHECK_ALIGNMENT(long long)
 678 fi
 679 FP_CHECK_ALIGNMENT(short)
 680 FP_CHECK_ALIGNMENT(unsigned char)
 681 FP_CHECK_ALIGNMENT(unsigned int)
 682 FP_CHECK_ALIGNMENT(unsigned long)
 683 if test "$ac_cv_type_long_long" = yes; then
 684 FP_CHECK_ALIGNMENT(unsigned long long)
 685 fi
 686 FP_CHECK_ALIGNMENT(unsigned short)
 687 FP_CHECK_ALIGNMENT(void *)
 688
 689 FP_CHECK_FUNC([WinExec],
 690   [@%:@include <windows.h>], [WinExec("",0)])
 691
 692 FP_CHECK_FUNC([GetModuleFileName],
 693   [@%:@include <windows.h>], [GetModuleFileName((HMODULE)0,(LPTSTR)0,0)])
 694
 695 dnl ** check return type of signal handlers
 696 dnl Foo: assumes we can use prototypes.
 697 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 698 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 699 dnl [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 700 dnl #include <signal.h>
 701 dnl #ifdef signal
 702 dnl #undef signal
 703 dnl #endif
 704 dnl void (*signal (int, void (*)(int)))(int);
 705 dnl ]],
 706 dnl [[int i;]])],
 707 dnl [ac_cv_type_signal_handler=void_int],
 708 dnl [ac_cv_type_signal_handler=int_void])])
 709 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 710 dnl AC_DEFINE(VOID_INT_SIGNALS)
 711 dnl fi
 712
 713 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 714 AC_TYPE_SIGNAL
 715 if test "$ac_cv_type_signal" = void; then
 716   AC_DEFINE([VOID_INT_SIGNALS], [1], [Define to 1 if signal handlers have type void (*)(int). Otherwise, they're assumed to have type int (*)(void).])
 717 fi
 718
 719 dnl ** check for more functions
 720 dnl ** The following have been verified to be used in ghc/, but might be used somewhere else, too.
 721 AC_CHECK_FUNCS([getclock getrusage gettimeofday setitimer siginterrupt sysconf times ctime_r sched_setaffinity setlocale])
 722
 723 AC_TRY_RUN([
 724 #include <sys/types.h>
 725 #include <sys/time.h>
 726 int main(void) {
 727   struct itimerval tval;
 728   tval.it_value.tv_sec = 1;
 729   tval.it_value.tv_usec = 0;
 730   tval.it_interval = tval.it_value;
 731   return setitimer(ITIMER_VIRTUAL, &tval, (void*)0) != 0;
 732 }
 733 ],[AC_DEFINE([HAVE_SETITIMER_VIRTUAL], [1], [Define to 1 if setitimer accepts ITIMER_VIRTUAL, 0 else.])])
 734
 735 dnl ** On OS X 10.4 (at least), time.h doesn't declare ctime_r if
 736 dnl ** _POSIX_C_SOURCE is defined
 737 AC_CHECK_DECLS([ctime_r], , ,
 738 [#define _POSIX_SOURCE 1
 739 #define _POSIX_C_SOURCE 199506L
 740 #include <time.h>])
 741
 742 dnl ** check for mingwex library
 743 AC_CHECK_LIB(mingwex, closedir, HaveLibMingwEx=YES, HaveLibMingwEx=NO)
 744 AC_SUBST(HaveLibMingwEx)
 745
 746 if test $HaveLibMingwEx = YES ; then
 747   AC_DEFINE([HAVE_MINGWEX], [1], [Define to 1 if you have the mingwex library.])
 748 fi
 749
 750 dnl ** check for math library
 751 dnl    Keep that check as early as possible.
 752 dnl    as we need to know whether we need libm
 753 dnl    for math functions or not
 754 dnl    (see http://hackage.haskell.org/trac/ghc/ticket/3730)
 755 AC_CHECK_LIB(m, atan, HaveLibM=YES, HaveLibM=NO)
 756 if test $HaveLibM = YES
 757 then
 758   AC_DEFINE([HAVE_LIBM], [1], [Define to 1 if you need to link with libm])
 759 fi
 760
 761 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 762 dnl    the order of these tests matters: bfd needs liberty
 763 AC_CHECK_LIB(iberty, xmalloc)
 764 AC_CHECK_LIB(bfd,    bfd_init)
 765
 766 dnl ################################################################
 767 dnl Check for libraries
 768 dnl ################################################################
 769
 770 dnl ** check whether we need -ldl to get dlopen()
 771
 772 AC_CHECK_LIB(dl, dlopen,
 773     [HaveLibDL=YES
 774      AC_DEFINE([HAVE_LIBDL], [1], [Define to 1 if you need -ldl to get dlopen().])
 775      LIBS="$LIBS -ldl"],
 776     [HaveLibDL=NO])
 777 AC_SUBST(HaveLibDL)
 778
 779 dnl --------------------------------------------------
 780 dnl * Miscellaneous feature tests
 781 dnl --------------------------------------------------
 782
 783 dnl ** can we get alloca?
 784 AC_FUNC_ALLOCA
 785
 786 dnl ** Working vfork?
 787 AC_FUNC_FORK
 788
 789 dnl ** determine whether or not const works
 790 AC_C_CONST
 791
 792 dnl ** are we big endian?
 793 AC_C_BIGENDIAN
 794 FPTOOLS_FLOAT_WORD_ORDER_BIGENDIAN
 795
 796 dnl ** check for leading underscores in symbol names
 797 FP_LEADING_UNDERSCORE
 798
 799 dnl ** check for ld, whether it has an -x option, and if it is GNU ld
 800 FP_PROG_LD_X
 801 FP_PROG_LD_IS_GNU
 802
 803 dnl ** check for Apple-style dead-stripping support
 804 dnl    (.subsections-via-symbols assembler directive)
 805
 806
 807 AC_MSG_CHECKING(for .subsections_via_symbols)
 808 AC_COMPILE_IFELSE(
 809     [AC_LANG_PROGRAM([], [__asm__ (".subsections_via_symbols");])],
 810     [AC_MSG_RESULT(yes)
 811      AC_DEFINE([HAVE_SUBSECTIONS_VIA_SYMBOLS],[1],
 812                [Define to 1 if Apple-style dead-stripping is supported.])
 813     ],
 814     [AC_MSG_RESULT(no)])
 815
 816 dnl *** check for GNU non-executable stack note support (ELF only)
 817 dnl     (.section .note.GNU-stack,"",@progbits)
 818
 819 dnl This test doesn't work with "gcc -g" in gcc 4.4 (GHC trac #3889:
 820 dnl     Error: can't resolve `.note.GNU-stack' {.note.GNU-stack section} - `.Ltext0' {.text section}
 821 dnl so we empty CFLAGS while running this test
 822 CFLAGS2="$CFLAGS"
 823 CFLAGS=
 824 AC_MSG_CHECKING(for GNU non-executable stack support)
 825 AC_COMPILE_IFELSE(
 826     [AC_LANG_PROGRAM([__asm__ (".section .note.GNU-stack,\"\",@progbits");], [0])],
 827     [AC_MSG_RESULT(yes)
 828      AC_DEFINE([HAVE_GNU_NONEXEC_STACK],[1],
 829                [Define to 1 if GNU non-executable stack notes are supported.])
 830     ],
 831     [AC_MSG_RESULT(no)])
 832 CFLAGS="$CFLAGS2"
 833
 834 FP_VISIBILITY_HIDDEN
 835
 836 dnl ** check for librt
 837 AC_CHECK_LIB(rt, clock_gettime)
 838 AC_CHECK_FUNCS(clock_gettime timer_create timer_settime)
 839 FP_CHECK_TIMER_CREATE
 840
 841 dnl ** check for Apple's "interesting" long double compatibility scheme
 842 AC_MSG_CHECKING(for printf\$LDBLStub)
 843 AC_TRY_LINK_FUNC(printf\$LDBLStub,
 844     [
 845         AC_MSG_RESULT(yes)
 846         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[1],
 847             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 848     ],
 849     [
 850         AC_MSG_RESULT(no)
 851         AC_DEFINE([HAVE_PRINTF_LDBLSTUB],[0],
 852             [Define to 1 if we have printf$LDBLStub (Apple Mac OS >= 10.4, PPC).])
 853     ])
 854
 855 dnl ** check for eventfd which is needed by the I/O manager
 856 AC_CHECK_HEADERS([sys/eventfd.h])
 857 AC_CHECK_FUNCS([eventfd])
 858
 859 # test for GTK+
 860 AC_PATH_PROGS([GTK_CONFIG], [pkg-config])
 861 if test -n "$GTK_CONFIG"; then
 862   if $GTK_CONFIG gtk+-2.0 --atleast-version=2.0; then
 863     GTK_CONFIG="$GTK_CONFIG gtk+-2.0"
 864   else
 865     AC_MSG_WARN([GTK+ not usable, need at least version 2.0])
 866     GTK_CONFIG=
 867   fi
 868 fi
 869 AC_SUBST([GTK_CONFIG])
 870
 871 #Checking for PAPI
 872 AC_CHECK_LIB(papi, PAPI_library_init, HavePapiLib=YES, HavePapiLib=NO)
 873 AC_CHECK_HEADER([papi.h], [HavePapiHeader=YES], [HavePapiHeader=NO])
 874 AC_SUBST(HavePapiLib)
 875 AC_SUBST(HavePapiHeader)
 876
 877 AC_CHECK_FUNCS(__mingw_vfprintf)
 878
 879 if test "$HavePapiLib" = "YES" -a "$HavePapiHeader" = "YES"; then
 880    HavePapi=YES
 881 else
 882    HavePapi=NO
 883 fi
 884 AC_SUBST(HavePapi)
 885
 886 if test "$HAVE_DOCBOOK_XSL" = "NO" ||
 887    test "$XsltprocCmd" = ""
 888 then
 889     BUILD_DOCBOOK_HTML=NO
 890 else
 891     BUILD_DOCBOOK_HTML=YES
 892 fi
 893 AC_SUBST(BUILD_DOCBOOK_HTML)
 894
 895 if test "$DblatexCmd" = ""
 896 then
 897     BUILD_DOCBOOK_PS=NO
 898     BUILD_DOCBOOK_PDF=NO
 899 else
 900     BUILD_DOCBOOK_PS=YES
 901     BUILD_DOCBOOK_PDF=YES
 902 fi
 903 AC_SUBST(BUILD_DOCBOOK_PS)
 904 AC_SUBST(BUILD_DOCBOOK_PDF)
 905
 906 LIBRARY_VERSION(base)
 907 LIBRARY_VERSION(Cabal)
 908 LIBRARY_VERSION(ghc-prim)
 909 LIBRARY_ghc_VERSION="$ProjectVersion"
 910 AC_SUBST(LIBRARY_ghc_VERSION)
 911
 912 if grep '       ' compiler/ghc.cabal.in 2>&1 >/dev/null; then
 913    AC_MSG_ERROR([compiler/ghc.cabal.in contains tab characters; please remove them])
 914 fi
 915
 916 AC_CONFIG_FILES([mk/config.mk mk/install.mk mk/project.mk compiler/ghc.cabal ghc/ghc-bin.cabal utils/runghc/runghc.cabal ghc.spec extra-gcc-opts docs/users_guide/ug-book.xml docs/users_guide/ug-ent.xml docs/index.html libraries/prologue.txt distrib/ghc.iss distrib/configure.ac])
 917 AC_CONFIG_COMMANDS([mk/stamp-h],[echo timestamp > mk/stamp-h])
 918 AC_OUTPUT
 919
 920 # We get caught by
 921 #     http://savannah.gnu.org/bugs/index.php?1516
 922 #     $(eval ...) inside conditionals causes errors
 923 # with make 3.80, so warn the user if it looks like they're about to
 924 # try to use it.
 925 # We would use "grep -q" here, but Solaris's grep doesn't support it.
 926 checkMake380() {
 927     if $1 --version 2>&1 | head -1 | grep 'GNU Make 3\.80' > /dev/null
 928     then
 929         echo
 930         echo "WARNING: It looks like \"$1\" is GNU make 3.80."
 931         echo "This version cannot be used to build GHC."
 932         echo "Please use GNU make >= 3.81."
 933     fi
 934 }
 935
 936 checkMake380 make
 937 checkMake380 gmake
 938
 939 echo ["
 940 ----------------------------------------------------------------------
 941 Configure completed successfully.
 942
 943    Building GHC version  : $ProjectVersion
 944
 945    Build platform        : $BuildPlatform
 946    Host platform         : $HostPlatform
 947    Target platform       : $TargetPlatform
 948 "]
 949
 950 if test "$BootingFromHc" = "YES"; then
 951 echo ["\
 952    Bootstrapping from HC files.
 953 "]
 954 else
 955 echo ["\
 956    Bootstrapping using   : $WithGhc
 957       which is version   : $GhcVersion
 958 "]
 959 fi
 960
 961 echo ["\
 962    Using GCC             : $WhatGccIsCalled
 963       which is version   : $GccVersion
 964
 965    ld       : $LdCmd
 966    Happy    : $HappyCmd ($HappyVersion)
 967    Alex     : $AlexCmd ($AlexVersion)
 968    Python   : $PythonCmd
 969    Perl     : $PerlCmd
 970    dblatex  : $DblatexCmd
 971    xsltproc : $XsltprocCmd"]
 972
 973 if test "$HSCOLOUR" = ""; then
 974 echo ["
 975    HsColour was not found; documentation will not contain source links
 976 "]
 977 else
 978 echo ["\
 979    HsColour : $HSCOLOUR
 980 "]
 981 fi
 982
 983 echo ["\
 984    Building DocBook HTML documentation : $BUILD_DOCBOOK_HTML
 985    Building DocBook PS documentation   : $BUILD_DOCBOOK_PS
 986    Building DocBook PDF documentation  : $BUILD_DOCBOOK_PDF"]
 987
 988 echo ["----------------------------------------------------------------------
 989 "]
 990
 991 echo "\
 992 For a standard build of GHC (fully optimised with profiling), type (g)make.
 993
 994 To make changes to the default build configuration, copy the file
 995 mk/build.mk.sample to mk/build.mk, and edit the settings in there.
 996
 997 For more information on how to configure your GHC build, see
 998    http://hackage.haskell.org/trac/ghc/wiki/Building
 999 "