configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha-dec-osf[[34]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         # We assume you're using mingw32 via the gcc that comes
 206         # with cygwin, and not the native port, so let's augment
 207         # the gcc command-line used here with -mno-cygwin to
 208         # arrange for good things to happen.
 209         CFLAGS="-mno-cygwin $CFLAGS"
 210         ;;
 211 m68k-next-nextstep2)
 212         HostPlatform_CPP='m68k_next_nextstep2'
 213         HostArch_CPP='m68k'
 214         HostVendor_CPP='next'
 215         HostOS_CPP='nextstep2'
 216         ;;
 217 m68k-next-nextstep3)
 218         HostPlatform_CPP='m68k_next_nextstep3'
 219         HostArch_CPP='m68k'
 220         HostVendor_CPP='next'
 221         HostOS_CPP='nextstep3'
 222         ;;
 223 i[[3456]]86-next-nextstep3)
 224         HostPlatform=i386-next-nextstep3 # hack again
 225         TargetPlatform=i386-next-nextstep3
 226         BuildPlatform=i386-next-nextstep3
 227         HostPlatform_CPP='i386_next_nextstep3'
 228         HostArch_CPP='i386'
 229         HostVendor_CPP='next'
 230         HostOS_CPP='nextstep3'
 231         ;;
 232 m68k-sun-sunos4*)
 233         HostPlatform=m68k-sun-sunos4
 234         TargetPlatform=m68k-sun-sunos4 #hack
 235         BuildPlatform=m68k-sun-sunos4 #hack
 236         HostPlatform_CPP='m68k_sun_sunos4'
 237         HostArch_CPP='m68k'
 238         HostVendor_CPP='sun'
 239         HostOS_CPP='sunos4'
 240         ;;
 241 mips-dec-ultrix*)
 242         HostPlatform_CPP='mips_dec_ultrix'
 243         HostArch_CPP='mipsel'   # NB a little different
 244         HostVendor_CPP='dec'
 245         HostOS_CPP='ultrix'
 246         ;;
 247 mips-sgi-irix*)
 248         HostPlatform=mips-sgi-irix
 249         TargetPlatform=mips-sgi-irix #hack
 250         BuildPlatform=mips-sgi-irix #hack
 251         HostPlatform_CPP='mips_sgi_irix'
 252         HostArch_CPP='mipseb'   # NB a little different
 253         HostVendor_CPP='sgi'
 254         HostOS_CPP='irix'
 255         ;;
 256 rs6000-ibm-aix*)
 257         HostPlatform=rs6000-ibm-aix
 258         TargetPlatform=rs6000-ibm-aix #hack
 259         BuildPlatform=rs6000-ibm-aix #hack
 260         HostPlatform_CPP='rs6000_ibm_aix'
 261         HostArch_CPP='rs6000'
 262         HostVendor_CPP='ibm'
 263         HostOS_CPP='aix'
 264         ;;
 265 powerpc-ibm-aix*)
 266         HostPlatform=powerpc-ibm-aix
 267         TargetPlatform=powerpc-ibm-aix #hack
 268         BuildPlatform=powerpc-ibm-aix #hack
 269         HostPlatform_CPP='powerpc_ibm_aix'
 270         HostArch_CPP='powerpc'
 271         HostVendor_CPP='ibm'
 272         HostOS_CPP='aix'
 273         ;;
 274 sparc-sun-sunos4*)
 275         HostPlatform=sparc-sun-sunos4
 276         TargetPlatform=sparc-sun-sunos4 #hack
 277         BuildPlatform=sparc-sun-sunos4 #hack
 278         HostPlatform_CPP='sparc_sun_sunos4'
 279         HostArch_CPP='sparc'
 280         HostVendor_CPP='sun'
 281         HostOS_CPP='sunos4'
 282         ;;
 283 sparc-sun-solaris2*)
 284         HostPlatform=sparc-sun-solaris2
 285         TargetPlatform=sparc-sun-solaris2 #hack
 286         BuildPlatform=sparc-sun-solaris2 #hack
 287         HostPlatform_CPP='sparc_sun_solaris2'
 288         HostArch_CPP='sparc'
 289         HostVendor_CPP='sun'
 290         HostOS_CPP='solaris2'
 291         ;;
 292 *)
 293         echo "Unrecognised platform: $HostPlatform"
 294         exit 1
 295         ;;
 296 esac
 297 echo "Canonicalised to: $HostPlatform"
 298 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 299 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 300
 301 BuildPlatform_CPP=$HostPlatform_CPP
 302 TargetPlatform_CPP=$HostPlatform_CPP
 303 BuildArch_CPP=$HostArch_CPP
 304 TargetArch_CPP=$HostArch_CPP
 305 BuildOS_CPP=$HostOS_CPP
 306 HostOS_Full=$host_os
 307 TargetOS_CPP=$HostOS_CPP
 308 BuildVendor_CPP=$HostVendor_CPP
 309 TargetVendor_CPP=$HostVendor_CPP
 310
 311 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 312 dnl AC_SUBST(BuildPlatform)
 313
 314 AC_SUBST(HostPlatform)
 315 AC_SUBST(TargetPlatform)
 316 AC_SUBST(HostPlatform_CPP)
 317 dnl AC_SUBST(BuildPlatform_CPP)
 318 dnl AC_SUBST(TargetPlatform_CPP)
 319
 320 AC_SUBST(HostArch_CPP)
 321 dnl AC_SUBST(BuildArch_CPP)
 322 dnl AC_SUBST(TargetArch_CPP)
 323
 324 AC_SUBST(HostOS_CPP)
 325 AC_SUBST(HostOS_Full)
 326 dnl AC_SUBST(BuildOS_CPP)
 327 dnl AC_SUBST(TargetOS_CPP)
 328
 329 AC_SUBST(HostVendor_CPP)
 330 dnl AC_SUBST(BuildVendor_CPP)
 331 dnl AC_SUBST(TargetVendor_CPP)
 332
 333 AC_SUBST(exeext)
 334
 335 dnl --------------------------------------------------------------
 336 dnl * Project specific configuration options
 337 dnl --------------------------------------------------------------
 338 dnl What follows is a bunch of options that can either be configured
 339 dnl through command line options to the configure script or by
 340 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 341 dnl use either is considered a Feature.
 342
 343 dnl ** What command to use to compile compiler sources ?
 344 dnl --------------------------------------------------------------
 345 if test "$GHC" = ""; then
 346   AC_PATH_PROG(GHC,ghc)
 347 fi
 348
 349 AC_ARG_WITH(hc,
 350 [  --with-hc=<haskell compiler>
 351         Use a command different from 'ghc' to compile generic Haskell code.
 352 ],
 353 [WithHc="$withval"],
 354 [WithHc=$GHC]
 355 )
 356 AC_SUBST(WithHc)
 357
 358 AC_ARG_WITH(ghc,
 359 [  --with-ghc=<haskell compiler>
 360         Use a command different from 'ghc' to compile GHC-specific Haskell code
 361             (including GHC itself).
 362 ],
 363 [WithGhc="$withval"],
 364 [WithGhc=$GHC]
 365 )
 366 AC_SUBST(WithGhc)
 367
 368 if test "$WithGhc" != ""; then
 369   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 370   AC_SUBST(GhcVersion)dnl
 371   AC_SUBST(GhcMajVersion)dnl
 372   AC_SUBST(GhcMinVersion)dnl
 373   AC_SUBST(GhcPatchLevel)dnl
 374 fi
 375
 376 AC_PATH_PROGS(NHC,nhc nhc98)
 377 AC_PATH_PROG(HBC,hbc)
 378
 379 dnl ** Which gcc to use?
 380 dnl --------------------------------------------------------------
 381 AC_ARG_WITH(gcc,
 382 [  --with-gcc=<gcc command>
 383         Use a different command instead of 'gcc' for the GNU C compiler.
 384 ],
 385 [WhatGccIsCalled="$withval"],
 386 [WhatGccIsCalled="gcc"]
 387 )
 388 AC_SUBST(WhatGccIsCalled)
 389
 390 dnl ** Booting from .hc files?
 391 dnl --------------------------------------------------------------
 392 AC_ARG_ENABLE(hc-boot,
 393 [  --enable-hc-boot
 394         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 395         (This option is mostly of interest to porters.)
 396 ],
 397 [BootingFromHc=YES],
 398 [BootingFromHc=NO]
 399 )
 400 AC_SUBST(BootingFromHc)
 401
 402
 403 dnl ** Enable the construction of Win32 DLLs?
 404 dnl --------------------------------------------------------------
 405 AC_ARG_ENABLE(win32-dlls,
 406 [  --enable-win32-dlls
 407         If on a Win32 platform running mingw32/cygwin, enable the
 408         construction of DLLs containing ghc-compiled code.
 409 ],
 410 [
 411 case $HostOS_CPP in
 412 cygwin32) ;;
 413 mingw32)  ;;
 414 *)    echo "Unrecognised win32 platform: $HostPlatform"
 415       exit 1
 416       ;;
 417 esac
 418 EnableWin32DLLs=YES
 419 ],
 420 [EnableWin32DLLs=NO]
 421 )
 422 AC_SUBST(EnableWin32DLLs)
 423 if test x"$EnableWin32DLLs" = "xYES" ; then
 424  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 425 fi
 426
 427 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 428 dnl --------------------------------------------------------------
 429 AC_ARG_ENABLE(hopengl,
 430 [  --enable-hopengl
 431         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 432         (This option is only relevant when hslibs are built.)
 433 ],
 434 [GhcLibsWithHOpenGL=YES],
 435 [GhcLibsWithHOpenGL=NO]
 436 )
 437 AC_SUBST(GhcLibsWithHOpenGL)
 438
 439 dnl ** Use a specific version of the GLUT API
 440 dnl --------------------------------------------------------------
 441 AC_ARG_WITH(glut-api,
 442 [  --with-glut-api=<version>
 443         Use a specific version of the GLUT API when building HOpenGL.
 444 ])
 445 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 446
 447
 448 dnl ** Use a specific version of the GLUT API
 449 dnl --------------------------------------------------------------
 450 AC_ARG_WITH(glut-xlib,
 451 [  --with-glut-xlib=<version>
 452         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 453 ])
 454 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 455
 456
 457 dnl --------------------------------------------------------------
 458 dnl End of configure script option section
 459 dnl --------------------------------------------------------------
 460
 461
 462 dnl --------------------------------------------------------------
 463 dnl * General configuration checks
 464 dnl --------------------------------------------------------------
 465
 466 dnl ** does #! work?
 467 AC_SYS_INTERPRETER()
 468
 469 dnl ** look for `perl', but only in /bin on Windows
 470 case $HostOS_CPP in
 471 cygwin32|mingw32)
 472    AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 473    if test -z "$PerlCmd"; then
 474       echo "You must install the version of Perl shipped with GHC"
 475       echo "(or a compatible one) in /bin."
 476       exit 1
 477    fi
 478    ;;
 479 *)
 480    AC_PATH_PROG(PerlCmd,perl)
 481    if test -z "$PerlCmd"; then
 482       echo "You must install perl before you can continue"
 483       echo "Perhaps it is already installed, but not in your PATH?"
 484       exit 1
 485    else
 486    FPTOOLS_CHECK_PERL_VERSION
 487    fi
 488    ;;
 489 esac
 490
 491 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 492 FPTOOLS_SHEBANG_PERL
 493
 494
 495 dnl ** look for GCC and find out which version
 496 dnl     Figure out which C compiler to use.  Gcc is preferred.
 497 dnl     If gcc, make sure it's at least 2.1
 498 dnl
 499 AC_PROG_CC
 500 FPTOOLS_HAVE_GCC
 501
 502 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 503 AC_PROG_CPP
 504
 505 dnl ** figure out how to do context diffs
 506 FPTOOLS_PROG_DIFF
 507
 508 dnl ** Find find command (for Win32's benefit)
 509 AC_PATH_PROG(FindCmd, find)
 510
 511 dnl ** look for a decent parser generator (bison preferred)
 512 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 513 dnl  on the suitability of the 'yacc' returned.)
 514 FPTOOLS_PROG_YACCY
 515
 516 dnl ** Find lex command (lex or flex) and library (-ll or -lfl)
 517 dnl     ( not that we care about the latter, see mk/config.mk.in )
 518 AC_PROG_LEX
 519
 520
 521 dnl ** figure out how to do a BSD-ish install
 522 AC_PROG_INSTALL
 523
 524 dnl If you can run configure, you certainly have /bin/sh
 525 AC_DEFINE(HAVE_BIN_SH)
 526
 527 dnl ** how to invoke `ar' and `ranlib'
 528 FPTOOLS_PROG_AR_AND_RANLIB
 529
 530
 531 dnl ** Check to see whether ln -s works
 532 AC_PROG_LN_S
 533
 534
 535 dnl ** Find the path to sed
 536 AC_PATH_PROG(SedCmd,sed)
 537
 538
 539 dnl ** check for time command
 540 AC_PATH_PROG(TimeCmd,time)
 541
 542
 543 dnl ** check for tar
 544 dnl   if GNU tar is named gtar, look for it first.
 545 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 546
 547 dnl ** check for gzip/compress
 548 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 549
 550 dnl ** check for jade/openjade & determine a working catalog
 551 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 552 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 553                         /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl $hardtop/glafp-utils/docbook/CATALOG*)
 554 if test -z "$Catalog"; then
 555   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 556 fi
 557 AC_SUBST(Catalog)
 558
 559 compress_nm=`basename $CompressCmd`
 560 if test x"$compress_nm" = xgzip; then
 561   CompressCmd="$CompressCmd -d"
 562   CompressSuffix="gz"
 563 else
 564   CompressSuffix="Z"
 565 fi
 566 AC_SUBST(CompressCmd)
 567 AC_SUBST(CompressSuffix)
 568
 569 dnl ** check for installed happy binary + version
 570 dnl    (don't do it if we're booting from .hc files though.)
 571 if (test "$BootingFromHc" = "NO"); then
 572 FPTOOLS_HAPPY
 573 fi;
 574
 575 dnl --------------------------------------------------
 576 dnl ### program checking section ends here ###
 577 dnl --------------------------------------------------
 578
 579 dnl --------------------------------------------------
 580 dnl * Platform header file and syscall feature tests
 581 dnl ### checking the state of the local header files and syscalls ###
 582
 583 dnl ** check for full ANSI header (.h) files
 584 AC_HEADER_STDC
 585
 586 dnl ** check for specific header (.h) files that we are interested in
 587 AC_CHECK_HEADERS(Files.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 588
 589 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 590 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 591
 592 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 593   HaveReadlineHeaders=YES
 594   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 595 else
 596   HaveReadlineHeaders=NO
 597   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 598 fi
 599 AC_SUBST(HaveReadlineHeaders)
 600
 601 dnl ** check for DOS include files
 602 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 603
 604 dnl ** check for Windows include files
 605 AC_CHECK_HEADERS(windows.h)
 606
 607 dnl ** check for OpenGL include files
 608 AC_CHECK_HEADERS(GL/gl.h)
 609
 610 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 611 AC_HEADER_TIME
 612
 613 dnl dynamic loading include files
 614 AC_CHECK_HEADERS(dlfcn.h dl.h)
 615
 616 dnl ** check for farcalloc (in bcc)
 617 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 618
 619 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 620 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 621
 622 dnl ** how do we get a timezone name, and UTC offset ?
 623 AC_STRUCT_TIMEZONE
 624
 625 dnl ** what's the type of timezone?
 626 FPTOOLS_HAVE_TIMEZONE
 627 FPTOOLS_TYPE_TIMEZONE
 628
 629 dnl ** do we have altzone?
 630 FPTOOLS_ALTZONE
 631
 632 dnl ** does struct stat contain st_blksize?
 633 AC_STRUCT_ST_BLKSIZE
 634
 635 dnl ** do we have long longs?
 636 FPTOOLS_C_LONG_LONG
 637
 638 dnl ** what are the sizes of various types
 639 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 640 AC_CHECK_SIZEOF(char,               1)
 641 AC_CHECK_SIZEOF(double,             8)
 642 AC_CHECK_SIZEOF(float,              4)
 643 AC_CHECK_SIZEOF(int,                4)
 644 AC_CHECK_SIZEOF(long,               4)
 645 if test "$fptools_cv_have_long_long" = yes; then
 646 AC_CHECK_SIZEOF(long long,          8)
 647 fi
 648 AC_CHECK_SIZEOF(short,              2)
 649 AC_CHECK_SIZEOF(unsigned char,      1)
 650 AC_CHECK_SIZEOF(unsigned int,       4)
 651 AC_CHECK_SIZEOF(unsigned long,      4)
 652 if test "$fptools_cv_have_long_long" = yes; then
 653 AC_CHECK_SIZEOF(unsigned long long, 8)
 654 fi
 655 AC_CHECK_SIZEOF(unsigned short,     2)
 656 AC_CHECK_SIZEOF(void *,             4)
 657
 658 dnl ** what are alignment constraints on various types
 659 FPTOOLS_CHECK_ALIGNMENT(char)
 660 FPTOOLS_CHECK_ALIGNMENT(double)
 661 FPTOOLS_CHECK_ALIGNMENT(float)
 662 FPTOOLS_CHECK_ALIGNMENT(int)
 663 FPTOOLS_CHECK_ALIGNMENT(long)
 664 if test "$fptools_cv_have_long_long" = yes; then
 665 FPTOOLS_CHECK_ALIGNMENT(long long)
 666 fi
 667 FPTOOLS_CHECK_ALIGNMENT(short)
 668 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 669 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 670 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 671 if test "$fptools_cv_have_long_long" = yes; then
 672 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 673 fi
 674 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 675 FPTOOLS_CHECK_ALIGNMENT(void *)
 676
 677 dnl ** map standard C types and ISO types to Haskell types
 678 FPTOOLS_CHECK_HTYPE(char)
 679 FPTOOLS_CHECK_HTYPE(signed char)
 680 FPTOOLS_CHECK_HTYPE(unsigned char)
 681 FPTOOLS_CHECK_HTYPE(short)
 682 FPTOOLS_CHECK_HTYPE(unsigned short)
 683 FPTOOLS_CHECK_HTYPE(int)
 684 FPTOOLS_CHECK_HTYPE(unsigned int)
 685 FPTOOLS_CHECK_HTYPE(long)
 686 FPTOOLS_CHECK_HTYPE(unsigned long)
 687 if test "$fptools_cv_have_long_long" = yes; then
 688 FPTOOLS_CHECK_HTYPE(long long)
 689 FPTOOLS_CHECK_HTYPE(unsigned long long)
 690 fi
 691 FPTOOLS_CHECK_HTYPE(float)
 692 FPTOOLS_CHECK_HTYPE(double)
 693 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 694 FPTOOLS_CHECK_HTYPE(size_t)
 695 FPTOOLS_CHECK_HTYPE(wchar_t)
 696 dnl Int32 is a HACK for non-ISO C compilers
 697 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 698 FPTOOLS_CHECK_HTYPE(clock_t)
 699 FPTOOLS_CHECK_HTYPE(time_t)
 700
 701 dnl ** Map OpenGL data types to Haskell types
 702 if test $GhcLibsWithHOpenGL = YES ; then
 703 FPTOOLS_CHECK_HTYPE(GLboolean)
 704 FPTOOLS_CHECK_HTYPE(GLbyte)
 705 FPTOOLS_CHECK_HTYPE(GLubyte)
 706 FPTOOLS_CHECK_HTYPE(GLshort)
 707 FPTOOLS_CHECK_HTYPE(GLushort)
 708 FPTOOLS_CHECK_HTYPE(GLint)
 709 FPTOOLS_CHECK_HTYPE(GLuint)
 710 FPTOOLS_CHECK_HTYPE(GLsizei)
 711 FPTOOLS_CHECK_HTYPE(GLenum)
 712 FPTOOLS_CHECK_HTYPE(GLbitfield)
 713 FPTOOLS_CHECK_HTYPE(GLfloat)
 714 FPTOOLS_CHECK_HTYPE(GLclampf)
 715 FPTOOLS_CHECK_HTYPE(GLdouble)
 716 FPTOOLS_CHECK_HTYPE(GLclampd)
 717 fi
 718
 719 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 720
 721 dnl ** can we open files in binary mode?
 722 FPTOOLS_O_BINARY
 723
 724 dnl ** check for GetModuleFileName and WinExec (windows only)
 725 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 726 dnl Doesn't work because the linker can't see the functions if
 727 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 728
 729 FPTOOLS_TRY_LINK_NOWARN(,[
 730 #if HAVE_WINDOWS_H
 731 #include <windows.h>
 732 #endif
 733 main() {
 734   WinExec("",0);
 735   exit(0);
 736 }
 737 ],
 738 [have_winexec=1],
 739 [have_winexec=0])
 740 if test "$have_winexec" = "1"; then
 741 AC_DEFINE(HAVE_WINEXEC)
 742 fi
 743
 744 FPTOOLS_TRY_LINK_NOWARN(,[
 745 #if HAVE_WINDOWS_H
 746 #include <windows.h>
 747 #endif
 748 main() {
 749   char* dir;
 750   GetModuleFileName((HMODULE)0,dir,0);
 751   exit(0);
 752 }
 753 ],
 754 [have_getmodulefilename=1],
 755 [have_getmodulefilename=0])
 756 if test "$have_getmodulefilename" = "1"; then
 757 AC_DEFINE(HAVE_GETMODULEFILENAME)
 758 fi
 759
 760 dnl ** check return type of signal handlers
 761 dnl Foo: assumes we can use prototypes.
 762 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 763 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 764 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 765 dnl #include <signal.h>
 766 dnl #ifdef signal
 767 dnl #undef signal
 768 dnl #endif
 769 dnl void (*signal (int, void (*)(int)))(int);
 770 dnl ],
 771 dnl [int i;],
 772 dnl ac_cv_type_signal_handler=void_int,
 773 dnl ac_cv_type_signal_handler=int_void)])
 774 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 775 dnl AC_DEFINE(VOID_INT_SIGNALS)
 776 dnl fi
 777
 778 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 779 AC_TYPE_SIGNAL
 780 if test "$ac_cv_type_signal" = void; then
 781 AC_DEFINE(VOID_INT_SIGNALS)
 782 fi
 783
 784 dnl ** check for more functions
 785 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 786 AC_CHECK_FUNCS(strcmp)
 787 AC_CHECK_FUNCS(realpath _fullpath)
 788 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 789 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 790 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 791 AC_CHECK_FUNCS(snprintf  _snprintf )
 792 AC_CHECK_FUNCS(popen     _popen )
 793 AC_CHECK_FUNCS(pclose    _pclose )
 794
 795
 796 dnl ** check for specific library functions that we are interested in
 797 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat symlink sysconf timelocal times vadvise vfork)
 798
 799 dnl ** check whether this machine has gmp3 installed
 800 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 801   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 802     HaveLibGmp=No; LibGmp=not-installed))
 803 AC_SUBST(HaveLibGmp)
 804 AC_SUBST(LibGmp)
 805
 806 dnl ** check whether this machine has GNU regex in libc.
 807 FPTOOLS_REGEX_IN_LIBC
 808
 809 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 810 dnl    the order of these tests matters: bfd needs liberty
 811 AC_CHECK_LIB(iberty, xmalloc)
 812 AC_CHECK_LIB(bfd,    bfd_init)
 813
 814 dnl ** check for readline, for Hugs and hslibs' Readline
 815 dnl ncurses supersedes termcap and curses, but for compatibility,
 816 dnl we have to check for all...
 817 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 818   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 819     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 820       HaveLibTermcap=NO; LibTermcap=not-installed)))
 821
 822 if test $HaveLibTermcap = YES ; then
 823   LIBS="-l$LibTermcap $LIBS"
 824   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 825 fi
 826
 827 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 828   AC_DEFINE(HAVE_READLINE_LIBS,1)
 829   LibsReadline="-lreadline -l$LibTermcap"
 830 else
 831   AC_DEFINE(HAVE_READLINE_LIBS,0)
 832   LibsReadline=
 833 fi
 834 AC_SUBST(LibsReadline)
 835
 836 dnl ################################################################
 837 dnl Check for libraries
 838 dnl ################################################################
 839
 840 FPTOOLS_CHECK_LIB_NOWARN(dl, dlopen)
 841 FPTOOLS_CHECK_LIB_NOWARN(dld, shl_load)
 842 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 843
 844 dnl --------------------------------------------------
 845 dnl * test for GTK+
 846 dnl --------------------------------------------------
 847
 848 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 849 if test "$GTK_CONFIG" != ""; then
 850    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 851         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 852     ])
 853     GTK_VERSION=$fptools_cv_gtk_version
 854 else
 855     GTK_VERSION=
 856 fi
 857
 858 case $fptools_cv_gtk_version in
 859   1.[[23]].*) ;;
 860   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 861      GTK_CONFIG=
 862      ;;
 863 esac
 864
 865 AC_SUBST(GTK_CONFIG)
 866 AC_SUBST(GTK_VERSION)
 867
 868 dnl --------------------------------------------------
 869 dnl * Miscellaneous feature tests
 870 dnl --------------------------------------------------
 871
 872 dnl ** can we get alloca?
 873 AC_FUNC_ALLOCA
 874
 875 dnl ** determine whether or not const works
 876 AC_C_CONST
 877
 878 dnl ** determine whether ANSI-function prototypes work?
 879 AC_C_PROTOTYPES
 880
 881 dnl ** are we big endian?
 882 AC_C_BIGENDIAN
 883 # Allay users' general fear of warnings of any kind.
 884 errprint((fptools configure script wizard sez: "don't worry, the above warning is harmless (to us.)")
 885 )
 886
 887 dnl ** check for leading underscores in symbol names
 888 FPTOOLS_UNDERSCORE
 889
 890 dnl ** how is the end of text section signalled?
 891 FPTOOLS_END_TEXT_SECTION
 892
 893 dnl ** how is the end of data section signalled?
 894 FPTOOLS_END_DATA_SECTION
 895
 896 dnl ** code before data?
 897 FPTOOLS_CODE_BEFORE_DATA
 898
 899 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )
 900
 901 echo ''
 902 echo '************************************************'
 903 echo '*** NOW DO: gmake boot followed by gmake all'
 904 echo '***         (where gmake == GNU make)'
 905 echo '************************************************'
 906 exit 0