configure.in

   1 dnl == autoconf source for the Glasgow FP tools ==
   2 dnl (run "grep '^dnl \*' configure.in | sed -e 's/dnl / /g; s/\*\*/   +/g;'"
   3 dnl  (or some such) to see the outline of this file)
   4 dnl
   5 #
   6 # (c) The AQUA Project, Glasgow University, 1994-1998
   7 #
   8 # Configure script template for the Glasgow functional programming tools
   9 #
  10 # Process with 'autoconf' to get a working configure script.
  11 #
  12 # For the generated configure script, do "./configure --help" to
  13 # see what flags are available. (Better yet, read the documentation!)
  14 #
  15
  16 # First off, a distrib sanity check..
  17 AC_INIT(mk/config.mk.in)
  18
  19 dnl * Declare subdirectories that have a private configure script
  20 dnl
  21 dnl After the toplevel configuration is complete, the script will recurse into
  22 dnl these subdirectories (the use of cache values makes repeated checks cheap)
  23 dnl (We probably have to add hslibs/{OpenGL,GLUT} here later...)
  24 AC_CONFIG_SUBDIRS(ghc)
  25
  26 # -------------------------------------------------------------------------
  27 # Prepare to generate the following header files
  28 #
  29 #
  30 AC_CONFIG_HEADER(mk/config.h)
  31
  32 # No, semi-sadly, we don't do `--srcdir'...
  33 if test x"$srcdir" != 'x.' ; then
  34     echo "This configuration does not support the \`--srcdir' option.."
  35     exit 1
  36 fi
  37
  38 #
  39 # Remove common automounter nonsense + convert from UNC to DOS style paths
  40 # (UNC awareness isn't quite there yet for cygwin32-beta18 and consituent tools.)
  41 #
  42 hardtop=`pwd`
  43 hardtop=`echo $hardtop | sed 's|^/tmp_mnt.*\(/local/.*\)$|\1|' | sed 's|^/tmp_mnt/|/|' | sed 's|^/grasp_tmp|/local/grasp_tmp|' | sed 's|^//\(.\)/|\1:/|' `
  44
  45 echo ''
  46 echo "*** The top of your build tree is: $hardtop"
  47 AC_SUBST(hardtop)
  48
  49 dnl--------------------------------------------------------------------
  50 dnl * Choose host(/target/build) platform
  51 dnl--------------------------------------------------------------------
  52
  53 dnl Guess host/target/build platform(s) if necessary.
  54 AC_CANONICAL_SYSTEM
  55
  56 # "$host" defaults to "$target"
  57 if test "x$host" = xNONE ; then
  58     host=$target
  59 fi
  60
  61 dnl ** canonicalize platform names
  62 BuildPlatform=`/bin/sh $srcdir/config.sub $build` || exit 1
  63 HostPlatform=`/bin/sh $srcdir/config.sub $host` || exit 1
  64 TargetPlatform=`/bin/sh $srcdir/config.sub $target` || exit 1
  65
  66 if test x"$TargetPlatform" != x"$HostPlatform" ; then
  67     echo "GHC configuration does not support differing host/target (i.e., cross-compiling)"
  68     exit 1
  69 fi
  70
  71 exeext=''
  72 #
  73 # The following will be more difficult when we *are* cross-compiling.
  74 # Suitable names to slam in *_CPP are in platform.h.in.
  75 # We also record the architecture, vendor, and operating system (OS)
  76 # separately.
  77 case $HostPlatform in
  78 alpha-dec-osf[[12]]*)
  79         HostPlatform=alpha-dec-osf1   # canonicalise for our purposes
  80         TargetPlatform=alpha-dec-osf1 # this will work for now... (hack)
  81         BuildPlatform=alpha-dec-osf1  # hack
  82         HostPlatform_CPP='alpha_dec_osf1'
  83         HostArch_CPP='alpha'
  84         HostVendor_CPP='dec'
  85         HostOS_CPP='osf1'
  86         ;;
  87 alpha-dec-osf[[34]]*)
  88         HostPlatform=alpha-dec-osf3   # canonicalise for our purposes
  89         TargetPlatform=alpha-dec-osf3 # this will work for now... (hack)
  90         BuildPlatform=alpha-dec-osf3  # hack
  91         HostPlatform_CPP='alpha_dec_osf3'
  92         HostArch_CPP='alpha'
  93         HostVendor_CPP='dec'
  94         HostOS_CPP='osf3'
  95         ;;
  96 alpha-unknown-linux)
  97         HostPlatform=alpha-unknown-linux
  98         TargetPlatform=alpha-unknown-linux
  99         BuildPlatform=alpha-unknown-linux
 100         HostPlatform_CPP='alpha_unknown_linux'
 101         HostArch_CPP='alpha'
 102         HostVendor_CPP='unknown'
 103         HostOS_CPP='linux'
 104         ;;
 105 alpha-unknown-freebsd*)
 106         HostPlatform=alpha-unknown-freebsd
 107         TargetPlatform=alpha-unknown-freebsd
 108         BuildPlatform=alpha-unknown-freebsd
 109         HostPlatform_CPP='alpha_unknown_freebsd'
 110         HostArch_CPP='alpha'
 111         HostVendor_CPP='unknown'
 112         HostOS_CPP='freebsd'
 113         ;;
 114 hppa1.1-hp-hpux*)
 115         HostPlatform=hppa1.1-hp-hpux  # canonicalise for our purposes (hack)
 116         TargetPlatform=hppa1.1-hp-hpux
 117         BuildPlatform=hppa1.1-hp-hpux
 118         HostPlatform_CPP='hppa1_1_hp_hpux'
 119         HostArch_CPP='hppa1_1'
 120         HostVendor_CPP='hp'
 121         HostOS_CPP='hpux'
 122         ;;
 123 i[[3456]]86-*-linuxaout*)
 124         HostPlatform=i386-unknown-linuxaout   # hack again
 125         TargetPlatform=i386-unknown-linuxaout
 126         BuildPlatform=i386-unknown-linuxaout
 127         HostPlatform_CPP='i386_unknown_linuxaout'
 128         HostArch_CPP='i386'
 129         HostVendor_CPP='unknown'
 130         HostOS_CPP='linuxaout'
 131         ;;
 132 i[[3456]]86-*-linux*)
 133         HostPlatform=i386-unknown-linux # hack again
 134         TargetPlatform=i386-unknown-linux
 135         BuildPlatform=i386-unknown-linux
 136         HostPlatform_CPP='i386_unknown_linux'
 137         HostArch_CPP='i386'
 138         HostVendor_CPP='unknown'
 139         HostOS_CPP='linux'
 140         ;;
 141 i[[3456]]86-*-freebsd[[3-9]]*) # FreeBSD 3.0+ uses ELF
 142         HostPlatform=i386-unknown-freebsd # hack again
 143         TargetPlatform=i386-unknown-freebsd
 144         BuildPlatform=i386-unknown-freebsd
 145         HostPlatform_CPP='i386_unknown_freebsd'
 146         HostArch_CPP='i386'
 147         HostVendor_CPP='unknown'
 148         HostOS_CPP='freebsd'
 149         ;;
 150 i[[3456]]86-*-freebsd2*) # Older FreeBSDs are a.out
 151         HostPlatform=i386-unknown-freebsd2 # hack again
 152         TargetPlatform=i386-unknown-freebsd2
 153         BuildPlatform=i386-unknown-freebsd2
 154         HostPlatform_CPP='i386_unknown_freebsd2'
 155         HostArch_CPP='i386'
 156         HostVendor_CPP='unknown'
 157         HostOS_CPP='freebsd2'
 158         ;;
 159 i[[3456]]86-*-netbsd*)
 160         HostPlatform=i386-unknown-netbsd # hack again
 161         TargetPlatform=i386-unknown-netbsd
 162         BuildPlatform=i386-unknown-netbsd
 163         HostPlatform_CPP='i386_unknown_netbsd'
 164         HostArch_CPP='i386'
 165         HostVendor_CPP='unknown'
 166         HostOS_CPP='netbsd'
 167         ;;
 168 i[[3456]]86-*-openbsd*)
 169         HostPlatform=i386-unknown-openbsd # hack again
 170         TargetPlatform=i386-unknown-openbsd
 171         BuildPlatform=i386-unknown-openbsd
 172         HostPlatform_CPP='i386_unknown_openbsd'
 173         HostArch_CPP='i386'
 174         HostVendor_CPP='unknown'
 175         HostOS_CPP='openbsd'
 176         ;;
 177 i[[3456]]86-*-solaris2*)
 178         HostPlatform=i386-unknown-solaris2 # hack again
 179         TargetPlatform=i386-unknown-solaris2
 180         BuildPlatform=i386-unknown-solaris2
 181         HostPlatform_CPP='i386_unknown_solaris2'
 182         HostArch_CPP='i386'
 183         HostVendor_CPP='unknown'
 184         HostOS_CPP='solaris2'
 185         ;;
 186 i[[3456]]86-*-cygwin*)
 187         HostPlatform=i386-unknown-cygwin32 # hack again
 188         TargetPlatform=i386-unknown-cygwin32
 189         BuildPlatform=i386-unknown-cygwin32
 190         HostPlatform_CPP='i386_unknown_cygwin32'
 191         HostArch_CPP='i386'
 192         HostVendor_CPP='unknown'
 193         HostOS_CPP='cygwin32'
 194         exeext='.exe'
 195         ;;
 196 i[[3456]]86-*-mingw32*)
 197         HostPlatform=i386-unknown-mingw32 # hack again
 198         TargetPlatform=i386-unknown-mingw32
 199         BuildPlatform=i386-unknown-mingw32
 200         HostPlatform_CPP='i386_unknown_mingw32'
 201         HostArch_CPP='i386'
 202         HostVendor_CPP='unknown'
 203         HostOS_CPP='mingw32'
 204         exeext='.exe'
 205         ;;
 206 m68k-next-nextstep2)
 207         HostPlatform_CPP='m68k_next_nextstep2'
 208         HostArch_CPP='m68k'
 209         HostVendor_CPP='next'
 210         HostOS_CPP='nextstep2'
 211         ;;
 212 m68k-next-nextstep3)
 213         HostPlatform_CPP='m68k_next_nextstep3'
 214         HostArch_CPP='m68k'
 215         HostVendor_CPP='next'
 216         HostOS_CPP='nextstep3'
 217         ;;
 218 i[[3456]]86-next-nextstep3)
 219         HostPlatform=i386-next-nextstep3 # hack again
 220         TargetPlatform=i386-next-nextstep3
 221         BuildPlatform=i386-next-nextstep3
 222         HostPlatform_CPP='i386_next_nextstep3'
 223         HostArch_CPP='i386'
 224         HostVendor_CPP='next'
 225         HostOS_CPP='nextstep3'
 226         ;;
 227 m68k-sun-sunos4*)
 228         HostPlatform=m68k-sun-sunos4
 229         TargetPlatform=m68k-sun-sunos4 #hack
 230         BuildPlatform=m68k-sun-sunos4 #hack
 231         HostPlatform_CPP='m68k_sun_sunos4'
 232         HostArch_CPP='m68k'
 233         HostVendor_CPP='sun'
 234         HostOS_CPP='sunos4'
 235         ;;
 236 mips-dec-ultrix*)
 237         HostPlatform_CPP='mips_dec_ultrix'
 238         HostArch_CPP='mipsel'   # NB a little different
 239         HostVendor_CPP='dec'
 240         HostOS_CPP='ultrix'
 241         ;;
 242 mips-sgi-irix*)
 243         HostPlatform=mips-sgi-irix
 244         TargetPlatform=mips-sgi-irix #hack
 245         BuildPlatform=mips-sgi-irix #hack
 246         HostPlatform_CPP='mips_sgi_irix'
 247         HostArch_CPP='mipseb'   # NB a little different
 248         HostVendor_CPP='sgi'
 249         HostOS_CPP='irix'
 250         ;;
 251 rs6000-ibm-aix*)
 252         HostPlatform=rs6000-ibm-aix
 253         TargetPlatform=rs6000-ibm-aix #hack
 254         BuildPlatform=rs6000-ibm-aix #hack
 255         HostPlatform_CPP='rs6000_ibm_aix'
 256         HostArch_CPP='rs6000'
 257         HostVendor_CPP='ibm'
 258         HostOS_CPP='aix'
 259         ;;
 260 powerpc-ibm-aix*)
 261         HostPlatform=powerpc-ibm-aix
 262         TargetPlatform=powerpc-ibm-aix #hack
 263         BuildPlatform=powerpc-ibm-aix #hack
 264         HostPlatform_CPP='powerpc_ibm_aix'
 265         HostArch_CPP='powerpc'
 266         HostVendor_CPP='ibm'
 267         HostOS_CPP='aix'
 268         ;;
 269 powerpc-apple-macosx*)
 270       HostPlatform=powerpc-apple-macosx
 271       TargetPlatform=powerpc-apple-macosx #hack
 272       BuildPlatform=powerpc-apple-macosx #hack
 273         HostPlatform_CPP='powerpc_apple_macosx'
 274         HostArch_CPP='powerpc'
 275         HostVendor_CPP='apple'
 276         HostOS_CPP='macosx'
 277         ;;
 278 sparc-sun-sunos4*)
 279         HostPlatform=sparc-sun-sunos4
 280         TargetPlatform=sparc-sun-sunos4 #hack
 281         BuildPlatform=sparc-sun-sunos4 #hack
 282         HostPlatform_CPP='sparc_sun_sunos4'
 283         HostArch_CPP='sparc'
 284         HostVendor_CPP='sun'
 285         HostOS_CPP='sunos4'
 286         ;;
 287 sparc-sun-solaris2*)
 288         HostPlatform=sparc-sun-solaris2
 289         TargetPlatform=sparc-sun-solaris2 #hack
 290         BuildPlatform=sparc-sun-solaris2 #hack
 291         HostPlatform_CPP='sparc_sun_solaris2'
 292         HostArch_CPP='sparc'
 293         HostVendor_CPP='sun'
 294         HostOS_CPP='solaris2'
 295         ;;
 296 *)
 297         echo "Unrecognised platform: $HostPlatform"
 298         exit 1
 299         ;;
 300 esac
 301 echo "Canonicalised to: $HostPlatform"
 302 test  x"$HostPlatform" != x"$TargetPlatform" && echo "Target platform set to $TargetPlatform"
 303 test  x"$BuildPlatform" != x"$HostPlatform"  && echo "Build platform set to $BuildPlatform"
 304
 305 BuildPlatform_CPP=$HostPlatform_CPP
 306 TargetPlatform_CPP=$HostPlatform_CPP
 307 BuildArch_CPP=$HostArch_CPP
 308 TargetArch_CPP=$HostArch_CPP
 309 BuildOS_CPP=$HostOS_CPP
 310 HostOS_Full=$host_os
 311 TargetOS_CPP=$HostOS_CPP
 312 BuildVendor_CPP=$HostVendor_CPP
 313 TargetVendor_CPP=$HostVendor_CPP
 314
 315 dnl Cannot afford all these SUBSTs (because of braindead seds w/ 99 cmd limits)
 316 dnl AC_SUBST(BuildPlatform)
 317
 318 AC_SUBST(HostPlatform)
 319 AC_SUBST(TargetPlatform)
 320 AC_SUBST(HostPlatform_CPP)
 321 dnl AC_SUBST(BuildPlatform_CPP)
 322 dnl AC_SUBST(TargetPlatform_CPP)
 323
 324 AC_SUBST(HostArch_CPP)
 325 dnl AC_SUBST(BuildArch_CPP)
 326 dnl AC_SUBST(TargetArch_CPP)
 327
 328 AC_SUBST(HostOS_CPP)
 329 AC_SUBST(HostOS_Full)
 330 dnl AC_SUBST(BuildOS_CPP)
 331 dnl AC_SUBST(TargetOS_CPP)
 332
 333 AC_SUBST(HostVendor_CPP)
 334 dnl AC_SUBST(BuildVendor_CPP)
 335 dnl AC_SUBST(TargetVendor_CPP)
 336
 337 AC_SUBST(exeext)
 338
 339 dnl --------------------------------------------------------------
 340 dnl * Project specific configuration options
 341 dnl --------------------------------------------------------------
 342 dnl What follows is a bunch of options that can either be configured
 343 dnl through command line options to the configure script or by
 344 dnl supplying defns in the build tree's mk/build.mk. Having the option to
 345 dnl use either is considered a Feature.
 346
 347 dnl ** What command to use to compile compiler sources ?
 348 dnl --------------------------------------------------------------
 349 if test "$GHC" = ""; then
 350   AC_PATH_PROG(GHC,ghc)
 351 fi
 352
 353 AC_ARG_WITH(ghc,
 354 [  --with-ghc=<haskell compiler>
 355         Use a command different from 'ghc' to compile GHC-specific Haskell code
 356             (including GHC itself).
 357 ],
 358 [WithGhc="$withval"],
 359 [WithGhc=$GHC]
 360 )
 361 AC_SUBST(WithGhc)
 362
 363 AC_ARG_WITH(hc,
 364 [  --with-hc=<haskell compiler>
 365         Use a command different from 'ghc' to compile generic Haskell code.
 366 ],
 367 [WithHc="$withval"],
 368 [WithHc=$WithGhc]
 369 )
 370 AC_SUBST(WithHc)
 371
 372 if test "$WithGhc" != ""; then
 373   FPTOOLS_GHC_VERSION([GhcVersion], [GhcMajVersion], [GhcMinVersion], [GhcPatchLevel])dnl
 374   AC_SUBST(GhcVersion)dnl
 375   AC_SUBST(GhcMajVersion)dnl
 376   AC_SUBST(GhcMinVersion)dnl
 377   AC_SUBST(GhcPatchLevel)dnl
 378 fi
 379
 380 AC_PATH_PROGS(NHC,nhc nhc98)
 381 AC_PATH_PROG(HBC,hbc)
 382
 383 dnl ** Which gcc to use?
 384 dnl --------------------------------------------------------------
 385 AC_ARG_WITH(gcc,
 386 [  --with-gcc=<gcc command>
 387         Use a different command instead of 'gcc' for the GNU C compiler.
 388 ],
 389 [WhatGccIsCalled="$withval"
 390  CC="$withval"],
 391 [WhatGccIsCalled="gcc"]
 392 )
 393 AC_SUBST(WhatGccIsCalled)
 394
 395 dnl ** Booting from .hc files?
 396 dnl --------------------------------------------------------------
 397 AC_ARG_ENABLE(hc-boot,
 398 [  --enable-hc-boot
 399         Boot the Glasgow Haskell Compiler from intermediate .hc files.
 400         (This option is mostly of interest to porters.)
 401 ],
 402 [BootingFromHc=YES],
 403 [BootingFromHc=NO]
 404 )
 405 AC_SUBST(BootingFromHc)
 406
 407
 408 dnl ** Enable the construction of Win32 DLLs?
 409 dnl --------------------------------------------------------------
 410 AC_ARG_ENABLE(win32-dlls,
 411 [  --enable-win32-dlls
 412         If on a Win32 platform running mingw32/cygwin, enable the
 413         construction of DLLs containing ghc-compiled code.
 414 ],
 415 [
 416 case $HostOS_CPP in
 417 cygwin32) ;;
 418 mingw32)  ;;
 419 *)    echo "Unrecognised win32 platform: $HostPlatform"
 420       exit 1
 421       ;;
 422 esac
 423 EnableWin32DLLs=YES
 424 ],
 425 [EnableWin32DLLs=NO]
 426 )
 427 AC_SUBST(EnableWin32DLLs)
 428 if test x"$EnableWin32DLLs" = "xYES" ; then
 429  AC_DEFINE(HAVE_WIN32_DLL_SUPPORT)
 430 fi
 431
 432 dnl ** Enable the building of the OpenGL/GLUT binding in hslibs?
 433 dnl --------------------------------------------------------------
 434 AC_ARG_ENABLE(hopengl,
 435 [  --enable-hopengl
 436         Build HOpenGL, a Haskell binding for OpenGL/GLUT, too.
 437         (This option is only relevant when hslibs are built.)
 438 ],
 439 [GhcLibsWithHOpenGL=YES],
 440 [GhcLibsWithHOpenGL=NO]
 441 )
 442 AC_SUBST(GhcLibsWithHOpenGL)
 443
 444 dnl ** Use a specific version of the GLUT API
 445 dnl --------------------------------------------------------------
 446 AC_ARG_WITH(glut-api,
 447 [  --with-glut-api=<version>
 448         Use a specific version of the GLUT API when building HOpenGL.
 449 ])
 450 test -n "$with_glut_api"  && CPPFLAGS="$CPPFLAGS -DGLUT_API_VERSION=$with_glut_api"
 451
 452
 453 dnl ** Use a specific version of the GLUT API
 454 dnl --------------------------------------------------------------
 455 AC_ARG_WITH(glut-xlib,
 456 [  --with-glut-xlib=<version>
 457         Use a specific version of the GLUT Xlib implementation when building HOpenGL.
 458 ])
 459 test -n "$with_glut_xlib" && CPPFLAGS="$CPPFLAGS -DGLUT_XLIB_IMPLEMENTATION=$with_glut_xlib"
 460
 461
 462
 463
 464 dnl --------------------------------------------------------------
 465 dnl End of configure script option section
 466 dnl --------------------------------------------------------------
 467
 468
 469 dnl --------------------------------------------------------------
 470 dnl * General configuration checks
 471 dnl --------------------------------------------------------------
 472
 473 dnl ** does #! work?
 474 AC_SYS_INTERPRETER()
 475
 476 dnl ** look for `perl', but only in /bin on Windows
 477 case $HostOS_CPP in
 478 cygwin32|mingw32)
 479       AC_CHECK_PROG(PerlCmd,perl,/bin/perl,,/bin)
 480       if test -z "$PerlCmd"; then
 481          echo "You must install the version of Perl shipped with GHC"
 482          echo "(or a compatible one) in /bin."
 483          exit 1
 484       fi
 485    ;;
 486 *)
 487    AC_PATH_PROG(PerlCmd,perl)
 488    if test -z "$PerlCmd"; then
 489       echo "You must install perl before you can continue"
 490       echo "Perhaps it is already installed, but not in your PATH?"
 491       exit 1
 492    else
 493    FPTOOLS_CHECK_PERL_VERSION
 494    fi
 495    ;;
 496 esac
 497
 498 dnl ** does #! path/to/perl work? (sometimes it's too long...)
 499 FPTOOLS_SHEBANG_PERL
 500
 501 dnl ** look for GCC and find out which version
 502 dnl     Figure out which C compiler to use.  Gcc is preferred.
 503 dnl     If gcc, make sure it's at least 2.1
 504 dnl
 505 AC_PROG_CC
 506 FPTOOLS_HAVE_GCC
 507
 508 dnl ** figure out how to invoke cpp directly (gcc -E is no good)
 509 AC_PROG_CPP
 510
 511 dnl ** does the C compiler support the following options?
 512 FPTOOLS_CC_FLAG(-mwin32,CC_SUPPORTS_MWIN32)
 513 FPTOOLS_CC_FLAG(-mno-cygwin,CC_SUPPORTS_MNO_CYGWIN)
 514
 515 EXTRA_CC_OPTS="$CC_SUPPORTS_MNO_CYGWIN $CC_SUPPORTS_MWIN32"
 516 SRC_CC_OPTS="-O $EXTRA_CC_OPTS"
 517 CPPFLAGS="$EXTRA_CC_OPTS $CPPFLAGS"
 518 AC_SUBST(SRC_CC_OPTS)
 519
 520 dnl ** figure out how to do context diffs
 521 FPTOOLS_PROG_DIFF
 522
 523 dnl ** Find find command (for Win32's benefit)
 524 AC_PATH_PROG(FindCmd, find)
 525
 526 dnl ** look for a decent parser generator (bison preferred)
 527 dnl (FPTOOLS_PROG_YACCY is AC_PROG_YACC, but with some extra testing
 528 dnl  on the suitability of the 'yacc' returned.)
 529 FPTOOLS_PROG_YACCY
 530
 531 dnl ** Find lex command (lex or flex) - *doesn't* use autoconf's
 532 dnl    AC_PROG_LEX, since it doesn't actually check whether 'lex'
 533 dnl    exists if 'flex' doesn't.
 534 AC_PROG_LEX_STRICT
 535
 536 dnl ** figure out how to do a BSD-ish install
 537 AC_PROG_INSTALL
 538
 539 dnl If you can run configure, you certainly have /bin/sh
 540 AC_DEFINE(HAVE_BIN_SH)
 541
 542 dnl ** how to invoke `ar' and `ranlib'
 543 FPTOOLS_PROG_AR_AND_RANLIB
 544
 545
 546 dnl ** Check to see whether ln -s works
 547 AC_PROG_LN_S
 548
 549
 550 dnl ** Find the path to sed
 551 AC_PATH_PROG(SedCmd,sed)
 552
 553
 554 dnl ** check for time command
 555 AC_PATH_PROG(TimeCmd,time)
 556
 557
 558 dnl ** check for tar
 559 dnl   if GNU tar is named gtar, look for it first.
 560 AC_PATH_PROGS(TarCmd,gtar tar,tar)
 561
 562 dnl ** check for gzip/compress
 563 AC_PATH_PROGS(CompressCmd,gzip compress,gzip)
 564
 565 dnl ** check for jade/openjade & determine a working catalog
 566 AC_PATH_PROGS(JadeCmd,openjade jade,jade)
 567 FPTOOLS_DOCBOOK_CATALOG(Catalog, $JadeCmd, docs/fptools-both.dsl,
 568                         /etc/sgml/catalog /etc/sgml.catalog /usr/share/sgml/CATALOG.docbkdsl glafp-utils/docbook/CATALOG*)
 569 if test -z "$Catalog"; then
 570   AC_MSG_RESULT([Warning: You will not be able to build the documentation.])
 571 fi
 572 Catalog=$hardtop/$Catalog
 573 AC_SUBST(Catalog)
 574
 575 compress_nm=`basename $CompressCmd`
 576 if test x"$compress_nm" = xgzip; then
 577   CompressCmd="$CompressCmd -d"
 578   CompressSuffix="gz"
 579 else
 580   CompressSuffix="Z"
 581 fi
 582 AC_SUBST(CompressCmd)
 583 AC_SUBST(CompressSuffix)
 584
 585 dnl ** check for installed happy binary + version
 586 dnl    (don't do it if we're booting from .hc files though.)
 587 if test "$BootingFromHc" = "NO"; then
 588 FPTOOLS_HAPPY
 589 fi;
 590
 591 dnl --------------------------------------------------
 592 dnl ### program checking section ends here ###
 593 dnl --------------------------------------------------
 594
 595 dnl --------------------------------------------------
 596 dnl * Platform header file and syscall feature tests
 597 dnl ### checking the state of the local header files and syscalls ###
 598
 599 dnl ** check for full ANSI header (.h) files
 600 AC_HEADER_STDC
 601
 602 dnl ** check for specific header (.h) files that we are interested in
 603 AC_CHECK_HEADERS(Files.h arpa/inet.h assert.h console.h ctype.h dirent.h errno.h fcntl.h float.h ftw.h grp.h ieee754.h inttypes.h malloc.h memory.h nlist.h pascal.h pwd.h sgtty.h siginfo.h signal.h stat.h stdint.h stdlib.h stdarg.h string.h sys/fault.h sys/file.h sys/ioctl.h sys/limits.h sys/mman.h sys/param.h sys/procfs.h sys/resource.h sys/signal.h sys/socket.h netdb.h netinet/in.h netinet/tcp.h sys/stat.h sys/syscall.h sys/time.h sys/timeb.h sys/timers.h sys/times.h sys/types.h sys/un.h sys/utsname.h sys/vadvise.h sys/wait.h termio.h termios.h time.h types.h unistd.h utime.h values.h vfork.h bfd.h winsock.h)
 604
 605 AC_CHECK_HEADER(readline/readline.h, HaveReadlineReadlineH=YES, HaveReadlineReadlineH=NO)
 606 AC_CHECK_HEADER(readline/history.h, HaveReadlineHistoryH=YES, HaveReadlineHistoryH=NO)
 607
 608 if test $HaveReadlineReadlineH = YES && test $HaveReadlineHistoryH = YES ; then
 609   HaveReadlineHeaders=YES
 610   AC_DEFINE(HAVE_READLINE_HEADERS,1)
 611 else
 612   HaveReadlineHeaders=NO
 613   AC_DEFINE(HAVE_READLINE_HEADERS,0)
 614 fi
 615 AC_SUBST(HaveReadlineHeaders)
 616
 617 dnl ** check for DOS include files
 618 AC_CHECK_HEADERS(dos.h conio.h io.h std.h)
 619
 620 dnl ** check for Windows include files
 621 AC_CHECK_HEADERS(windows.h)
 622
 623 dnl ** check for OpenGL include files
 624 AC_CHECK_HEADERS(GL/gl.h)
 625
 626 dnl ** check if it is safe to include both <time.h> and <sys/time.h>
 627 AC_HEADER_TIME
 628
 629 dnl dynamic loading include files
 630 AC_CHECK_HEADERS(dlfcn.h dl.h)
 631
 632 dnl ** check for farcalloc (in bcc)
 633 AC_CHECK_HEADER(alloc.h,AC_CHECK_FUNCS(farcalloc))
 634
 635 dnl ** check for valloc (in sunos, solaris, mips, amiga, next, minix, ultrix)
 636 AC_CHECK_HEADER(malloc.h,AC_CHECK_FUNCS(valloc))
 637
 638 dnl ** how do we get a timezone name, and UTC offset ?
 639 AC_STRUCT_TIMEZONE
 640
 641 dnl ** what's the type of timezone?
 642 FPTOOLS_HAVE_TIMEZONE
 643 FPTOOLS_TYPE_TIMEZONE
 644
 645 dnl ** do we have altzone?
 646 FPTOOLS_ALTZONE
 647
 648 dnl ** does struct stat contain st_blksize?
 649 AC_STRUCT_ST_BLKSIZE
 650
 651 dnl ** do we have long longs?
 652 FPTOOLS_C_LONG_LONG
 653
 654 dnl ** what are the sizes of various types
 655 dnl    (these must come before GHC_CHECK_ALIGNMENT)
 656 AC_CHECK_SIZEOF(char,               1)
 657 AC_CHECK_SIZEOF(double,             8)
 658 AC_CHECK_SIZEOF(float,              4)
 659 AC_CHECK_SIZEOF(int,                4)
 660 AC_CHECK_SIZEOF(long,               4)
 661 if test "$fptools_cv_have_long_long" = yes; then
 662 AC_CHECK_SIZEOF(long long,          8)
 663 fi
 664 AC_CHECK_SIZEOF(short,              2)
 665 AC_CHECK_SIZEOF(unsigned char,      1)
 666 AC_CHECK_SIZEOF(unsigned int,       4)
 667 AC_CHECK_SIZEOF(unsigned long,      4)
 668 if test "$fptools_cv_have_long_long" = yes; then
 669 AC_CHECK_SIZEOF(unsigned long long, 8)
 670 fi
 671 AC_CHECK_SIZEOF(unsigned short,     2)
 672 AC_CHECK_SIZEOF(void *,             4)
 673
 674 dnl ** what are alignment constraints on various types
 675 FPTOOLS_CHECK_ALIGNMENT(char)
 676 FPTOOLS_CHECK_ALIGNMENT(double)
 677 FPTOOLS_CHECK_ALIGNMENT(float)
 678 FPTOOLS_CHECK_ALIGNMENT(int)
 679 FPTOOLS_CHECK_ALIGNMENT(long)
 680 if test "$fptools_cv_have_long_long" = yes; then
 681 FPTOOLS_CHECK_ALIGNMENT(long long)
 682 fi
 683 FPTOOLS_CHECK_ALIGNMENT(short)
 684 FPTOOLS_CHECK_ALIGNMENT(unsigned char)
 685 FPTOOLS_CHECK_ALIGNMENT(unsigned int)
 686 FPTOOLS_CHECK_ALIGNMENT(unsigned long)
 687 if test "$fptools_cv_have_long_long" = yes; then
 688 FPTOOLS_CHECK_ALIGNMENT(unsigned long long)
 689 fi
 690 FPTOOLS_CHECK_ALIGNMENT(unsigned short)
 691 FPTOOLS_CHECK_ALIGNMENT(void *)
 692
 693 dnl ** map standard C types and ISO types to Haskell types
 694 FPTOOLS_CHECK_HTYPE(char)
 695 FPTOOLS_CHECK_HTYPE(signed char)
 696 FPTOOLS_CHECK_HTYPE(unsigned char)
 697 FPTOOLS_CHECK_HTYPE(short)
 698 FPTOOLS_CHECK_HTYPE(unsigned short)
 699 FPTOOLS_CHECK_HTYPE(int)
 700 FPTOOLS_CHECK_HTYPE(unsigned int)
 701 FPTOOLS_CHECK_HTYPE(long)
 702 FPTOOLS_CHECK_HTYPE(unsigned long)
 703 if test "$fptools_cv_have_long_long" = yes; then
 704 FPTOOLS_CHECK_HTYPE(long long)
 705 FPTOOLS_CHECK_HTYPE(unsigned long long)
 706 fi
 707 FPTOOLS_CHECK_HTYPE(float)
 708 FPTOOLS_CHECK_HTYPE(double)
 709 FPTOOLS_CHECK_HTYPE(ptrdiff_t)
 710 FPTOOLS_CHECK_HTYPE(size_t)
 711 FPTOOLS_CHECK_HTYPE(wchar_t)
 712 dnl Int32 is a HACK for non-ISO C compilers
 713 FPTOOLS_CHECK_HTYPE(sig_atomic_t, Int32)
 714 FPTOOLS_CHECK_HTYPE(clock_t)
 715 FPTOOLS_CHECK_HTYPE(time_t)
 716
 717 dnl ** Map OpenGL data types to Haskell types
 718 if test $GhcLibsWithHOpenGL = YES ; then
 719 FPTOOLS_CHECK_HTYPE(GLboolean)
 720 FPTOOLS_CHECK_HTYPE(GLbyte)
 721 FPTOOLS_CHECK_HTYPE(GLubyte)
 722 FPTOOLS_CHECK_HTYPE(GLshort)
 723 FPTOOLS_CHECK_HTYPE(GLushort)
 724 FPTOOLS_CHECK_HTYPE(GLint)
 725 FPTOOLS_CHECK_HTYPE(GLuint)
 726 FPTOOLS_CHECK_HTYPE(GLsizei)
 727 FPTOOLS_CHECK_HTYPE(GLenum)
 728 FPTOOLS_CHECK_HTYPE(GLbitfield)
 729 FPTOOLS_CHECK_HTYPE(GLfloat)
 730 FPTOOLS_CHECK_HTYPE(GLclampf)
 731 FPTOOLS_CHECK_HTYPE(GLdouble)
 732 FPTOOLS_CHECK_HTYPE(GLclampd)
 733 fi
 734
 735 FPTOOLS_CHECK_CCONSTS(E2BIG EACCES EADDRINUSE EADDRNOTAVAIL EADV EAFNOSUPPORT EAGAIN EALREADY EBADF EBADMSG EBADRPC EBUSY ECHILD ECOMM ECONNABORTED ECONNREFUSED ECONNRESET EDEADLK EDESTADDRREQ EDIRTY EDOM EDQUOT EEXIST EFAULT EFBIG EFTYPE EHOSTDOWN EHOSTUNREACH EIDRM EILSEQ EINPROGRESS EINTR EINVAL EIO EISCONN EISDIR ELOOP EMFILE EMLINK EMSGSIZE EMULTIHOP ENAMETOOLONG ENETDOWN ENETRESET ENETUNREACH ENFILE ENOBUFS ENODATA ENODEV ENOENT ENOEXEC ENOLCK ENOLINK ENOMEM ENOMSG ENONET ENOPROTOOPT ENOSPC ENOSR ENOSTR ENOSYS ENOTBLK ENOTCONN ENOTDIR ENOTEMPTY ENOTSOCK ENOTTY ENXIO EOPNOTSUPP EPERM EPFNOSUPPORT EPIPE EPROCLIM EPROCUNAVAIL EPROGMISMATCH EPROGUNAVAIL EPROTO EPROTONOSUPPORT EPROTOTYPE ERANGE EREMCHG EREMOTE EROFS ERPCMISMATCH ERREMOTE ESHUTDOWN ESOCKTNOSUPPORT ESPIPE ESRCH ESRMNT ESTALE ETIME ETIMEDOUT ETOOMANYREFS ETXTBSY EUSERS EWOULDBLOCK EXDEV)
 736
 737 dnl ** can we open files in binary mode?
 738 FPTOOLS_O_BINARY
 739
 740 dnl ** check for GetModuleFileName and WinExec (windows only)
 741 dnl Old: AC_CHECK_FUNCS(WinExec GetModuleFileName)       dnl Windows
 742 dnl Doesn't work because the linker can't see the functions if
 743 dnl you omit the #include <windows.h>.  (I've no idea why not...)
 744
 745 FPTOOLS_TRY_LINK_NOWARN(,[
 746 #if HAVE_WINDOWS_H
 747 #include <windows.h>
 748 #endif
 749 main() {
 750   WinExec("",0);
 751   exit(0);
 752 }
 753 ],
 754 [have_winexec=1],
 755 [have_winexec=0])
 756 if test "$have_winexec" = "1"; then
 757 AC_DEFINE(HAVE_WINEXEC)
 758 fi
 759
 760 FPTOOLS_TRY_LINK_NOWARN(,[
 761 #if HAVE_WINDOWS_H
 762 #include <windows.h>
 763 #endif
 764 main() {
 765   char* dir;
 766   GetModuleFileName((HMODULE)0,dir,0);
 767   exit(0);
 768 }
 769 ],
 770 [have_getmodulefilename=1],
 771 [have_getmodulefilename=0])
 772 if test "$have_getmodulefilename" = "1"; then
 773 AC_DEFINE(HAVE_GETMODULEFILENAME)
 774 fi
 775
 776 dnl ** check return type of signal handlers
 777 dnl Foo: assumes we can use prototypes.
 778 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 779 dnl AC_CACHE_CHECK([type of signal handlers], ac_cv_type_signal_handler,
 780 dnl [AC_TRY_COMPILE([#include <sys/types.h>
 781 dnl #include <signal.h>
 782 dnl #ifdef signal
 783 dnl #undef signal
 784 dnl #endif
 785 dnl void (*signal (int, void (*)(int)))(int);
 786 dnl ],
 787 dnl [int i;],
 788 dnl ac_cv_type_signal_handler=void_int,
 789 dnl ac_cv_type_signal_handler=int_void)])
 790 dnl if test "$ac_cv_type_signal_handler" = void_int; then
 791 dnl AC_DEFINE(VOID_INT_SIGNALS)
 792 dnl fi
 793
 794 dnl On BCC, signal handlers have type "int(void)", elsewhere its "void(int)".
 795 AC_TYPE_SIGNAL
 796 if test "$ac_cv_type_signal" = void; then
 797 AC_DEFINE(VOID_INT_SIGNALS)
 798 fi
 799
 800 dnl ** check for more functions
 801 AC_CHECK_FUNCS(strcasecmp _stricmp stricmp strcmpi)
 802 AC_CHECK_FUNCS(strcmp)
 803 AC_CHECK_FUNCS(realpath _fullpath)
 804 AC_CHECK_FUNCS(PBHSetVolSync macsystem)
 805 AC_CHECK_FUNCS(fgetpos fsetpos fseek ftell)
 806 AC_CHECK_FUNCS(vsnprintf _vsnprintf)
 807 AC_CHECK_FUNCS(snprintf  _snprintf )
 808 AC_CHECK_FUNCS(popen     _popen )
 809 AC_CHECK_FUNCS(pclose    _pclose )
 810
 811
 812 dnl ** check for specific library functions that we are interested in
 813 AC_CHECK_FUNCS(access ftime getclock getpagesize getrusage gettimeofday mktime mprotect readlink setitimer stat symlink sysconf timelocal times vadvise vfork)
 814
 815 dnl ** check whether this machine has gmp3 installed
 816 AC_CHECK_LIB(gmp,  __gmpz_fdiv_qr, HaveLibGmp=YES; LibGmp=gmp,
 817   AC_CHECK_LIB(gmp3, __gmpz_fdiv_qr,  HaveLibGmp=YES; LibGmp=gmp3,
 818     HaveLibGmp=No; LibGmp=not-installed))
 819 AC_SUBST(HaveLibGmp)
 820 AC_SUBST(LibGmp)
 821
 822 dnl ** check whether this machine has GNU regex in libc.
 823 FPTOOLS_REGEX_IN_LIBC
 824
 825 dnl ** check whether this machine has BFD and liberty installed (used for debugging)
 826 dnl    the order of these tests matters: bfd needs liberty
 827 AC_CHECK_LIB(iberty, xmalloc)
 828 AC_CHECK_LIB(bfd,    bfd_init)
 829
 830 dnl ** check for readline, for Hugs and hslibs' Readline
 831 dnl ncurses supersedes termcap and curses, but for compatibility,
 832 dnl we have to check for all...
 833 AC_CHECK_LIB(ncurses, tputs, HaveLibTermcap=YES; LibTermcap=ncurses,
 834   AC_CHECK_LIB(termcap, tputs, HaveLibTermcap=YES; LibTermcap=termcap,
 835     AC_CHECK_LIB(curses, tputs, HaveLibTermcap=YES; LibTermcap=curses,
 836       HaveLibTermcap=NO; LibTermcap=not-installed)))
 837
 838 if test $HaveLibTermcap = YES ; then
 839   LIBS="-l$LibTermcap $LIBS"
 840   AC_CHECK_LIB(readline, readline, HaveLibReadline=YES, HaveLibReadline=NO)
 841 fi
 842
 843 if test $HaveLibTermcap = YES && test x"$HaveLibReadline" = xYES ; then
 844   AC_DEFINE(HAVE_READLINE_LIBS,1)
 845   LibsReadline="readline $LibTermcap"
 846 else
 847   AC_DEFINE(HAVE_READLINE_LIBS,0)
 848   LibsReadline=
 849 fi
 850 AC_SUBST(LibsReadline)
 851
 852 if test "$HaveLibReadline"; then
 853   AC_CHECK_LIB(readline, rl_erase_empty_line,
 854     [AC_DEFINE(HAVE_READLINE_4, 1)],
 855     [AC_DEFINE(HAVE_READLINE_4, 0)])
 856   AC_CHECK_LIB(readline, rl_free_undo_list,
 857     [AC_DEFINE(HAVE_READLINE_4_2, 1)],
 858     [AC_DEFINE(HAVE_READLINE_4_2, 0)])
 859 else
 860   AC_DEFINE(HAVE_READLINE_4, 0)
 861   AC_DEFINE(HAVE_READLINE_4_2, 0)
 862 fi
 863
 864 dnl ** check for math library
 865 FPTOOLS_CHECK_LIBM()
 866 AC_SUBST(LIBM)
 867
 868 case $HostOS_CPP in
 869 cygwin32) ;;
 870 mingw32)  ;;
 871 *) AC_PATH_XTRA() ;;
 872 esac
 873
 874 dnl ################################################################
 875 dnl Check for libraries
 876 dnl ################################################################
 877
 878 AC_CHECK_LIB(dl, dlopen,
 879         [HaveLibDL=YES
 880          AC_DEFINE(HAVE_LIBDL)
 881          LIBS="$LIBS -ldl"],
 882         [HaveLibDL=NO])
 883 AC_CHECK_FUNCS(dlopen)
 884 AC_SUBST(HaveLibDL)
 885
 886 FPTOOLS_CHECK_LIB_NOWARN(m, atan)
 887
 888 dnl --------------------------------------------------
 889 dnl * test for GTK+
 890 dnl --------------------------------------------------
 891
 892 AC_PATH_PROGS(GTK_CONFIG, gtk-config gtk12-config)
 893 if test "$GTK_CONFIG" != ""; then
 894    AC_CACHE_CHECK([for version of GTK+], fptools_cv_gtk_version, [
 895         fptools_cv_gtk_version=`$GTK_CONFIG --version`
 896     ])
 897     GTK_VERSION=$fptools_cv_gtk_version
 898 else
 899     GTK_VERSION=
 900 fi
 901
 902 case $fptools_cv_gtk_version in
 903   1.[[23]].*) ;;
 904   *) AC_MSG_WARN([GTK+ not usable; need at least version 1.2])
 905      GTK_CONFIG=
 906      ;;
 907 esac
 908
 909 AC_SUBST(GTK_CONFIG)
 910 AC_SUBST(GTK_VERSION)
 911
 912 dnl --------------------------------------------------
 913 dnl * Miscellaneous feature tests
 914 dnl --------------------------------------------------
 915
 916 dnl ** can we get alloca?
 917 AC_FUNC_ALLOCA
 918
 919 dnl ** determine whether or not const works
 920 AC_C_CONST
 921
 922 dnl ** determine whether ANSI-function prototypes work?
 923 AC_C_PROTOTYPES
 924
 925 dnl ** are we big endian?
 926 AC_C_BIGENDIAN
 927 # Allay users' general fear of warnings of any kind.
 928 errprint((fptools configure script wizard sez: "don't worry, the above warning is harmless (to us.)")
 929 )
 930
 931 dnl ** check for leading underscores in symbol names
 932 FPTOOLS_UNDERSCORE
 933
 934 dnl ** how is the end of text section signalled?
 935 FPTOOLS_END_TEXT_SECTION
 936
 937 dnl ** how is the end of data section signalled?
 938 FPTOOLS_END_DATA_SECTION
 939
 940 dnl ** code before data?
 941 FPTOOLS_CODE_BEFORE_DATA
 942
 943
 944 AC_OUTPUT(mk/config.mk, echo timestamp > mk/stamp-h )