configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 # -------------------------------------------------------------------------
  20 # Prepare to generate the following header files
  21 #
  22 #
  23 AC_CONFIG_HEADER(mk/config.h)
  24
  25 # No, semi-sadly, we don't do `--srcdir'...
  26 if test x"$srcdir" != 'x.' ; then
  27     echo "This configuration does not support the \`--srcdir' option.."
  28     exit 1
  29 fi
  30
  31 #
  32 # Remove common automounter nonsense + convert from UNC to DOS style paths
  33 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  34 #
  35 hardtop=`pwd`
  36 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  37
  38 echo ''
  39 echo "*** The top of your build tree is: $hardtop"
  40 AC_SUBST(hardtop)
  41
  42 dnl--------------------------------------------------------------------
  43 dnl * Choose host(/target/build) platform
  44 dnl--------------------------------------------------------------------
  45
  46 dnl Guess host/target/build platform(s) if necessary.
  47 AC_CANONICAL_SYSTEM
  48
  49 # "$host" defaults to "$target"
  50 if test "x$host" = xNONE ; then
  51     host=$target
  52 fi
  53
  54 dnl ** canonicalize platform names
  55 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  56 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  57 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  58
  59 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  60     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  61     exit 1
  62 fi
  63
  64 exeext=''
  65 #
  66 # The following will be more difficult when we *are* cross-compiling.
  67 # Suitable names to slam in *_CPP are in platform.h.in.
  68 # We also record the architecture, vendor, and operating system (OS)
  69 # separately.
  70 case $HostPlatform in
  71 alpha-dec-osf[[12]]*)
  72         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  73         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  74         BuildPlatform=alpha-dec-osf1  # hack
  75         HostPlatform_CPP='alpha_dec_osf1'
  76         HostArch_CPP='alpha'
  77         HostVendor_CPP='dec'
  78         HostOS_CPP='osf1'
  79         ;;
  80 alpha-dec-osf[[34]]*)
  81         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  82         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  83         BuildPlatform=alpha-dec-osf3  # hack
  84         HostPlatform_CPP='alpha_dec_osf3'
  85         HostArch_CPP='alpha'
  86         HostVendor_CPP='dec'
  87         HostOS_CPP='osf3'
  88         ;;
  89 hppa1.1-hp-hpux*)
  90         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
  91         TargetPlatform=hppa1.1-hp-hpux
  92         BuildPlatform=hppa1.1-hp-hpux
  93         HostPlatform_CPP='hppa1_1_hp_hpux'
  94         HostArch_CPP='hppa1_1'
  95         HostVendor_CPP='hp'
  96         HostOS_CPP='hpux'
  97         ;;
  98 i[[3456]]86-*-linuxaout*)
  99         HostPlatform=i386-unknown-linuxaout   # hack again
 100         TargetPlatform=i386-unknown-linuxaout
 101         BuildPlatform=i386-unknown-linuxaout
 102         HostPlatform_CPP='i386_unknown_linuxaout'
 103         HostArch_CPP='i386'
 104         HostVendor_CPP='unknown'
 105         HostOS_CPP='linuxaout'
 106         ;;
 107 i[[3456]]86-*-linux*)
 108         HostPlatform=i386-unknown-linux # hack again
 109         TargetPlatform=i386-unknown-linux
 110         BuildPlatform=i386-unknown-linux
 111         HostPlatform_CPP='i386_unknown_linux'
 112         HostArch_CPP='i386'
 113         HostVendor_CPP='unknown'
 114         HostOS_CPP='linux'
 115         ;;
 116 i[[3456]]86-*-freebsd3*) # FreeBSD 3.0+ uses ELF
 117         HostPlatform=i386-unknown-freebsd3 # hack again
 118         TargetPlatform=i386-unknown-freebsd3
 119         BuildPlatform=i386-unknown-freebsd3
 120         HostPlatform_CPP='i386_unknown_freebsd3'
 121         HostArch_CPP='i386'
 122         HostVendor_CPP='unknown'
 123         HostOS_CPP='freebsd3'
 124         ;;
 125 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 126         HostPlatform=i386-unknown-freebsd2 # hack again
 127         TargetPlatform=i386-unknown-freebsd2
 128         BuildPlatform=i386-unknown-freebsd2
 129         HostPlatform_CPP='i386_unknown_freebsd2'
 130         HostArch_CPP='i386'
 131         HostVendor_CPP='unknown'
 132         HostOS_CPP='freebsd2'
 133         ;;
 134 i[[3456]]86-*-netbsd*)
 135         HostPlatform=i386-unknown-netbsd # hack again
 136         TargetPlatform=i386-unknown-netbsd
 137         BuildPlatform=i386-unknown-netbsd
 138         HostPlatform_CPP='i386_unknown_netbsd'
 139         HostArch_CPP='i386'
 140         HostVendor_CPP='unknown'
 141         HostOS_CPP='netbsd'
 142         ;;
 143 i[[3456]]86-*-solaris2*)
 144         HostPlatform=i386-unknown-solaris2 # hack again
 145         TargetPlatform=i386-unknown-solaris2
 146         BuildPlatform=i386-unknown-solaris2
 147         HostPlatform_CPP='i386_unknown_solaris2'
 148         HostArch_CPP='i386'
 149         HostVendor_CPP='unknown'
 150         HostOS_CPP='solaris2'
 151         ;;
 152 i[[3456]]86-*-cygwin32*)
 153         HostPlatform=i386-unknown-cygwin32 # hack again
 154         TargetPlatform=i386-unknown-cygwin32
 155         BuildPlatform=i386-unknown-cygwin32
 156         HostPlatform_CPP='i386_unknown_cygwin32'
 157         HostArch_CPP='i386'
 158         HostVendor_CPP='unknown'
 159         HostOS_CPP='cygwin32'
 160         exeext='.exe'
 161         ;;
 162 m68k-next-nextstep2)
 163         HostPlatform_CPP='m68k_next_nextstep2'
 164         HostArch_CPP='m68k'
 165         HostVendor_CPP='next'
 166         HostOS_CPP='nextstep2'
 167         ;;
 168 m68k-next-nextstep3)
 169         HostPlatform_CPP='m68k_next_nextstep3'
 170         HostArch_CPP='m68k'
 171         HostVendor_CPP='next'
 172         HostOS_CPP='nextstep3'
 173         ;;
 174 i[[3456]]86-next-nextstep3)
 175         HostPlatform=i386-next-nextstep3 # hack again
 176         TargetPlatform=i386-next-nextstep3
 177         BuildPlatform=i386-next-nextstep3
 178         HostPlatform_CPP='i386_next_nextstep3'
 179         HostArch_CPP='i386'
 180         HostVendor_CPP='next'
 181         HostOS_CPP='nextstep3'
 182         ;;
 183 m68k-sun-sunos4*)
 184         HostPlatform=m68k-sun-sunos4
 185         TargetPlatform=m68k-sun-sunos4 #hack
 186         BuildPlatform=m68k-sun-sunos4 #hack
 187         HostPlatform_CPP='m68k_sun_sunos4'
 188         HostArch_CPP='m68k'
 189         HostVendor_CPP='sun'
 190         HostOS_CPP='sunos4'
 191         ;;
 192 mips-dec-ultrix*)
 193         HostPlatform_CPP='mips_dec_ultrix'
 194         HostArch_CPP='mipsel'   # NB a little different
 195         HostVendor_CPP='dec'
 196         HostOS_CPP='ultrix'
 197         ;;
 198 mips-sgi-irix*)
 199         HostPlatform=mips-sgi-irix
 200         TargetPlatform=mips-sgi-irix #hack
 201         BuildPlatform=mips-sgi-irix #hack
 202         HostPlatform_CPP='mips_sgi_irix'
 203         HostArch_CPP='mipseb'   # NB a little different
 204         HostVendor_CPP='sgi'
 205         HostOS_CPP='irix'
 206         ;;
 207 rs6000-ibm-aix*)
 208         HostPlatform=rs6000-ibm-aix
 209         TargetPlatform=rs6000-ibm-aix #hack
 210         BuildPlatform=rs6000-ibm-aix #hack
 211         HostPlatform_CPP='rs6000_ibm_aix'
 212         HostArch_CPP='rs6000'
 213         HostVendor_CPP='ibm'
 214         HostOS_CPP='aix'
 215         ;;
 216 powerpc-ibm-aix*)
 217         HostPlatform=powerpc-ibm-aix
 218         TargetPlatform=powerpc-ibm-aix #hack
 219         BuildPlatform=powerpc-ibm-aix #hack
 220         HostPlatform_CPP='powerpc_ibm_aix'
 221         HostArch_CPP='powerpc'
 222         HostVendor_CPP='ibm'
 223         HostOS_CPP='aix'
 224         ;;
 225 sparc-sun-sunos4*)
 226         HostPlatform=sparc-sun-sunos4
 227         TargetPlatform=sparc-sun-sunos4 #hack
 228         BuildPlatform=sparc-sun-sunos4 #hack
 229         HostPlatform_CPP='sparc_sun_sunos4'
 230         HostArch_CPP='sparc'
 231         HostVendor_CPP='sun'
 232         HostOS_CPP='sunos4'
 233         ;;
 234 sparc-sun-solaris2*)
 235         HostPlatform=sparc-sun-solaris2
 236         TargetPlatform=sparc-sun-solaris2 #hack
 237         BuildPlatform=sparc-sun-solaris2 #hack
 238         HostPlatform_CPP='sparc_sun_solaris2'
 239         HostArch_CPP='sparc'
 240         HostVendor_CPP='sun'
 241         HostOS_CPP='solaris2'
 242         ;;
 243 *)
 244         echo "Unrecognised platform: $HostPlatform"
 245         exit 1
 246         ;;
 247 esac
 248 echo "Canonicalised to: $HostPlatform"
 249 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 250 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 251
 252 BuildPlatform_CPP=$HostPlatform_CPP
 253 TargetPlatform_CPP=$HostPlatform_CPP
 254 BuildArch_CPP=$HostArch_CPP
 255 TargetArch_CPP=$HostArch_CPP
 256 BuildOS_CPP=$HostOS_CPP
 257 HostOS_Full=$host_os
 258 TargetOS_CPP=$HostOS_CPP
 259 BuildVendor_CPP=$HostVendor_CPP
 260 TargetVendor_CPP=$HostVendor_CPP
 261
 262 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 263 dnl AC_SUBST(BuildPlatform)
 264
 265 AC_SUBST(HostPlatform)
 266 AC_SUBST(TargetPlatform)
 267 AC_SUBST(HostPlatform_CPP)
 268 dnl AC_SUBST(BuildPlatform_CPP)
 269 dnl AC_SUBST(TargetPlatform_CPP)
 270
 271 AC_SUBST(HostArch_CPP)
 272 dnl AC_SUBST(BuildArch_CPP)
 273 dnl AC_SUBST(TargetArch_CPP)
 274
 275 AC_SUBST(HostOS_CPP)
 276 AC_SUBST(HostOS_Full)
 277 dnl AC_SUBST(BuildOS_CPP)
 278 dnl AC_SUBST(TargetOS_CPP)
 279
 280 AC_SUBST(HostVendor_CPP)
 281 dnl AC_SUBST(BuildVendor_CPP)
 282 dnl AC_SUBST(TargetVendor_CPP)
 283
 284 AC_SUBST(exeext)
 285
 286 dnl --------------------------------------------------------------
 287 dnl * Project specific configuration options
 288 dnl --------------------------------------------------------------
 289 dnl What follows is a bunch of options that can either be configured
 290 dnl through command line options to the configure script or by
 291 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 292 dnl use either is considered a Feature.
 293
 294 dnl ** What command to use to compile compiler sources ?
 295 dnl --------------------------------------------------------------
 296 AC_ARG_WITH(ghc-hc,
 297 [  --with-ghc-hc=<haskell compiler>
 298         Use a command different from 'ghc-2.10' to compile up the GHC compiler sources.
 299          (no claims currently made that this will work with a compiler other than a
 300           recent version of GHC, but you could always try...)
 301 ],
 302 [WithGhcHc="$withval"],
 303 [WithGhcHc="ghc"]
 304 )
 305 AC_SUBST(WithGhcHc)
 306
 307 dnl ** Which gcc to use?
 308 dnl --------------------------------------------------------------
 309 AC_ARG_WITH(gcc,
 310 [  --with-gcc=<gcc command>
 311         Use a different command instead of 'gcc' for the GNU C compiler.
 312 ],
 313 [WhatGccIsCalled="$withval"],
 314 [WhatGccIsCalled="gcc"]
 315 )
 316 AC_SUBST(WhatGccIsCalled)
 317
 318 dnl ** Booting from .hc files?
 319 dnl --------------------------------------------------------------
 320 AC_ARG_ENABLE(hc-boot,
 321 [  --enable-hc-boot
 322         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 323         (This option is mostly of interest to porters.)
 324 ],
 325 [BootingFromHc=YES],
 326 [BootingFromHc=NO]
 327 )
 328 AC_SUBST(BootingFromHc)
 329
 330
 331 dnl --------------------------------------------------------------
 332 dnl End of configure script option section
 333 dnl --------------------------------------------------------------
 334
 335
 336 dnl --------------------------------------------------------------
 337 dnl * General configuration checks
 338 dnl --------------------------------------------------------------
 339
 340 dnl ** does #! work?
 341 AC_SYS_INTERPRETER()
 342
 343 dnl ** look for `perl', but watch out for version 4.035
 344 AC_PATH_PROG(PerlCmd,perl)
 345 if test -z "$PerlCmd"; then
 346    echo "You must install perl before you can continue"
 347    echo "Perhaps it is already installed, but not in your PATH?"
 348    exit 1
 349 else
 350 FPTOOLS_CHECK_PERL_VERSION
 351 fi
 352
 353 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 354 FPTOOLS_SHEBANG_PERL
 355
 356
 357 dnl ** look for GCC and find out which version
 358 dnl     Figure out which C compiler to use.  Gcc is preferred.
 359 dnl     If gcc, make sure it's at least 2.1
 360 dnl
 361 AC_PROG_CC
 362 FPTOOLS_HAVE_GCC
 363
 364 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 365 AC_PROG_CPP
 366 FPTOOLS_PROG_GNUCPP
 367
 368 dnl ** figure out how to do context diffs
 369 FPTOOLS_PROG_DIFF
 370
 371
 372 dnl ** look for a decent parser generator (bison preferred)
 373 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 374 dnl  on the suitability of the 'yacc' returned.)
 375 FPTOOLS_PROG_YACCY
 376
 377 dnl ** Find lex command (lex or flex) and library (-ll or -lfl)
 378 dnl     ( not that we care about the latter, see mk/config.mk.in )
 379 AC_PROG_LEX
 380
 381
 382 dnl ** figure out how to do a BSD-ish install
 383 AC_PROG_INSTALL
 384
 385 dnl ** how to invoke `ar' and `ranlib'
 386 FPTOOLS_PROG_AR_AND_RANLIB
 387
 388
 389 dnl ** Check to see whether ln -s works
 390 AC_PROG_LN_S
 391
 392
 393 dnl ** Find the path to sed
 394 AC_PATH_PROG(SedCmd,sed)
 395
 396
 397 dnl ** check for time command
 398 AC_PATH_PROG(TimeCmd,time)
 399
 400
 401 dnl ** check for tar
 402 dnl   if GNU tar is named gtar, look for it first.
 403 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 404
 405 dnl ** check for gzip/compress
 406 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 407
 408 compress_nm=`basename $CompressCmd`
 409 if test x"$compress_nm" = xgzip; then
 410   CompressCmd="$CompressCmd -d"
 411   CompressSuffix="gz"
 412 else
 413   CompressSuffix="Z"
 414 fi
 415 AC_SUBST(CompressCmd)
 416 AC_SUBST(CompressSuffix)
 417
 418 dnl ** check for installed happy binary + version
 419 dnl    (don't do it if we're booting from .hc files though.)
 420 if (test "$BootingFromHc" = "NO"); then
 421 FPTOOLS_HAPPY
 422 fi;
 423
 424 dnl --------------------------------------------------
 425 dnl ### program checking section ends here ###
 426 dnl --------------------------------------------------
 427
 428 dnl --------------------------------------------------
 429 dnl * Platform header file and syscall feature tests
 430 dnl ### checking the state of the local header files and syscalls ###
 431
 432 dnl ** check for full ANSI header (.h) files
 433 AC_HEADER_STDC
 434
 435 dnl ** check for specific header (.h) files that we are interested in
 436 AC_CHECK_HEADERS(dirent.h fcntl.h grp.h malloc.h memory.h nlist.h pwd.h siginfo.h signal.h stdlib.h string.h sys/fault.h sys/file.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/utsname.h sys/vadvise.h sys/wait.h termios.h time.h types.h unistd.h utime.h vfork.h readline/readline.h bfd.h)
 437
 438 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 439 AC_HEADER_TIME
 440
 441 dnl ** how do we get a timezone name, and UTC offset ?
 442 AC_STRUCT_TIMEZONE
 443
 444 dnl ** what's the type of timezone?
 445 FPTOOLS_TYPE_TIMEZONE
 446
 447 dnl ** do we have altzone?
 448 FPTOOLS_ALTZONE
 449
 450 dnl ** does struct stat contain st_blksize?
 451 AC_STRUCT_ST_BLKSIZE
 452
 453 dnl ** what are the sizes of various types
 454 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 455 AC_CHECK_SIZEOF(unsigned int,4)
 456 AC_CHECK_SIZEOF(float,       4)
 457 AC_CHECK_SIZEOF(double,      8)
 458 AC_CHECK_SIZEOF(long,        4)
 459 AC_CHECK_SIZEOF(void *,      4)
 460
 461 dnl ** what are alignment constraints on various types
 462 FPTOOLS_CHECK_ALIGNMENT(unsigned int) dnl redundant but harmless
 463 FPTOOLS_CHECK_ALIGNMENT(long)
 464 FPTOOLS_CHECK_ALIGNMENT(float)
 465 FPTOOLS_CHECK_ALIGNMENT(double)
 466
 467 dnl ** do we have long longs?
 468 FPTOOLS_C_LONG_LONG
 469
 470 dnl ** can we open files in binary mode?
 471 FPTOOLS_O_BINARY
 472
 473 dnl ** check for specific library functions that we are interested in
 474 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect setitimer stat sysconf timelocal times vadvise vfork)
 475
 476 dnl ** check whether this machine has gmp2 installed
 477 AC_CHECK_LIB(gmp,  mpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 478   AC_CHECK_LIB(gmp2, mpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp2,
 479     HaveLibGmp=No; LibGmp=not-installed))
 480 AC_SUBST(HaveLibGmp)
 481 AC_SUBST(LibGmp)
 482
 483 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 484 dnl    the order of these tests matters: bfd needs liberty
 485 AC_CHECK_LIB(iberty, xmalloc)
 486 AC_CHECK_LIB(bfd,    bfd_init)
 487
 488
 489 dnl --------------------------------------------------
 490 dnl * Miscellaneous feature tests
 491 dnl --------------------------------------------------
 492
 493 dnl ** can we get alloca?
 494 AC_FUNC_ALLOCA
 495
 496 dnl ** determine whether or not const works
 497 AC_C_CONST
 498
 499 dnl ** are we big endian?
 500 AC_C_BIGENDIAN
 501
 502 dnl ** determine the return type of signal()
 503 AC_TYPE_SIGNAL
 504
 505 dnl ** check for leading underscores in symbol names
 506 FPTOOLS_UNDERSCORE
 507
 508 dnl ** how is the end of text section signalled?
 509 FPTOOLS_END_TEXT_SECTION
 510
 511 dnl ** how is the end of data section signalled?
 512 FPTOOLS_END_DATA_SECTION
 513
 514 dnl ** code before data?
 515 FPTOOLS_CODE_BEFORE_DATA
 516
 517 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )
 518
 519 echo ''
 520 echo '************************************************'
 521 echo '*** NOW DO: gmake boot followed by gmake all'
 522 echo '***         (where gmake == GNU make)'
 523 echo '************************************************'
 524 exit 0