configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha*-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha*-dec-osf[[345]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha*-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha*-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         ;;
 206 m68k-next-nextstep2)
 207         HostPlatform_CPP='m68k_next_nextstep2'
 208         HostArch_CPP='m68k'
 209         HostVendor_CPP='next'
 210         HostOS_CPP='nextstep2'
 211         ;;
 212 m68k-next-nextstep3)
 213         HostPlatform_CPP='m68k_next_nextstep3'
 214         HostArch_CPP='m68k'
 215         HostVendor_CPP='next'
 216         HostOS_CPP='nextstep3'
 217         ;;
 218 i[[3456]]86-next-nextstep3)
 219         HostPlatform=i386-next-nextstep3 # hack again
 220         TargetPlatform=i386-next-nextstep3
 221         BuildPlatform=i386-next-nextstep3
 222         HostPlatform_CPP='i386_next_nextstep3'
 223         HostArch_CPP='i386'
 224         HostVendor_CPP='next'
 225         HostOS_CPP='nextstep3'
 226         ;;
 227 m68k-sun-sunos4*)
 228         HostPlatform=m68k-sun-sunos4
 229         TargetPlatform=m68k-sun-sunos4 #hack
 230         BuildPlatform=m68k-sun-sunos4 #hack
 231         HostPlatform_CPP='m68k_sun_sunos4'
 232         HostArch_CPP='m68k'
 233         HostVendor_CPP='sun'
 234         HostOS_CPP='sunos4'
 235         ;;
 236 mips-dec-ultrix*)
 237         HostPlatform_CPP='mips_dec_ultrix'
 238         HostArch_CPP='mipsel'   # NB a little different
 239         HostVendor_CPP='dec'
 240         HostOS_CPP='ultrix'
 241         ;;
 242 mips-sgi-irix*)
 243         HostPlatform=mips-sgi-irix
 244         TargetPlatform=mips-sgi-irix #hack
 245         BuildPlatform=mips-sgi-irix #hack
 246         HostPlatform_CPP='mips_sgi_irix'
 247         HostArch_CPP='mipseb'   # NB a little different
 248         HostVendor_CPP='sgi'
 249         HostOS_CPP='irix'
 250         ;;
 251 rs6000-ibm-aix*)
 252         HostPlatform=rs6000-ibm-aix
 253         TargetPlatform=rs6000-ibm-aix #hack
 254         BuildPlatform=rs6000-ibm-aix #hack
 255         HostPlatform_CPP='rs6000_ibm_aix'
 256         HostArch_CPP='rs6000'
 257         HostVendor_CPP='ibm'
 258         HostOS_CPP='aix'
 259         ;;
 260 powerpc-ibm-aix*)
 261         HostPlatform=powerpc-ibm-aix
 262         TargetPlatform=powerpc-ibm-aix #hack
 263         BuildPlatform=powerpc-ibm-aix #hack
 264         HostPlatform_CPP='powerpc_ibm_aix'
 265         HostArch_CPP='powerpc'
 266         HostVendor_CPP='ibm'
 267         HostOS_CPP='aix'
 268         ;;
 269 powerpc-apple-macosx*)
 270       HostPlatform=powerpc-apple-macosx
 271       TargetPlatform=powerpc-apple-macosx #hack
 272       BuildPlatform=powerpc-apple-macosx #hack
 273         HostPlatform_CPP='powerpc_apple_macosx'
 274         HostArch_CPP='powerpc'
 275         HostVendor_CPP='apple'
 276         HostOS_CPP='macosx'
 277         ;;
 278 sparc-sun-sunos4*)
 279         HostPlatform=sparc-sun-sunos4
 280         TargetPlatform=sparc-sun-sunos4 #hack
 281         BuildPlatform=sparc-sun-sunos4 #hack
 282         HostPlatform_CPP='sparc_sun_sunos4'
 283         HostArch_CPP='sparc'
 284         HostVendor_CPP='sun'
 285         HostOS_CPP='sunos4'
 286         ;;
 287 sparc-sun-solaris2*)
 288         HostPlatform=sparc-sun-solaris2
 289         TargetPlatform=sparc-sun-solaris2 #hack
 290         BuildPlatform=sparc-sun-solaris2 #hack
 291         HostPlatform_CPP='sparc_sun_solaris2'
 292         HostArch_CPP='sparc'
 293         HostVendor_CPP='sun'
 294         HostOS_CPP='solaris2'
 295         ;;
 296 *)
 297         echo "Unrecognised platform: $HostPlatform"
 298         exit 1
 299         ;;
 300 esac
 301 echo "Canonicalised to: $HostPlatform"
 302 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 303 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 304
 305 BuildPlatform_CPP=$HostPlatform_CPP
 306 TargetPlatform_CPP=$HostPlatform_CPP
 307 BuildArch_CPP=$HostArch_CPP
 308 TargetArch_CPP=$HostArch_CPP
 309 BuildOS_CPP=$HostOS_CPP
 310 HostOS_Full=$host_os
 311 TargetOS_CPP=$HostOS_CPP
 312 BuildVendor_CPP=$HostVendor_CPP
 313 TargetVendor_CPP=$HostVendor_CPP
 314
 315 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 316 dnl AC_SUBST(BuildPlatform)
 317
 318 AC_SUBST(HostPlatform)
 319 AC_SUBST(TargetPlatform)
 320 AC_SUBST(HostPlatform_CPP)
 321 dnl AC_SUBST(BuildPlatform_CPP)
 322 dnl AC_SUBST(TargetPlatform_CPP)
 323
 324 AC_SUBST(HostArch_CPP)
 325 dnl AC_SUBST(BuildArch_CPP)
 326 dnl AC_SUBST(TargetArch_CPP)
 327
 328 AC_SUBST(HostOS_CPP)
 329 AC_SUBST(HostOS_Full)
 330 dnl AC_SUBST(BuildOS_CPP)
 331 dnl AC_SUBST(TargetOS_CPP)
 332
 333 AC_SUBST(HostVendor_CPP)
 334 dnl AC_SUBST(BuildVendor_CPP)
 335 dnl AC_SUBST(TargetVendor_CPP)
 336
 337 AC_SUBST(exeext)
 338
 339 dnl --------------------------------------------------------------
 340 dnl * Project specific configuration options
 341 dnl --------------------------------------------------------------
 342 dnl What follows is a bunch of options that can either be configured
 343 dnl through command line options to the configure script or by
 344 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 345 dnl use either is considered a Feature.
 346
 347 dnl ** What command to use to compile compiler sources ?
 348 dnl --------------------------------------------------------------
 349 if test "$GHC" = ""; then
 350   AC_PATH_PROG(GHC,ghc)
 351 fi
 352
 353 AC_ARG_WITH(ghc,
 354 [  --with-ghc=<haskell compiler>
 355         Use a command different from 'ghc' to compile GHC-specific Haskell code
 356             (including GHC itself).
 357 ],
 358 [WithGhc="$withval"],
 359 [WithGhc=$GHC]
 360 )
 361 AC_SUBST(WithGhc)
 362
 363 AC_ARG_WITH(hc,
 364 [  --with-hc=<haskell compiler>
 365         Use a command different from 'ghc' to compile generic Haskell code.
 366 ],
 367 [WithHc="$withval"],
 368 [WithHc=$WithGhc]
 369 )
 370 AC_SUBST(WithHc)
 371
 372 if test "$WithGhc" != ""; then
 373   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 374   AC_SUBST(GhcVersion)dnl
 375   AC_SUBST(GhcMajVersion)dnl
 376   AC_SUBST(GhcMinVersion)dnl
 377   AC_SUBST(GhcPatchLevel)dnl
 378 fi
 379
 380 AC_PATH_PROGS(NHC,nhc nhc98)
 381 AC_PATH_PROG(HBC,hbc)
 382
 383 dnl ** Which gcc to use?
 384 dnl --------------------------------------------------------------
 385 AC_ARG_WITH(gcc,
 386 [  --with-gcc=<gcc command>
 387         Use a different command instead of 'gcc' for the GNU C compiler.
 388 ],
 389 [WhatGccIsCalled="$withval"
 390  CC="$withval"],
 391 [WhatGccIsCalled="gcc"]
 392 )
 393 AC_SUBST(WhatGccIsCalled)
 394
 395 dnl ** Booting from .hc files?
 396 dnl --------------------------------------------------------------
 397 AC_ARG_ENABLE(hc-boot,
 398 [  --enable-hc-boot
 399         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 400         (This option is mostly of interest to porters.)
 401 ],
 402 [BootingFromHc=YES],
 403 [BootingFromHc=NO]
 404 )
 405 AC_SUBST(BootingFromHc)
 406
 407 dnl ** Booting from unregisterised .hc files?
 408 dnl --------------------------------------------------------------
 409 AC_ARG_ENABLE(hc-boot-unregisterised,
 410 [  --enable-hc-boot-unregisterised
 411         With --enable-hc-boot, treat the intermediate .hc files as
 412         unregisterised rather than registerised code.
 413         (This option is mostly of interest to porters.)
 414 ],
 415 [BootingFromUnregisterisedHc=YES],
 416 [BootingFromUnregisterisedHc=NO]
 417 )
 418 AC_SUBST(BootingFromUnregisterisedHc)
 419
 420 if test "$BootingFromHc" = "NO"; then
 421 if test "$BootingFromUnregisterisedHc" = "YES"; then
 422 AC_MSG_ERROR([--enable-hc-boot-unregisterised requires --enable-hc-boot.])
 423 fi;
 424 fi;
 425
 426
 427 dnl ** Enable the construction of Win32 DLLs?
 428 dnl --------------------------------------------------------------
 429 AC_ARG_ENABLE(win32-dlls,
 430 [  --enable-win32-dlls
 431         If on a Win32 platform running mingw32/cygwin, enable the
 432         construction of DLLs containing ghc-compiled code.
 433 ],
 434 [
 435 case $HostOS_CPP in
 436 cygwin32) ;;
 437 mingw32)  ;;
 438 *)    echo "Unrecognised win32 platform: $HostPlatform"
 439       exit 1
 440       ;;
 441 esac
 442 EnableWin32DLLs=YES
 443 ],
 444 [EnableWin32DLLs=NO]
 445 )
 446 AC_SUBST(EnableWin32DLLs)
 447 if test x"$EnableWin32DLLs" = "xYES" ; then
 448  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 449 fi
 450
 451 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 452 dnl --------------------------------------------------------------
 453 AC_ARG_ENABLE(hopengl,
 454 [  --enable-hopengl
 455         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 456         (This option is only relevant when hslibs are built.)
 457 ],
 458 [GhcLibsWithHOpenGL=YES],
 459 [GhcLibsWithHOpenGL=NO]
 460 )
 461 AC_SUBST(GhcLibsWithHOpenGL)
 462
 463 dnl ** Use a specific version of the GLUT API
 464 dnl --------------------------------------------------------------
 465 AC_ARG_WITH(glut-api,
 466 [  --with-glut-api=<version>
 467         Use a specific version of the GLUT API when building HOpenGL.
 468 ])
 469 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 470
 471
 472 dnl ** Use a specific version of the GLUT API
 473 dnl --------------------------------------------------------------
 474 AC_ARG_WITH(glut-xlib,
 475 [  --with-glut-xlib=<version>
 476         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 477 ])
 478 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 479
 480
 481
 482
 483 dnl --------------------------------------------------------------
 484 dnl End of configure script option section
 485 dnl --------------------------------------------------------------
 486
 487
 488 dnl --------------------------------------------------------------
 489 dnl * General configuration checks
 490 dnl --------------------------------------------------------------
 491
 492 dnl ** does #! work?
 493 AC_SYS_INTERPRETER()
 494
 495 dnl ** look for `perl', but only in /bin on Windows
 496 case $HostOS_CPP in
 497 cygwin32|mingw32)
 498       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 499       if test -z "$PerlCmd"; then
 500          echo "You must install the version of Perl shipped with GHC"
 501          echo "(or a compatible one) in /bin."
 502          exit 1
 503       fi
 504    ;;
 505 *)
 506    AC_PATH_PROG(PerlCmd,perl)
 507    if test -z "$PerlCmd"; then
 508       echo "You must install perl before you can continue"
 509       echo "Perhaps it is already installed, but not in your PATH?"
 510       exit 1
 511    else
 512    FPTOOLS_CHECK_PERL_VERSION
 513    fi
 514    ;;
 515 esac
 516
 517 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 518 FPTOOLS_SHEBANG_PERL
 519
 520 dnl ** look for GCC and find out which version
 521 dnl     Figure out which C compiler to use.  Gcc is preferred.
 522 dnl     If gcc, make sure it's at least 2.1
 523 dnl
 524 AC_PROG_CC
 525 FPTOOLS_HAVE_GCC
 526
 527 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 528 AC_PROG_CPP
 529
 530 dnl ** does the C compiler support the following options?
 531 FPTOOLS_CC_FLAG(-mwin32,CC_SUPPORTS_MWIN32)
 532 FPTOOLS_CC_FLAG(-mno-cygwin,CC_SUPPORTS_MNO_CYGWIN)
 533
 534 EXTRA_CC_OPTS="$CC_SUPPORTS_MNO_CYGWIN $CC_SUPPORTS_MWIN32"
 535 SRC_CC_OPTS="-O $EXTRA_CC_OPTS"
 536 CPPFLAGS="$EXTRA_CC_OPTS $CPPFLAGS"
 537 AC_SUBST(SRC_CC_OPTS)
 538
 539 dnl ** figure out how to do context diffs
 540 FPTOOLS_PROG_DIFF
 541
 542 dnl ** Find find command (for Win32's benefit)
 543 AC_PATH_PROG(FindCmd, find)
 544
 545 dnl ** look for a decent parser generator (bison preferred)
 546 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 547 dnl  on the suitability of the 'yacc' returned.)
 548 FPTOOLS_PROG_YACCY
 549
 550 dnl ** Find lex command (lex or flex) - *doesn't* use autoconf's
 551 dnl    AC_PROG_LEX, since it doesn't actually check whether 'lex'
 552 dnl    exists if 'flex' doesn't.
 553 AC_PROG_LEX_STRICT
 554
 555 dnl ** figure out how to do a BSD-ish install
 556 AC_PROG_INSTALL
 557
 558 dnl If you can run configure, you certainly have /bin/sh
 559 AC_DEFINE(HAVE_BIN_SH)
 560
 561 dnl ** how to invoke `ar' and `ranlib'
 562 FPTOOLS_PROG_AR_AND_RANLIB
 563
 564
 565 dnl ** Check to see whether ln -s works
 566 AC_PROG_LN_S
 567
 568
 569 dnl ** Find the path to sed
 570 AC_PATH_PROG(SedCmd,sed)
 571
 572
 573 dnl ** check for time command
 574 AC_PATH_PROG(TimeCmd,time)
 575
 576
 577 dnl ** check for tar
 578 dnl   if GNU tar is named gtar, look for it first.
 579 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 580
 581 dnl ** check for gzip/compress
 582 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 583
 584 dnl ** check for jade/openjade & determine a working catalog
 585 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 586 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 587                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl glafp-utils/docbook/CATALOG*)
 588 if test -z "$Catalog"; then
 589   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 590 fi
 591 case $Catalog in
 592    glafp*)
 593         case $HostOS_CPP in
 594            mingw32)
 595               Catalog=`cygpath -w $hardtop/$Catalog`
 596               ;;
 597            *) Catalog=$hardtop/$Catalog
 598               ;;
 599         esac
 600    ;;
 601 esac
 602 AC_SUBST(Catalog)
 603
 604 compress_nm=`basename $CompressCmd`
 605 if test x"$compress_nm" = xgzip; then
 606   CompressCmd="$CompressCmd -d"
 607   CompressSuffix="gz"
 608 else
 609   CompressSuffix="Z"
 610 fi
 611 AC_SUBST(CompressCmd)
 612 AC_SUBST(CompressSuffix)
 613
 614 dnl ** check for installed happy binary + version
 615 dnl    (don't do it if we're booting from .hc files though.)
 616 if test "$BootingFromHc" = "NO"; then
 617 FPTOOLS_HAPPY
 618 fi;
 619
 620 dnl --------------------------------------------------
 621 dnl ### program checking section ends here ###
 622 dnl --------------------------------------------------
 623
 624 dnl --------------------------------------------------
 625 dnl * Platform header file and syscall feature tests
 626 dnl ### checking the state of the local header files and syscalls ###
 627
 628 dnl ** check for full ANSI header (.h) files
 629 AC_HEADER_STDC
 630
 631 dnl ** check for specific header (.h) files that we are interested in
 632 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h limits.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 633
 634 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 635 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 636
 637 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 638   HaveReadlineHeaders=YES
 639   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 640 else
 641   HaveReadlineHeaders=NO
 642   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 643 fi
 644 AC_SUBST(HaveReadlineHeaders)
 645
 646 dnl ** check for DOS include files
 647 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 648
 649 dnl ** check for Windows include files
 650 AC_CHECK_HEADERS(windows.h)
 651
 652 dnl ** check for OpenGL include files
 653 AC_CHECK_HEADERS(GL/gl.h)
 654
 655 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 656 AC_HEADER_TIME
 657
 658 dnl dynamic loading include files
 659 AC_CHECK_HEADERS(dlfcn.h dl.h)
 660
 661 dnl ** check for farcalloc (in bcc)
 662 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 663
 664 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 665 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 666
 667 dnl ** how do we get a timezone name, and UTC offset ?
 668 AC_STRUCT_TIMEZONE
 669
 670 dnl ** what's the type of timezone?
 671 FPTOOLS_HAVE_TIMEZONE
 672 FPTOOLS_TYPE_TIMEZONE
 673
 674 dnl ** do we have altzone?
 675 FPTOOLS_ALTZONE
 676
 677 dnl ** does struct stat contain st_blksize?
 678 AC_STRUCT_ST_BLKSIZE
 679
 680 dnl ** do we have long longs?
 681 FPTOOLS_C_LONG_LONG
 682
 683 dnl ** what are the sizes of various types
 684 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 685 AC_CHECK_SIZEOF(char,               1)
 686 AC_CHECK_SIZEOF(double,             8)
 687 AC_CHECK_SIZEOF(float,              4)
 688 AC_CHECK_SIZEOF(int,                4)
 689 AC_CHECK_SIZEOF(long,               4)
 690 if test "$fptools_cv_have_long_long" = yes; then
 691 AC_CHECK_SIZEOF(long long,          8)
 692 fi
 693 AC_CHECK_SIZEOF(short,              2)
 694 AC_CHECK_SIZEOF(unsigned char,      1)
 695 AC_CHECK_SIZEOF(unsigned int,       4)
 696 AC_CHECK_SIZEOF(unsigned long,      4)
 697 if test "$fptools_cv_have_long_long" = yes; then
 698 AC_CHECK_SIZEOF(unsigned long long, 8)
 699 fi
 700 AC_CHECK_SIZEOF(unsigned short,     2)
 701 AC_CHECK_SIZEOF(void *,             4)
 702
 703 dnl ** what are alignment constraints on various types
 704 FPTOOLS_CHECK_ALIGNMENT(char)
 705 FPTOOLS_CHECK_ALIGNMENT(double)
 706 FPTOOLS_CHECK_ALIGNMENT(float)
 707 FPTOOLS_CHECK_ALIGNMENT(int)
 708 FPTOOLS_CHECK_ALIGNMENT(long)
 709 if test "$fptools_cv_have_long_long" = yes; then
 710 FPTOOLS_CHECK_ALIGNMENT(long long)
 711 fi
 712 FPTOOLS_CHECK_ALIGNMENT(short)
 713 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 714 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 715 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 716 if test "$fptools_cv_have_long_long" = yes; then
 717 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 718 fi
 719 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 720 FPTOOLS_CHECK_ALIGNMENT(void *)
 721
 722 dnl ** map standard C types and ISO types to Haskell types
 723 FPTOOLS_CHECK_HTYPE(char)
 724 FPTOOLS_CHECK_HTYPE(signed char)
 725 FPTOOLS_CHECK_HTYPE(unsigned char)
 726 FPTOOLS_CHECK_HTYPE(short)
 727 FPTOOLS_CHECK_HTYPE(unsigned short)
 728 FPTOOLS_CHECK_HTYPE(int)
 729 FPTOOLS_CHECK_HTYPE(unsigned int)
 730 FPTOOLS_CHECK_HTYPE(long)
 731 FPTOOLS_CHECK_HTYPE(unsigned long)
 732 if test "$fptools_cv_have_long_long" = yes; then
 733 FPTOOLS_CHECK_HTYPE(long long)
 734 FPTOOLS_CHECK_HTYPE(unsigned long long)
 735 fi
 736 FPTOOLS_CHECK_HTYPE(float)
 737 FPTOOLS_CHECK_HTYPE(double)
 738 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 739 FPTOOLS_CHECK_HTYPE(size_t)
 740 FPTOOLS_CHECK_HTYPE(wchar_t)
 741 dnl Int32 is a HACK for non-ISO C compilers
 742 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 743 FPTOOLS_CHECK_HTYPE(clock_t)
 744 FPTOOLS_CHECK_HTYPE(time_t)
 745
 746 dnl ** Map OpenGL data types to Haskell types
 747 if test $GhcLibsWithHOpenGL = YES ; then
 748 FPTOOLS_CHECK_HTYPE(GLboolean)
 749 FPTOOLS_CHECK_HTYPE(GLbyte)
 750 FPTOOLS_CHECK_HTYPE(GLubyte)
 751 FPTOOLS_CHECK_HTYPE(GLshort)
 752 FPTOOLS_CHECK_HTYPE(GLushort)
 753 FPTOOLS_CHECK_HTYPE(GLint)
 754 FPTOOLS_CHECK_HTYPE(GLuint)
 755 FPTOOLS_CHECK_HTYPE(GLsizei)
 756 FPTOOLS_CHECK_HTYPE(GLenum)
 757 FPTOOLS_CHECK_HTYPE(GLbitfield)
 758 FPTOOLS_CHECK_HTYPE(GLfloat)
 759 FPTOOLS_CHECK_HTYPE(GLclampf)
 760 FPTOOLS_CHECK_HTYPE(GLdouble)
 761 FPTOOLS_CHECK_HTYPE(GLclampd)
 762 fi
 763
 764 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 765
 766 dnl ** can we open files in binary mode?
 767 FPTOOLS_O_BINARY
 768
 769 dnl ** check for GetModuleFileName and WinExec (windows only)
 770 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 771 dnl Doesn't work because the linker can't see the functions if
 772 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 773
 774 FPTOOLS_TRY_LINK_NOWARN(,[
 775 #if HAVE_WINDOWS_H
 776 #include <windows.h>
 777 #endif
 778 main() {
 779   WinExec("",0);
 780   exit(0);
 781 }
 782 ],
 783 [have_winexec=1],
 784 [have_winexec=0])
 785 if test "$have_winexec" = "1"; then
 786 AC_DEFINE(HAVE_WINEXEC)
 787 fi
 788
 789 FPTOOLS_TRY_LINK_NOWARN(,[
 790 #if HAVE_WINDOWS_H
 791 #include <windows.h>
 792 #endif
 793 main() {
 794   char* dir;
 795   GetModuleFileName((HMODULE)0,dir,0);
 796   exit(0);
 797 }
 798 ],
 799 [have_getmodulefilename=1],
 800 [have_getmodulefilename=0])
 801 if test "$have_getmodulefilename" = "1"; then
 802 AC_DEFINE(HAVE_GETMODULEFILENAME)
 803 fi
 804
 805 dnl ** check return type of signal handlers
 806 dnl Foo: assumes we can use prototypes.
 807 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 808 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 809 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 810 dnl #include <signal.h>
 811 dnl #ifdef signal
 812 dnl #undef signal
 813 dnl #endif
 814 dnl void (*signal (int, void (*)(int)))(int);
 815 dnl ],
 816 dnl [int i;],
 817 dnl ac_cv_type_signal_handler=void_int,
 818 dnl ac_cv_type_signal_handler=int_void)])
 819 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 820 dnl AC_DEFINE(VOID_INT_SIGNALS)
 821 dnl fi
 822
 823 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 824 AC_TYPE_SIGNAL
 825 if test "$ac_cv_type_signal" = void; then
 826 AC_DEFINE(VOID_INT_SIGNALS)
 827 fi
 828
 829 dnl ** check for more functions
 830 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 831 AC_CHECK_FUNCS(strcmp)
 832 AC_CHECK_FUNCS(realpath _fullpath)
 833 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 834 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 835 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 836 AC_CHECK_FUNCS(snprintf  _snprintf )
 837 AC_CHECK_FUNCS(popen     _popen )
 838 AC_CHECK_FUNCS(pclose    _pclose )
 839
 840
 841 dnl ** check for specific library functions that we are interested in
 842 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat lstat symlink sysconf timelocal times vadvise vfork localtime_r gmtime_r)
 843
 844 dnl ** check whether this machine has gmp3 installed
 845 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 846   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 847     HaveLibGmp=No; LibGmp=not-installed))
 848 AC_SUBST(HaveLibGmp)
 849 AC_SUBST(LibGmp)
 850
 851 dnl ** check whether this machine has GNU regex in libc.
 852 FPTOOLS_REGEX_IN_LIBC
 853
 854 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 855 dnl    the order of these tests matters: bfd needs liberty
 856 AC_CHECK_LIB(iberty, xmalloc)
 857 AC_CHECK_LIB(bfd,    bfd_init)
 858
 859 dnl ** check for readline, for Hugs and hslibs' Readline
 860 dnl ncurses supersedes termcap and curses, but for compatibility,
 861 dnl we have to check for all...
 862 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 863   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 864     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 865       HaveLibTermcap=NO; LibTermcap=not-installed)))
 866
 867 if test $HaveLibTermcap = YES ; then
 868   LIBS="-l$LibTermcap $LIBS"
 869   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 870 fi
 871
 872 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 873   AC_DEFINE(HAVE_READLINE_LIBS,1)
 874   LibsReadline="readline $LibTermcap"
 875 else
 876   AC_DEFINE(HAVE_READLINE_LIBS,0)
 877   LibsReadline=
 878 fi
 879 AC_SUBST(LibsReadline)
 880
 881 if test "$HaveLibReadline"; then
 882   AC_CHECK_LIB(readline, rl_erase_empty_line,
 883     [AC_DEFINE(HAVE_READLINE_4, 1)],
 884     [AC_DEFINE(HAVE_READLINE_4, 0)])
 885   AC_CHECK_LIB(readline, rl_free_undo_list,
 886     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
 887     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
 888 else
 889   AC_DEFINE(HAVE_READLINE_4, 0)
 890   AC_DEFINE(HAVE_READLINE_4_2, 0)
 891 fi
 892
 893 dnl ** check for math library
 894 FPTOOLS_CHECK_LIBM()
 895 AC_SUBST(LIBM)
 896
 897 case $HostOS_CPP in
 898 cygwin32) ;;
 899 mingw32)  ;;
 900 *) AC_PATH_XTRA() ;;
 901 esac
 902
 903 dnl ################################################################
 904 dnl Check for libraries
 905 dnl ################################################################
 906
 907 AC_CHECK_LIB(dl, dlopen,
 908         [HaveLibDL=YES
 909          AC_DEFINE(HAVE_LIBDL)
 910          LIBS="$LIBS -ldl"],
 911         [HaveLibDL=NO])
 912 AC_CHECK_FUNCS(dlopen)
 913 AC_SUBST(HaveLibDL)
 914
 915 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 916
 917 dnl --------------------------------------------------
 918 dnl * test for GTK+
 919 dnl --------------------------------------------------
 920
 921 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 922 if test "$GTK_CONFIG" != ""; then
 923    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 924         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 925     ])
 926     GTK_VERSION=$fptools_cv_gtk_version
 927 else
 928     GTK_VERSION=
 929 fi
 930
 931 case $fptools_cv_gtk_version in
 932   1.[[23]].*) ;;
 933   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 934      GTK_CONFIG=
 935      ;;
 936 esac
 937
 938 AC_SUBST(GTK_CONFIG)
 939 AC_SUBST(GTK_VERSION)
 940
 941 dnl --------------------------------------------------
 942 dnl * Miscellaneous feature tests
 943 dnl --------------------------------------------------
 944
 945 dnl ** can we get alloca?
 946 AC_FUNC_ALLOCA
 947
 948 dnl ** determine whether or not const works
 949 AC_C_CONST
 950
 951 dnl ** determine whether ANSI-function prototypes work?
 952 AC_C_PROTOTYPES
 953
 954 dnl ** are we big endian?
 955 AC_C_BIGENDIAN
 956 # Allay users' general fear of warnings of any kind.
 957 errprint(fptools configure script wizard sez: autoconf-2.50 or later should produce no warnings
 958 )
 959 errprint(if you are using 2.13 or earlier, you may get a (harmless) warning message.
 960 )
 961
 962 dnl ** check for leading underscores in symbol names
 963 FPTOOLS_UNDERSCORE
 964
 965 dnl ** how is the end of text section signalled?
 966 FPTOOLS_END_TEXT_SECTION
 967
 968 dnl ** how is the end of data section signalled?
 969 FPTOOLS_END_DATA_SECTION
 970
 971 dnl ** code before data?
 972 FPTOOLS_CODE_BEFORE_DATA
 973
 974
 975 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )